lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use DBIx::Class::SQLAHacks;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14 use List::Util();
  15
  16 __PACKAGE__->mk_group_accessors('simple' =>
  17     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  18        _conn_pid _conn_tid transaction_depth _dbh_autocommit savepoints/
  19 );
  20
  21 # the values for these accessors are picked out (and deleted) from
  22 # the attribute hashref passed to connect_info
  23 my @storage_options = qw/
  24   on_connect_do on_disconnect_do disable_sth_caching unsafe auto_savepoint
  25 /;
  26 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  27
  28
  29 # default cursor class, overridable in connect_info attributes
  30 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  31
  32 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  33 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  34
  35
  36 =head1 NAME
  37
  38 DBIx::Class::Storage::DBI - DBI storage handler
  39
  40 =head1 SYNOPSIS
  41
  42   my $schema = MySchema->connect('dbi:SQLite:my.db');
  43
  44   $schema->storage->debug(1);
  45   $schema->dbh_do("DROP TABLE authors");
  46
  47   $schema->resultset('Book')->search({
  48      written_on => $schema->storage->datetime_parser(DateTime->now)
  49   });
  50
  51 =head1 DESCRIPTION
  52
  53 This class represents the connection to an RDBMS via L<DBI>.  See
  54 L<DBIx::Class::Storage> for general information.  This pod only
  55 documents DBI-specific methods and behaviors.
  56
  57 =head1 METHODS
  58
  59 =cut
  60
  61 sub new {
  62   my $new = shift->next::method(@_);
  63
  64   $new->transaction_depth(0);
  65   $new->_sql_maker_opts({});
  66   $new->{savepoints} = [];
  67   $new->{_in_dbh_do} = 0;
  68   $new->{_dbh_gen} = 0;
  69
  70   $new;
  71 }
  72
  73 =head2 connect_info
  74
  75 This method is normally called by L<DBIx::Class::Schema/connection>, which
  76 encapsulates its argument list in an arrayref before passing them here.
  77
  78 The argument list may contain:
  79
  80 =over
  81
  82 =item *
  83
  84 The same 4-element argument set one would normally pass to
  85 L<DBI/connect>, optionally followed by
  86 L<extra attributes|/DBIx::Class specific connection attributes>
  87 recognized by DBIx::Class:
  88
  89   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
  90
  91 =item *
  92
  93 A single code reference which returns a connected
  94 L<DBI database handle|DBI/connect> optionally followed by
  95 L<extra attributes|/DBIx::Class specific connection attributes> recognized
  96 by DBIx::Class:
  97
  98   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
  99
 100 =item *
 101
 102 A single hashref with all the attributes and the dsn/user/password
 103 mixed together:
 104
 105   $connect_info_args = [{
 106     dsn => $dsn,
 107     user => $user,
 108     password => $pass,
 109     %dbi_attributes,
 110     %extra_attributes,
 111   }];
 112
 113 This is particularly useful for L<Catalyst> based applications, allowing the
 114 following config (L<Config::General> style):
 115
 116   <Model::DB>
 117     schema_class   App::DB
 118     <connect_info>
 119       dsn          dbi:mysql:database=test
 120       user         testuser
 121       password     TestPass
 122       AutoCommit   1
 123     </connect_info>
 124   </Model::DB>
 125
 126 =back
 127
 128 Please note that the L<DBI> docs recommend that you always explicitly
 129 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 130 recommends that it be set to I<1>, and that you perform transactions
 131 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 132 to I<1> if you do not do explicitly set it to zero.  This is the default
 133 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 134
 135 =head3 DBIx::Class specific connection attributes
 136
 137 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 138 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 139 the following connection options. These options can be mixed in with your other
 140 L<DBI> connection attributes, or placed in a seperate hashref
 141 (C<\%extra_attributes>) as shown above.
 142
 143 Every time C<connect_info> is invoked, any previous settings for
 144 these options will be cleared before setting the new ones, regardless of
 145 whether any options are specified in the new C<connect_info>.
 146
 147
 148 =over
 149
 150 =item on_connect_do
 151
 152 Specifies things to do immediately after connecting or re-connecting to
 153 the database.  Its value may contain:
 154
 155 =over
 156
 157 =item a scalar
 158
 159 This contains one SQL statement to execute.
 160
 161 =item an array reference
 162
 163 This contains SQL statements to execute in order.  Each element contains
 164 a string or a code reference that returns a string.
 165
 166 =item a code reference
 167
 168 This contains some code to execute.  Unlike code references within an
 169 array reference, its return value is ignored.
 170
 171 =back
 172
 173 =item on_disconnect_do
 174
 175 Takes arguments in the same form as L</on_connect_do> and executes them
 176 immediately before disconnecting from the database.
 177
 178 Note, this only runs if you explicitly call L</disconnect> on the
 179 storage object.
 180
 181 =item disable_sth_caching
 182
 183 If set to a true value, this option will disable the caching of
 184 statement handles via L<DBI/prepare_cached>.
 185
 186 =item limit_dialect
 187
 188 Sets the limit dialect. This is useful for JDBC-bridge among others
 189 where the remote SQL-dialect cannot be determined by the name of the
 190 driver alone. See also L<SQL::Abstract::Limit>.
 191
 192 =item quote_char
 193
 194 Specifies what characters to use to quote table and column names. If
 195 you use this you will want to specify L</name_sep> as well.
 196
 197 C<quote_char> expects either a single character, in which case is it
 198 is placed on either side of the table/column name, or an arrayref of length
 199 2 in which case the table/column name is placed between the elements.
 200
 201 For example under MySQL you should use C<< quote_char => '`' >>, and for
 202 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 203
 204 =item name_sep
 205
 206 This only needs to be used in conjunction with C<quote_char>, and is used to
 207 specify the charecter that seperates elements (schemas, tables, columns) from
 208 each other. In most cases this is simply a C<.>.
 209
 210 The consequences of not supplying this value is that L<SQL::Abstract>
 211 will assume DBIx::Class' uses of aliases to be complete column
 212 names. The output will look like I<"me.name"> when it should actually
 213 be I<"me"."name">.
 214
 215 =item unsafe
 216
 217 This Storage driver normally installs its own C<HandleError>, sets
 218 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 219 all database handles, including those supplied by a coderef.  It does this
 220 so that it can have consistent and useful error behavior.
 221
 222 If you set this option to a true value, Storage will not do its usual
 223 modifications to the database handle's attributes, and instead relies on
 224 the settings in your connect_info DBI options (or the values you set in
 225 your connection coderef, in the case that you are connecting via coderef).
 226
 227 Note that your custom settings can cause Storage to malfunction,
 228 especially if you set a C<HandleError> handler that suppresses exceptions
 229 and/or disable C<RaiseError>.
 230
 231 =item auto_savepoint
 232
 233 If this option is true, L<DBIx::Class> will use savepoints when nesting
 234 transactions, making it possible to recover from failure in the inner
 235 transaction without having to abort all outer transactions.
 236
 237 =item cursor_class
 238
 239 Use this argument to supply a cursor class other than the default
 240 L<DBIx::Class::Storage::DBI::Cursor>.
 241
 242 =back
 243
 244 Some real-life examples of arguments to L</connect_info> and
 245 L<DBIx::Class::Schema/connect>
 246
 247   # Simple SQLite connection
 248   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 249
 250   # Connect via subref
 251   ->connect_info([ sub { DBI->connect(...) } ]);
 252
 253   # A bit more complicated
 254   ->connect_info(
 255     [
 256       'dbi:Pg:dbname=foo',
 257       'postgres',
 258       'my_pg_password',
 259       { AutoCommit => 1 },
 260       { quote_char => q{"}, name_sep => q{.} },
 261     ]
 262   );
 263
 264   # Equivalent to the previous example
 265   ->connect_info(
 266     [
 267       'dbi:Pg:dbname=foo',
 268       'postgres',
 269       'my_pg_password',
 270       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 271     ]
 272   );
 273
 274   # Same, but with hashref as argument
 275   # See parse_connect_info for explanation
 276   ->connect_info(
 277     [{
 278       dsn         => 'dbi:Pg:dbname=foo',
 279       user        => 'postgres',
 280       password    => 'my_pg_password',
 281       AutoCommit  => 1,
 282       quote_char  => q{"},
 283       name_sep    => q{.},
 284     }]
 285   );
 286
 287   # Subref + DBIx::Class-specific connection options
 288   ->connect_info(
 289     [
 290       sub { DBI->connect(...) },
 291       {
 292           quote_char => q{`},
 293           name_sep => q{@},
 294           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 295           disable_sth_caching => 1,
 296       },
 297     ]
 298   );
 299
 300
 301
 302 =cut
 303
 304 sub connect_info {
 305   my ($self, $info_arg) = @_;
 306
 307   return $self->_connect_info if !$info_arg;
 308
 309   my @args = @$info_arg;  # take a shallow copy for further mutilation
 310   $self->_connect_info([@args]); # copy for _connect_info
 311
 312
 313   # combine/pre-parse arguments depending on invocation style
 314
 315   my %attrs;
 316   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 317     %attrs = %{ $args[1] || {} };
 318     @args = $args[0];
 319   }
 320   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 321     %attrs = %{$args[0]};
 322     @args = ();
 323     for (qw/password user dsn/) {
 324       unshift @args, delete $attrs{$_};
 325     }
 326   }
 327   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 328     %attrs = (
 329       % { $args[3] || {} },
 330       % { $args[4] || {} },
 331     );
 332     @args = @args[0,1,2];
 333   }
 334
 335   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 336   #  the new set of options
 337   $self->_sql_maker(undef);
 338   $self->_sql_maker_opts({});
 339
 340   if(keys %attrs) {
 341     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 342       if(my $value = delete $attrs{$storage_opt}) {
 343         $self->$storage_opt($value);
 344       }
 345     }
 346     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 347       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 348         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 349       }
 350     }
 351   }
 352
 353   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 354
 355   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 356   $self->_connect_info;
 357 }
 358
 359 =head2 on_connect_do
 360
 361 This method is deprecated in favour of setting via L</connect_info>.
 362
 363
 364 =head2 dbh_do
 365
 366 Arguments: ($subref | $method_name), @extra_coderef_args?
 367
 368 Execute the given $subref or $method_name using the new exception-based
 369 connection management.
 370
 371 The first two arguments will be the storage object that C<dbh_do> was called
 372 on and a database handle to use.  Any additional arguments will be passed
 373 verbatim to the called subref as arguments 2 and onwards.
 374
 375 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 376 exception handling and reconnection (or failover in future subclasses).
 377
 378 Your subref should have no side-effects outside of the database, as
 379 there is the potential for your subref to be partially double-executed
 380 if the database connection was stale/dysfunctional.
 381
 382 Example:
 383
 384   my @stuff = $schema->storage->dbh_do(
 385     sub {
 386       my ($storage, $dbh, @cols) = @_;
 387       my $cols = join(q{, }, @cols);
 388       $dbh->selectrow_array("SELECT $cols FROM foo");
 389     },
 390     @column_list
 391   );
 392
 393 =cut
 394
 395 sub dbh_do {
 396   my $self = shift;
 397   my $code = shift;
 398
 399   my $dbh = $self->_dbh;
 400
 401   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 402       || $self->{transaction_depth};
 403
 404   local $self->{_in_dbh_do} = 1;
 405
 406   my @result;
 407   my $want_array = wantarray;
 408
 409   eval {
 410     $self->_verify_pid if $dbh;
 411     if(!$self->_dbh) {
 412         $self->_populate_dbh;
 413         $dbh = $self->_dbh;
 414     }
 415
 416     if($want_array) {
 417         @result = $self->$code($dbh, @_);
 418     }
 419     elsif(defined $want_array) {
 420         $result[0] = $self->$code($dbh, @_);
 421     }
 422     else {
 423         $self->$code($dbh, @_);
 424     }
 425   };
 426
 427   my $exception = $@;
 428   if(!$exception) { return $want_array ? @result : $result[0] }
 429
 430   $self->throw_exception($exception) if $self->connected;
 431
 432   # We were not connected - reconnect and retry, but let any
 433   #  exception fall right through this time
 434   $self->_populate_dbh;
 435   $self->$code($self->_dbh, @_);
 436 }
 437
 438 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 439 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 440 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 441 sub txn_do {
 442   my $self = shift;
 443   my $coderef = shift;
 444
 445   ref $coderef eq 'CODE' or $self->throw_exception
 446     ('$coderef must be a CODE reference');
 447
 448   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 449
 450   local $self->{_in_dbh_do} = 1;
 451
 452   my @result;
 453   my $want_array = wantarray;
 454
 455   my $tried = 0;
 456   while(1) {
 457     eval {
 458       $self->_verify_pid if $self->_dbh;
 459       $self->_populate_dbh if !$self->_dbh;
 460
 461       $self->txn_begin;
 462       if($want_array) {
 463           @result = $coderef->(@_);
 464       }
 465       elsif(defined $want_array) {
 466           $result[0] = $coderef->(@_);
 467       }
 468       else {
 469           $coderef->(@_);
 470       }
 471       $self->txn_commit;
 472     };
 473
 474     my $exception = $@;
 475     if(!$exception) { return $want_array ? @result : $result[0] }
 476
 477     if($tried++ > 0 || $self->connected) {
 478       eval { $self->txn_rollback };
 479       my $rollback_exception = $@;
 480       if($rollback_exception) {
 481         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 482         $self->throw_exception($exception)  # propagate nested rollback
 483           if $rollback_exception =~ /$exception_class/;
 484
 485         $self->throw_exception(
 486           "Transaction aborted: ${exception}. "
 487           . "Rollback failed: ${rollback_exception}"
 488         );
 489       }
 490       $self->throw_exception($exception)
 491     }
 492
 493     # We were not connected, and was first try - reconnect and retry
 494     # via the while loop
 495     $self->_populate_dbh;
 496   }
 497 }
 498
 499 =head2 disconnect
 500
 501 Our C<disconnect> method also performs a rollback first if the
 502 database is not in C<AutoCommit> mode.
 503
 504 =cut
 505
 506 sub disconnect {
 507   my ($self) = @_;
 508
 509   if( $self->connected ) {
 510     my $connection_do = $self->on_disconnect_do;
 511     $self->_do_connection_actions($connection_do) if ref($connection_do);
 512
 513     $self->_dbh->rollback unless $self->_dbh_autocommit;
 514     $self->_dbh->disconnect;
 515     $self->_dbh(undef);
 516     $self->{_dbh_gen}++;
 517   }
 518 }
 519
 520 =head2 with_deferred_fk_checks
 521
 522 =over 4
 523
 524 =item Arguments: C<$coderef>
 525
 526 =item Return Value: The return value of $coderef
 527
 528 =back
 529
 530 Storage specific method to run the code ref with FK checks deferred or
 531 in MySQL's case disabled entirely.
 532
 533 =cut
 534
 535 # Storage subclasses should override this
 536 sub with_deferred_fk_checks {
 537   my ($self, $sub) = @_;
 538
 539   $sub->();
 540 }
 541
 542 sub connected {
 543   my ($self) = @_;
 544
 545   if(my $dbh = $self->_dbh) {
 546       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 547           $self->_dbh(undef);
 548           $self->{_dbh_gen}++;
 549           return;
 550       }
 551       else {
 552           $self->_verify_pid;
 553           return 0 if !$self->_dbh;
 554       }
 555       return ($dbh->FETCH('Active') && $dbh->ping);
 556   }
 557
 558   return 0;
 559 }
 560
 561 # handle pid changes correctly
 562 #  NOTE: assumes $self->_dbh is a valid $dbh
 563 sub _verify_pid {
 564   my ($self) = @_;
 565
 566   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 567
 568   $self->_dbh->{InactiveDestroy} = 1;
 569   $self->_dbh(undef);
 570   $self->{_dbh_gen}++;
 571
 572   return;
 573 }
 574
 575 sub ensure_connected {
 576   my ($self) = @_;
 577
 578   unless ($self->connected) {
 579     $self->_populate_dbh;
 580   }
 581 }
 582
 583 =head2 dbh
 584
 585 Returns the dbh - a data base handle of class L<DBI>.
 586
 587 =cut
 588
 589 sub dbh {
 590   my ($self) = @_;
 591
 592   $self->ensure_connected;
 593   return $self->_dbh;
 594 }
 595
 596 sub _sql_maker_args {
 597     my ($self) = @_;
 598
 599     return ( bindtype=>'columns', array_datatypes => 1, limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 600 }
 601
 602 sub sql_maker {
 603   my ($self) = @_;
 604   unless ($self->_sql_maker) {
 605     my $sql_maker_class = $self->sql_maker_class;
 606     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 607   }
 608   return $self->_sql_maker;
 609 }
 610
 611 sub _rebless {}
 612
 613 sub _populate_dbh {
 614   my ($self) = @_;
 615   my @info = @{$self->_dbi_connect_info || []};
 616   $self->_dbh($self->_connect(@info));
 617
 618   $self->_conn_pid($$);
 619   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 620
 621   $self->_determine_driver;
 622
 623   # Always set the transaction depth on connect, since
 624   #  there is no transaction in progress by definition
 625   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 626
 627   my $connection_do = $self->on_connect_do;
 628   $self->_do_connection_actions($connection_do) if $connection_do;
 629 }
 630
 631 sub _determine_driver {
 632   my ($self) = @_;
 633
 634   if (ref $self eq 'DBIx::Class::Storage::DBI') {
 635     my $driver;
 636
 637     if ($self->_dbh) { # we are connected
 638       $driver = $self->_dbh->{Driver}{Name};
 639     } else {
 640       # try to use dsn to not require being connected, the driver may still
 641       # force a connection in _rebless to determine version
 642       ($driver) = $self->_dbi_connect_info->[0] =~ /dbi:([^:]+):/i;
 643     }
 644
 645     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 646       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 647       $self->_rebless();
 648     }
 649   }
 650 }
 651
 652 sub _do_connection_actions {
 653   my $self = shift;
 654   my $connection_do = shift;
 655
 656   if (!ref $connection_do) {
 657     $self->_do_query($connection_do);
 658   }
 659   elsif (ref $connection_do eq 'ARRAY') {
 660     $self->_do_query($_) foreach @$connection_do;
 661   }
 662   elsif (ref $connection_do eq 'CODE') {
 663     $connection_do->($self);
 664   }
 665   else {
 666     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref $connection_do) );
 667   }
 668
 669   return $self;
 670 }
 671
 672 sub _do_query {
 673   my ($self, $action) = @_;
 674
 675   if (ref $action eq 'CODE') {
 676     $action = $action->($self);
 677     $self->_do_query($_) foreach @$action;
 678   }
 679   else {
 680     # Most debuggers expect ($sql, @bind), so we need to exclude
 681     # the attribute hash which is the second argument to $dbh->do
 682     # furthermore the bind values are usually to be presented
 683     # as named arrayref pairs, so wrap those here too
 684     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 685     my $sql = shift @do_args;
 686     my $attrs = shift @do_args;
 687     my @bind = map { [ undef, $_ ] } @do_args;
 688
 689     $self->_query_start($sql, @bind);
 690     $self->_dbh->do($sql, $attrs, @do_args);
 691     $self->_query_end($sql, @bind);
 692   }
 693
 694   return $self;
 695 }
 696
 697 sub _connect {
 698   my ($self, @info) = @_;
 699
 700   $self->throw_exception("You failed to provide any connection info")
 701     if !@info;
 702
 703   my ($old_connect_via, $dbh);
 704
 705   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 706     $old_connect_via = $DBI::connect_via;
 707     $DBI::connect_via = 'connect';
 708   }
 709
 710   eval {
 711     if(ref $info[0] eq 'CODE') {
 712        $dbh = &{$info[0]}
 713     }
 714     else {
 715        $dbh = DBI->connect(@info);
 716     }
 717
 718     if($dbh && !$self->unsafe) {
 719       my $weak_self = $self;
 720       weaken($weak_self);
 721       $dbh->{HandleError} = sub {
 722           if ($weak_self) {
 723             $weak_self->throw_exception("DBI Exception: $_[0]");
 724           }
 725           else {
 726             croak ("DBI Exception: $_[0]");
 727           }
 728       };
 729       $dbh->{ShowErrorStatement} = 1;
 730       $dbh->{RaiseError} = 1;
 731       $dbh->{PrintError} = 0;
 732     }
 733   };
 734
 735   $DBI::connect_via = $old_connect_via if $old_connect_via;
 736
 737   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 738     if !$dbh || $@;
 739
 740   $self->_dbh_autocommit($dbh->{AutoCommit});
 741
 742   $dbh;
 743 }
 744
 745 sub svp_begin {
 746   my ($self, $name) = @_;
 747
 748   $name = $self->_svp_generate_name
 749     unless defined $name;
 750
 751   $self->throw_exception ("You can't use savepoints outside a transaction")
 752     if $self->{transaction_depth} == 0;
 753
 754   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 755     unless $self->can('_svp_begin');
 756
 757   push @{ $self->{savepoints} }, $name;
 758
 759   $self->debugobj->svp_begin($name) if $self->debug;
 760
 761   return $self->_svp_begin($name);
 762 }
 763
 764 sub svp_release {
 765   my ($self, $name) = @_;
 766
 767   $self->throw_exception ("You can't use savepoints outside a transaction")
 768     if $self->{transaction_depth} == 0;
 769
 770   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 771     unless $self->can('_svp_release');
 772
 773   if (defined $name) {
 774     $self->throw_exception ("Savepoint '$name' does not exist")
 775       unless grep { $_ eq $name } @{ $self->{savepoints} };
 776
 777     # Dig through the stack until we find the one we are releasing.  This keeps
 778     # the stack up to date.
 779     my $svp;
 780
 781     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
 782   } else {
 783     $name = pop @{ $self->{savepoints} };
 784   }
 785
 786   $self->debugobj->svp_release($name) if $self->debug;
 787
 788   return $self->_svp_release($name);
 789 }
 790
 791 sub svp_rollback {
 792   my ($self, $name) = @_;
 793
 794   $self->throw_exception ("You can't use savepoints outside a transaction")
 795     if $self->{transaction_depth} == 0;
 796
 797   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 798     unless $self->can('_svp_rollback');
 799
 800   if (defined $name) {
 801       # If they passed us a name, verify that it exists in the stack
 802       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
 803           $self->throw_exception("Savepoint '$name' does not exist!");
 804       }
 805
 806       # Dig through the stack until we find the one we are releasing.  This keeps
 807       # the stack up to date.
 808       while(my $s = pop(@{ $self->{savepoints} })) {
 809           last if($s eq $name);
 810       }
 811       # Add the savepoint back to the stack, as a rollback doesn't remove the
 812       # named savepoint, only everything after it.
 813       push(@{ $self->{savepoints} }, $name);
 814   } else {
 815       # We'll assume they want to rollback to the last savepoint
 816       $name = $self->{savepoints}->[-1];
 817   }
 818
 819   $self->debugobj->svp_rollback($name) if $self->debug;
 820
 821   return $self->_svp_rollback($name);
 822 }
 823
 824 sub _svp_generate_name {
 825     my ($self) = @_;
 826
 827     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
 828 }
 829
 830 sub txn_begin {
 831   my $self = shift;
 832   $self->ensure_connected();
 833   if($self->{transaction_depth} == 0) {
 834     $self->debugobj->txn_begin()
 835       if $self->debug;
 836     # this isn't ->_dbh-> because
 837     #  we should reconnect on begin_work
 838     #  for AutoCommit users
 839     $self->dbh->begin_work;
 840   } elsif ($self->auto_savepoint) {
 841     $self->svp_begin;
 842   }
 843   $self->{transaction_depth}++;
 844 }
 845
 846 sub txn_commit {
 847   my $self = shift;
 848   if ($self->{transaction_depth} == 1) {
 849     my $dbh = $self->_dbh;
 850     $self->debugobj->txn_commit()
 851       if ($self->debug);
 852     $dbh->commit;
 853     $self->{transaction_depth} = 0
 854       if $self->_dbh_autocommit;
 855   }
 856   elsif($self->{transaction_depth} > 1) {
 857     $self->{transaction_depth}--;
 858     $self->svp_release
 859       if $self->auto_savepoint;
 860   }
 861 }
 862
 863 sub txn_rollback {
 864   my $self = shift;
 865   my $dbh = $self->_dbh;
 866   eval {
 867     if ($self->{transaction_depth} == 1) {
 868       $self->debugobj->txn_rollback()
 869         if ($self->debug);
 870       $self->{transaction_depth} = 0
 871         if $self->_dbh_autocommit;
 872       $dbh->rollback;
 873     }
 874     elsif($self->{transaction_depth} > 1) {
 875       $self->{transaction_depth}--;
 876       if ($self->auto_savepoint) {
 877         $self->svp_rollback;
 878         $self->svp_release;
 879       }
 880     }
 881     else {
 882       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 883     }
 884   };
 885   if ($@) {
 886     my $error = $@;
 887     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 888     $error =~ /$exception_class/ and $self->throw_exception($error);
 889     # ensure that a failed rollback resets the transaction depth
 890     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 891     $self->throw_exception($error);
 892   }
 893 }
 894
 895 # This used to be the top-half of _execute.  It was split out to make it
 896 #  easier to override in NoBindVars without duping the rest.  It takes up
 897 #  all of _execute's args, and emits $sql, @bind.
 898 sub _prep_for_execute {
 899   my ($self, $op, $extra_bind, $ident, $args) = @_;
 900
 901   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 902     $ident = $ident->from();
 903   }
 904
 905   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 906
 907   unshift(@bind,
 908     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 909       if $extra_bind;
 910   return ($sql, \@bind);
 911 }
 912
 913 sub _fix_bind_params {
 914     my ($self, @bind) = @_;
 915
 916     ### Turn @bind from something like this:
 917     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
 918     ### to this:
 919     ###   ( "'1'", "'1'", "'3'" )
 920     return
 921         map {
 922             if ( defined( $_ && $_->[1] ) ) {
 923                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
 924             }
 925             else { q{'NULL'}; }
 926         } @bind;
 927 }
 928
 929 sub _flatten_bind_params {
 930     my ($self, @bind) = @_;
 931
 932     ### Turn @bind from something like this:
 933     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
 934     ### to this:
 935     ###   ( 1, 1, 3 )
 936     return
 937         map {
 938             if ( defined( $_ && $_->[1] ) ) {
 939                 @{$_}[ 1 .. $#$_ ];
 940             }
 941             else { undef; }
 942         } @bind;
 943 }
 944
 945 sub _query_start {
 946     my ( $self, $sql, @bind ) = @_;
 947
 948     if ( $self->debug ) {
 949         @bind = $self->_fix_bind_params(@bind);
 950
 951         $self->debugobj->query_start( $sql, @bind );
 952     }
 953 }
 954
 955 sub _query_end {
 956     my ( $self, $sql, @bind ) = @_;
 957
 958     if ( $self->debug ) {
 959         @bind = $self->_fix_bind_params(@bind);
 960         $self->debugobj->query_end( $sql, @bind );
 961     }
 962 }
 963
 964 sub _dbh_execute {
 965   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 966
 967   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 968
 969   $self->_query_start( $sql, @$bind );
 970
 971   my $sth = $self->sth($sql,$op);
 972
 973   my $placeholder_index = 1;
 974
 975   foreach my $bound (@$bind) {
 976     my $attributes = {};
 977     my($column_name, @data) = @$bound;
 978
 979     if ($bind_attributes) {
 980       $attributes = $bind_attributes->{$column_name}
 981       if defined $bind_attributes->{$column_name};
 982     }
 983
 984     foreach my $data (@data) {
 985       my $ref = ref $data;
 986       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
 987
 988       $sth->bind_param($placeholder_index, $data, $attributes);
 989       $placeholder_index++;
 990     }
 991   }
 992
 993   # Can this fail without throwing an exception anyways???
 994   my $rv = $sth->execute();
 995   $self->throw_exception($sth->errstr) if !$rv;
 996
 997   $self->_query_end( $sql, @$bind );
 998
 999   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1000 }
1001
1002 sub _execute {
1003     my $self = shift;
1004     $self->dbh_do('_dbh_execute', @_)
1005 }
1006
1007 sub insert {
1008   my ($self, $source, $to_insert) = @_;
1009
1010   my $ident = $source->from;
1011   my $bind_attributes = $self->source_bind_attributes($source);
1012
1013   my $updated_cols = {};
1014
1015   $self->ensure_connected;
1016   foreach my $col ( $source->columns ) {
1017     if ( !defined $to_insert->{$col} ) {
1018       my $col_info = $source->column_info($col);
1019
1020       if ( $col_info->{auto_nextval} ) {
1021         $updated_cols->{$col} = $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1022       }
1023     }
1024   }
1025
1026   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1027
1028   return $updated_cols;
1029 }
1030
1031 ## Still not quite perfect, and EXPERIMENTAL
1032 ## Currently it is assumed that all values passed will be "normal", i.e. not
1033 ## scalar refs, or at least, all the same type as the first set, the statement is
1034 ## only prepped once.
1035 sub insert_bulk {
1036   my ($self, $source, $cols, $data) = @_;
1037   my %colvalues;
1038   my $table = $source->from;
1039   @colvalues{@$cols} = (0..$#$cols);
1040   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1041
1042   $self->_query_start( $sql, @bind );
1043   my $sth = $self->sth($sql);
1044
1045 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1046
1047   ## This must be an arrayref, else nothing works!
1048   my $tuple_status = [];
1049
1050   ## Get the bind_attributes, if any exist
1051   my $bind_attributes = $self->source_bind_attributes($source);
1052
1053   ## Bind the values and execute
1054   my $placeholder_index = 1;
1055
1056   foreach my $bound (@bind) {
1057
1058     my $attributes = {};
1059     my ($column_name, $data_index) = @$bound;
1060
1061     if( $bind_attributes ) {
1062       $attributes = $bind_attributes->{$column_name}
1063       if defined $bind_attributes->{$column_name};
1064     }
1065
1066     my @data = map { $_->[$data_index] } @$data;
1067
1068     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1069     $placeholder_index++;
1070   }
1071   my $rv = eval { $sth->execute_array({ArrayTupleStatus => $tuple_status}) };
1072   if (my $err = $@) {
1073     my $i = 0;
1074     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1075
1076     $self->throw_exception($sth->errstr || "Unexpected populate error: $err")
1077       if ($i > $#$tuple_status);
1078
1079     require Data::Dumper;
1080     local $Data::Dumper::Terse = 1;
1081     local $Data::Dumper::Indent = 1;
1082     local $Data::Dumper::Useqq = 1;
1083     local $Data::Dumper::Quotekeys = 0;
1084
1085     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1086       $tuple_status->[$i][1],
1087       Data::Dumper::Dumper(
1088         { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) }
1089       ),
1090     );
1091   }
1092   $self->throw_exception($sth->errstr) if !$rv;
1093
1094   $self->_query_end( $sql, @bind );
1095   return (wantarray ? ($rv, $sth, @bind) : $rv);
1096 }
1097
1098 sub update {
1099   my $self = shift @_;
1100   my $source = shift @_;
1101   my $bind_attributes = $self->source_bind_attributes($source);
1102
1103   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1104 }
1105
1106
1107 sub delete {
1108   my $self = shift @_;
1109   my $source = shift @_;
1110
1111   my $bind_attrs = {}; ## If ever it's needed...
1112
1113   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1114 }
1115
1116 # We were sent here because the $rs contains a complex search
1117 # which will require a subquery to select the correct rows
1118 # (i.e. joined or limited resultsets)
1119 #
1120 # Genarating a single PK column subquery is trivial and supported
1121 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1122 # Look at _multipk_update_delete()
1123 sub subq_update_delete {
1124   my $self = shift;
1125   my ($rs, $op, $values) = @_;
1126
1127   my $rsrc = $rs->result_source;
1128
1129   # we already check this, but double check naively just in case. Should be removed soon
1130   my $sel = $rs->_resolved_attrs->{select};
1131   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1132   my @pcols = $rsrc->primary_columns;
1133   if (@$sel != @pcols) {
1134     $self->throw_exception (
1135       'Subquery update/delete can not be called on resultsets selecting a'
1136      .' number of columns different than the number of primary keys'
1137     );
1138   }
1139
1140   if (@pcols == 1) {
1141     return $self->$op (
1142       $rsrc,
1143       $op eq 'update' ? $values : (),
1144       { $pcols[0] => { -in => $rs->as_query } },
1145     );
1146   }
1147
1148   else {
1149     return $self->_multipk_update_delete (@_);
1150   }
1151 }
1152
1153 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1154 # resultset update/delete involving subqueries. So by default resort
1155 # to simple (and inefficient) delete_all style per-row opearations,
1156 # while allowing specific storages to override this with a faster
1157 # implementation.
1158 #
1159 sub _multipk_update_delete {
1160   return shift->_per_row_update_delete (@_);
1161 }
1162
1163 # This is the default loop used to delete/update rows for multi PK
1164 # resultsets, and used by mysql exclusively (because it can't do anything
1165 # else).
1166 #
1167 # We do not use $row->$op style queries, because resultset update/delete
1168 # is not expected to cascade (this is what delete_all/update_all is for).
1169 #
1170 # There should be no race conditions as the entire operation is rolled
1171 # in a transaction.
1172 #
1173 sub _per_row_update_delete {
1174   my $self = shift;
1175   my ($rs, $op, $values) = @_;
1176
1177   my $rsrc = $rs->result_source;
1178   my @pcols = $rsrc->primary_columns;
1179
1180   my $guard = $self->txn_scope_guard;
1181
1182   # emulate the return value of $sth->execute for non-selects
1183   my $row_cnt = '0E0';
1184
1185   my $subrs_cur = $rs->cursor;
1186   while (my @pks = $subrs_cur->next) {
1187
1188     my $cond;
1189     for my $i (0.. $#pcols) {
1190       $cond->{$pcols[$i]} = $pks[$i];
1191     }
1192
1193     $self->$op (
1194       $rsrc,
1195       $op eq 'update' ? $values : (),
1196       $cond,
1197     );
1198
1199     $row_cnt++;
1200   }
1201
1202   $guard->commit;
1203
1204   return $row_cnt;
1205 }
1206
1207 sub _select {
1208   my $self = shift;
1209   my $sql_maker = $self->sql_maker;
1210   local $sql_maker->{for};
1211   return $self->_execute($self->_select_args(@_));
1212 }
1213
1214 sub _select_args {
1215   my ($self, $ident, $select, $condition, $attrs) = @_;
1216   my $order = $attrs->{order_by};
1217
1218   my $for = delete $attrs->{for};
1219   my $sql_maker = $self->sql_maker;
1220   $sql_maker->{for} = $for;
1221
1222   my @in_order_attrs = qw/group_by having _virtual_order_by/;
1223   if (List::Util::first { exists $attrs->{$_} } (@in_order_attrs) ) {
1224     $order = {
1225       ($order
1226         ? (order_by => $order)
1227         : ()
1228       ),
1229       ( map { $_ => $attrs->{$_} } (@in_order_attrs) )
1230     };
1231   }
1232   my $bind_attrs = {}; ## Future support
1233   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1234   if ($attrs->{software_limit} ||
1235       $sql_maker->_default_limit_syntax eq "GenericSubQ") {
1236         $attrs->{software_limit} = 1;
1237   } else {
1238     $self->throw_exception("rows attribute must be positive if present")
1239       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1240
1241     # MySQL actually recommends this approach.  I cringe.
1242     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1243     push @args, $attrs->{rows}, $attrs->{offset};
1244   }
1245   return @args;
1246 }
1247
1248 sub _trim_attributes_for_count {
1249   my ($self, $source, $attrs) = @_;
1250   my %attrs = %$attrs;
1251
1252   # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1253   delete $attrs{$_} for (qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1254
1255   return \%attrs;
1256 }
1257
1258 sub count {
1259   my ($self, $source, $attrs) = @_;
1260
1261   my $new_attrs = $self->_trim_attributes_for_count($source, $attrs);
1262
1263   $new_attrs->{select} = { count => '*' };
1264   $new_attrs->{as} = [qw/count/];
1265
1266   my $tmp_rs = $source->resultset_class->new($source, $new_attrs);
1267   my ($count) = $tmp_rs->cursor->next;
1268
1269   return $count;
1270 }
1271
1272 sub source_bind_attributes {
1273   my ($self, $source) = @_;
1274
1275   my $bind_attributes;
1276   foreach my $column ($source->columns) {
1277
1278     my $data_type = $source->column_info($column)->{data_type} || '';
1279     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1280      if $data_type;
1281   }
1282
1283   return $bind_attributes;
1284 }
1285
1286 =head2 select
1287
1288 =over 4
1289
1290 =item Arguments: $ident, $select, $condition, $attrs
1291
1292 =back
1293
1294 Handle a SQL select statement.
1295
1296 =cut
1297
1298 sub select {
1299   my $self = shift;
1300   my ($ident, $select, $condition, $attrs) = @_;
1301   return $self->cursor_class->new($self, \@_, $attrs);
1302 }
1303
1304 sub select_single {
1305   my $self = shift;
1306   my ($rv, $sth, @bind) = $self->_select(@_);
1307   my @row = $sth->fetchrow_array;
1308   my @nextrow = $sth->fetchrow_array if @row;
1309   if(@row && @nextrow) {
1310     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1311   }
1312   # Need to call finish() to work round broken DBDs
1313   $sth->finish();
1314   return @row;
1315 }
1316
1317 =head2 sth
1318
1319 =over 4
1320
1321 =item Arguments: $sql
1322
1323 =back
1324
1325 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1326
1327 =cut
1328
1329 sub _dbh_sth {
1330   my ($self, $dbh, $sql) = @_;
1331
1332   # 3 is the if_active parameter which avoids active sth re-use
1333   my $sth = $self->disable_sth_caching
1334     ? $dbh->prepare($sql)
1335     : $dbh->prepare_cached($sql, {}, 3);
1336
1337   # XXX You would think RaiseError would make this impossible,
1338   #  but apparently that's not true :(
1339   $self->throw_exception($dbh->errstr) if !$sth;
1340
1341   $sth;
1342 }
1343
1344 sub sth {
1345   my ($self, $sql) = @_;
1346   $self->dbh_do('_dbh_sth', $sql);
1347 }
1348
1349 sub _dbh_columns_info_for {
1350   my ($self, $dbh, $table) = @_;
1351
1352   if ($dbh->can('column_info')) {
1353     my %result;
1354     eval {
1355       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1356       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1357       $sth->execute();
1358       while ( my $info = $sth->fetchrow_hashref() ){
1359         my %column_info;
1360         $column_info{data_type}   = $info->{TYPE_NAME};
1361         $column_info{size}      = $info->{COLUMN_SIZE};
1362         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1363         $column_info{default_value} = $info->{COLUMN_DEF};
1364         my $col_name = $info->{COLUMN_NAME};
1365         $col_name =~ s/^\"(.*)\"$/$1/;
1366
1367         $result{$col_name} = \%column_info;
1368       }
1369     };
1370     return \%result if !$@ && scalar keys %result;
1371   }
1372
1373   my %result;
1374   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1375   $sth->execute;
1376   my @columns = @{$sth->{NAME_lc}};
1377   for my $i ( 0 .. $#columns ){
1378     my %column_info;
1379     $column_info{data_type} = $sth->{TYPE}->[$i];
1380     $column_info{size} = $sth->{PRECISION}->[$i];
1381     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1382
1383     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1384       $column_info{data_type} = $1;
1385       $column_info{size}    = $2;
1386     }
1387
1388     $result{$columns[$i]} = \%column_info;
1389   }
1390   $sth->finish;
1391
1392   foreach my $col (keys %result) {
1393     my $colinfo = $result{$col};
1394     my $type_num = $colinfo->{data_type};
1395     my $type_name;
1396     if(defined $type_num && $dbh->can('type_info')) {
1397       my $type_info = $dbh->type_info($type_num);
1398       $type_name = $type_info->{TYPE_NAME} if $type_info;
1399       $colinfo->{data_type} = $type_name if $type_name;
1400     }
1401   }
1402
1403   return \%result;
1404 }
1405
1406 sub columns_info_for {
1407   my ($self, $table) = @_;
1408   $self->dbh_do('_dbh_columns_info_for', $table);
1409 }
1410
1411 =head2 last_insert_id
1412
1413 Return the row id of the last insert.
1414
1415 =cut
1416
1417 sub _dbh_last_insert_id {
1418     # All Storage's need to register their own _dbh_last_insert_id
1419     # the old SQLite-based method was highly inappropriate
1420
1421     my $self = shift;
1422     my $class = ref $self;
1423     $self->throw_exception (<<EOE);
1424
1425 No _dbh_last_insert_id() method found in $class.
1426 Since the method of obtaining the autoincrement id of the last insert
1427 operation varies greatly between different databases, this method must be
1428 individually implemented for every storage class.
1429 EOE
1430 }
1431
1432 sub last_insert_id {
1433   my $self = shift;
1434   $self->dbh_do('_dbh_last_insert_id', @_);
1435 }
1436
1437 =head2 sqlt_type
1438
1439 Returns the database driver name.
1440
1441 =cut
1442
1443 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1444
1445 =head2 bind_attribute_by_data_type
1446
1447 Given a datatype from column info, returns a database specific bind
1448 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
1449 let the database planner just handle it.
1450
1451 Generally only needed for special case column types, like bytea in postgres.
1452
1453 =cut
1454
1455 sub bind_attribute_by_data_type {
1456     return;
1457 }
1458
1459 =head2 create_ddl_dir (EXPERIMENTAL)
1460
1461 =over 4
1462
1463 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1464
1465 =back
1466
1467 Creates a SQL file based on the Schema, for each of the specified
1468 database engines in C<\@databases> in the given directory.
1469 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
1470
1471 Given a previous version number, this will also create a file containing
1472 the ALTER TABLE statements to transform the previous schema into the
1473 current one. Note that these statements may contain C<DROP TABLE> or
1474 C<DROP COLUMN> statements that can potentially destroy data.
1475
1476 The file names are created using the C<ddl_filename> method below, please
1477 override this method in your schema if you would like a different file
1478 name format. For the ALTER file, the same format is used, replacing
1479 $version in the name with "$preversion-$version".
1480
1481 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
1482 The most common value for this would be C<< { add_drop_table => 1 } >>
1483 to have the SQL produced include a C<DROP TABLE> statement for each table
1484 created. For quoting purposes supply C<quote_table_names> and
1485 C<quote_field_names>.
1486
1487 If no arguments are passed, then the following default values are assumed:
1488
1489 =over 4
1490
1491 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
1492
1493 =item version    - $schema->schema_version
1494
1495 =item directory  - './'
1496
1497 =item preversion - <none>
1498
1499 =back
1500
1501 By default, C<\%sqlt_args> will have
1502
1503  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1504
1505 merged with the hash passed in. To disable any of those features, pass in a
1506 hashref like the following
1507
1508  { ignore_constraint_names => 0, # ... other options }
1509
1510
1511 Note that this feature is currently EXPERIMENTAL and may not work correctly
1512 across all databases, or fully handle complex relationships.
1513
1514 WARNING: Please check all SQL files created, before applying them.
1515
1516 =cut
1517
1518 sub create_ddl_dir {
1519   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1520
1521   if(!$dir || !-d $dir) {
1522     carp "No directory given, using ./\n";
1523     $dir = "./";
1524   }
1525   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1526   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1527
1528   my $schema_version = $schema->schema_version || '1.x';
1529   $version ||= $schema_version;
1530
1531   $sqltargs = {
1532     add_drop_table => 1,
1533     ignore_constraint_names => 1,
1534     ignore_index_names => 1,
1535     %{$sqltargs || {}}
1536   };
1537
1538   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09003: '}
1539       . $self->_check_sqlt_message . q{'})
1540           if !$self->_check_sqlt_version;
1541
1542   my $sqlt = SQL::Translator->new( $sqltargs );
1543
1544   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1545   my $sqlt_schema = $sqlt->translate({ data => $schema })
1546     or $self->throw_exception ($sqlt->error);
1547
1548   foreach my $db (@$databases) {
1549     $sqlt->reset();
1550     $sqlt->{schema} = $sqlt_schema;
1551     $sqlt->producer($db);
1552
1553     my $file;
1554     my $filename = $schema->ddl_filename($db, $version, $dir);
1555     if (-e $filename && ($version eq $schema_version )) {
1556       # if we are dumping the current version, overwrite the DDL
1557       carp "Overwriting existing DDL file - $filename";
1558       unlink($filename);
1559     }
1560
1561     my $output = $sqlt->translate;
1562     if(!$output) {
1563       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1564       next;
1565     }
1566     if(!open($file, ">$filename")) {
1567       $self->throw_exception("Can't open $filename for writing ($!)");
1568       next;
1569     }
1570     print $file $output;
1571     close($file);
1572
1573     next unless ($preversion);
1574
1575     require SQL::Translator::Diff;
1576
1577     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1578     if(!-e $prefilename) {
1579       carp("No previous schema file found ($prefilename)");
1580       next;
1581     }
1582
1583     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1584     if(-e $difffile) {
1585       carp("Overwriting existing diff file - $difffile");
1586       unlink($difffile);
1587     }
1588
1589     my $source_schema;
1590     {
1591       my $t = SQL::Translator->new($sqltargs);
1592       $t->debug( 0 );
1593       $t->trace( 0 );
1594
1595       $t->parser( $db )
1596         or $self->throw_exception ($t->error);
1597
1598       my $out = $t->translate( $prefilename )
1599         or $self->throw_exception ($t->error);
1600
1601       $source_schema = $t->schema;
1602
1603       $source_schema->name( $prefilename )
1604         unless ( $source_schema->name );
1605     }
1606
1607     # The "new" style of producers have sane normalization and can support
1608     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1609     # And we have to diff parsed SQL against parsed SQL.
1610     my $dest_schema = $sqlt_schema;
1611
1612     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1613       my $t = SQL::Translator->new($sqltargs);
1614       $t->debug( 0 );
1615       $t->trace( 0 );
1616
1617       $t->parser( $db )
1618         or $self->throw_exception ($t->error);
1619
1620       my $out = $t->translate( $filename )
1621         or $self->throw_exception ($t->error);
1622
1623       $dest_schema = $t->schema;
1624
1625       $dest_schema->name( $filename )
1626         unless $dest_schema->name;
1627     }
1628
1629     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1630                                                   $dest_schema,   $db,
1631                                                   $sqltargs
1632                                                  );
1633     if(!open $file, ">$difffile") {
1634       $self->throw_exception("Can't write to $difffile ($!)");
1635       next;
1636     }
1637     print $file $diff;
1638     close($file);
1639   }
1640 }
1641
1642 =head2 deployment_statements
1643
1644 =over 4
1645
1646 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1647
1648 =back
1649
1650 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1651
1652 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
1653 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
1654
1655 C<$directory> is used to return statements from files in a previously created
1656 L</create_ddl_dir> directory and is optional. The filenames are constructed
1657 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1658
1659 If no C<$directory> is specified then the statements are constructed on the
1660 fly using L<SQL::Translator> and C<$version> is ignored.
1661
1662 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1663
1664 =cut
1665
1666 sub deployment_statements {
1667   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1668   # Need to be connected to get the correct sqlt_type
1669   $self->ensure_connected() unless $type;
1670   $type ||= $self->sqlt_type;
1671   $version ||= $schema->schema_version || '1.x';
1672   $dir ||= './';
1673   my $filename = $schema->ddl_filename($type, $version, $dir);
1674   if(-f $filename)
1675   {
1676       my $file;
1677       open($file, "<$filename")
1678         or $self->throw_exception("Can't open $filename ($!)");
1679       my @rows = <$file>;
1680       close($file);
1681       return join('', @rows);
1682   }
1683
1684   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09003: '}
1685       . $self->_check_sqlt_message . q{'})
1686           if !$self->_check_sqlt_version;
1687
1688   require SQL::Translator::Parser::DBIx::Class;
1689   eval qq{use SQL::Translator::Producer::${type}};
1690   $self->throw_exception($@) if $@;
1691
1692   # sources needs to be a parser arg, but for simplicty allow at top level
1693   # coming in
1694   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1695       if exists $sqltargs->{sources};
1696
1697   my $tr = SQL::Translator->new(%$sqltargs);
1698   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1699   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1700 }
1701
1702 sub deploy {
1703   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1704   my $deploy = sub {
1705     my $line = shift;
1706     return if($line =~ /^--/);
1707     return if(!$line);
1708     # next if($line =~ /^DROP/m);
1709     return if($line =~ /^BEGIN TRANSACTION/m);
1710     return if($line =~ /^COMMIT/m);
1711     return if $line =~ /^\s+$/; # skip whitespace only
1712     $self->_query_start($line);
1713     eval {
1714       $self->dbh->do($line); # shouldn't be using ->dbh ?
1715     };
1716     if ($@) {
1717       carp qq{$@ (running "${line}")};
1718     }
1719     $self->_query_end($line);
1720   };
1721   my @statements = $self->deployment_statements($schema, $type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
1722   if (@statements > 1) {
1723     foreach my $statement (@statements) {
1724       $deploy->( $statement );
1725     }
1726   }
1727   elsif (@statements == 1) {
1728     foreach my $line ( split(";\n", $statements[0])) {
1729       $deploy->( $line );
1730     }
1731   }
1732 }
1733
1734 =head2 datetime_parser
1735
1736 Returns the datetime parser class
1737
1738 =cut
1739
1740 sub datetime_parser {
1741   my $self = shift;
1742   return $self->{datetime_parser} ||= do {
1743     $self->ensure_connected;
1744     $self->build_datetime_parser(@_);
1745   };
1746 }
1747
1748 =head2 datetime_parser_type
1749
1750 Defines (returns) the datetime parser class - currently hardwired to
1751 L<DateTime::Format::MySQL>
1752
1753 =cut
1754
1755 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1756
1757 =head2 build_datetime_parser
1758
1759 See L</datetime_parser>
1760
1761 =cut
1762
1763 sub build_datetime_parser {
1764   my $self = shift;
1765   my $type = $self->datetime_parser_type(@_);
1766   eval "use ${type}";
1767   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1768   return $type;
1769 }
1770
1771 {
1772     my $_check_sqlt_version; # private
1773     my $_check_sqlt_message; # private
1774     sub _check_sqlt_version {
1775         return $_check_sqlt_version if defined $_check_sqlt_version;
1776         eval 'use SQL::Translator "0.09003"';
1777         $_check_sqlt_message = $@ || '';
1778         $_check_sqlt_version = !$@;
1779     }
1780
1781     sub _check_sqlt_message {
1782         _check_sqlt_version if !defined $_check_sqlt_message;
1783         $_check_sqlt_message;
1784     }
1785 }
1786
1787 =head2 is_replicating
1788
1789 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1790 replicate from a master database.  Default is undef, which is the result
1791 returned by databases that don't support replication.
1792
1793 =cut
1794
1795 sub is_replicating {
1796     return;
1797
1798 }
1799
1800 =head2 lag_behind_master
1801
1802 Returns a number that represents a certain amount of lag behind a master db
1803 when a given storage is replicating.  The number is database dependent, but
1804 starts at zero and increases with the amount of lag. Default in undef
1805
1806 =cut
1807
1808 sub lag_behind_master {
1809     return;
1810 }
1811
1812 sub DESTROY {
1813   my $self = shift;
1814   return if !$self->_dbh;
1815   $self->_verify_pid;
1816   $self->_dbh(undef);
1817 }
1818
1819 1;
1820
1821 =head1 USAGE NOTES
1822
1823 =head2 DBIx::Class and AutoCommit
1824
1825 DBIx::Class can do some wonderful magic with handling exceptions,
1826 disconnections, and transactions when you use C<< AutoCommit => 1 >>
1827 combined with C<txn_do> for transaction support.
1828
1829 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
1830 in an assumed transaction between commits, and you're telling us you'd
1831 like to manage that manually.  A lot of the magic protections offered by
1832 this module will go away.  We can't protect you from exceptions due to database
1833 disconnects because we don't know anything about how to restart your
1834 transactions.  You're on your own for handling all sorts of exceptional
1835 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
1836 be with raw DBI.
1837
1838
1839
1840 =head1 AUTHORS
1841
1842 Matt S. Trout <mst@shadowcatsystems.co.uk>
1843
1844 Andy Grundman <andy@hybridized.org>
1845
1846 =head1 LICENSE
1847
1848 You may distribute this code under the same terms as Perl itself.
1849
1850 =cut