lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2
   3 use base 'DBIx::Class::Storage';
   4
   5 use strict;
   6 use warnings;
   7 use DBI;
   8 use SQL::Abstract::Limit;
   9 use DBIx::Class::Storage::DBI::Cursor;
  10 use IO::File;
  11 use Carp::Clan qw/DBIx::Class/;
  12
  13 BEGIN {
  14
  15 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  16
  17 use base qw/SQL::Abstract::Limit/;
  18
  19 sub select {
  20   my ($self, $table, $fields, $where, $order, @rest) = @_;
  21   $table = $self->_quote($table) unless ref($table);
  22   @rest = (-1) unless defined $rest[0];
  23   local $self->{having_bind} = [];
  24   my ($sql, @ret) = $self->SUPER::select(
  25     $table, $self->_recurse_fields($fields), $where, $order, @rest
  26   );
  27   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  28 }
  29
  30 sub insert {
  31   my $self = shift;
  32   my $table = shift;
  33   $table = $self->_quote($table) unless ref($table);
  34   $self->SUPER::insert($table, @_);
  35 }
  36
  37 sub update {
  38   my $self = shift;
  39   my $table = shift;
  40   $table = $self->_quote($table) unless ref($table);
  41   $self->SUPER::update($table, @_);
  42 }
  43
  44 sub delete {
  45   my $self = shift;
  46   my $table = shift;
  47   $table = $self->_quote($table) unless ref($table);
  48   $self->SUPER::delete($table, @_);
  49 }
  50
  51 sub _emulate_limit {
  52   my $self = shift;
  53   if ($_[3] == -1) {
  54     return $_[1].$self->_order_by($_[2]);
  55   } else {
  56     return $self->SUPER::_emulate_limit(@_);
  57   }
  58 }
  59
  60 sub _recurse_fields {
  61   my ($self, $fields) = @_;
  62   my $ref = ref $fields;
  63   return $self->_quote($fields) unless $ref;
  64   return $$fields if $ref eq 'SCALAR';
  65
  66   if ($ref eq 'ARRAY') {
  67     return join(', ', map { $self->_recurse_fields($_) } @$fields);
  68   } elsif ($ref eq 'HASH') {
  69     foreach my $func (keys %$fields) {
  70       return $self->_sqlcase($func)
  71         .'( '.$self->_recurse_fields($fields->{$func}).' )';
  72     }
  73   }
  74 }
  75
  76 sub _order_by {
  77   my $self = shift;
  78   my $ret = '';
  79   my @extra;
  80   if (ref $_[0] eq 'HASH') {
  81     if (defined $_[0]->{group_by}) {
  82       $ret = $self->_sqlcase(' group by ')
  83                .$self->_recurse_fields($_[0]->{group_by});
  84     }
  85     if (defined $_[0]->{having}) {
  86       my $frag;
  87       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
  88       push(@{$self->{having_bind}}, @extra);
  89       $ret .= $self->_sqlcase(' having ').$frag;
  90     }
  91     if (defined $_[0]->{order_by}) {
  92       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
  93     }
  94   } elsif(ref $_[0] eq 'SCALAR') {
  95     $ret = $self->_sqlcase(' order by ').${ $_[0] };
  96   } else {
  97     $ret = $self->SUPER::_order_by(@_);
  98   }
  99   return $ret;
 100 }
 101
 102 sub _order_directions {
 103   my ($self, $order) = @_;
 104   $order = $order->{order_by} if ref $order eq 'HASH';
 105   return $self->SUPER::_order_directions($order);
 106 }
 107
 108 sub _table {
 109   my ($self, $from) = @_;
 110   if (ref $from eq 'ARRAY') {
 111     return $self->_recurse_from(@$from);
 112   } elsif (ref $from eq 'HASH') {
 113     return $self->_make_as($from);
 114   } else {
 115     return $from; # would love to quote here but _table ends up getting called
 116                   # twice during an ->select without a limit clause due to
 117                   # the way S::A::Limit->select works. should maybe consider
 118                   # bypassing this and doing S::A::select($self, ...) in
 119                   # our select method above. meantime, quoting shims have
 120                   # been added to select/insert/update/delete here
 121   }
 122 }
 123
 124 sub _recurse_from {
 125   my ($self, $from, @join) = @_;
 126   my @sqlf;
 127   push(@sqlf, $self->_make_as($from));
 128   foreach my $j (@join) {
 129     my ($to, $on) = @$j;
 130
 131     # check whether a join type exists
 132     my $join_clause = '';
 133     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
 134       $join_clause = ' '.uc($to->{-join_type}).' JOIN ';
 135     } else {
 136       $join_clause = ' JOIN ';
 137     }
 138     push(@sqlf, $join_clause);
 139
 140     if (ref $to eq 'ARRAY') {
 141       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 142     } else {
 143       push(@sqlf, $self->_make_as($to));
 144     }
 145     push(@sqlf, ' ON ', $self->_join_condition($on));
 146   }
 147   return join('', @sqlf);
 148 }
 149
 150 sub _make_as {
 151   my ($self, $from) = @_;
 152   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 153                      reverse each %{$self->_skip_options($from)});
 154 }
 155
 156 sub _skip_options {
 157   my ($self, $hash) = @_;
 158   my $clean_hash = {};
 159   $clean_hash->{$_} = $hash->{$_}
 160     for grep {!/^-/} keys %$hash;
 161   return $clean_hash;
 162 }
 163
 164 sub _join_condition {
 165   my ($self, $cond) = @_;
 166   if (ref $cond eq 'HASH') {
 167     my %j;
 168     for (keys %$cond) {
 169       my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x;
 170     };
 171     return $self->_recurse_where(\%j);
 172   } elsif (ref $cond eq 'ARRAY') {
 173     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 174   } else {
 175     die "Can't handle this yet!";
 176   }
 177 }
 178
 179 sub _quote {
 180   my ($self, $label) = @_;
 181   return '' unless defined $label;
 182   return "*" if $label eq '*';
 183   return $label unless $self->{quote_char};
 184   if(ref $self->{quote_char} eq "ARRAY"){
 185     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 186       if !defined $self->{name_sep};
 187     my $sep = $self->{name_sep};
 188     return join($self->{name_sep},
 189         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 190        split(/\Q$sep\E/,$label));
 191   }
 192   return $self->SUPER::_quote($label);
 193 }
 194
 195 sub _RowNum {
 196    my $self = shift;
 197    my $c;
 198    $_[0] =~ s/SELECT (.*?) FROM/
 199      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
 200    $self->SUPER::_RowNum(@_);
 201 }
 202
 203 # Accessor for setting limit dialect. This is useful
 204 # for JDBC-bridge among others where the remote SQL-dialect cannot
 205 # be determined by the name of the driver alone.
 206 #
 207 sub limit_dialect {
 208     my $self = shift;
 209     $self->{limit_dialect} = shift if @_;
 210     return $self->{limit_dialect};
 211 }
 212
 213 sub quote_char {
 214     my $self = shift;
 215     $self->{quote_char} = shift if @_;
 216     return $self->{quote_char};
 217 }
 218
 219 sub name_sep {
 220     my $self = shift;
 221     $self->{name_sep} = shift if @_;
 222     return $self->{name_sep};
 223 }
 224
 225
 226
 227
 228 package DBIx::Class::Storage::DBI::DebugCallback;
 229
 230 sub print {
 231   my ($self, $string) = @_;
 232   $string =~ m/^(\w+)/;
 233   ${$self}->($1, $string);
 234 }
 235
 236 } # End of BEGIN block
 237
 238 use base qw/DBIx::Class/;
 239
 240 __PACKAGE__->load_components(qw/AccessorGroup/);
 241
 242 __PACKAGE__->mk_group_accessors('simple' =>
 243   qw/_connect_info _dbh _sql_maker _conn_pid _conn_tid debug debugfh
 244      cursor on_connect_do transaction_depth/);
 245
 246 sub new {
 247   my $new = bless({}, ref $_[0] || $_[0]);
 248   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 249   $new->transaction_depth(0);
 250   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
 251      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
 252     $new->debugfh(IO::File->new($1, 'w'))
 253       or $new->throw_exception("Cannot open trace file $1");
 254   } else {
 255     $new->debugfh(IO::File->new('>&STDERR'));
 256   }
 257   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
 258   return $new;
 259 }
 260
 261 sub throw_exception {
 262   my ($self, $msg) = @_;
 263   croak($msg);
 264 }
 265
 266 =head1 NAME
 267
 268 DBIx::Class::Storage::DBI - DBI storage handler
 269
 270 =head1 SYNOPSIS
 271
 272 =head1 DESCRIPTION
 273
 274 This class represents the connection to the database
 275
 276 =head1 METHODS
 277
 278 =cut
 279
 280 =head2 connect_info
 281
 282 Connection information arrayref.  Can either be the same arguments
 283 one would pass to DBI->connect, or a code-reference which returns
 284 a connected database handle.  In either case, there is an optional
 285 final element in the arrayref, which can hold a hashref of
 286 connection-specific Storage::DBI options.  These include
 287 C<on_connect_do>, and the sql_maker options C<limit_dialect>,
 288 C<quote_char>, and C<name_sep>.  Examples:
 289
 290   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 291   ->connect_info(sub { DBI->connect(...) });
 292   ->connect_info([ 'dbi:Pg:dbname=foo',
 293                    'postgres',
 294                    '',
 295                    { AutoCommit => 0 },
 296                    { quote_char => q{`}, name_sep => q{@} },
 297                  ]);
 298
 299 =head2 on_connect_do
 300
 301 Executes the sql statements given as a listref on every db connect.
 302
 303 =head2 debug
 304
 305 Causes SQL trace information to be emitted on C<debugfh> filehandle
 306 (or C<STDERR> if C<debugfh> has not specifically been set).
 307
 308 =head2 debugfh
 309
 310 Sets or retrieves the filehandle used for trace/debug output.  This
 311 should be an IO::Handle compatible object (only the C<print> method is
 312 used).  Initially set to be STDERR - although see information on the
 313 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
 314
 315 =head2 debugcb
 316
 317 Sets a callback to be executed each time a statement is run; takes a sub
 318 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
 319 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
 320 be printed.
 321
 322 =cut
 323
 324 sub debugcb {
 325   my ($self, $cb) = @_;
 326   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
 327   $self->debugfh($cb_obj);
 328 }
 329
 330 sub disconnect {
 331   my ($self) = @_;
 332
 333   if( $self->connected ) {
 334     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 335     $self->_dbh->disconnect;
 336     $self->_dbh(undef);
 337   }
 338 }
 339
 340 sub connected {
 341   my ($self) = @_;
 342
 343   if(my $dbh = $self->_dbh) {
 344       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 345           $self->_sql_maker(undef);
 346           return $self->_dbh(undef);
 347       }
 348       elsif($self->_conn_pid != $$) {
 349           $self->_dbh->{InactiveDestroy} = 1;
 350           $self->_sql_maker(undef);
 351           return $self->_dbh(undef)
 352       }
 353       return ($dbh->FETCH('Active') && $dbh->ping);
 354   }
 355
 356   return 0;
 357 }
 358
 359 sub ensure_connected {
 360   my ($self) = @_;
 361
 362   unless ($self->connected) {
 363     $self->_populate_dbh;
 364   }
 365 }
 366
 367 sub dbh {
 368   my ($self) = @_;
 369
 370   $self->ensure_connected;
 371   return $self->_dbh;
 372 }
 373
 374 sub sql_maker {
 375   my ($self) = @_;
 376   unless ($self->_sql_maker) {
 377     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
 378   }
 379   return $self->_sql_maker;
 380 }
 381
 382 sub connect_info {
 383     my ($self, $info_arg) = @_;
 384
 385     if($info_arg) {
 386         my $info = [ @$info_arg ]; # copy because we can alter it
 387         my $last_info = $info->[-1];
 388         if(ref $last_info eq 'HASH') {
 389             my $used;
 390             if(my $on_connect_do = $last_info->{on_connect_do}) {
 391                $used = 1;
 392                $self->on_connect_do($on_connect_do);
 393             }
 394             for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 395                 if(my $opt_val = $last_info->{$sql_maker_opt}) {
 396                     $used = 1;
 397                     $self->sql_maker->$sql_maker_opt($opt_val);
 398                 }
 399             }
 400
 401             # remove our options hashref if it was there, to avoid confusing
 402             #   DBI in the case the user didn't use all 4 DBI options, as in:
 403             #   [ 'dbi:SQLite:foo.db', { quote_char => q{`} } ]
 404             pop(@$info) if $used;
 405         }
 406
 407         $self->_connect_info($info);
 408     }
 409
 410     $self->_connect_info;
 411 }
 412
 413 sub _populate_dbh {
 414   my ($self) = @_;
 415   my @info = @{$self->_connect_info || []};
 416   $self->_dbh($self->_connect(@info));
 417   my $driver = $self->_dbh->{Driver}->{Name};
 418   eval "require DBIx::Class::Storage::DBI::${driver}";
 419   unless ($@) {
 420     bless $self, "DBIx::Class::Storage::DBI::${driver}";
 421   }
 422   # if on-connect sql statements are given execute them
 423   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 424     $self->_dbh->do($sql_statement);
 425   }
 426
 427   $self->_conn_pid($$);
 428   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 429 }
 430
 431 sub _connect {
 432   my ($self, @info) = @_;
 433
 434   $self->throw_exception("You failed to provide any connection info")
 435       if !@info;
 436
 437   my ($old_connect_via, $dbh);
 438
 439   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 440       $old_connect_via = $DBI::connect_via;
 441       $DBI::connect_via = 'connect';
 442   }
 443
 444   eval {
 445     if(ref $info[0] eq 'CODE') {
 446         $dbh = &{$info[0]};
 447     }
 448     else {
 449         $dbh = DBI->connect(@info);
 450     }
 451   };
 452
 453   $DBI::connect_via = $old_connect_via if $old_connect_via;
 454
 455   if (!$dbh || $@) {
 456     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 457   }
 458
 459   $dbh;
 460 }
 461
 462 =head2 txn_begin
 463
 464 Calls begin_work on the current dbh.
 465
 466 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
 467 an entire code block to be executed transactionally.
 468
 469 =cut
 470
 471 sub txn_begin {
 472   my $self = shift;
 473   if ($self->{transaction_depth}++ == 0) {
 474     my $dbh = $self->dbh;
 475     if ($dbh->{AutoCommit}) {
 476       $self->debugfh->print("BEGIN WORK\n")
 477         if ($self->debug);
 478       $dbh->begin_work;
 479     }
 480   }
 481 }
 482
 483 =head2 txn_commit
 484
 485 Issues a commit against the current dbh.
 486
 487 =cut
 488
 489 sub txn_commit {
 490   my $self = shift;
 491   if ($self->{transaction_depth} == 0) {
 492     my $dbh = $self->dbh;
 493     unless ($dbh->{AutoCommit}) {
 494       $self->debugfh->print("COMMIT\n")
 495         if ($self->debug);
 496       $dbh->commit;
 497     }
 498   }
 499   else {
 500     if (--$self->{transaction_depth} == 0) {
 501       $self->debugfh->print("COMMIT\n")
 502         if ($self->debug);
 503       $self->dbh->commit;
 504     }
 505   }
 506 }
 507
 508 =head2 txn_rollback
 509
 510 Issues a rollback against the current dbh. A nested rollback will
 511 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
 512 which allows the rollback to propagate to the outermost transaction.
 513
 514 =cut
 515
 516 sub txn_rollback {
 517   my $self = shift;
 518
 519   eval {
 520     if ($self->{transaction_depth} == 0) {
 521       my $dbh = $self->dbh;
 522       unless ($dbh->{AutoCommit}) {
 523         $self->debugfh->print("ROLLBACK\n")
 524           if ($self->debug);
 525         $dbh->rollback;
 526       }
 527     }
 528     else {
 529       if (--$self->{transaction_depth} == 0) {
 530         $self->debugfh->print("ROLLBACK\n")
 531           if ($self->debug);
 532         $self->dbh->rollback;
 533       }
 534       else {
 535         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 536       }
 537     }
 538   };
 539
 540   if ($@) {
 541     my $error = $@;
 542     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 543     $error =~ /$exception_class/ and $self->throw_exception($error);
 544     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 545     $self->throw_exception($error);          # resets the transaction depth
 546   }
 547 }
 548
 549 sub _execute {
 550   my ($self, $op, $extra_bind, $ident, @args) = @_;
 551   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 552   unshift(@bind, @$extra_bind) if $extra_bind;
 553   if ($self->debug) {
 554       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 555       $self->debugfh->print("$sql: " . join(', ', @debug_bind) . "\n");
 556   }
 557   my $sth = eval { $self->sth($sql,$op) };
 558
 559   if (!$sth || $@) {
 560     $self->throw_exception('no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql");
 561   }
 562
 563   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 564   my $rv;
 565   if ($sth) {
 566     $rv = eval { $sth->execute(@bind) };
 567
 568     if ($@ || !$rv) {
 569       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 570     }
 571   } else {
 572     $self->throw_exception("'$sql' did not generate a statement.");
 573   }
 574   return (wantarray ? ($rv, $sth, @bind) : $rv);
 575 }
 576
 577 sub insert {
 578   my ($self, $ident, $to_insert) = @_;
 579   $self->throw_exception(
 580     "Couldn't insert ".join(', ',
 581       map "$_ => $to_insert->{$_}", keys %$to_insert
 582     )." into ${ident}"
 583   ) unless ($self->_execute('insert' => [], $ident, $to_insert));
 584   return $to_insert;
 585 }
 586
 587 sub update {
 588   return shift->_execute('update' => [], @_);
 589 }
 590
 591 sub delete {
 592   return shift->_execute('delete' => [], @_);
 593 }
 594
 595 sub _select {
 596   my ($self, $ident, $select, $condition, $attrs) = @_;
 597   my $order = $attrs->{order_by};
 598   if (ref $condition eq 'SCALAR') {
 599     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
 600   }
 601   if (exists $attrs->{group_by} || $attrs->{having}) {
 602     $order = {
 603       group_by => $attrs->{group_by},
 604       having => $attrs->{having},
 605       ($order ? (order_by => $order) : ())
 606     };
 607   }
 608   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
 609   if ($attrs->{software_limit} ||
 610       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
 611         $attrs->{software_limit} = 1;
 612   } else {
 613     push @args, $attrs->{rows}, $attrs->{offset};
 614   }
 615   return $self->_execute(@args);
 616 }
 617
 618 sub select {
 619   my $self = shift;
 620   my ($ident, $select, $condition, $attrs) = @_;
 621   return $self->cursor->new($self, \@_, $attrs);
 622 }
 623
 624 # Need to call finish() to work round broken DBDs
 625
 626 sub select_single {
 627   my $self = shift;
 628   my ($rv, $sth, @bind) = $self->_select(@_);
 629   my @row = $sth->fetchrow_array;
 630   $sth->finish();
 631   return @row;
 632 }
 633
 634 sub sth {
 635   my ($self, $sql) = @_;
 636   # 3 is the if_active parameter which avoids active sth re-use
 637   return $self->dbh->prepare_cached($sql, {}, 3);
 638 }
 639
 640 =head2 columns_info_for
 641
 642 Returns database type info for a given table columns.
 643
 644 =cut
 645
 646 sub columns_info_for {
 647   my ($self, $table) = @_;
 648
 649   my $dbh = $self->dbh;
 650
 651   if ($dbh->can('column_info')) {
 652     my %result;
 653     my $old_raise_err = $dbh->{RaiseError};
 654     my $old_print_err = $dbh->{PrintError};
 655     $dbh->{RaiseError} = 1;
 656     $dbh->{PrintError} = 0;
 657     eval {
 658       my $sth = $dbh->column_info( undef, undef, $table, '%' );
 659       $sth->execute();
 660       while ( my $info = $sth->fetchrow_hashref() ){
 661         my %column_info;
 662         $column_info{data_type}   = $info->{TYPE_NAME};
 663         $column_info{size}      = $info->{COLUMN_SIZE};
 664         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 665         $column_info{default_value} = $info->{COLUMN_DEF};
 666
 667         $result{$info->{COLUMN_NAME}} = \%column_info;
 668       }
 669     };
 670     $dbh->{RaiseError} = $old_raise_err;
 671     $dbh->{PrintError} = $old_print_err;
 672     return \%result if !$@;
 673   }
 674
 675   my %result;
 676   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
 677   $sth->execute;
 678   my @columns = @{$sth->{NAME_lc}};
 679   for my $i ( 0 .. $#columns ){
 680     my %column_info;
 681     my $type_num = $sth->{TYPE}->[$i];
 682     my $type_name;
 683     if(defined $type_num && $dbh->can('type_info')) {
 684       my $type_info = $dbh->type_info($type_num);
 685       $type_name = $type_info->{TYPE_NAME} if $type_info;
 686     }
 687     $column_info{data_type} = $type_name ? $type_name : $type_num;
 688     $column_info{size} = $sth->{PRECISION}->[$i];
 689     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 690
 691     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 692       $column_info{data_type} = $1;
 693       $column_info{size}    = $2;
 694     }
 695
 696     $result{$columns[$i]} = \%column_info;
 697   }
 698
 699   return \%result;
 700 }
 701
 702 sub last_insert_id {
 703   my ($self, $row) = @_;
 704
 705   return $self->dbh->func('last_insert_rowid');
 706
 707 }
 708
 709 sub sqlt_type { shift->dbh->{Driver}->{Name} }
 710
 711 sub deployment_statements {
 712   my ($self, $schema, $type, $sqltargs) = @_;
 713   $type ||= $self->sqlt_type;
 714   eval "use SQL::Translator";
 715   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
 716   eval "use SQL::Translator::Parser::DBIx::Class;";
 717   $self->throw_exception($@) if $@;
 718   eval "use SQL::Translator::Producer::${type};";
 719   $self->throw_exception($@) if $@;
 720   my $tr = SQL::Translator->new(%$sqltargs);
 721   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
 722   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
 723 }
 724
 725 sub deploy {
 726   my ($self, $schema, $type, $sqltargs) = @_;
 727   foreach my $statement ( $self->deployment_statements($schema, $type, $sqltargs) ) {
 728     for ( split(";\n", $statement)) {
 729       $self->debugfh->print("$_\n") if $self->debug;
 730       $self->dbh->do($_) or warn "SQL was:\n $_";
 731     }
 732   }
 733 }
 734
 735 sub DESTROY { shift->disconnect }
 736
 737 1;
 738
 739 =head1 ENVIRONMENT VARIABLES
 740
 741 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
 742
 743 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
 744 is produced (as when the L<debug> method is set).
 745
 746 If the value is of the form C<1=/path/name> then the trace output is
 747 written to the file C</path/name>.
 748
 749 =head1 AUTHORS
 750
 751 Matt S. Trout <mst@shadowcatsystems.co.uk>
 752
 753 Andy Grundman <andy@hybridized.org>
 754
 755 =head1 LICENSE
 756
 757 You may distribute this code under the same terms as Perl itself.
 758
 759 =cut
 760