lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use base 'DBIx::Class::Storage';
   4
   5 use strict;
   6 use warnings;
   7 use DBI;
   8 use SQL::Abstract::Limit;
   9 use DBIx::Class::Storage::DBI::Cursor;
  10 use IO::File;
  11 use Carp::Clan qw/DBIx::Class/;
  12
  13 BEGIN {
  14
  15 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  16
  17 use base qw/SQL::Abstract::Limit/;
  18
  19 sub select {
  20   my ($self, $table, $fields, $where, $order, @rest) = @_;
  21   $table = $self->_quote($table) unless ref($table);
  22   @rest = (-1) unless defined $rest[0];
  23   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  24     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  25   local $self->{having_bind} = [];
  26   my ($sql, @ret) = $self->SUPER::select(
  27     $table, $self->_recurse_fields($fields), $where, $order, @rest
  28   );
  29   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  30 }
  31
  32 sub insert {
  33   my $self = shift;
  34   my $table = shift;
  35   $table = $self->_quote($table) unless ref($table);
  36   $self->SUPER::insert($table, @_);
  37 }
  38
  39 sub update {
  40   my $self = shift;
  41   my $table = shift;
  42   $table = $self->_quote($table) unless ref($table);
  43   $self->SUPER::update($table, @_);
  44 }
  45
  46 sub delete {
  47   my $self = shift;
  48   my $table = shift;
  49   $table = $self->_quote($table) unless ref($table);
  50   $self->SUPER::delete($table, @_);
  51 }
  52
  53 sub _emulate_limit {
  54   my $self = shift;
  55   if ($_[3] == -1) {
  56     return $_[1].$self->_order_by($_[2]);
  57   } else {
  58     return $self->SUPER::_emulate_limit(@_);
  59   }
  60 }
  61
  62 sub _recurse_fields {
  63   my ($self, $fields) = @_;
  64   my $ref = ref $fields;
  65   return $self->_quote($fields) unless $ref;
  66   return $$fields if $ref eq 'SCALAR';
  67
  68   if ($ref eq 'ARRAY') {
  69     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  70   } elsif ($ref eq 'HASH') {
  71     foreach my $func (keys %$fields) {
  72       return $self->_sqlcase($func)
  73         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  74     }
  75   }
  76 }
  77
  78 sub _order_by {
  79   my $self = shift;
  80   my $ret = '';
  81   my @extra;
  82   if (ref $_[0] eq 'HASH') {
  83     if (defined $_[0]->{group_by}) {
  84       $ret = $self->_sqlcase(' group by ')
  85                .$self->_recurse_fields($_[0]->{group_by});
  86     }
  87     if (defined $_[0]->{having}) {
  88       my $frag;
  89       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  90       push(@{$self->{having_bind}}, @extra);
  91       $ret .= $self->_sqlcase(' having ').$frag;
  92     }
  93     if (defined $_[0]->{order_by}) {
  94       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  95     }
  96   } elsif(ref $_[0] eq 'SCALAR') {
  97     $ret = $self->_sqlcase(' order by ').${ $_[0] };
  98   } else {
  99     $ret = $self->SUPER::_order_by(@_);
 100   }
 101   return $ret;
 102 }
 103
 104 sub _order_directions {
 105   my ($self, $order) = @_;
 106   $order = $order->{order_by} if ref $order eq 'HASH';
 107   return $self->SUPER::_order_directions($order);
 108 }
 109
 110 sub _table {
 111   my ($self, $from) = @_;
 112   if (ref $from eq 'ARRAY') {
 113     return $self->_recurse_from(@$from);
 114   } elsif (ref $from eq 'HASH') {
 115     return $self->_make_as($from);
 116   } else {
 117     return $from; # would love to quote here but _table ends up getting called
 118                   # twice during an ->select without a limit clause due to
 119                   # the way S::A::Limit->select works. should maybe consider
 120                   # bypassing this and doing S::A::select($self, ...) in
 121                   # our select method above. meantime, quoting shims have
 122                   # been added to select/insert/update/delete here
 123   }
 124 }
 125
 126 sub _recurse_from {
 127   my ($self, $from, @join) = @_;
 128   my @sqlf;
 129   push(@sqlf, $self->_make_as($from));
 130   foreach my $j (@join) {
 131     my ($to, $on) = @$j;
 132
 133     # check whether a join type exists
 134     my $join_clause = '';
 135     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 136       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 137     } else {
 138       $join_clause = ' JOIN ';
 139     }
 140     push(@sqlf, $join_clause);
 141
 142     if (ref $to eq 'ARRAY') {
 143       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 144     } else {
 145       push(@sqlf, $self->_make_as($to));
 146     }
 147     push(@sqlf, ' ON ', $self->_join_condition($on));
 148   }
 149   return join('', @sqlf);
 150 }
 151
 152 sub _make_as {
 153   my ($self, $from) = @_;
 154   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 155                      reverse each %{$self->_skip_options($from)});
 156 }
 157
 158 sub _skip_options {
 159   my ($self, $hash) = @_;
 160   my $clean_hash = {};
 161   $clean_hash->{$_} = $hash->{$_}
 162     for grep {!/^-/} keys %$hash;
 163   return $clean_hash;
 164 }
 165
 166 sub _join_condition {
 167   my ($self, $cond) = @_;
 168   if (ref $cond eq 'HASH') {
 169     my %j;
 170     for (keys %$cond) {
 171       my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x;
 172     };
 173     return $self->_recurse_where(\%j);
 174   } elsif (ref $cond eq 'ARRAY') {
 175     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 176   } else {
 177     die "Can't handle this yet!";
 178   }
 179 }
 180
 181 sub _quote {
 182   my ($self, $label) = @_;
 183   return '' unless defined $label;
 184   return "*" if $label eq '*';
 185   return $label unless $self->{quote_char};
 186   if(ref $self->{quote_char} eq "ARRAY"){
 187     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 188       if !defined $self->{name_sep};
 189     my $sep = $self->{name_sep};
 190     return join($self->{name_sep},
 191         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 192        split(/\Q$sep\E/,$label));
 193   }
 194   return $self->SUPER::_quote($label);
 195 }
 196
 197 sub _RowNum {
 198    my $self = shift;
 199    my $c;
 200    $_[0] =~ s/SELECT (.*?) FROM/
 201      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 202    $self->SUPER::_RowNum(@_);
 203 }
 204
 205 # Accessor for setting limit dialect. This is useful
 206 # for JDBC-bridge among others where the remote SQL-dialect cannot
 207 # be determined by the name of the driver alone.
 208 #
 209 sub limit_dialect {
 210     my $self = shift;
 211     $self->{limit_dialect} = shift if @_;
 212     return $self->{limit_dialect};
 213 }
 214
 215 sub quote_char {
 216     my $self = shift;
 217     $self->{quote_char} = shift if @_;
 218     return $self->{quote_char};
 219 }
 220
 221 sub name_sep {
 222     my $self = shift;
 223     $self->{name_sep} = shift if @_;
 224     return $self->{name_sep};
 225 }
 226
 227
 228
 229
 230 package DBIx::Class::Storage::DBI::DebugCallback;
 231
 232 sub print {
 233   my ($self, $string) = @_;
 234   $string =~ m/^(\w+)/;
 235   ${$self}->($1, $string);
 236 }
 237
 238 } # End of BEGIN block
 239
 240 use base qw/DBIx::Class/;
 241
 242 __PACKAGE__->load_components(qw/AccessorGroup/);
 243
 244 __PACKAGE__->mk_group_accessors('simple' =>
 245   qw/connect_info _dbh _sql_maker _conn_pid _conn_tid debug debugfh
 246      cursor on_connect_do transaction_depth/);
 247
 248 sub new {
 249   my $new = bless({}, ref $_[0] || $_[0]);
 250   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 251   $new->transaction_depth(0);
 252   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 253      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 254     $new->debugfh(IO::File->new($1, 'w'))
 255       or $new->throw_exception("Cannot open trace file $1");
 256   } else {
 257     $new->debugfh(IO::File->new('>&STDERR'));
 258   }
 259   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 260   return $new;
 261 }
 262
 263 sub throw_exception {
 264   my ($self, $msg) = @_;
 265   croak($msg);
 266 }
 267
 268 =head1 NAME
 269
 270 DBIx::Class::Storage::DBI - DBI storage handler
 271
 272 =head1 SYNOPSIS
 273
 274 =head1 DESCRIPTION
 275
 276 This class represents the connection to the database
 277
 278 =head1 METHODS
 279
 280 =cut
 281
 282 =head2 on_connect_do
 283
 284 Executes the sql statements given as a listref on every db connect.
 285
 286 =head2 debug
 287
 288 Causes SQL trace information to be emitted on C<debugfh> filehandle
 289 (or C<STDERR> if C<debugfh> has not specifically been set).
 290
 291 =head2 debugfh
 292
 293 Sets or retrieves the filehandle used for trace/debug output.  This
 294 should be an IO::Handle compatible object (only the C<print> method is
 295 used).  Initially set to be STDERR - although see information on the
 296 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 297
 298 =head2 debugcb
 299
 300 Sets a callback to be executed each time a statement is run; takes a sub
 301 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 302 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 303 be printed.
 304
 305 =cut
 306
 307 sub debugcb {
 308   my ($self, $cb) = @_;
 309   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 310   $self->debugfh($cb_obj);
 311 }
 312
 313 sub disconnect {
 314   my ($self) = @_;
 315
 316   if( $self->connected ) {
 317     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 318     $self->_dbh->disconnect;
 319     $self->_dbh(undef);
 320   }
 321 }
 322
 323 sub connected {
 324   my ($self) = @_;
 325
 326   if(my $dbh = $self->_dbh) {
 327       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 328           $self->_sql_maker(undef);
 329           return $self->_dbh(undef);
 330       }
 331       elsif($self->_conn_pid != $$) {
 332           $self->_dbh->{InactiveDestroy} = 1;
 333           $self->_sql_maker(undef);
 334           return $self->_dbh(undef)
 335       }
 336       return ($dbh->FETCH('Active') && $dbh->ping);
 337   }
 338
 339   return 0;
 340 }
 341
 342 sub ensure_connected {
 343   my ($self) = @_;
 344
 345   unless ($self->connected) {
 346     $self->_populate_dbh;
 347   }
 348 }
 349
 350 =head2 dbh
 351
 352 Returns the dbh - a data base handle of class L<DBI>.
 353
 354 =cut
 355
 356 sub dbh {
 357   my ($self) = @_;
 358
 359   $self->ensure_connected;
 360   return $self->_dbh;
 361 }
 362
 363 sub sql_maker {
 364   my ($self) = @_;
 365   unless ($self->_sql_maker) {
 366     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 367   }
 368   return $self->_sql_maker;
 369 }
 370
 371 sub _populate_dbh {
 372   my ($self) = @_;
 373   my @info = @{$self->connect_info || []};
 374   $self->_dbh($self->_connect(@info));
 375   my $driver = $self->_dbh->{Driver}->{Name};
 376   eval "require DBIx::Class::Storage::DBI::${driver}";
 377   unless ($@) {
 378     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 379   }
 380   # if on-connect sql statements are given execute them
 381   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 382     $self->_dbh->do($sql_statement);
 383   }
 384
 385   $self->_conn_pid($$);
 386   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 387 }
 388
 389 sub _connect {
 390   my ($self, @info) = @_;
 391
 392   $self->throw_exception("You failed to provide any connection info")
 393       if !@info;
 394
 395   my ($old_connect_via, $dbh);
 396
 397   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 398       $old_connect_via = $DBI::connect_via;
 399       $DBI::connect_via = 'connect';
 400   }
 401
 402   eval {
 403     if(ref $info[0] eq 'CODE') {
 404         $dbh = &{$info[0]};
 405     }
 406     else {
 407         $dbh = DBI->connect(@info);
 408     }
 409   };
 410
 411   $DBI::connect_via = $old_connect_via if $old_connect_via;
 412
 413   if (!$dbh || $@) {
 414     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 415   }
 416
 417   $dbh;
 418 }
 419
 420 =head2 txn_begin
 421
 422 Calls begin_work on the current dbh.
 423
 424 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
 425 an entire code block to be executed transactionally.
 426
 427 =cut
 428
 429 sub txn_begin {
 430   my $self = shift;
 431   if ($self->{transaction_depth}++ == 0) {
 432     my $dbh = $self->dbh;
 433     if ($dbh->{AutoCommit}) {
 434       $self->debugfh->print("BEGIN WORK\n")
 435         if ($self->debug);
 436       $dbh->begin_work;
 437     }
 438   }
 439 }
 440
 441 =head2 txn_commit
 442
 443 Issues a commit against the current dbh.
 444
 445 =cut
 446
 447 sub txn_commit {
 448   my $self = shift;
 449   if ($self->{transaction_depth} == 0) {
 450     my $dbh = $self->dbh;
 451     unless ($dbh->{AutoCommit}) {
 452       $self->debugfh->print("COMMIT\n")
 453         if ($self->debug);
 454       $dbh->commit;
 455     }
 456   }
 457   else {
 458     if (--$self->{transaction_depth} == 0) {
 459       $self->debugfh->print("COMMIT\n")
 460         if ($self->debug);
 461       $self->dbh->commit;
 462     }
 463   }
 464 }
 465
 466 =head2 txn_rollback
 467
 468 Issues a rollback against the current dbh. A nested rollback will
 469 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 470 which allows the rollback to propagate to the outermost transaction.
 471
 472 =cut
 473
 474 sub txn_rollback {
 475   my $self = shift;
 476
 477   eval {
 478     if ($self->{transaction_depth} == 0) {
 479       my $dbh = $self->dbh;
 480       unless ($dbh->{AutoCommit}) {
 481         $self->debugfh->print("ROLLBACK\n")
 482           if ($self->debug);
 483         $dbh->rollback;
 484       }
 485     }
 486     else {
 487       if (--$self->{transaction_depth} == 0) {
 488         $self->debugfh->print("ROLLBACK\n")
 489           if ($self->debug);
 490         $self->dbh->rollback;
 491       }
 492       else {
 493         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 494       }
 495     }
 496   };
 497
 498   if ($@) {
 499     my $error = $@;
 500     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 501     $error =~ /$exception_class/ and $self->throw_exception($error);
 502     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 503     $self->throw_exception($error);          # resets the transaction depth
 504   }
 505 }
 506
 507 sub _execute {
 508   my ($self, $op, $extra_bind, $ident, @args) = @_;
 509   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 510   unshift(@bind, @$extra_bind) if $extra_bind;
 511   if ($self->debug) {
 512       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 513       $self->debugfh->print("$sql: " . join(', ', @debug_bind) . "\n");
 514   }
 515   my $sth = eval { $self->sth($sql,$op) };
 516
 517   if (!$sth || $@) {
 518     $self->throw_exception('no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql");
 519   }
 520
 521   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 522   my $rv;
 523   if ($sth) {
 524     $rv = eval { $sth->execute(@bind) };
 525
 526     if ($@ || !$rv) {
 527       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 528     }
 529   } else {
 530     $self->throw_exception("'$sql' did not generate a statement.");
 531   }
 532   return (wantarray ? ($rv, $sth, @bind) : $rv);
 533 }
 534
 535 sub insert {
 536   my ($self, $ident, $to_insert) = @_;
 537   $self->throw_exception(
 538     "Couldn't insert ".join(', ',
 539       map "$_ => $to_insert->{$_}", keys %$to_insert
 540     )." into ${ident}"
 541   ) unless ($self->_execute('insert' => [], $ident, $to_insert));
 542   return $to_insert;
 543 }
 544
 545 sub update {
 546   return shift->_execute('update' => [], @_);
 547 }
 548
 549 sub delete {
 550   return shift->_execute('delete' => [], @_);
 551 }
 552
 553 sub _select {
 554   my ($self, $ident, $select, $condition, $attrs) = @_;
 555   my $order = $attrs->{order_by};
 556   if (ref $condition eq 'SCALAR') {
 557     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 558   }
 559   if (exists $attrs->{group_by} || $attrs->{having}) {
 560     $order = {
 561       group_by => $attrs->{group_by},
 562       having => $attrs->{having},
 563       ($order ? (order_by => $order) : ())
 564     };
 565   }
 566   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 567   if ($attrs->{software_limit} ||
 568       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 569         $attrs->{software_limit} = 1;
 570   } else {
 571     $self->throw_exception("rows attribute must be positive if present")
 572       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
 573     push @args, $attrs->{rows}, $attrs->{offset};
 574   }
 575   return $self->_execute(@args);
 576 }
 577
 578 sub select {
 579   my $self = shift;
 580   my ($ident, $select, $condition, $attrs) = @_;
 581   return $self->cursor->new($self, \@_, $attrs);
 582 }
 583
 584 # Need to call finish() to work round broken DBDs
 585
 586 sub select_single {
 587   my $self = shift;
 588   my ($rv, $sth, @bind) = $self->_select(@_);
 589   my @row = $sth->fetchrow_array;
 590   $sth->finish();
 591   return @row;
 592 }
 593
 594 sub sth {
 595   my ($self, $sql) = @_;
 596   # 3 is the if_active parameter which avoids active sth re-use
 597   return $self->dbh->prepare_cached($sql, {}, 3);
 598 }
 599
 600 =head2 columns_info_for
 601
 602 Returns database type info for a given table columns.
 603
 604 =cut
 605
 606 sub columns_info_for {
 607   my ($self, $table) = @_;
 608
 609   my $dbh = $self->dbh;
 610
 611   if ($dbh->can('column_info')) {
 612     my %result;
 613     my $old_raise_err = $dbh->{RaiseError};
 614     my $old_print_err = $dbh->{PrintError};
 615     $dbh->{RaiseError} = 1;
 616     $dbh->{PrintError} = 0;
 617     eval {
 618       my $sth = $dbh->column_info( undef, undef, $table, '%' );
 619       $sth->execute();
 620       while ( my $info = $sth->fetchrow_hashref() ){
 621         my %column_info;
 622         $column_info{data_type}   = $info->{TYPE_NAME};
 623         $column_info{size}      = $info->{COLUMN_SIZE};
 624         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 625         $column_info{default_value} = $info->{COLUMN_DEF};
 626
 627         $result{$info->{COLUMN_NAME}} = \%column_info;
 628       }
 629     };
 630     $dbh->{RaiseError} = $old_raise_err;
 631     $dbh->{PrintError} = $old_print_err;
 632     return \%result if !$@;
 633   }
 634
 635   my %result;
 636   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
 637   $sth->execute;
 638   my @columns = @{$sth->{NAME_lc}};
 639   for my $i ( 0 .. $#columns ){
 640     my %column_info;
 641     my $type_num = $sth->{TYPE}->[$i];
 642     my $type_name;
 643     if(defined $type_num && $dbh->can('type_info')) {
 644       my $type_info = $dbh->type_info($type_num);
 645       $type_name = $type_info->{TYPE_NAME} if $type_info;
 646     }
 647     $column_info{data_type} = $type_name ? $type_name : $type_num;
 648     $column_info{size} = $sth->{PRECISION}->[$i];
 649     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 650
 651     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 652       $column_info{data_type} = $1;
 653       $column_info{size}    = $2;
 654     }
 655
 656     $result{$columns[$i]} = \%column_info;
 657   }
 658
 659   return \%result;
 660 }
 661
 662 sub last_insert_id {
 663   my ($self, $row) = @_;
 664
 665   return $self->dbh->func('last_insert_rowid');
 666
 667 }
 668
 669 sub sqlt_type { shift->dbh->{Driver}->{Name} }
 670
 671 sub deployment_statements {
 672   my ($self, $schema, $type, $sqltargs) = @_;
 673   $type ||= $self->sqlt_type;
 674   eval "use SQL::Translator";
 675   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
 676   eval "use SQL::Translator::Parser::DBIx::Class;";
 677   $self->throw_exception($@) if $@;
 678   eval "use SQL::Translator::Producer::${type};";
 679   $self->throw_exception($@) if $@;
 680   my $tr = SQL::Translator->new(%$sqltargs);
 681   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
 682   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
 683 }
 684
 685 sub deploy {
 686   my ($self, $schema, $type, $sqltargs) = @_;
 687   foreach my $statement ( $self->deployment_statements($schema, $type, $sqltargs) ) {
 688     for ( split(";\n", $statement)) {
 689       $self->debugfh->print("$_\n") if $self->debug;
 690       $self->dbh->do($_) or warn "SQL was:\n $_";
 691     }
 692   }
 693 }
 694
 695 sub DESTROY { shift->disconnect }
 696
 697 1;
 698
 699 =head1 ENVIRONMENT VARIABLES
 700
 701 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 702
 703 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 704 is produced (as when the L<debug> method is set).
 705
 706 If the value is of the form C<1=/path/name> then the trace output is
 707 written to the file C</path/name>.
 708
 709 =head1 AUTHORS
 710
 711 Matt S. Trout <mst@shadowcatsystems.co.uk>
 712
 713 Andy Grundman <andy@hybridized.org>
 714
 715 =head1 LICENSE
 716
 717 You may distribute this code under the same terms as Perl itself.
 718
 719 =cut
 720