lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid transaction_depth _dbh_autocommit savepoints/
  18 );
  19
  20 # the values for these accessors are picked out (and deleted) from
  21 # the attribute hashref passed to connect_info
  22 my @storage_options = qw/
  23   on_connect_do on_disconnect_do disable_sth_caching unsafe auto_savepoint
  24 /;
  25 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  26
  27
  28 # default cursor class, overridable in connect_info attributes
  29 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  30
  31 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  32 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  33
  34 BEGIN {
  35
  36 package # Hide from PAUSE
  37   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  38
  39 use base qw/SQL::Abstract::Limit/;
  40 use Carp::Clan qw/^DBIx::Class/;
  41
  42 sub new {
  43   my $self = shift->SUPER::new(@_);
  44
  45   # This prevents the caching of $dbh in S::A::L, I believe
  46   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  47   #   it with what it resolves to:
  48   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  49     if ref $self->{limit_dialect};
  50
  51   $self;
  52 }
  53
  54
  55
  56 # Some databases (sqlite) do not handle multiple parenthesis
  57 # around in/between arguments. A tentative x IN ( ( 1, 2 ,3) )
  58 # is interpreted as x IN 1 or something similar.
  59 #
  60 # Since we currently do not have access to the SQLA AST, resort
  61 # to barbaric mutilation of any SQL supplied in literal form
  62
  63 sub _strip_outer_paren {
  64   my ($self, $arg) = @_;
  65
  66   return $self->_SWITCH_refkind ($arg, {
  67     ARRAYREFREF => sub {
  68       $$arg->[0] = __strip_outer_paren ($$arg->[0]);
  69       return $arg;
  70     },
  71     SCALARREF => sub {
  72       return \__strip_outer_paren( $$arg );
  73     },
  74     FALLBACK => sub {
  75       return $arg
  76     },
  77   });
  78 }
  79
  80 sub __strip_outer_paren {
  81   my $sql = shift;
  82
  83   if ($sql and not ref $sql) {
  84     while ($sql =~ /^ \s* \( (.*) \) \s* $/x ) {
  85       $sql = $1;
  86     }
  87   }
  88
  89   return $sql;
  90 }
  91
  92 sub _where_field_IN {
  93   my ($self, $lhs, $op, $rhs) = @_;
  94   $rhs = $self->_strip_outer_paren ($rhs);
  95   return $self->SUPER::_where_field_IN ($lhs, $op, $rhs);
  96 }
  97
  98 sub _where_field_BETWEEN {
  99   my ($self, $lhs, $op, $rhs) = @_;
 100   $rhs = $self->_strip_outer_paren ($rhs);
 101   return $self->SUPER::_where_field_BETWEEN ($lhs, $op, $rhs);
 102 }
 103
 104
 105
 106 # DB2 is the only remaining DB using this. Even though we are not sure if
 107 # RowNumberOver is still needed here (should be part of SQLA) leave the
 108 # code in place
 109 sub _RowNumberOver {
 110   my ($self, $sql, $order, $rows, $offset ) = @_;
 111
 112   $offset += 1;
 113   my $last = $rows + $offset;
 114   my ( $order_by ) = $self->_order_by( $order );
 115
 116   $sql = <<"SQL";
 117 SELECT * FROM
 118 (
 119    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
 120       $sql
 121       $order_by
 122    ) Q1
 123 ) Q2
 124 WHERE ROW_NUM BETWEEN $offset AND $last
 125
 126 SQL
 127
 128   return $sql;
 129 }
 130
 131
 132 # While we're at it, this should make LIMIT queries more efficient,
 133 #  without digging into things too deeply
 134 use Scalar::Util 'blessed';
 135 sub _find_syntax {
 136   my ($self, $syntax) = @_;
 137
 138   # DB2 is the only remaining DB using this. Even though we are not sure if
 139   # RowNumberOver is still needed here (should be part of SQLA) leave the
 140   # code in place
 141   my $dbhname = blessed($syntax) ? $syntax->{Driver}{Name} : $syntax;
 142   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
 143     return 'RowNumberOver';
 144   }
 145
 146   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
 147 }
 148
 149 sub select {
 150   my ($self, $table, $fields, $where, $order, @rest) = @_;
 151   local $self->{having_bind} = [];
 152   local $self->{from_bind} = [];
 153
 154   if (ref $table eq 'SCALAR') {
 155     $table = $$table;
 156   }
 157   elsif (not ref $table) {
 158     $table = $self->_quote($table);
 159   }
 160   local $self->{rownum_hack_count} = 1
 161     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
 162   @rest = (-1) unless defined $rest[0];
 163   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
 164     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
 165   my ($sql, @where_bind) = $self->SUPER::select(
 166     $table, $self->_recurse_fields($fields), $where, $order, @rest
 167   );
 168   $sql .=
 169     $self->{for} ?
 170     (
 171       $self->{for} eq 'update' ? ' FOR UPDATE' :
 172       $self->{for} eq 'shared' ? ' FOR SHARE'  :
 173       ''
 174     ) :
 175     ''
 176   ;
 177   return wantarray ? ($sql, @{$self->{from_bind}}, @where_bind, @{$self->{having_bind}}) : $sql;
 178 }
 179
 180 sub insert {
 181   my $self = shift;
 182   my $table = shift;
 183   $table = $self->_quote($table) unless ref($table);
 184   $self->SUPER::insert($table, @_);
 185 }
 186
 187 sub update {
 188   my $self = shift;
 189   my $table = shift;
 190   $table = $self->_quote($table) unless ref($table);
 191   $self->SUPER::update($table, @_);
 192 }
 193
 194 sub delete {
 195   my $self = shift;
 196   my $table = shift;
 197   $table = $self->_quote($table) unless ref($table);
 198   $self->SUPER::delete($table, @_);
 199 }
 200
 201 sub _emulate_limit {
 202   my $self = shift;
 203   if ($_[3] == -1) {
 204     return $_[1].$self->_order_by($_[2]);
 205   } else {
 206     return $self->SUPER::_emulate_limit(@_);
 207   }
 208 }
 209
 210 sub _recurse_fields {
 211   my ($self, $fields, $params) = @_;
 212   my $ref = ref $fields;
 213   return $self->_quote($fields) unless $ref;
 214   return $$fields if $ref eq 'SCALAR';
 215
 216   if ($ref eq 'ARRAY') {
 217     return join(', ', map {
 218       $self->_recurse_fields($_)
 219         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 220           ? ' AS col'.$self->{rownum_hack_count}++
 221           : '')
 222       } @$fields);
 223   } elsif ($ref eq 'HASH') {
 224     foreach my $func (keys %$fields) {
 225       if ($func eq 'distinct') {
 226         my $_fields = $fields->{$func};
 227         if (ref $_fields eq 'ARRAY' && @{$_fields} > 1) {
 228           die "Unsupported syntax, please use " .
 229               "{ group_by => [ qw/" . (join ' ', @$_fields) . "/ ] }" .
 230               " or " .
 231               "{ select => [ qw/" . (join ' ', @$_fields) . "/ ], distinct => 1 }";
 232         }
 233         else {
 234           carp "This syntax will be deprecated in 09, please use " .
 235                "{ group_by => '${_fields}' }" .
 236                " or " .
 237                "{ select => '${_fields}', distinct => 1 }";
 238         }
 239       }
 240
 241       return $self->_sqlcase($func)
 242         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 243     }
 244   }
 245   # Is the second check absolutely necessary?
 246   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 247     return $self->_fold_sqlbind( $fields );
 248   }
 249   else {
 250     Carp::croak($ref . qq{ unexpected in _recurse_fields()})
 251   }
 252 }
 253
 254 sub _order_by {
 255   my $self = shift;
 256   my $ret = '';
 257   my @extra;
 258   if (ref $_[0] eq 'HASH') {
 259     if (defined $_[0]->{group_by}) {
 260       $ret = $self->_sqlcase(' group by ')
 261         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 262     }
 263     if (defined $_[0]->{having}) {
 264       my $frag;
 265       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 266       push(@{$self->{having_bind}}, @extra);
 267       $ret .= $self->_sqlcase(' having ').$frag;
 268     }
 269     if (defined $_[0]->{order_by}) {
 270       $ret .= $self->_order_by($_[0]->{order_by});
 271     }
 272     if (grep { $_ =~ /^-(desc|asc)/i } keys %{$_[0]}) {
 273       return $self->SUPER::_order_by($_[0]);
 274     }
 275   } elsif (ref $_[0] eq 'SCALAR') {
 276     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 277   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 278     my @order = @{+shift};
 279     $ret = $self->_sqlcase(' order by ')
 280           .join(', ', map {
 281                         my $r = $self->_order_by($_, @_);
 282                         $r =~ s/^ ?ORDER BY //i;
 283                         $r;
 284                       } @order);
 285   } else {
 286     $ret = $self->SUPER::_order_by(@_);
 287   }
 288   return $ret;
 289 }
 290
 291 sub _order_directions {
 292   my ($self, $order) = @_;
 293   $order = $order->{order_by} if ref $order eq 'HASH';
 294   return $self->SUPER::_order_directions($order);
 295 }
 296
 297 sub _table {
 298   my ($self, $from) = @_;
 299   if (ref $from eq 'ARRAY') {
 300     return $self->_recurse_from(@$from);
 301   } elsif (ref $from eq 'HASH') {
 302     return $self->_make_as($from);
 303   } else {
 304     return $from; # would love to quote here but _table ends up getting called
 305                   # twice during an ->select without a limit clause due to
 306                   # the way S::A::Limit->select works. should maybe consider
 307                   # bypassing this and doing S::A::select($self, ...) in
 308                   # our select method above. meantime, quoting shims have
 309                   # been added to select/insert/update/delete here
 310   }
 311 }
 312
 313 sub _recurse_from {
 314   my ($self, $from, @join) = @_;
 315   my @sqlf;
 316   push(@sqlf, $self->_make_as($from));
 317   foreach my $j (@join) {
 318     my ($to, $on) = @$j;
 319
 320     # check whether a join type exists
 321     my $join_clause = '';
 322     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 323     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 324       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 325     } else {
 326       $join_clause = ' JOIN ';
 327     }
 328     push(@sqlf, $join_clause);
 329
 330     if (ref $to eq 'ARRAY') {
 331       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 332     } else {
 333       push(@sqlf, $self->_make_as($to));
 334     }
 335     push(@sqlf, ' ON ', $self->_join_condition($on));
 336   }
 337   return join('', @sqlf);
 338 }
 339
 340 sub _fold_sqlbind {
 341   my ($self, $sqlbind) = @_;
 342   my $sql = shift @$$sqlbind;
 343   push @{$self->{from_bind}}, @$$sqlbind;
 344   return $sql;
 345 }
 346
 347 sub _make_as {
 348   my ($self, $from) = @_;
 349   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_
 350                         : ref $_ eq 'REF'    ? $self->_fold_sqlbind($_)
 351                         : $self->_quote($_))
 352                        } reverse each %{$self->_skip_options($from)});
 353 }
 354
 355 sub _skip_options {
 356   my ($self, $hash) = @_;
 357   my $clean_hash = {};
 358   $clean_hash->{$_} = $hash->{$_}
 359     for grep {!/^-/} keys %$hash;
 360   return $clean_hash;
 361 }
 362
 363 sub _join_condition {
 364   my ($self, $cond) = @_;
 365   if (ref $cond eq 'HASH') {
 366     my %j;
 367     for (keys %$cond) {
 368       my $v = $cond->{$_};
 369       if (ref $v) {
 370         # XXX no throw_exception() in this package and croak() fails with strange results
 371         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 372             if ref($v) ne 'SCALAR';
 373         $j{$_} = $v;
 374       }
 375       else {
 376         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 377       }
 378     };
 379     return scalar($self->_recurse_where(\%j));
 380   } elsif (ref $cond eq 'ARRAY') {
 381     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 382   } else {
 383     die "Can't handle this yet!";
 384   }
 385 }
 386
 387 sub _quote {
 388   my ($self, $label) = @_;
 389   return '' unless defined $label;
 390   return "*" if $label eq '*';
 391   return $label unless $self->{quote_char};
 392   if(ref $self->{quote_char} eq "ARRAY"){
 393     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 394       if !defined $self->{name_sep};
 395     my $sep = $self->{name_sep};
 396     return join($self->{name_sep},
 397         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 398        split(/\Q$sep\E/,$label));
 399   }
 400   return $self->SUPER::_quote($label);
 401 }
 402
 403 sub limit_dialect {
 404     my $self = shift;
 405     $self->{limit_dialect} = shift if @_;
 406     return $self->{limit_dialect};
 407 }
 408
 409 sub quote_char {
 410     my $self = shift;
 411     $self->{quote_char} = shift if @_;
 412     return $self->{quote_char};
 413 }
 414
 415 sub name_sep {
 416     my $self = shift;
 417     $self->{name_sep} = shift if @_;
 418     return $self->{name_sep};
 419 }
 420
 421 } # End of BEGIN block
 422
 423 =head1 NAME
 424
 425 DBIx::Class::Storage::DBI - DBI storage handler
 426
 427 =head1 SYNOPSIS
 428
 429   my $schema = MySchema->connect('dbi:SQLite:my.db');
 430
 431   $schema->storage->debug(1);
 432   $schema->dbh_do("DROP TABLE authors");
 433
 434   $schema->resultset('Book')->search({
 435      written_on => $schema->storage->datetime_parser(DateTime->now)
 436   });
 437
 438 =head1 DESCRIPTION
 439
 440 This class represents the connection to an RDBMS via L<DBI>.  See
 441 L<DBIx::Class::Storage> for general information.  This pod only
 442 documents DBI-specific methods and behaviors.
 443
 444 =head1 METHODS
 445
 446 =cut
 447
 448 sub new {
 449   my $new = shift->next::method(@_);
 450
 451   $new->transaction_depth(0);
 452   $new->_sql_maker_opts({});
 453   $new->{savepoints} = [];
 454   $new->{_in_dbh_do} = 0;
 455   $new->{_dbh_gen} = 0;
 456
 457   $new;
 458 }
 459
 460 =head2 connect_info
 461
 462 This method is normally called by L<DBIx::Class::Schema/connection>, which
 463 encapsulates its argument list in an arrayref before passing them here.
 464
 465 The argument list may contain:
 466
 467 =over
 468
 469 =item *
 470
 471 The same 4-element argument set one would normally pass to
 472 L<DBI/connect>, optionally followed by
 473 L<extra attributes|/DBIx::Class specific connection attributes>
 474 recognized by DBIx::Class:
 475
 476   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 477
 478 =item *
 479
 480 A single code reference which returns a connected
 481 L<DBI database handle|DBI/connect> optionally followed by
 482 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 483 by DBIx::Class:
 484
 485   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 486
 487 =item *
 488
 489 A single hashref with all the attributes and the dsn/user/password
 490 mixed together:
 491
 492   $connect_info_args = [{
 493     dsn => $dsn,
 494     user => $user,
 495     password => $pass,
 496     %dbi_attributes,
 497     %extra_attributes,
 498   }];
 499
 500 This is particularly useful for L<Catalyst> based applications, allowing the
 501 following config (L<Config::General> style):
 502
 503   <Model::DB>
 504     schema_class   App::DB
 505     <connect_info>
 506       dsn          dbi:mysql:database=test
 507       user         testuser
 508       password     TestPass
 509       AutoCommit   1
 510     </connect_info>
 511   </Model::DB>
 512
 513 =back
 514
 515 Please note that the L<DBI> docs recommend that you always explicitly
 516 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 517 recommends that it be set to I<1>, and that you perform transactions
 518 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 519 to I<1> if you do not do explicitly set it to zero.  This is the default
 520 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 521
 522 =head3 DBIx::Class specific connection attributes
 523
 524 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 525 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 526 the following connection options. These options can be mixed in with your other
 527 L<DBI> connection attributes, or placed in a seperate hashref
 528 (C<\%extra_attributes>) as shown above.
 529
 530 Every time C<connect_info> is invoked, any previous settings for
 531 these options will be cleared before setting the new ones, regardless of
 532 whether any options are specified in the new C<connect_info>.
 533
 534
 535 =over
 536
 537 =item on_connect_do
 538
 539 Specifies things to do immediately after connecting or re-connecting to
 540 the database.  Its value may contain:
 541
 542 =over
 543
 544 =item an array reference
 545
 546 This contains SQL statements to execute in order.  Each element contains
 547 a string or a code reference that returns a string.
 548
 549 =item a code reference
 550
 551 This contains some code to execute.  Unlike code references within an
 552 array reference, its return value is ignored.
 553
 554 =back
 555
 556 =item on_disconnect_do
 557
 558 Takes arguments in the same form as L</on_connect_do> and executes them
 559 immediately before disconnecting from the database.
 560
 561 Note, this only runs if you explicitly call L</disconnect> on the
 562 storage object.
 563
 564 =item disable_sth_caching
 565
 566 If set to a true value, this option will disable the caching of
 567 statement handles via L<DBI/prepare_cached>.
 568
 569 =item limit_dialect
 570
 571 Sets the limit dialect. This is useful for JDBC-bridge among others
 572 where the remote SQL-dialect cannot be determined by the name of the
 573 driver alone. See also L<SQL::Abstract::Limit>.
 574
 575 =item quote_char
 576
 577 Specifies what characters to use to quote table and column names. If
 578 you use this you will want to specify L</name_sep> as well.
 579
 580 C<quote_char> expects either a single character, in which case is it
 581 is placed on either side of the table/column name, or an arrayref of length
 582 2 in which case the table/column name is placed between the elements.
 583
 584 For example under MySQL you should use C<< quote_char => '`' >>, and for
 585 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 586
 587 =item name_sep
 588
 589 This only needs to be used in conjunction with C<quote_char>, and is used to
 590 specify the charecter that seperates elements (schemas, tables, columns) from
 591 each other. In most cases this is simply a C<.>.
 592
 593 The consequences of not supplying this value is that L<SQL::Abstract>
 594 will assume DBIx::Class' uses of aliases to be complete column
 595 names. The output will look like I<"me.name"> when it should actually
 596 be I<"me"."name">.
 597
 598 =item unsafe
 599
 600 This Storage driver normally installs its own C<HandleError>, sets
 601 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 602 all database handles, including those supplied by a coderef.  It does this
 603 so that it can have consistent and useful error behavior.
 604
 605 If you set this option to a true value, Storage will not do its usual
 606 modifications to the database handle's attributes, and instead relies on
 607 the settings in your connect_info DBI options (or the values you set in
 608 your connection coderef, in the case that you are connecting via coderef).
 609
 610 Note that your custom settings can cause Storage to malfunction,
 611 especially if you set a C<HandleError> handler that suppresses exceptions
 612 and/or disable C<RaiseError>.
 613
 614 =item auto_savepoint
 615
 616 If this option is true, L<DBIx::Class> will use savepoints when nesting
 617 transactions, making it possible to recover from failure in the inner
 618 transaction without having to abort all outer transactions.
 619
 620 =item cursor_class
 621
 622 Use this argument to supply a cursor class other than the default
 623 L<DBIx::Class::Storage::DBI::Cursor>.
 624
 625 =back
 626
 627 Some real-life examples of arguments to L</connect_info> and
 628 L<DBIx::Class::Schema/connect>
 629
 630   # Simple SQLite connection
 631   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 632
 633   # Connect via subref
 634   ->connect_info([ sub { DBI->connect(...) } ]);
 635
 636   # A bit more complicated
 637   ->connect_info(
 638     [
 639       'dbi:Pg:dbname=foo',
 640       'postgres',
 641       'my_pg_password',
 642       { AutoCommit => 1 },
 643       { quote_char => q{"}, name_sep => q{.} },
 644     ]
 645   );
 646
 647   # Equivalent to the previous example
 648   ->connect_info(
 649     [
 650       'dbi:Pg:dbname=foo',
 651       'postgres',
 652       'my_pg_password',
 653       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 654     ]
 655   );
 656
 657   # Same, but with hashref as argument
 658   # See parse_connect_info for explanation
 659   ->connect_info(
 660     [{
 661       dsn         => 'dbi:Pg:dbname=foo',
 662       user        => 'postgres',
 663       password    => 'my_pg_password',
 664       AutoCommit  => 1,
 665       quote_char  => q{"},
 666       name_sep    => q{.},
 667     }]
 668   );
 669
 670   # Subref + DBIx::Class-specific connection options
 671   ->connect_info(
 672     [
 673       sub { DBI->connect(...) },
 674       {
 675           quote_char => q{`},
 676           name_sep => q{@},
 677           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 678           disable_sth_caching => 1,
 679       },
 680     ]
 681   );
 682
 683
 684
 685 =cut
 686
 687 sub connect_info {
 688   my ($self, $info_arg) = @_;
 689
 690   return $self->_connect_info if !$info_arg;
 691
 692   my @args = @$info_arg;  # take a shallow copy for further mutilation
 693   $self->_connect_info([@args]); # copy for _connect_info
 694
 695
 696   # combine/pre-parse arguments depending on invocation style
 697
 698   my %attrs;
 699   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 700     %attrs = %{ $args[1] || {} };
 701     @args = $args[0];
 702   }
 703   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 704     %attrs = %{$args[0]};
 705     @args = ();
 706     for (qw/password user dsn/) {
 707       unshift @args, delete $attrs{$_};
 708     }
 709   }
 710   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 711     %attrs = (
 712       % { $args[3] || {} },
 713       % { $args[4] || {} },
 714     );
 715     @args = @args[0,1,2];
 716   }
 717
 718   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 719   #  the new set of options
 720   $self->_sql_maker(undef);
 721   $self->_sql_maker_opts({});
 722
 723   if(keys %attrs) {
 724     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 725       if(my $value = delete $attrs{$storage_opt}) {
 726         $self->$storage_opt($value);
 727       }
 728     }
 729     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 730       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 731         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 732       }
 733     }
 734   }
 735
 736   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 737
 738   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 739   $self->_connect_info;
 740 }
 741
 742 =head2 on_connect_do
 743
 744 This method is deprecated in favour of setting via L</connect_info>.
 745
 746
 747 =head2 dbh_do
 748
 749 Arguments: ($subref | $method_name), @extra_coderef_args?
 750
 751 Execute the given $subref or $method_name using the new exception-based
 752 connection management.
 753
 754 The first two arguments will be the storage object that C<dbh_do> was called
 755 on and a database handle to use.  Any additional arguments will be passed
 756 verbatim to the called subref as arguments 2 and onwards.
 757
 758 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 759 exception handling and reconnection (or failover in future subclasses).
 760
 761 Your subref should have no side-effects outside of the database, as
 762 there is the potential for your subref to be partially double-executed
 763 if the database connection was stale/dysfunctional.
 764
 765 Example:
 766
 767   my @stuff = $schema->storage->dbh_do(
 768     sub {
 769       my ($storage, $dbh, @cols) = @_;
 770       my $cols = join(q{, }, @cols);
 771       $dbh->selectrow_array("SELECT $cols FROM foo");
 772     },
 773     @column_list
 774   );
 775
 776 =cut
 777
 778 sub dbh_do {
 779   my $self = shift;
 780   my $code = shift;
 781
 782   my $dbh = $self->_dbh;
 783
 784   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 785       || $self->{transaction_depth};
 786
 787   local $self->{_in_dbh_do} = 1;
 788
 789   my @result;
 790   my $want_array = wantarray;
 791
 792   eval {
 793     $self->_verify_pid if $dbh;
 794     if(!$self->_dbh) {
 795         $self->_populate_dbh;
 796         $dbh = $self->_dbh;
 797     }
 798
 799     if($want_array) {
 800         @result = $self->$code($dbh, @_);
 801     }
 802     elsif(defined $want_array) {
 803         $result[0] = $self->$code($dbh, @_);
 804     }
 805     else {
 806         $self->$code($dbh, @_);
 807     }
 808   };
 809
 810   my $exception = $@;
 811   if(!$exception) { return $want_array ? @result : $result[0] }
 812
 813   $self->throw_exception($exception) if $self->connected;
 814
 815   # We were not connected - reconnect and retry, but let any
 816   #  exception fall right through this time
 817   $self->_populate_dbh;
 818   $self->$code($self->_dbh, @_);
 819 }
 820
 821 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 822 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 823 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 824 sub txn_do {
 825   my $self = shift;
 826   my $coderef = shift;
 827
 828   ref $coderef eq 'CODE' or $self->throw_exception
 829     ('$coderef must be a CODE reference');
 830
 831   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 832
 833   local $self->{_in_dbh_do} = 1;
 834
 835   my @result;
 836   my $want_array = wantarray;
 837
 838   my $tried = 0;
 839   while(1) {
 840     eval {
 841       $self->_verify_pid if $self->_dbh;
 842       $self->_populate_dbh if !$self->_dbh;
 843
 844       $self->txn_begin;
 845       if($want_array) {
 846           @result = $coderef->(@_);
 847       }
 848       elsif(defined $want_array) {
 849           $result[0] = $coderef->(@_);
 850       }
 851       else {
 852           $coderef->(@_);
 853       }
 854       $self->txn_commit;
 855     };
 856
 857     my $exception = $@;
 858     if(!$exception) { return $want_array ? @result : $result[0] }
 859
 860     if($tried++ > 0 || $self->connected) {
 861       eval { $self->txn_rollback };
 862       my $rollback_exception = $@;
 863       if($rollback_exception) {
 864         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 865         $self->throw_exception($exception)  # propagate nested rollback
 866           if $rollback_exception =~ /$exception_class/;
 867
 868         $self->throw_exception(
 869           "Transaction aborted: ${exception}. "
 870           . "Rollback failed: ${rollback_exception}"
 871         );
 872       }
 873       $self->throw_exception($exception)
 874     }
 875
 876     # We were not connected, and was first try - reconnect and retry
 877     # via the while loop
 878     $self->_populate_dbh;
 879   }
 880 }
 881
 882 =head2 disconnect
 883
 884 Our C<disconnect> method also performs a rollback first if the
 885 database is not in C<AutoCommit> mode.
 886
 887 =cut
 888
 889 sub disconnect {
 890   my ($self) = @_;
 891
 892   if( $self->connected ) {
 893     my $connection_do = $self->on_disconnect_do;
 894     $self->_do_connection_actions($connection_do) if ref($connection_do);
 895
 896     $self->_dbh->rollback unless $self->_dbh_autocommit;
 897     $self->_dbh->disconnect;
 898     $self->_dbh(undef);
 899     $self->{_dbh_gen}++;
 900   }
 901 }
 902
 903 =head2 with_deferred_fk_checks
 904
 905 =over 4
 906
 907 =item Arguments: C<$coderef>
 908
 909 =item Return Value: The return value of $coderef
 910
 911 =back
 912
 913 Storage specific method to run the code ref with FK checks deferred or
 914 in MySQL's case disabled entirely.
 915
 916 =cut
 917
 918 # Storage subclasses should override this
 919 sub with_deferred_fk_checks {
 920   my ($self, $sub) = @_;
 921
 922   $sub->();
 923 }
 924
 925 sub connected {
 926   my ($self) = @_;
 927
 928   if(my $dbh = $self->_dbh) {
 929       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 930           $self->_dbh(undef);
 931           $self->{_dbh_gen}++;
 932           return;
 933       }
 934       else {
 935           $self->_verify_pid;
 936           return 0 if !$self->_dbh;
 937       }
 938       return ($dbh->FETCH('Active') && $dbh->ping);
 939   }
 940
 941   return 0;
 942 }
 943
 944 # handle pid changes correctly
 945 #  NOTE: assumes $self->_dbh is a valid $dbh
 946 sub _verify_pid {
 947   my ($self) = @_;
 948
 949   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 950
 951   $self->_dbh->{InactiveDestroy} = 1;
 952   $self->_dbh(undef);
 953   $self->{_dbh_gen}++;
 954
 955   return;
 956 }
 957
 958 sub ensure_connected {
 959   my ($self) = @_;
 960
 961   unless ($self->connected) {
 962     $self->_populate_dbh;
 963   }
 964 }
 965
 966 =head2 dbh
 967
 968 Returns the dbh - a data base handle of class L<DBI>.
 969
 970 =cut
 971
 972 sub dbh {
 973   my ($self) = @_;
 974
 975   $self->ensure_connected;
 976   return $self->_dbh;
 977 }
 978
 979 sub _sql_maker_args {
 980     my ($self) = @_;
 981
 982     return ( bindtype=>'columns', array_datatypes => 1, limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 983 }
 984
 985 sub sql_maker {
 986   my ($self) = @_;
 987   unless ($self->_sql_maker) {
 988     my $sql_maker_class = $self->sql_maker_class;
 989     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 990   }
 991   return $self->_sql_maker;
 992 }
 993
 994 sub _rebless {}
 995
 996 sub _populate_dbh {
 997   my ($self) = @_;
 998   my @info = @{$self->_dbi_connect_info || []};
 999   $self->_dbh($self->_connect(@info));
1000
1001   # Always set the transaction depth on connect, since
1002   #  there is no transaction in progress by definition
1003   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1004
1005   if(ref $self eq 'DBIx::Class::Storage::DBI') {
1006     my $driver = $self->_dbh->{Driver}->{Name};
1007     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
1008       bless $self, "DBIx::Class::Storage::DBI::${driver}";
1009       $self->_rebless();
1010     }
1011   }
1012
1013   $self->_conn_pid($$);
1014   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
1015
1016   my $connection_do = $self->on_connect_do;
1017   $self->_do_connection_actions($connection_do) if ref($connection_do);
1018 }
1019
1020 sub _do_connection_actions {
1021   my $self = shift;
1022   my $connection_do = shift;
1023
1024   if (ref $connection_do eq 'ARRAY') {
1025     $self->_do_query($_) foreach @$connection_do;
1026   }
1027   elsif (ref $connection_do eq 'CODE') {
1028     $connection_do->($self);
1029   }
1030
1031   return $self;
1032 }
1033
1034 sub _do_query {
1035   my ($self, $action) = @_;
1036
1037   if (ref $action eq 'CODE') {
1038     $action = $action->($self);
1039     $self->_do_query($_) foreach @$action;
1040   }
1041   else {
1042     # Most debuggers expect ($sql, @bind), so we need to exclude
1043     # the attribute hash which is the second argument to $dbh->do
1044     # furthermore the bind values are usually to be presented
1045     # as named arrayref pairs, so wrap those here too
1046     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1047     my $sql = shift @do_args;
1048     my $attrs = shift @do_args;
1049     my @bind = map { [ undef, $_ ] } @do_args;
1050
1051     $self->_query_start($sql, @bind);
1052     $self->_dbh->do($sql, $attrs, @do_args);
1053     $self->_query_end($sql, @bind);
1054   }
1055
1056   return $self;
1057 }
1058
1059 sub _connect {
1060   my ($self, @info) = @_;
1061
1062   $self->throw_exception("You failed to provide any connection info")
1063     if !@info;
1064
1065   my ($old_connect_via, $dbh);
1066
1067   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1068     $old_connect_via = $DBI::connect_via;
1069     $DBI::connect_via = 'connect';
1070   }
1071
1072   eval {
1073     if(ref $info[0] eq 'CODE') {
1074        $dbh = &{$info[0]}
1075     }
1076     else {
1077        $dbh = DBI->connect(@info);
1078     }
1079
1080     if($dbh && !$self->unsafe) {
1081       my $weak_self = $self;
1082       weaken($weak_self);
1083       $dbh->{HandleError} = sub {
1084           if ($weak_self) {
1085             $weak_self->throw_exception("DBI Exception: $_[0]");
1086           }
1087           else {
1088             croak ("DBI Exception: $_[0]");
1089           }
1090       };
1091       $dbh->{ShowErrorStatement} = 1;
1092       $dbh->{RaiseError} = 1;
1093       $dbh->{PrintError} = 0;
1094     }
1095   };
1096
1097   $DBI::connect_via = $old_connect_via if $old_connect_via;
1098
1099   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
1100     if !$dbh || $@;
1101
1102   $self->_dbh_autocommit($dbh->{AutoCommit});
1103
1104   $dbh;
1105 }
1106
1107 sub svp_begin {
1108   my ($self, $name) = @_;
1109
1110   $name = $self->_svp_generate_name
1111     unless defined $name;
1112
1113   $self->throw_exception ("You can't use savepoints outside a transaction")
1114     if $self->{transaction_depth} == 0;
1115
1116   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1117     unless $self->can('_svp_begin');
1118
1119   push @{ $self->{savepoints} }, $name;
1120
1121   $self->debugobj->svp_begin($name) if $self->debug;
1122
1123   return $self->_svp_begin($name);
1124 }
1125
1126 sub svp_release {
1127   my ($self, $name) = @_;
1128
1129   $self->throw_exception ("You can't use savepoints outside a transaction")
1130     if $self->{transaction_depth} == 0;
1131
1132   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1133     unless $self->can('_svp_release');
1134
1135   if (defined $name) {
1136     $self->throw_exception ("Savepoint '$name' does not exist")
1137       unless grep { $_ eq $name } @{ $self->{savepoints} };
1138
1139     # Dig through the stack until we find the one we are releasing.  This keeps
1140     # the stack up to date.
1141     my $svp;
1142
1143     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1144   } else {
1145     $name = pop @{ $self->{savepoints} };
1146   }
1147
1148   $self->debugobj->svp_release($name) if $self->debug;
1149
1150   return $self->_svp_release($name);
1151 }
1152
1153 sub svp_rollback {
1154   my ($self, $name) = @_;
1155
1156   $self->throw_exception ("You can't use savepoints outside a transaction")
1157     if $self->{transaction_depth} == 0;
1158
1159   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1160     unless $self->can('_svp_rollback');
1161
1162   if (defined $name) {
1163       # If they passed us a name, verify that it exists in the stack
1164       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1165           $self->throw_exception("Savepoint '$name' does not exist!");
1166       }
1167
1168       # Dig through the stack until we find the one we are releasing.  This keeps
1169       # the stack up to date.
1170       while(my $s = pop(@{ $self->{savepoints} })) {
1171           last if($s eq $name);
1172       }
1173       # Add the savepoint back to the stack, as a rollback doesn't remove the
1174       # named savepoint, only everything after it.
1175       push(@{ $self->{savepoints} }, $name);
1176   } else {
1177       # We'll assume they want to rollback to the last savepoint
1178       $name = $self->{savepoints}->[-1];
1179   }
1180
1181   $self->debugobj->svp_rollback($name) if $self->debug;
1182
1183   return $self->_svp_rollback($name);
1184 }
1185
1186 sub _svp_generate_name {
1187     my ($self) = @_;
1188
1189     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1190 }
1191
1192 sub txn_begin {
1193   my $self = shift;
1194   $self->ensure_connected();
1195   if($self->{transaction_depth} == 0) {
1196     $self->debugobj->txn_begin()
1197       if $self->debug;
1198     # this isn't ->_dbh-> because
1199     #  we should reconnect on begin_work
1200     #  for AutoCommit users
1201     $self->dbh->begin_work;
1202   } elsif ($self->auto_savepoint) {
1203     $self->svp_begin;
1204   }
1205   $self->{transaction_depth}++;
1206 }
1207
1208 sub txn_commit {
1209   my $self = shift;
1210   if ($self->{transaction_depth} == 1) {
1211     my $dbh = $self->_dbh;
1212     $self->debugobj->txn_commit()
1213       if ($self->debug);
1214     $dbh->commit;
1215     $self->{transaction_depth} = 0
1216       if $self->_dbh_autocommit;
1217   }
1218   elsif($self->{transaction_depth} > 1) {
1219     $self->{transaction_depth}--;
1220     $self->svp_release
1221       if $self->auto_savepoint;
1222   }
1223 }
1224
1225 sub txn_rollback {
1226   my $self = shift;
1227   my $dbh = $self->_dbh;
1228   eval {
1229     if ($self->{transaction_depth} == 1) {
1230       $self->debugobj->txn_rollback()
1231         if ($self->debug);
1232       $self->{transaction_depth} = 0
1233         if $self->_dbh_autocommit;
1234       $dbh->rollback;
1235     }
1236     elsif($self->{transaction_depth} > 1) {
1237       $self->{transaction_depth}--;
1238       if ($self->auto_savepoint) {
1239         $self->svp_rollback;
1240         $self->svp_release;
1241       }
1242     }
1243     else {
1244       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1245     }
1246   };
1247   if ($@) {
1248     my $error = $@;
1249     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1250     $error =~ /$exception_class/ and $self->throw_exception($error);
1251     # ensure that a failed rollback resets the transaction depth
1252     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1253     $self->throw_exception($error);
1254   }
1255 }
1256
1257 # This used to be the top-half of _execute.  It was split out to make it
1258 #  easier to override in NoBindVars without duping the rest.  It takes up
1259 #  all of _execute's args, and emits $sql, @bind.
1260 sub _prep_for_execute {
1261   my ($self, $op, $extra_bind, $ident, $args) = @_;
1262
1263   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1264     $ident = $ident->from();
1265   }
1266
1267   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1268
1269   unshift(@bind,
1270     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1271       if $extra_bind;
1272   return ($sql, \@bind);
1273 }
1274
1275 sub _fix_bind_params {
1276     my ($self, @bind) = @_;
1277
1278     ### Turn @bind from something like this:
1279     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1280     ### to this:
1281     ###   ( "'1'", "'1'", "'3'" )
1282     return
1283         map {
1284             if ( defined( $_ && $_->[1] ) ) {
1285                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1286             }
1287             else { q{'NULL'}; }
1288         } @bind;
1289 }
1290
1291 sub _query_start {
1292     my ( $self, $sql, @bind ) = @_;
1293
1294     if ( $self->debug ) {
1295         @bind = $self->_fix_bind_params(@bind);
1296
1297         $self->debugobj->query_start( $sql, @bind );
1298     }
1299 }
1300
1301 sub _query_end {
1302     my ( $self, $sql, @bind ) = @_;
1303
1304     if ( $self->debug ) {
1305         @bind = $self->_fix_bind_params(@bind);
1306         $self->debugobj->query_end( $sql, @bind );
1307     }
1308 }
1309
1310 sub _dbh_execute {
1311   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1312
1313   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1314
1315   $self->_query_start( $sql, @$bind );
1316
1317   my $sth = $self->sth($sql,$op);
1318
1319   my $placeholder_index = 1;
1320
1321   foreach my $bound (@$bind) {
1322     my $attributes = {};
1323     my($column_name, @data) = @$bound;
1324
1325     if ($bind_attributes) {
1326       $attributes = $bind_attributes->{$column_name}
1327       if defined $bind_attributes->{$column_name};
1328     }
1329
1330     foreach my $data (@data) {
1331       my $ref = ref $data;
1332       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1333
1334       $sth->bind_param($placeholder_index, $data, $attributes);
1335       $placeholder_index++;
1336     }
1337   }
1338
1339   # Can this fail without throwing an exception anyways???
1340   my $rv = $sth->execute();
1341   $self->throw_exception($sth->errstr) if !$rv;
1342
1343   $self->_query_end( $sql, @$bind );
1344
1345   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1346 }
1347
1348 sub _execute {
1349     my $self = shift;
1350     $self->dbh_do('_dbh_execute', @_)
1351 }
1352
1353 sub insert {
1354   my ($self, $source, $to_insert) = @_;
1355
1356   my $ident = $source->from;
1357   my $bind_attributes = $self->source_bind_attributes($source);
1358
1359   my $updated_cols = {};
1360
1361   $self->ensure_connected;
1362   foreach my $col ( $source->columns ) {
1363     if ( !defined $to_insert->{$col} ) {
1364       my $col_info = $source->column_info($col);
1365
1366       if ( $col_info->{auto_nextval} ) {
1367         $updated_cols->{$col} = $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1368       }
1369     }
1370   }
1371
1372   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1373
1374   return $updated_cols;
1375 }
1376
1377 ## Still not quite perfect, and EXPERIMENTAL
1378 ## Currently it is assumed that all values passed will be "normal", i.e. not
1379 ## scalar refs, or at least, all the same type as the first set, the statement is
1380 ## only prepped once.
1381 sub insert_bulk {
1382   my ($self, $source, $cols, $data) = @_;
1383   my %colvalues;
1384   my $table = $source->from;
1385   @colvalues{@$cols} = (0..$#$cols);
1386   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1387
1388   $self->_query_start( $sql, @bind );
1389   my $sth = $self->sth($sql);
1390
1391 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1392
1393   ## This must be an arrayref, else nothing works!
1394   my $tuple_status = [];
1395
1396   ## Get the bind_attributes, if any exist
1397   my $bind_attributes = $self->source_bind_attributes($source);
1398
1399   ## Bind the values and execute
1400   my $placeholder_index = 1;
1401
1402   foreach my $bound (@bind) {
1403
1404     my $attributes = {};
1405     my ($column_name, $data_index) = @$bound;
1406
1407     if( $bind_attributes ) {
1408       $attributes = $bind_attributes->{$column_name}
1409       if defined $bind_attributes->{$column_name};
1410     }
1411
1412     my @data = map { $_->[$data_index] } @$data;
1413
1414     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1415     $placeholder_index++;
1416   }
1417   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1418   $self->throw_exception($sth->errstr) if !$rv;
1419
1420   $self->_query_end( $sql, @bind );
1421   return (wantarray ? ($rv, $sth, @bind) : $rv);
1422 }
1423
1424 sub update {
1425   my $self = shift @_;
1426   my $source = shift @_;
1427   my $bind_attributes = $self->source_bind_attributes($source);
1428
1429   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1430 }
1431
1432
1433 sub delete {
1434   my $self = shift @_;
1435   my $source = shift @_;
1436
1437   my $bind_attrs = {}; ## If ever it's needed...
1438
1439   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1440 }
1441
1442 sub _select {
1443   my $self = shift;
1444   my $sql_maker = $self->sql_maker;
1445   local $sql_maker->{for};
1446   return $self->_execute($self->_select_args(@_));
1447 }
1448
1449 sub _select_args {
1450   my ($self, $ident, $select, $condition, $attrs) = @_;
1451   my $order = $attrs->{order_by};
1452
1453   my $for = delete $attrs->{for};
1454   my $sql_maker = $self->sql_maker;
1455   $sql_maker->{for} = $for;
1456
1457   if (exists $attrs->{group_by} || $attrs->{having}) {
1458     $order = {
1459       group_by => $attrs->{group_by},
1460       having => $attrs->{having},
1461       ($order ? (order_by => $order) : ())
1462     };
1463   }
1464   my $bind_attrs = {}; ## Future support
1465   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1466   if ($attrs->{software_limit} ||
1467       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1468         $attrs->{software_limit} = 1;
1469   } else {
1470     $self->throw_exception("rows attribute must be positive if present")
1471       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1472
1473     # MySQL actually recommends this approach.  I cringe.
1474     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1475     push @args, $attrs->{rows}, $attrs->{offset};
1476   }
1477   return @args;
1478 }
1479
1480 sub source_bind_attributes {
1481   my ($self, $source) = @_;
1482
1483   my $bind_attributes;
1484   foreach my $column ($source->columns) {
1485
1486     my $data_type = $source->column_info($column)->{data_type} || '';
1487     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1488      if $data_type;
1489   }
1490
1491   return $bind_attributes;
1492 }
1493
1494 =head2 select
1495
1496 =over 4
1497
1498 =item Arguments: $ident, $select, $condition, $attrs
1499
1500 =back
1501
1502 Handle a SQL select statement.
1503
1504 =cut
1505
1506 sub select {
1507   my $self = shift;
1508   my ($ident, $select, $condition, $attrs) = @_;
1509   return $self->cursor_class->new($self, \@_, $attrs);
1510 }
1511
1512 sub select_single {
1513   my $self = shift;
1514   my ($rv, $sth, @bind) = $self->_select(@_);
1515   my @row = $sth->fetchrow_array;
1516   my @nextrow = $sth->fetchrow_array if @row;
1517   if(@row && @nextrow) {
1518     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1519   }
1520   # Need to call finish() to work round broken DBDs
1521   $sth->finish();
1522   return @row;
1523 }
1524
1525 =head2 sth
1526
1527 =over 4
1528
1529 =item Arguments: $sql
1530
1531 =back
1532
1533 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1534
1535 =cut
1536
1537 sub _dbh_sth {
1538   my ($self, $dbh, $sql) = @_;
1539
1540   # 3 is the if_active parameter which avoids active sth re-use
1541   my $sth = $self->disable_sth_caching
1542     ? $dbh->prepare($sql)
1543     : $dbh->prepare_cached($sql, {}, 3);
1544
1545   # XXX You would think RaiseError would make this impossible,
1546   #  but apparently that's not true :(
1547   $self->throw_exception($dbh->errstr) if !$sth;
1548
1549   $sth;
1550 }
1551
1552 sub sth {
1553   my ($self, $sql) = @_;
1554   $self->dbh_do('_dbh_sth', $sql);
1555 }
1556
1557 sub _dbh_columns_info_for {
1558   my ($self, $dbh, $table) = @_;
1559
1560   if ($dbh->can('column_info')) {
1561     my %result;
1562     eval {
1563       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1564       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1565       $sth->execute();
1566       while ( my $info = $sth->fetchrow_hashref() ){
1567         my %column_info;
1568         $column_info{data_type}   = $info->{TYPE_NAME};
1569         $column_info{size}      = $info->{COLUMN_SIZE};
1570         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1571         $column_info{default_value} = $info->{COLUMN_DEF};
1572         my $col_name = $info->{COLUMN_NAME};
1573         $col_name =~ s/^\"(.*)\"$/$1/;
1574
1575         $result{$col_name} = \%column_info;
1576       }
1577     };
1578     return \%result if !$@ && scalar keys %result;
1579   }
1580
1581   my %result;
1582   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1583   $sth->execute;
1584   my @columns = @{$sth->{NAME_lc}};
1585   for my $i ( 0 .. $#columns ){
1586     my %column_info;
1587     $column_info{data_type} = $sth->{TYPE}->[$i];
1588     $column_info{size} = $sth->{PRECISION}->[$i];
1589     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1590
1591     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1592       $column_info{data_type} = $1;
1593       $column_info{size}    = $2;
1594     }
1595
1596     $result{$columns[$i]} = \%column_info;
1597   }
1598   $sth->finish;
1599
1600   foreach my $col (keys %result) {
1601     my $colinfo = $result{$col};
1602     my $type_num = $colinfo->{data_type};
1603     my $type_name;
1604     if(defined $type_num && $dbh->can('type_info')) {
1605       my $type_info = $dbh->type_info($type_num);
1606       $type_name = $type_info->{TYPE_NAME} if $type_info;
1607       $colinfo->{data_type} = $type_name if $type_name;
1608     }
1609   }
1610
1611   return \%result;
1612 }
1613
1614 sub columns_info_for {
1615   my ($self, $table) = @_;
1616   $self->dbh_do('_dbh_columns_info_for', $table);
1617 }
1618
1619 =head2 last_insert_id
1620
1621 Return the row id of the last insert.
1622
1623 =cut
1624
1625 sub _dbh_last_insert_id {
1626     # All Storage's need to register their own _dbh_last_insert_id
1627     # the old SQLite-based method was highly inappropriate
1628
1629     my $self = shift;
1630     my $class = ref $self;
1631     $self->throw_exception (<<EOE);
1632
1633 No _dbh_last_insert_id() method found in $class.
1634 Since the method of obtaining the autoincrement id of the last insert
1635 operation varies greatly between different databases, this method must be
1636 individually implemented for every storage class.
1637 EOE
1638 }
1639
1640 sub last_insert_id {
1641   my $self = shift;
1642   $self->dbh_do('_dbh_last_insert_id', @_);
1643 }
1644
1645 =head2 sqlt_type
1646
1647 Returns the database driver name.
1648
1649 =cut
1650
1651 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1652
1653 =head2 bind_attribute_by_data_type
1654
1655 Given a datatype from column info, returns a database specific bind
1656 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
1657 let the database planner just handle it.
1658
1659 Generally only needed for special case column types, like bytea in postgres.
1660
1661 =cut
1662
1663 sub bind_attribute_by_data_type {
1664     return;
1665 }
1666
1667 =head2 create_ddl_dir
1668
1669 =over 4
1670
1671 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1672
1673 =back
1674
1675 Creates a SQL file based on the Schema, for each of the specified
1676 database types, in the given directory.
1677
1678 By default, C<\%sqlt_args> will have
1679
1680  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1681
1682 merged with the hash passed in. To disable any of those features, pass in a
1683 hashref like the following
1684
1685  { ignore_constraint_names => 0, # ... other options }
1686
1687 =cut
1688
1689 sub create_ddl_dir {
1690   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1691
1692   if(!$dir || !-d $dir) {
1693     warn "No directory given, using ./\n";
1694     $dir = "./";
1695   }
1696   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1697   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1698
1699   my $schema_version = $schema->schema_version || '1.x';
1700   $version ||= $schema_version;
1701
1702   $sqltargs = {
1703     add_drop_table => 1,
1704     ignore_constraint_names => 1,
1705     ignore_index_names => 1,
1706     %{$sqltargs || {}}
1707   };
1708
1709   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09003: '}
1710       . $self->_check_sqlt_message . q{'})
1711           if !$self->_check_sqlt_version;
1712
1713   my $sqlt = SQL::Translator->new( $sqltargs );
1714
1715   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1716   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1717
1718   foreach my $db (@$databases) {
1719     $sqlt->reset();
1720     $sqlt->{schema} = $sqlt_schema;
1721     $sqlt->producer($db);
1722
1723     my $file;
1724     my $filename = $schema->ddl_filename($db, $version, $dir);
1725     if (-e $filename && ($version eq $schema_version )) {
1726       # if we are dumping the current version, overwrite the DDL
1727       warn "Overwriting existing DDL file - $filename";
1728       unlink($filename);
1729     }
1730
1731     my $output = $sqlt->translate;
1732     if(!$output) {
1733       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1734       next;
1735     }
1736     if(!open($file, ">$filename")) {
1737       $self->throw_exception("Can't open $filename for writing ($!)");
1738       next;
1739     }
1740     print $file $output;
1741     close($file);
1742
1743     next unless ($preversion);
1744
1745     require SQL::Translator::Diff;
1746
1747     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1748     if(!-e $prefilename) {
1749       warn("No previous schema file found ($prefilename)");
1750       next;
1751     }
1752
1753     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1754     if(-e $difffile) {
1755       warn("Overwriting existing diff file - $difffile");
1756       unlink($difffile);
1757     }
1758
1759     my $source_schema;
1760     {
1761       my $t = SQL::Translator->new($sqltargs);
1762       $t->debug( 0 );
1763       $t->trace( 0 );
1764       $t->parser( $db )                       or die $t->error;
1765       my $out = $t->translate( $prefilename ) or die $t->error;
1766       $source_schema = $t->schema;
1767       unless ( $source_schema->name ) {
1768         $source_schema->name( $prefilename );
1769       }
1770     }
1771
1772     # The "new" style of producers have sane normalization and can support
1773     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1774     # And we have to diff parsed SQL against parsed SQL.
1775     my $dest_schema = $sqlt_schema;
1776
1777     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1778       my $t = SQL::Translator->new($sqltargs);
1779       $t->debug( 0 );
1780       $t->trace( 0 );
1781       $t->parser( $db )                    or die $t->error;
1782       my $out = $t->translate( $filename ) or die $t->error;
1783       $dest_schema = $t->schema;
1784       $dest_schema->name( $filename )
1785         unless $dest_schema->name;
1786     }
1787
1788     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1789                                                   $dest_schema,   $db,
1790                                                   $sqltargs
1791                                                  );
1792     if(!open $file, ">$difffile") {
1793       $self->throw_exception("Can't write to $difffile ($!)");
1794       next;
1795     }
1796     print $file $diff;
1797     close($file);
1798   }
1799 }
1800
1801 =head2 deployment_statements
1802
1803 =over 4
1804
1805 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1806
1807 =back
1808
1809 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1810 The database driver name is given by C<$type>, though the value from
1811 L</sqlt_type> is used if it is not specified.
1812
1813 C<$directory> is used to return statements from files in a previously created
1814 L</create_ddl_dir> directory and is optional. The filenames are constructed
1815 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1816
1817 If no C<$directory> is specified then the statements are constructed on the
1818 fly using L<SQL::Translator> and C<$version> is ignored.
1819
1820 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1821
1822 =cut
1823
1824 sub deployment_statements {
1825   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1826   # Need to be connected to get the correct sqlt_type
1827   $self->ensure_connected() unless $type;
1828   $type ||= $self->sqlt_type;
1829   $version ||= $schema->schema_version || '1.x';
1830   $dir ||= './';
1831   my $filename = $schema->ddl_filename($type, $version, $dir);
1832   if(-f $filename)
1833   {
1834       my $file;
1835       open($file, "<$filename")
1836         or $self->throw_exception("Can't open $filename ($!)");
1837       my @rows = <$file>;
1838       close($file);
1839       return join('', @rows);
1840   }
1841
1842   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09003: '}
1843       . $self->_check_sqlt_message . q{'})
1844           if !$self->_check_sqlt_version;
1845
1846   require SQL::Translator::Parser::DBIx::Class;
1847   eval qq{use SQL::Translator::Producer::${type}};
1848   $self->throw_exception($@) if $@;
1849
1850   # sources needs to be a parser arg, but for simplicty allow at top level
1851   # coming in
1852   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1853       if exists $sqltargs->{sources};
1854
1855   my $tr = SQL::Translator->new(%$sqltargs);
1856   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1857   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1858 }
1859
1860 sub deploy {
1861   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1862   my $deploy = sub {
1863     my $line = shift;
1864     return if($line =~ /^--/);
1865     return if(!$line);
1866     # next if($line =~ /^DROP/m);
1867     return if($line =~ /^BEGIN TRANSACTION/m);
1868     return if($line =~ /^COMMIT/m);
1869     return if $line =~ /^\s+$/; # skip whitespace only
1870     $self->_query_start($line);
1871     eval {
1872       $self->dbh->do($line); # shouldn't be using ->dbh ?
1873     };
1874     if ($@) {
1875       warn qq{$@ (running "${line}")};
1876     }
1877     $self->_query_end($line);
1878   };
1879   my @statements = $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } );
1880   if (@statements > 1) {
1881     foreach my $statement (@statements) {
1882       $deploy->( $statement );
1883     }
1884   }
1885   elsif (@statements == 1) {
1886     foreach my $line ( split(";\n", $statements[0])) {
1887       $deploy->( $line );
1888     }
1889   }
1890 }
1891
1892 =head2 datetime_parser
1893
1894 Returns the datetime parser class
1895
1896 =cut
1897
1898 sub datetime_parser {
1899   my $self = shift;
1900   return $self->{datetime_parser} ||= do {
1901     $self->ensure_connected;
1902     $self->build_datetime_parser(@_);
1903   };
1904 }
1905
1906 =head2 datetime_parser_type
1907
1908 Defines (returns) the datetime parser class - currently hardwired to
1909 L<DateTime::Format::MySQL>
1910
1911 =cut
1912
1913 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1914
1915 =head2 build_datetime_parser
1916
1917 See L</datetime_parser>
1918
1919 =cut
1920
1921 sub build_datetime_parser {
1922   my $self = shift;
1923   my $type = $self->datetime_parser_type(@_);
1924   eval "use ${type}";
1925   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1926   return $type;
1927 }
1928
1929 {
1930     my $_check_sqlt_version; # private
1931     my $_check_sqlt_message; # private
1932     sub _check_sqlt_version {
1933         return $_check_sqlt_version if defined $_check_sqlt_version;
1934         eval 'use SQL::Translator "0.09003"';
1935         $_check_sqlt_message = $@ || '';
1936         $_check_sqlt_version = !$@;
1937     }
1938
1939     sub _check_sqlt_message {
1940         _check_sqlt_version if !defined $_check_sqlt_message;
1941         $_check_sqlt_message;
1942     }
1943 }
1944
1945 =head2 is_replicating
1946
1947 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1948 replicate from a master database.  Default is undef, which is the result
1949 returned by databases that don't support replication.
1950
1951 =cut
1952
1953 sub is_replicating {
1954     return;
1955
1956 }
1957
1958 =head2 lag_behind_master
1959
1960 Returns a number that represents a certain amount of lag behind a master db
1961 when a given storage is replicating.  The number is database dependent, but
1962 starts at zero and increases with the amount of lag. Default in undef
1963
1964 =cut
1965
1966 sub lag_behind_master {
1967     return;
1968 }
1969
1970 sub DESTROY {
1971   my $self = shift;
1972   return if !$self->_dbh;
1973   $self->_verify_pid;
1974   $self->_dbh(undef);
1975 }
1976
1977 1;
1978
1979 =head1 USAGE NOTES
1980
1981 =head2 DBIx::Class and AutoCommit
1982
1983 DBIx::Class can do some wonderful magic with handling exceptions,
1984 disconnections, and transactions when you use C<< AutoCommit => 1 >>
1985 combined with C<txn_do> for transaction support.
1986
1987 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
1988 in an assumed transaction between commits, and you're telling us you'd
1989 like to manage that manually.  A lot of the magic protections offered by
1990 this module will go away.  We can't protect you from exceptions due to database
1991 disconnects because we don't know anything about how to restart your
1992 transactions.  You're on your own for handling all sorts of exceptional
1993 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
1994 be with raw DBI.
1995
1996
1997 =head1 SQL METHODS
1998
1999 The module defines a set of methods within the DBIC::SQL::Abstract
2000 namespace.  These build on L<SQL::Abstract::Limit> to provide the
2001 SQL query functions.
2002
2003 The following methods are extended:-
2004
2005 =over 4
2006
2007 =item delete
2008
2009 =item insert
2010
2011 =item select
2012
2013 =item update
2014
2015 =item limit_dialect
2016
2017 See L</connect_info> for details.
2018
2019 =item quote_char
2020
2021 See L</connect_info> for details.
2022
2023 =item name_sep
2024
2025 See L</connect_info> for details.
2026
2027 =back
2028
2029 =head1 AUTHORS
2030
2031 Matt S. Trout <mst@shadowcatsystems.co.uk>
2032
2033 Andy Grundman <andy@hybridized.org>
2034
2035 =head1 LICENSE
2036
2037 You may distribute this code under the same terms as Perl itself.
2038
2039 =cut