lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util qw/blessed weaken/;
  13
  14 __PACKAGE__->mk_group_accessors('simple' =>
  15     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  16        _conn_pid _conn_tid disable_sth_caching on_connect_do
  17        on_disconnect_do transaction_depth unsafe _dbh_autocommit/
  18 );
  19
  20 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  21
  22 BEGIN {
  23
  24 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  25
  26 use base qw/SQL::Abstract::Limit/;
  27
  28 # This prevents the caching of $dbh in S::A::L, I believe
  29 sub new {
  30   my $self = shift->SUPER::new(@_);
  31
  32   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  33   #   it with what it resolves to:
  34   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  35     if ref $self->{limit_dialect};
  36
  37   $self;
  38 }
  39
  40 sub _RowNumberOver {
  41   my ($self, $sql, $order, $rows, $offset ) = @_;
  42
  43   $offset += 1;
  44   my $last = $rows + $offset;
  45   my ( $order_by ) = $self->_order_by( $order );
  46
  47   $sql = <<"";
  48 SELECT * FROM
  49 (
  50    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  51       $sql
  52       $order_by
  53    ) Q1
  54 ) Q2
  55 WHERE ROW_NUM BETWEEN $offset AND $last
  56
  57   return $sql;
  58 }
  59
  60
  61 # While we're at it, this should make LIMIT queries more efficient,
  62 #  without digging into things too deeply
  63 use Scalar::Util 'blessed';
  64 sub _find_syntax {
  65   my ($self, $syntax) = @_;
  66   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  67   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  68     return 'RowNumberOver';
  69   }
  70
  71   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  72 }
  73
  74 sub select {
  75   my ($self, $table, $fields, $where, $order, @rest) = @_;
  76   $table = $self->_quote($table) unless ref($table);
  77   local $self->{rownum_hack_count} = 1
  78     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  79   @rest = (-1) unless defined $rest[0];
  80   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  81     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  82   local $self->{having_bind} = [];
  83   my ($sql, @ret) = $self->SUPER::select(
  84     $table, $self->_recurse_fields($fields), $where, $order, @rest
  85   );
  86   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  87 }
  88
  89 sub insert {
  90   my $self = shift;
  91   my $table = shift;
  92   $table = $self->_quote($table) unless ref($table);
  93   $self->SUPER::insert($table, @_);
  94 }
  95
  96 sub update {
  97   my $self = shift;
  98   my $table = shift;
  99   $table = $self->_quote($table) unless ref($table);
 100   $self->SUPER::update($table, @_);
 101 }
 102
 103 sub delete {
 104   my $self = shift;
 105   my $table = shift;
 106   $table = $self->_quote($table) unless ref($table);
 107   $self->SUPER::delete($table, @_);
 108 }
 109
 110 sub _emulate_limit {
 111   my $self = shift;
 112   if ($_[3] == -1) {
 113     return $_[1].$self->_order_by($_[2]);
 114   } else {
 115     return $self->SUPER::_emulate_limit(@_);
 116   }
 117 }
 118
 119 sub _recurse_fields {
 120   my ($self, $fields, $params) = @_;
 121   my $ref = ref $fields;
 122   return $self->_quote($fields) unless $ref;
 123   return $$fields if $ref eq 'SCALAR';
 124
 125   if ($ref eq 'ARRAY') {
 126     return join(', ', map {
 127       $self->_recurse_fields($_)
 128         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 129           ? ' AS col'.$self->{rownum_hack_count}++
 130           : '')
 131       } @$fields);
 132   } elsif ($ref eq 'HASH') {
 133     foreach my $func (keys %$fields) {
 134       return $self->_sqlcase($func)
 135         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 136     }
 137   }
 138 }
 139
 140 sub _order_by {
 141   my $self = shift;
 142   my $ret = '';
 143   my @extra;
 144   if (ref $_[0] eq 'HASH') {
 145     if (defined $_[0]->{group_by}) {
 146       $ret = $self->_sqlcase(' group by ')
 147         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 148     }
 149     if (defined $_[0]->{having}) {
 150       my $frag;
 151       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 152       push(@{$self->{having_bind}}, @extra);
 153       $ret .= $self->_sqlcase(' having ').$frag;
 154     }
 155     if (defined $_[0]->{order_by}) {
 156       $ret .= $self->_order_by($_[0]->{order_by});
 157     }
 158   } elsif (ref $_[0] eq 'SCALAR') {
 159     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 160   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 161     my @order = @{+shift};
 162     $ret = $self->_sqlcase(' order by ')
 163           .join(', ', map {
 164                         my $r = $self->_order_by($_, @_);
 165                         $r =~ s/^ ?ORDER BY //i;
 166                         $r;
 167                       } @order);
 168   } else {
 169     $ret = $self->SUPER::_order_by(@_);
 170   }
 171   return $ret;
 172 }
 173
 174 sub _order_directions {
 175   my ($self, $order) = @_;
 176   $order = $order->{order_by} if ref $order eq 'HASH';
 177   return $self->SUPER::_order_directions($order);
 178 }
 179
 180 sub _table {
 181   my ($self, $from) = @_;
 182   if (ref $from eq 'ARRAY') {
 183     return $self->_recurse_from(@$from);
 184   } elsif (ref $from eq 'HASH') {
 185     return $self->_make_as($from);
 186   } else {
 187     return $from; # would love to quote here but _table ends up getting called
 188                   # twice during an ->select without a limit clause due to
 189                   # the way S::A::Limit->select works. should maybe consider
 190                   # bypassing this and doing S::A::select($self, ...) in
 191                   # our select method above. meantime, quoting shims have
 192                   # been added to select/insert/update/delete here
 193   }
 194 }
 195
 196 sub _recurse_from {
 197   my ($self, $from, @join) = @_;
 198   my @sqlf;
 199   push(@sqlf, $self->_make_as($from));
 200   foreach my $j (@join) {
 201     my ($to, $on) = @$j;
 202
 203     # check whether a join type exists
 204     my $join_clause = '';
 205     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 206     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 207       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 208     } else {
 209       $join_clause = ' JOIN ';
 210     }
 211     push(@sqlf, $join_clause);
 212
 213     if (ref $to eq 'ARRAY') {
 214       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 215     } else {
 216       push(@sqlf, $self->_make_as($to));
 217     }
 218     push(@sqlf, ' ON ', $self->_join_condition($on));
 219   }
 220   return join('', @sqlf);
 221 }
 222
 223 sub _make_as {
 224   my ($self, $from) = @_;
 225   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 226                      reverse each %{$self->_skip_options($from)});
 227 }
 228
 229 sub _skip_options {
 230   my ($self, $hash) = @_;
 231   my $clean_hash = {};
 232   $clean_hash->{$_} = $hash->{$_}
 233     for grep {!/^-/} keys %$hash;
 234   return $clean_hash;
 235 }
 236
 237 sub _join_condition {
 238   my ($self, $cond) = @_;
 239   if (ref $cond eq 'HASH') {
 240     my %j;
 241     for (keys %$cond) {
 242       my $v = $cond->{$_};
 243       if (ref $v) {
 244         # XXX no throw_exception() in this package and croak() fails with strange results
 245         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 246             if ref($v) ne 'SCALAR';
 247         $j{$_} = $v;
 248       }
 249       else {
 250         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 251       }
 252     };
 253     return scalar($self->_recurse_where(\%j));
 254   } elsif (ref $cond eq 'ARRAY') {
 255     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 256   } else {
 257     die "Can't handle this yet!";
 258   }
 259 }
 260
 261 sub _quote {
 262   my ($self, $label) = @_;
 263   return '' unless defined $label;
 264   return "*" if $label eq '*';
 265   return $label unless $self->{quote_char};
 266   if(ref $self->{quote_char} eq "ARRAY"){
 267     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 268       if !defined $self->{name_sep};
 269     my $sep = $self->{name_sep};
 270     return join($self->{name_sep},
 271         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 272        split(/\Q$sep\E/,$label));
 273   }
 274   return $self->SUPER::_quote($label);
 275 }
 276
 277 sub limit_dialect {
 278     my $self = shift;
 279     $self->{limit_dialect} = shift if @_;
 280     return $self->{limit_dialect};
 281 }
 282
 283 sub quote_char {
 284     my $self = shift;
 285     $self->{quote_char} = shift if @_;
 286     return $self->{quote_char};
 287 }
 288
 289 sub name_sep {
 290     my $self = shift;
 291     $self->{name_sep} = shift if @_;
 292     return $self->{name_sep};
 293 }
 294
 295 } # End of BEGIN block
 296
 297 =head1 NAME
 298
 299 DBIx::Class::Storage::DBI - DBI storage handler
 300
 301 =head1 SYNOPSIS
 302
 303 =head1 DESCRIPTION
 304
 305 This class represents the connection to an RDBMS via L<DBI>.  See
 306 L<DBIx::Class::Storage> for general information.  This pod only
 307 documents DBI-specific methods and behaviors.
 308
 309 =head1 METHODS
 310
 311 =cut
 312
 313 sub new {
 314   my $new = shift->next::method(@_);
 315
 316   $new->transaction_depth(0);
 317   $new->_sql_maker_opts({});
 318   $new->{_in_dbh_do} = 0;
 319   $new->{_dbh_gen} = 0;
 320
 321   $new;
 322 }
 323
 324 =head2 connect_info
 325
 326 The arguments of C<connect_info> are always a single array reference.
 327
 328 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 329 encapsulates its argument list in an arrayref before calling
 330 C<connect_info> here.
 331
 332 The arrayref can either contain the same set of arguments one would
 333 normally pass to L<DBI/connect>, or a lone code reference which returns
 334 a connected database handle.  Please note that the L<DBI> docs
 335 recommend that you always explicitly set C<AutoCommit> to either
 336 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 337 to C<1>, and that you perform transactions via our L</txn_do>
 338 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 339 set it to zero.  This is the default for most DBDs.  See below for more
 340 details.
 341
 342 In either case, if the final argument in your connect_info happens
 343 to be a hashref, C<connect_info> will look there for several
 344 connection-specific options:
 345
 346 =over 4
 347
 348 =item on_connect_do
 349
 350 Specifies things to do immediately after connecting or re-connecting to
 351 the database.  Its value may contain:
 352
 353 =over
 354
 355 =item an array reference
 356
 357 This contains SQL statements to execute in order.  Each element contains
 358 a string or a code reference that returns a string.
 359
 360 =item a code reference
 361
 362 This contains some code to execute.  Unlike code references within an
 363 array reference, its return value is ignored.
 364
 365 =back
 366
 367 =item on_disconnect_do
 368
 369 Takes arguments in the same for as L<on_connect_do> and executes them
 370 immediately before disconnecting from the database.
 371
 372 Note, this only runs if you explicitly call L<disconnect> on the
 373 storage object.
 374
 375 =item disable_sth_caching
 376
 377 If set to a true value, this option will disable the caching of
 378 statement handles via L<DBI/prepare_cached>.
 379
 380 =item limit_dialect
 381
 382 Sets the limit dialect. This is useful for JDBC-bridge among others
 383 where the remote SQL-dialect cannot be determined by the name of the
 384 driver alone.
 385
 386 =item quote_char
 387
 388 Specifies what characters to use to quote table and column names. If
 389 you use this you will want to specify L<name_sep> as well.
 390
 391 quote_char expects either a single character, in which case is it is placed
 392 on either side of the table/column, or an arrayref of length 2 in which case the
 393 table/column name is placed between the elements.
 394
 395 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 396 use C<quote_char =E<gt> [qw/[ ]/]>.
 397
 398 =item name_sep
 399
 400 This only needs to be used in conjunction with L<quote_char>, and is used to
 401 specify the charecter that seperates elements (schemas, tables, columns) from
 402 each other. In most cases this is simply a C<.>.
 403
 404 =item unsafe
 405
 406 This Storage driver normally installs its own C<HandleError>, sets
 407 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 408 all database handles, including those supplied by a coderef.  It does this
 409 so that it can have consistent and useful error behavior.
 410
 411 If you set this option to a true value, Storage will not do its usual
 412 modifications to the database handle's attributes, and instead relies on
 413 the settings in your connect_info DBI options (or the values you set in
 414 your connection coderef, in the case that you are connecting via coderef).
 415
 416 Note that your custom settings can cause Storage to malfunction,
 417 especially if you set a C<HandleError> handler that suppresses exceptions
 418 and/or disable C<RaiseError>.
 419
 420 =back
 421
 422 These options can be mixed in with your other L<DBI> connection attributes,
 423 or placed in a seperate hashref after all other normal L<DBI> connection
 424 arguments.
 425
 426 Every time C<connect_info> is invoked, any previous settings for
 427 these options will be cleared before setting the new ones, regardless of
 428 whether any options are specified in the new C<connect_info>.
 429
 430 Another Important Note:
 431
 432 DBIC can do some wonderful magic with handling exceptions,
 433 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 434 combined with C<txn_do> for transaction support.
 435
 436 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 437 in an assumed transaction between commits, and you're telling us you'd
 438 like to manage that manually.  A lot of DBIC's magic protections
 439 go away.  We can't protect you from exceptions due to database
 440 disconnects because we don't know anything about how to restart your
 441 transactions.  You're on your own for handling all sorts of exceptional
 442 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 443 be with raw DBI.
 444
 445 Examples:
 446
 447   # Simple SQLite connection
 448   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 449
 450   # Connect via subref
 451   ->connect_info([ sub { DBI->connect(...) } ]);
 452
 453   # A bit more complicated
 454   ->connect_info(
 455     [
 456       'dbi:Pg:dbname=foo',
 457       'postgres',
 458       'my_pg_password',
 459       { AutoCommit => 1 },
 460       { quote_char => q{"}, name_sep => q{.} },
 461     ]
 462   );
 463
 464   # Equivalent to the previous example
 465   ->connect_info(
 466     [
 467       'dbi:Pg:dbname=foo',
 468       'postgres',
 469       'my_pg_password',
 470       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 471     ]
 472   );
 473
 474   # Subref + DBIC-specific connection options
 475   ->connect_info(
 476     [
 477       sub { DBI->connect(...) },
 478       {
 479           quote_char => q{`},
 480           name_sep => q{@},
 481           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 482           disable_sth_caching => 1,
 483       },
 484     ]
 485   );
 486
 487 =cut
 488
 489 sub connect_info {
 490   my ($self, $info_arg) = @_;
 491
 492   return $self->_connect_info if !$info_arg;
 493
 494   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 495   #  the new set of options
 496   $self->_sql_maker(undef);
 497   $self->_sql_maker_opts({});
 498   $self->_connect_info([@$info_arg]); # copy for _connect_info
 499
 500   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 501
 502   my $last_info = $dbi_info->[-1];
 503   if(ref $last_info eq 'HASH') {
 504     $last_info = { %$last_info }; # so delete is non-destructive
 505     my @storage_option = qw(
 506       on_connect_do on_disconnect_do disable_sth_caching unsafe cursor_class
 507     );
 508     for my $storage_opt (@storage_option) {
 509       if(my $value = delete $last_info->{$storage_opt}) {
 510         $self->$storage_opt($value);
 511       }
 512     }
 513     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 514       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 515         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 516       }
 517     }
 518     # re-insert modified hashref
 519     $dbi_info->[-1] = $last_info;
 520
 521     # Get rid of any trailing empty hashref
 522     pop(@$dbi_info) if !keys %$last_info;
 523   }
 524   $self->_dbi_connect_info($dbi_info);
 525
 526   $self->_connect_info;
 527 }
 528
 529 =head2 on_connect_do
 530
 531 This method is deprecated in favor of setting via L</connect_info>.
 532
 533 =head2 dbh_do
 534
 535 Arguments: $subref, @extra_coderef_args?
 536
 537 Execute the given subref using the new exception-based connection management.
 538
 539 The first two arguments will be the storage object that C<dbh_do> was called
 540 on and a database handle to use.  Any additional arguments will be passed
 541 verbatim to the called subref as arguments 2 and onwards.
 542
 543 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 544 exception handling and reconnection (or failover in future subclasses).
 545
 546 Your subref should have no side-effects outside of the database, as
 547 there is the potential for your subref to be partially double-executed
 548 if the database connection was stale/dysfunctional.
 549
 550 Example:
 551
 552   my @stuff = $schema->storage->dbh_do(
 553     sub {
 554       my ($storage, $dbh, @cols) = @_;
 555       my $cols = join(q{, }, @cols);
 556       $dbh->selectrow_array("SELECT $cols FROM foo");
 557     },
 558     @column_list
 559   );
 560
 561 =cut
 562
 563 sub dbh_do {
 564   my $self = shift;
 565   my $coderef = shift;
 566
 567   ref $coderef eq 'CODE' or $self->throw_exception
 568     ('$coderef must be a CODE reference');
 569
 570   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 571       || $self->{transaction_depth};
 572
 573   local $self->{_in_dbh_do} = 1;
 574
 575   my @result;
 576   my $want_array = wantarray;
 577
 578   eval {
 579     $self->_verify_pid if $self->_dbh;
 580     $self->_populate_dbh if !$self->_dbh;
 581     if($want_array) {
 582         @result = $coderef->($self, $self->_dbh, @_);
 583     }
 584     elsif(defined $want_array) {
 585         $result[0] = $coderef->($self, $self->_dbh, @_);
 586     }
 587     else {
 588         $coderef->($self, $self->_dbh, @_);
 589     }
 590   };
 591
 592   my $exception = $@;
 593   if(!$exception) { return $want_array ? @result : $result[0] }
 594
 595   $self->throw_exception($exception) if $self->connected;
 596
 597   # We were not connected - reconnect and retry, but let any
 598   #  exception fall right through this time
 599   $self->_populate_dbh;
 600   $coderef->($self, $self->_dbh, @_);
 601 }
 602
 603 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 604 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 605 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 606 sub txn_do {
 607   my $self = shift;
 608   my $coderef = shift;
 609
 610   ref $coderef eq 'CODE' or $self->throw_exception
 611     ('$coderef must be a CODE reference');
 612
 613   return $coderef->(@_) if $self->{transaction_depth};
 614
 615   local $self->{_in_dbh_do} = 1;
 616
 617   my @result;
 618   my $want_array = wantarray;
 619
 620   my $tried = 0;
 621   while(1) {
 622     eval {
 623       $self->_verify_pid if $self->_dbh;
 624       $self->_populate_dbh if !$self->_dbh;
 625
 626       $self->txn_begin;
 627       if($want_array) {
 628           @result = $coderef->(@_);
 629       }
 630       elsif(defined $want_array) {
 631           $result[0] = $coderef->(@_);
 632       }
 633       else {
 634           $coderef->(@_);
 635       }
 636       $self->txn_commit;
 637     };
 638
 639     my $exception = $@;
 640     if(!$exception) { return $want_array ? @result : $result[0] }
 641
 642     if($tried++ > 0 || $self->connected) {
 643       eval { $self->txn_rollback };
 644       my $rollback_exception = $@;
 645       if($rollback_exception) {
 646         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 647         $self->throw_exception($exception)  # propagate nested rollback
 648           if $rollback_exception =~ /$exception_class/;
 649
 650         $self->throw_exception(
 651           "Transaction aborted: ${exception}. "
 652           . "Rollback failed: ${rollback_exception}"
 653         );
 654       }
 655       $self->throw_exception($exception)
 656     }
 657
 658     # We were not connected, and was first try - reconnect and retry
 659     # via the while loop
 660     $self->_populate_dbh;
 661   }
 662 }
 663
 664 =head2 disconnect
 665
 666 Our C<disconnect> method also performs a rollback first if the
 667 database is not in C<AutoCommit> mode.
 668
 669 =cut
 670
 671 sub disconnect {
 672   my ($self) = @_;
 673
 674   if( $self->connected ) {
 675     my $connection_do = $self->on_disconnect_do;
 676     $self->_do_connection_actions($connection_do) if ref($connection_do);
 677
 678     $self->_dbh->rollback unless $self->_dbh_autocommit;
 679     $self->_dbh->disconnect;
 680     $self->_dbh(undef);
 681     $self->{_dbh_gen}++;
 682   }
 683 }
 684
 685 sub connected {
 686   my ($self) = @_;
 687
 688   if(my $dbh = $self->_dbh) {
 689       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 690           $self->_dbh(undef);
 691           $self->{_dbh_gen}++;
 692           return;
 693       }
 694       else {
 695           $self->_verify_pid;
 696           return 0 if !$self->_dbh;
 697       }
 698       return ($dbh->FETCH('Active') && $dbh->ping);
 699   }
 700
 701   return 0;
 702 }
 703
 704 # handle pid changes correctly
 705 #  NOTE: assumes $self->_dbh is a valid $dbh
 706 sub _verify_pid {
 707   my ($self) = @_;
 708
 709   return if $self->_conn_pid == $$;
 710
 711   $self->_dbh->{InactiveDestroy} = 1;
 712   $self->_dbh(undef);
 713   $self->{_dbh_gen}++;
 714
 715   return;
 716 }
 717
 718 sub ensure_connected {
 719   my ($self) = @_;
 720
 721   unless ($self->connected) {
 722     $self->_populate_dbh;
 723   }
 724 }
 725
 726 =head2 dbh
 727
 728 Returns the dbh - a data base handle of class L<DBI>.
 729
 730 =cut
 731
 732 sub dbh {
 733   my ($self) = @_;
 734
 735   $self->ensure_connected;
 736   return $self->_dbh;
 737 }
 738
 739 sub _sql_maker_args {
 740     my ($self) = @_;
 741
 742     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 743 }
 744
 745 sub sql_maker {
 746   my ($self) = @_;
 747   unless ($self->_sql_maker) {
 748     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 749   }
 750   return $self->_sql_maker;
 751 }
 752
 753 sub _populate_dbh {
 754   my ($self) = @_;
 755   my @info = @{$self->_dbi_connect_info || []};
 756   $self->_dbh($self->_connect(@info));
 757
 758   # Always set the transaction depth on connect, since
 759   #  there is no transaction in progress by definition
 760   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 761
 762   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 763     my $driver = $self->_dbh->{Driver}->{Name};
 764     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 765       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 766       $self->_rebless() if $self->can('_rebless');
 767     }
 768   }
 769
 770   my $connection_do = $self->on_connect_do;
 771   $self->_do_connection_actions($connection_do) if ref($connection_do);
 772
 773   $self->_conn_pid($$);
 774   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 775 }
 776
 777 sub _do_connection_actions {
 778   my $self = shift;
 779   my $connection_do = shift;
 780
 781   if (ref $connection_do eq 'ARRAY') {
 782     $self->_do_query($_) foreach @$connection_do;
 783   }
 784   elsif (ref $connection_do eq 'CODE') {
 785     $connection_do->();
 786   }
 787
 788   return $self;
 789 }
 790
 791 sub _do_query {
 792   my ($self, $action) = @_;
 793
 794   if (ref $action eq 'CODE') {
 795     $action->($self);
 796   }
 797   else {
 798     $self->debugobj->query_start($action) if $self->debug();
 799     $self->_dbh->do($action);
 800     $self->debugobj->query_end($action) if $self->debug();
 801   }
 802
 803   return $self;
 804 }
 805
 806 sub _connect {
 807   my ($self, @info) = @_;
 808
 809   $self->throw_exception("You failed to provide any connection info")
 810     if !@info;
 811
 812   my ($old_connect_via, $dbh);
 813
 814   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 815     $old_connect_via = $DBI::connect_via;
 816     $DBI::connect_via = 'connect';
 817   }
 818
 819   eval {
 820     if(ref $info[0] eq 'CODE') {
 821        $dbh = &{$info[0]}
 822     }
 823     else {
 824        $dbh = DBI->connect(@info);
 825     }
 826
 827     if($dbh && !$self->unsafe) {
 828       my $weak_self = $self;
 829       weaken($weak_self);
 830       $dbh->{HandleError} = sub {
 831           $weak_self->throw_exception("DBI Exception: $_[0]")
 832       };
 833       $dbh->{ShowErrorStatement} = 1;
 834       $dbh->{RaiseError} = 1;
 835       $dbh->{PrintError} = 0;
 836     }
 837   };
 838
 839   $DBI::connect_via = $old_connect_via if $old_connect_via;
 840
 841   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 842     if !$dbh || $@;
 843
 844   $self->_dbh_autocommit($dbh->{AutoCommit});
 845
 846   $dbh;
 847 }
 848
 849
 850 sub txn_begin {
 851   my $self = shift;
 852   $self->ensure_connected();
 853   if($self->{transaction_depth} == 0) {
 854     $self->debugobj->txn_begin()
 855       if $self->debug;
 856     # this isn't ->_dbh-> because
 857     #  we should reconnect on begin_work
 858     #  for AutoCommit users
 859     $self->dbh->begin_work;
 860   }
 861   $self->{transaction_depth}++;
 862 }
 863
 864 sub txn_commit {
 865   my $self = shift;
 866   if ($self->{transaction_depth} == 1) {
 867     my $dbh = $self->_dbh;
 868     $self->debugobj->txn_commit()
 869       if ($self->debug);
 870     $dbh->commit;
 871     $self->{transaction_depth} = 0
 872       if $self->_dbh_autocommit;
 873   }
 874   elsif($self->{transaction_depth} > 1) {
 875     $self->{transaction_depth}--
 876   }
 877 }
 878
 879 sub txn_rollback {
 880   my $self = shift;
 881   my $dbh = $self->_dbh;
 882   eval {
 883     if ($self->{transaction_depth} == 1) {
 884       $self->debugobj->txn_rollback()
 885         if ($self->debug);
 886       $self->{transaction_depth} = 0
 887         if $self->_dbh_autocommit;
 888       $dbh->rollback;
 889     }
 890     elsif($self->{transaction_depth} > 1) {
 891       $self->{transaction_depth}--;
 892     }
 893     else {
 894       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 895     }
 896   };
 897   if ($@) {
 898     my $error = $@;
 899     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 900     $error =~ /$exception_class/ and $self->throw_exception($error);
 901     # ensure that a failed rollback resets the transaction depth
 902     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 903     $self->throw_exception($error);
 904   }
 905 }
 906
 907 # This used to be the top-half of _execute.  It was split out to make it
 908 #  easier to override in NoBindVars without duping the rest.  It takes up
 909 #  all of _execute's args, and emits $sql, @bind.
 910 sub _prep_for_execute {
 911   my ($self, $op, $extra_bind, $ident, $args) = @_;
 912
 913   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 914   unshift(@bind,
 915     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 916       if $extra_bind;
 917
 918   return ($sql, \@bind);
 919 }
 920
 921 sub _fix_bind_params {
 922     my ($self, @bind) = @_;
 923
 924     ### Turn @bind from something like this:
 925     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
 926     ### to this:
 927     ###   ( "'1'", "'1'", "'3'" )
 928     return
 929         map {
 930             if ( defined( $_ && $_->[1] ) ) {
 931                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
 932             }
 933             else { q{'NULL'}; }
 934         } @bind;
 935 }
 936
 937 sub _query_start {
 938     my ( $self, $sql, @bind ) = @_;
 939
 940     if ( $self->debug ) {
 941         @bind = $self->_fix_bind_params(@bind);
 942         $self->debugobj->query_start( $sql, @bind );
 943     }
 944 }
 945
 946 sub _query_end {
 947     my ( $self, $sql, @bind ) = @_;
 948
 949     if ( $self->debug ) {
 950         @bind = $self->_fix_bind_params(@bind);
 951         $self->debugobj->query_end( $sql, @bind );
 952     }
 953 }
 954
 955 sub _dbh_execute {
 956   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 957
 958   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 959     $ident = $ident->from();
 960   }
 961
 962   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 963
 964   $self->_query_start( $sql, @$bind );
 965
 966   my $sth = $self->sth($sql,$op);
 967
 968   my $placeholder_index = 1;
 969
 970   foreach my $bound (@$bind) {
 971     my $attributes = {};
 972     my($column_name, @data) = @$bound;
 973
 974     if ($bind_attributes) {
 975       $attributes = $bind_attributes->{$column_name}
 976       if defined $bind_attributes->{$column_name};
 977     }
 978
 979     foreach my $data (@data) {
 980       $data = ref $data ? ''.$data : $data; # stringify args
 981
 982       $sth->bind_param($placeholder_index, $data, $attributes);
 983       $placeholder_index++;
 984     }
 985   }
 986
 987   # Can this fail without throwing an exception anyways???
 988   my $rv = $sth->execute();
 989   $self->throw_exception($sth->errstr) if !$rv;
 990
 991   $self->_query_end( $sql, @$bind );
 992
 993   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 994 }
 995
 996 sub _execute {
 997     my $self = shift;
 998     $self->dbh_do($self->can('_dbh_execute'), @_)
 999 }
1000
1001 sub insert {
1002   my ($self, $source, $to_insert) = @_;
1003
1004   my $ident = $source->from;
1005   my $bind_attributes = $self->source_bind_attributes($source);
1006
1007   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1008
1009   return $to_insert;
1010 }
1011
1012 ## Still not quite perfect, and EXPERIMENTAL
1013 ## Currently it is assumed that all values passed will be "normal", i.e. not
1014 ## scalar refs, or at least, all the same type as the first set, the statement is
1015 ## only prepped once.
1016 sub insert_bulk {
1017   my ($self, $source, $cols, $data) = @_;
1018   my %colvalues;
1019   my $table = $source->from;
1020   @colvalues{@$cols} = (0..$#$cols);
1021   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1022
1023   $self->_query_start( $sql, @bind );
1024   my $sth = $self->sth($sql);
1025
1026 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1027
1028   ## This must be an arrayref, else nothing works!
1029
1030   my $tuple_status = [];
1031
1032   ##use Data::Dumper;
1033   ##print STDERR Dumper( $data, $sql, [@bind] );
1034
1035   my $time = time();
1036
1037   ## Get the bind_attributes, if any exist
1038   my $bind_attributes = $self->source_bind_attributes($source);
1039
1040   ## Bind the values and execute
1041   my $placeholder_index = 1;
1042
1043   foreach my $bound (@bind) {
1044
1045     my $attributes = {};
1046     my ($column_name, $data_index) = @$bound;
1047
1048     if( $bind_attributes ) {
1049       $attributes = $bind_attributes->{$column_name}
1050       if defined $bind_attributes->{$column_name};
1051     }
1052
1053     my @data = map { $_->[$data_index] } @$data;
1054
1055     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1056     $placeholder_index++;
1057   }
1058   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1059   $self->throw_exception($sth->errstr) if !$rv;
1060
1061   $self->_query_end( $sql, @bind );
1062   return (wantarray ? ($rv, $sth, @bind) : $rv);
1063 }
1064
1065 sub update {
1066   my $self = shift @_;
1067   my $source = shift @_;
1068   my $bind_attributes = $self->source_bind_attributes($source);
1069
1070   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1071 }
1072
1073
1074 sub delete {
1075   my $self = shift @_;
1076   my $source = shift @_;
1077
1078   my $bind_attrs = {}; ## If ever it's needed...
1079
1080   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1081 }
1082
1083 sub _select {
1084   my ($self, $ident, $select, $condition, $attrs) = @_;
1085   my $order = $attrs->{order_by};
1086   if (ref $condition eq 'SCALAR') {
1087     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1088   }
1089   if (exists $attrs->{group_by} || $attrs->{having}) {
1090     $order = {
1091       group_by => $attrs->{group_by},
1092       having => $attrs->{having},
1093       ($order ? (order_by => $order) : ())
1094     };
1095   }
1096   my $bind_attrs = {}; ## Future support
1097   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1098   if ($attrs->{software_limit} ||
1099       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1100         $attrs->{software_limit} = 1;
1101   } else {
1102     $self->throw_exception("rows attribute must be positive if present")
1103       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1104     push @args, $attrs->{rows}, $attrs->{offset};
1105   }
1106   return $self->_execute(@args);
1107 }
1108
1109 sub source_bind_attributes {
1110   my ($self, $source) = @_;
1111
1112   my $bind_attributes;
1113   foreach my $column ($source->columns) {
1114
1115     my $data_type = $source->column_info($column)->{data_type} || '';
1116     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1117      if $data_type;
1118   }
1119
1120   return $bind_attributes;
1121 }
1122
1123 =head2 select
1124
1125 =over 4
1126
1127 =item Arguments: $ident, $select, $condition, $attrs
1128
1129 =back
1130
1131 Handle a SQL select statement.
1132
1133 =cut
1134
1135 sub select {
1136   my $self = shift;
1137   my ($ident, $select, $condition, $attrs) = @_;
1138   return $self->cursor_class->new($self, \@_, $attrs);
1139 }
1140
1141 sub select_single {
1142   my $self = shift;
1143   my ($rv, $sth, @bind) = $self->_select(@_);
1144   my @row = $sth->fetchrow_array;
1145   # Need to call finish() to work round broken DBDs
1146   $sth->finish();
1147   return @row;
1148 }
1149
1150 =head2 sth
1151
1152 =over 4
1153
1154 =item Arguments: $sql
1155
1156 =back
1157
1158 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1159
1160 =cut
1161
1162 sub _dbh_sth {
1163   my ($self, $dbh, $sql) = @_;
1164
1165   # 3 is the if_active parameter which avoids active sth re-use
1166   my $sth = $self->disable_sth_caching
1167     ? $dbh->prepare($sql)
1168     : $dbh->prepare_cached($sql, {}, 3);
1169
1170   # XXX You would think RaiseError would make this impossible,
1171   #  but apparently that's not true :(
1172   $self->throw_exception($dbh->errstr) if !$sth;
1173
1174   $sth;
1175 }
1176
1177 sub sth {
1178   my ($self, $sql) = @_;
1179   $self->dbh_do($self->can('_dbh_sth'), $sql);
1180 }
1181
1182 sub _dbh_columns_info_for {
1183   my ($self, $dbh, $table) = @_;
1184
1185   if ($dbh->can('column_info')) {
1186     my %result;
1187     eval {
1188       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1189       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1190       $sth->execute();
1191       while ( my $info = $sth->fetchrow_hashref() ){
1192         my %column_info;
1193         $column_info{data_type}   = $info->{TYPE_NAME};
1194         $column_info{size}      = $info->{COLUMN_SIZE};
1195         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1196         $column_info{default_value} = $info->{COLUMN_DEF};
1197         my $col_name = $info->{COLUMN_NAME};
1198         $col_name =~ s/^\"(.*)\"$/$1/;
1199
1200         $result{$col_name} = \%column_info;
1201       }
1202     };
1203     return \%result if !$@ && scalar keys %result;
1204   }
1205
1206   my %result;
1207   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1208   $sth->execute;
1209   my @columns = @{$sth->{NAME_lc}};
1210   for my $i ( 0 .. $#columns ){
1211     my %column_info;
1212     $column_info{data_type} = $sth->{TYPE}->[$i];
1213     $column_info{size} = $sth->{PRECISION}->[$i];
1214     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1215
1216     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1217       $column_info{data_type} = $1;
1218       $column_info{size}    = $2;
1219     }
1220
1221     $result{$columns[$i]} = \%column_info;
1222   }
1223   $sth->finish;
1224
1225   foreach my $col (keys %result) {
1226     my $colinfo = $result{$col};
1227     my $type_num = $colinfo->{data_type};
1228     my $type_name;
1229     if(defined $type_num && $dbh->can('type_info')) {
1230       my $type_info = $dbh->type_info($type_num);
1231       $type_name = $type_info->{TYPE_NAME} if $type_info;
1232       $colinfo->{data_type} = $type_name if $type_name;
1233     }
1234   }
1235
1236   return \%result;
1237 }
1238
1239 sub columns_info_for {
1240   my ($self, $table) = @_;
1241   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1242 }
1243
1244 =head2 last_insert_id
1245
1246 Return the row id of the last insert.
1247
1248 =cut
1249
1250 sub _dbh_last_insert_id {
1251     my ($self, $dbh, $source, $col) = @_;
1252     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1253     $dbh->func('last_insert_rowid');
1254 }
1255
1256 sub last_insert_id {
1257   my $self = shift;
1258   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1259 }
1260
1261 =head2 sqlt_type
1262
1263 Returns the database driver name.
1264
1265 =cut
1266
1267 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1268
1269 =head2 bind_attribute_by_data_type
1270
1271 Given a datatype from column info, returns a database specific bind attribute for
1272 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1273 just handle it.
1274
1275 Generally only needed for special case column types, like bytea in postgres.
1276
1277 =cut
1278
1279 sub bind_attribute_by_data_type {
1280     return;
1281 }
1282
1283 =head2 create_ddl_dir
1284
1285 =over 4
1286
1287 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1288
1289 =back
1290
1291 Creates a SQL file based on the Schema, for each of the specified
1292 database types, in the given directory.
1293
1294 =cut
1295
1296 sub create_ddl_dir
1297 {
1298   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1299
1300   if(!$dir || !-d $dir)
1301   {
1302     warn "No directory given, using ./\n";
1303     $dir = "./";
1304   }
1305   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1306   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1307   $version ||= $schema->VERSION || '1.x';
1308   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1309
1310   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.08: '}
1311       . $self->_check_sqlt_message . q{'})
1312           if !$self->_check_sqlt_version;
1313
1314   my $sqlt = SQL::Translator->new({
1315 #      debug => 1,
1316       add_drop_table => 1,
1317   });
1318   foreach my $db (@$databases)
1319   {
1320     $sqlt->reset();
1321     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1322 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1323     $sqlt = $self->configure_sqlt($sqlt, $db);
1324     $sqlt->data($schema);
1325     $sqlt->producer($db);
1326
1327     my $file;
1328     my $filename = $schema->ddl_filename($db, $dir, $version);
1329     if(-e $filename)
1330     {
1331       warn("$filename already exists, skipping $db");
1332       next;
1333     }
1334
1335     my $output = $sqlt->translate;
1336     if(!$output)
1337     {
1338       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1339       next;
1340     }
1341     if(!open($file, ">$filename"))
1342     {
1343         $self->throw_exception("Can't open $filename for writing ($!)");
1344         next;
1345     }
1346     print $file $output;
1347     close($file);
1348
1349     if($preversion)
1350     {
1351       require SQL::Translator::Diff;
1352
1353       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1354 #      print "Previous version $prefilename\n";
1355       if(!-e $prefilename)
1356       {
1357         warn("No previous schema file found ($prefilename)");
1358         next;
1359       }
1360       #### We need to reparse the SQLite file we just wrote, so that
1361       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1362       ##   FIXME: rip Diff to pieces!
1363 #      my $target_schema = $sqlt->schema;
1364 #      unless ( $target_schema->name ) {
1365 #        $target_schema->name( $filename );
1366 #      }
1367       my @input;
1368       push @input, {file => $prefilename, parser => $db};
1369       push @input, {file => $filename, parser => $db};
1370       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1371         my $file   = $_->{'file'};
1372         my $parser = $_->{'parser'};
1373
1374         my $t = SQL::Translator->new;
1375         $t->debug( 0 );
1376         $t->trace( 0 );
1377         $t->parser( $parser )            or die $t->error;
1378         my $out = $t->translate( $file ) or die $t->error;
1379         my $schema = $t->schema;
1380         unless ( $schema->name ) {
1381           $schema->name( $file );
1382         }
1383         ($schema, $parser);
1384       } @input;
1385
1386       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1387                                                     $target_schema, $db,
1388                                                     {}
1389                                                    );
1390       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1391       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1392       if(-e $difffile)
1393       {
1394         warn("$difffile already exists, skipping");
1395         next;
1396       }
1397       if(!open $file, ">$difffile")
1398       {
1399         $self->throw_exception("Can't write to $difffile ($!)");
1400         next;
1401       }
1402       print $file $diff;
1403       close($file);
1404     }
1405   }
1406 }
1407
1408 sub configure_sqlt() {
1409   my $self = shift;
1410   my $tr = shift;
1411   my $db = shift || $self->sqlt_type;
1412   if ($db eq 'PostgreSQL') {
1413     $tr->quote_table_names(0);
1414     $tr->quote_field_names(0);
1415   }
1416   return $tr;
1417 }
1418
1419 =head2 deployment_statements
1420
1421 =over 4
1422
1423 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1424
1425 =back
1426
1427 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1428 The database driver name is given by C<$type>, though the value from
1429 L</sqlt_type> is used if it is not specified.
1430
1431 C<$directory> is used to return statements from files in a previously created
1432 L</create_ddl_dir> directory and is optional. The filenames are constructed
1433 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1434
1435 If no C<$directory> is specified then the statements are constructed on the
1436 fly using L<SQL::Translator> and C<$version> is ignored.
1437
1438 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1439
1440 =cut
1441
1442 sub deployment_statements {
1443   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1444   # Need to be connected to get the correct sqlt_type
1445   $self->ensure_connected() unless $type;
1446   $type ||= $self->sqlt_type;
1447   $version ||= $schema->VERSION || '1.x';
1448   $dir ||= './';
1449   my $filename = $schema->ddl_filename($type, $dir, $version);
1450   if(-f $filename)
1451   {
1452       my $file;
1453       open($file, "<$filename")
1454         or $self->throw_exception("Can't open $filename ($!)");
1455       my @rows = <$file>;
1456       close($file);
1457       return join('', @rows);
1458   }
1459
1460   $self->throw_exception(q{Can't deploy without SQL::Translator 0.08: '}
1461       . $self->_check_sqlt_message . q{'})
1462           if !$self->_check_sqlt_version;
1463
1464   require SQL::Translator::Parser::DBIx::Class;
1465   eval qq{use SQL::Translator::Producer::${type}};
1466   $self->throw_exception($@) if $@;
1467
1468   # sources needs to be a parser arg, but for simplicty allow at top level
1469   # coming in
1470   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1471       if exists $sqltargs->{sources};
1472
1473   my $tr = SQL::Translator->new(%$sqltargs);
1474   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1475   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1476
1477   return;
1478
1479 }
1480
1481 sub deploy {
1482   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1483   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1484     foreach my $line ( split(";\n", $statement)) {
1485       next if($line =~ /^--/);
1486       next if(!$line);
1487 #      next if($line =~ /^DROP/m);
1488       next if($line =~ /^BEGIN TRANSACTION/m);
1489       next if($line =~ /^COMMIT/m);
1490       next if $line =~ /^\s+$/; # skip whitespace only
1491       $self->_query_start($line);
1492       eval {
1493         $self->dbh->do($line); # shouldn't be using ->dbh ?
1494       };
1495       if ($@) {
1496         warn qq{$@ (running "${line}")};
1497       }
1498       $self->_query_end($line);
1499     }
1500   }
1501 }
1502
1503 =head2 datetime_parser
1504
1505 Returns the datetime parser class
1506
1507 =cut
1508
1509 sub datetime_parser {
1510   my $self = shift;
1511   return $self->{datetime_parser} ||= do {
1512     $self->ensure_connected;
1513     $self->build_datetime_parser(@_);
1514   };
1515 }
1516
1517 =head2 datetime_parser_type
1518
1519 Defines (returns) the datetime parser class - currently hardwired to
1520 L<DateTime::Format::MySQL>
1521
1522 =cut
1523
1524 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1525
1526 =head2 build_datetime_parser
1527
1528 See L</datetime_parser>
1529
1530 =cut
1531
1532 sub build_datetime_parser {
1533   my $self = shift;
1534   my $type = $self->datetime_parser_type(@_);
1535   eval "use ${type}";
1536   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1537   return $type;
1538 }
1539
1540 {
1541     my $_check_sqlt_version; # private
1542     my $_check_sqlt_message; # private
1543     sub _check_sqlt_version {
1544         return $_check_sqlt_version if defined $_check_sqlt_version;
1545         eval 'use SQL::Translator 0.08';
1546         $_check_sqlt_message = $@ ? $@ : '';
1547         $_check_sqlt_version = $@ ? 0 : 1;
1548     }
1549
1550     sub _check_sqlt_message {
1551         _check_sqlt_version if !defined $_check_sqlt_message;
1552         $_check_sqlt_message;
1553     }
1554 }
1555
1556 sub DESTROY {
1557   my $self = shift;
1558   return if !$self->_dbh;
1559   $self->_verify_pid;
1560   $self->_dbh(undef);
1561 }
1562
1563 1;
1564
1565 =head1 SQL METHODS
1566
1567 The module defines a set of methods within the DBIC::SQL::Abstract
1568 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1569 SQL query functions.
1570
1571 The following methods are extended:-
1572
1573 =over 4
1574
1575 =item delete
1576
1577 =item insert
1578
1579 =item select
1580
1581 =item update
1582
1583 =item limit_dialect
1584
1585 See L</connect_info> for details.
1586 For setting, this method is deprecated in favor of L</connect_info>.
1587
1588 =item quote_char
1589
1590 See L</connect_info> for details.
1591 For setting, this method is deprecated in favor of L</connect_info>.
1592
1593 =item name_sep
1594
1595 See L</connect_info> for details.
1596 For setting, this method is deprecated in favor of L</connect_info>.
1597
1598 =back
1599
1600 =head1 AUTHORS
1601
1602 Matt S. Trout <mst@shadowcatsystems.co.uk>
1603
1604 Andy Grundman <andy@hybridized.org>
1605
1606 =head1 LICENSE
1607
1608 You may distribute this code under the same terms as Perl itself.
1609
1610 =cut