lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use base 'DBIx::Class::Storage';
   4
   5 use strict;
   6 use warnings;
   7 use DBI;
   8 use SQL::Abstract::Limit;
   9 use DBIx::Class::Storage::DBI::Cursor;
  10 use IO::File;
  11 use Carp::Clan qw/DBIx::Class/;
  12
  13 BEGIN {
  14
  15 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  16
  17 use base qw/SQL::Abstract::Limit/;
  18
  19 sub select {
  20   my ($self, $table, $fields, $where, $order, @rest) = @_;
  21   @rest = (-1) unless defined $rest[0];
  22   local $self->{having_bind} = [];
  23   my ($sql, @ret) = $self->SUPER::select(
  24     $table, $self->_recurse_fields($fields), $where, $order, @rest
  25   );
  26   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  27 }
  28
  29 sub _emulate_limit {
  30   my $self = shift;
  31   if ($_[3] == -1) {
  32     return $_[1].$self->_order_by($_[2]);
  33   } else {
  34     return $self->SUPER::_emulate_limit(@_);
  35   }
  36 }
  37
  38 sub _recurse_fields {
  39   my ($self, $fields) = @_;
  40   my $ref = ref $fields;
  41   return $self->_quote($fields) unless $ref;
  42   return $$fields if $ref eq 'SCALAR';
  43
  44   if ($ref eq 'ARRAY') {
  45     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  46   } elsif ($ref eq 'HASH') {
  47     foreach my $func (keys %$fields) {
  48       return $self->_sqlcase($func)
  49         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  50     }
  51   }
  52 }
  53
  54 sub _order_by {
  55   my $self = shift;
  56   my $ret = '';
  57   my @extra;
  58   if (ref $_[0] eq 'HASH') {
  59     if (defined $_[0]->{group_by}) {
  60       $ret = $self->_sqlcase(' group by ')
  61                .$self->_recurse_fields($_[0]->{group_by});
  62     }
  63     if (defined $_[0]->{having}) {
  64       my $frag;
  65       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  66       push(@{$self->{having_bind}}, @extra);
  67       $ret .= $self->_sqlcase(' having ').$frag;
  68     }
  69     if (defined $_[0]->{order_by}) {
  70       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  71     }
  72   } elsif(ref $_[0] eq 'SCALAR') {
  73     $ret = $self->_sqlcase(' order by ').${ $_[0] };
  74   } else {
  75     $ret = $self->SUPER::_order_by(@_);
  76   }
  77   return $ret;
  78 }
  79
  80 sub _order_directions {
  81   my ($self, $order) = @_;
  82   $order = $order->{order_by} if ref $order eq 'HASH';
  83   return $self->SUPER::_order_directions($order);
  84 }
  85
  86 sub _table {
  87   my ($self, $from) = @_;
  88   if (ref $from eq 'ARRAY') {
  89     return $self->_recurse_from(@$from);
  90   } elsif (ref $from eq 'HASH') {
  91     return $self->_make_as($from);
  92   } else {
  93     return $from;
  94   }
  95 }
  96
  97 sub _recurse_from {
  98   my ($self, $from, @join) = @_;
  99   my @sqlf;
 100   push(@sqlf, $self->_make_as($from));
 101   foreach my $j (@join) {
 102     my ($to, $on) = @$j;
 103
 104     # check whether a join type exists
 105     my $join_clause = '';
 106     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 107       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 108     } else {
 109       $join_clause = ' JOIN ';
 110     }
 111     push(@sqlf, $join_clause);
 112
 113     if (ref $to eq 'ARRAY') {
 114       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 115     } else {
 116       push(@sqlf, $self->_make_as($to));
 117     }
 118     push(@sqlf, ' ON ', $self->_join_condition($on));
 119   }
 120   return join('', @sqlf);
 121 }
 122
 123 sub _make_as {
 124   my ($self, $from) = @_;
 125   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 126                      reverse each %{$self->_skip_options($from)});
 127 }
 128
 129 sub _skip_options {
 130   my ($self, $hash) = @_;
 131   my $clean_hash = {};
 132   $clean_hash->{$_} = $hash->{$_}
 133     for grep {!/^-/} keys %$hash;
 134   return $clean_hash;
 135 }
 136
 137 sub _join_condition {
 138   my ($self, $cond) = @_;
 139   if (ref $cond eq 'HASH') {
 140     my %j;
 141     for (keys %$cond) {
 142       my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x;
 143     };
 144     return $self->_recurse_where(\%j);
 145   } elsif (ref $cond eq 'ARRAY') {
 146     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 147   } else {
 148     die "Can't handle this yet!";
 149   }
 150 }
 151
 152 sub _quote {
 153   my ($self, $label) = @_;
 154   return '' unless defined $label;
 155   return "*" if $label eq '*';
 156   return $label unless $self->{quote_char};
 157   if(ref $self->{quote_char} eq "ARRAY"){
 158     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 159       if !defined $self->{name_sep};
 160     my $sep = $self->{name_sep};
 161     return join($self->{name_sep},
 162         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 163        split(/\Q$sep\E/,$label));
 164   }
 165   return $self->SUPER::_quote($label);
 166 }
 167
 168 sub _RowNum {
 169    my $self = shift;
 170    my $c;
 171    $_[0] =~ s/SELECT (.*?) FROM/
 172      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 173    $self->SUPER::_RowNum(@_);
 174 }
 175
 176 # Accessor for setting limit dialect. This is useful
 177 # for JDBC-bridge among others where the remote SQL-dialect cannot
 178 # be determined by the name of the driver alone.
 179 #
 180 sub limit_dialect {
 181     my $self = shift;
 182     $self->{limit_dialect} = shift if @_;
 183     return $self->{limit_dialect};
 184 }
 185
 186 sub quote_char {
 187     my $self = shift;
 188     $self->{quote_char} = shift if @_;
 189     return $self->{quote_char};
 190 }
 191
 192 sub name_sep {
 193     my $self = shift;
 194     $self->{name_sep} = shift if @_;
 195     return $self->{name_sep};
 196 }
 197
 198
 199
 200
 201 package DBIx::Class::Storage::DBI::DebugCallback;
 202
 203 sub print {
 204   my ($self, $string) = @_;
 205   $string =~ m/^(\w+)/;
 206   ${$self}->($1, $string);
 207 }
 208
 209 } # End of BEGIN block
 210
 211 use base qw/DBIx::Class/;
 212
 213 __PACKAGE__->load_components(qw/AccessorGroup/);
 214
 215 __PACKAGE__->mk_group_accessors('simple' =>
 216   qw/_connect_info _dbh _sql_maker _conn_pid _conn_tid debug debugfh
 217      cursor on_connect_do transaction_depth/);
 218
 219 sub new {
 220   my $new = bless({}, ref $_[0] || $_[0]);
 221   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 222   $new->transaction_depth(0);
 223   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 224      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 225     $new->debugfh(IO::File->new($1, 'w'))
 226       or $new->throw_exception("Cannot open trace file $1");
 227   } else {
 228     $new->debugfh(IO::File->new('>&STDERR'));
 229   }
 230   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 231   return $new;
 232 }
 233
 234 sub throw_exception {
 235   my ($self, $msg) = @_;
 236   croak($msg);
 237 }
 238
 239 =head1 NAME
 240
 241 DBIx::Class::Storage::DBI - DBI storage handler
 242
 243 =head1 SYNOPSIS
 244
 245 =head1 DESCRIPTION
 246
 247 This class represents the connection to the database
 248
 249 =head1 METHODS
 250
 251 =cut
 252
 253 =head2 connect_info
 254
 255 Connection information arrayref.  Can either be the same arguments
 256 one would pass to DBI->connect, or a code-reference which returns
 257 a connected database handle.  In either case, there is an optional
 258 final element in the arrayref, which can hold a hashref of
 259 connection-specific Storage::DBI options.  These include
 260 C<on_connect_do>, and the sql_maker options C<limit_dialect>,
 261 C<quote_char>, and C<name_sep>.  Examples:
 262
 263   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 264   ->connect_info(sub { DBI->connect(...) });
 265   ->connect_info([ 'dbi:Pg:dbname=foo',
 266                    'postgres',
 267                    '',
 268                    { AutoCommit => 0 },
 269                    { quote_char => q{`}, name_sep => q{@} },
 270                  ]);
 271
 272 =head2 on_connect_do
 273
 274 Executes the sql statements given as a listref on every db connect.
 275
 276 =head2 debug
 277
 278 Causes SQL trace information to be emitted on C<debugfh> filehandle
 279 (or C<STDERR> if C<debugfh> has not specifically been set).
 280
 281 =head2 debugfh
 282
 283 Sets or retrieves the filehandle used for trace/debug output.  This
 284 should be an IO::Handle compatible object (only the C<print> method is
 285 used).  Initially set to be STDERR - although see information on the
 286 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 287
 288 =head2 debugcb
 289
 290 Sets a callback to be executed each time a statement is run; takes a sub
 291 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 292 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 293 be printed.
 294
 295 =cut
 296
 297 sub debugcb {
 298   my ($self, $cb) = @_;
 299   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 300   $self->debugfh($cb_obj);
 301 }
 302
 303 sub disconnect {
 304   my ($self) = @_;
 305
 306   if( $self->connected ) {
 307     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 308     $self->_dbh->disconnect;
 309     $self->_dbh(undef);
 310   }
 311 }
 312
 313 sub connected {
 314   my ($self) = @_;
 315
 316   if(my $dbh = $self->_dbh) {
 317       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 318           $self->_sql_maker(undef);
 319           return $self->_dbh(undef);
 320       }
 321       elsif($self->_conn_pid != $$) {
 322           $self->_dbh->{InactiveDestroy} = 1;
 323           $self->_sql_maker(undef);
 324           return $self->_dbh(undef)
 325       }
 326       return ($dbh->FETCH('Active') && $dbh->ping);
 327   }
 328
 329   return 0;
 330 }
 331
 332 sub ensure_connected {
 333   my ($self) = @_;
 334
 335   unless ($self->connected) {
 336     $self->_populate_dbh;
 337   }
 338 }
 339
 340 sub dbh {
 341   my ($self) = @_;
 342
 343   $self->ensure_connected;
 344   return $self->_dbh;
 345 }
 346
 347 sub sql_maker {
 348   my ($self) = @_;
 349   unless ($self->_sql_maker) {
 350     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 351   }
 352   return $self->_sql_maker;
 353 }
 354
 355 sub connect_info {
 356     my ($self, $info_arg) = @_;
 357
 358     if($info_arg) {
 359         my $info = [ @$info_arg ]; # copy because we can alter it
 360         my $last_info = $info->[-1];
 361         if(ref $last_info eq 'HASH') {
 362             my $used;
 363             if(my $on_connect_do = $last_info->{on_connect_do}) {
 364                $used = 1;
 365                $self->on_connect_do($on_connect_do);
 366             }
 367             for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 368                 if(my $opt_val = $last_info->{$sql_maker_opt}) {
 369                     $used = 1;
 370                     $self->sql_maker->$sql_maker_opt($opt_val);
 371                 }
 372             }
 373
 374             # remove our options hashref if it was there, to avoid confusing
 375             #   DBI in the case the user didn't use all 4 DBI options, as in:
 376             #   [ 'dbi:SQLite:foo.db', { quote_char => q{`} } ]
 377             pop(@$info) if $used;
 378         }
 379
 380         $self->_connect_info($info);
 381     }
 382
 383     $self->_connect_info;
 384 }
 385
 386 sub _populate_dbh {
 387   my ($self) = @_;
 388   my @info = @{$self->_connect_info || []};
 389   $self->_dbh($self->_connect(@info));
 390   my $driver = $self->_dbh->{Driver}->{Name};
 391   eval "require DBIx::Class::Storage::DBI::${driver}";
 392   unless ($@) {
 393     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 394   }
 395   # if on-connect sql statements are given execute them
 396   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 397     $self->_dbh->do($sql_statement);
 398   }
 399
 400   $self->_conn_pid($$);
 401   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 402 }
 403
 404 sub _connect {
 405   my ($self, @info) = @_;
 406
 407   $self->throw_exception("You failed to provide any connection info")
 408       if !@info;
 409
 410   my ($old_connect_via, $dbh);
 411
 412   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 413       $old_connect_via = $DBI::connect_via;
 414       $DBI::connect_via = 'connect';
 415   }
 416
 417   if(ref $info[0] eq 'CODE') {
 418       $dbh = &{$info[0]};
 419   }
 420   else {
 421       $dbh = DBI->connect(@info);
 422   }
 423
 424   $DBI::connect_via = $old_connect_via if $old_connect_via;
 425
 426   $self->throw_exception("DBI Connection failed: $DBI::errstr")
 427       unless $dbh;
 428
 429   $dbh;
 430 }
 431
 432 =head2 txn_begin
 433
 434 Calls begin_work on the current dbh.
 435
 436 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
 437 an entire code block to be executed transactionally.
 438
 439 =cut
 440
 441 sub txn_begin {
 442   my $self = shift;
 443   $self->dbh->begin_work
 444     if $self->{transaction_depth}++ == 0 and $self->dbh->{AutoCommit};
 445 }
 446
 447 =head2 txn_commit
 448
 449 Issues a commit against the current dbh.
 450
 451 =cut
 452
 453 sub txn_commit {
 454   my $self = shift;
 455   if ($self->{transaction_depth} == 0) {
 456     $self->dbh->commit unless $self->dbh->{AutoCommit};
 457   }
 458   else {
 459     $self->dbh->commit if --$self->{transaction_depth} == 0;
 460   }
 461 }
 462
 463 =head2 txn_rollback
 464
 465 Issues a rollback against the current dbh. A nested rollback will
 466 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 467 which allows the rollback to propagate to the outermost transaction.
 468
 469 =cut
 470
 471 sub txn_rollback {
 472   my $self = shift;
 473
 474   eval {
 475     if ($self->{transaction_depth} == 0) {
 476       $self->dbh->rollback unless $self->dbh->{AutoCommit};
 477     }
 478     else {
 479       --$self->{transaction_depth} == 0 ?
 480         $self->dbh->rollback :
 481         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 482     }
 483   };
 484
 485   if ($@) {
 486     my $error = $@;
 487     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 488     $error =~ /$exception_class/ and $self->throw_exception($error);
 489     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 490     $self->throw_exception($error);          # resets the transaction depth
 491   }
 492 }
 493
 494 sub _execute {
 495   my ($self, $op, $extra_bind, $ident, @args) = @_;
 496   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 497   unshift(@bind, @$extra_bind) if $extra_bind;
 498   if ($self->debug) {
 499       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 500       $self->debugfh->print("$sql: " . join(', ', @debug_bind) . "\n");
 501   }
 502   my $sth = $self->sth($sql,$op);
 503   $self->throw_exception("no sth generated via sql: $sql") unless $sth;
 504   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 505   my $rv;
 506   if ($sth) {
 507     $rv = $sth->execute(@bind)
 508       or $self->throw_exception("Error executing '$sql': " . $sth->errstr);
 509   } else {
 510     $self->throw_exception("'$sql' did not generate a statement.");
 511   }
 512   return (wantarray ? ($rv, $sth, @bind) : $rv);
 513 }
 514
 515 sub insert {
 516   my ($self, $ident, $to_insert) = @_;
 517   $self->throw_exception(
 518     "Couldn't insert ".join(', ',
 519       map "$_ => $to_insert->{$_}", keys %$to_insert
 520     )." into ${ident}"
 521   ) unless ($self->_execute('insert' => [], $ident, $to_insert));
 522   return $to_insert;
 523 }
 524
 525 sub update {
 526   return shift->_execute('update' => [], @_);
 527 }
 528
 529 sub delete {
 530   return shift->_execute('delete' => [], @_);
 531 }
 532
 533 sub _select {
 534   my ($self, $ident, $select, $condition, $attrs) = @_;
 535   my $order = $attrs->{order_by};
 536   if (ref $condition eq 'SCALAR') {
 537     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 538   }
 539   if (exists $attrs->{group_by} || $attrs->{having}) {
 540     $order = {
 541       group_by => $attrs->{group_by},
 542       having => $attrs->{having},
 543       ($order ? (order_by => $order) : ())
 544     };
 545   }
 546   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 547   if ($attrs->{software_limit} ||
 548       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 549         $attrs->{software_limit} = 1;
 550   } else {
 551     push @args, $attrs->{rows}, $attrs->{offset};
 552   }
 553   return $self->_execute(@args);
 554 }
 555
 556 sub select {
 557   my $self = shift;
 558   my ($ident, $select, $condition, $attrs) = @_;
 559   return $self->cursor->new($self, \@_, $attrs);
 560 }
 561
 562 # Need to call finish() to work round broken DBDs
 563
 564 sub select_single {
 565   my $self = shift;
 566   my ($rv, $sth, @bind) = $self->_select(@_);
 567   my @row = $sth->fetchrow_array;
 568   $sth->finish();
 569   return @row;
 570 }
 571
 572 sub sth {
 573   my ($self, $sql) = @_;
 574   # 3 is the if_active parameter which avoids active sth re-use
 575   return $self->dbh->prepare_cached($sql, {}, 3);
 576 }
 577
 578 =head2 columns_info_for
 579
 580 Returns database type info for a given table columns.
 581
 582 =cut
 583
 584 sub columns_info_for {
 585   my ($self, $table) = @_;
 586
 587   if ($self->dbh->can('column_info')) {
 588     my %result;
 589     my $old_raise_err = $self->dbh->{RaiseError};
 590     my $old_print_err = $self->dbh->{PrintError};
 591     $self->dbh->{RaiseError} = 1;
 592     $self->dbh->{PrintError} = 0;
 593     eval {
 594       my $sth = $self->dbh->column_info( undef, undef, $table, '%' );
 595       $sth->execute();
 596       while ( my $info = $sth->fetchrow_hashref() ){
 597         my %column_info;
 598         $column_info{data_type}   = $info->{TYPE_NAME};
 599         $column_info{size}      = $info->{COLUMN_SIZE};
 600         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 601         $column_info{default_value} = $info->{COLUMN_DEF};
 602
 603         $result{$info->{COLUMN_NAME}} = \%column_info;
 604       }
 605     };
 606     $self->dbh->{RaiseError} = $old_raise_err;
 607     $self->dbh->{PrintError} = $old_print_err;
 608     return \%result if !$@;
 609   }
 610
 611   my %result;
 612   my $sth = $self->dbh->prepare("SELECT * FROM $table WHERE 1=0");
 613   $sth->execute;
 614   my @columns = @{$sth->{NAME_lc}};
 615   for my $i ( 0 .. $#columns ){
 616     my %column_info;
 617     my $type_num = $sth->{TYPE}->[$i];
 618     my $type_name;
 619     if(defined $type_num && $self->dbh->can('type_info')) {
 620       my $type_info = $self->dbh->type_info($type_num);
 621       $type_name = $type_info->{TYPE_NAME} if $type_info;
 622     }
 623     $column_info{data_type} = $type_name ? $type_name : $type_num;
 624     $column_info{size} = $sth->{PRECISION}->[$i];
 625     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 626
 627     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 628       $column_info{data_type} = $1;
 629       $column_info{size}    = $2;
 630     }
 631
 632     $result{$columns[$i]} = \%column_info;
 633   }
 634
 635   return \%result;
 636 }
 637
 638 sub last_insert_id {
 639   my ($self, $row) = @_;
 640
 641   return $self->dbh->func('last_insert_rowid');
 642
 643 }
 644
 645 sub sqlt_type { shift->dbh->{Driver}->{Name} }
 646
 647 sub deployment_statements {
 648   my ($self, $schema, $type, $sqltargs) = @_;
 649   $type ||= $self->sqlt_type;
 650   eval "use SQL::Translator";
 651   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
 652   eval "use SQL::Translator::Parser::DBIx::Class;";
 653   $self->throw_exception($@) if $@;
 654   eval "use SQL::Translator::Producer::${type};";
 655   $self->throw_exception($@) if $@;
 656   my $tr = SQL::Translator->new(%$sqltargs);
 657   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
 658   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
 659 }
 660
 661 sub deploy {
 662   my ($self, $schema, $type, $sqltargs) = @_;
 663   my @statements = $self->deployment_statements($schema, $type, $sqltargs);
 664   foreach(split(";\n", @statements)) {
 665     $self->debugfh->print("$_\n") if $self->debug;
 666     $self->dbh->do($_) or warn "SQL was:\n $_";
 667   }
 668 }
 669
 670 sub DESTROY { shift->disconnect }
 671
 672 1;
 673
 674 =head1 ENVIRONMENT VARIABLES
 675
 676 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 677
 678 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 679 is produced (as when the L<debug> method is set).
 680
 681 If the value is of the form C<1=/path/name> then the trace output is
 682 written to the file C</path/name>.
 683
 684 =head1 AUTHORS
 685
 686 Matt S. Trout <mst@shadowcatsystems.co.uk>
 687
 688 Andy Grundman <andy@hybridized.org>
 689
 690 =head1 LICENSE
 691
 692 You may distribute this code under the same terms as Perl itself.
 693
 694 =cut
 695