lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13 use Scalar::Util 'blessed';
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid disable_sth_caching cursor on_connect_do
  18        transaction_depth/
  19 );
  20
  21 BEGIN {
  22
  23 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  24
  25 use base qw/SQL::Abstract::Limit/;
  26
  27 # This prevents the caching of $dbh in S::A::L, I believe
  28 sub new {
  29   my $self = shift->SUPER::new(@_);
  30
  31   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  32   #   it with what it resolves to:
  33   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  34     if ref $self->{limit_dialect};
  35
  36   $self;
  37 }
  38
  39 sub _RowNumberOver {
  40   my ($self, $sql, $order, $rows, $offset ) = @_;
  41
  42   $offset += 1;
  43   my $last = $rows + $offset;
  44   my ( $order_by ) = $self->_order_by( $order );
  45
  46   $sql = <<"";
  47 SELECT * FROM
  48 (
  49    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  50       $sql
  51       $order_by
  52    ) Q1
  53 ) Q2
  54 WHERE ROW_NUM BETWEEN $offset AND $last
  55
  56   return $sql;
  57 }
  58
  59
  60 # While we're at it, this should make LIMIT queries more efficient,
  61 #  without digging into things too deeply
  62 use Scalar::Util 'blessed';
  63 sub _find_syntax {
  64   my ($self, $syntax) = @_;
  65   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  66   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  67     return 'RowNumberOver';
  68   }
  69
  70   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  71 }
  72
  73 sub select {
  74   my ($self, $table, $fields, $where, $order, @rest) = @_;
  75   $table = $self->_quote($table) unless ref($table);
  76   local $self->{rownum_hack_count} = 1
  77     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  78   @rest = (-1) unless defined $rest[0];
  79   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  80     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  81   local $self->{having_bind} = [];
  82   my ($sql, @ret) = $self->SUPER::select(
  83     $table, $self->_recurse_fields($fields), $where, $order, @rest
  84   );
  85   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  86 }
  87
  88 sub insert {
  89   my $self = shift;
  90   my $table = shift;
  91   $table = $self->_quote($table) unless ref($table);
  92   $self->SUPER::insert($table, @_);
  93 }
  94
  95 sub update {
  96   my $self = shift;
  97   my $table = shift;
  98   $table = $self->_quote($table) unless ref($table);
  99   $self->SUPER::update($table, @_);
 100 }
 101
 102 sub delete {
 103   my $self = shift;
 104   my $table = shift;
 105   $table = $self->_quote($table) unless ref($table);
 106   $self->SUPER::delete($table, @_);
 107 }
 108
 109 sub _emulate_limit {
 110   my $self = shift;
 111   if ($_[3] == -1) {
 112     return $_[1].$self->_order_by($_[2]);
 113   } else {
 114     return $self->SUPER::_emulate_limit(@_);
 115   }
 116 }
 117
 118 sub _recurse_fields {
 119   my ($self, $fields) = @_;
 120   my $ref = ref $fields;
 121   return $self->_quote($fields) unless $ref;
 122   return $$fields if $ref eq 'SCALAR';
 123
 124   if ($ref eq 'ARRAY') {
 125     return join(', ', map {
 126       $self->_recurse_fields($_)
 127       .(exists $self->{rownum_hack_count}
 128          ? ' AS col'.$self->{rownum_hack_count}++
 129          : '')
 130      } @$fields);
 131   } elsif ($ref eq 'HASH') {
 132     foreach my $func (keys %$fields) {
 133       return $self->_sqlcase($func)
 134         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 135     }
 136   }
 137 }
 138
 139 sub _order_by {
 140   my $self = shift;
 141   my $ret = '';
 142   my @extra;
 143   if (ref $_[0] eq 'HASH') {
 144     if (defined $_[0]->{group_by}) {
 145       $ret = $self->_sqlcase(' group by ')
 146                .$self->_recurse_fields($_[0]->{group_by});
 147     }
 148     if (defined $_[0]->{having}) {
 149       my $frag;
 150       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 151       push(@{$self->{having_bind}}, @extra);
 152       $ret .= $self->_sqlcase(' having ').$frag;
 153     }
 154     if (defined $_[0]->{order_by}) {
 155       $ret .= $self->_order_by($_[0]->{order_by});
 156     }
 157   } elsif (ref $_[0] eq 'SCALAR') {
 158     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 159   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 160     my @order = @{+shift};
 161     $ret = $self->_sqlcase(' order by ')
 162           .join(', ', map {
 163                         my $r = $self->_order_by($_, @_);
 164                         $r =~ s/^ ?ORDER BY //i;
 165                         $r;
 166                       } @order);
 167   } else {
 168     $ret = $self->SUPER::_order_by(@_);
 169   }
 170   return $ret;
 171 }
 172
 173 sub _order_directions {
 174   my ($self, $order) = @_;
 175   $order = $order->{order_by} if ref $order eq 'HASH';
 176   return $self->SUPER::_order_directions($order);
 177 }
 178
 179 sub _table {
 180   my ($self, $from) = @_;
 181   if (ref $from eq 'ARRAY') {
 182     return $self->_recurse_from(@$from);
 183   } elsif (ref $from eq 'HASH') {
 184     return $self->_make_as($from);
 185   } else {
 186     return $from; # would love to quote here but _table ends up getting called
 187                   # twice during an ->select without a limit clause due to
 188                   # the way S::A::Limit->select works. should maybe consider
 189                   # bypassing this and doing S::A::select($self, ...) in
 190                   # our select method above. meantime, quoting shims have
 191                   # been added to select/insert/update/delete here
 192   }
 193 }
 194
 195 sub _recurse_from {
 196   my ($self, $from, @join) = @_;
 197   my @sqlf;
 198   push(@sqlf, $self->_make_as($from));
 199   foreach my $j (@join) {
 200     my ($to, $on) = @$j;
 201
 202     # check whether a join type exists
 203     my $join_clause = '';
 204     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 205     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 206       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 207     } else {
 208       $join_clause = ' JOIN ';
 209     }
 210     push(@sqlf, $join_clause);
 211
 212     if (ref $to eq 'ARRAY') {
 213       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 214     } else {
 215       push(@sqlf, $self->_make_as($to));
 216     }
 217     push(@sqlf, ' ON ', $self->_join_condition($on));
 218   }
 219   return join('', @sqlf);
 220 }
 221
 222 sub _make_as {
 223   my ($self, $from) = @_;
 224   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 225                      reverse each %{$self->_skip_options($from)});
 226 }
 227
 228 sub _skip_options {
 229   my ($self, $hash) = @_;
 230   my $clean_hash = {};
 231   $clean_hash->{$_} = $hash->{$_}
 232     for grep {!/^-/} keys %$hash;
 233   return $clean_hash;
 234 }
 235
 236 sub _join_condition {
 237   my ($self, $cond) = @_;
 238   if (ref $cond eq 'HASH') {
 239     my %j;
 240     for (keys %$cond) {
 241       my $v = $cond->{$_};
 242       if (ref $v) {
 243         # XXX no throw_exception() in this package and croak() fails with strange results
 244         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 245             if ref($v) ne 'SCALAR';
 246         $j{$_} = $v;
 247       }
 248       else {
 249         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 250       }
 251     };
 252     return scalar($self->_recurse_where(\%j));
 253   } elsif (ref $cond eq 'ARRAY') {
 254     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 255   } else {
 256     die "Can't handle this yet!";
 257   }
 258 }
 259
 260 sub _quote {
 261   my ($self, $label) = @_;
 262   return '' unless defined $label;
 263   return "*" if $label eq '*';
 264   return $label unless $self->{quote_char};
 265   if(ref $self->{quote_char} eq "ARRAY"){
 266     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 267       if !defined $self->{name_sep};
 268     my $sep = $self->{name_sep};
 269     return join($self->{name_sep},
 270         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 271        split(/\Q$sep\E/,$label));
 272   }
 273   return $self->SUPER::_quote($label);
 274 }
 275
 276 sub limit_dialect {
 277     my $self = shift;
 278     $self->{limit_dialect} = shift if @_;
 279     return $self->{limit_dialect};
 280 }
 281
 282 sub quote_char {
 283     my $self = shift;
 284     $self->{quote_char} = shift if @_;
 285     return $self->{quote_char};
 286 }
 287
 288 sub name_sep {
 289     my $self = shift;
 290     $self->{name_sep} = shift if @_;
 291     return $self->{name_sep};
 292 }
 293
 294 } # End of BEGIN block
 295
 296 =head1 NAME
 297
 298 DBIx::Class::Storage::DBI - DBI storage handler
 299
 300 =head1 SYNOPSIS
 301
 302 =head1 DESCRIPTION
 303
 304 This class represents the connection to an RDBMS via L<DBI>.  See
 305 L<DBIx::Class::Storage> for general information.  This pod only
 306 documents DBI-specific methods and behaviors.
 307
 308 =head1 METHODS
 309
 310 =cut
 311
 312 sub new {
 313   my $new = shift->next::method(@_);
 314
 315   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 316   $new->transaction_depth(0);
 317   $new->_sql_maker_opts({});
 318   $new->{_in_dbh_do} = 0;
 319   $new->{_dbh_gen} = 0;
 320
 321   $new;
 322 }
 323
 324 =head2 connect_info
 325
 326 The arguments of C<connect_info> are always a single array reference.
 327
 328 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 329 encapsulates its argument list in an arrayref before calling
 330 C<connect_info> here.
 331
 332 The arrayref can either contain the same set of arguments one would
 333 normally pass to L<DBI/connect>, or a lone code reference which returns
 334 a connected database handle.  Please note that the L<DBI> docs
 335 recommend that you always explicitly set C<AutoCommit> to either
 336 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 337 to C<1>, and that you perform transactions via our L</txn_do>
 338 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 339 set it to zero.  This is the default for most DBDs.  See below for more
 340 details.
 341
 342 In either case, if the final argument in your connect_info happens
 343 to be a hashref, C<connect_info> will look there for several
 344 connection-specific options:
 345
 346 =over 4
 347
 348 =item on_connect_do
 349
 350 This can be set to an arrayref of literal sql statements, which will
 351 be executed immediately after making the connection to the database
 352 every time we [re-]connect.
 353
 354 =item disable_sth_caching
 355
 356 If set to a true value, this option will disable the caching of
 357 statement handles via L<DBI/prepare_cached>.
 358
 359 =item limit_dialect
 360
 361 Sets the limit dialect. This is useful for JDBC-bridge among others
 362 where the remote SQL-dialect cannot be determined by the name of the
 363 driver alone.
 364
 365 =item quote_char
 366
 367 Specifies what characters to use to quote table and column names. If
 368 you use this you will want to specify L<name_sep> as well.
 369
 370 quote_char expects either a single character, in which case is it is placed
 371 on either side of the table/column, or an arrayref of length 2 in which case the
 372 table/column name is placed between the elements.
 373
 374 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 375 use C<quote_char =E<gt> [qw/[ ]/]>.
 376
 377 =item name_sep
 378
 379 This only needs to be used in conjunction with L<quote_char>, and is used to
 380 specify the charecter that seperates elements (schemas, tables, columns) from
 381 each other. In most cases this is simply a C<.>.
 382
 383 =back
 384
 385 These options can be mixed in with your other L<DBI> connection attributes,
 386 or placed in a seperate hashref after all other normal L<DBI> connection
 387 arguments.
 388
 389 Every time C<connect_info> is invoked, any previous settings for
 390 these options will be cleared before setting the new ones, regardless of
 391 whether any options are specified in the new C<connect_info>.
 392
 393 Important note:  DBIC expects the returned database handle provided by
 394 a subref argument to have RaiseError set on it.  If it doesn't, things
 395 might not work very well, YMMV.  If you don't use a subref, DBIC will
 396 force this setting for you anyways.  Setting HandleError to anything
 397 other than simple exception object wrapper might cause problems too.
 398
 399 Another Important Note:
 400
 401 DBIC can do some wonderful magic with handling exceptions,
 402 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 403 combined with C<txn_do> for transaction support.
 404
 405 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 406 in an assumed transaction between commits, and you're telling us you'd
 407 like to manage that manually.  A lot of DBIC's magic protections
 408 go away.  We can't protect you from exceptions due to database
 409 disconnects because we don't know anything about how to restart your
 410 transactions.  You're on your own for handling all sorts of exceptional
 411 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 412 be with raw DBI.
 413
 414 Examples:
 415
 416   # Simple SQLite connection
 417   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 418
 419   # Connect via subref
 420   ->connect_info([ sub { DBI->connect(...) } ]);
 421
 422   # A bit more complicated
 423   ->connect_info(
 424     [
 425       'dbi:Pg:dbname=foo',
 426       'postgres',
 427       'my_pg_password',
 428       { AutoCommit => 1 },
 429       { quote_char => q{"}, name_sep => q{.} },
 430     ]
 431   );
 432
 433   # Equivalent to the previous example
 434   ->connect_info(
 435     [
 436       'dbi:Pg:dbname=foo',
 437       'postgres',
 438       'my_pg_password',
 439       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 440     ]
 441   );
 442
 443   # Subref + DBIC-specific connection options
 444   ->connect_info(
 445     [
 446       sub { DBI->connect(...) },
 447       {
 448           quote_char => q{`},
 449           name_sep => q{@},
 450           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 451           disable_sth_caching => 1,
 452       },
 453     ]
 454   );
 455
 456 =cut
 457
 458 sub connect_info {
 459   my ($self, $info_arg) = @_;
 460
 461   return $self->_connect_info if !$info_arg;
 462
 463   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 464   #  the new set of options
 465   $self->_sql_maker(undef);
 466   $self->_sql_maker_opts({});
 467   $self->_connect_info([@$info_arg]); # copy for _connect_info
 468
 469   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 470
 471   my $last_info = $dbi_info->[-1];
 472   if(ref $last_info eq 'HASH') {
 473     for my $storage_opt (qw/on_connect_do disable_sth_caching/) {
 474       if(my $value = delete $last_info->{$storage_opt}) {
 475         $self->$storage_opt($value);
 476       }
 477     }
 478     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 479       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 480         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 481       }
 482     }
 483
 484     # Get rid of any trailing empty hashref
 485     pop(@$dbi_info) if !keys %$last_info;
 486   }
 487   $self->_dbi_connect_info($dbi_info);
 488
 489   $self->_connect_info;
 490 }
 491
 492 =head2 on_connect_do
 493
 494 This method is deprecated in favor of setting via L</connect_info>.
 495
 496 =head2 dbh_do
 497
 498 Arguments: $subref, @extra_coderef_args?
 499
 500 Execute the given subref using the new exception-based connection management.
 501
 502 The first two arguments will be the storage object that C<dbh_do> was called
 503 on and a database handle to use.  Any additional arguments will be passed
 504 verbatim to the called subref as arguments 2 and onwards.
 505
 506 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 507 exception handling and reconnection (or failover in future subclasses).
 508
 509 Your subref should have no side-effects outside of the database, as
 510 there is the potential for your subref to be partially double-executed
 511 if the database connection was stale/dysfunctional.
 512
 513 Example:
 514
 515   my @stuff = $schema->storage->dbh_do(
 516     sub {
 517       my ($storage, $dbh, @cols) = @_;
 518       my $cols = join(q{, }, @cols);
 519       $dbh->selectrow_array("SELECT $cols FROM foo");
 520     },
 521     @column_list
 522   );
 523
 524 =cut
 525
 526 sub dbh_do {
 527   my $self = shift;
 528   my $coderef = shift;
 529
 530   ref $coderef eq 'CODE' or $self->throw_exception
 531     ('$coderef must be a CODE reference');
 532
 533   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 534       || $self->{transaction_depth};
 535
 536   local $self->{_in_dbh_do} = 1;
 537
 538   my @result;
 539   my $want_array = wantarray;
 540
 541   eval {
 542     $self->_verify_pid if $self->_dbh;
 543     $self->_populate_dbh if !$self->_dbh;
 544     if($want_array) {
 545         @result = $coderef->($self, $self->_dbh, @_);
 546     }
 547     elsif(defined $want_array) {
 548         $result[0] = $coderef->($self, $self->_dbh, @_);
 549     }
 550     else {
 551         $coderef->($self, $self->_dbh, @_);
 552     }
 553   };
 554
 555   my $exception = $@;
 556   if(!$exception) { return $want_array ? @result : $result[0] }
 557
 558   $self->throw_exception($exception) if $self->connected;
 559
 560   # We were not connected - reconnect and retry, but let any
 561   #  exception fall right through this time
 562   $self->_populate_dbh;
 563   $coderef->($self, $self->_dbh, @_);
 564 }
 565
 566 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 567 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 568 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 569 sub txn_do {
 570   my $self = shift;
 571   my $coderef = shift;
 572
 573   ref $coderef eq 'CODE' or $self->throw_exception
 574     ('$coderef must be a CODE reference');
 575
 576   local $self->{_in_dbh_do} = 1;
 577
 578   my @result;
 579   my $want_array = wantarray;
 580
 581   my $tried = 0;
 582   while(1) {
 583     eval {
 584       $self->_verify_pid if $self->_dbh;
 585       $self->_populate_dbh if !$self->_dbh;
 586
 587       $self->txn_begin;
 588       if($want_array) {
 589           @result = $coderef->(@_);
 590       }
 591       elsif(defined $want_array) {
 592           $result[0] = $coderef->(@_);
 593       }
 594       else {
 595           $coderef->(@_);
 596       }
 597       $self->txn_commit;
 598     };
 599
 600     my $exception = $@;
 601     if(!$exception) { return $want_array ? @result : $result[0] }
 602
 603     if($tried++ > 0 || $self->connected) {
 604       eval { $self->txn_rollback };
 605       my $rollback_exception = $@;
 606       if($rollback_exception) {
 607         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 608         $self->throw_exception($exception)  # propagate nested rollback
 609           if $rollback_exception =~ /$exception_class/;
 610
 611         $self->throw_exception(
 612           "Transaction aborted: ${exception}. "
 613           . "Rollback failed: ${rollback_exception}"
 614         );
 615       }
 616       $self->throw_exception($exception)
 617     }
 618
 619     # We were not connected, and was first try - reconnect and retry
 620     # via the while loop
 621     $self->_populate_dbh;
 622   }
 623 }
 624
 625 =head2 disconnect
 626
 627 Our C<disconnect> method also performs a rollback first if the
 628 database is not in C<AutoCommit> mode.
 629
 630 =cut
 631
 632 sub disconnect {
 633   my ($self) = @_;
 634
 635   if( $self->connected ) {
 636     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 637     $self->_dbh->disconnect;
 638     $self->_dbh(undef);
 639     $self->{_dbh_gen}++;
 640   }
 641 }
 642
 643 sub connected {
 644   my ($self) = @_;
 645
 646   if(my $dbh = $self->_dbh) {
 647       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 648           $self->_dbh(undef);
 649           $self->{_dbh_gen}++;
 650           return;
 651       }
 652       else {
 653           $self->_verify_pid;
 654       }
 655       return ($dbh->FETCH('Active') && $dbh->ping);
 656   }
 657
 658   return 0;
 659 }
 660
 661 # handle pid changes correctly
 662 #  NOTE: assumes $self->_dbh is a valid $dbh
 663 sub _verify_pid {
 664   my ($self) = @_;
 665
 666   return if $self->_conn_pid == $$;
 667
 668   $self->_dbh->{InactiveDestroy} = 1;
 669   $self->_dbh(undef);
 670   $self->{_dbh_gen}++;
 671
 672   return;
 673 }
 674
 675 sub ensure_connected {
 676   my ($self) = @_;
 677
 678   unless ($self->connected) {
 679     $self->_populate_dbh;
 680   }
 681 }
 682
 683 =head2 dbh
 684
 685 Returns the dbh - a data base handle of class L<DBI>.
 686
 687 =cut
 688
 689 sub dbh {
 690   my ($self) = @_;
 691
 692   $self->ensure_connected;
 693   return $self->_dbh;
 694 }
 695
 696 sub _sql_maker_args {
 697     my ($self) = @_;
 698
 699     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 700 }
 701
 702 sub sql_maker {
 703   my ($self) = @_;
 704   unless ($self->_sql_maker) {
 705     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 706   }
 707   return $self->_sql_maker;
 708 }
 709
 710 sub _populate_dbh {
 711   my ($self) = @_;
 712   my @info = @{$self->_dbi_connect_info || []};
 713   $self->_dbh($self->_connect(@info));
 714
 715   # Always set the transaction depth on connect, since
 716   #  there is no transaction in progress by definition
 717   $self->{transaction_depth} = $self->_dbh->{AutoCommit} ? 0 : 1;
 718
 719   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 720     my $driver = $self->_dbh->{Driver}->{Name};
 721     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 722       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 723       $self->_rebless() if $self->can('_rebless');
 724     }
 725   }
 726
 727   # if on-connect sql statements are given execute them
 728   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 729     $self->debugobj->query_start($sql_statement) if $self->debug();
 730     $self->_dbh->do($sql_statement);
 731     $self->debugobj->query_end($sql_statement) if $self->debug();
 732   }
 733
 734   $self->_conn_pid($$);
 735   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 736 }
 737
 738 sub _connect {
 739   my ($self, @info) = @_;
 740
 741   $self->throw_exception("You failed to provide any connection info")
 742       if !@info;
 743
 744   my ($old_connect_via, $dbh);
 745
 746   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 747       $old_connect_via = $DBI::connect_via;
 748       $DBI::connect_via = 'connect';
 749   }
 750
 751   eval {
 752     if(ref $info[0] eq 'CODE') {
 753        $dbh = &{$info[0]}
 754     }
 755     else {
 756        $dbh = DBI->connect(@info);
 757        $dbh->{RaiseError} = 1;
 758        $dbh->{PrintError} = 0;
 759        $dbh->{PrintWarn} = 0;
 760     }
 761   };
 762
 763   $DBI::connect_via = $old_connect_via if $old_connect_via;
 764
 765   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 766     if !$dbh || $@;
 767
 768   $dbh;
 769 }
 770
 771
 772 sub txn_begin {
 773   my $self = shift;
 774   if($self->{transaction_depth}++ == 0) {
 775     $self->debugobj->txn_begin()
 776       if $self->debug;
 777     # this isn't ->_dbh-> because
 778     #  we should reconnect on begin_work
 779     #  for AutoCommit users
 780     $self->dbh->begin_work;
 781   }
 782 }
 783
 784 sub txn_commit {
 785   my $self = shift;
 786   if ($self->{transaction_depth} == 1) {
 787     my $dbh = $self->_dbh;
 788     $self->debugobj->txn_commit()
 789       if ($self->debug);
 790     $dbh->commit;
 791     $self->{transaction_depth} = 0
 792       if $dbh->{AutoCommit};
 793   }
 794   elsif($self->{transaction_depth} > 1) {
 795     $self->{transaction_depth}--
 796   }
 797 }
 798
 799 sub txn_rollback {
 800   my $self = shift;
 801   my $dbh = $self->_dbh;
 802   my $autocommit;
 803   eval {
 804     $autocommit = $dbh->{AutoCommit};
 805     if ($self->{transaction_depth} == 1) {
 806       $self->debugobj->txn_rollback()
 807         if ($self->debug);
 808       $dbh->rollback;
 809       $self->{transaction_depth} = 0
 810         if $autocommit;
 811     }
 812     elsif($self->{transaction_depth} > 1) {
 813       $self->{transaction_depth}--;
 814     }
 815     else {
 816       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 817     }
 818   };
 819   if ($@) {
 820     my $error = $@;
 821     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 822     $error =~ /$exception_class/ and $self->throw_exception($error);
 823     # ensure that a failed rollback resets the transaction depth
 824     $self->{transaction_depth} = $autocommit ? 0 : 1;
 825     $self->throw_exception($error);
 826   }
 827 }
 828
 829 # This used to be the top-half of _execute.  It was split out to make it
 830 #  easier to override in NoBindVars without duping the rest.  It takes up
 831 #  all of _execute's args, and emits $sql, @bind.
 832 sub _prep_for_execute {
 833   my ($self, $op, $extra_bind, $ident, @args) = @_;
 834
 835   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 836   unshift(@bind,
 837     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 838       if $extra_bind;
 839   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 840
 841   return ($sql, @bind);
 842 }
 843
 844 sub _execute {
 845   my ($self, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 846
 847   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 848     $ident = $ident->from();
 849   }
 850
 851   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 852   unshift(@bind,
 853     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 854       if $extra_bind;
 855
 856   if ($self->debug) {
 857       my @debug_bind =
 858         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 859       $self->debugobj->query_start($sql, @debug_bind);
 860   }
 861
 862   my $sth = eval { $self->sth($sql,$op) };
 863   $self->throw_exception("no sth generated via sql ($@): $sql") if $@;
 864
 865   my $rv = eval {
 866     my $placeholder_index = 1;
 867
 868     foreach my $bound (@bind) {
 869       my $attributes = {};
 870       my($column_name, @data) = @$bound;
 871
 872       if ($bind_attributes) {
 873         $attributes = $bind_attributes->{$column_name}
 874         if defined $bind_attributes->{$column_name};
 875       }
 876
 877       foreach my $data (@data) {
 878         $data = ref $data ? ''.$data : $data; # stringify args
 879
 880         $sth->bind_param($placeholder_index, $data, $attributes);
 881         $placeholder_index++;
 882       }
 883     }
 884     $sth->execute();
 885   };
 886
 887   $self->throw_exception("Error executing '$sql': " . ($@ || $sth->errstr))
 888     if $@ || !$rv;
 889
 890   if ($self->debug) {
 891      my @debug_bind =
 892        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 893      $self->debugobj->query_end($sql, @debug_bind);
 894   }
 895   return (wantarray ? ($rv, $sth, @bind) : $rv);
 896 }
 897
 898 sub insert {
 899   my ($self, $source, $to_insert) = @_;
 900
 901   my $ident = $source->from;
 902   my $bind_attributes = $self->source_bind_attributes($source);
 903
 904   eval { $self->_execute('insert' => [], $source, $bind_attributes, $to_insert) };
 905   $self->throw_exception(
 906     "Couldn't insert ".join(', ',
 907       map "$_ => $to_insert->{$_}", keys %$to_insert
 908     )." into ${ident}: $@"
 909   ) if $@;
 910
 911   return $to_insert;
 912 }
 913
 914 ## Still not quite perfect, and EXPERIMENTAL
 915 ## Currently it is assumed that all values passed will be "normal", i.e. not
 916 ## scalar refs, or at least, all the same type as the first set, the statement is
 917 ## only prepped once.
 918 sub insert_bulk {
 919   my ($self, $source, $cols, $data) = @_;
 920   my %colvalues;
 921   my $table = $source->from;
 922   @colvalues{@$cols} = (0..$#$cols);
 923   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 924
 925   if ($self->debug) {
 926       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 927       $self->debugobj->query_start($sql, @debug_bind);
 928   }
 929   my $sth = $self->sth($sql);
 930
 931 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 932
 933   my $rv;
 934
 935   ## This must be an arrayref, else nothing works!
 936
 937   my $tuple_status = [];
 938
 939   ##use Data::Dumper;
 940   ##print STDERR Dumper( $data, $sql, [@bind] );
 941
 942   if ($sth) {
 943
 944     my $time = time();
 945
 946     ## Get the bind_attributes, if any exist
 947     my $bind_attributes = $self->source_bind_attributes($source);
 948
 949     ## Bind the values and execute
 950     $rv = eval {
 951
 952      my $placeholder_index = 1;
 953
 954         foreach my $bound (@bind) {
 955
 956           my $attributes = {};
 957           my ($column_name, $data_index) = @$bound;
 958
 959           if( $bind_attributes ) {
 960             $attributes = $bind_attributes->{$column_name}
 961             if defined $bind_attributes->{$column_name};
 962           }
 963
 964           my @data = map { $_->[$data_index] } @$data;
 965
 966           $sth->bind_param_array( $placeholder_index, [@data], $attributes );
 967           $placeholder_index++;
 968       }
 969       $sth->execute_array( {ArrayTupleStatus => $tuple_status} );
 970
 971     };
 972
 973     if ($@ || !defined $rv) {
 974       my $errors = '';
 975       foreach my $tuple (@$tuple_status) {
 976           $errors .= "\n" . $tuple->[1] if(ref $tuple);
 977       }
 978       $self->throw_exception("Error executing '$sql': ".($@ || $errors));
 979     }
 980   } else {
 981     $self->throw_exception("'$sql' did not generate a statement.");
 982   }
 983   if ($self->debug) {
 984       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 985       $self->debugobj->query_end($sql, @debug_bind);
 986   }
 987   return (wantarray ? ($rv, $sth, @bind) : $rv);
 988 }
 989
 990 sub update {
 991   my $self = shift @_;
 992   my $source = shift @_;
 993   my $bind_attributes = $self->source_bind_attributes($source);
 994
 995   return $self->_execute('update' => [], $source, $bind_attributes, @_);
 996 }
 997
 998
 999 sub delete {
1000   my $self = shift @_;
1001   my $source = shift @_;
1002
1003   my $bind_attrs = {}; ## If ever it's needed...
1004
1005   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1006 }
1007
1008 sub _select {
1009   my ($self, $ident, $select, $condition, $attrs) = @_;
1010   my $order = $attrs->{order_by};
1011   if (ref $condition eq 'SCALAR') {
1012     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1013   }
1014   if (exists $attrs->{group_by} || $attrs->{having}) {
1015     $order = {
1016       group_by => $attrs->{group_by},
1017       having => $attrs->{having},
1018       ($order ? (order_by => $order) : ())
1019     };
1020   }
1021   my $bind_attrs = {}; ## Future support
1022   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1023   if ($attrs->{software_limit} ||
1024       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1025         $attrs->{software_limit} = 1;
1026   } else {
1027     $self->throw_exception("rows attribute must be positive if present")
1028       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1029     push @args, $attrs->{rows}, $attrs->{offset};
1030   }
1031   return $self->_execute(@args);
1032 }
1033
1034 sub source_bind_attributes {
1035   my ($self, $source) = @_;
1036
1037   my $bind_attributes;
1038   foreach my $column ($source->columns) {
1039
1040     my $data_type = $source->column_info($column)->{data_type} || '';
1041     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1042      if $data_type;
1043   }
1044
1045   return $bind_attributes;
1046 }
1047
1048 =head2 select
1049
1050 =over 4
1051
1052 =item Arguments: $ident, $select, $condition, $attrs
1053
1054 =back
1055
1056 Handle a SQL select statement.
1057
1058 =cut
1059
1060 sub select {
1061   my $self = shift;
1062   my ($ident, $select, $condition, $attrs) = @_;
1063   return $self->cursor->new($self, \@_, $attrs);
1064 }
1065
1066 sub select_single {
1067   my $self = shift;
1068   my ($rv, $sth, @bind) = $self->_select(@_);
1069   my @row = $sth->fetchrow_array;
1070   # Need to call finish() to work round broken DBDs
1071   $sth->finish();
1072   return @row;
1073 }
1074
1075 =head2 sth
1076
1077 =over 4
1078
1079 =item Arguments: $sql
1080
1081 =back
1082
1083 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1084
1085 =cut
1086
1087 sub _dbh_sth {
1088   my ($self, $dbh, $sql) = @_;
1089
1090   # 3 is the if_active parameter which avoids active sth re-use
1091   my $sth = $self->disable_sth_caching
1092     ? $dbh->prepare($sql)
1093     : $dbh->prepare_cached($sql, {}, 3);
1094
1095   # XXX You would think RaiseError would make this impossible,
1096   #  but apparently that's not true :(
1097   die $dbh->errstr if !$sth;
1098
1099   $sth;
1100 }
1101
1102 sub sth {
1103   my ($self, $sql) = @_;
1104   $self->dbh_do($self->can('_dbh_sth'), $sql);
1105 }
1106
1107 sub _dbh_columns_info_for {
1108   my ($self, $dbh, $table) = @_;
1109
1110   if ($dbh->can('column_info')) {
1111     my %result;
1112     eval {
1113       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1114       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1115       $sth->execute();
1116       while ( my $info = $sth->fetchrow_hashref() ){
1117         my %column_info;
1118         $column_info{data_type}   = $info->{TYPE_NAME};
1119         $column_info{size}      = $info->{COLUMN_SIZE};
1120         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1121         $column_info{default_value} = $info->{COLUMN_DEF};
1122         my $col_name = $info->{COLUMN_NAME};
1123         $col_name =~ s/^\"(.*)\"$/$1/;
1124
1125         $result{$col_name} = \%column_info;
1126       }
1127     };
1128     return \%result if !$@ && scalar keys %result;
1129   }
1130
1131   my %result;
1132   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1133   $sth->execute;
1134   my @columns = @{$sth->{NAME_lc}};
1135   for my $i ( 0 .. $#columns ){
1136     my %column_info;
1137     $column_info{data_type} = $sth->{TYPE}->[$i];
1138     $column_info{size} = $sth->{PRECISION}->[$i];
1139     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1140
1141     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1142       $column_info{data_type} = $1;
1143       $column_info{size}    = $2;
1144     }
1145
1146     $result{$columns[$i]} = \%column_info;
1147   }
1148   $sth->finish;
1149
1150   foreach my $col (keys %result) {
1151     my $colinfo = $result{$col};
1152     my $type_num = $colinfo->{data_type};
1153     my $type_name;
1154     if(defined $type_num && $dbh->can('type_info')) {
1155       my $type_info = $dbh->type_info($type_num);
1156       $type_name = $type_info->{TYPE_NAME} if $type_info;
1157       $colinfo->{data_type} = $type_name if $type_name;
1158     }
1159   }
1160
1161   return \%result;
1162 }
1163
1164 sub columns_info_for {
1165   my ($self, $table) = @_;
1166   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1167 }
1168
1169 =head2 last_insert_id
1170
1171 Return the row id of the last insert.
1172
1173 =cut
1174
1175 sub _dbh_last_insert_id {
1176     my ($self, $dbh, $source, $col) = @_;
1177     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1178     $dbh->func('last_insert_rowid');
1179 }
1180
1181 sub last_insert_id {
1182   my $self = shift;
1183   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1184 }
1185
1186 =head2 sqlt_type
1187
1188 Returns the database driver name.
1189
1190 =cut
1191
1192 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1193
1194 =head2 bind_attribute_by_data_type
1195
1196 Given a datatype from column info, returns a database specific bind attribute for
1197 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1198 just handle it.
1199
1200 Generally only needed for special case column types, like bytea in postgres.
1201
1202 =cut
1203
1204 sub bind_attribute_by_data_type {
1205     return;
1206 }
1207
1208 =head2 create_ddl_dir (EXPERIMENTAL)
1209
1210 =over 4
1211
1212 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1213
1214 =back
1215
1216 Creates a SQL file based on the Schema, for each of the specified
1217 database types, in the given directory.
1218
1219 Note that this feature is currently EXPERIMENTAL and may not work correctly
1220 across all databases, or fully handle complex relationships.
1221
1222 =cut
1223
1224 sub create_ddl_dir
1225 {
1226   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1227
1228   if(!$dir || !-d $dir)
1229   {
1230     warn "No directory given, using ./\n";
1231     $dir = "./";
1232   }
1233   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1234   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1235   $version ||= $schema->VERSION || '1.x';
1236   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1237
1238   eval "use SQL::Translator";
1239   $self->throw_exception("Can't create a ddl file without SQL::Translator: $@") if $@;
1240
1241   my $sqlt = SQL::Translator->new({
1242 #      debug => 1,
1243       add_drop_table => 1,
1244   });
1245   foreach my $db (@$databases)
1246   {
1247     $sqlt->reset();
1248     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1249 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1250     $sqlt = $self->configure_sqlt($sqlt, $db);
1251     $sqlt->data($schema);
1252     $sqlt->producer($db);
1253
1254     my $file;
1255     my $filename = $schema->ddl_filename($db, $dir, $version);
1256     if(-e $filename)
1257     {
1258       warn("$filename already exists, skipping $db");
1259       next;
1260     }
1261
1262     my $output = $sqlt->translate;
1263     if(!$output)
1264     {
1265       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1266       next;
1267     }
1268     if(!open($file, ">$filename"))
1269     {
1270         $self->throw_exception("Can't open $filename for writing ($!)");
1271         next;
1272     }
1273     print $file $output;
1274     close($file);
1275
1276     if($preversion)
1277     {
1278       eval "use SQL::Translator::Diff";
1279       if($@)
1280       {
1281         warn("Can't diff versions without SQL::Translator::Diff: $@");
1282         next;
1283       }
1284
1285       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1286 #      print "Previous version $prefilename\n";
1287       if(!-e $prefilename)
1288       {
1289         warn("No previous schema file found ($prefilename)");
1290         next;
1291       }
1292       #### We need to reparse the SQLite file we just wrote, so that
1293       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1294       ##   FIXME: rip Diff to pieces!
1295 #      my $target_schema = $sqlt->schema;
1296 #      unless ( $target_schema->name ) {
1297 #        $target_schema->name( $filename );
1298 #      }
1299       my @input;
1300       push @input, {file => $prefilename, parser => $db};
1301       push @input, {file => $filename, parser => $db};
1302       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1303         my $file   = $_->{'file'};
1304         my $parser = $_->{'parser'};
1305
1306         my $t = SQL::Translator->new;
1307         $t->debug( 0 );
1308         $t->trace( 0 );
1309         $t->parser( $parser )            or die $t->error;
1310         my $out = $t->translate( $file ) or die $t->error;
1311         my $schema = $t->schema;
1312         unless ( $schema->name ) {
1313           $schema->name( $file );
1314         }
1315         ($schema, $parser);
1316       } @input;
1317
1318       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1319                                                     $target_schema, $db,
1320                                                     {}
1321                                                    );
1322       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1323       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1324       if(-e $difffile)
1325       {
1326         warn("$difffile already exists, skipping");
1327         next;
1328       }
1329       if(!open $file, ">$difffile")
1330       {
1331         $self->throw_exception("Can't write to $difffile ($!)");
1332         next;
1333       }
1334       print $file $diff;
1335       close($file);
1336     }
1337   }
1338 }
1339
1340 sub configure_sqlt() {
1341   my $self = shift;
1342   my $tr = shift;
1343   my $db = shift || $self->sqlt_type;
1344   if ($db eq 'PostgreSQL') {
1345     $tr->quote_table_names(0);
1346     $tr->quote_field_names(0);
1347   }
1348   return $tr;
1349 }
1350
1351 =head2 deployment_statements
1352
1353 =over 4
1354
1355 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1356
1357 =back
1358
1359 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1360 The database driver name is given by C<$type>, though the value from
1361 L</sqlt_type> is used if it is not specified.
1362
1363 C<$directory> is used to return statements from files in a previously created
1364 L</create_ddl_dir> directory and is optional. The filenames are constructed
1365 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1366
1367 If no C<$directory> is specified then the statements are constructed on the
1368 fly using L<SQL::Translator> and C<$version> is ignored.
1369
1370 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1371
1372 =cut
1373
1374 sub deployment_statements {
1375   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1376   # Need to be connected to get the correct sqlt_type
1377   $self->ensure_connected() unless $type;
1378   $type ||= $self->sqlt_type;
1379   $version ||= $schema->VERSION || '1.x';
1380   $dir ||= './';
1381   my $filename = $schema->ddl_filename($type, $dir, $version);
1382   if(-f $filename)
1383   {
1384       my $file;
1385       open($file, "<$filename")
1386         or $self->throw_exception("Can't open $filename ($!)");
1387       my @rows = <$file>;
1388       close($file);
1389       return join('', @rows);
1390   }
1391
1392   eval "use SQL::Translator";
1393   if(!$@)
1394   {
1395     eval "use SQL::Translator::Parser::DBIx::Class;";
1396     $self->throw_exception($@) if $@;
1397     eval "use SQL::Translator::Producer::${type};";
1398     $self->throw_exception($@) if $@;
1399
1400     # sources needs to be a parser arg, but for simplicty allow at top level
1401     # coming in
1402     $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1403         if exists $sqltargs->{sources};
1404
1405     my $tr = SQL::Translator->new(%$sqltargs);
1406     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1407     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1408   }
1409
1410   $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
1411   return;
1412
1413 }
1414
1415 sub deploy {
1416   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1417   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1418     for ( split(";\n", $statement)) {
1419       next if($_ =~ /^--/);
1420       next if(!$_);
1421 #      next if($_ =~ /^DROP/m);
1422       next if($_ =~ /^BEGIN TRANSACTION/m);
1423       next if($_ =~ /^COMMIT/m);
1424       next if $_ =~ /^\s+$/; # skip whitespace only
1425       $self->debugobj->query_start($_) if $self->debug;
1426       $self->dbh->do($_); # shouldn't be using ->dbh ?
1427       $self->debugobj->query_end($_) if $self->debug;
1428     }
1429   }
1430 }
1431
1432 =head2 datetime_parser
1433
1434 Returns the datetime parser class
1435
1436 =cut
1437
1438 sub datetime_parser {
1439   my $self = shift;
1440   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
1441 }
1442
1443 =head2 datetime_parser_type
1444
1445 Defines (returns) the datetime parser class - currently hardwired to
1446 L<DateTime::Format::MySQL>
1447
1448 =cut
1449
1450 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1451
1452 =head2 build_datetime_parser
1453
1454 See L</datetime_parser>
1455
1456 =cut
1457
1458 sub build_datetime_parser {
1459   my $self = shift;
1460   my $type = $self->datetime_parser_type(@_);
1461   eval "use ${type}";
1462   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1463   return $type;
1464 }
1465
1466 sub DESTROY {
1467   my $self = shift;
1468   return if !$self->_dbh;
1469   $self->_verify_pid;
1470   $self->_dbh(undef);
1471 }
1472
1473 1;
1474
1475 =head1 SQL METHODS
1476
1477 The module defines a set of methods within the DBIC::SQL::Abstract
1478 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1479 SQL query functions.
1480
1481 The following methods are extended:-
1482
1483 =over 4
1484
1485 =item delete
1486
1487 =item insert
1488
1489 =item select
1490
1491 =item update
1492
1493 =item limit_dialect
1494
1495 See L</connect_info> for details.
1496 For setting, this method is deprecated in favor of L</connect_info>.
1497
1498 =item quote_char
1499
1500 See L</connect_info> for details.
1501 For setting, this method is deprecated in favor of L</connect_info>.
1502
1503 =item name_sep
1504
1505 See L</connect_info> for details.
1506 For setting, this method is deprecated in favor of L</connect_info>.
1507
1508 =back
1509
1510 =head1 AUTHORS
1511
1512 Matt S. Trout <mst@shadowcatsystems.co.uk>
1513
1514 Andy Grundman <andy@hybridized.org>
1515
1516 =head1 LICENSE
1517
1518 You may distribute this code under the same terms as Perl itself.
1519
1520 =cut