lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util qw/blessed weaken/;
  13
  14 __PACKAGE__->mk_group_accessors('simple' =>
  15     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  16        _conn_pid _conn_tid disable_sth_caching cursor on_connect_do
  17        on_disconnect_do transaction_depth unsafe _dbh_autocommit/
  18 );
  19
  20 BEGIN {
  21
  22 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  23
  24 use base qw/SQL::Abstract::Limit/;
  25
  26 # This prevents the caching of $dbh in S::A::L, I believe
  27 sub new {
  28   my $self = shift->SUPER::new(@_);
  29
  30   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  31   #   it with what it resolves to:
  32   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  33     if ref $self->{limit_dialect};
  34
  35   $self;
  36 }
  37
  38 sub _RowNumberOver {
  39   my ($self, $sql, $order, $rows, $offset ) = @_;
  40
  41   $offset += 1;
  42   my $last = $rows + $offset;
  43   my ( $order_by ) = $self->_order_by( $order );
  44
  45   $sql = <<"";
  46 SELECT * FROM
  47 (
  48    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  49       $sql
  50       $order_by
  51    ) Q1
  52 ) Q2
  53 WHERE ROW_NUM BETWEEN $offset AND $last
  54
  55   return $sql;
  56 }
  57
  58
  59 # While we're at it, this should make LIMIT queries more efficient,
  60 #  without digging into things too deeply
  61 use Scalar::Util 'blessed';
  62 sub _find_syntax {
  63   my ($self, $syntax) = @_;
  64   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  65   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  66     return 'RowNumberOver';
  67   }
  68
  69   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  70 }
  71
  72 sub select {
  73   my ($self, $table, $fields, $where, $order, @rest) = @_;
  74   $table = $self->_quote($table) unless ref($table);
  75   local $self->{rownum_hack_count} = 1
  76     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  77   @rest = (-1) unless defined $rest[0];
  78   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  79     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  80   local $self->{having_bind} = [];
  81   my ($sql, @ret) = $self->SUPER::select(
  82     $table, $self->_recurse_fields($fields), $where, $order, @rest
  83   );
  84   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  85 }
  86
  87 sub insert {
  88   my $self = shift;
  89   my $table = shift;
  90   $table = $self->_quote($table) unless ref($table);
  91   $self->SUPER::insert($table, @_);
  92 }
  93
  94 sub update {
  95   my $self = shift;
  96   my $table = shift;
  97   $table = $self->_quote($table) unless ref($table);
  98   $self->SUPER::update($table, @_);
  99 }
 100
 101 sub delete {
 102   my $self = shift;
 103   my $table = shift;
 104   $table = $self->_quote($table) unless ref($table);
 105   $self->SUPER::delete($table, @_);
 106 }
 107
 108 sub _emulate_limit {
 109   my $self = shift;
 110   if ($_[3] == -1) {
 111     return $_[1].$self->_order_by($_[2]);
 112   } else {
 113     return $self->SUPER::_emulate_limit(@_);
 114   }
 115 }
 116
 117 sub _recurse_fields {
 118   my ($self, $fields, $params) = @_;
 119   my $ref = ref $fields;
 120   return $self->_quote($fields) unless $ref;
 121   return $$fields if $ref eq 'SCALAR';
 122
 123   if ($ref eq 'ARRAY') {
 124     return join(', ', map {
 125       $self->_recurse_fields($_)
 126         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 127           ? ' AS col'.$self->{rownum_hack_count}++
 128           : '')
 129       } @$fields);
 130   } elsif ($ref eq 'HASH') {
 131     foreach my $func (keys %$fields) {
 132       return $self->_sqlcase($func)
 133         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 134     }
 135   }
 136 }
 137
 138 sub _order_by {
 139   my $self = shift;
 140   my $ret = '';
 141   my @extra;
 142   if (ref $_[0] eq 'HASH') {
 143     if (defined $_[0]->{group_by}) {
 144       $ret = $self->_sqlcase(' group by ')
 145         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 146     }
 147     if (defined $_[0]->{having}) {
 148       my $frag;
 149       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 150       push(@{$self->{having_bind}}, @extra);
 151       $ret .= $self->_sqlcase(' having ').$frag;
 152     }
 153     if (defined $_[0]->{order_by}) {
 154       $ret .= $self->_order_by($_[0]->{order_by});
 155     }
 156   } elsif (ref $_[0] eq 'SCALAR') {
 157     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 158   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 159     my @order = @{+shift};
 160     $ret = $self->_sqlcase(' order by ')
 161           .join(', ', map {
 162                         my $r = $self->_order_by($_, @_);
 163                         $r =~ s/^ ?ORDER BY //i;
 164                         $r;
 165                       } @order);
 166   } else {
 167     $ret = $self->SUPER::_order_by(@_);
 168   }
 169   return $ret;
 170 }
 171
 172 sub _order_directions {
 173   my ($self, $order) = @_;
 174   $order = $order->{order_by} if ref $order eq 'HASH';
 175   return $self->SUPER::_order_directions($order);
 176 }
 177
 178 sub _table {
 179   my ($self, $from) = @_;
 180   if (ref $from eq 'ARRAY') {
 181     return $self->_recurse_from(@$from);
 182   } elsif (ref $from eq 'HASH') {
 183     return $self->_make_as($from);
 184   } else {
 185     return $from; # would love to quote here but _table ends up getting called
 186                   # twice during an ->select without a limit clause due to
 187                   # the way S::A::Limit->select works. should maybe consider
 188                   # bypassing this and doing S::A::select($self, ...) in
 189                   # our select method above. meantime, quoting shims have
 190                   # been added to select/insert/update/delete here
 191   }
 192 }
 193
 194 sub _recurse_from {
 195   my ($self, $from, @join) = @_;
 196   my @sqlf;
 197   push(@sqlf, $self->_make_as($from));
 198   foreach my $j (@join) {
 199     my ($to, $on) = @$j;
 200
 201     # check whether a join type exists
 202     my $join_clause = '';
 203     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 204     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 205       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 206     } else {
 207       $join_clause = ' JOIN ';
 208     }
 209     push(@sqlf, $join_clause);
 210
 211     if (ref $to eq 'ARRAY') {
 212       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 213     } else {
 214       push(@sqlf, $self->_make_as($to));
 215     }
 216     push(@sqlf, ' ON ', $self->_join_condition($on));
 217   }
 218   return join('', @sqlf);
 219 }
 220
 221 sub _make_as {
 222   my ($self, $from) = @_;
 223   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 224                      reverse each %{$self->_skip_options($from)});
 225 }
 226
 227 sub _skip_options {
 228   my ($self, $hash) = @_;
 229   my $clean_hash = {};
 230   $clean_hash->{$_} = $hash->{$_}
 231     for grep {!/^-/} keys %$hash;
 232   return $clean_hash;
 233 }
 234
 235 sub _join_condition {
 236   my ($self, $cond) = @_;
 237   if (ref $cond eq 'HASH') {
 238     my %j;
 239     for (keys %$cond) {
 240       my $v = $cond->{$_};
 241       if (ref $v) {
 242         # XXX no throw_exception() in this package and croak() fails with strange results
 243         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 244             if ref($v) ne 'SCALAR';
 245         $j{$_} = $v;
 246       }
 247       else {
 248         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 249       }
 250     };
 251     return scalar($self->_recurse_where(\%j));
 252   } elsif (ref $cond eq 'ARRAY') {
 253     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 254   } else {
 255     die "Can't handle this yet!";
 256   }
 257 }
 258
 259 sub _quote {
 260   my ($self, $label) = @_;
 261   return '' unless defined $label;
 262   return "*" if $label eq '*';
 263   return $label unless $self->{quote_char};
 264   if(ref $self->{quote_char} eq "ARRAY"){
 265     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 266       if !defined $self->{name_sep};
 267     my $sep = $self->{name_sep};
 268     return join($self->{name_sep},
 269         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 270        split(/\Q$sep\E/,$label));
 271   }
 272   return $self->SUPER::_quote($label);
 273 }
 274
 275 sub limit_dialect {
 276     my $self = shift;
 277     $self->{limit_dialect} = shift if @_;
 278     return $self->{limit_dialect};
 279 }
 280
 281 sub quote_char {
 282     my $self = shift;
 283     $self->{quote_char} = shift if @_;
 284     return $self->{quote_char};
 285 }
 286
 287 sub name_sep {
 288     my $self = shift;
 289     $self->{name_sep} = shift if @_;
 290     return $self->{name_sep};
 291 }
 292
 293 } # End of BEGIN block
 294
 295 =head1 NAME
 296
 297 DBIx::Class::Storage::DBI - DBI storage handler
 298
 299 =head1 SYNOPSIS
 300
 301 =head1 DESCRIPTION
 302
 303 This class represents the connection to an RDBMS via L<DBI>.  See
 304 L<DBIx::Class::Storage> for general information.  This pod only
 305 documents DBI-specific methods and behaviors.
 306
 307 =head1 METHODS
 308
 309 =cut
 310
 311 sub new {
 312   my $new = shift->next::method(@_);
 313
 314   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 315   $new->transaction_depth(0);
 316   $new->_sql_maker_opts({});
 317   $new->{_in_dbh_do} = 0;
 318   $new->{_dbh_gen} = 0;
 319
 320   $new;
 321 }
 322
 323 =head2 connect_info
 324
 325 The arguments of C<connect_info> are always a single array reference.
 326
 327 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 328 encapsulates its argument list in an arrayref before calling
 329 C<connect_info> here.
 330
 331 The arrayref can either contain the same set of arguments one would
 332 normally pass to L<DBI/connect>, or a lone code reference which returns
 333 a connected database handle.  Please note that the L<DBI> docs
 334 recommend that you always explicitly set C<AutoCommit> to either
 335 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 336 to C<1>, and that you perform transactions via our L</txn_do>
 337 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 338 set it to zero.  This is the default for most DBDs.  See below for more
 339 details.
 340
 341 In either case, if the final argument in your connect_info happens
 342 to be a hashref, C<connect_info> will look there for several
 343 connection-specific options:
 344
 345 =over 4
 346
 347 =item on_connect_do
 348
 349 Specifies things to do immediately after connecting or re-connecting to
 350 the database.  Its value may contain:
 351
 352 =over
 353
 354 =item an array reference
 355
 356 This contains SQL statements to execute in order.  Each element contains
 357 a string or a code reference that returns a string.
 358
 359 =item a code reference
 360
 361 This contains some code to execute.  Unlike code references within an
 362 array reference, its return value is ignored.
 363
 364 =back
 365
 366 =item on_disconnect_do
 367
 368 Takes arguments in the same for as L<on_connect_do> and executes them
 369 immediately before disconnecting from the database.
 370
 371 Note, this only runs if you explicitly call L<disconnect> on the
 372 storage object.
 373
 374 =item disable_sth_caching
 375
 376 If set to a true value, this option will disable the caching of
 377 statement handles via L<DBI/prepare_cached>.
 378
 379 =item limit_dialect
 380
 381 Sets the limit dialect. This is useful for JDBC-bridge among others
 382 where the remote SQL-dialect cannot be determined by the name of the
 383 driver alone.
 384
 385 =item quote_char
 386
 387 Specifies what characters to use to quote table and column names. If
 388 you use this you will want to specify L<name_sep> as well.
 389
 390 quote_char expects either a single character, in which case is it is placed
 391 on either side of the table/column, or an arrayref of length 2 in which case the
 392 table/column name is placed between the elements.
 393
 394 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 395 use C<quote_char =E<gt> [qw/[ ]/]>.
 396
 397 =item name_sep
 398
 399 This only needs to be used in conjunction with L<quote_char>, and is used to
 400 specify the charecter that seperates elements (schemas, tables, columns) from
 401 each other. In most cases this is simply a C<.>.
 402
 403 =item unsafe
 404
 405 This Storage driver normally installs its own C<HandleError>, sets
 406 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 407 all database handles, including those supplied by a coderef.  It does this
 408 so that it can have consistent and useful error behavior.
 409
 410 If you set this option to a true value, Storage will not do its usual
 411 modifications to the database handle's attributes, and instead relies on
 412 the settings in your connect_info DBI options (or the values you set in
 413 your connection coderef, in the case that you are connecting via coderef).
 414
 415 Note that your custom settings can cause Storage to malfunction,
 416 especially if you set a C<HandleError> handler that suppresses exceptions
 417 and/or disable C<RaiseError>.
 418
 419 =back
 420
 421 These options can be mixed in with your other L<DBI> connection attributes,
 422 or placed in a seperate hashref after all other normal L<DBI> connection
 423 arguments.
 424
 425 Every time C<connect_info> is invoked, any previous settings for
 426 these options will be cleared before setting the new ones, regardless of
 427 whether any options are specified in the new C<connect_info>.
 428
 429 Another Important Note:
 430
 431 DBIC can do some wonderful magic with handling exceptions,
 432 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 433 combined with C<txn_do> for transaction support.
 434
 435 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 436 in an assumed transaction between commits, and you're telling us you'd
 437 like to manage that manually.  A lot of DBIC's magic protections
 438 go away.  We can't protect you from exceptions due to database
 439 disconnects because we don't know anything about how to restart your
 440 transactions.  You're on your own for handling all sorts of exceptional
 441 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 442 be with raw DBI.
 443
 444 Examples:
 445
 446   # Simple SQLite connection
 447   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 448
 449   # Connect via subref
 450   ->connect_info([ sub { DBI->connect(...) } ]);
 451
 452   # A bit more complicated
 453   ->connect_info(
 454     [
 455       'dbi:Pg:dbname=foo',
 456       'postgres',
 457       'my_pg_password',
 458       { AutoCommit => 1 },
 459       { quote_char => q{"}, name_sep => q{.} },
 460     ]
 461   );
 462
 463   # Equivalent to the previous example
 464   ->connect_info(
 465     [
 466       'dbi:Pg:dbname=foo',
 467       'postgres',
 468       'my_pg_password',
 469       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 470     ]
 471   );
 472
 473   # Subref + DBIC-specific connection options
 474   ->connect_info(
 475     [
 476       sub { DBI->connect(...) },
 477       {
 478           quote_char => q{`},
 479           name_sep => q{@},
 480           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 481           disable_sth_caching => 1,
 482       },
 483     ]
 484   );
 485
 486 =cut
 487
 488 sub connect_info {
 489   my ($self, $info_arg) = @_;
 490
 491   return $self->_connect_info if !$info_arg;
 492
 493   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 494   #  the new set of options
 495   $self->_sql_maker(undef);
 496   $self->_sql_maker_opts({});
 497   $self->_connect_info([@$info_arg]); # copy for _connect_info
 498
 499   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 500
 501   my $last_info = $dbi_info->[-1];
 502   if(ref $last_info eq 'HASH') {
 503     $last_info = { %$last_info }; # so delete is non-destructive
 504     my @storage_option =
 505        qw/on_connect_do on_disconnect_do disable_sth_caching unsafe/;
 506     for my $storage_opt (@storage_option) {
 507       if(my $value = delete $last_info->{$storage_opt}) {
 508         $self->$storage_opt($value);
 509       }
 510     }
 511     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 512       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 513         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 514       }
 515     }
 516     # re-insert modified hashref
 517     $dbi_info->[-1] = $last_info;
 518
 519     # Get rid of any trailing empty hashref
 520     pop(@$dbi_info) if !keys %$last_info;
 521   }
 522   $self->_dbi_connect_info($dbi_info);
 523
 524   $self->_connect_info;
 525 }
 526
 527 =head2 on_connect_do
 528
 529 This method is deprecated in favor of setting via L</connect_info>.
 530
 531 =head2 dbh_do
 532
 533 Arguments: $subref, @extra_coderef_args?
 534
 535 Execute the given subref using the new exception-based connection management.
 536
 537 The first two arguments will be the storage object that C<dbh_do> was called
 538 on and a database handle to use.  Any additional arguments will be passed
 539 verbatim to the called subref as arguments 2 and onwards.
 540
 541 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 542 exception handling and reconnection (or failover in future subclasses).
 543
 544 Your subref should have no side-effects outside of the database, as
 545 there is the potential for your subref to be partially double-executed
 546 if the database connection was stale/dysfunctional.
 547
 548 Example:
 549
 550   my @stuff = $schema->storage->dbh_do(
 551     sub {
 552       my ($storage, $dbh, @cols) = @_;
 553       my $cols = join(q{, }, @cols);
 554       $dbh->selectrow_array("SELECT $cols FROM foo");
 555     },
 556     @column_list
 557   );
 558
 559 =cut
 560
 561 sub dbh_do {
 562   my $self = shift;
 563   my $coderef = shift;
 564
 565   ref $coderef eq 'CODE' or $self->throw_exception
 566     ('$coderef must be a CODE reference');
 567
 568   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 569       || $self->{transaction_depth};
 570
 571   local $self->{_in_dbh_do} = 1;
 572
 573   my @result;
 574   my $want_array = wantarray;
 575
 576   eval {
 577     $self->_verify_pid if $self->_dbh;
 578     $self->_populate_dbh if !$self->_dbh;
 579     if($want_array) {
 580         @result = $coderef->($self, $self->_dbh, @_);
 581     }
 582     elsif(defined $want_array) {
 583         $result[0] = $coderef->($self, $self->_dbh, @_);
 584     }
 585     else {
 586         $coderef->($self, $self->_dbh, @_);
 587     }
 588   };
 589
 590   my $exception = $@;
 591   if(!$exception) { return $want_array ? @result : $result[0] }
 592
 593   $self->throw_exception($exception) if $self->connected;
 594
 595   # We were not connected - reconnect and retry, but let any
 596   #  exception fall right through this time
 597   $self->_populate_dbh;
 598   $coderef->($self, $self->_dbh, @_);
 599 }
 600
 601 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 602 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 603 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 604 sub txn_do {
 605   my $self = shift;
 606   my $coderef = shift;
 607
 608   ref $coderef eq 'CODE' or $self->throw_exception
 609     ('$coderef must be a CODE reference');
 610
 611   return $coderef->(@_) if $self->{transaction_depth};
 612
 613   local $self->{_in_dbh_do} = 1;
 614
 615   my @result;
 616   my $want_array = wantarray;
 617
 618   my $tried = 0;
 619   while(1) {
 620     eval {
 621       $self->_verify_pid if $self->_dbh;
 622       $self->_populate_dbh if !$self->_dbh;
 623
 624       $self->txn_begin;
 625       if($want_array) {
 626           @result = $coderef->(@_);
 627       }
 628       elsif(defined $want_array) {
 629           $result[0] = $coderef->(@_);
 630       }
 631       else {
 632           $coderef->(@_);
 633       }
 634       $self->txn_commit;
 635     };
 636
 637     my $exception = $@;
 638     if(!$exception) { return $want_array ? @result : $result[0] }
 639
 640     if($tried++ > 0 || $self->connected) {
 641       eval { $self->txn_rollback };
 642       my $rollback_exception = $@;
 643       if($rollback_exception) {
 644         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 645         $self->throw_exception($exception)  # propagate nested rollback
 646           if $rollback_exception =~ /$exception_class/;
 647
 648         $self->throw_exception(
 649           "Transaction aborted: ${exception}. "
 650           . "Rollback failed: ${rollback_exception}"
 651         );
 652       }
 653       $self->throw_exception($exception)
 654     }
 655
 656     # We were not connected, and was first try - reconnect and retry
 657     # via the while loop
 658     $self->_populate_dbh;
 659   }
 660 }
 661
 662 =head2 disconnect
 663
 664 Our C<disconnect> method also performs a rollback first if the
 665 database is not in C<AutoCommit> mode.
 666
 667 =cut
 668
 669 sub disconnect {
 670   my ($self) = @_;
 671
 672   if( $self->connected ) {
 673     my $connection_do = $self->on_disconnect_do;
 674     $self->_do_connection_actions($connection_do) if ref($connection_do);
 675
 676     $self->_dbh->rollback unless $self->_dbh_autocommit;
 677     $self->_dbh->disconnect;
 678     $self->_dbh(undef);
 679     $self->{_dbh_gen}++;
 680   }
 681 }
 682
 683 sub connected {
 684   my ($self) = @_;
 685
 686   if(my $dbh = $self->_dbh) {
 687       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 688           $self->_dbh(undef);
 689           $self->{_dbh_gen}++;
 690           return;
 691       }
 692       else {
 693           $self->_verify_pid;
 694       }
 695       return ($dbh->FETCH('Active') && $dbh->ping);
 696   }
 697
 698   return 0;
 699 }
 700
 701 # handle pid changes correctly
 702 #  NOTE: assumes $self->_dbh is a valid $dbh
 703 sub _verify_pid {
 704   my ($self) = @_;
 705
 706   return if $self->_conn_pid == $$;
 707
 708   $self->_dbh->{InactiveDestroy} = 1;
 709   $self->_dbh(undef);
 710   $self->{_dbh_gen}++;
 711
 712   return;
 713 }
 714
 715 sub ensure_connected {
 716   my ($self) = @_;
 717
 718   unless ($self->connected) {
 719     $self->_populate_dbh;
 720   }
 721 }
 722
 723 =head2 dbh
 724
 725 Returns the dbh - a data base handle of class L<DBI>.
 726
 727 =cut
 728
 729 sub dbh {
 730   my ($self) = @_;
 731
 732   $self->ensure_connected;
 733   return $self->_dbh;
 734 }
 735
 736 sub _sql_maker_args {
 737     my ($self) = @_;
 738
 739     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 740 }
 741
 742 sub sql_maker {
 743   my ($self) = @_;
 744   unless ($self->_sql_maker) {
 745     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 746   }
 747   return $self->_sql_maker;
 748 }
 749
 750 sub _populate_dbh {
 751   my ($self) = @_;
 752   my @info = @{$self->_dbi_connect_info || []};
 753   $self->_dbh($self->_connect(@info));
 754
 755   # Always set the transaction depth on connect, since
 756   #  there is no transaction in progress by definition
 757   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 758
 759   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 760     my $driver = $self->_dbh->{Driver}->{Name};
 761     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 762       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 763       $self->_rebless() if $self->can('_rebless');
 764     }
 765   }
 766
 767   my $connection_do = $self->on_connect_do;
 768   $self->_do_connection_actions($connection_do) if ref($connection_do);
 769
 770   $self->_conn_pid($$);
 771   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 772 }
 773
 774 sub _do_connection_actions {
 775   my $self = shift;
 776   my $connection_do = shift;
 777
 778   if (ref $connection_do eq 'ARRAY') {
 779     $self->_do_query($_) foreach @$connection_do;
 780   }
 781   elsif (ref $connection_do eq 'CODE') {
 782     $connection_do->();
 783   }
 784
 785   return $self;
 786 }
 787
 788 sub _do_query {
 789   my ($self, $action) = @_;
 790
 791   if (ref $action eq 'CODE') {
 792     $action->($self);
 793   }
 794   else {
 795     $self->debugobj->query_start($action) if $self->debug();
 796     $self->_dbh->do($action);
 797     $self->debugobj->query_end($action) if $self->debug();
 798   }
 799
 800   return $self;
 801 }
 802
 803 sub _connect {
 804   my ($self, @info) = @_;
 805
 806   $self->throw_exception("You failed to provide any connection info")
 807     if !@info;
 808
 809   my ($old_connect_via, $dbh);
 810
 811   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 812     $old_connect_via = $DBI::connect_via;
 813     $DBI::connect_via = 'connect';
 814   }
 815
 816   eval {
 817     if(ref $info[0] eq 'CODE') {
 818        $dbh = &{$info[0]}
 819     }
 820     else {
 821        $dbh = DBI->connect(@info);
 822     }
 823
 824     if(!$self->unsafe) {
 825       my $weak_self = $self;
 826       weaken($weak_self);
 827       $dbh->{HandleError} = sub {
 828           $weak_self->throw_exception("DBI Exception: $_[0]")
 829       };
 830       $dbh->{ShowErrorStatement} = 1;
 831       $dbh->{RaiseError} = 1;
 832       $dbh->{PrintError} = 0;
 833     }
 834   };
 835
 836   $DBI::connect_via = $old_connect_via if $old_connect_via;
 837
 838   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 839     if !$dbh || $@;
 840
 841   $self->_dbh_autocommit($dbh->{AutoCommit});
 842
 843   $dbh;
 844 }
 845
 846
 847 sub txn_begin {
 848   my $self = shift;
 849   $self->ensure_connected();
 850   if($self->{transaction_depth} == 0) {
 851     $self->debugobj->txn_begin()
 852       if $self->debug;
 853     # this isn't ->_dbh-> because
 854     #  we should reconnect on begin_work
 855     #  for AutoCommit users
 856     $self->dbh->begin_work;
 857   }
 858   $self->{transaction_depth}++;
 859 }
 860
 861 sub txn_commit {
 862   my $self = shift;
 863   if ($self->{transaction_depth} == 1) {
 864     my $dbh = $self->_dbh;
 865     $self->debugobj->txn_commit()
 866       if ($self->debug);
 867     $dbh->commit;
 868     $self->{transaction_depth} = 0
 869       if $self->_dbh_autocommit;
 870   }
 871   elsif($self->{transaction_depth} > 1) {
 872     $self->{transaction_depth}--
 873   }
 874 }
 875
 876 sub txn_rollback {
 877   my $self = shift;
 878   my $dbh = $self->_dbh;
 879   eval {
 880     if ($self->{transaction_depth} == 1) {
 881       $self->debugobj->txn_rollback()
 882         if ($self->debug);
 883       $self->{transaction_depth} = 0
 884         if $self->_dbh_autocommit;
 885       $dbh->rollback;
 886     }
 887     elsif($self->{transaction_depth} > 1) {
 888       $self->{transaction_depth}--;
 889     }
 890     else {
 891       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 892     }
 893   };
 894   if ($@) {
 895     my $error = $@;
 896     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 897     $error =~ /$exception_class/ and $self->throw_exception($error);
 898     # ensure that a failed rollback resets the transaction depth
 899     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 900     $self->throw_exception($error);
 901   }
 902 }
 903
 904 # This used to be the top-half of _execute.  It was split out to make it
 905 #  easier to override in NoBindVars without duping the rest.  It takes up
 906 #  all of _execute's args, and emits $sql, @bind.
 907 sub _prep_for_execute {
 908   my ($self, $op, $extra_bind, $ident, $args) = @_;
 909
 910   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 911   unshift(@bind,
 912     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 913       if $extra_bind;
 914
 915   return ($sql, \@bind);
 916 }
 917
 918 sub _dbh_execute {
 919   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 920
 921   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 922     $ident = $ident->from();
 923   }
 924
 925   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 926
 927   if ($self->debug) {
 928       my @debug_bind =
 929         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 930       $self->debugobj->query_start($sql, @debug_bind);
 931   }
 932
 933   my $sth = $self->sth($sql,$op);
 934
 935   my $placeholder_index = 1;
 936
 937   foreach my $bound (@$bind) {
 938     my $attributes = {};
 939     my($column_name, @data) = @$bound;
 940
 941     if ($bind_attributes) {
 942       $attributes = $bind_attributes->{$column_name}
 943       if defined $bind_attributes->{$column_name};
 944     }
 945
 946     foreach my $data (@data) {
 947       $data = ref $data ? ''.$data : $data; # stringify args
 948
 949       $sth->bind_param($placeholder_index, $data, $attributes);
 950       $placeholder_index++;
 951     }
 952   }
 953
 954   # Can this fail without throwing an exception anyways???
 955   my $rv = $sth->execute();
 956   $self->throw_exception($sth->errstr) if !$rv;
 957
 958   if ($self->debug) {
 959      my @debug_bind =
 960        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 961      $self->debugobj->query_end($sql, @debug_bind);
 962   }
 963
 964   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 965 }
 966
 967 sub _execute {
 968     my $self = shift;
 969     $self->dbh_do($self->can('_dbh_execute'), @_)
 970 }
 971
 972 sub insert {
 973   my ($self, $source, $to_insert) = @_;
 974
 975   my $ident = $source->from;
 976   my $bind_attributes = $self->source_bind_attributes($source);
 977
 978   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
 979
 980   return $to_insert;
 981 }
 982
 983 ## Still not quite perfect, and EXPERIMENTAL
 984 ## Currently it is assumed that all values passed will be "normal", i.e. not
 985 ## scalar refs, or at least, all the same type as the first set, the statement is
 986 ## only prepped once.
 987 sub insert_bulk {
 988   my ($self, $source, $cols, $data) = @_;
 989   my %colvalues;
 990   my $table = $source->from;
 991   @colvalues{@$cols} = (0..$#$cols);
 992   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 993
 994   if ($self->debug) {
 995       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 996       $self->debugobj->query_start($sql, @debug_bind);
 997   }
 998   my $sth = $self->sth($sql);
 999
1000 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1001
1002   ## This must be an arrayref, else nothing works!
1003
1004   my $tuple_status = [];
1005
1006   ##use Data::Dumper;
1007   ##print STDERR Dumper( $data, $sql, [@bind] );
1008
1009   my $time = time();
1010
1011   ## Get the bind_attributes, if any exist
1012   my $bind_attributes = $self->source_bind_attributes($source);
1013
1014   ## Bind the values and execute
1015   my $placeholder_index = 1;
1016
1017   foreach my $bound (@bind) {
1018
1019     my $attributes = {};
1020     my ($column_name, $data_index) = @$bound;
1021
1022     if( $bind_attributes ) {
1023       $attributes = $bind_attributes->{$column_name}
1024       if defined $bind_attributes->{$column_name};
1025     }
1026
1027     my @data = map { $_->[$data_index] } @$data;
1028
1029     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1030     $placeholder_index++;
1031   }
1032   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1033   $self->throw_exception($sth->errstr) if !$rv;
1034
1035   if ($self->debug) {
1036       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
1037       $self->debugobj->query_end($sql, @debug_bind);
1038   }
1039   return (wantarray ? ($rv, $sth, @bind) : $rv);
1040 }
1041
1042 sub update {
1043   my $self = shift @_;
1044   my $source = shift @_;
1045   my $bind_attributes = $self->source_bind_attributes($source);
1046
1047   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1048 }
1049
1050
1051 sub delete {
1052   my $self = shift @_;
1053   my $source = shift @_;
1054
1055   my $bind_attrs = {}; ## If ever it's needed...
1056
1057   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1058 }
1059
1060 sub _select {
1061   my ($self, $ident, $select, $condition, $attrs) = @_;
1062   my $order = $attrs->{order_by};
1063   if (ref $condition eq 'SCALAR') {
1064     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1065   }
1066   if (exists $attrs->{group_by} || $attrs->{having}) {
1067     $order = {
1068       group_by => $attrs->{group_by},
1069       having => $attrs->{having},
1070       ($order ? (order_by => $order) : ())
1071     };
1072   }
1073   my $bind_attrs = {}; ## Future support
1074   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1075   if ($attrs->{software_limit} ||
1076       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1077         $attrs->{software_limit} = 1;
1078   } else {
1079     $self->throw_exception("rows attribute must be positive if present")
1080       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1081     push @args, $attrs->{rows}, $attrs->{offset};
1082   }
1083   return $self->_execute(@args);
1084 }
1085
1086 sub source_bind_attributes {
1087   my ($self, $source) = @_;
1088
1089   my $bind_attributes;
1090   foreach my $column ($source->columns) {
1091
1092     my $data_type = $source->column_info($column)->{data_type} || '';
1093     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1094      if $data_type;
1095   }
1096
1097   return $bind_attributes;
1098 }
1099
1100 =head2 select
1101
1102 =over 4
1103
1104 =item Arguments: $ident, $select, $condition, $attrs
1105
1106 =back
1107
1108 Handle a SQL select statement.
1109
1110 =cut
1111
1112 sub select {
1113   my $self = shift;
1114   my ($ident, $select, $condition, $attrs) = @_;
1115   return $self->cursor->new($self, \@_, $attrs);
1116 }
1117
1118 sub select_single {
1119   my $self = shift;
1120   my ($rv, $sth, @bind) = $self->_select(@_);
1121   my @row = $sth->fetchrow_array;
1122   # Need to call finish() to work round broken DBDs
1123   $sth->finish();
1124   return @row;
1125 }
1126
1127 =head2 sth
1128
1129 =over 4
1130
1131 =item Arguments: $sql
1132
1133 =back
1134
1135 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1136
1137 =cut
1138
1139 sub _dbh_sth {
1140   my ($self, $dbh, $sql) = @_;
1141
1142   # 3 is the if_active parameter which avoids active sth re-use
1143   my $sth = $self->disable_sth_caching
1144     ? $dbh->prepare($sql)
1145     : $dbh->prepare_cached($sql, {}, 3);
1146
1147   # XXX You would think RaiseError would make this impossible,
1148   #  but apparently that's not true :(
1149   $self->throw_exception($dbh->errstr) if !$sth;
1150
1151   $sth;
1152 }
1153
1154 sub sth {
1155   my ($self, $sql) = @_;
1156   $self->dbh_do($self->can('_dbh_sth'), $sql);
1157 }
1158
1159 sub _dbh_columns_info_for {
1160   my ($self, $dbh, $table) = @_;
1161
1162   if ($dbh->can('column_info')) {
1163     my %result;
1164     eval {
1165       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1166       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1167       $sth->execute();
1168       while ( my $info = $sth->fetchrow_hashref() ){
1169         my %column_info;
1170         $column_info{data_type}   = $info->{TYPE_NAME};
1171         $column_info{size}      = $info->{COLUMN_SIZE};
1172         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1173         $column_info{default_value} = $info->{COLUMN_DEF};
1174         my $col_name = $info->{COLUMN_NAME};
1175         $col_name =~ s/^\"(.*)\"$/$1/;
1176
1177         $result{$col_name} = \%column_info;
1178       }
1179     };
1180     return \%result if !$@ && scalar keys %result;
1181   }
1182
1183   my %result;
1184   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1185   $sth->execute;
1186   my @columns = @{$sth->{NAME_lc}};
1187   for my $i ( 0 .. $#columns ){
1188     my %column_info;
1189     $column_info{data_type} = $sth->{TYPE}->[$i];
1190     $column_info{size} = $sth->{PRECISION}->[$i];
1191     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1192
1193     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1194       $column_info{data_type} = $1;
1195       $column_info{size}    = $2;
1196     }
1197
1198     $result{$columns[$i]} = \%column_info;
1199   }
1200   $sth->finish;
1201
1202   foreach my $col (keys %result) {
1203     my $colinfo = $result{$col};
1204     my $type_num = $colinfo->{data_type};
1205     my $type_name;
1206     if(defined $type_num && $dbh->can('type_info')) {
1207       my $type_info = $dbh->type_info($type_num);
1208       $type_name = $type_info->{TYPE_NAME} if $type_info;
1209       $colinfo->{data_type} = $type_name if $type_name;
1210     }
1211   }
1212
1213   return \%result;
1214 }
1215
1216 sub columns_info_for {
1217   my ($self, $table) = @_;
1218   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1219 }
1220
1221 =head2 last_insert_id
1222
1223 Return the row id of the last insert.
1224
1225 =cut
1226
1227 sub _dbh_last_insert_id {
1228     my ($self, $dbh, $source, $col) = @_;
1229     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1230     $dbh->func('last_insert_rowid');
1231 }
1232
1233 sub last_insert_id {
1234   my $self = shift;
1235   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1236 }
1237
1238 =head2 sqlt_type
1239
1240 Returns the database driver name.
1241
1242 =cut
1243
1244 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1245
1246 =head2 bind_attribute_by_data_type
1247
1248 Given a datatype from column info, returns a database specific bind attribute for
1249 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1250 just handle it.
1251
1252 Generally only needed for special case column types, like bytea in postgres.
1253
1254 =cut
1255
1256 sub bind_attribute_by_data_type {
1257     return;
1258 }
1259
1260 =head2 create_ddl_dir
1261
1262 =over 4
1263
1264 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1265
1266 =back
1267
1268 Creates a SQL file based on the Schema, for each of the specified
1269 database types, in the given directory.
1270
1271 =cut
1272
1273 sub create_ddl_dir
1274 {
1275   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1276
1277   if(!$dir || !-d $dir)
1278   {
1279     warn "No directory given, using ./\n";
1280     $dir = "./";
1281   }
1282   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1283   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1284   $version ||= $schema->VERSION || '1.x';
1285   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1286
1287   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.08: '}
1288       . $self->_check_sqlt_message . q{'})
1289           if !$self->_check_sqlt_version;
1290
1291   my $sqlt = SQL::Translator->new({
1292 #      debug => 1,
1293       add_drop_table => 1,
1294   });
1295   foreach my $db (@$databases)
1296   {
1297     $sqlt->reset();
1298     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1299 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1300     $sqlt = $self->configure_sqlt($sqlt, $db);
1301     $sqlt->data($schema);
1302     $sqlt->producer($db);
1303
1304     my $file;
1305     my $filename = $schema->ddl_filename($db, $dir, $version);
1306     if(-e $filename)
1307     {
1308       warn("$filename already exists, skipping $db");
1309       next;
1310     }
1311
1312     my $output = $sqlt->translate;
1313     if(!$output)
1314     {
1315       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1316       next;
1317     }
1318     if(!open($file, ">$filename"))
1319     {
1320         $self->throw_exception("Can't open $filename for writing ($!)");
1321         next;
1322     }
1323     print $file $output;
1324     close($file);
1325
1326     if($preversion)
1327     {
1328       require SQL::Translator::Diff;
1329
1330       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1331 #      print "Previous version $prefilename\n";
1332       if(!-e $prefilename)
1333       {
1334         warn("No previous schema file found ($prefilename)");
1335         next;
1336       }
1337       #### We need to reparse the SQLite file we just wrote, so that
1338       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1339       ##   FIXME: rip Diff to pieces!
1340 #      my $target_schema = $sqlt->schema;
1341 #      unless ( $target_schema->name ) {
1342 #        $target_schema->name( $filename );
1343 #      }
1344       my @input;
1345       push @input, {file => $prefilename, parser => $db};
1346       push @input, {file => $filename, parser => $db};
1347       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1348         my $file   = $_->{'file'};
1349         my $parser = $_->{'parser'};
1350
1351         my $t = SQL::Translator->new;
1352         $t->debug( 0 );
1353         $t->trace( 0 );
1354         $t->parser( $parser )            or die $t->error;
1355         my $out = $t->translate( $file ) or die $t->error;
1356         my $schema = $t->schema;
1357         unless ( $schema->name ) {
1358           $schema->name( $file );
1359         }
1360         ($schema, $parser);
1361       } @input;
1362
1363       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1364                                                     $target_schema, $db,
1365                                                     {}
1366                                                    );
1367       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1368       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1369       if(-e $difffile)
1370       {
1371         warn("$difffile already exists, skipping");
1372         next;
1373       }
1374       if(!open $file, ">$difffile")
1375       {
1376         $self->throw_exception("Can't write to $difffile ($!)");
1377         next;
1378       }
1379       print $file $diff;
1380       close($file);
1381     }
1382   }
1383 }
1384
1385 sub configure_sqlt() {
1386   my $self = shift;
1387   my $tr = shift;
1388   my $db = shift || $self->sqlt_type;
1389   if ($db eq 'PostgreSQL') {
1390     $tr->quote_table_names(0);
1391     $tr->quote_field_names(0);
1392   }
1393   return $tr;
1394 }
1395
1396 =head2 deployment_statements
1397
1398 =over 4
1399
1400 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1401
1402 =back
1403
1404 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1405 The database driver name is given by C<$type>, though the value from
1406 L</sqlt_type> is used if it is not specified.
1407
1408 C<$directory> is used to return statements from files in a previously created
1409 L</create_ddl_dir> directory and is optional. The filenames are constructed
1410 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1411
1412 If no C<$directory> is specified then the statements are constructed on the
1413 fly using L<SQL::Translator> and C<$version> is ignored.
1414
1415 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1416
1417 =cut
1418
1419 sub deployment_statements {
1420   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1421   # Need to be connected to get the correct sqlt_type
1422   $self->ensure_connected() unless $type;
1423   $type ||= $self->sqlt_type;
1424   $version ||= $schema->VERSION || '1.x';
1425   $dir ||= './';
1426   my $filename = $schema->ddl_filename($type, $dir, $version);
1427   if(-f $filename)
1428   {
1429       my $file;
1430       open($file, "<$filename")
1431         or $self->throw_exception("Can't open $filename ($!)");
1432       my @rows = <$file>;
1433       close($file);
1434       return join('', @rows);
1435   }
1436
1437   $self->throw_exception(q{Can't deploy without SQL::Translator 0.08: '}
1438       . $self->_check_sqlt_message . q{'})
1439           if !$self->_check_sqlt_version;
1440
1441   require SQL::Translator::Parser::DBIx::Class;
1442   eval qq{use SQL::Translator::Producer::${type}};
1443   $self->throw_exception($@) if $@;
1444
1445   # sources needs to be a parser arg, but for simplicty allow at top level
1446   # coming in
1447   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1448       if exists $sqltargs->{sources};
1449
1450   my $tr = SQL::Translator->new(%$sqltargs);
1451   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1452   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1453
1454   return;
1455
1456 }
1457
1458 sub deploy {
1459   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1460   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1461     foreach my $line ( split(";\n", $statement)) {
1462       next if($line =~ /^--/);
1463       next if(!$line);
1464 #      next if($line =~ /^DROP/m);
1465       next if($line =~ /^BEGIN TRANSACTION/m);
1466       next if($line =~ /^COMMIT/m);
1467       next if $line =~ /^\s+$/; # skip whitespace only
1468       $self->debugobj->query_start($line) if $self->debug;
1469       eval {
1470         $self->dbh->do($line); # shouldn't be using ->dbh ?
1471       };
1472       if ($@) {
1473         warn qq{$@ (running "${line}")};
1474       }
1475       $self->debugobj->query_end($line) if $self->debug;
1476     }
1477   }
1478 }
1479
1480 =head2 datetime_parser
1481
1482 Returns the datetime parser class
1483
1484 =cut
1485
1486 sub datetime_parser {
1487   my $self = shift;
1488   return $self->{datetime_parser} ||= do {
1489     $self->ensure_connected;
1490     $self->build_datetime_parser(@_);
1491   };
1492 }
1493
1494 =head2 datetime_parser_type
1495
1496 Defines (returns) the datetime parser class - currently hardwired to
1497 L<DateTime::Format::MySQL>
1498
1499 =cut
1500
1501 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1502
1503 =head2 build_datetime_parser
1504
1505 See L</datetime_parser>
1506
1507 =cut
1508
1509 sub build_datetime_parser {
1510   my $self = shift;
1511   my $type = $self->datetime_parser_type(@_);
1512   eval "use ${type}";
1513   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1514   return $type;
1515 }
1516
1517 {
1518     my $_check_sqlt_version; # private
1519     my $_check_sqlt_message; # private
1520     sub _check_sqlt_version {
1521         return $_check_sqlt_version if defined $_check_sqlt_version;
1522         eval 'use SQL::Translator 0.08';
1523         $_check_sqlt_message = $@ ? $@ : '';
1524         $_check_sqlt_version = $@ ? 0 : 1;
1525     }
1526
1527     sub _check_sqlt_message {
1528         _check_sqlt_version if !defined $_check_sqlt_message;
1529         $_check_sqlt_message;
1530     }
1531 }
1532
1533 sub DESTROY {
1534   my $self = shift;
1535   return if !$self->_dbh;
1536   $self->_verify_pid;
1537   $self->_dbh(undef);
1538 }
1539
1540 1;
1541
1542 =head1 SQL METHODS
1543
1544 The module defines a set of methods within the DBIC::SQL::Abstract
1545 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1546 SQL query functions.
1547
1548 The following methods are extended:-
1549
1550 =over 4
1551
1552 =item delete
1553
1554 =item insert
1555
1556 =item select
1557
1558 =item update
1559
1560 =item limit_dialect
1561
1562 See L</connect_info> for details.
1563 For setting, this method is deprecated in favor of L</connect_info>.
1564
1565 =item quote_char
1566
1567 See L</connect_info> for details.
1568 For setting, this method is deprecated in favor of L</connect_info>.
1569
1570 =item name_sep
1571
1572 See L</connect_info> for details.
1573 For setting, this method is deprecated in favor of L</connect_info>.
1574
1575 =back
1576
1577 =head1 AUTHORS
1578
1579 Matt S. Trout <mst@shadowcatsystems.co.uk>
1580
1581 Andy Grundman <andy@hybridized.org>
1582
1583 =head1 LICENSE
1584
1585 You may distribute this code under the same terms as Perl itself.
1586
1587 =cut