lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13
  14 __PACKAGE__->mk_group_accessors(
  15   'simple' =>
  16     qw/_connect_info _dbh _sql_maker _sql_maker_opts _conn_pid _conn_tid
  17        disable_sth_caching cursor on_connect_do transaction_depth/
  18 );
  19
  20 BEGIN {
  21
  22 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  23
  24 use base qw/SQL::Abstract::Limit/;
  25
  26 # This prevents the caching of $dbh in S::A::L, I believe
  27 sub new {
  28   my $self = shift->SUPER::new(@_);
  29
  30   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  31   #   it with what it resolves to:
  32   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  33     if ref $self->{limit_dialect};
  34
  35   $self;
  36 }
  37
  38 sub _RowNumberOver {
  39   my ($self, $sql, $order, $rows, $offset ) = @_;
  40
  41   $offset += 1;
  42   my $last = $rows + $offset;
  43   my ( $order_by ) = $self->_order_by( $order );
  44
  45   $sql = <<"";
  46 SELECT * FROM
  47 (
  48    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  49       $sql
  50       $order_by
  51    ) Q1
  52 ) Q2
  53 WHERE ROW_NUM BETWEEN $offset AND $last
  54
  55   return $sql;
  56 }
  57
  58
  59 # While we're at it, this should make LIMIT queries more efficient,
  60 #  without digging into things too deeply
  61 use Scalar::Util 'blessed';
  62 sub _find_syntax {
  63   my ($self, $syntax) = @_;
  64   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  65   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  66     return 'RowNumberOver';
  67   }
  68
  69   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  70 }
  71
  72 sub select {
  73   my ($self, $table, $fields, $where, $order, @rest) = @_;
  74   $table = $self->_quote($table) unless ref($table);
  75   local $self->{rownum_hack_count} = 1
  76     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  77   @rest = (-1) unless defined $rest[0];
  78   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  79     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  80   local $self->{having_bind} = [];
  81   my ($sql, @ret) = $self->SUPER::select(
  82     $table, $self->_recurse_fields($fields), $where, $order, @rest
  83   );
  84   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  85 }
  86
  87 sub insert {
  88   my $self = shift;
  89   my $table = shift;
  90   $table = $self->_quote($table) unless ref($table);
  91   $self->SUPER::insert($table, @_);
  92 }
  93
  94 sub update {
  95   my $self = shift;
  96   my $table = shift;
  97   $table = $self->_quote($table) unless ref($table);
  98   $self->SUPER::update($table, @_);
  99 }
 100
 101 sub delete {
 102   my $self = shift;
 103   my $table = shift;
 104   $table = $self->_quote($table) unless ref($table);
 105   $self->SUPER::delete($table, @_);
 106 }
 107
 108 sub _emulate_limit {
 109   my $self = shift;
 110   if ($_[3] == -1) {
 111     return $_[1].$self->_order_by($_[2]);
 112   } else {
 113     return $self->SUPER::_emulate_limit(@_);
 114   }
 115 }
 116
 117 sub _recurse_fields {
 118   my ($self, $fields) = @_;
 119   my $ref = ref $fields;
 120   return $self->_quote($fields) unless $ref;
 121   return $$fields if $ref eq 'SCALAR';
 122
 123   if ($ref eq 'ARRAY') {
 124     return join(', ', map {
 125       $self->_recurse_fields($_)
 126       .(exists $self->{rownum_hack_count}
 127          ? ' AS col'.$self->{rownum_hack_count}++
 128          : '')
 129      } @$fields);
 130   } elsif ($ref eq 'HASH') {
 131     foreach my $func (keys %$fields) {
 132       return $self->_sqlcase($func)
 133         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 134     }
 135   }
 136 }
 137
 138 sub _order_by {
 139   my $self = shift;
 140   my $ret = '';
 141   my @extra;
 142   if (ref $_[0] eq 'HASH') {
 143     if (defined $_[0]->{group_by}) {
 144       $ret = $self->_sqlcase(' group by ')
 145                .$self->_recurse_fields($_[0]->{group_by});
 146     }
 147     if (defined $_[0]->{having}) {
 148       my $frag;
 149       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 150       push(@{$self->{having_bind}}, @extra);
 151       $ret .= $self->_sqlcase(' having ').$frag;
 152     }
 153     if (defined $_[0]->{order_by}) {
 154       $ret .= $self->_order_by($_[0]->{order_by});
 155     }
 156   } elsif (ref $_[0] eq 'SCALAR') {
 157     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 158   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 159     my @order = @{+shift};
 160     $ret = $self->_sqlcase(' order by ')
 161           .join(', ', map {
 162                         my $r = $self->_order_by($_, @_);
 163                         $r =~ s/^ ?ORDER BY //i;
 164                         $r;
 165                       } @order);
 166   } else {
 167     $ret = $self->SUPER::_order_by(@_);
 168   }
 169   return $ret;
 170 }
 171
 172 sub _order_directions {
 173   my ($self, $order) = @_;
 174   $order = $order->{order_by} if ref $order eq 'HASH';
 175   return $self->SUPER::_order_directions($order);
 176 }
 177
 178 sub _table {
 179   my ($self, $from) = @_;
 180   if (ref $from eq 'ARRAY') {
 181     return $self->_recurse_from(@$from);
 182   } elsif (ref $from eq 'HASH') {
 183     return $self->_make_as($from);
 184   } else {
 185     return $from; # would love to quote here but _table ends up getting called
 186                   # twice during an ->select without a limit clause due to
 187                   # the way S::A::Limit->select works. should maybe consider
 188                   # bypassing this and doing S::A::select($self, ...) in
 189                   # our select method above. meantime, quoting shims have
 190                   # been added to select/insert/update/delete here
 191   }
 192 }
 193
 194 sub _recurse_from {
 195   my ($self, $from, @join) = @_;
 196   my @sqlf;
 197   push(@sqlf, $self->_make_as($from));
 198   foreach my $j (@join) {
 199     my ($to, $on) = @$j;
 200
 201     # check whether a join type exists
 202     my $join_clause = '';
 203     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 204     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 205       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 206     } else {
 207       $join_clause = ' JOIN ';
 208     }
 209     push(@sqlf, $join_clause);
 210
 211     if (ref $to eq 'ARRAY') {
 212       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 213     } else {
 214       push(@sqlf, $self->_make_as($to));
 215     }
 216     push(@sqlf, ' ON ', $self->_join_condition($on));
 217   }
 218   return join('', @sqlf);
 219 }
 220
 221 sub _make_as {
 222   my ($self, $from) = @_;
 223   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 224                      reverse each %{$self->_skip_options($from)});
 225 }
 226
 227 sub _skip_options {
 228   my ($self, $hash) = @_;
 229   my $clean_hash = {};
 230   $clean_hash->{$_} = $hash->{$_}
 231     for grep {!/^-/} keys %$hash;
 232   return $clean_hash;
 233 }
 234
 235 sub _join_condition {
 236   my ($self, $cond) = @_;
 237   if (ref $cond eq 'HASH') {
 238     my %j;
 239     for (keys %$cond) {
 240       my $v = $cond->{$_};
 241       if (ref $v) {
 242         # XXX no throw_exception() in this package and croak() fails with strange results
 243         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 244             if ref($v) ne 'SCALAR';
 245         $j{$_} = $v;
 246       }
 247       else {
 248         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 249       }
 250     };
 251     return scalar($self->_recurse_where(\%j));
 252   } elsif (ref $cond eq 'ARRAY') {
 253     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 254   } else {
 255     die "Can't handle this yet!";
 256   }
 257 }
 258
 259 sub _quote {
 260   my ($self, $label) = @_;
 261   return '' unless defined $label;
 262   return "*" if $label eq '*';
 263   return $label unless $self->{quote_char};
 264   if(ref $self->{quote_char} eq "ARRAY"){
 265     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 266       if !defined $self->{name_sep};
 267     my $sep = $self->{name_sep};
 268     return join($self->{name_sep},
 269         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 270        split(/\Q$sep\E/,$label));
 271   }
 272   return $self->SUPER::_quote($label);
 273 }
 274
 275 sub limit_dialect {
 276     my $self = shift;
 277     $self->{limit_dialect} = shift if @_;
 278     return $self->{limit_dialect};
 279 }
 280
 281 sub quote_char {
 282     my $self = shift;
 283     $self->{quote_char} = shift if @_;
 284     return $self->{quote_char};
 285 }
 286
 287 sub name_sep {
 288     my $self = shift;
 289     $self->{name_sep} = shift if @_;
 290     return $self->{name_sep};
 291 }
 292
 293 } # End of BEGIN block
 294
 295 =head1 NAME
 296
 297 DBIx::Class::Storage::DBI - DBI storage handler
 298
 299 =head1 SYNOPSIS
 300
 301 =head1 DESCRIPTION
 302
 303 This class represents the connection to an RDBMS via L<DBI>.  See
 304 L<DBIx::Class::Storage> for general information.  This pod only
 305 documents DBI-specific methods and behaviors.
 306
 307 =head1 METHODS
 308
 309 =cut
 310
 311 sub new {
 312   my $new = shift->next::method(@_);
 313
 314   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 315   $new->transaction_depth(0);
 316   $new->_sql_maker_opts({});
 317   $new->{_in_dbh_do} = 0;
 318   $new->{_dbh_gen} = 0;
 319
 320   $new;
 321 }
 322
 323 =head2 connect_info
 324
 325 The arguments of C<connect_info> are always a single array reference.
 326
 327 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 328 encapsulates its argument list in an arrayref before calling
 329 C<connect_info> here.
 330
 331 The arrayref can either contain the same set of arguments one would
 332 normally pass to L<DBI/connect>, or a lone code reference which returns
 333 a connected database handle.
 334
 335 In either case, if the final argument in your connect_info happens
 336 to be a hashref, C<connect_info> will look there for several
 337 connection-specific options:
 338
 339 =over 4
 340
 341 =item on_connect_do
 342
 343 This can be set to an arrayref of literal sql statements, which will
 344 be executed immediately after making the connection to the database
 345 every time we [re-]connect.
 346
 347 =item disable_sth_caching
 348
 349 If set to a true value, this option will disable the caching of
 350 statement handles via L<DBI/prepare_cached>.
 351
 352 =item limit_dialect
 353
 354 Sets the limit dialect. This is useful for JDBC-bridge among others
 355 where the remote SQL-dialect cannot be determined by the name of the
 356 driver alone.
 357
 358 =item quote_char
 359
 360 Specifies what characters to use to quote table and column names. If
 361 you use this you will want to specify L<name_sep> as well.
 362
 363 quote_char expects either a single character, in which case is it is placed
 364 on either side of the table/column, or an arrayref of length 2 in which case the
 365 table/column name is placed between the elements.
 366
 367 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 368 use C<quote_char =E<gt> [qw/[ ]/]>.
 369
 370 =item name_sep
 371
 372 This only needs to be used in conjunction with L<quote_char>, and is used to
 373 specify the charecter that seperates elements (schemas, tables, columns) from
 374 each other. In most cases this is simply a C<.>.
 375
 376 =back
 377
 378 These options can be mixed in with your other L<DBI> connection attributes,
 379 or placed in a seperate hashref after all other normal L<DBI> connection
 380 arguments.
 381
 382 Every time C<connect_info> is invoked, any previous settings for
 383 these options will be cleared before setting the new ones, regardless of
 384 whether any options are specified in the new C<connect_info>.
 385
 386 Important note:  DBIC expects the returned database handle provided by
 387 a subref argument to have RaiseError set on it.  If it doesn't, things
 388 might not work very well, YMMV.  If you don't use a subref, DBIC will
 389 force this setting for you anyways.  Setting HandleError to anything
 390 other than simple exception object wrapper might cause problems too.
 391
 392 Examples:
 393
 394   # Simple SQLite connection
 395   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 396
 397   # Connect via subref
 398   ->connect_info([ sub { DBI->connect(...) } ]);
 399
 400   # A bit more complicated
 401   ->connect_info(
 402     [
 403       'dbi:Pg:dbname=foo',
 404       'postgres',
 405       'my_pg_password',
 406       { AutoCommit => 0 },
 407       { quote_char => q{"}, name_sep => q{.} },
 408     ]
 409   );
 410
 411   # Equivalent to the previous example
 412   ->connect_info(
 413     [
 414       'dbi:Pg:dbname=foo',
 415       'postgres',
 416       'my_pg_password',
 417       { AutoCommit => 0, quote_char => q{"}, name_sep => q{.} },
 418     ]
 419   );
 420
 421   # Subref + DBIC-specific connection options
 422   ->connect_info(
 423     [
 424       sub { DBI->connect(...) },
 425       {
 426           quote_char => q{`},
 427           name_sep => q{@},
 428           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 429           disable_sth_caching => 1,
 430       },
 431     ]
 432   );
 433
 434 =cut
 435
 436 sub connect_info {
 437   my ($self, $info_arg) = @_;
 438
 439   return $self->_connect_info if !$info_arg;
 440
 441   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 442   #  the new set of options
 443   $self->_sql_maker(undef);
 444   $self->_sql_maker_opts({});
 445
 446   my $info = [ @$info_arg ]; # copy because we can alter it
 447   my $last_info = $info->[-1];
 448   if(ref $last_info eq 'HASH') {
 449     for my $storage_opt (qw/on_connect_do disable_sth_caching/) {
 450       if(my $value = delete $last_info->{$storage_opt}) {
 451         $self->$storage_opt($value);
 452       }
 453     }
 454     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 455       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 456         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 457       }
 458     }
 459
 460     # Get rid of any trailing empty hashref
 461     pop(@$info) if !keys %$last_info;
 462   }
 463
 464   $self->_connect_info($info);
 465 }
 466
 467 =head2 on_connect_do
 468
 469 This method is deprecated in favor of setting via L</connect_info>.
 470
 471 =head2 dbh_do
 472
 473 Arguments: $subref, @extra_coderef_args?
 474
 475 Execute the given subref using the new exception-based connection management.
 476
 477 The first two arguments will be the storage object that C<dbh_do> was called
 478 on and a database handle to use.  Any additional arguments will be passed
 479 verbatim to the called subref as arguments 2 and onwards.
 480
 481 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 482 exception handling and reconnection (or failover in future subclasses).
 483
 484 Your subref should have no side-effects outside of the database, as
 485 there is the potential for your subref to be partially double-executed
 486 if the database connection was stale/dysfunctional.
 487
 488 Example:
 489
 490   my @stuff = $schema->storage->dbh_do(
 491     sub {
 492       my ($storage, $dbh, @cols) = @_;
 493       my $cols = join(q{, }, @cols);
 494       $dbh->selectrow_array("SELECT $cols FROM foo");
 495     },
 496     @column_list
 497   );
 498
 499 =cut
 500
 501 sub dbh_do {
 502   my $self = shift;
 503   my $coderef = shift;
 504
 505   ref $coderef eq 'CODE' or $self->throw_exception
 506     ('$coderef must be a CODE reference');
 507
 508   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do};
 509   local $self->{_in_dbh_do} = 1;
 510
 511   my @result;
 512   my $want_array = wantarray;
 513
 514   eval {
 515     $self->_verify_pid if $self->_dbh;
 516     $self->_populate_dbh if !$self->_dbh;
 517     if($want_array) {
 518         @result = $coderef->($self, $self->_dbh, @_);
 519     }
 520     elsif(defined $want_array) {
 521         $result[0] = $coderef->($self, $self->_dbh, @_);
 522     }
 523     else {
 524         $coderef->($self, $self->_dbh, @_);
 525     }
 526   };
 527
 528   my $exception = $@;
 529   if(!$exception) { return $want_array ? @result : $result[0] }
 530
 531   $self->throw_exception($exception) if $self->connected;
 532
 533   # We were not connected - reconnect and retry, but let any
 534   #  exception fall right through this time
 535   $self->_populate_dbh;
 536   $coderef->($self, $self->_dbh, @_);
 537 }
 538
 539 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 540 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 541 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 542 sub txn_do {
 543   my $self = shift;
 544   my $coderef = shift;
 545
 546   ref $coderef eq 'CODE' or $self->throw_exception
 547     ('$coderef must be a CODE reference');
 548
 549   local $self->{_in_dbh_do} = 1;
 550
 551   my @result;
 552   my $want_array = wantarray;
 553
 554   my $tried = 0;
 555   while(1) {
 556     eval {
 557       $self->_verify_pid if $self->_dbh;
 558       $self->_populate_dbh if !$self->_dbh;
 559
 560       $self->txn_begin;
 561       if($want_array) {
 562           @result = $coderef->(@_);
 563       }
 564       elsif(defined $want_array) {
 565           $result[0] = $coderef->(@_);
 566       }
 567       else {
 568           $coderef->(@_);
 569       }
 570       $self->txn_commit;
 571     };
 572
 573     my $exception = $@;
 574     if(!$exception) { return $want_array ? @result : $result[0] }
 575
 576     if($tried++ > 0 || $self->connected) {
 577       eval { $self->txn_rollback };
 578       my $rollback_exception = $@;
 579       if($rollback_exception) {
 580         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 581         $self->throw_exception($exception)  # propagate nested rollback
 582           if $rollback_exception =~ /$exception_class/;
 583
 584         $self->throw_exception(
 585           "Transaction aborted: ${exception}. "
 586           . "Rollback failed: ${rollback_exception}"
 587         );
 588       }
 589       $self->throw_exception($exception)
 590     }
 591
 592     # We were not connected, and was first try - reconnect and retry
 593     # via the while loop
 594     $self->_populate_dbh;
 595   }
 596 }
 597
 598 =head2 disconnect
 599
 600 Our C<disconnect> method also performs a rollback first if the
 601 database is not in C<AutoCommit> mode.
 602
 603 =cut
 604
 605 sub disconnect {
 606   my ($self) = @_;
 607
 608   if( $self->connected ) {
 609     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 610     $self->_dbh->disconnect;
 611     $self->_dbh(undef);
 612     $self->{_dbh_gen}++;
 613   }
 614 }
 615
 616 sub connected {
 617   my ($self) = @_;
 618
 619   if(my $dbh = $self->_dbh) {
 620       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 621           $self->_dbh(undef);
 622           $self->{_dbh_gen}++;
 623           return;
 624       }
 625       else {
 626           $self->_verify_pid;
 627       }
 628       return ($dbh->FETCH('Active') && $dbh->ping);
 629   }
 630
 631   return 0;
 632 }
 633
 634 # handle pid changes correctly
 635 #  NOTE: assumes $self->_dbh is a valid $dbh
 636 sub _verify_pid {
 637   my ($self) = @_;
 638
 639   return if $self->_conn_pid == $$;
 640
 641   $self->_dbh->{InactiveDestroy} = 1;
 642   $self->_dbh(undef);
 643   $self->{_dbh_gen}++;
 644
 645   return;
 646 }
 647
 648 sub ensure_connected {
 649   my ($self) = @_;
 650
 651   unless ($self->connected) {
 652     $self->_populate_dbh;
 653   }
 654 }
 655
 656 =head2 dbh
 657
 658 Returns the dbh - a data base handle of class L<DBI>.
 659
 660 =cut
 661
 662 sub dbh {
 663   my ($self) = @_;
 664
 665   $self->ensure_connected;
 666   return $self->_dbh;
 667 }
 668
 669 sub _sql_maker_args {
 670     my ($self) = @_;
 671
 672     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 673 }
 674
 675 sub sql_maker {
 676   my ($self) = @_;
 677   unless ($self->_sql_maker) {
 678     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 679   }
 680   return $self->_sql_maker;
 681 }
 682
 683 sub _populate_dbh {
 684   my ($self) = @_;
 685   my @info = @{$self->_connect_info || []};
 686   $self->_dbh($self->_connect(@info));
 687
 688   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 689     my $driver = $self->_dbh->{Driver}->{Name};
 690     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 691       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 692       $self->_rebless() if $self->can('_rebless');
 693     }
 694   }
 695
 696   # if on-connect sql statements are given execute them
 697   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 698     $self->debugobj->query_start($sql_statement) if $self->debug();
 699     $self->_dbh->do($sql_statement);
 700     $self->debugobj->query_end($sql_statement) if $self->debug();
 701   }
 702
 703   $self->_conn_pid($$);
 704   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 705 }
 706
 707 sub _connect {
 708   my ($self, @info) = @_;
 709
 710   $self->throw_exception("You failed to provide any connection info")
 711       if !@info;
 712
 713   my ($old_connect_via, $dbh);
 714
 715   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 716       $old_connect_via = $DBI::connect_via;
 717       $DBI::connect_via = 'connect';
 718   }
 719
 720   eval {
 721     if(ref $info[0] eq 'CODE') {
 722        $dbh = &{$info[0]}
 723     }
 724     else {
 725        $dbh = DBI->connect(@info);
 726        $dbh->{RaiseError} = 1;
 727        $dbh->{PrintError} = 0;
 728        $dbh->{PrintWarn} = 0;
 729     }
 730   };
 731
 732   $DBI::connect_via = $old_connect_via if $old_connect_via;
 733
 734   if (!$dbh || $@) {
 735     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 736   }
 737
 738   $dbh;
 739 }
 740
 741 sub _dbh_txn_begin {
 742   my ($self, $dbh) = @_;
 743   if ($dbh->{AutoCommit}) {
 744     $self->debugobj->txn_begin()
 745       if ($self->debug);
 746     $dbh->begin_work;
 747   }
 748 }
 749
 750 sub txn_begin {
 751   my $self = shift;
 752   $self->dbh_do($self->can('_dbh_txn_begin'))
 753     if $self->{transaction_depth}++ == 0;
 754 }
 755
 756 sub _dbh_txn_commit {
 757   my ($self, $dbh) = @_;
 758   if ($self->{transaction_depth} == 0) {
 759     unless ($dbh->{AutoCommit}) {
 760       $self->debugobj->txn_commit()
 761         if ($self->debug);
 762       $dbh->commit;
 763     }
 764   }
 765   else {
 766     if (--$self->{transaction_depth} == 0) {
 767       $self->debugobj->txn_commit()
 768         if ($self->debug);
 769       $dbh->commit;
 770     }
 771   }
 772 }
 773
 774 sub txn_commit {
 775   my $self = shift;
 776   $self->dbh_do($self->can('_dbh_txn_commit'));
 777 }
 778
 779 sub _dbh_txn_rollback {
 780   my ($self, $dbh) = @_;
 781   if ($self->{transaction_depth} == 0) {
 782     unless ($dbh->{AutoCommit}) {
 783       $self->debugobj->txn_rollback()
 784         if ($self->debug);
 785       $dbh->rollback;
 786     }
 787   }
 788   else {
 789     if (--$self->{transaction_depth} == 0) {
 790       $self->debugobj->txn_rollback()
 791         if ($self->debug);
 792       $dbh->rollback;
 793     }
 794     else {
 795       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 796     }
 797   }
 798 }
 799
 800 sub txn_rollback {
 801   my $self = shift;
 802
 803   eval { $self->dbh_do($self->can('_dbh_txn_rollback')) };
 804   if ($@) {
 805     my $error = $@;
 806     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 807     $error =~ /$exception_class/ and $self->throw_exception($error);
 808     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 809     $self->throw_exception($error);          # resets the transaction depth
 810   }
 811 }
 812
 813 # This used to be the top-half of _execute.  It was split out to make it
 814 #  easier to override in NoBindVars without duping the rest.  It takes up
 815 #  all of _execute's args, and emits $sql, @bind.
 816 sub _prep_for_execute {
 817   my ($self, $op, $extra_bind, $ident, @args) = @_;
 818
 819   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 820   unshift(@bind,
 821     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 822       if $extra_bind;
 823   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 824
 825   return ($sql, @bind);
 826 }
 827
 828 sub _execute {
 829   my ($self, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 830
 831   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 832   unshift(@bind,
 833     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 834       if $extra_bind;
 835   if ($self->debug) {
 836       my @debug_bind =
 837         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 838       $self->debugobj->query_start($sql, @debug_bind);
 839   }
 840   my $sth = eval { $self->sth($sql,$op) };
 841
 842   if (!$sth || $@) {
 843     $self->throw_exception(
 844       'no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql"
 845     );
 846   }
 847
 848   my $rv;
 849   if ($sth) {
 850     my $time = time();
 851
 852     $rv = eval {
 853
 854       my $placeholder_index = 1;
 855
 856       foreach my $bound (@bind) {
 857
 858         my $attributes = {};
 859         my($column_name, @data) = @$bound;
 860
 861         if( $bind_attributes ) {
 862           $attributes = $bind_attributes->{$column_name}
 863           if defined $bind_attributes->{$column_name};
 864         }
 865
 866                 foreach my $data (@data)
 867                 {
 868           $data = ref $data ? ''.$data : $data; # stringify args
 869
 870           $sth->bind_param($placeholder_index, $data, $attributes);
 871           $placeholder_index++;
 872                 }
 873       }
 874       $sth->execute();
 875     };
 876
 877     if ($@ || !$rv) {
 878       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 879     }
 880   } else {
 881     $self->throw_exception("'$sql' did not generate a statement.");
 882   }
 883   if ($self->debug) {
 884      my @debug_bind =
 885        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 886      $self->debugobj->query_end($sql, @debug_bind);
 887   }
 888   return (wantarray ? ($rv, $sth, @bind) : $rv);
 889 }
 890
 891 sub insert {
 892   my ($self, $source, $to_insert) = @_;
 893
 894   my $ident = $source->from;
 895   my $bind_attributes = $self->source_bind_attributes($source);
 896
 897   $self->throw_exception(
 898     "Couldn't insert ".join(', ',
 899       map "$_ => $to_insert->{$_}", keys %$to_insert
 900     )." into ${ident}"
 901   ) unless ($self->_execute('insert' => [], $ident, $bind_attributes, $to_insert));
 902   return $to_insert;
 903 }
 904
 905 ## Still not quite perfect, and EXPERIMENTAL
 906 ## Currently it is assumed that all values passed will be "normal", i.e. not
 907 ## scalar refs, or at least, all the same type as the first set, the statement is
 908 ## only prepped once.
 909 sub insert_bulk {
 910   my ($self, $source, $cols, $data) = @_;
 911   my %colvalues;
 912   my $table = $source->from;
 913   @colvalues{@$cols} = (0..$#$cols);
 914   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 915
 916   if ($self->debug) {
 917       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 918       $self->debugobj->query_start($sql, @debug_bind);
 919   }
 920   my $sth = $self->sth($sql);
 921
 922 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 923
 924   my $rv;
 925
 926   ## This must be an arrayref, else nothing works!
 927
 928   my $tuple_status = [];
 929
 930   ##use Data::Dumper;
 931   ##print STDERR Dumper( $data, $sql, [@bind] );
 932
 933   if ($sth) {
 934
 935     my $time = time();
 936
 937     #$rv = eval {
 938         #
 939         #  $sth->execute_array({
 940
 941         #    ArrayTupleFetch => sub {
 942
 943         #      my $values = shift @$data;
 944     #      return if !$values;
 945     #      return [ @{$values}[@bind] ];
 946         #    },
 947
 948         #    ArrayTupleStatus => $tuple_status,
 949         #  })
 950     #};
 951
 952         ## Get the bind_attributes, if any exist
 953     my $bind_attributes = $self->source_bind_attributes($source);
 954
 955         ## Bind the values and execute
 956         $rv = eval {
 957
 958      my $placeholder_index = 1;
 959
 960         foreach my $bound (@bind) {
 961
 962           my $attributes = {};
 963           my ($column_name, $data_index) = @$bound;
 964
 965           if( $bind_attributes ) {
 966             $attributes = $bind_attributes->{$column_name}
 967             if defined $bind_attributes->{$column_name};
 968           }
 969
 970                   my @data = map { $_->[$data_index] } @$data;
 971
 972           $sth->bind_param_array( $placeholder_index, [@data], $attributes );
 973           $placeholder_index++;
 974       }
 975           $sth->execute_array( {ArrayTupleStatus => $tuple_status} );
 976
 977         };
 978
 979     if ($@ || !defined $rv) {
 980       my $errors = '';
 981       foreach my $tuple (@$tuple_status)
 982       {
 983           $errors .= "\n" . $tuple->[1] if(ref $tuple);
 984       }
 985       $self->throw_exception("Error executing '$sql': ".($@ || $errors));
 986     }
 987   } else {
 988     $self->throw_exception("'$sql' did not generate a statement.");
 989   }
 990   if ($self->debug) {
 991       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 992       $self->debugobj->query_end($sql, @debug_bind);
 993   }
 994   return (wantarray ? ($rv, $sth, @bind) : $rv);
 995 }
 996
 997 sub update {
 998   my $self = shift @_;
 999   my $source = shift @_;
1000   my $bind_attributes = $self->source_bind_attributes($source);
1001   my $ident = $source->from;
1002
1003   return $self->_execute('update' => [], $ident, $bind_attributes, @_);
1004 }
1005
1006
1007 sub delete {
1008   my $self = shift @_;
1009   my $source = shift @_;
1010
1011   my $bind_attrs = {}; ## If ever it's needed...
1012   my $ident = $source->from;
1013
1014   return $self->_execute('delete' => [], $ident, $bind_attrs, @_);
1015 }
1016
1017 sub _select {
1018   my ($self, $ident, $select, $condition, $attrs) = @_;
1019   my $order = $attrs->{order_by};
1020   if (ref $condition eq 'SCALAR') {
1021     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1022   }
1023   if (exists $attrs->{group_by} || $attrs->{having}) {
1024     $order = {
1025       group_by => $attrs->{group_by},
1026       having => $attrs->{having},
1027       ($order ? (order_by => $order) : ())
1028     };
1029   }
1030   my $bind_attrs = {}; ## Future support
1031   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1032   if ($attrs->{software_limit} ||
1033       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1034         $attrs->{software_limit} = 1;
1035   } else {
1036     $self->throw_exception("rows attribute must be positive if present")
1037       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1038     push @args, $attrs->{rows}, $attrs->{offset};
1039   }
1040   return $self->_execute(@args);
1041 }
1042
1043 sub source_bind_attributes {
1044   my ($self, $source) = @_;
1045
1046   my $bind_attributes;
1047   foreach my $column ($source->columns) {
1048
1049     my $data_type = $source->column_info($column)->{data_type} || '';
1050     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1051          if $data_type;
1052   }
1053
1054   return $bind_attributes;
1055 }
1056
1057 =head2 select
1058
1059 =over 4
1060
1061 =item Arguments: $ident, $select, $condition, $attrs
1062
1063 =back
1064
1065 Handle a SQL select statement.
1066
1067 =cut
1068
1069 sub select {
1070   my $self = shift;
1071   my ($ident, $select, $condition, $attrs) = @_;
1072   return $self->cursor->new($self, \@_, $attrs);
1073 }
1074
1075 sub select_single {
1076   my $self = shift;
1077   my ($rv, $sth, @bind) = $self->_select(@_);
1078   my @row = $sth->fetchrow_array;
1079   # Need to call finish() to work round broken DBDs
1080   $sth->finish();
1081   return @row;
1082 }
1083
1084 =head2 sth
1085
1086 =over 4
1087
1088 =item Arguments: $sql
1089
1090 =back
1091
1092 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1093
1094 =cut
1095
1096 sub _dbh_sth {
1097   my ($self, $dbh, $sql) = @_;
1098
1099   # 3 is the if_active parameter which avoids active sth re-use
1100   my $sth = $self->disable_sth_caching
1101     ? $dbh->prepare($sql)
1102     : $dbh->prepare_cached($sql, {}, 3);
1103
1104   $self->throw_exception(
1105     'no sth generated via sql (' . ($@ || $dbh->errstr) . "): $sql"
1106   ) if !$sth;
1107
1108   $sth;
1109 }
1110
1111 sub sth {
1112   my ($self, $sql) = @_;
1113   $self->dbh_do($self->can('_dbh_sth'), $sql);
1114 }
1115
1116 sub _dbh_columns_info_for {
1117   my ($self, $dbh, $table) = @_;
1118
1119   if ($dbh->can('column_info')) {
1120     my %result;
1121     eval {
1122       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1123       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1124       $sth->execute();
1125       while ( my $info = $sth->fetchrow_hashref() ){
1126         my %column_info;
1127         $column_info{data_type}   = $info->{TYPE_NAME};
1128         $column_info{size}      = $info->{COLUMN_SIZE};
1129         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1130         $column_info{default_value} = $info->{COLUMN_DEF};
1131         my $col_name = $info->{COLUMN_NAME};
1132         $col_name =~ s/^\"(.*)\"$/$1/;
1133
1134         $result{$col_name} = \%column_info;
1135       }
1136     };
1137     return \%result if !$@ && scalar keys %result;
1138   }
1139
1140   my %result;
1141   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
1142   $sth->execute;
1143   my @columns = @{$sth->{NAME_lc}};
1144   for my $i ( 0 .. $#columns ){
1145     my %column_info;
1146     my $type_num = $sth->{TYPE}->[$i];
1147     my $type_name;
1148     if(defined $type_num && $dbh->can('type_info')) {
1149       my $type_info = $dbh->type_info($type_num);
1150       $type_name = $type_info->{TYPE_NAME} if $type_info;
1151     }
1152     $column_info{data_type} = $type_name ? $type_name : $type_num;
1153     $column_info{size} = $sth->{PRECISION}->[$i];
1154     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1155
1156     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1157       $column_info{data_type} = $1;
1158       $column_info{size}    = $2;
1159     }
1160
1161     $result{$columns[$i]} = \%column_info;
1162   }
1163
1164   return \%result;
1165 }
1166
1167 sub columns_info_for {
1168   my ($self, $table) = @_;
1169   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1170 }
1171
1172 =head2 last_insert_id
1173
1174 Return the row id of the last insert.
1175
1176 =cut
1177
1178 sub _dbh_last_insert_id {
1179     my ($self, $dbh, $source, $col) = @_;
1180     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1181     $dbh->func('last_insert_rowid');
1182 }
1183
1184 sub last_insert_id {
1185   my $self = shift;
1186   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1187 }
1188
1189 =head2 sqlt_type
1190
1191 Returns the database driver name.
1192
1193 =cut
1194
1195 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1196
1197 =head2 bind_attribute_by_data_type
1198
1199 Given a datatype from column info, returns a database specific bind attribute for
1200 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1201 just handle it.
1202
1203 Generally only needed for special case column types, like bytea in postgres.
1204
1205 =cut
1206
1207 sub bind_attribute_by_data_type {
1208     return;
1209 }
1210
1211 =head2 create_ddl_dir (EXPERIMENTAL)
1212
1213 =over 4
1214
1215 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1216
1217 =back
1218
1219 Creates a SQL file based on the Schema, for each of the specified
1220 database types, in the given directory.
1221
1222 Note that this feature is currently EXPERIMENTAL and may not work correctly
1223 across all databases, or fully handle complex relationships.
1224
1225 =cut
1226
1227 sub create_ddl_dir
1228 {
1229   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1230
1231   if(!$dir || !-d $dir)
1232   {
1233     warn "No directory given, using ./\n";
1234     $dir = "./";
1235   }
1236   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1237   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1238   $version ||= $schema->VERSION || '1.x';
1239   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1240
1241   eval "use SQL::Translator";
1242   $self->throw_exception("Can't create a ddl file without SQL::Translator: $@") if $@;
1243
1244   my $sqlt = SQL::Translator->new({
1245 #      debug => 1,
1246       add_drop_table => 1,
1247   });
1248   foreach my $db (@$databases)
1249   {
1250     $sqlt->reset();
1251     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1252 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1253     $sqlt = $self->configure_sqlt($sqlt, $db);
1254     $sqlt->data($schema);
1255     $sqlt->producer($db);
1256
1257     my $file;
1258     my $filename = $schema->ddl_filename($db, $dir, $version);
1259     if(-e $filename)
1260     {
1261       warn("$filename already exists, skipping $db");
1262       next;
1263     }
1264
1265     my $output = $sqlt->translate;
1266     if(!$output)
1267     {
1268       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1269       next;
1270     }
1271     if(!open($file, ">$filename"))
1272     {
1273         $self->throw_exception("Can't open $filename for writing ($!)");
1274         next;
1275     }
1276     print $file $output;
1277     close($file);
1278
1279     if($preversion)
1280     {
1281       eval "use SQL::Translator::Diff";
1282       if($@)
1283       {
1284         warn("Can't diff versions without SQL::Translator::Diff: $@");
1285         next;
1286       }
1287
1288       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1289 #      print "Previous version $prefilename\n";
1290       if(!-e $prefilename)
1291       {
1292         warn("No previous schema file found ($prefilename)");
1293         next;
1294       }
1295       #### We need to reparse the SQLite file we just wrote, so that
1296       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1297       ##   FIXME: rip Diff to pieces!
1298 #      my $target_schema = $sqlt->schema;
1299 #      unless ( $target_schema->name ) {
1300 #        $target_schema->name( $filename );
1301 #      }
1302       my @input;
1303       push @input, {file => $prefilename, parser => $db};
1304       push @input, {file => $filename, parser => $db};
1305       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1306         my $file   = $_->{'file'};
1307         my $parser = $_->{'parser'};
1308
1309         my $t = SQL::Translator->new;
1310         $t->debug( 0 );
1311         $t->trace( 0 );
1312         $t->parser( $parser )            or die $t->error;
1313         my $out = $t->translate( $file ) or die $t->error;
1314         my $schema = $t->schema;
1315         unless ( $schema->name ) {
1316           $schema->name( $file );
1317         }
1318         ($schema, $parser);
1319       } @input;
1320
1321       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1322                                                     $target_schema, $db,
1323                                                     {}
1324                                                    );
1325       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1326       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1327       if(-e $difffile)
1328       {
1329         warn("$difffile already exists, skipping");
1330         next;
1331       }
1332       if(!open $file, ">$difffile")
1333       {
1334         $self->throw_exception("Can't write to $difffile ($!)");
1335         next;
1336       }
1337       print $file $diff;
1338       close($file);
1339     }
1340   }
1341 }
1342
1343 sub configure_sqlt() {
1344   my $self = shift;
1345   my $tr = shift;
1346   my $db = shift || $self->sqlt_type;
1347   if ($db eq 'PostgreSQL') {
1348     $tr->quote_table_names(0);
1349     $tr->quote_field_names(0);
1350   }
1351   return $tr;
1352 }
1353
1354 =head2 deployment_statements
1355
1356 =over 4
1357
1358 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1359
1360 =back
1361
1362 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1363 The database driver name is given by C<$type>, though the value from
1364 L</sqlt_type> is used if it is not specified.
1365
1366 C<$directory> is used to return statements from files in a previously created
1367 L</create_ddl_dir> directory and is optional. The filenames are constructed
1368 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1369
1370 If no C<$directory> is specified then the statements are constructed on the
1371 fly using L<SQL::Translator> and C<$version> is ignored.
1372
1373 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1374
1375 =cut
1376
1377 sub deployment_statements {
1378   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1379   # Need to be connected to get the correct sqlt_type
1380   $self->ensure_connected() unless $type;
1381   $type ||= $self->sqlt_type;
1382   $version ||= $schema->VERSION || '1.x';
1383   $dir ||= './';
1384   my $filename = $schema->ddl_filename($type, $dir, $version);
1385   if(-f $filename)
1386   {
1387       my $file;
1388       open($file, "<$filename")
1389         or $self->throw_exception("Can't open $filename ($!)");
1390       my @rows = <$file>;
1391       close($file);
1392       return join('', @rows);
1393   }
1394
1395   eval "use SQL::Translator";
1396   if(!$@)
1397   {
1398     eval "use SQL::Translator::Parser::DBIx::Class;";
1399     $self->throw_exception($@) if $@;
1400     eval "use SQL::Translator::Producer::${type};";
1401     $self->throw_exception($@) if $@;
1402
1403     # sources needs to be a parser arg, but for simplicty allow at top level
1404     # coming in
1405     $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1406         if exists $sqltargs->{sources};
1407
1408     my $tr = SQL::Translator->new(%$sqltargs);
1409     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1410     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1411   }
1412
1413   $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
1414   return;
1415
1416 }
1417
1418 sub deploy {
1419   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1420   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1421     for ( split(";\n", $statement)) {
1422       next if($_ =~ /^--/);
1423       next if(!$_);
1424 #      next if($_ =~ /^DROP/m);
1425       next if($_ =~ /^BEGIN TRANSACTION/m);
1426       next if($_ =~ /^COMMIT/m);
1427       next if $_ =~ /^\s+$/; # skip whitespace only
1428       $self->debugobj->query_start($_) if $self->debug;
1429       $self->dbh->do($_) or warn "SQL was:\n $_"; # XXX exceptions?
1430       $self->debugobj->query_end($_) if $self->debug;
1431     }
1432   }
1433 }
1434
1435 =head2 datetime_parser
1436
1437 Returns the datetime parser class
1438
1439 =cut
1440
1441 sub datetime_parser {
1442   my $self = shift;
1443   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
1444 }
1445
1446 =head2 datetime_parser_type
1447
1448 Defines (returns) the datetime parser class - currently hardwired to
1449 L<DateTime::Format::MySQL>
1450
1451 =cut
1452
1453 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1454
1455 =head2 build_datetime_parser
1456
1457 See L</datetime_parser>
1458
1459 =cut
1460
1461 sub build_datetime_parser {
1462   my $self = shift;
1463   my $type = $self->datetime_parser_type(@_);
1464   eval "use ${type}";
1465   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1466   return $type;
1467 }
1468
1469 sub DESTROY {
1470   my $self = shift;
1471   return if !$self->_dbh;
1472   $self->_verify_pid;
1473   $self->_dbh(undef);
1474 }
1475
1476 1;
1477
1478 =head1 SQL METHODS
1479
1480 The module defines a set of methods within the DBIC::SQL::Abstract
1481 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1482 SQL query functions.
1483
1484 The following methods are extended:-
1485
1486 =over 4
1487
1488 =item delete
1489
1490 =item insert
1491
1492 =item select
1493
1494 =item update
1495
1496 =item limit_dialect
1497
1498 See L</connect_info> for details.
1499 For setting, this method is deprecated in favor of L</connect_info>.
1500
1501 =item quote_char
1502
1503 See L</connect_info> for details.
1504 For setting, this method is deprecated in favor of L</connect_info>.
1505
1506 =item name_sep
1507
1508 See L</connect_info> for details.
1509 For setting, this method is deprecated in favor of L</connect_info>.
1510
1511 =back
1512
1513 =head1 AUTHORS
1514
1515 Matt S. Trout <mst@shadowcatsystems.co.uk>
1516
1517 Andy Grundman <andy@hybridized.org>
1518
1519 =head1 LICENSE
1520
1521 You may distribute this code under the same terms as Perl itself.
1522
1523 =cut