lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use SQL::Abstract::Limit;
   7 use DBIx::Class::Storage::DBI::Cursor;
   8
   9 use base qw/DBIx::Class/;
  10
  11 __PACKAGE__->load_components(qw/Exception AccessorGroup/);
  12
  13 __PACKAGE__->mk_group_accessors('simple' =>
  14   qw/connect_info _dbh sql_maker debug cursor/);
  15
  16 sub new {
  17   my $new = bless({}, ref $_[0] || $_[0]);
  18   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
  19   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
  20   return $new;
  21 }
  22
  23 sub get_simple {
  24   my ($self, $get) = @_;
  25   return $self->{$get};
  26 }
  27
  28 sub set_simple {
  29   my ($self, $set, $val) = @_;
  30   return $self->{$set} = $val;
  31 }
  32
  33 =head1 NAME
  34
  35 DBIx::Class::Storage::DBI - DBI storage handler
  36
  37 =head1 SYNOPSIS
  38
  39 =head1 DESCRIPTION
  40
  41 This class represents the connection to the database
  42
  43 =head1 METHODS
  44
  45 =over 4
  46
  47 =cut
  48
  49 sub dbh {
  50   my ($self) = @_;
  51   my $dbh;
  52   unless (($dbh = $self->_dbh) && $dbh->FETCH('Active') && $dbh->ping) {
  53     $self->_populate_dbh;
  54   }
  55   return $self->_dbh;
  56 }
  57
  58 sub _populate_dbh {
  59   my ($self) = @_;
  60   my @info = @{$self->connect_info || []};
  61   $self->_dbh($self->_connect(@info));
  62   $self->sql_maker(new SQL::Abstract::Limit( limit_dialect => $self->_dbh ));
  63 }
  64
  65 sub _connect {
  66   my ($self, @info) = @_;
  67   return DBI->connect(@info);
  68 }
  69
  70 =item commit
  71
  72   $class->commit;
  73
  74 Issues a commit again the current dbh
  75
  76 =cut
  77
  78 sub commit { $_[0]->dbh->commit; }
  79
  80 =item rollback
  81
  82   $class->rollback;
  83
  84 Issues a rollback again the current dbh
  85
  86 =cut
  87
  88 sub rollback { $_[0]->dbh->rollback; }
  89
  90 sub _execute {
  91   my ($self, $op, $extra_bind, $ident, @args) = @_;
  92   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
  93   unshift(@bind, @$extra_bind) if $extra_bind;
  94   warn "$sql: @bind" if $self->debug;
  95   my $sth = $self->sth($sql);
  96   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
  97   my $rv = $sth->execute(@bind);
  98   return (wantarray ? ($rv, $sth, @bind) : $rv);
  99 }
 100
 101 sub insert {
 102   my ($self, $ident, $to_insert) = @_;
 103   $self->throw( "Couldn't insert ".join(', ', map "$_ => $to_insert->{$_}", keys %$to_insert)." into ${ident}" )
 104     unless ($self->_execute('insert' => [], $ident, $to_insert) > 0);
 105   return $to_insert;
 106 }
 107
 108 sub update {
 109   return shift->_execute('update' => [], @_);
 110 }
 111
 112 sub delete {
 113   return shift->_execute('delete' => [], @_);
 114 }
 115
 116 sub select {
 117   my ($self, $ident, $select, $condition, $attrs) = @_;
 118   my $order = $attrs->{order_by};
 119   if (ref $condition eq 'SCALAR') {
 120     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 121   }
 122   my ($rv, $sth, @bind) = $self->_execute('select', $attrs->{bind}, $ident, $select, $condition, $order, $attrs->{rows}, $attrs->{offset});
 123   return $self->cursor->new($sth, \@bind, $attrs);
 124 }
 125
 126 sub select_single {
 127   my ($self, $ident, $select, $condition, $attrs) = @_;
 128   my $order = $attrs->{order_by};
 129   if (ref $condition eq 'SCALAR') {
 130     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 131   }
 132   my ($rv, $sth, @bind) = $self->_execute('select', $attrs->{bind}, $ident, $select, $condition, $order, 1, $attrs->{offset});
 133   return $sth->fetchrow_array;
 134 }
 135
 136 sub sth {
 137   shift->dbh->prepare(@_);
 138 }
 139
 140 1;
 141
 142 =back
 143
 144 =head1 AUTHORS
 145
 146 Matt S. Trout <mst@shadowcatsystems.co.uk>
 147
 148 =head1 LICENSE
 149
 150 You may distribute this code under the same terms as Perl itself.
 151
 152 =cut
 153