lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use DBIx::Class::Exception;
  12 use Scalar::Util qw/refaddr weaken reftype blessed/;
  13 use List::Util qw/first/;
  14 use Sub::Name 'subname';
  15 use Try::Tiny;
  16 use overload ();
  17 use Data::Compare (); # no imports!!! guard against insane architecture
  18 use namespace::clean;
  19
  20 # default cursor class, overridable in connect_info attributes
  21 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  22
  23 __PACKAGE__->mk_group_accessors('inherited' => qw/
  24   sql_limit_dialect sql_quote_char sql_name_sep
  25 /);
  26
  27 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  28
  29 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  30 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  31
  32 __PACKAGE__->sql_name_sep('.');
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/
  35   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  36   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  37 /);
  38
  39 # the values for these accessors are picked out (and deleted) from
  40 # the attribute hashref passed to connect_info
  41 my @storage_options = qw/
  42   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  43   disable_sth_caching unsafe auto_savepoint
  44 /;
  45 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  46
  47
  48 # capability definitions, using a 2-tiered accessor system
  49 # The rationale is:
  50 #
  51 # A driver/user may define _use_X, which blindly without any checks says:
  52 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  53 # type accessor)
  54 #
  55 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  56 # accessor, which in turn calls _determine_supports_X, and stores the return
  57 # in a special slot on the storage object, which is wiped every time a $dbh
  58 # reconnection takes place (it is not guaranteed that upon reconnection we
  59 # will get the same rdbms version). _determine_supports_X does not need to
  60 # exist on a driver, as we ->can for it before calling.
  61
  62 my @capabilities = (qw/
  63   insert_returning
  64   insert_returning_bound
  65
  66   multicolumn_in
  67
  68   placeholders
  69   typeless_placeholders
  70
  71   join_optimizer
  72 /);
  73 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  74 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  75
  76 # on by default, not strictly a capability (pending rewrite)
  77 __PACKAGE__->_use_join_optimizer (1);
  78 sub _determine_supports_join_optimizer { 1 };
  79
  80 # Each of these methods need _determine_driver called before itself
  81 # in order to function reliably. This is a purely DRY optimization
  82 #
  83 # get_(use)_dbms_capability need to be called on the correct Storage
  84 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  85 # _determine_supports_X which obv. needs a correct driver as well
  86 my @rdbms_specific_methods = qw/
  87   deployment_statements
  88   sqlt_type
  89   sql_maker
  90   build_datetime_parser
  91   datetime_parser_type
  92
  93   txn_begin
  94   insert
  95   insert_bulk
  96   update
  97   delete
  98   select
  99   select_single
 100   with_deferred_fk_checks
 101
 102   get_use_dbms_capability
 103   get_dbms_capability
 104
 105   _server_info
 106   _get_server_version
 107 /;
 108
 109 for my $meth (@rdbms_specific_methods) {
 110
 111   my $orig = __PACKAGE__->can ($meth)
 112     or die "$meth is not a ::Storage::DBI method!";
 113
 114   no strict qw/refs/;
 115   no warnings qw/redefine/;
 116   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 117     if (
 118       # only fire when invoked on an instance, a valid class-based invocation
 119       # would e.g. be setting a default for an inherited accessor
 120       ref $_[0]
 121         and
 122       ! $_[0]->_driver_determined
 123         and
 124       ! $_[0]->{_in_determine_driver}
 125     ) {
 126       $_[0]->_determine_driver;
 127
 128       # This for some reason crashes and burns on perl 5.8.1
 129       # IFF the method ends up throwing an exception
 130       #goto $_[0]->can ($meth);
 131
 132       my $cref = $_[0]->can ($meth);
 133       goto $cref;
 134     }
 135
 136     goto $orig;
 137   };
 138 }
 139
 140 =head1 NAME
 141
 142 DBIx::Class::Storage::DBI - DBI storage handler
 143
 144 =head1 SYNOPSIS
 145
 146   my $schema = MySchema->connect('dbi:SQLite:my.db');
 147
 148   $schema->storage->debug(1);
 149
 150   my @stuff = $schema->storage->dbh_do(
 151     sub {
 152       my ($storage, $dbh, @args) = @_;
 153       $dbh->do("DROP TABLE authors");
 154     },
 155     @column_list
 156   );
 157
 158   $schema->resultset('Book')->search({
 159      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 160   });
 161
 162 =head1 DESCRIPTION
 163
 164 This class represents the connection to an RDBMS via L<DBI>.  See
 165 L<DBIx::Class::Storage> for general information.  This pod only
 166 documents DBI-specific methods and behaviors.
 167
 168 =head1 METHODS
 169
 170 =cut
 171
 172 sub new {
 173   my $new = shift->next::method(@_);
 174
 175   $new->_sql_maker_opts({});
 176   $new->_dbh_details({});
 177   $new->{_in_do_block} = 0;
 178   $new->{_dbh_gen} = 0;
 179
 180   # read below to see what this does
 181   $new->_arm_global_destructor;
 182
 183   $new;
 184 }
 185
 186 # This is hack to work around perl shooting stuff in random
 187 # order on exit(). If we do not walk the remaining storage
 188 # objects in an END block, there is a *small but real* chance
 189 # of a fork()ed child to kill the parent's shared DBI handle,
 190 # *before perl reaches the DESTROY in this package*
 191 # Yes, it is ugly and effective.
 192 # Additionally this registry is used by the CLONE method to
 193 # make sure no handles are shared between threads
 194 {
 195   my %seek_and_destroy;
 196
 197   sub _arm_global_destructor {
 198     my $self = shift;
 199     my $key = refaddr ($self);
 200     $seek_and_destroy{$key} = $self;
 201     weaken ($seek_and_destroy{$key});
 202   }
 203
 204   END {
 205     local $?; # just in case the DBI destructor changes it somehow
 206
 207     # destroy just the object if not native to this process/thread
 208     $_->_verify_pid for (grep
 209       { defined $_ }
 210       values %seek_and_destroy
 211     );
 212   }
 213
 214   sub CLONE {
 215     # As per DBI's recommendation, DBIC disconnects all handles as
 216     # soon as possible (DBIC will reconnect only on demand from within
 217     # the thread)
 218     for (values %seek_and_destroy) {
 219       next unless $_;
 220       $_->{_dbh_gen}++;  # so that existing cursors will drop as well
 221       $_->_dbh(undef);
 222
 223       $_->transaction_depth(0);
 224       $_->savepoints([]);
 225     }
 226   }
 227 }
 228
 229 sub DESTROY {
 230   my $self = shift;
 231
 232   # some databases spew warnings on implicit disconnect
 233   $self->_verify_pid;
 234   local $SIG{__WARN__} = sub {};
 235   $self->_dbh(undef);
 236
 237   # this op is necessary, since the very last perl runtime statement
 238   # triggers a global destruction shootout, and the $SIG localization
 239   # may very well be destroyed before perl actually gets to do the
 240   # $dbh undef
 241   1;
 242 }
 243
 244 # handle pid changes correctly - do not destroy parent's connection
 245 sub _verify_pid {
 246   my $self = shift;
 247
 248   my $pid = $self->_conn_pid;
 249   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 250     $dbh->{InactiveDestroy} = 1;
 251     $self->{_dbh_gen}++;
 252     $self->_dbh(undef);
 253     $self->transaction_depth(0);
 254     $self->savepoints([]);
 255   }
 256
 257   return;
 258 }
 259
 260 =head2 connect_info
 261
 262 This method is normally called by L<DBIx::Class::Schema/connection>, which
 263 encapsulates its argument list in an arrayref before passing them here.
 264
 265 The argument list may contain:
 266
 267 =over
 268
 269 =item *
 270
 271 The same 4-element argument set one would normally pass to
 272 L<DBI/connect>, optionally followed by
 273 L<extra attributes|/DBIx::Class specific connection attributes>
 274 recognized by DBIx::Class:
 275
 276   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 277
 278 =item *
 279
 280 A single code reference which returns a connected
 281 L<DBI database handle|DBI/connect> optionally followed by
 282 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 283 by DBIx::Class:
 284
 285   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 286
 287 =item *
 288
 289 A single hashref with all the attributes and the dsn/user/password
 290 mixed together:
 291
 292   $connect_info_args = [{
 293     dsn => $dsn,
 294     user => $user,
 295     password => $pass,
 296     %dbi_attributes,
 297     %extra_attributes,
 298   }];
 299
 300   $connect_info_args = [{
 301     dbh_maker => sub { DBI->connect (...) },
 302     %dbi_attributes,
 303     %extra_attributes,
 304   }];
 305
 306 This is particularly useful for L<Catalyst> based applications, allowing the
 307 following config (L<Config::General> style):
 308
 309   <Model::DB>
 310     schema_class   App::DB
 311     <connect_info>
 312       dsn          dbi:mysql:database=test
 313       user         testuser
 314       password     TestPass
 315       AutoCommit   1
 316     </connect_info>
 317   </Model::DB>
 318
 319 The C<dsn>/C<user>/C<password> combination can be substituted by the
 320 C<dbh_maker> key whose value is a coderef that returns a connected
 321 L<DBI database handle|DBI/connect>
 322
 323 =back
 324
 325 Please note that the L<DBI> docs recommend that you always explicitly
 326 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 327 recommends that it be set to I<1>, and that you perform transactions
 328 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 329 to I<1> if you do not do explicitly set it to zero.  This is the default
 330 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 331
 332 =head3 DBIx::Class specific connection attributes
 333
 334 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 335 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 336 the following connection options. These options can be mixed in with your other
 337 L<DBI> connection attributes, or placed in a separate hashref
 338 (C<\%extra_attributes>) as shown above.
 339
 340 Every time C<connect_info> is invoked, any previous settings for
 341 these options will be cleared before setting the new ones, regardless of
 342 whether any options are specified in the new C<connect_info>.
 343
 344
 345 =over
 346
 347 =item on_connect_do
 348
 349 Specifies things to do immediately after connecting or re-connecting to
 350 the database.  Its value may contain:
 351
 352 =over
 353
 354 =item a scalar
 355
 356 This contains one SQL statement to execute.
 357
 358 =item an array reference
 359
 360 This contains SQL statements to execute in order.  Each element contains
 361 a string or a code reference that returns a string.
 362
 363 =item a code reference
 364
 365 This contains some code to execute.  Unlike code references within an
 366 array reference, its return value is ignored.
 367
 368 =back
 369
 370 =item on_disconnect_do
 371
 372 Takes arguments in the same form as L</on_connect_do> and executes them
 373 immediately before disconnecting from the database.
 374
 375 Note, this only runs if you explicitly call L</disconnect> on the
 376 storage object.
 377
 378 =item on_connect_call
 379
 380 A more generalized form of L</on_connect_do> that calls the specified
 381 C<connect_call_METHOD> methods in your storage driver.
 382
 383   on_connect_do => 'select 1'
 384
 385 is equivalent to:
 386
 387   on_connect_call => [ [ do_sql => 'select 1' ] ]
 388
 389 Its values may contain:
 390
 391 =over
 392
 393 =item a scalar
 394
 395 Will call the C<connect_call_METHOD> method.
 396
 397 =item a code reference
 398
 399 Will execute C<< $code->($storage) >>
 400
 401 =item an array reference
 402
 403 Each value can be a method name or code reference.
 404
 405 =item an array of arrays
 406
 407 For each array, the first item is taken to be the C<connect_call_> method name
 408 or code reference, and the rest are parameters to it.
 409
 410 =back
 411
 412 Some predefined storage methods you may use:
 413
 414 =over
 415
 416 =item do_sql
 417
 418 Executes a SQL string or a code reference that returns a SQL string. This is
 419 what L</on_connect_do> and L</on_disconnect_do> use.
 420
 421 It can take:
 422
 423 =over
 424
 425 =item a scalar
 426
 427 Will execute the scalar as SQL.
 428
 429 =item an arrayref
 430
 431 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 432 attributes hashref and bind values.
 433
 434 =item a code reference
 435
 436 Will execute C<< $code->($storage) >> and execute the return array refs as
 437 above.
 438
 439 =back
 440
 441 =item datetime_setup
 442
 443 Execute any statements necessary to initialize the database session to return
 444 and accept datetime/timestamp values used with
 445 L<DBIx::Class::InflateColumn::DateTime>.
 446
 447 Only necessary for some databases, see your specific storage driver for
 448 implementation details.
 449
 450 =back
 451
 452 =item on_disconnect_call
 453
 454 Takes arguments in the same form as L</on_connect_call> and executes them
 455 immediately before disconnecting from the database.
 456
 457 Calls the C<disconnect_call_METHOD> methods as opposed to the
 458 C<connect_call_METHOD> methods called by L</on_connect_call>.
 459
 460 Note, this only runs if you explicitly call L</disconnect> on the
 461 storage object.
 462
 463 =item disable_sth_caching
 464
 465 If set to a true value, this option will disable the caching of
 466 statement handles via L<DBI/prepare_cached>.
 467
 468 =item limit_dialect
 469
 470 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 471 default L</sql_limit_dialect> setting of the storage (if any). For a list
 472 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 473
 474 =item quote_names
 475
 476 When true automatically sets L</quote_char> and L</name_sep> to the characters
 477 appropriate for your particular RDBMS. This option is preferred over specifying
 478 L</quote_char> directly.
 479
 480 =item quote_char
 481
 482 Specifies what characters to use to quote table and column names.
 483
 484 C<quote_char> expects either a single character, in which case is it
 485 is placed on either side of the table/column name, or an arrayref of length
 486 2 in which case the table/column name is placed between the elements.
 487
 488 For example under MySQL you should use C<< quote_char => '`' >>, and for
 489 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 490
 491 =item name_sep
 492
 493 This parameter is only useful in conjunction with C<quote_char>, and is used to
 494 specify the character that separates elements (schemas, tables, columns) from
 495 each other. If unspecified it defaults to the most commonly used C<.>.
 496
 497 =item unsafe
 498
 499 This Storage driver normally installs its own C<HandleError>, sets
 500 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 501 all database handles, including those supplied by a coderef.  It does this
 502 so that it can have consistent and useful error behavior.
 503
 504 If you set this option to a true value, Storage will not do its usual
 505 modifications to the database handle's attributes, and instead relies on
 506 the settings in your connect_info DBI options (or the values you set in
 507 your connection coderef, in the case that you are connecting via coderef).
 508
 509 Note that your custom settings can cause Storage to malfunction,
 510 especially if you set a C<HandleError> handler that suppresses exceptions
 511 and/or disable C<RaiseError>.
 512
 513 =item auto_savepoint
 514
 515 If this option is true, L<DBIx::Class> will use savepoints when nesting
 516 transactions, making it possible to recover from failure in the inner
 517 transaction without having to abort all outer transactions.
 518
 519 =item cursor_class
 520
 521 Use this argument to supply a cursor class other than the default
 522 L<DBIx::Class::Storage::DBI::Cursor>.
 523
 524 =back
 525
 526 Some real-life examples of arguments to L</connect_info> and
 527 L<DBIx::Class::Schema/connect>
 528
 529   # Simple SQLite connection
 530   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 531
 532   # Connect via subref
 533   ->connect_info([ sub { DBI->connect(...) } ]);
 534
 535   # Connect via subref in hashref
 536   ->connect_info([{
 537     dbh_maker => sub { DBI->connect(...) },
 538     on_connect_do => 'alter session ...',
 539   }]);
 540
 541   # A bit more complicated
 542   ->connect_info(
 543     [
 544       'dbi:Pg:dbname=foo',
 545       'postgres',
 546       'my_pg_password',
 547       { AutoCommit => 1 },
 548       { quote_char => q{"} },
 549     ]
 550   );
 551
 552   # Equivalent to the previous example
 553   ->connect_info(
 554     [
 555       'dbi:Pg:dbname=foo',
 556       'postgres',
 557       'my_pg_password',
 558       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 559     ]
 560   );
 561
 562   # Same, but with hashref as argument
 563   # See parse_connect_info for explanation
 564   ->connect_info(
 565     [{
 566       dsn         => 'dbi:Pg:dbname=foo',
 567       user        => 'postgres',
 568       password    => 'my_pg_password',
 569       AutoCommit  => 1,
 570       quote_char  => q{"},
 571       name_sep    => q{.},
 572     }]
 573   );
 574
 575   # Subref + DBIx::Class-specific connection options
 576   ->connect_info(
 577     [
 578       sub { DBI->connect(...) },
 579       {
 580           quote_char => q{`},
 581           name_sep => q{@},
 582           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 583           disable_sth_caching => 1,
 584       },
 585     ]
 586   );
 587
 588
 589
 590 =cut
 591
 592 sub connect_info {
 593   my ($self, $info) = @_;
 594
 595   return $self->_connect_info if !$info;
 596
 597   $self->_connect_info($info); # copy for _connect_info
 598
 599   $info = $self->_normalize_connect_info($info)
 600     if ref $info eq 'ARRAY';
 601
 602   for my $storage_opt (keys %{ $info->{storage_options} }) {
 603     my $value = $info->{storage_options}{$storage_opt};
 604
 605     $self->$storage_opt($value);
 606   }
 607
 608   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 609   #  the new set of options
 610   $self->_sql_maker(undef);
 611   $self->_sql_maker_opts({});
 612
 613   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 614     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 615
 616     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 617   }
 618
 619   my %attrs = (
 620     %{ $self->_default_dbi_connect_attributes || {} },
 621     %{ $info->{attributes} || {} },
 622   );
 623
 624   my @args = @{ $info->{arguments} };
 625
 626   if (keys %attrs and ref $args[0] ne 'CODE') {
 627     carp
 628         'You provided explicit AutoCommit => 0 in your connection_info. '
 629       . 'This is almost universally a bad idea (see the footnotes of '
 630       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 631       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 632       . 'this warning.'
 633       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 634
 635     push @args, \%attrs if keys %attrs;
 636   }
 637   $self->_dbi_connect_info(\@args);
 638
 639   # FIXME - dirty:
 640   # save attributes them in a separate accessor so they are always
 641   # introspectable, even in case of a CODE $dbhmaker
 642   $self->_dbic_connect_attributes (\%attrs);
 643
 644   return $self->_connect_info;
 645 }
 646
 647 sub _normalize_connect_info {
 648   my ($self, $info_arg) = @_;
 649   my %info;
 650
 651   my @args = @$info_arg;  # take a shallow copy for further mutilation
 652
 653   # combine/pre-parse arguments depending on invocation style
 654
 655   my %attrs;
 656   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 657     %attrs = %{ $args[1] || {} };
 658     @args = $args[0];
 659   }
 660   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 661     %attrs = %{$args[0]};
 662     @args = ();
 663     if (my $code = delete $attrs{dbh_maker}) {
 664       @args = $code;
 665
 666       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 667       if (@ignored) {
 668         carp sprintf (
 669             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 670           . "to the result of 'dbh_maker'",
 671
 672           join (', ', map { "'$_'" } (@ignored) ),
 673         );
 674       }
 675     }
 676     else {
 677       @args = delete @attrs{qw/dsn user password/};
 678     }
 679   }
 680   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 681     %attrs = (
 682       % { $args[3] || {} },
 683       % { $args[4] || {} },
 684     );
 685     @args = @args[0,1,2];
 686   }
 687
 688   $info{arguments} = \@args;
 689
 690   my @storage_opts = grep exists $attrs{$_},
 691     @storage_options, 'cursor_class';
 692
 693   @{ $info{storage_options} }{@storage_opts} =
 694     delete @attrs{@storage_opts} if @storage_opts;
 695
 696   my @sql_maker_opts = grep exists $attrs{$_},
 697     qw/limit_dialect quote_char name_sep quote_names/;
 698
 699   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 700     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 701
 702   $info{attributes} = \%attrs if %attrs;
 703
 704   return \%info;
 705 }
 706
 707 sub _default_dbi_connect_attributes () {
 708   +{
 709     AutoCommit => 1,
 710     PrintError => 0,
 711     RaiseError => 1,
 712     ShowErrorStatement => 1,
 713   };
 714 }
 715
 716 =head2 on_connect_do
 717
 718 This method is deprecated in favour of setting via L</connect_info>.
 719
 720 =cut
 721
 722 =head2 on_disconnect_do
 723
 724 This method is deprecated in favour of setting via L</connect_info>.
 725
 726 =cut
 727
 728 sub _parse_connect_do {
 729   my ($self, $type) = @_;
 730
 731   my $val = $self->$type;
 732   return () if not defined $val;
 733
 734   my @res;
 735
 736   if (not ref($val)) {
 737     push @res, [ 'do_sql', $val ];
 738   } elsif (ref($val) eq 'CODE') {
 739     push @res, $val;
 740   } elsif (ref($val) eq 'ARRAY') {
 741     push @res, map { [ 'do_sql', $_ ] } @$val;
 742   } else {
 743     $self->throw_exception("Invalid type for $type: ".ref($val));
 744   }
 745
 746   return \@res;
 747 }
 748
 749 =head2 dbh_do
 750
 751 Arguments: ($subref | $method_name), @extra_coderef_args?
 752
 753 Execute the given $subref or $method_name using the new exception-based
 754 connection management.
 755
 756 The first two arguments will be the storage object that C<dbh_do> was called
 757 on and a database handle to use.  Any additional arguments will be passed
 758 verbatim to the called subref as arguments 2 and onwards.
 759
 760 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 761 exception handling and reconnection (or failover in future subclasses).
 762
 763 Your subref should have no side-effects outside of the database, as
 764 there is the potential for your subref to be partially double-executed
 765 if the database connection was stale/dysfunctional.
 766
 767 Example:
 768
 769   my @stuff = $schema->storage->dbh_do(
 770     sub {
 771       my ($storage, $dbh, @cols) = @_;
 772       my $cols = join(q{, }, @cols);
 773       $dbh->selectrow_array("SELECT $cols FROM foo");
 774     },
 775     @column_list
 776   );
 777
 778 =cut
 779
 780 sub dbh_do {
 781   my $self = shift;
 782   my $run_target = shift;
 783
 784   # short circuit when we know there is no need for a runner
 785   #
 786   # FIXME - asumption may be wrong
 787   # the rationale for the txn_depth check is that if this block is a part
 788   # of a larger transaction, everything up to that point is screwed anyway
 789   return $self->$run_target($self->_get_dbh, @_)
 790     if $self->{_in_do_block} or $self->transaction_depth;
 791
 792   my $args = \@_;
 793
 794   DBIx::Class::Storage::BlockRunner->new(
 795     storage => $self,
 796     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 797     wrap_txn => 0,
 798     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 799   )->run;
 800 }
 801
 802 sub txn_do {
 803   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 804   shift->next::method(@_);
 805 }
 806
 807 =head2 disconnect
 808
 809 Our C<disconnect> method also performs a rollback first if the
 810 database is not in C<AutoCommit> mode.
 811
 812 =cut
 813
 814 sub disconnect {
 815   my ($self) = @_;
 816
 817   if( $self->_dbh ) {
 818     my @actions;
 819
 820     push @actions, ( $self->on_disconnect_call || () );
 821     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 822
 823     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 824
 825     # stops the "implicit rollback on disconnect" warning
 826     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 827
 828     %{ $self->_dbh->{CachedKids} } = ();
 829     $self->_dbh->disconnect;
 830     $self->_dbh(undef);
 831     $self->{_dbh_gen}++;
 832   }
 833 }
 834
 835 =head2 with_deferred_fk_checks
 836
 837 =over 4
 838
 839 =item Arguments: C<$coderef>
 840
 841 =item Return Value: The return value of $coderef
 842
 843 =back
 844
 845 Storage specific method to run the code ref with FK checks deferred or
 846 in MySQL's case disabled entirely.
 847
 848 =cut
 849
 850 # Storage subclasses should override this
 851 sub with_deferred_fk_checks {
 852   my ($self, $sub) = @_;
 853   $sub->();
 854 }
 855
 856 =head2 connected
 857
 858 =over
 859
 860 =item Arguments: none
 861
 862 =item Return Value: 1|0
 863
 864 =back
 865
 866 Verifies that the current database handle is active and ready to execute
 867 an SQL statement (e.g. the connection did not get stale, server is still
 868 answering, etc.) This method is used internally by L</dbh>.
 869
 870 =cut
 871
 872 sub connected {
 873   my $self = shift;
 874   return 0 unless $self->_seems_connected;
 875
 876   #be on the safe side
 877   local $self->_dbh->{RaiseError} = 1;
 878
 879   return $self->_ping;
 880 }
 881
 882 sub _seems_connected {
 883   my $self = shift;
 884
 885   $self->_verify_pid;
 886
 887   my $dbh = $self->_dbh
 888     or return 0;
 889
 890   return $dbh->FETCH('Active');
 891 }
 892
 893 sub _ping {
 894   my $self = shift;
 895
 896   my $dbh = $self->_dbh or return 0;
 897
 898   return $dbh->ping;
 899 }
 900
 901 sub ensure_connected {
 902   my ($self) = @_;
 903
 904   unless ($self->connected) {
 905     $self->_populate_dbh;
 906   }
 907 }
 908
 909 =head2 dbh
 910
 911 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 912 is guaranteed to be healthy by implicitly calling L</connected>, and if
 913 necessary performing a reconnection before returning. Keep in mind that this
 914 is very B<expensive> on some database engines. Consider using L</dbh_do>
 915 instead.
 916
 917 =cut
 918
 919 sub dbh {
 920   my ($self) = @_;
 921
 922   if (not $self->_dbh) {
 923     $self->_populate_dbh;
 924   } else {
 925     $self->ensure_connected;
 926   }
 927   return $self->_dbh;
 928 }
 929
 930 # this is the internal "get dbh or connect (don't check)" method
 931 sub _get_dbh {
 932   my $self = shift;
 933   $self->_verify_pid;
 934   $self->_populate_dbh unless $self->_dbh;
 935   return $self->_dbh;
 936 }
 937
 938 sub sql_maker {
 939   my ($self) = @_;
 940   unless ($self->_sql_maker) {
 941     my $sql_maker_class = $self->sql_maker_class;
 942
 943     my %opts = %{$self->_sql_maker_opts||{}};
 944     my $dialect =
 945       $opts{limit_dialect}
 946         ||
 947       $self->sql_limit_dialect
 948         ||
 949       do {
 950         my $s_class = (ref $self) || $self;
 951         carp (
 952           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 953         . 'have not supplied an explicit limit_dialect in your connection_info. '
 954         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 955         . 'databases but can be (and often is) painfully slow. '
 956         . "Please file an RT ticket against '$s_class' ."
 957         );
 958
 959         'GenericSubQ';
 960       }
 961     ;
 962
 963     my ($quote_char, $name_sep);
 964
 965     if ($opts{quote_names}) {
 966       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 967         my $s_class = (ref $self) || $self;
 968         carp (
 969           "You requested 'quote_names' but your storage class ($s_class) does "
 970         . 'not explicitly define a default sql_quote_char and you have not '
 971         . 'supplied a quote_char as part of your connection_info. DBIC will '
 972         .q{default to the ANSI SQL standard quote '"', which works most of }
 973         . "the time. Please file an RT ticket against '$s_class'."
 974         );
 975
 976         '"'; # RV
 977       };
 978
 979       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 980     }
 981
 982     $self->_sql_maker($sql_maker_class->new(
 983       bindtype=>'columns',
 984       array_datatypes => 1,
 985       limit_dialect => $dialect,
 986       ($quote_char ? (quote_char => $quote_char) : ()),
 987       name_sep => ($name_sep || '.'),
 988       %opts,
 989     ));
 990   }
 991   return $self->_sql_maker;
 992 }
 993
 994 # nothing to do by default
 995 sub _rebless {}
 996 sub _init {}
 997
 998 sub _populate_dbh {
 999   my ($self) = @_;
1000
1001   my @info = @{$self->_dbi_connect_info || []};
1002   $self->_dbh(undef); # in case ->connected failed we might get sent here
1003   $self->_dbh_details({}); # reset everything we know
1004
1005   $self->_dbh($self->_connect(@info));
1006
1007   $self->_conn_pid($$) if $^O ne 'MSWin32'; # on win32 these are in fact threads
1008
1009   $self->_determine_driver;
1010
1011   # Always set the transaction depth on connect, since
1012   #  there is no transaction in progress by definition
1013   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1014
1015   $self->_run_connection_actions unless $self->{_in_determine_driver};
1016 }
1017
1018 sub _run_connection_actions {
1019   my $self = shift;
1020   my @actions;
1021
1022   push @actions, ( $self->on_connect_call || () );
1023   push @actions, $self->_parse_connect_do ('on_connect_do');
1024
1025   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1026 }
1027
1028
1029
1030 sub set_use_dbms_capability {
1031   $_[0]->set_inherited ($_[1], $_[2]);
1032 }
1033
1034 sub get_use_dbms_capability {
1035   my ($self, $capname) = @_;
1036
1037   my $use = $self->get_inherited ($capname);
1038   return defined $use
1039     ? $use
1040     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1041   ;
1042 }
1043
1044 sub set_dbms_capability {
1045   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1046 }
1047
1048 sub get_dbms_capability {
1049   my ($self, $capname) = @_;
1050
1051   my $cap = $self->_dbh_details->{capability}{$capname};
1052
1053   unless (defined $cap) {
1054     if (my $meth = $self->can ("_determine$capname")) {
1055       $cap = $self->$meth ? 1 : 0;
1056     }
1057     else {
1058       $cap = 0;
1059     }
1060
1061     $self->set_dbms_capability ($capname, $cap);
1062   }
1063
1064   return $cap;
1065 }
1066
1067 sub _server_info {
1068   my $self = shift;
1069
1070   my $info;
1071   unless ($info = $self->_dbh_details->{info}) {
1072
1073     $info = {};
1074
1075     my $server_version = try { $self->_get_server_version };
1076
1077     if (defined $server_version) {
1078       $info->{dbms_version} = $server_version;
1079
1080       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1081       my @verparts = split (/\./, $numeric_version);
1082       if (
1083         @verparts
1084           &&
1085         $verparts[0] <= 999
1086       ) {
1087         # consider only up to 3 version parts, iff not more than 3 digits
1088         my @use_parts;
1089         while (@verparts && @use_parts < 3) {
1090           my $p = shift @verparts;
1091           last if $p > 999;
1092           push @use_parts, $p;
1093         }
1094         push @use_parts, 0 while @use_parts < 3;
1095
1096         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1097       }
1098     }
1099
1100     $self->_dbh_details->{info} = $info;
1101   }
1102
1103   return $info;
1104 }
1105
1106 sub _get_server_version {
1107   shift->_dbh_get_info(18);
1108 }
1109
1110 sub _dbh_get_info {
1111   my ($self, $info) = @_;
1112
1113   return try { $self->_get_dbh->get_info($info) } || undef;
1114 }
1115
1116 sub _determine_driver {
1117   my ($self) = @_;
1118
1119   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1120     my $started_connected = 0;
1121     local $self->{_in_determine_driver} = 1;
1122
1123     if (ref($self) eq __PACKAGE__) {
1124       my $driver;
1125       if ($self->_dbh) { # we are connected
1126         $driver = $self->_dbh->{Driver}{Name};
1127         $started_connected = 1;
1128       } else {
1129         # if connect_info is a CODEREF, we have no choice but to connect
1130         if (ref $self->_dbi_connect_info->[0] &&
1131             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1132           $self->_populate_dbh;
1133           $driver = $self->_dbh->{Driver}{Name};
1134         }
1135         else {
1136           # try to use dsn to not require being connected, the driver may still
1137           # force a connection in _rebless to determine version
1138           # (dsn may not be supplied at all if all we do is make a mock-schema)
1139           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1140           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1141           $driver ||= $ENV{DBI_DRIVER};
1142         }
1143       }
1144
1145       if ($driver) {
1146         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1147         if ($self->load_optional_class($storage_class)) {
1148           mro::set_mro($storage_class, 'c3');
1149           bless $self, $storage_class;
1150           $self->_rebless();
1151         }
1152       }
1153     }
1154
1155     $self->_driver_determined(1);
1156
1157     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1158
1159     $self->_init; # run driver-specific initializations
1160
1161     $self->_run_connection_actions
1162         if !$started_connected && defined $self->_dbh;
1163   }
1164 }
1165
1166 sub _do_connection_actions {
1167   my $self          = shift;
1168   my $method_prefix = shift;
1169   my $call          = shift;
1170
1171   if (not ref($call)) {
1172     my $method = $method_prefix . $call;
1173     $self->$method(@_);
1174   } elsif (ref($call) eq 'CODE') {
1175     $self->$call(@_);
1176   } elsif (ref($call) eq 'ARRAY') {
1177     if (ref($call->[0]) ne 'ARRAY') {
1178       $self->_do_connection_actions($method_prefix, $_) for @$call;
1179     } else {
1180       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1181     }
1182   } else {
1183     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1184   }
1185
1186   return $self;
1187 }
1188
1189 sub connect_call_do_sql {
1190   my $self = shift;
1191   $self->_do_query(@_);
1192 }
1193
1194 sub disconnect_call_do_sql {
1195   my $self = shift;
1196   $self->_do_query(@_);
1197 }
1198
1199 # override in db-specific backend when necessary
1200 sub connect_call_datetime_setup { 1 }
1201
1202 sub _do_query {
1203   my ($self, $action) = @_;
1204
1205   if (ref $action eq 'CODE') {
1206     $action = $action->($self);
1207     $self->_do_query($_) foreach @$action;
1208   }
1209   else {
1210     # Most debuggers expect ($sql, @bind), so we need to exclude
1211     # the attribute hash which is the second argument to $dbh->do
1212     # furthermore the bind values are usually to be presented
1213     # as named arrayref pairs, so wrap those here too
1214     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1215     my $sql = shift @do_args;
1216     my $attrs = shift @do_args;
1217     my @bind = map { [ undef, $_ ] } @do_args;
1218
1219     $self->_query_start($sql, \@bind);
1220     $self->_get_dbh->do($sql, $attrs, @do_args);
1221     $self->_query_end($sql, \@bind);
1222   }
1223
1224   return $self;
1225 }
1226
1227 sub _connect {
1228   my ($self, @info) = @_;
1229
1230   $self->throw_exception("You failed to provide any connection info")
1231     if !@info;
1232
1233   my ($old_connect_via, $dbh);
1234
1235   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1236     $old_connect_via = $DBI::connect_via;
1237     $DBI::connect_via = 'connect';
1238   }
1239
1240   try {
1241     if(ref $info[0] eq 'CODE') {
1242       $dbh = $info[0]->();
1243     }
1244     else {
1245       require DBI;
1246       $dbh = DBI->connect(@info);
1247     }
1248
1249     if (!$dbh) {
1250       die $DBI::errstr;
1251     }
1252
1253     unless ($self->unsafe) {
1254
1255       $self->throw_exception(
1256         'Refusing clobbering of {HandleError} installed on externally supplied '
1257        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1258       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1259
1260       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1261       # request, or an external handle. Complain and set anyway
1262       unless ($dbh->{RaiseError}) {
1263         carp( ref $info[0] eq 'CODE'
1264
1265           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1266            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1267            .'attribute has been supplied'
1268
1269           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1270            .'unsafe => 1. Toggling RaiseError back to true'
1271         );
1272
1273         $dbh->{RaiseError} = 1;
1274       }
1275
1276       # this odd anonymous coderef dereference is in fact really
1277       # necessary to avoid the unwanted effect described in perl5
1278       # RT#75792
1279       sub {
1280         my $weak_self = $_[0];
1281         weaken $weak_self;
1282
1283         # the coderef is blessed so we can distinguish it from externally
1284         # supplied handles (which must be preserved)
1285         $_[1]->{HandleError} = bless sub {
1286           if ($weak_self) {
1287             $weak_self->throw_exception("DBI Exception: $_[0]");
1288           }
1289           else {
1290             # the handler may be invoked by something totally out of
1291             # the scope of DBIC
1292             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1293           }
1294         }, '__DBIC__DBH__ERROR__HANDLER__';
1295       }->($self, $dbh);
1296     }
1297   }
1298   catch {
1299     $self->throw_exception("DBI Connection failed: $_")
1300   }
1301   finally {
1302     $DBI::connect_via = $old_connect_via if $old_connect_via;
1303   };
1304
1305   $self->_dbh_autocommit($dbh->{AutoCommit});
1306   $dbh;
1307 }
1308
1309 sub txn_begin {
1310   my $self = shift;
1311
1312   # this means we have not yet connected and do not know the AC status
1313   # (e.g. coderef $dbh), need a full-fledged connection check
1314   if (! defined $self->_dbh_autocommit) {
1315     $self->ensure_connected;
1316   }
1317   # Otherwise simply connect or re-connect on pid changes
1318   else {
1319     $self->_get_dbh;
1320   }
1321
1322   $self->next::method(@_);
1323 }
1324
1325 sub _exec_txn_begin {
1326   my $self = shift;
1327
1328   # if the user is utilizing txn_do - good for him, otherwise we need to
1329   # ensure that the $dbh is healthy on BEGIN.
1330   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1331   # will be replaced by a failure of begin_work itself (which will be
1332   # then retried on reconnect)
1333   if ($self->{_in_do_block}) {
1334     $self->_dbh->begin_work;
1335   } else {
1336     $self->dbh_do(sub { $_[1]->begin_work });
1337   }
1338 }
1339
1340 sub txn_commit {
1341   my $self = shift;
1342
1343   $self->_verify_pid if $self->_dbh;
1344   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1345     unless $self->_dbh;
1346
1347   # esoteric case for folks using external $dbh handles
1348   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1349     carp "Storage transaction_depth 0 does not match "
1350         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1351     $self->transaction_depth(1);
1352   }
1353
1354   $self->next::method(@_);
1355
1356   # if AutoCommit is disabled txn_depth never goes to 0
1357   # as a new txn is started immediately on commit
1358   $self->transaction_depth(1) if (
1359     !$self->transaction_depth
1360       and
1361     defined $self->_dbh_autocommit
1362       and
1363     ! $self->_dbh_autocommit
1364   );
1365 }
1366
1367 sub _exec_txn_commit {
1368   shift->_dbh->commit;
1369 }
1370
1371 sub txn_rollback {
1372   my $self = shift;
1373
1374   $self->_verify_pid if $self->_dbh;
1375   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1376     unless $self->_dbh;
1377
1378   # esoteric case for folks using external $dbh handles
1379   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1380     carp "Storage transaction_depth 0 does not match "
1381         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1382     $self->transaction_depth(1);
1383   }
1384
1385   $self->next::method(@_);
1386
1387   # if AutoCommit is disabled txn_depth never goes to 0
1388   # as a new txn is started immediately on commit
1389   $self->transaction_depth(1) if (
1390     !$self->transaction_depth
1391       and
1392     defined $self->_dbh_autocommit
1393       and
1394     ! $self->_dbh_autocommit
1395   );
1396 }
1397
1398 sub _exec_txn_rollback {
1399   shift->_dbh->rollback;
1400 }
1401
1402 # generate some identical methods
1403 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1404   no strict qw/refs/;
1405   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1406     my $self = shift;
1407     $self->_verify_pid if $self->_dbh;
1408     $self->throw_exception("Unable to $meth() on a disconnected storage")
1409       unless $self->_dbh;
1410     $self->next::method(@_);
1411   };
1412 }
1413
1414 # This used to be the top-half of _execute.  It was split out to make it
1415 #  easier to override in NoBindVars without duping the rest.  It takes up
1416 #  all of _execute's args, and emits $sql, @bind.
1417 sub _prep_for_execute {
1418   #my ($self, $op, $ident, $args) = @_;
1419   return shift->_gen_sql_bind(@_)
1420 }
1421
1422 sub _gen_sql_bind {
1423   my ($self, $op, $ident, $args) = @_;
1424
1425   my ($sql, @bind) = $self->sql_maker->$op(
1426     blessed($ident) ? $ident->from : $ident,
1427     @$args,
1428   );
1429
1430   if (
1431     ! $ENV{DBIC_DT_SEARCH_OK}
1432       and
1433     $op eq 'select'
1434       and
1435     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1436   ) {
1437     carp_unique 'DateTime objects passed to search() are not supported '
1438       . 'properly (InflateColumn::DateTime formats and settings are not '
1439       . 'respected.) See "Formatting DateTime objects in queries" in '
1440       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1441       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1442   }
1443
1444   return( $sql, $self->_resolve_bindattrs(
1445     $ident, [ @{$args->[2]{bind}||[]}, @bind ]
1446   ));
1447 }
1448
1449 sub _resolve_bindattrs {
1450   my ($self, $ident, $bind, $colinfos) = @_;
1451
1452   $colinfos ||= {};
1453
1454   my $resolve_bindinfo = sub {
1455     #my $infohash = shift;
1456
1457     %$colinfos = %{ $self->_resolve_column_info($ident) }
1458       unless keys %$colinfos;
1459
1460     my $ret;
1461     if (my $col = $_[0]->{dbic_colname}) {
1462       $ret = { %{$_[0]} };
1463
1464       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1465         if $colinfos->{$col}{data_type};
1466
1467       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1468         if $colinfos->{$col}{size};
1469     }
1470
1471     $ret || $_[0];
1472   };
1473
1474   return [ map {
1475     if (ref $_ ne 'ARRAY') {
1476       [{}, $_]
1477     }
1478     elsif (! defined $_->[0]) {
1479       [{}, $_->[1]]
1480     }
1481     elsif (ref $_->[0] eq 'HASH') {
1482       [
1483         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1484         $_->[1]
1485       ]
1486     }
1487     elsif (ref $_->[0] eq 'SCALAR') {
1488       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1489     }
1490     else {
1491       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1492     }
1493   } @$bind ];
1494 }
1495
1496 sub _format_for_trace {
1497   #my ($self, $bind) = @_;
1498
1499   ### Turn @bind from something like this:
1500   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1501   ### to this:
1502   ###   ( "'1'", "'3'" )
1503
1504   map {
1505     defined( $_ && $_->[1] )
1506       ? qq{'$_->[1]'}
1507       : q{NULL}
1508   } @{$_[1] || []};
1509 }
1510
1511 sub _query_start {
1512   my ( $self, $sql, $bind ) = @_;
1513
1514   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1515     if $self->debug;
1516 }
1517
1518 sub _query_end {
1519   my ( $self, $sql, $bind ) = @_;
1520
1521   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1522     if $self->debug;
1523 }
1524
1525 my $sba_compat;
1526 sub _dbi_attrs_for_bind {
1527   my ($self, $ident, $bind) = @_;
1528
1529   if (! defined $sba_compat) {
1530     $self->_determine_driver;
1531     $sba_compat = $self->can('source_bind_attributes') == \&source_bind_attributes
1532       ? 0
1533       : 1
1534     ;
1535   }
1536
1537   my $sba_attrs;
1538   if ($sba_compat) {
1539     my $class = ref $self;
1540     carp_unique (
1541       "The source_bind_attributes() override in $class relies on a deprecated codepath. "
1542      .'You are strongly advised to switch your code to override bind_attribute_by_datatype() '
1543      .'instead. This legacy compat shim will also disappear some time before DBIC 0.09'
1544     );
1545
1546     my $sba_attrs = $self->source_bind_attributes
1547   }
1548
1549   my @attrs;
1550
1551   for (map { $_->[0] } @$bind) {
1552     push @attrs, do {
1553       if (exists $_->{dbd_attrs}) {
1554         $_->{dbd_attrs}
1555       }
1556       elsif($_->{sqlt_datatype}) {
1557         # cache the result in the dbh_details hash, as it can not change unless
1558         # we connect to something else
1559         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1560         if (not exists $cache->{$_->{sqlt_datatype}}) {
1561           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1562         }
1563         $cache->{$_->{sqlt_datatype}};
1564       }
1565       elsif ($sba_attrs and $_->{dbic_colname}) {
1566         $sba_attrs->{$_->{dbic_colname}} || undef;
1567       }
1568       else {
1569         undef;  # always push something at this position
1570       }
1571     }
1572   }
1573
1574   return \@attrs;
1575 }
1576
1577 sub _execute {
1578   my ($self, $op, $ident, @args) = @_;
1579
1580   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1581
1582   shift->dbh_do(    # retry over disconnects
1583     '_dbh_execute',
1584     $sql,
1585     $bind,
1586     $self->_dbi_attrs_for_bind($ident, $bind)
1587   );
1588 }
1589
1590 sub _dbh_execute {
1591   my ($self, undef, $sql, $bind, $bind_attrs) = @_;
1592
1593   $self->_query_start( $sql, $bind );
1594   my $sth = $self->_sth($sql);
1595
1596   for my $i (0 .. $#$bind) {
1597     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1598       $sth->bind_param_inout(
1599         $i + 1, # bind params counts are 1-based
1600         $bind->[$i][1],
1601         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1602         $bind_attrs->[$i],
1603       );
1604     }
1605     else {
1606       $sth->bind_param(
1607         $i + 1,
1608         (ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""'))
1609           ? "$bind->[$i][1]"
1610           : $bind->[$i][1]
1611         ,
1612         $bind_attrs->[$i],
1613       );
1614     }
1615   }
1616
1617   # Can this fail without throwing an exception anyways???
1618   my $rv = $sth->execute();
1619   $self->throw_exception(
1620     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1621   ) if !$rv;
1622
1623   $self->_query_end( $sql, $bind );
1624
1625   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1626 }
1627
1628 sub _prefetch_autovalues {
1629   my ($self, $source, $to_insert) = @_;
1630
1631   my $colinfo = $source->columns_info;
1632
1633   my %values;
1634   for my $col (keys %$colinfo) {
1635     if (
1636       $colinfo->{$col}{auto_nextval}
1637         and
1638       (
1639         ! exists $to_insert->{$col}
1640           or
1641         ref $to_insert->{$col} eq 'SCALAR'
1642           or
1643         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1644       )
1645     ) {
1646       $values{$col} = $self->_sequence_fetch(
1647         'NEXTVAL',
1648         ( $colinfo->{$col}{sequence} ||=
1649             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1650         ),
1651       );
1652     }
1653   }
1654
1655   \%values;
1656 }
1657
1658 sub insert {
1659   my ($self, $source, $to_insert) = @_;
1660
1661   my $prefetched_values = $self->_prefetch_autovalues($source, $to_insert);
1662
1663   # fuse the values, but keep a separate list of prefetched_values so that
1664   # they can be fused once again with the final return
1665   $to_insert = { %$to_insert, %$prefetched_values };
1666
1667   my $col_infos = $source->columns_info;
1668   my %pcols = map { $_ => 1 } $source->primary_columns;
1669   my %retrieve_cols;
1670   for my $col ($source->columns) {
1671     # nothing to retrieve when explicit values are supplied
1672     next if (defined $to_insert->{$col} and ! (
1673       ref $to_insert->{$col} eq 'SCALAR'
1674         or
1675       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1676     ));
1677
1678     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1679     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1680       $pcols{$col}
1681         or
1682       $col_infos->{$col}{retrieve_on_insert}
1683     );
1684   };
1685
1686   my ($sqla_opts, @ir_container);
1687   if (%retrieve_cols and $self->_use_insert_returning) {
1688     $sqla_opts->{returning_container} = \@ir_container
1689       if $self->_use_insert_returning_bound;
1690
1691     $sqla_opts->{returning} = [
1692       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1693     ];
1694   }
1695
1696   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1697
1698   my %returned_cols = %$to_insert;
1699   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1700     @ir_container = try {
1701       local $SIG{__WARN__} = sub {};
1702       my @r = $sth->fetchrow_array;
1703       $sth->finish;
1704       @r;
1705     } unless @ir_container;
1706
1707     @returned_cols{@$retlist} = @ir_container if @ir_container;
1708   }
1709   else {
1710     # pull in PK if needed and then everything else
1711     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1712
1713       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1714         unless $self->can('last_insert_id');
1715
1716       my @pri_values = $self->last_insert_id($source, @missing_pri);
1717
1718       $self->throw_exception( "Can't get last insert id" )
1719         unless (@pri_values == @missing_pri);
1720
1721       @returned_cols{@missing_pri} = @pri_values;
1722       delete $retrieve_cols{$_} for @missing_pri;
1723     }
1724
1725     # if there is more left to pull
1726     if (%retrieve_cols) {
1727       $self->throw_exception(
1728         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1729       ) unless %pcols;
1730
1731       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1732
1733       my $cur = DBIx::Class::ResultSet->new($source, {
1734         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1735         select => \@left_to_fetch,
1736       })->cursor;
1737
1738       @returned_cols{@left_to_fetch} = $cur->next;
1739
1740       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1741         if scalar $cur->next;
1742     }
1743   }
1744
1745   return { %$prefetched_values, %returned_cols };
1746 }
1747
1748 sub insert_bulk {
1749   my ($self, $source, $cols, $data) = @_;
1750
1751   my @col_range = (0..$#$cols);
1752
1753   # FIXME - perhaps this is not even needed? does DBI stringify?
1754   #
1755   # forcibly stringify whatever is stringifiable
1756   # ResultSet::populate() hands us a copy - safe to mangle
1757   for my $r (0 .. $#$data) {
1758     for my $c (0 .. $#{$data->[$r]}) {
1759       $data->[$r][$c] = "$data->[$r][$c]"
1760         if ( ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1761     }
1762   }
1763
1764   my $colinfo_cache = {}; # since we will run _resolve_bindattrs on the same $source a lot
1765
1766   # get a slice type index based on first row of data
1767   # a "column" in this context may refer to more than one bind value
1768   # e.g. \[ '?, ?', [...], [...] ]
1769   #
1770   # construct the value type index - a description of values types for every
1771   # per-column slice of $data:
1772   #
1773   # nonexistent - nonbind literal
1774   # 0 - regular value
1775   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1776   #
1777   # also construct the column hash to pass to the SQL generator. For plain
1778   # (non literal) values - convert the members of the first row into a
1779   # literal+bind combo, with extra positional info in the bind attr hashref.
1780   # This will allow us to match the order properly, and is so contrived
1781   # because a user-supplied literal/bind (or something else specific to a
1782   # resultsource and/or storage driver) can inject extra binds along the
1783   # way, so one can't rely on "shift positions" ordering at all. Also we
1784   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1785   # can be later matched up by address), because we want to supply a real
1786   # value on which perhaps e.g. datatype checks will be performed
1787   my ($proto_data, $value_type_idx);
1788   for my $i (@col_range) {
1789     my $colname = $cols->[$i];
1790     if (ref $data->[0][$i] eq 'SCALAR') {
1791       # no bind value at all - no type
1792
1793       $proto_data->{$colname} = $data->[0][$i];
1794     }
1795     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1796       # repack, so we don't end up mangling the original \[]
1797       my ($sql, @bind) = @${$data->[0][$i]};
1798
1799       # normalization of user supplied stuff
1800       my $resolved_bind = $self->_resolve_bindattrs(
1801         $source, \@bind, $colinfo_cache,
1802       );
1803
1804       # store value-less (attrs only) bind info - we will be comparing all
1805       # supplied binds against this for sanity
1806       $value_type_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1807
1808       $proto_data->{$colname} = \[ $sql, map { [
1809         # inject slice order to use for $proto_bind construction
1810           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i }
1811             =>
1812           $resolved_bind->[$_][1]
1813         ] } (0 .. $#bind)
1814       ];
1815     }
1816     else {
1817       $value_type_idx->{$i} = 0;
1818
1819       $proto_data->{$colname} = \[ '?', [
1820         { dbic_colname => $colname, _bind_data_slice_idx => $i }
1821           =>
1822         $data->[0][$i]
1823       ] ];
1824     }
1825   }
1826
1827   my ($sql, $proto_bind) = $self->_prep_for_execute (
1828     'insert',
1829     $source,
1830     [ $proto_data ],
1831   );
1832
1833   if (! @$proto_bind and keys %$value_type_idx) {
1834     # if the bindlist is empty and we had some dynamic binds, this means the
1835     # storage ate them away (e.g. the NoBindVars component) and interpolated
1836     # them directly into the SQL. This obviously can't be good for multi-inserts
1837     $self->throw_exception('Cannot insert_bulk without support for placeholders');
1838   }
1839
1840   # sanity checks
1841   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
1842   #
1843   # use an error reporting closure for convenience (less to pass)
1844   my $bad_slice_report_cref = sub {
1845     my ($msg, $r_idx, $c_idx) = @_;
1846     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1847       $msg,
1848       $cols->[$c_idx],
1849       do {
1850         require Data::Dumper::Concise;
1851         local $Data::Dumper::Maxdepth = 5;
1852         Data::Dumper::Concise::Dumper ({
1853           map { $cols->[$_] =>
1854             $data->[$r_idx][$_]
1855           } @col_range
1856         }),
1857       }
1858     );
1859   };
1860
1861   for my $col_idx (@col_range) {
1862     my $reference_val = $data->[0][$col_idx];
1863
1864     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
1865       my $val = $data->[$row_idx][$col_idx];
1866
1867       if (! exists $value_type_idx->{$col_idx}) { # literal no binds
1868         if (ref $val ne 'SCALAR') {
1869           $bad_slice_report_cref->(
1870             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
1871             $row_idx,
1872             $col_idx,
1873           );
1874         }
1875         elsif ($$val ne $$reference_val) {
1876           $bad_slice_report_cref->(
1877             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
1878             $row_idx,
1879             $col_idx,
1880           );
1881         }
1882       }
1883       elsif (! $value_type_idx->{$col_idx} ) {  # regular non-literal value
1884         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
1885           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
1886         }
1887       }
1888       else {  # binds from a \[], compare type and attrs
1889         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
1890           $bad_slice_report_cref->(
1891             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
1892             $row_idx,
1893             $col_idx,
1894           );
1895         }
1896         # start drilling down and bail out early on identical refs
1897         elsif (
1898           $reference_val != $val
1899             or
1900           $$reference_val != $$val
1901         ) {
1902           if (${$val}->[0] ne ${$reference_val}->[0]) {
1903             $bad_slice_report_cref->(
1904               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
1905               $row_idx,
1906               $col_idx,
1907             );
1908           }
1909           # need to check the bind attrs - a bind will happen only once for
1910           # the entire dataset, so any changes further down will be ignored.
1911           elsif (! Data::Compare::Compare(
1912             $value_type_idx->{$col_idx},
1913             [
1914               map
1915               { $_->[0] }
1916               @{$self->_resolve_bindattrs(
1917                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfo_cache,
1918               )}
1919             ],
1920           )) {
1921             $bad_slice_report_cref->(
1922               'Differing bind attributes on literal/bind values not supported',
1923               $row_idx,
1924               $col_idx,
1925             );
1926           }
1927         }
1928       }
1929     }
1930   }
1931
1932   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
1933   # are atomic (even if execute_for_fetch is a single call). Thus a safety
1934   # scope guard
1935   my $guard = $self->txn_scope_guard;
1936
1937   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
1938   my $sth = $self->_sth($sql);
1939   my $rv = do {
1940     if (@$proto_bind) {
1941       # proto bind contains the information on which pieces of $data to pull
1942       # $cols is passed in only for prettier error-reporting
1943       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
1944     }
1945     else {
1946       # bind_param_array doesn't work if there are no binds
1947       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1948     }
1949   };
1950
1951   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
1952
1953   $guard->commit;
1954
1955   return (wantarray ? ($rv, $sth, @$proto_bind) : $rv);
1956 }
1957
1958 # execute_for_fetch is capable of returning data just fine (it means it
1959 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
1960 # is the void-populate fast-path we will just ignore this altogether
1961 # for the time being.
1962 sub _dbh_execute_for_fetch {
1963   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
1964
1965   my @idx_range = ( 0 .. $#$proto_bind );
1966
1967   # If we have any bind attributes to take care of, we will bind the
1968   # proto-bind data (which will never be used by execute_for_fetch)
1969   # However since column bindtypes are "sticky", this is sufficient
1970   # to get the DBD to apply the bindtype to all values later on
1971
1972   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
1973
1974   for my $i (@idx_range) {
1975     $sth->bind_param (
1976       $i+1, # DBI bind indexes are 1-based
1977       $proto_bind->[$i][1],
1978       $bind_attrs->[$i],
1979     ) if defined $bind_attrs->[$i];
1980   }
1981
1982   # At this point $data slots named in the _bind_data_slice_idx of
1983   # each piece of $proto_bind are either \[]s or plain values to be
1984   # passed in. Construct the dispensing coderef. *NOTE* the order
1985   # of $data will differ from this of the ?s in the SQL (due to
1986   # alphabetical ordering by colname). We actually do want to
1987   # preserve this behavior so that prepare_cached has a better
1988   # chance of matching on unrelated calls
1989   my %data_reorder = map { $proto_bind->[$_][0]{_bind_data_slice_idx} => $_ } @idx_range;
1990
1991   my $fetch_row_idx = -1; # saner loop this way
1992   my $fetch_tuple = sub {
1993     return undef if ++$fetch_row_idx > $#$data;
1994
1995     return [ map
1996       { (ref $_ eq 'REF' and ref $$_ eq 'ARRAY')
1997         ? map { $_->[-1] } @{$$_}[1 .. $#$$_]
1998         : $_
1999       }
2000       map
2001         { $data->[$fetch_row_idx][$_]}
2002         sort
2003           { $data_reorder{$a} <=> $data_reorder{$b} }
2004           keys %data_reorder
2005     ];
2006   };
2007
2008   my $tuple_status = [];
2009   my ($rv, $err);
2010   try {
2011     $rv = $sth->execute_for_fetch(
2012       $fetch_tuple,
2013       $tuple_status,
2014     );
2015   }
2016   catch {
2017     $err = shift;
2018   };
2019
2020   # Not all DBDs are create equal. Some throw on error, some return
2021   # an undef $rv, and some set $sth->err - try whatever we can
2022   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2023     ! defined $err
2024       and
2025     ( !defined $rv or $sth->err )
2026   );
2027
2028   # Statement must finish even if there was an exception.
2029   try {
2030     $sth->finish
2031   }
2032   catch {
2033     $err = shift unless defined $err
2034   };
2035
2036   if (defined $err) {
2037     my $i = 0;
2038     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2039
2040     $self->throw_exception("Unexpected populate error: $err")
2041       if ($i > $#$tuple_status);
2042
2043     require Data::Dumper::Concise;
2044     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2045       ($tuple_status->[$i][1] || $err),
2046       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2047     );
2048   }
2049
2050   return $rv;
2051 }
2052
2053 sub _dbh_execute_inserts_with_no_binds {
2054   my ($self, $sth, $count) = @_;
2055
2056   my $err;
2057   try {
2058     my $dbh = $self->_get_dbh;
2059     local $dbh->{RaiseError} = 1;
2060     local $dbh->{PrintError} = 0;
2061
2062     $sth->execute foreach 1..$count;
2063   }
2064   catch {
2065     $err = shift;
2066   };
2067
2068   # Make sure statement is finished even if there was an exception.
2069   try {
2070     $sth->finish
2071   }
2072   catch {
2073     $err = shift unless defined $err;
2074   };
2075
2076   $self->throw_exception($err) if defined $err;
2077
2078   return $count;
2079 }
2080
2081 sub update {
2082   #my ($self, $source, @args) = @_;
2083   shift->_execute('update', @_);
2084 }
2085
2086
2087 sub delete {
2088   #my ($self, $source, @args) = @_;
2089   shift->_execute('delete', @_);
2090 }
2091
2092 sub _select {
2093   my $self = shift;
2094   $self->_execute($self->_select_args(@_));
2095 }
2096
2097 sub _select_args_to_query {
2098   my $self = shift;
2099
2100   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2101   #  = $self->_select_args($ident, $select, $cond, $attrs);
2102   my ($op, $ident, @args) =
2103     $self->_select_args(@_);
2104
2105   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2106   my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, \@args);
2107   $prepared_bind ||= [];
2108
2109   return wantarray
2110     ? ($sql, $prepared_bind)
2111     : \[ "($sql)", @$prepared_bind ]
2112   ;
2113 }
2114
2115 sub _select_args {
2116   my ($self, $ident, $select, $where, $attrs) = @_;
2117
2118   my $sql_maker = $self->sql_maker;
2119   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2120
2121   $attrs = {
2122     %$attrs,
2123     select => $select,
2124     from => $ident,
2125     where => $where,
2126     $rs_alias && $alias2source->{$rs_alias}
2127       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2128       : ()
2129     ,
2130   };
2131
2132   # Sanity check the attributes (SQLMaker does it too, but
2133   # in case of a software_limit we'll never reach there)
2134   if (defined $attrs->{offset}) {
2135     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2136       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2137   }
2138
2139   if (defined $attrs->{rows}) {
2140     $self->throw_exception("The rows attribute must be a positive integer if present")
2141       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2142   }
2143   elsif ($attrs->{offset}) {
2144     # MySQL actually recommends this approach.  I cringe.
2145     $attrs->{rows} = $sql_maker->__max_int;
2146   }
2147
2148   my @limit;
2149
2150   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2151   # storage, unless software limit was requested
2152   if (
2153     #limited has_many
2154     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
2155        ||
2156     # grouped prefetch (to satisfy group_by == select)
2157     ( $attrs->{group_by}
2158         &&
2159       @{$attrs->{group_by}}
2160         &&
2161       $attrs->{_prefetch_selector_range}
2162     )
2163   ) {
2164     ($ident, $select, $where, $attrs)
2165       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2166   }
2167   elsif (! $attrs->{software_limit} ) {
2168     push @limit, (
2169       $attrs->{rows} || (),
2170       $attrs->{offset} || (),
2171     );
2172   }
2173
2174   # try to simplify the joinmap further (prune unreferenced type-single joins)
2175   $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2176
2177 ###
2178   # This would be the point to deflate anything found in $where
2179   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2180   # expect a row object. And all we have is a resultsource (it is trivial
2181   # to extract deflator coderefs via $alias2source above).
2182   #
2183   # I don't see a way forward other than changing the way deflators are
2184   # invoked, and that's just bad...
2185 ###
2186
2187   return ('select', $ident, $select, $where, $attrs, @limit);
2188 }
2189
2190 # Returns a counting SELECT for a simple count
2191 # query. Abstracted so that a storage could override
2192 # this to { count => 'firstcol' } or whatever makes
2193 # sense as a performance optimization
2194 sub _count_select {
2195   #my ($self, $source, $rs_attrs) = @_;
2196   return { count => '*' };
2197 }
2198
2199 sub source_bind_attributes {
2200   shift->throw_exception(
2201     'source_bind_attributes() was never meant to be a callable public method - '
2202    .'please contact the DBIC dev-team and describe your use case so that a reasonable '
2203    .'solution can be provided'
2204    ."\nhttp://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT"
2205   );
2206 }
2207
2208 =head2 select
2209
2210 =over 4
2211
2212 =item Arguments: $ident, $select, $condition, $attrs
2213
2214 =back
2215
2216 Handle a SQL select statement.
2217
2218 =cut
2219
2220 sub select {
2221   my $self = shift;
2222   my ($ident, $select, $condition, $attrs) = @_;
2223   return $self->cursor_class->new($self, \@_, $attrs);
2224 }
2225
2226 sub select_single {
2227   my $self = shift;
2228   my ($rv, $sth, @bind) = $self->_select(@_);
2229   my @row = $sth->fetchrow_array;
2230   my @nextrow = $sth->fetchrow_array if @row;
2231   if(@row && @nextrow) {
2232     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2233   }
2234   # Need to call finish() to work round broken DBDs
2235   $sth->finish();
2236   return @row;
2237 }
2238
2239 =head2 sql_limit_dialect
2240
2241 This is an accessor for the default SQL limit dialect used by a particular
2242 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2243 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2244 see L<DBIx::Class::SQLMaker::LimitDialects>.
2245
2246 =cut
2247
2248 sub _dbh_sth {
2249   my ($self, $dbh, $sql) = @_;
2250
2251   # 3 is the if_active parameter which avoids active sth re-use
2252   my $sth = $self->disable_sth_caching
2253     ? $dbh->prepare($sql)
2254     : $dbh->prepare_cached($sql, {}, 3);
2255
2256   # XXX You would think RaiseError would make this impossible,
2257   #  but apparently that's not true :(
2258   $self->throw_exception(
2259     $dbh->errstr
2260       ||
2261     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
2262             .'an exception and/or setting $dbh->errstr',
2263       length ($sql) > 20
2264         ? substr($sql, 0, 20) . '...'
2265         : $sql
2266       ,
2267       'DBD::' . $dbh->{Driver}{Name},
2268     )
2269   ) if !$sth;
2270
2271   $sth;
2272 }
2273
2274 sub sth {
2275   carp_unique 'sth was mistakenly marked/documented as public, stop calling it (will be removed before DBIC v0.09)';
2276   shift->_sth(@_);
2277 }
2278
2279 sub _sth {
2280   my ($self, $sql) = @_;
2281   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2282 }
2283
2284 sub _dbh_columns_info_for {
2285   my ($self, $dbh, $table) = @_;
2286
2287   if ($dbh->can('column_info')) {
2288     my %result;
2289     my $caught;
2290     try {
2291       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2292       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2293       $sth->execute();
2294       while ( my $info = $sth->fetchrow_hashref() ){
2295         my %column_info;
2296         $column_info{data_type}   = $info->{TYPE_NAME};
2297         $column_info{size}      = $info->{COLUMN_SIZE};
2298         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2299         $column_info{default_value} = $info->{COLUMN_DEF};
2300         my $col_name = $info->{COLUMN_NAME};
2301         $col_name =~ s/^\"(.*)\"$/$1/;
2302
2303         $result{$col_name} = \%column_info;
2304       }
2305     } catch {
2306       $caught = 1;
2307     };
2308     return \%result if !$caught && scalar keys %result;
2309   }
2310
2311   my %result;
2312   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2313   $sth->execute;
2314   my @columns = @{$sth->{NAME_lc}};
2315   for my $i ( 0 .. $#columns ){
2316     my %column_info;
2317     $column_info{data_type} = $sth->{TYPE}->[$i];
2318     $column_info{size} = $sth->{PRECISION}->[$i];
2319     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2320
2321     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2322       $column_info{data_type} = $1;
2323       $column_info{size}    = $2;
2324     }
2325
2326     $result{$columns[$i]} = \%column_info;
2327   }
2328   $sth->finish;
2329
2330   foreach my $col (keys %result) {
2331     my $colinfo = $result{$col};
2332     my $type_num = $colinfo->{data_type};
2333     my $type_name;
2334     if(defined $type_num && $dbh->can('type_info')) {
2335       my $type_info = $dbh->type_info($type_num);
2336       $type_name = $type_info->{TYPE_NAME} if $type_info;
2337       $colinfo->{data_type} = $type_name if $type_name;
2338     }
2339   }
2340
2341   return \%result;
2342 }
2343
2344 sub columns_info_for {
2345   my ($self, $table) = @_;
2346   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2347 }
2348
2349 =head2 last_insert_id
2350
2351 Return the row id of the last insert.
2352
2353 =cut
2354
2355 sub _dbh_last_insert_id {
2356     my ($self, $dbh, $source, $col) = @_;
2357
2358     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2359
2360     return $id if defined $id;
2361
2362     my $class = ref $self;
2363     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2364 }
2365
2366 sub last_insert_id {
2367   my $self = shift;
2368   $self->_dbh_last_insert_id ($self->_dbh, @_);
2369 }
2370
2371 =head2 _native_data_type
2372
2373 =over 4
2374
2375 =item Arguments: $type_name
2376
2377 =back
2378
2379 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2380 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2381 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2382
2383 The default implementation returns C<undef>, implement in your Storage driver if
2384 you need this functionality.
2385
2386 Should map types from other databases to the native RDBMS type, for example
2387 C<VARCHAR2> to C<VARCHAR>.
2388
2389 Types with modifiers should map to the underlying data type. For example,
2390 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2391
2392 Composite types should map to the container type, for example
2393 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2394
2395 =cut
2396
2397 sub _native_data_type {
2398   #my ($self, $data_type) = @_;
2399   return undef
2400 }
2401
2402 # Check if placeholders are supported at all
2403 sub _determine_supports_placeholders {
2404   my $self = shift;
2405   my $dbh  = $self->_get_dbh;
2406
2407   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2408   # but it is inaccurate more often than not
2409   return try {
2410     local $dbh->{PrintError} = 0;
2411     local $dbh->{RaiseError} = 1;
2412     $dbh->do('select ?', {}, 1);
2413     1;
2414   }
2415   catch {
2416     0;
2417   };
2418 }
2419
2420 # Check if placeholders bound to non-string types throw exceptions
2421 #
2422 sub _determine_supports_typeless_placeholders {
2423   my $self = shift;
2424   my $dbh  = $self->_get_dbh;
2425
2426   return try {
2427     local $dbh->{PrintError} = 0;
2428     local $dbh->{RaiseError} = 1;
2429     # this specifically tests a bind that is NOT a string
2430     $dbh->do('select 1 where 1 = ?', {}, 1);
2431     1;
2432   }
2433   catch {
2434     0;
2435   };
2436 }
2437
2438 =head2 sqlt_type
2439
2440 Returns the database driver name.
2441
2442 =cut
2443
2444 sub sqlt_type {
2445   shift->_get_dbh->{Driver}->{Name};
2446 }
2447
2448 =head2 bind_attribute_by_data_type
2449
2450 Given a datatype from column info, returns a database specific bind
2451 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2452 let the database planner just handle it.
2453
2454 Generally only needed for special case column types, like bytea in postgres.
2455
2456 =cut
2457
2458 sub bind_attribute_by_data_type {
2459     return;
2460 }
2461
2462 =head2 is_datatype_numeric
2463
2464 Given a datatype from column_info, returns a boolean value indicating if
2465 the current RDBMS considers it a numeric value. This controls how
2466 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2467 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2468 be performed instead of the usual C<eq>.
2469
2470 =cut
2471
2472 sub is_datatype_numeric {
2473   #my ($self, $dt) = @_;
2474
2475   return 0 unless $_[1];
2476
2477   $_[1] =~ /^ (?:
2478     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2479   ) $/ix;
2480 }
2481
2482
2483 =head2 create_ddl_dir
2484
2485 =over 4
2486
2487 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2488
2489 =back
2490
2491 Creates a SQL file based on the Schema, for each of the specified
2492 database engines in C<\@databases> in the given directory.
2493 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2494
2495 Given a previous version number, this will also create a file containing
2496 the ALTER TABLE statements to transform the previous schema into the
2497 current one. Note that these statements may contain C<DROP TABLE> or
2498 C<DROP COLUMN> statements that can potentially destroy data.
2499
2500 The file names are created using the C<ddl_filename> method below, please
2501 override this method in your schema if you would like a different file
2502 name format. For the ALTER file, the same format is used, replacing
2503 $version in the name with "$preversion-$version".
2504
2505 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2506 The most common value for this would be C<< { add_drop_table => 1 } >>
2507 to have the SQL produced include a C<DROP TABLE> statement for each table
2508 created. For quoting purposes supply C<quote_table_names> and
2509 C<quote_field_names>.
2510
2511 If no arguments are passed, then the following default values are assumed:
2512
2513 =over 4
2514
2515 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2516
2517 =item version    - $schema->schema_version
2518
2519 =item directory  - './'
2520
2521 =item preversion - <none>
2522
2523 =back
2524
2525 By default, C<\%sqlt_args> will have
2526
2527  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2528
2529 merged with the hash passed in. To disable any of those features, pass in a
2530 hashref like the following
2531
2532  { ignore_constraint_names => 0, # ... other options }
2533
2534
2535 WARNING: You are strongly advised to check all SQL files created, before applying
2536 them.
2537
2538 =cut
2539
2540 sub create_ddl_dir {
2541   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2542
2543   unless ($dir) {
2544     carp "No directory given, using ./\n";
2545     $dir = './';
2546   } else {
2547       -d $dir
2548         or
2549       (require File::Path and File::Path::make_path ("$dir"))  # make_path does not like objects (i.e. Path::Class::Dir)
2550         or
2551       $self->throw_exception(
2552         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2553       );
2554   }
2555
2556   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2557
2558   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2559   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2560
2561   my $schema_version = $schema->schema_version || '1.x';
2562   $version ||= $schema_version;
2563
2564   $sqltargs = {
2565     add_drop_table => 1,
2566     ignore_constraint_names => 1,
2567     ignore_index_names => 1,
2568     %{$sqltargs || {}}
2569   };
2570
2571   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2572     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2573   }
2574
2575   my $sqlt = SQL::Translator->new( $sqltargs );
2576
2577   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2578   my $sqlt_schema = $sqlt->translate({ data => $schema })
2579     or $self->throw_exception ($sqlt->error);
2580
2581   foreach my $db (@$databases) {
2582     $sqlt->reset();
2583     $sqlt->{schema} = $sqlt_schema;
2584     $sqlt->producer($db);
2585
2586     my $file;
2587     my $filename = $schema->ddl_filename($db, $version, $dir);
2588     if (-e $filename && ($version eq $schema_version )) {
2589       # if we are dumping the current version, overwrite the DDL
2590       carp "Overwriting existing DDL file - $filename";
2591       unlink($filename);
2592     }
2593
2594     my $output = $sqlt->translate;
2595     if(!$output) {
2596       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2597       next;
2598     }
2599     if(!open($file, ">$filename")) {
2600       $self->throw_exception("Can't open $filename for writing ($!)");
2601       next;
2602     }
2603     print $file $output;
2604     close($file);
2605
2606     next unless ($preversion);
2607
2608     require SQL::Translator::Diff;
2609
2610     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2611     if(!-e $prefilename) {
2612       carp("No previous schema file found ($prefilename)");
2613       next;
2614     }
2615
2616     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2617     if(-e $difffile) {
2618       carp("Overwriting existing diff file - $difffile");
2619       unlink($difffile);
2620     }
2621
2622     my $source_schema;
2623     {
2624       my $t = SQL::Translator->new($sqltargs);
2625       $t->debug( 0 );
2626       $t->trace( 0 );
2627
2628       $t->parser( $db )
2629         or $self->throw_exception ($t->error);
2630
2631       my $out = $t->translate( $prefilename )
2632         or $self->throw_exception ($t->error);
2633
2634       $source_schema = $t->schema;
2635
2636       $source_schema->name( $prefilename )
2637         unless ( $source_schema->name );
2638     }
2639
2640     # The "new" style of producers have sane normalization and can support
2641     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2642     # And we have to diff parsed SQL against parsed SQL.
2643     my $dest_schema = $sqlt_schema;
2644
2645     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2646       my $t = SQL::Translator->new($sqltargs);
2647       $t->debug( 0 );
2648       $t->trace( 0 );
2649
2650       $t->parser( $db )
2651         or $self->throw_exception ($t->error);
2652
2653       my $out = $t->translate( $filename )
2654         or $self->throw_exception ($t->error);
2655
2656       $dest_schema = $t->schema;
2657
2658       $dest_schema->name( $filename )
2659         unless $dest_schema->name;
2660     }
2661
2662     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2663                                                   $dest_schema,   $db,
2664                                                   $sqltargs
2665                                                  );
2666     if(!open $file, ">$difffile") {
2667       $self->throw_exception("Can't write to $difffile ($!)");
2668       next;
2669     }
2670     print $file $diff;
2671     close($file);
2672   }
2673 }
2674
2675 =head2 deployment_statements
2676
2677 =over 4
2678
2679 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2680
2681 =back
2682
2683 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2684
2685 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2686 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2687
2688 C<$directory> is used to return statements from files in a previously created
2689 L</create_ddl_dir> directory and is optional. The filenames are constructed
2690 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2691
2692 If no C<$directory> is specified then the statements are constructed on the
2693 fly using L<SQL::Translator> and C<$version> is ignored.
2694
2695 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2696
2697 =cut
2698
2699 sub deployment_statements {
2700   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2701   $type ||= $self->sqlt_type;
2702   $version ||= $schema->schema_version || '1.x';
2703   $dir ||= './';
2704   my $filename = $schema->ddl_filename($type, $version, $dir);
2705   if(-f $filename)
2706   {
2707       # FIXME replace this block when a proper sane sql parser is available
2708       my $file;
2709       open($file, "<$filename")
2710         or $self->throw_exception("Can't open $filename ($!)");
2711       my @rows = <$file>;
2712       close($file);
2713       return join('', @rows);
2714   }
2715
2716   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2717     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2718   }
2719
2720   # sources needs to be a parser arg, but for simplicty allow at top level
2721   # coming in
2722   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2723       if exists $sqltargs->{sources};
2724
2725   my $tr = SQL::Translator->new(
2726     producer => "SQL::Translator::Producer::${type}",
2727     %$sqltargs,
2728     parser => 'SQL::Translator::Parser::DBIx::Class',
2729     data => $schema,
2730   );
2731
2732   my @ret;
2733   if (wantarray) {
2734     @ret = $tr->translate;
2735   }
2736   else {
2737     $ret[0] = $tr->translate;
2738   }
2739
2740   $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2741     unless (@ret && defined $ret[0]);
2742
2743   return wantarray ? @ret : $ret[0];
2744 }
2745
2746 # FIXME deploy() currently does not accurately report sql errors
2747 # Will always return true while errors are warned
2748 sub deploy {
2749   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2750   my $deploy = sub {
2751     my $line = shift;
2752     return if(!$line);
2753     return if($line =~ /^--/);
2754     # next if($line =~ /^DROP/m);
2755     return if($line =~ /^BEGIN TRANSACTION/m);
2756     return if($line =~ /^COMMIT/m);
2757     return if $line =~ /^\s+$/; # skip whitespace only
2758     $self->_query_start($line);
2759     try {
2760       # do a dbh_do cycle here, as we need some error checking in
2761       # place (even though we will ignore errors)
2762       $self->dbh_do (sub { $_[1]->do($line) });
2763     } catch {
2764       carp qq{$_ (running "${line}")};
2765     };
2766     $self->_query_end($line);
2767   };
2768   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2769   if (@statements > 1) {
2770     foreach my $statement (@statements) {
2771       $deploy->( $statement );
2772     }
2773   }
2774   elsif (@statements == 1) {
2775     # split on single line comments and end of statements
2776     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2777       $deploy->( $line );
2778     }
2779   }
2780 }
2781
2782 =head2 datetime_parser
2783
2784 Returns the datetime parser class
2785
2786 =cut
2787
2788 sub datetime_parser {
2789   my $self = shift;
2790   return $self->{datetime_parser} ||= do {
2791     $self->build_datetime_parser(@_);
2792   };
2793 }
2794
2795 =head2 datetime_parser_type
2796
2797 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2798
2799 =head2 build_datetime_parser
2800
2801 See L</datetime_parser>
2802
2803 =cut
2804
2805 sub build_datetime_parser {
2806   my $self = shift;
2807   my $type = $self->datetime_parser_type(@_);
2808   return $type;
2809 }
2810
2811
2812 =head2 is_replicating
2813
2814 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2815 replicate from a master database.  Default is undef, which is the result
2816 returned by databases that don't support replication.
2817
2818 =cut
2819
2820 sub is_replicating {
2821     return;
2822
2823 }
2824
2825 =head2 lag_behind_master
2826
2827 Returns a number that represents a certain amount of lag behind a master db
2828 when a given storage is replicating.  The number is database dependent, but
2829 starts at zero and increases with the amount of lag. Default in undef
2830
2831 =cut
2832
2833 sub lag_behind_master {
2834     return;
2835 }
2836
2837 =head2 relname_to_table_alias
2838
2839 =over 4
2840
2841 =item Arguments: $relname, $join_count
2842
2843 =back
2844
2845 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2846 queries.
2847
2848 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2849 way these aliases are named.
2850
2851 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2852 otherwise C<"$relname">.
2853
2854 =cut
2855
2856 sub relname_to_table_alias {
2857   my ($self, $relname, $join_count) = @_;
2858
2859   my $alias = ($join_count && $join_count > 1 ?
2860     join('_', $relname, $join_count) : $relname);
2861
2862   return $alias;
2863 }
2864
2865 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
2866 # version and it may be necessary to amend or override it for a specific storage
2867 # if such binds are necessary.
2868 sub _max_column_bytesize {
2869   my ($self, $attr) = @_;
2870
2871   my $max_size;
2872
2873   if ($attr->{sqlt_datatype}) {
2874     my $data_type = lc($attr->{sqlt_datatype});
2875
2876     if ($attr->{sqlt_size}) {
2877
2878       # String/sized-binary types
2879       if ($data_type =~ /^(?:
2880           l? (?:var)? char(?:acter)? (?:\s*varying)?
2881             |
2882           (?:var)? binary (?:\s*varying)?
2883             |
2884           raw
2885         )\b/x
2886       ) {
2887         $max_size = $attr->{sqlt_size};
2888       }
2889       # Other charset/unicode types, assume scale of 4
2890       elsif ($data_type =~ /^(?:
2891           national \s* character (?:\s*varying)?
2892             |
2893           nchar
2894             |
2895           univarchar
2896             |
2897           nvarchar
2898         )\b/x
2899       ) {
2900         $max_size = $attr->{sqlt_size} * 4;
2901       }
2902     }
2903
2904     if (!$max_size and !$self->_is_lob_type($data_type)) {
2905       $max_size = 100 # for all other (numeric?) datatypes
2906     }
2907   }
2908
2909   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
2910 }
2911
2912 # Determine if a data_type is some type of BLOB
2913 sub _is_lob_type {
2914   my ($self, $data_type) = @_;
2915   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
2916     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
2917                                   |varchar|character\s*varying|nvarchar
2918                                   |national\s*character\s*varying))?\z/xi);
2919 }
2920
2921 sub _is_binary_lob_type {
2922   my ($self, $data_type) = @_;
2923   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
2924     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
2925 }
2926
2927 sub _is_text_lob_type {
2928   my ($self, $data_type) = @_;
2929   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
2930     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
2931                         |national\s*character\s*varying))\z/xi);
2932 }
2933
2934 1;
2935
2936 =head1 USAGE NOTES
2937
2938 =head2 DBIx::Class and AutoCommit
2939
2940 DBIx::Class can do some wonderful magic with handling exceptions,
2941 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2942 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
2943 transaction support.
2944
2945 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
2946 in an assumed transaction between commits, and you're telling us you'd
2947 like to manage that manually.  A lot of the magic protections offered by
2948 this module will go away.  We can't protect you from exceptions due to database
2949 disconnects because we don't know anything about how to restart your
2950 transactions.  You're on your own for handling all sorts of exceptional
2951 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
2952 be with raw DBI.
2953
2954
2955 =head1 AUTHORS
2956
2957 Matt S. Trout <mst@shadowcatsystems.co.uk>
2958
2959 Andy Grundman <andy@hybridized.org>
2960
2961 =head1 LICENSE
2962
2963 You may distribute this code under the same terms as Perl itself.
2964
2965 =cut