lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util qw/blessed weaken/;
  13
  14 __PACKAGE__->mk_group_accessors('simple' =>
  15     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  16        _conn_pid _conn_tid disable_sth_caching on_connect_do
  17        on_disconnect_do transaction_depth unsafe _dbh_autocommit/
  18 );
  19
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  23 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  24
  25 BEGIN {
  26
  27 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  28
  29 use base qw/SQL::Abstract::Limit/;
  30
  31 # This prevents the caching of $dbh in S::A::L, I believe
  32 sub new {
  33   my $self = shift->SUPER::new(@_);
  34
  35   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  36   #   it with what it resolves to:
  37   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  38     if ref $self->{limit_dialect};
  39
  40   $self;
  41 }
  42
  43 sub _RowNumberOver {
  44   my ($self, $sql, $order, $rows, $offset ) = @_;
  45
  46   $offset += 1;
  47   my $last = $rows + $offset;
  48   my ( $order_by ) = $self->_order_by( $order );
  49
  50   $sql = <<"";
  51 SELECT * FROM
  52 (
  53    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  54       $sql
  55       $order_by
  56    ) Q1
  57 ) Q2
  58 WHERE ROW_NUM BETWEEN $offset AND $last
  59
  60   return $sql;
  61 }
  62
  63
  64 # While we're at it, this should make LIMIT queries more efficient,
  65 #  without digging into things too deeply
  66 use Scalar::Util 'blessed';
  67 sub _find_syntax {
  68   my ($self, $syntax) = @_;
  69   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  70   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  71     return 'RowNumberOver';
  72   }
  73
  74   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  75 }
  76
  77 sub select {
  78   my ($self, $table, $fields, $where, $order, @rest) = @_;
  79   $table = $self->_quote($table) unless ref($table);
  80   local $self->{rownum_hack_count} = 1
  81     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  82   @rest = (-1) unless defined $rest[0];
  83   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  84     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  85   local $self->{having_bind} = [];
  86   my ($sql, @ret) = $self->SUPER::select(
  87     $table, $self->_recurse_fields($fields), $where, $order, @rest
  88   );
  89   $sql .=
  90     $self->{for} ?
  91     (
  92       $self->{for} eq 'update' ? ' FOR UPDATE' :
  93       $self->{for} eq 'shared' ? ' FOR SHARE'  :
  94       ''
  95     ) :
  96     ''
  97   ;
  98   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  99 }
 100
 101 sub insert {
 102   my $self = shift;
 103   my $table = shift;
 104   $table = $self->_quote($table) unless ref($table);
 105   $self->SUPER::insert($table, @_);
 106 }
 107
 108 sub update {
 109   my $self = shift;
 110   my $table = shift;
 111   $table = $self->_quote($table) unless ref($table);
 112   $self->SUPER::update($table, @_);
 113 }
 114
 115 sub delete {
 116   my $self = shift;
 117   my $table = shift;
 118   $table = $self->_quote($table) unless ref($table);
 119   $self->SUPER::delete($table, @_);
 120 }
 121
 122 sub _emulate_limit {
 123   my $self = shift;
 124   if ($_[3] == -1) {
 125     return $_[1].$self->_order_by($_[2]);
 126   } else {
 127     return $self->SUPER::_emulate_limit(@_);
 128   }
 129 }
 130
 131 sub _recurse_fields {
 132   my ($self, $fields, $params) = @_;
 133   my $ref = ref $fields;
 134   return $self->_quote($fields) unless $ref;
 135   return $$fields if $ref eq 'SCALAR';
 136
 137   if ($ref eq 'ARRAY') {
 138     return join(', ', map {
 139       $self->_recurse_fields($_)
 140         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 141           ? ' AS col'.$self->{rownum_hack_count}++
 142           : '')
 143       } @$fields);
 144   } elsif ($ref eq 'HASH') {
 145     foreach my $func (keys %$fields) {
 146       return $self->_sqlcase($func)
 147         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 148     }
 149   }
 150 }
 151
 152 sub _order_by {
 153   my $self = shift;
 154   my $ret = '';
 155   my @extra;
 156   if (ref $_[0] eq 'HASH') {
 157     if (defined $_[0]->{group_by}) {
 158       $ret = $self->_sqlcase(' group by ')
 159         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 160     }
 161     if (defined $_[0]->{having}) {
 162       my $frag;
 163       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 164       push(@{$self->{having_bind}}, @extra);
 165       $ret .= $self->_sqlcase(' having ').$frag;
 166     }
 167     if (defined $_[0]->{order_by}) {
 168       $ret .= $self->_order_by($_[0]->{order_by});
 169     }
 170   } elsif (ref $_[0] eq 'SCALAR') {
 171     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 172   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 173     my @order = @{+shift};
 174     $ret = $self->_sqlcase(' order by ')
 175           .join(', ', map {
 176                         my $r = $self->_order_by($_, @_);
 177                         $r =~ s/^ ?ORDER BY //i;
 178                         $r;
 179                       } @order);
 180   } else {
 181     $ret = $self->SUPER::_order_by(@_);
 182   }
 183   return $ret;
 184 }
 185
 186 sub _order_directions {
 187   my ($self, $order) = @_;
 188   $order = $order->{order_by} if ref $order eq 'HASH';
 189   return $self->SUPER::_order_directions($order);
 190 }
 191
 192 sub _table {
 193   my ($self, $from) = @_;
 194   if (ref $from eq 'ARRAY') {
 195     return $self->_recurse_from(@$from);
 196   } elsif (ref $from eq 'HASH') {
 197     return $self->_make_as($from);
 198   } else {
 199     return $from; # would love to quote here but _table ends up getting called
 200                   # twice during an ->select without a limit clause due to
 201                   # the way S::A::Limit->select works. should maybe consider
 202                   # bypassing this and doing S::A::select($self, ...) in
 203                   # our select method above. meantime, quoting shims have
 204                   # been added to select/insert/update/delete here
 205   }
 206 }
 207
 208 sub _recurse_from {
 209   my ($self, $from, @join) = @_;
 210   my @sqlf;
 211   push(@sqlf, $self->_make_as($from));
 212   foreach my $j (@join) {
 213     my ($to, $on) = @$j;
 214
 215     # check whether a join type exists
 216     my $join_clause = '';
 217     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 218     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 219       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 220     } else {
 221       $join_clause = ' JOIN ';
 222     }
 223     push(@sqlf, $join_clause);
 224
 225     if (ref $to eq 'ARRAY') {
 226       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 227     } else {
 228       push(@sqlf, $self->_make_as($to));
 229     }
 230     push(@sqlf, ' ON ', $self->_join_condition($on));
 231   }
 232   return join('', @sqlf);
 233 }
 234
 235 sub _make_as {
 236   my ($self, $from) = @_;
 237   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 238                      reverse each %{$self->_skip_options($from)});
 239 }
 240
 241 sub _skip_options {
 242   my ($self, $hash) = @_;
 243   my $clean_hash = {};
 244   $clean_hash->{$_} = $hash->{$_}
 245     for grep {!/^-/} keys %$hash;
 246   return $clean_hash;
 247 }
 248
 249 sub _join_condition {
 250   my ($self, $cond) = @_;
 251   if (ref $cond eq 'HASH') {
 252     my %j;
 253     for (keys %$cond) {
 254       my $v = $cond->{$_};
 255       if (ref $v) {
 256         # XXX no throw_exception() in this package and croak() fails with strange results
 257         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 258             if ref($v) ne 'SCALAR';
 259         $j{$_} = $v;
 260       }
 261       else {
 262         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 263       }
 264     };
 265     return scalar($self->_recurse_where(\%j));
 266   } elsif (ref $cond eq 'ARRAY') {
 267     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 268   } else {
 269     die "Can't handle this yet!";
 270   }
 271 }
 272
 273 sub _quote {
 274   my ($self, $label) = @_;
 275   return '' unless defined $label;
 276   return "*" if $label eq '*';
 277   return $label unless $self->{quote_char};
 278   if(ref $self->{quote_char} eq "ARRAY"){
 279     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 280       if !defined $self->{name_sep};
 281     my $sep = $self->{name_sep};
 282     return join($self->{name_sep},
 283         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 284        split(/\Q$sep\E/,$label));
 285   }
 286   return $self->SUPER::_quote($label);
 287 }
 288
 289 sub limit_dialect {
 290     my $self = shift;
 291     $self->{limit_dialect} = shift if @_;
 292     return $self->{limit_dialect};
 293 }
 294
 295 sub quote_char {
 296     my $self = shift;
 297     $self->{quote_char} = shift if @_;
 298     return $self->{quote_char};
 299 }
 300
 301 sub name_sep {
 302     my $self = shift;
 303     $self->{name_sep} = shift if @_;
 304     return $self->{name_sep};
 305 }
 306
 307 } # End of BEGIN block
 308
 309 =head1 NAME
 310
 311 DBIx::Class::Storage::DBI - DBI storage handler
 312
 313 =head1 SYNOPSIS
 314
 315 =head1 DESCRIPTION
 316
 317 This class represents the connection to an RDBMS via L<DBI>.  See
 318 L<DBIx::Class::Storage> for general information.  This pod only
 319 documents DBI-specific methods and behaviors.
 320
 321 =head1 METHODS
 322
 323 =cut
 324
 325 sub new {
 326   my $new = shift->next::method(@_);
 327
 328   $new->transaction_depth(0);
 329   $new->_sql_maker_opts({});
 330   $new->{_in_dbh_do} = 0;
 331   $new->{_dbh_gen} = 0;
 332
 333   $new;
 334 }
 335
 336 =head2 connect_info
 337
 338 The arguments of C<connect_info> are always a single array reference.
 339
 340 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 341 encapsulates its argument list in an arrayref before calling
 342 C<connect_info> here.
 343
 344 The arrayref can either contain the same set of arguments one would
 345 normally pass to L<DBI/connect>, or a lone code reference which returns
 346 a connected database handle.  Please note that the L<DBI> docs
 347 recommend that you always explicitly set C<AutoCommit> to either
 348 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 349 to C<1>, and that you perform transactions via our L</txn_do>
 350 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 351 set it to zero.  This is the default for most DBDs.  See below for more
 352 details.
 353
 354 In either case, if the final argument in your connect_info happens
 355 to be a hashref, C<connect_info> will look there for several
 356 connection-specific options:
 357
 358 =over 4
 359
 360 =item on_connect_do
 361
 362 Specifies things to do immediately after connecting or re-connecting to
 363 the database.  Its value may contain:
 364
 365 =over
 366
 367 =item an array reference
 368
 369 This contains SQL statements to execute in order.  Each element contains
 370 a string or a code reference that returns a string.
 371
 372 =item a code reference
 373
 374 This contains some code to execute.  Unlike code references within an
 375 array reference, its return value is ignored.
 376
 377 =back
 378
 379 =item on_disconnect_do
 380
 381 Takes arguments in the same form as L<on_connect_do> and executes them
 382 immediately before disconnecting from the database.
 383
 384 Note, this only runs if you explicitly call L<disconnect> on the
 385 storage object.
 386
 387 =item disable_sth_caching
 388
 389 If set to a true value, this option will disable the caching of
 390 statement handles via L<DBI/prepare_cached>.
 391
 392 =item limit_dialect
 393
 394 Sets the limit dialect. This is useful for JDBC-bridge among others
 395 where the remote SQL-dialect cannot be determined by the name of the
 396 driver alone.
 397
 398 =item quote_char
 399
 400 Specifies what characters to use to quote table and column names. If
 401 you use this you will want to specify L<name_sep> as well.
 402
 403 quote_char expects either a single character, in which case is it is placed
 404 on either side of the table/column, or an arrayref of length 2 in which case the
 405 table/column name is placed between the elements.
 406
 407 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 408 use C<quote_char =E<gt> [qw/[ ]/]>.
 409
 410 =item name_sep
 411
 412 This only needs to be used in conjunction with L<quote_char>, and is used to
 413 specify the charecter that seperates elements (schemas, tables, columns) from
 414 each other. In most cases this is simply a C<.>.
 415
 416 =item unsafe
 417
 418 This Storage driver normally installs its own C<HandleError>, sets
 419 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 420 all database handles, including those supplied by a coderef.  It does this
 421 so that it can have consistent and useful error behavior.
 422
 423 If you set this option to a true value, Storage will not do its usual
 424 modifications to the database handle's attributes, and instead relies on
 425 the settings in your connect_info DBI options (or the values you set in
 426 your connection coderef, in the case that you are connecting via coderef).
 427
 428 Note that your custom settings can cause Storage to malfunction,
 429 especially if you set a C<HandleError> handler that suppresses exceptions
 430 and/or disable C<RaiseError>.
 431
 432 =back
 433
 434 These options can be mixed in with your other L<DBI> connection attributes,
 435 or placed in a seperate hashref after all other normal L<DBI> connection
 436 arguments.
 437
 438 Every time C<connect_info> is invoked, any previous settings for
 439 these options will be cleared before setting the new ones, regardless of
 440 whether any options are specified in the new C<connect_info>.
 441
 442 Another Important Note:
 443
 444 DBIC can do some wonderful magic with handling exceptions,
 445 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 446 combined with C<txn_do> for transaction support.
 447
 448 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 449 in an assumed transaction between commits, and you're telling us you'd
 450 like to manage that manually.  A lot of DBIC's magic protections
 451 go away.  We can't protect you from exceptions due to database
 452 disconnects because we don't know anything about how to restart your
 453 transactions.  You're on your own for handling all sorts of exceptional
 454 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 455 be with raw DBI.
 456
 457 Examples:
 458
 459   # Simple SQLite connection
 460   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 461
 462   # Connect via subref
 463   ->connect_info([ sub { DBI->connect(...) } ]);
 464
 465   # A bit more complicated
 466   ->connect_info(
 467     [
 468       'dbi:Pg:dbname=foo',
 469       'postgres',
 470       'my_pg_password',
 471       { AutoCommit => 1 },
 472       { quote_char => q{"}, name_sep => q{.} },
 473     ]
 474   );
 475
 476   # Equivalent to the previous example
 477   ->connect_info(
 478     [
 479       'dbi:Pg:dbname=foo',
 480       'postgres',
 481       'my_pg_password',
 482       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 483     ]
 484   );
 485
 486   # Subref + DBIC-specific connection options
 487   ->connect_info(
 488     [
 489       sub { DBI->connect(...) },
 490       {
 491           quote_char => q{`},
 492           name_sep => q{@},
 493           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 494           disable_sth_caching => 1,
 495       },
 496     ]
 497   );
 498
 499 =cut
 500
 501 sub connect_info {
 502   my ($self, $info_arg) = @_;
 503
 504   return $self->_connect_info if !$info_arg;
 505
 506   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 507   #  the new set of options
 508   $self->_sql_maker(undef);
 509   $self->_sql_maker_opts({});
 510   $self->_connect_info([@$info_arg]); # copy for _connect_info
 511
 512   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 513
 514   my $last_info = $dbi_info->[-1];
 515   if(ref $last_info eq 'HASH') {
 516     $last_info = { %$last_info }; # so delete is non-destructive
 517     my @storage_option = qw(
 518       on_connect_do on_disconnect_do disable_sth_caching unsafe cursor_class
 519     );
 520     for my $storage_opt (@storage_option) {
 521       if(my $value = delete $last_info->{$storage_opt}) {
 522         $self->$storage_opt($value);
 523       }
 524     }
 525     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 526       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 527         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 528       }
 529     }
 530     # re-insert modified hashref
 531     $dbi_info->[-1] = $last_info;
 532
 533     # Get rid of any trailing empty hashref
 534     pop(@$dbi_info) if !keys %$last_info;
 535   }
 536   $self->_dbi_connect_info($dbi_info);
 537
 538   $self->_connect_info;
 539 }
 540
 541 =head2 on_connect_do
 542
 543 This method is deprecated in favor of setting via L</connect_info>.
 544
 545 =head2 dbh_do
 546
 547 Arguments: $subref, @extra_coderef_args?
 548
 549 Execute the given subref using the new exception-based connection management.
 550
 551 The first two arguments will be the storage object that C<dbh_do> was called
 552 on and a database handle to use.  Any additional arguments will be passed
 553 verbatim to the called subref as arguments 2 and onwards.
 554
 555 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 556 exception handling and reconnection (or failover in future subclasses).
 557
 558 Your subref should have no side-effects outside of the database, as
 559 there is the potential for your subref to be partially double-executed
 560 if the database connection was stale/dysfunctional.
 561
 562 Example:
 563
 564   my @stuff = $schema->storage->dbh_do(
 565     sub {
 566       my ($storage, $dbh, @cols) = @_;
 567       my $cols = join(q{, }, @cols);
 568       $dbh->selectrow_array("SELECT $cols FROM foo");
 569     },
 570     @column_list
 571   );
 572
 573 =cut
 574
 575 sub dbh_do {
 576   my $self = shift;
 577   my $coderef = shift;
 578
 579   ref $coderef eq 'CODE' or $self->throw_exception
 580     ('$coderef must be a CODE reference');
 581
 582   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 583       || $self->{transaction_depth};
 584
 585   local $self->{_in_dbh_do} = 1;
 586
 587   my @result;
 588   my $want_array = wantarray;
 589
 590   eval {
 591     $self->_verify_pid if $self->_dbh;
 592     $self->_populate_dbh if !$self->_dbh;
 593     if($want_array) {
 594         @result = $coderef->($self, $self->_dbh, @_);
 595     }
 596     elsif(defined $want_array) {
 597         $result[0] = $coderef->($self, $self->_dbh, @_);
 598     }
 599     else {
 600         $coderef->($self, $self->_dbh, @_);
 601     }
 602   };
 603
 604   my $exception = $@;
 605   if(!$exception) { return $want_array ? @result : $result[0] }
 606
 607   $self->throw_exception($exception) if $self->connected;
 608
 609   # We were not connected - reconnect and retry, but let any
 610   #  exception fall right through this time
 611   $self->_populate_dbh;
 612   $coderef->($self, $self->_dbh, @_);
 613 }
 614
 615 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 616 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 617 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 618 sub txn_do {
 619   my $self = shift;
 620   my $coderef = shift;
 621
 622   ref $coderef eq 'CODE' or $self->throw_exception
 623     ('$coderef must be a CODE reference');
 624
 625   return $coderef->(@_) if $self->{transaction_depth};
 626
 627   local $self->{_in_dbh_do} = 1;
 628
 629   my @result;
 630   my $want_array = wantarray;
 631
 632   my $tried = 0;
 633   while(1) {
 634     eval {
 635       $self->_verify_pid if $self->_dbh;
 636       $self->_populate_dbh if !$self->_dbh;
 637
 638       $self->txn_begin;
 639       if($want_array) {
 640           @result = $coderef->(@_);
 641       }
 642       elsif(defined $want_array) {
 643           $result[0] = $coderef->(@_);
 644       }
 645       else {
 646           $coderef->(@_);
 647       }
 648       $self->txn_commit;
 649     };
 650
 651     my $exception = $@;
 652     if(!$exception) { return $want_array ? @result : $result[0] }
 653
 654     if($tried++ > 0 || $self->connected) {
 655       eval { $self->txn_rollback };
 656       my $rollback_exception = $@;
 657       if($rollback_exception) {
 658         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 659         $self->throw_exception($exception)  # propagate nested rollback
 660           if $rollback_exception =~ /$exception_class/;
 661
 662         $self->throw_exception(
 663           "Transaction aborted: ${exception}. "
 664           . "Rollback failed: ${rollback_exception}"
 665         );
 666       }
 667       $self->throw_exception($exception)
 668     }
 669
 670     # We were not connected, and was first try - reconnect and retry
 671     # via the while loop
 672     $self->_populate_dbh;
 673   }
 674 }
 675
 676 =head2 disconnect
 677
 678 Our C<disconnect> method also performs a rollback first if the
 679 database is not in C<AutoCommit> mode.
 680
 681 =cut
 682
 683 sub disconnect {
 684   my ($self) = @_;
 685
 686   if( $self->connected ) {
 687     my $connection_do = $self->on_disconnect_do;
 688     $self->_do_connection_actions($connection_do) if ref($connection_do);
 689
 690     $self->_dbh->rollback unless $self->_dbh_autocommit;
 691     $self->_dbh->disconnect;
 692     $self->_dbh(undef);
 693     $self->{_dbh_gen}++;
 694   }
 695 }
 696
 697 sub connected {
 698   my ($self) = @_;
 699
 700   if(my $dbh = $self->_dbh) {
 701       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 702           $self->_dbh(undef);
 703           $self->{_dbh_gen}++;
 704           return;
 705       }
 706       else {
 707           $self->_verify_pid;
 708           return 0 if !$self->_dbh;
 709       }
 710       return ($dbh->FETCH('Active') && $dbh->ping);
 711   }
 712
 713   return 0;
 714 }
 715
 716 # handle pid changes correctly
 717 #  NOTE: assumes $self->_dbh is a valid $dbh
 718 sub _verify_pid {
 719   my ($self) = @_;
 720
 721   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 722
 723   $self->_dbh->{InactiveDestroy} = 1;
 724   $self->_dbh(undef);
 725   $self->{_dbh_gen}++;
 726
 727   return;
 728 }
 729
 730 sub ensure_connected {
 731   my ($self) = @_;
 732
 733   unless ($self->connected) {
 734     $self->_populate_dbh;
 735   }
 736 }
 737
 738 =head2 dbh
 739
 740 Returns the dbh - a data base handle of class L<DBI>.
 741
 742 =cut
 743
 744 sub dbh {
 745   my ($self) = @_;
 746
 747   $self->ensure_connected;
 748   return $self->_dbh;
 749 }
 750
 751 sub _sql_maker_args {
 752     my ($self) = @_;
 753
 754     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 755 }
 756
 757 sub sql_maker {
 758   my ($self) = @_;
 759   unless ($self->_sql_maker) {
 760     my $sql_maker_class = $self->sql_maker_class;
 761     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 762   }
 763   return $self->_sql_maker;
 764 }
 765
 766 sub _populate_dbh {
 767   my ($self) = @_;
 768   my @info = @{$self->_dbi_connect_info || []};
 769   $self->_dbh($self->_connect(@info));
 770
 771   # Always set the transaction depth on connect, since
 772   #  there is no transaction in progress by definition
 773   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 774
 775   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 776     my $driver = $self->_dbh->{Driver}->{Name};
 777     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 778       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 779       $self->_rebless() if $self->can('_rebless');
 780     }
 781   }
 782
 783   my $connection_do = $self->on_connect_do;
 784   $self->_do_connection_actions($connection_do) if ref($connection_do);
 785
 786   $self->_conn_pid($$);
 787   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 788 }
 789
 790 sub _do_connection_actions {
 791   my $self = shift;
 792   my $connection_do = shift;
 793
 794   if (ref $connection_do eq 'ARRAY') {
 795     $self->_do_query($_) foreach @$connection_do;
 796   }
 797   elsif (ref $connection_do eq 'CODE') {
 798     $connection_do->();
 799   }
 800
 801   return $self;
 802 }
 803
 804 sub _do_query {
 805   my ($self, $action) = @_;
 806
 807   if (ref $action eq 'CODE') {
 808     $action = $action->($self);
 809     $self->_do_query($_) foreach @$action;
 810   }
 811   else {
 812     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 813     $self->_query_start(@to_run);
 814     $self->_dbh->do(@to_run);
 815     $self->_query_end(@to_run);
 816   }
 817
 818   return $self;
 819 }
 820
 821 sub _connect {
 822   my ($self, @info) = @_;
 823
 824   $self->throw_exception("You failed to provide any connection info")
 825     if !@info;
 826
 827   my ($old_connect_via, $dbh);
 828
 829   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 830     $old_connect_via = $DBI::connect_via;
 831     $DBI::connect_via = 'connect';
 832   }
 833
 834   eval {
 835     if(ref $info[0] eq 'CODE') {
 836        $dbh = &{$info[0]}
 837     }
 838     else {
 839        $dbh = DBI->connect(@info);
 840     }
 841
 842     if($dbh && !$self->unsafe) {
 843       my $weak_self = $self;
 844       weaken($weak_self);
 845       $dbh->{HandleError} = sub {
 846           $weak_self->throw_exception("DBI Exception: $_[0]")
 847       };
 848       $dbh->{ShowErrorStatement} = 1;
 849       $dbh->{RaiseError} = 1;
 850       $dbh->{PrintError} = 0;
 851     }
 852   };
 853
 854   $DBI::connect_via = $old_connect_via if $old_connect_via;
 855
 856   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 857     if !$dbh || $@;
 858
 859   $self->_dbh_autocommit($dbh->{AutoCommit});
 860
 861   $dbh;
 862 }
 863
 864
 865 sub txn_begin {
 866   my $self = shift;
 867   $self->ensure_connected();
 868   if($self->{transaction_depth} == 0) {
 869     $self->debugobj->txn_begin()
 870       if $self->debug;
 871     # this isn't ->_dbh-> because
 872     #  we should reconnect on begin_work
 873     #  for AutoCommit users
 874     $self->dbh->begin_work;
 875   }
 876   $self->{transaction_depth}++;
 877 }
 878
 879 sub txn_commit {
 880   my $self = shift;
 881   if ($self->{transaction_depth} == 1) {
 882     my $dbh = $self->_dbh;
 883     $self->debugobj->txn_commit()
 884       if ($self->debug);
 885     $dbh->commit;
 886     $self->{transaction_depth} = 0
 887       if $self->_dbh_autocommit;
 888   }
 889   elsif($self->{transaction_depth} > 1) {
 890     $self->{transaction_depth}--
 891   }
 892 }
 893
 894 sub txn_rollback {
 895   my $self = shift;
 896   my $dbh = $self->_dbh;
 897   eval {
 898     if ($self->{transaction_depth} == 1) {
 899       $self->debugobj->txn_rollback()
 900         if ($self->debug);
 901       $self->{transaction_depth} = 0
 902         if $self->_dbh_autocommit;
 903       $dbh->rollback;
 904     }
 905     elsif($self->{transaction_depth} > 1) {
 906       $self->{transaction_depth}--;
 907     }
 908     else {
 909       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 910     }
 911   };
 912   if ($@) {
 913     my $error = $@;
 914     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 915     $error =~ /$exception_class/ and $self->throw_exception($error);
 916     # ensure that a failed rollback resets the transaction depth
 917     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 918     $self->throw_exception($error);
 919   }
 920 }
 921
 922 # This used to be the top-half of _execute.  It was split out to make it
 923 #  easier to override in NoBindVars without duping the rest.  It takes up
 924 #  all of _execute's args, and emits $sql, @bind.
 925 sub _prep_for_execute {
 926   my ($self, $op, $extra_bind, $ident, $args) = @_;
 927
 928   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 929   unshift(@bind,
 930     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 931       if $extra_bind;
 932
 933   return ($sql, \@bind);
 934 }
 935
 936 sub _fix_bind_params {
 937     my ($self, @bind) = @_;
 938
 939     ### Turn @bind from something like this:
 940     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
 941     ### to this:
 942     ###   ( "'1'", "'1'", "'3'" )
 943     return
 944         map {
 945             if ( defined( $_ && $_->[1] ) ) {
 946                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
 947             }
 948             else { q{'NULL'}; }
 949         } @bind;
 950 }
 951
 952 sub _query_start {
 953     my ( $self, $sql, @bind ) = @_;
 954
 955     if ( $self->debug ) {
 956         @bind = $self->_fix_bind_params(@bind);
 957         $self->debugobj->query_start( $sql, @bind );
 958     }
 959 }
 960
 961 sub _query_end {
 962     my ( $self, $sql, @bind ) = @_;
 963
 964     if ( $self->debug ) {
 965         @bind = $self->_fix_bind_params(@bind);
 966         $self->debugobj->query_end( $sql, @bind );
 967     }
 968 }
 969
 970 sub _dbh_execute {
 971   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 972
 973   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 974     $ident = $ident->from();
 975   }
 976
 977   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 978
 979   $self->_query_start( $sql, @$bind );
 980
 981   my $sth = $self->sth($sql,$op);
 982
 983   my $placeholder_index = 1;
 984
 985   foreach my $bound (@$bind) {
 986     my $attributes = {};
 987     my($column_name, @data) = @$bound;
 988
 989     if ($bind_attributes) {
 990       $attributes = $bind_attributes->{$column_name}
 991       if defined $bind_attributes->{$column_name};
 992     }
 993
 994     foreach my $data (@data) {
 995       $data = ref $data ? ''.$data : $data; # stringify args
 996
 997       $sth->bind_param($placeholder_index, $data, $attributes);
 998       $placeholder_index++;
 999     }
1000   }
1001
1002   # Can this fail without throwing an exception anyways???
1003   my $rv = $sth->execute();
1004   $self->throw_exception($sth->errstr) if !$rv;
1005
1006   $self->_query_end( $sql, @$bind );
1007
1008   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1009 }
1010
1011 sub _execute {
1012     my $self = shift;
1013     $self->dbh_do($self->can('_dbh_execute'), @_)
1014 }
1015
1016 sub insert {
1017   my ($self, $source, $to_insert) = @_;
1018
1019   my $ident = $source->from;
1020   my $bind_attributes = $self->source_bind_attributes($source);
1021
1022   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1023
1024   return $to_insert;
1025 }
1026
1027 ## Still not quite perfect, and EXPERIMENTAL
1028 ## Currently it is assumed that all values passed will be "normal", i.e. not
1029 ## scalar refs, or at least, all the same type as the first set, the statement is
1030 ## only prepped once.
1031 sub insert_bulk {
1032   my ($self, $source, $cols, $data) = @_;
1033   my %colvalues;
1034   my $table = $source->from;
1035   @colvalues{@$cols} = (0..$#$cols);
1036   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1037
1038   $self->_query_start( $sql, @bind );
1039   my $sth = $self->sth($sql);
1040
1041 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1042
1043   ## This must be an arrayref, else nothing works!
1044
1045   my $tuple_status = [];
1046
1047   ##use Data::Dumper;
1048   ##print STDERR Dumper( $data, $sql, [@bind] );
1049
1050   my $time = time();
1051
1052   ## Get the bind_attributes, if any exist
1053   my $bind_attributes = $self->source_bind_attributes($source);
1054
1055   ## Bind the values and execute
1056   my $placeholder_index = 1;
1057
1058   foreach my $bound (@bind) {
1059
1060     my $attributes = {};
1061     my ($column_name, $data_index) = @$bound;
1062
1063     if( $bind_attributes ) {
1064       $attributes = $bind_attributes->{$column_name}
1065       if defined $bind_attributes->{$column_name};
1066     }
1067
1068     my @data = map { $_->[$data_index] } @$data;
1069
1070     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1071     $placeholder_index++;
1072   }
1073   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1074   $self->throw_exception($sth->errstr) if !$rv;
1075
1076   $self->_query_end( $sql, @bind );
1077   return (wantarray ? ($rv, $sth, @bind) : $rv);
1078 }
1079
1080 sub update {
1081   my $self = shift @_;
1082   my $source = shift @_;
1083   my $bind_attributes = $self->source_bind_attributes($source);
1084
1085   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1086 }
1087
1088
1089 sub delete {
1090   my $self = shift @_;
1091   my $source = shift @_;
1092
1093   my $bind_attrs = {}; ## If ever it's needed...
1094
1095   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1096 }
1097
1098 sub _select {
1099   my ($self, $ident, $select, $condition, $attrs) = @_;
1100   my $order = $attrs->{order_by};
1101
1102   if (ref $condition eq 'SCALAR') {
1103     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1104   }
1105
1106   my $for = delete $attrs->{for};
1107   my $sql_maker = $self->sql_maker;
1108   local $sql_maker->{for} = $for;
1109
1110   if (exists $attrs->{group_by} || $attrs->{having}) {
1111     $order = {
1112       group_by => $attrs->{group_by},
1113       having => $attrs->{having},
1114       ($order ? (order_by => $order) : ())
1115     };
1116   }
1117   my $bind_attrs = {}; ## Future support
1118   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1119   if ($attrs->{software_limit} ||
1120       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1121         $attrs->{software_limit} = 1;
1122   } else {
1123     $self->throw_exception("rows attribute must be positive if present")
1124       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1125
1126     # MySQL actually recommends this approach.  I cringe.
1127     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1128     push @args, $attrs->{rows}, $attrs->{offset};
1129   }
1130
1131   return $self->_execute(@args);
1132 }
1133
1134 sub source_bind_attributes {
1135   my ($self, $source) = @_;
1136
1137   my $bind_attributes;
1138   foreach my $column ($source->columns) {
1139
1140     my $data_type = $source->column_info($column)->{data_type} || '';
1141     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1142      if $data_type;
1143   }
1144
1145   return $bind_attributes;
1146 }
1147
1148 =head2 select
1149
1150 =over 4
1151
1152 =item Arguments: $ident, $select, $condition, $attrs
1153
1154 =back
1155
1156 Handle a SQL select statement.
1157
1158 =cut
1159
1160 sub select {
1161   my $self = shift;
1162   my ($ident, $select, $condition, $attrs) = @_;
1163   return $self->cursor_class->new($self, \@_, $attrs);
1164 }
1165
1166 sub select_single {
1167   my $self = shift;
1168   my ($rv, $sth, @bind) = $self->_select(@_);
1169   my @row = $sth->fetchrow_array;
1170   # Need to call finish() to work round broken DBDs
1171   $sth->finish();
1172   return @row;
1173 }
1174
1175 =head2 sth
1176
1177 =over 4
1178
1179 =item Arguments: $sql
1180
1181 =back
1182
1183 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1184
1185 =cut
1186
1187 sub _dbh_sth {
1188   my ($self, $dbh, $sql) = @_;
1189
1190   # 3 is the if_active parameter which avoids active sth re-use
1191   my $sth = $self->disable_sth_caching
1192     ? $dbh->prepare($sql)
1193     : $dbh->prepare_cached($sql, {}, 3);
1194
1195   # XXX You would think RaiseError would make this impossible,
1196   #  but apparently that's not true :(
1197   $self->throw_exception($dbh->errstr) if !$sth;
1198
1199   $sth;
1200 }
1201
1202 sub sth {
1203   my ($self, $sql) = @_;
1204   $self->dbh_do($self->can('_dbh_sth'), $sql);
1205 }
1206
1207 sub _dbh_columns_info_for {
1208   my ($self, $dbh, $table) = @_;
1209
1210   if ($dbh->can('column_info')) {
1211     my %result;
1212     eval {
1213       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1214       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1215       $sth->execute();
1216       while ( my $info = $sth->fetchrow_hashref() ){
1217         my %column_info;
1218         $column_info{data_type}   = $info->{TYPE_NAME};
1219         $column_info{size}      = $info->{COLUMN_SIZE};
1220         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1221         $column_info{default_value} = $info->{COLUMN_DEF};
1222         my $col_name = $info->{COLUMN_NAME};
1223         $col_name =~ s/^\"(.*)\"$/$1/;
1224
1225         $result{$col_name} = \%column_info;
1226       }
1227     };
1228     return \%result if !$@ && scalar keys %result;
1229   }
1230
1231   my %result;
1232   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1233   $sth->execute;
1234   my @columns = @{$sth->{NAME_lc}};
1235   for my $i ( 0 .. $#columns ){
1236     my %column_info;
1237     $column_info{data_type} = $sth->{TYPE}->[$i];
1238     $column_info{size} = $sth->{PRECISION}->[$i];
1239     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1240
1241     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1242       $column_info{data_type} = $1;
1243       $column_info{size}    = $2;
1244     }
1245
1246     $result{$columns[$i]} = \%column_info;
1247   }
1248   $sth->finish;
1249
1250   foreach my $col (keys %result) {
1251     my $colinfo = $result{$col};
1252     my $type_num = $colinfo->{data_type};
1253     my $type_name;
1254     if(defined $type_num && $dbh->can('type_info')) {
1255       my $type_info = $dbh->type_info($type_num);
1256       $type_name = $type_info->{TYPE_NAME} if $type_info;
1257       $colinfo->{data_type} = $type_name if $type_name;
1258     }
1259   }
1260
1261   return \%result;
1262 }
1263
1264 sub columns_info_for {
1265   my ($self, $table) = @_;
1266   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1267 }
1268
1269 =head2 last_insert_id
1270
1271 Return the row id of the last insert.
1272
1273 =cut
1274
1275 sub _dbh_last_insert_id {
1276     my ($self, $dbh, $source, $col) = @_;
1277     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1278     $dbh->func('last_insert_rowid');
1279 }
1280
1281 sub last_insert_id {
1282   my $self = shift;
1283   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1284 }
1285
1286 =head2 sqlt_type
1287
1288 Returns the database driver name.
1289
1290 =cut
1291
1292 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1293
1294 =head2 bind_attribute_by_data_type
1295
1296 Given a datatype from column info, returns a database specific bind attribute for
1297 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1298 just handle it.
1299
1300 Generally only needed for special case column types, like bytea in postgres.
1301
1302 =cut
1303
1304 sub bind_attribute_by_data_type {
1305     return;
1306 }
1307
1308 =head2 create_ddl_dir
1309
1310 =over 4
1311
1312 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1313
1314 =back
1315
1316 Creates a SQL file based on the Schema, for each of the specified
1317 database types, in the given directory.
1318
1319 =cut
1320
1321 sub create_ddl_dir
1322 {
1323   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1324
1325   if(!$dir || !-d $dir)
1326   {
1327     warn "No directory given, using ./\n";
1328     $dir = "./";
1329   }
1330   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1331   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1332   $version ||= $schema->VERSION || '1.x';
1333   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1334
1335   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09: '}
1336       . $self->_check_sqlt_message . q{'})
1337           if !$self->_check_sqlt_version;
1338
1339   my $sqlt = SQL::Translator->new({
1340       add_drop_table => 1,
1341   });
1342
1343   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1344   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1345
1346   foreach my $db (@$databases)
1347   {
1348     $sqlt->reset();
1349     $sqlt = $self->configure_sqlt($sqlt, $db);
1350     $sqlt->{schema} = $sqlt_schema;
1351     $sqlt->producer($db);
1352
1353     my $file;
1354     my $filename = $schema->ddl_filename($db, $dir, $version);
1355     if(-e $filename)
1356     {
1357       warn("$filename already exists, skipping $db");
1358       next unless ($preversion);
1359     } else {
1360       my $output = $sqlt->translate;
1361       if(!$output)
1362       {
1363         warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1364         next;
1365       }
1366       if(!open($file, ">$filename"))
1367       {
1368           $self->throw_exception("Can't open $filename for writing ($!)");
1369           next;
1370       }
1371       print $file $output;
1372       close($file);
1373     }
1374     if($preversion)
1375     {
1376       require SQL::Translator::Diff;
1377
1378       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1379 #      print "Previous version $prefilename\n";
1380       if(!-e $prefilename)
1381       {
1382         warn("No previous schema file found ($prefilename)");
1383         next;
1384       }
1385
1386       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1387       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1388       if(-e $difffile)
1389       {
1390         warn("$difffile already exists, skipping");
1391         next;
1392       }
1393
1394       my $source_schema;
1395       {
1396         my $t = SQL::Translator->new;
1397         $t->debug( 0 );
1398         $t->trace( 0 );
1399         $t->parser( $db )                       or die $t->error;
1400         my $out = $t->translate( $prefilename ) or die $t->error;
1401         $source_schema = $t->schema;
1402         unless ( $source_schema->name ) {
1403           $source_schema->name( $prefilename );
1404         }
1405       }
1406
1407       # The "new" style of producers have sane normalization and can support
1408       # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1409       # And we have to diff parsed SQL against parsed SQL.
1410       my $dest_schema = $sqlt_schema;
1411
1412       unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1413         my $t = SQL::Translator->new;
1414         $t->debug( 0 );
1415         $t->trace( 0 );
1416         $t->parser( $db )                    or die $t->error;
1417         my $out = $t->translate( $filename ) or die $t->error;
1418         $dest_schema = $t->schema;
1419         $dest_schema->name( $filename )
1420           unless $dest_schema->name;
1421       }
1422
1423       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1424                                                     $dest_schema,   $db,
1425                                                     {}
1426                                                    );
1427       if(!open $file, ">$difffile")
1428       {
1429         $self->throw_exception("Can't write to $difffile ($!)");
1430         next;
1431       }
1432       print $file $diff;
1433       close($file);
1434     }
1435   }
1436 }
1437
1438 sub configure_sqlt() {
1439   my $self = shift;
1440   my $tr = shift;
1441   my $db = shift || $self->sqlt_type;
1442   if ($db eq 'PostgreSQL') {
1443     $tr->quote_table_names(0);
1444     $tr->quote_field_names(0);
1445   }
1446   return $tr;
1447 }
1448
1449 =head2 deployment_statements
1450
1451 =over 4
1452
1453 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1454
1455 =back
1456
1457 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1458 The database driver name is given by C<$type>, though the value from
1459 L</sqlt_type> is used if it is not specified.
1460
1461 C<$directory> is used to return statements from files in a previously created
1462 L</create_ddl_dir> directory and is optional. The filenames are constructed
1463 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1464
1465 If no C<$directory> is specified then the statements are constructed on the
1466 fly using L<SQL::Translator> and C<$version> is ignored.
1467
1468 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1469
1470 =cut
1471
1472 sub deployment_statements {
1473   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1474   # Need to be connected to get the correct sqlt_type
1475   $self->ensure_connected() unless $type;
1476   $type ||= $self->sqlt_type;
1477   $version ||= $schema->VERSION || '1.x';
1478   $dir ||= './';
1479   my $filename = $schema->ddl_filename($type, $dir, $version);
1480   if(-f $filename)
1481   {
1482       my $file;
1483       open($file, "<$filename")
1484         or $self->throw_exception("Can't open $filename ($!)");
1485       my @rows = <$file>;
1486       close($file);
1487       return join('', @rows);
1488   }
1489
1490   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09: '}
1491       . $self->_check_sqlt_message . q{'})
1492           if !$self->_check_sqlt_version;
1493
1494   require SQL::Translator::Parser::DBIx::Class;
1495   eval qq{use SQL::Translator::Producer::${type}};
1496   $self->throw_exception($@) if $@;
1497
1498   # sources needs to be a parser arg, but for simplicty allow at top level
1499   # coming in
1500   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1501       if exists $sqltargs->{sources};
1502
1503   my $tr = SQL::Translator->new(%$sqltargs);
1504   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1505   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1506
1507   return;
1508
1509 }
1510
1511 sub deploy {
1512   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1513   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1514     foreach my $line ( split(";\n", $statement)) {
1515       next if($line =~ /^--/);
1516       next if(!$line);
1517 #      next if($line =~ /^DROP/m);
1518       next if($line =~ /^BEGIN TRANSACTION/m);
1519       next if($line =~ /^COMMIT/m);
1520       next if $line =~ /^\s+$/; # skip whitespace only
1521       $self->_query_start($line);
1522       eval {
1523         $self->dbh->do($line); # shouldn't be using ->dbh ?
1524       };
1525       if ($@) {
1526         warn qq{$@ (running "${line}")};
1527       }
1528       $self->_query_end($line);
1529     }
1530   }
1531 }
1532
1533 =head2 datetime_parser
1534
1535 Returns the datetime parser class
1536
1537 =cut
1538
1539 sub datetime_parser {
1540   my $self = shift;
1541   return $self->{datetime_parser} ||= do {
1542     $self->ensure_connected;
1543     $self->build_datetime_parser(@_);
1544   };
1545 }
1546
1547 =head2 datetime_parser_type
1548
1549 Defines (returns) the datetime parser class - currently hardwired to
1550 L<DateTime::Format::MySQL>
1551
1552 =cut
1553
1554 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1555
1556 =head2 build_datetime_parser
1557
1558 See L</datetime_parser>
1559
1560 =cut
1561
1562 sub build_datetime_parser {
1563   my $self = shift;
1564   my $type = $self->datetime_parser_type(@_);
1565   eval "use ${type}";
1566   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1567   return $type;
1568 }
1569
1570 {
1571     my $_check_sqlt_version; # private
1572     my $_check_sqlt_message; # private
1573     sub _check_sqlt_version {
1574         return $_check_sqlt_version if defined $_check_sqlt_version;
1575         eval 'use SQL::Translator "0.09"';
1576         $_check_sqlt_message = $@ || '';
1577         $_check_sqlt_version = !$@;
1578     }
1579
1580     sub _check_sqlt_message {
1581         _check_sqlt_version if !defined $_check_sqlt_message;
1582         $_check_sqlt_message;
1583     }
1584 }
1585
1586 sub DESTROY {
1587   my $self = shift;
1588   return if !$self->_dbh;
1589   $self->_verify_pid;
1590   $self->_dbh(undef);
1591 }
1592
1593 1;
1594
1595 =head1 SQL METHODS
1596
1597 The module defines a set of methods within the DBIC::SQL::Abstract
1598 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1599 SQL query functions.
1600
1601 The following methods are extended:-
1602
1603 =over 4
1604
1605 =item delete
1606
1607 =item insert
1608
1609 =item select
1610
1611 =item update
1612
1613 =item limit_dialect
1614
1615 See L</connect_info> for details.
1616 For setting, this method is deprecated in favor of L</connect_info>.
1617
1618 =item quote_char
1619
1620 See L</connect_info> for details.
1621 For setting, this method is deprecated in favor of L</connect_info>.
1622
1623 =item name_sep
1624
1625 See L</connect_info> for details.
1626 For setting, this method is deprecated in favor of L</connect_info>.
1627
1628 =back
1629
1630 =head1 AUTHORS
1631
1632 Matt S. Trout <mst@shadowcatsystems.co.uk>
1633
1634 Andy Grundman <andy@hybridized.org>
1635
1636 =head1 LICENSE
1637
1638 You may distribute this code under the same terms as Perl itself.
1639
1640 =cut