lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use DBIx::Class::Exception;
  12 use Scalar::Util qw/refaddr weaken reftype blessed/;
  13 use List::Util qw/first/;
  14 use Sub::Name 'subname';
  15 use Context::Preserve 'preserve_context';
  16 use Try::Tiny;
  17 use overload ();
  18 use Data::Compare (); # no imports!!! guard against insane architecture
  19 use DBI::Const::GetInfoType (); # no import of retarded global hash
  20 use namespace::clean;
  21
  22 # default cursor class, overridable in connect_info attributes
  23 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  24
  25 __PACKAGE__->mk_group_accessors('inherited' => qw/
  26   sql_limit_dialect sql_quote_char sql_name_sep
  27 /);
  28
  29 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  30
  31 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  32 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  33
  34 __PACKAGE__->sql_name_sep('.');
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/
  37   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  38   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  39   _perform_autoinc_retrieval _autoinc_supplied_for_op
  40 /);
  41
  42 # the values for these accessors are picked out (and deleted) from
  43 # the attribute hashref passed to connect_info
  44 my @storage_options = qw/
  45   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  46   disable_sth_caching unsafe auto_savepoint
  47 /;
  48 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  49
  50
  51 # capability definitions, using a 2-tiered accessor system
  52 # The rationale is:
  53 #
  54 # A driver/user may define _use_X, which blindly without any checks says:
  55 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  56 # type accessor)
  57 #
  58 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  59 # accessor, which in turn calls _determine_supports_X, and stores the return
  60 # in a special slot on the storage object, which is wiped every time a $dbh
  61 # reconnection takes place (it is not guaranteed that upon reconnection we
  62 # will get the same rdbms version). _determine_supports_X does not need to
  63 # exist on a driver, as we ->can for it before calling.
  64
  65 my @capabilities = (qw/
  66   insert_returning
  67   insert_returning_bound
  68
  69   multicolumn_in
  70
  71   placeholders
  72   typeless_placeholders
  73
  74   join_optimizer
  75 /);
  76 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  77 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  78
  79 # on by default, not strictly a capability (pending rewrite)
  80 __PACKAGE__->_use_join_optimizer (1);
  81 sub _determine_supports_join_optimizer { 1 };
  82
  83 # Each of these methods need _determine_driver called before itself
  84 # in order to function reliably. This is a purely DRY optimization
  85 #
  86 # get_(use)_dbms_capability need to be called on the correct Storage
  87 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  88 # _determine_supports_X which obv. needs a correct driver as well
  89 my @rdbms_specific_methods = qw/
  90   deployment_statements
  91   sqlt_type
  92   sql_maker
  93   build_datetime_parser
  94   datetime_parser_type
  95
  96   txn_begin
  97   insert
  98   insert_bulk
  99   update
 100   delete
 101   select
 102   select_single
 103   with_deferred_fk_checks
 104
 105   get_use_dbms_capability
 106   get_dbms_capability
 107
 108   _server_info
 109   _get_server_version
 110 /;
 111
 112 for my $meth (@rdbms_specific_methods) {
 113
 114   my $orig = __PACKAGE__->can ($meth)
 115     or die "$meth is not a ::Storage::DBI method!";
 116
 117   no strict qw/refs/;
 118   no warnings qw/redefine/;
 119   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 120     if (
 121       # only fire when invoked on an instance, a valid class-based invocation
 122       # would e.g. be setting a default for an inherited accessor
 123       ref $_[0]
 124         and
 125       ! $_[0]->_driver_determined
 126         and
 127       ! $_[0]->{_in_determine_driver}
 128     ) {
 129       $_[0]->_determine_driver;
 130
 131       # This for some reason crashes and burns on perl 5.8.1
 132       # IFF the method ends up throwing an exception
 133       #goto $_[0]->can ($meth);
 134
 135       my $cref = $_[0]->can ($meth);
 136       goto $cref;
 137     }
 138
 139     goto $orig;
 140   };
 141 }
 142
 143 =head1 NAME
 144
 145 DBIx::Class::Storage::DBI - DBI storage handler
 146
 147 =head1 SYNOPSIS
 148
 149   my $schema = MySchema->connect('dbi:SQLite:my.db');
 150
 151   $schema->storage->debug(1);
 152
 153   my @stuff = $schema->storage->dbh_do(
 154     sub {
 155       my ($storage, $dbh, @args) = @_;
 156       $dbh->do("DROP TABLE authors");
 157     },
 158     @column_list
 159   );
 160
 161   $schema->resultset('Book')->search({
 162      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 163   });
 164
 165 =head1 DESCRIPTION
 166
 167 This class represents the connection to an RDBMS via L<DBI>.  See
 168 L<DBIx::Class::Storage> for general information.  This pod only
 169 documents DBI-specific methods and behaviors.
 170
 171 =head1 METHODS
 172
 173 =cut
 174
 175 sub new {
 176   my $new = shift->next::method(@_);
 177
 178   $new->_sql_maker_opts({});
 179   $new->_dbh_details({});
 180   $new->{_in_do_block} = 0;
 181   $new->{_dbh_gen} = 0;
 182
 183   # read below to see what this does
 184   $new->_arm_global_destructor;
 185
 186   $new;
 187 }
 188
 189 # This is hack to work around perl shooting stuff in random
 190 # order on exit(). If we do not walk the remaining storage
 191 # objects in an END block, there is a *small but real* chance
 192 # of a fork()ed child to kill the parent's shared DBI handle,
 193 # *before perl reaches the DESTROY in this package*
 194 # Yes, it is ugly and effective.
 195 # Additionally this registry is used by the CLONE method to
 196 # make sure no handles are shared between threads
 197 {
 198   my %seek_and_destroy;
 199
 200   sub _arm_global_destructor {
 201     my $self = shift;
 202     my $key = refaddr ($self);
 203     $seek_and_destroy{$key} = $self;
 204     weaken ($seek_and_destroy{$key});
 205   }
 206
 207   END {
 208     local $?; # just in case the DBI destructor changes it somehow
 209
 210     # destroy just the object if not native to this process/thread
 211     $_->_verify_pid for (grep
 212       { defined $_ }
 213       values %seek_and_destroy
 214     );
 215   }
 216
 217   sub CLONE {
 218     # As per DBI's recommendation, DBIC disconnects all handles as
 219     # soon as possible (DBIC will reconnect only on demand from within
 220     # the thread)
 221     for (values %seek_and_destroy) {
 222       next unless $_;
 223       $_->{_dbh_gen}++;  # so that existing cursors will drop as well
 224       $_->_dbh(undef);
 225
 226       $_->transaction_depth(0);
 227       $_->savepoints([]);
 228     }
 229   }
 230 }
 231
 232 sub DESTROY {
 233   my $self = shift;
 234
 235   # some databases spew warnings on implicit disconnect
 236   $self->_verify_pid;
 237   local $SIG{__WARN__} = sub {};
 238   $self->_dbh(undef);
 239
 240   # this op is necessary, since the very last perl runtime statement
 241   # triggers a global destruction shootout, and the $SIG localization
 242   # may very well be destroyed before perl actually gets to do the
 243   # $dbh undef
 244   1;
 245 }
 246
 247 # handle pid changes correctly - do not destroy parent's connection
 248 sub _verify_pid {
 249   my $self = shift;
 250
 251   my $pid = $self->_conn_pid;
 252   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 253     $dbh->{InactiveDestroy} = 1;
 254     $self->{_dbh_gen}++;
 255     $self->_dbh(undef);
 256     $self->transaction_depth(0);
 257     $self->savepoints([]);
 258   }
 259
 260   return;
 261 }
 262
 263 =head2 connect_info
 264
 265 This method is normally called by L<DBIx::Class::Schema/connection>, which
 266 encapsulates its argument list in an arrayref before passing them here.
 267
 268 The argument list may contain:
 269
 270 =over
 271
 272 =item *
 273
 274 The same 4-element argument set one would normally pass to
 275 L<DBI/connect>, optionally followed by
 276 L<extra attributes|/DBIx::Class specific connection attributes>
 277 recognized by DBIx::Class:
 278
 279   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 280
 281 =item *
 282
 283 A single code reference which returns a connected
 284 L<DBI database handle|DBI/connect> optionally followed by
 285 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 286 by DBIx::Class:
 287
 288   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 289
 290 =item *
 291
 292 A single hashref with all the attributes and the dsn/user/password
 293 mixed together:
 294
 295   $connect_info_args = [{
 296     dsn => $dsn,
 297     user => $user,
 298     password => $pass,
 299     %dbi_attributes,
 300     %extra_attributes,
 301   }];
 302
 303   $connect_info_args = [{
 304     dbh_maker => sub { DBI->connect (...) },
 305     %dbi_attributes,
 306     %extra_attributes,
 307   }];
 308
 309 This is particularly useful for L<Catalyst> based applications, allowing the
 310 following config (L<Config::General> style):
 311
 312   <Model::DB>
 313     schema_class   App::DB
 314     <connect_info>
 315       dsn          dbi:mysql:database=test
 316       user         testuser
 317       password     TestPass
 318       AutoCommit   1
 319     </connect_info>
 320   </Model::DB>
 321
 322 The C<dsn>/C<user>/C<password> combination can be substituted by the
 323 C<dbh_maker> key whose value is a coderef that returns a connected
 324 L<DBI database handle|DBI/connect>
 325
 326 =back
 327
 328 Please note that the L<DBI> docs recommend that you always explicitly
 329 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 330 recommends that it be set to I<1>, and that you perform transactions
 331 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 332 to I<1> if you do not do explicitly set it to zero.  This is the default
 333 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 334
 335 =head3 DBIx::Class specific connection attributes
 336
 337 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 338 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 339 the following connection options. These options can be mixed in with your other
 340 L<DBI> connection attributes, or placed in a separate hashref
 341 (C<\%extra_attributes>) as shown above.
 342
 343 Every time C<connect_info> is invoked, any previous settings for
 344 these options will be cleared before setting the new ones, regardless of
 345 whether any options are specified in the new C<connect_info>.
 346
 347
 348 =over
 349
 350 =item on_connect_do
 351
 352 Specifies things to do immediately after connecting or re-connecting to
 353 the database.  Its value may contain:
 354
 355 =over
 356
 357 =item a scalar
 358
 359 This contains one SQL statement to execute.
 360
 361 =item an array reference
 362
 363 This contains SQL statements to execute in order.  Each element contains
 364 a string or a code reference that returns a string.
 365
 366 =item a code reference
 367
 368 This contains some code to execute.  Unlike code references within an
 369 array reference, its return value is ignored.
 370
 371 =back
 372
 373 =item on_disconnect_do
 374
 375 Takes arguments in the same form as L</on_connect_do> and executes them
 376 immediately before disconnecting from the database.
 377
 378 Note, this only runs if you explicitly call L</disconnect> on the
 379 storage object.
 380
 381 =item on_connect_call
 382
 383 A more generalized form of L</on_connect_do> that calls the specified
 384 C<connect_call_METHOD> methods in your storage driver.
 385
 386   on_connect_do => 'select 1'
 387
 388 is equivalent to:
 389
 390   on_connect_call => [ [ do_sql => 'select 1' ] ]
 391
 392 Its values may contain:
 393
 394 =over
 395
 396 =item a scalar
 397
 398 Will call the C<connect_call_METHOD> method.
 399
 400 =item a code reference
 401
 402 Will execute C<< $code->($storage) >>
 403
 404 =item an array reference
 405
 406 Each value can be a method name or code reference.
 407
 408 =item an array of arrays
 409
 410 For each array, the first item is taken to be the C<connect_call_> method name
 411 or code reference, and the rest are parameters to it.
 412
 413 =back
 414
 415 Some predefined storage methods you may use:
 416
 417 =over
 418
 419 =item do_sql
 420
 421 Executes a SQL string or a code reference that returns a SQL string. This is
 422 what L</on_connect_do> and L</on_disconnect_do> use.
 423
 424 It can take:
 425
 426 =over
 427
 428 =item a scalar
 429
 430 Will execute the scalar as SQL.
 431
 432 =item an arrayref
 433
 434 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 435 attributes hashref and bind values.
 436
 437 =item a code reference
 438
 439 Will execute C<< $code->($storage) >> and execute the return array refs as
 440 above.
 441
 442 =back
 443
 444 =item datetime_setup
 445
 446 Execute any statements necessary to initialize the database session to return
 447 and accept datetime/timestamp values used with
 448 L<DBIx::Class::InflateColumn::DateTime>.
 449
 450 Only necessary for some databases, see your specific storage driver for
 451 implementation details.
 452
 453 =back
 454
 455 =item on_disconnect_call
 456
 457 Takes arguments in the same form as L</on_connect_call> and executes them
 458 immediately before disconnecting from the database.
 459
 460 Calls the C<disconnect_call_METHOD> methods as opposed to the
 461 C<connect_call_METHOD> methods called by L</on_connect_call>.
 462
 463 Note, this only runs if you explicitly call L</disconnect> on the
 464 storage object.
 465
 466 =item disable_sth_caching
 467
 468 If set to a true value, this option will disable the caching of
 469 statement handles via L<DBI/prepare_cached>.
 470
 471 =item limit_dialect
 472
 473 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 474 default L</sql_limit_dialect> setting of the storage (if any). For a list
 475 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 476
 477 =item quote_names
 478
 479 When true automatically sets L</quote_char> and L</name_sep> to the characters
 480 appropriate for your particular RDBMS. This option is preferred over specifying
 481 L</quote_char> directly.
 482
 483 =item quote_char
 484
 485 Specifies what characters to use to quote table and column names.
 486
 487 C<quote_char> expects either a single character, in which case is it
 488 is placed on either side of the table/column name, or an arrayref of length
 489 2 in which case the table/column name is placed between the elements.
 490
 491 For example under MySQL you should use C<< quote_char => '`' >>, and for
 492 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 493
 494 =item name_sep
 495
 496 This parameter is only useful in conjunction with C<quote_char>, and is used to
 497 specify the character that separates elements (schemas, tables, columns) from
 498 each other. If unspecified it defaults to the most commonly used C<.>.
 499
 500 =item unsafe
 501
 502 This Storage driver normally installs its own C<HandleError>, sets
 503 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 504 all database handles, including those supplied by a coderef.  It does this
 505 so that it can have consistent and useful error behavior.
 506
 507 If you set this option to a true value, Storage will not do its usual
 508 modifications to the database handle's attributes, and instead relies on
 509 the settings in your connect_info DBI options (or the values you set in
 510 your connection coderef, in the case that you are connecting via coderef).
 511
 512 Note that your custom settings can cause Storage to malfunction,
 513 especially if you set a C<HandleError> handler that suppresses exceptions
 514 and/or disable C<RaiseError>.
 515
 516 =item auto_savepoint
 517
 518 If this option is true, L<DBIx::Class> will use savepoints when nesting
 519 transactions, making it possible to recover from failure in the inner
 520 transaction without having to abort all outer transactions.
 521
 522 =item cursor_class
 523
 524 Use this argument to supply a cursor class other than the default
 525 L<DBIx::Class::Storage::DBI::Cursor>.
 526
 527 =back
 528
 529 Some real-life examples of arguments to L</connect_info> and
 530 L<DBIx::Class::Schema/connect>
 531
 532   # Simple SQLite connection
 533   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 534
 535   # Connect via subref
 536   ->connect_info([ sub { DBI->connect(...) } ]);
 537
 538   # Connect via subref in hashref
 539   ->connect_info([{
 540     dbh_maker => sub { DBI->connect(...) },
 541     on_connect_do => 'alter session ...',
 542   }]);
 543
 544   # A bit more complicated
 545   ->connect_info(
 546     [
 547       'dbi:Pg:dbname=foo',
 548       'postgres',
 549       'my_pg_password',
 550       { AutoCommit => 1 },
 551       { quote_char => q{"} },
 552     ]
 553   );
 554
 555   # Equivalent to the previous example
 556   ->connect_info(
 557     [
 558       'dbi:Pg:dbname=foo',
 559       'postgres',
 560       'my_pg_password',
 561       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 562     ]
 563   );
 564
 565   # Same, but with hashref as argument
 566   # See parse_connect_info for explanation
 567   ->connect_info(
 568     [{
 569       dsn         => 'dbi:Pg:dbname=foo',
 570       user        => 'postgres',
 571       password    => 'my_pg_password',
 572       AutoCommit  => 1,
 573       quote_char  => q{"},
 574       name_sep    => q{.},
 575     }]
 576   );
 577
 578   # Subref + DBIx::Class-specific connection options
 579   ->connect_info(
 580     [
 581       sub { DBI->connect(...) },
 582       {
 583           quote_char => q{`},
 584           name_sep => q{@},
 585           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 586           disable_sth_caching => 1,
 587       },
 588     ]
 589   );
 590
 591
 592
 593 =cut
 594
 595 sub connect_info {
 596   my ($self, $info) = @_;
 597
 598   return $self->_connect_info if !$info;
 599
 600   $self->_connect_info($info); # copy for _connect_info
 601
 602   $info = $self->_normalize_connect_info($info)
 603     if ref $info eq 'ARRAY';
 604
 605   for my $storage_opt (keys %{ $info->{storage_options} }) {
 606     my $value = $info->{storage_options}{$storage_opt};
 607
 608     $self->$storage_opt($value);
 609   }
 610
 611   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 612   #  the new set of options
 613   $self->_sql_maker(undef);
 614   $self->_sql_maker_opts({});
 615
 616   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 617     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 618
 619     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 620   }
 621
 622   my %attrs = (
 623     %{ $self->_default_dbi_connect_attributes || {} },
 624     %{ $info->{attributes} || {} },
 625   );
 626
 627   my @args = @{ $info->{arguments} };
 628
 629   if (keys %attrs and ref $args[0] ne 'CODE') {
 630     carp
 631         'You provided explicit AutoCommit => 0 in your connection_info. '
 632       . 'This is almost universally a bad idea (see the footnotes of '
 633       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 634       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 635       . 'this warning.'
 636       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 637
 638     push @args, \%attrs if keys %attrs;
 639   }
 640   $self->_dbi_connect_info(\@args);
 641
 642   # FIXME - dirty:
 643   # save attributes them in a separate accessor so they are always
 644   # introspectable, even in case of a CODE $dbhmaker
 645   $self->_dbic_connect_attributes (\%attrs);
 646
 647   return $self->_connect_info;
 648 }
 649
 650 sub _normalize_connect_info {
 651   my ($self, $info_arg) = @_;
 652   my %info;
 653
 654   my @args = @$info_arg;  # take a shallow copy for further mutilation
 655
 656   # combine/pre-parse arguments depending on invocation style
 657
 658   my %attrs;
 659   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 660     %attrs = %{ $args[1] || {} };
 661     @args = $args[0];
 662   }
 663   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 664     %attrs = %{$args[0]};
 665     @args = ();
 666     if (my $code = delete $attrs{dbh_maker}) {
 667       @args = $code;
 668
 669       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 670       if (@ignored) {
 671         carp sprintf (
 672             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 673           . "to the result of 'dbh_maker'",
 674
 675           join (', ', map { "'$_'" } (@ignored) ),
 676         );
 677       }
 678     }
 679     else {
 680       @args = delete @attrs{qw/dsn user password/};
 681     }
 682   }
 683   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 684     %attrs = (
 685       % { $args[3] || {} },
 686       % { $args[4] || {} },
 687     );
 688     @args = @args[0,1,2];
 689   }
 690
 691   $info{arguments} = \@args;
 692
 693   my @storage_opts = grep exists $attrs{$_},
 694     @storage_options, 'cursor_class';
 695
 696   @{ $info{storage_options} }{@storage_opts} =
 697     delete @attrs{@storage_opts} if @storage_opts;
 698
 699   my @sql_maker_opts = grep exists $attrs{$_},
 700     qw/limit_dialect quote_char name_sep quote_names/;
 701
 702   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 703     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 704
 705   $info{attributes} = \%attrs if %attrs;
 706
 707   return \%info;
 708 }
 709
 710 sub _default_dbi_connect_attributes () {
 711   +{
 712     AutoCommit => 1,
 713     PrintError => 0,
 714     RaiseError => 1,
 715     ShowErrorStatement => 1,
 716   };
 717 }
 718
 719 =head2 on_connect_do
 720
 721 This method is deprecated in favour of setting via L</connect_info>.
 722
 723 =cut
 724
 725 =head2 on_disconnect_do
 726
 727 This method is deprecated in favour of setting via L</connect_info>.
 728
 729 =cut
 730
 731 sub _parse_connect_do {
 732   my ($self, $type) = @_;
 733
 734   my $val = $self->$type;
 735   return () if not defined $val;
 736
 737   my @res;
 738
 739   if (not ref($val)) {
 740     push @res, [ 'do_sql', $val ];
 741   } elsif (ref($val) eq 'CODE') {
 742     push @res, $val;
 743   } elsif (ref($val) eq 'ARRAY') {
 744     push @res, map { [ 'do_sql', $_ ] } @$val;
 745   } else {
 746     $self->throw_exception("Invalid type for $type: ".ref($val));
 747   }
 748
 749   return \@res;
 750 }
 751
 752 =head2 dbh_do
 753
 754 Arguments: ($subref | $method_name), @extra_coderef_args?
 755
 756 Execute the given $subref or $method_name using the new exception-based
 757 connection management.
 758
 759 The first two arguments will be the storage object that C<dbh_do> was called
 760 on and a database handle to use.  Any additional arguments will be passed
 761 verbatim to the called subref as arguments 2 and onwards.
 762
 763 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 764 exception handling and reconnection (or failover in future subclasses).
 765
 766 Your subref should have no side-effects outside of the database, as
 767 there is the potential for your subref to be partially double-executed
 768 if the database connection was stale/dysfunctional.
 769
 770 Example:
 771
 772   my @stuff = $schema->storage->dbh_do(
 773     sub {
 774       my ($storage, $dbh, @cols) = @_;
 775       my $cols = join(q{, }, @cols);
 776       $dbh->selectrow_array("SELECT $cols FROM foo");
 777     },
 778     @column_list
 779   );
 780
 781 =cut
 782
 783 sub dbh_do {
 784   my $self = shift;
 785   my $run_target = shift;
 786
 787   # short circuit when we know there is no need for a runner
 788   #
 789   # FIXME - asumption may be wrong
 790   # the rationale for the txn_depth check is that if this block is a part
 791   # of a larger transaction, everything up to that point is screwed anyway
 792   return $self->$run_target($self->_get_dbh, @_)
 793     if $self->{_in_do_block} or $self->transaction_depth;
 794
 795   my $args = \@_;
 796
 797   DBIx::Class::Storage::BlockRunner->new(
 798     storage => $self,
 799     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 800     wrap_txn => 0,
 801     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 802   )->run;
 803 }
 804
 805 sub txn_do {
 806   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 807   shift->next::method(@_);
 808 }
 809
 810 =head2 disconnect
 811
 812 Our C<disconnect> method also performs a rollback first if the
 813 database is not in C<AutoCommit> mode.
 814
 815 =cut
 816
 817 sub disconnect {
 818   my ($self) = @_;
 819
 820   if( $self->_dbh ) {
 821     my @actions;
 822
 823     push @actions, ( $self->on_disconnect_call || () );
 824     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 825
 826     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 827
 828     # stops the "implicit rollback on disconnect" warning
 829     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 830
 831     %{ $self->_dbh->{CachedKids} } = ();
 832     $self->_dbh->disconnect;
 833     $self->_dbh(undef);
 834     $self->{_dbh_gen}++;
 835   }
 836 }
 837
 838 =head2 with_deferred_fk_checks
 839
 840 =over 4
 841
 842 =item Arguments: C<$coderef>
 843
 844 =item Return Value: The return value of $coderef
 845
 846 =back
 847
 848 Storage specific method to run the code ref with FK checks deferred or
 849 in MySQL's case disabled entirely.
 850
 851 =cut
 852
 853 # Storage subclasses should override this
 854 sub with_deferred_fk_checks {
 855   my ($self, $sub) = @_;
 856   $sub->();
 857 }
 858
 859 =head2 connected
 860
 861 =over
 862
 863 =item Arguments: none
 864
 865 =item Return Value: 1|0
 866
 867 =back
 868
 869 Verifies that the current database handle is active and ready to execute
 870 an SQL statement (e.g. the connection did not get stale, server is still
 871 answering, etc.) This method is used internally by L</dbh>.
 872
 873 =cut
 874
 875 sub connected {
 876   my $self = shift;
 877   return 0 unless $self->_seems_connected;
 878
 879   #be on the safe side
 880   local $self->_dbh->{RaiseError} = 1;
 881
 882   return $self->_ping;
 883 }
 884
 885 sub _seems_connected {
 886   my $self = shift;
 887
 888   $self->_verify_pid;
 889
 890   my $dbh = $self->_dbh
 891     or return 0;
 892
 893   return $dbh->FETCH('Active');
 894 }
 895
 896 sub _ping {
 897   my $self = shift;
 898
 899   my $dbh = $self->_dbh or return 0;
 900
 901   return $dbh->ping;
 902 }
 903
 904 sub ensure_connected {
 905   my ($self) = @_;
 906
 907   unless ($self->connected) {
 908     $self->_populate_dbh;
 909   }
 910 }
 911
 912 =head2 dbh
 913
 914 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 915 is guaranteed to be healthy by implicitly calling L</connected>, and if
 916 necessary performing a reconnection before returning. Keep in mind that this
 917 is very B<expensive> on some database engines. Consider using L</dbh_do>
 918 instead.
 919
 920 =cut
 921
 922 sub dbh {
 923   my ($self) = @_;
 924
 925   if (not $self->_dbh) {
 926     $self->_populate_dbh;
 927   } else {
 928     $self->ensure_connected;
 929   }
 930   return $self->_dbh;
 931 }
 932
 933 # this is the internal "get dbh or connect (don't check)" method
 934 sub _get_dbh {
 935   my $self = shift;
 936   $self->_verify_pid;
 937   $self->_populate_dbh unless $self->_dbh;
 938   return $self->_dbh;
 939 }
 940
 941 sub sql_maker {
 942   my ($self) = @_;
 943   unless ($self->_sql_maker) {
 944     my $sql_maker_class = $self->sql_maker_class;
 945
 946     my %opts = %{$self->_sql_maker_opts||{}};
 947     my $dialect =
 948       $opts{limit_dialect}
 949         ||
 950       $self->sql_limit_dialect
 951         ||
 952       do {
 953         my $s_class = (ref $self) || $self;
 954         carp (
 955           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 956         . 'have not supplied an explicit limit_dialect in your connection_info. '
 957         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 958         . 'databases but can be (and often is) painfully slow. '
 959         . "Please file an RT ticket against '$s_class' ."
 960         );
 961
 962         'GenericSubQ';
 963       }
 964     ;
 965
 966     my ($quote_char, $name_sep);
 967
 968     if ($opts{quote_names}) {
 969       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 970         my $s_class = (ref $self) || $self;
 971         carp (
 972           "You requested 'quote_names' but your storage class ($s_class) does "
 973         . 'not explicitly define a default sql_quote_char and you have not '
 974         . 'supplied a quote_char as part of your connection_info. DBIC will '
 975         .q{default to the ANSI SQL standard quote '"', which works most of }
 976         . "the time. Please file an RT ticket against '$s_class'."
 977         );
 978
 979         '"'; # RV
 980       };
 981
 982       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 983     }
 984
 985     $self->_sql_maker($sql_maker_class->new(
 986       bindtype=>'columns',
 987       array_datatypes => 1,
 988       limit_dialect => $dialect,
 989       ($quote_char ? (quote_char => $quote_char) : ()),
 990       name_sep => ($name_sep || '.'),
 991       %opts,
 992     ));
 993   }
 994   return $self->_sql_maker;
 995 }
 996
 997 # nothing to do by default
 998 sub _rebless {}
 999 sub _init {}
1000
1001 sub _populate_dbh {
1002   my ($self) = @_;
1003
1004   my @info = @{$self->_dbi_connect_info || []};
1005   $self->_dbh(undef); # in case ->connected failed we might get sent here
1006   $self->_dbh_details({}); # reset everything we know
1007
1008   $self->_dbh($self->_connect(@info));
1009
1010   $self->_conn_pid($$) if $^O ne 'MSWin32'; # on win32 these are in fact threads
1011
1012   $self->_determine_driver;
1013
1014   # Always set the transaction depth on connect, since
1015   #  there is no transaction in progress by definition
1016   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1017
1018   $self->_run_connection_actions unless $self->{_in_determine_driver};
1019 }
1020
1021 sub _run_connection_actions {
1022   my $self = shift;
1023   my @actions;
1024
1025   push @actions, ( $self->on_connect_call || () );
1026   push @actions, $self->_parse_connect_do ('on_connect_do');
1027
1028   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1029 }
1030
1031
1032
1033 sub set_use_dbms_capability {
1034   $_[0]->set_inherited ($_[1], $_[2]);
1035 }
1036
1037 sub get_use_dbms_capability {
1038   my ($self, $capname) = @_;
1039
1040   my $use = $self->get_inherited ($capname);
1041   return defined $use
1042     ? $use
1043     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1044   ;
1045 }
1046
1047 sub set_dbms_capability {
1048   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1049 }
1050
1051 sub get_dbms_capability {
1052   my ($self, $capname) = @_;
1053
1054   my $cap = $self->_dbh_details->{capability}{$capname};
1055
1056   unless (defined $cap) {
1057     if (my $meth = $self->can ("_determine$capname")) {
1058       $cap = $self->$meth ? 1 : 0;
1059     }
1060     else {
1061       $cap = 0;
1062     }
1063
1064     $self->set_dbms_capability ($capname, $cap);
1065   }
1066
1067   return $cap;
1068 }
1069
1070 sub _server_info {
1071   my $self = shift;
1072
1073   my $info;
1074   unless ($info = $self->_dbh_details->{info}) {
1075
1076     $info = {};
1077
1078     my $server_version = try { $self->_get_server_version };
1079
1080     if (defined $server_version) {
1081       $info->{dbms_version} = $server_version;
1082
1083       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1084       my @verparts = split (/\./, $numeric_version);
1085       if (
1086         @verparts
1087           &&
1088         $verparts[0] <= 999
1089       ) {
1090         # consider only up to 3 version parts, iff not more than 3 digits
1091         my @use_parts;
1092         while (@verparts && @use_parts < 3) {
1093           my $p = shift @verparts;
1094           last if $p > 999;
1095           push @use_parts, $p;
1096         }
1097         push @use_parts, 0 while @use_parts < 3;
1098
1099         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1100       }
1101     }
1102
1103     $self->_dbh_details->{info} = $info;
1104   }
1105
1106   return $info;
1107 }
1108
1109 sub _get_server_version {
1110   shift->_dbh_get_info('SQL_DBMS_VER');
1111 }
1112
1113 sub _dbh_get_info {
1114   my ($self, $info) = @_;
1115
1116   if ($info =~ /[^0-9]/) {
1117     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1118     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1119       unless defined $info;
1120   }
1121
1122   return try { $self->_get_dbh->get_info($info) } || undef;
1123 }
1124
1125 sub _determine_driver {
1126   my ($self) = @_;
1127
1128   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1129     my $started_connected = 0;
1130     local $self->{_in_determine_driver} = 1;
1131
1132     if (ref($self) eq __PACKAGE__) {
1133       my $driver;
1134       if ($self->_dbh) { # we are connected
1135         $driver = $self->_dbh->{Driver}{Name};
1136         $started_connected = 1;
1137       } else {
1138         # if connect_info is a CODEREF, we have no choice but to connect
1139         if (ref $self->_dbi_connect_info->[0] &&
1140             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1141           $self->_populate_dbh;
1142           $driver = $self->_dbh->{Driver}{Name};
1143         }
1144         else {
1145           # try to use dsn to not require being connected, the driver may still
1146           # force a connection in _rebless to determine version
1147           # (dsn may not be supplied at all if all we do is make a mock-schema)
1148           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1149           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1150           $driver ||= $ENV{DBI_DRIVER};
1151         }
1152       }
1153
1154       if ($driver) {
1155         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1156         if ($self->load_optional_class($storage_class)) {
1157           mro::set_mro($storage_class, 'c3');
1158           bless $self, $storage_class;
1159           $self->_rebless();
1160         }
1161       }
1162     }
1163
1164     $self->_driver_determined(1);
1165
1166     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1167
1168     $self->_init; # run driver-specific initializations
1169
1170     $self->_run_connection_actions
1171         if !$started_connected && defined $self->_dbh;
1172   }
1173 }
1174
1175 sub _do_connection_actions {
1176   my $self          = shift;
1177   my $method_prefix = shift;
1178   my $call          = shift;
1179
1180   if (not ref($call)) {
1181     my $method = $method_prefix . $call;
1182     $self->$method(@_);
1183   } elsif (ref($call) eq 'CODE') {
1184     $self->$call(@_);
1185   } elsif (ref($call) eq 'ARRAY') {
1186     if (ref($call->[0]) ne 'ARRAY') {
1187       $self->_do_connection_actions($method_prefix, $_) for @$call;
1188     } else {
1189       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1190     }
1191   } else {
1192     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1193   }
1194
1195   return $self;
1196 }
1197
1198 sub connect_call_do_sql {
1199   my $self = shift;
1200   $self->_do_query(@_);
1201 }
1202
1203 sub disconnect_call_do_sql {
1204   my $self = shift;
1205   $self->_do_query(@_);
1206 }
1207
1208 # override in db-specific backend when necessary
1209 sub connect_call_datetime_setup { 1 }
1210
1211 sub _do_query {
1212   my ($self, $action) = @_;
1213
1214   if (ref $action eq 'CODE') {
1215     $action = $action->($self);
1216     $self->_do_query($_) foreach @$action;
1217   }
1218   else {
1219     # Most debuggers expect ($sql, @bind), so we need to exclude
1220     # the attribute hash which is the second argument to $dbh->do
1221     # furthermore the bind values are usually to be presented
1222     # as named arrayref pairs, so wrap those here too
1223     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1224     my $sql = shift @do_args;
1225     my $attrs = shift @do_args;
1226     my @bind = map { [ undef, $_ ] } @do_args;
1227
1228     $self->dbh_do(sub {
1229       $_[0]->_query_start($sql, \@bind);
1230       $_[1]->do($sql, $attrs, @do_args);
1231       $_[0]->_query_end($sql, \@bind);
1232     });
1233   }
1234
1235   return $self;
1236 }
1237
1238 sub _connect {
1239   my ($self, @info) = @_;
1240
1241   $self->throw_exception("You failed to provide any connection info")
1242     if !@info;
1243
1244   my ($old_connect_via, $dbh);
1245
1246   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1247
1248   try {
1249     if(ref $info[0] eq 'CODE') {
1250       $dbh = $info[0]->();
1251     }
1252     else {
1253       require DBI;
1254       $dbh = DBI->connect(@info);
1255     }
1256
1257     if (!$dbh) {
1258       die $DBI::errstr;
1259     }
1260
1261     unless ($self->unsafe) {
1262
1263       $self->throw_exception(
1264         'Refusing clobbering of {HandleError} installed on externally supplied '
1265        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1266       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1267
1268       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1269       # request, or an external handle. Complain and set anyway
1270       unless ($dbh->{RaiseError}) {
1271         carp( ref $info[0] eq 'CODE'
1272
1273           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1274            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1275            .'attribute has been supplied'
1276
1277           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1278            .'unsafe => 1. Toggling RaiseError back to true'
1279         );
1280
1281         $dbh->{RaiseError} = 1;
1282       }
1283
1284       # this odd anonymous coderef dereference is in fact really
1285       # necessary to avoid the unwanted effect described in perl5
1286       # RT#75792
1287       sub {
1288         my $weak_self = $_[0];
1289         weaken $weak_self;
1290
1291         # the coderef is blessed so we can distinguish it from externally
1292         # supplied handles (which must be preserved)
1293         $_[1]->{HandleError} = bless sub {
1294           if ($weak_self) {
1295             $weak_self->throw_exception("DBI Exception: $_[0]");
1296           }
1297           else {
1298             # the handler may be invoked by something totally out of
1299             # the scope of DBIC
1300             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1301           }
1302         }, '__DBIC__DBH__ERROR__HANDLER__';
1303       }->($self, $dbh);
1304     }
1305   }
1306   catch {
1307     $self->throw_exception("DBI Connection failed: $_")
1308   };
1309
1310   $self->_dbh_autocommit($dbh->{AutoCommit});
1311   $dbh;
1312 }
1313
1314 sub txn_begin {
1315   my $self = shift;
1316
1317   # this means we have not yet connected and do not know the AC status
1318   # (e.g. coderef $dbh), need a full-fledged connection check
1319   if (! defined $self->_dbh_autocommit) {
1320     $self->ensure_connected;
1321   }
1322   # Otherwise simply connect or re-connect on pid changes
1323   else {
1324     $self->_get_dbh;
1325   }
1326
1327   $self->next::method(@_);
1328 }
1329
1330 sub _exec_txn_begin {
1331   my $self = shift;
1332
1333   # if the user is utilizing txn_do - good for him, otherwise we need to
1334   # ensure that the $dbh is healthy on BEGIN.
1335   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1336   # will be replaced by a failure of begin_work itself (which will be
1337   # then retried on reconnect)
1338   if ($self->{_in_do_block}) {
1339     $self->_dbh->begin_work;
1340   } else {
1341     $self->dbh_do(sub { $_[1]->begin_work });
1342   }
1343 }
1344
1345 sub txn_commit {
1346   my $self = shift;
1347
1348   $self->_verify_pid if $self->_dbh;
1349   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1350     unless $self->_dbh;
1351
1352   # esoteric case for folks using external $dbh handles
1353   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1354     carp "Storage transaction_depth 0 does not match "
1355         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1356     $self->transaction_depth(1);
1357   }
1358
1359   $self->next::method(@_);
1360
1361   # if AutoCommit is disabled txn_depth never goes to 0
1362   # as a new txn is started immediately on commit
1363   $self->transaction_depth(1) if (
1364     !$self->transaction_depth
1365       and
1366     defined $self->_dbh_autocommit
1367       and
1368     ! $self->_dbh_autocommit
1369   );
1370 }
1371
1372 sub _exec_txn_commit {
1373   shift->_dbh->commit;
1374 }
1375
1376 sub txn_rollback {
1377   my $self = shift;
1378
1379   $self->_verify_pid if $self->_dbh;
1380   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1381     unless $self->_dbh;
1382
1383   # esoteric case for folks using external $dbh handles
1384   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1385     carp "Storage transaction_depth 0 does not match "
1386         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1387     $self->transaction_depth(1);
1388   }
1389
1390   $self->next::method(@_);
1391
1392   # if AutoCommit is disabled txn_depth never goes to 0
1393   # as a new txn is started immediately on commit
1394   $self->transaction_depth(1) if (
1395     !$self->transaction_depth
1396       and
1397     defined $self->_dbh_autocommit
1398       and
1399     ! $self->_dbh_autocommit
1400   );
1401 }
1402
1403 sub _exec_txn_rollback {
1404   shift->_dbh->rollback;
1405 }
1406
1407 # generate some identical methods
1408 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1409   no strict qw/refs/;
1410   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1411     my $self = shift;
1412     $self->_verify_pid if $self->_dbh;
1413     $self->throw_exception("Unable to $meth() on a disconnected storage")
1414       unless $self->_dbh;
1415     $self->next::method(@_);
1416   };
1417 }
1418
1419 # This used to be the top-half of _execute.  It was split out to make it
1420 #  easier to override in NoBindVars without duping the rest.  It takes up
1421 #  all of _execute's args, and emits $sql, @bind.
1422 sub _prep_for_execute {
1423   #my ($self, $op, $ident, $args) = @_;
1424   return shift->_gen_sql_bind(@_)
1425 }
1426
1427 sub _gen_sql_bind {
1428   my ($self, $op, $ident, $args) = @_;
1429
1430   my ($sql, @bind) = $self->sql_maker->$op(
1431     blessed($ident) ? $ident->from : $ident,
1432     @$args,
1433   );
1434
1435   if (
1436     ! $ENV{DBIC_DT_SEARCH_OK}
1437       and
1438     $op eq 'select'
1439       and
1440     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1441   ) {
1442     carp_unique 'DateTime objects passed to search() are not supported '
1443       . 'properly (InflateColumn::DateTime formats and settings are not '
1444       . 'respected.) See "Formatting DateTime objects in queries" in '
1445       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1446       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1447   }
1448
1449   return( $sql, $self->_resolve_bindattrs(
1450     $ident, [ @{$args->[2]{bind}||[]}, @bind ]
1451   ));
1452 }
1453
1454 sub _resolve_bindattrs {
1455   my ($self, $ident, $bind, $colinfos) = @_;
1456
1457   $colinfos ||= {};
1458
1459   my $resolve_bindinfo = sub {
1460     #my $infohash = shift;
1461
1462     %$colinfos = %{ $self->_resolve_column_info($ident) }
1463       unless keys %$colinfos;
1464
1465     my $ret;
1466     if (my $col = $_[0]->{dbic_colname}) {
1467       $ret = { %{$_[0]} };
1468
1469       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1470         if $colinfos->{$col}{data_type};
1471
1472       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1473         if $colinfos->{$col}{size};
1474     }
1475
1476     $ret || $_[0];
1477   };
1478
1479   return [ map {
1480     if (ref $_ ne 'ARRAY') {
1481       [{}, $_]
1482     }
1483     elsif (! defined $_->[0]) {
1484       [{}, $_->[1]]
1485     }
1486     elsif (ref $_->[0] eq 'HASH') {
1487       [
1488         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1489         $_->[1]
1490       ]
1491     }
1492     elsif (ref $_->[0] eq 'SCALAR') {
1493       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1494     }
1495     else {
1496       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1497     }
1498   } @$bind ];
1499 }
1500
1501 sub _format_for_trace {
1502   #my ($self, $bind) = @_;
1503
1504   ### Turn @bind from something like this:
1505   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1506   ### to this:
1507   ###   ( "'1'", "'3'" )
1508
1509   map {
1510     defined( $_ && $_->[1] )
1511       ? qq{'$_->[1]'}
1512       : q{NULL}
1513   } @{$_[1] || []};
1514 }
1515
1516 sub _query_start {
1517   my ( $self, $sql, $bind ) = @_;
1518
1519   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1520     if $self->debug;
1521 }
1522
1523 sub _query_end {
1524   my ( $self, $sql, $bind ) = @_;
1525
1526   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1527     if $self->debug;
1528 }
1529
1530 my $sba_compat;
1531 sub _dbi_attrs_for_bind {
1532   my ($self, $ident, $bind) = @_;
1533
1534   if (! defined $sba_compat) {
1535     $self->_determine_driver;
1536     $sba_compat = $self->can('source_bind_attributes') == \&source_bind_attributes
1537       ? 0
1538       : 1
1539     ;
1540   }
1541
1542   my $sba_attrs;
1543   if ($sba_compat) {
1544     my $class = ref $self;
1545     carp_unique (
1546       "The source_bind_attributes() override in $class relies on a deprecated codepath. "
1547      .'You are strongly advised to switch your code to override bind_attribute_by_datatype() '
1548      .'instead. This legacy compat shim will also disappear some time before DBIC 0.09'
1549     );
1550
1551     my $sba_attrs = $self->source_bind_attributes
1552   }
1553
1554   my @attrs;
1555
1556   for (map { $_->[0] } @$bind) {
1557     push @attrs, do {
1558       if (exists $_->{dbd_attrs}) {
1559         $_->{dbd_attrs}
1560       }
1561       elsif($_->{sqlt_datatype}) {
1562         # cache the result in the dbh_details hash, as it can not change unless
1563         # we connect to something else
1564         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1565         if (not exists $cache->{$_->{sqlt_datatype}}) {
1566           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1567         }
1568         $cache->{$_->{sqlt_datatype}};
1569       }
1570       elsif ($sba_attrs and $_->{dbic_colname}) {
1571         $sba_attrs->{$_->{dbic_colname}} || undef;
1572       }
1573       else {
1574         undef;  # always push something at this position
1575       }
1576     }
1577   }
1578
1579   return \@attrs;
1580 }
1581
1582 sub _execute {
1583   my ($self, $op, $ident, @args) = @_;
1584
1585   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1586
1587   shift->dbh_do(    # retry over disconnects
1588     '_dbh_execute',
1589     $sql,
1590     $bind,
1591     $self->_dbi_attrs_for_bind($ident, $bind)
1592   );
1593 }
1594
1595 sub _dbh_execute {
1596   my ($self, undef, $sql, $bind, $bind_attrs) = @_;
1597
1598   $self->_query_start( $sql, $bind );
1599   my $sth = $self->_sth($sql);
1600
1601   for my $i (0 .. $#$bind) {
1602     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1603       $sth->bind_param_inout(
1604         $i + 1, # bind params counts are 1-based
1605         $bind->[$i][1],
1606         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1607         $bind_attrs->[$i],
1608       );
1609     }
1610     else {
1611       $sth->bind_param(
1612         $i + 1,
1613         (ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""'))
1614           ? "$bind->[$i][1]"
1615           : $bind->[$i][1]
1616         ,
1617         $bind_attrs->[$i],
1618       );
1619     }
1620   }
1621
1622   # Can this fail without throwing an exception anyways???
1623   my $rv = $sth->execute();
1624   $self->throw_exception(
1625     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1626   ) if !$rv;
1627
1628   $self->_query_end( $sql, $bind );
1629
1630   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1631 }
1632
1633 sub _prefetch_autovalues {
1634   my ($self, $source, $to_insert) = @_;
1635
1636   my $colinfo = $source->columns_info;
1637
1638   my %values;
1639   for my $col (keys %$colinfo) {
1640     if (
1641       $colinfo->{$col}{auto_nextval}
1642         and
1643       (
1644         ! exists $to_insert->{$col}
1645           or
1646         ref $to_insert->{$col} eq 'SCALAR'
1647           or
1648         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1649       )
1650     ) {
1651       $values{$col} = $self->_sequence_fetch(
1652         'NEXTVAL',
1653         ( $colinfo->{$col}{sequence} ||=
1654             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1655         ),
1656       );
1657     }
1658   }
1659
1660   \%values;
1661 }
1662
1663 sub insert {
1664   my ($self, $source, $to_insert) = @_;
1665
1666   my $prefetched_values = $self->_prefetch_autovalues($source, $to_insert);
1667
1668   # fuse the values, but keep a separate list of prefetched_values so that
1669   # they can be fused once again with the final return
1670   $to_insert = { %$to_insert, %$prefetched_values };
1671
1672   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1673   # Investigate what does it take to s/defined/exists/
1674   my $col_infos = $source->columns_info;
1675   my %pcols = map { $_ => 1 } $source->primary_columns;
1676   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1677   for my $col ($source->columns) {
1678     if ($col_infos->{$col}{is_auto_increment}) {
1679       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1680       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1681     }
1682
1683     # nothing to retrieve when explicit values are supplied
1684     next if (defined $to_insert->{$col} and ! (
1685       ref $to_insert->{$col} eq 'SCALAR'
1686         or
1687       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1688     ));
1689
1690     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1691     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1692       $pcols{$col}
1693         or
1694       $col_infos->{$col}{retrieve_on_insert}
1695     );
1696   };
1697
1698   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1699   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1700
1701   my ($sqla_opts, @ir_container);
1702   if (%retrieve_cols and $self->_use_insert_returning) {
1703     $sqla_opts->{returning_container} = \@ir_container
1704       if $self->_use_insert_returning_bound;
1705
1706     $sqla_opts->{returning} = [
1707       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1708     ];
1709   }
1710
1711   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1712
1713   my %returned_cols = %$to_insert;
1714   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1715     @ir_container = try {
1716       local $SIG{__WARN__} = sub {};
1717       my @r = $sth->fetchrow_array;
1718       $sth->finish;
1719       @r;
1720     } unless @ir_container;
1721
1722     @returned_cols{@$retlist} = @ir_container if @ir_container;
1723   }
1724   else {
1725     # pull in PK if needed and then everything else
1726     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1727
1728       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1729         unless $self->can('last_insert_id');
1730
1731       my @pri_values = $self->last_insert_id($source, @missing_pri);
1732
1733       $self->throw_exception( "Can't get last insert id" )
1734         unless (@pri_values == @missing_pri);
1735
1736       @returned_cols{@missing_pri} = @pri_values;
1737       delete $retrieve_cols{$_} for @missing_pri;
1738     }
1739
1740     # if there is more left to pull
1741     if (%retrieve_cols) {
1742       $self->throw_exception(
1743         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1744       ) unless %pcols;
1745
1746       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1747
1748       my $cur = DBIx::Class::ResultSet->new($source, {
1749         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1750         select => \@left_to_fetch,
1751       })->cursor;
1752
1753       @returned_cols{@left_to_fetch} = $cur->next;
1754
1755       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1756         if scalar $cur->next;
1757     }
1758   }
1759
1760   return { %$prefetched_values, %returned_cols };
1761 }
1762
1763 sub insert_bulk {
1764   my ($self, $source, $cols, $data) = @_;
1765
1766   my @col_range = (0..$#$cols);
1767
1768   # FIXME - perhaps this is not even needed? does DBI stringify?
1769   #
1770   # forcibly stringify whatever is stringifiable
1771   # ResultSet::populate() hands us a copy - safe to mangle
1772   for my $r (0 .. $#$data) {
1773     for my $c (0 .. $#{$data->[$r]}) {
1774       $data->[$r][$c] = "$data->[$r][$c]"
1775         if ( ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1776     }
1777   }
1778
1779   my $colinfos = $source->columns_info($cols);
1780
1781   local $self->{_autoinc_supplied_for_op} =
1782     (first { $_->{is_auto_increment} } values %$colinfos)
1783       ? 1
1784       : 0
1785   ;
1786
1787   # get a slice type index based on first row of data
1788   # a "column" in this context may refer to more than one bind value
1789   # e.g. \[ '?, ?', [...], [...] ]
1790   #
1791   # construct the value type index - a description of values types for every
1792   # per-column slice of $data:
1793   #
1794   # nonexistent - nonbind literal
1795   # 0 - regular value
1796   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1797   #
1798   # also construct the column hash to pass to the SQL generator. For plain
1799   # (non literal) values - convert the members of the first row into a
1800   # literal+bind combo, with extra positional info in the bind attr hashref.
1801   # This will allow us to match the order properly, and is so contrived
1802   # because a user-supplied literal/bind (or something else specific to a
1803   # resultsource and/or storage driver) can inject extra binds along the
1804   # way, so one can't rely on "shift positions" ordering at all. Also we
1805   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1806   # can be later matched up by address), because we want to supply a real
1807   # value on which perhaps e.g. datatype checks will be performed
1808   my ($proto_data, $value_type_idx);
1809   for my $i (@col_range) {
1810     my $colname = $cols->[$i];
1811     if (ref $data->[0][$i] eq 'SCALAR') {
1812       # no bind value at all - no type
1813
1814       $proto_data->{$colname} = $data->[0][$i];
1815     }
1816     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1817       # repack, so we don't end up mangling the original \[]
1818       my ($sql, @bind) = @${$data->[0][$i]};
1819
1820       # normalization of user supplied stuff
1821       my $resolved_bind = $self->_resolve_bindattrs(
1822         $source, \@bind, $colinfos,
1823       );
1824
1825       # store value-less (attrs only) bind info - we will be comparing all
1826       # supplied binds against this for sanity
1827       $value_type_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1828
1829       $proto_data->{$colname} = \[ $sql, map { [
1830         # inject slice order to use for $proto_bind construction
1831           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i }
1832             =>
1833           $resolved_bind->[$_][1]
1834         ] } (0 .. $#bind)
1835       ];
1836     }
1837     else {
1838       $value_type_idx->{$i} = 0;
1839
1840       $proto_data->{$colname} = \[ '?', [
1841         { dbic_colname => $colname, _bind_data_slice_idx => $i }
1842           =>
1843         $data->[0][$i]
1844       ] ];
1845     }
1846   }
1847
1848   my ($sql, $proto_bind) = $self->_prep_for_execute (
1849     'insert',
1850     $source,
1851     [ $proto_data ],
1852   );
1853
1854   if (! @$proto_bind and keys %$value_type_idx) {
1855     # if the bindlist is empty and we had some dynamic binds, this means the
1856     # storage ate them away (e.g. the NoBindVars component) and interpolated
1857     # them directly into the SQL. This obviously can't be good for multi-inserts
1858     $self->throw_exception('Cannot insert_bulk without support for placeholders');
1859   }
1860
1861   # sanity checks
1862   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
1863   #
1864   # use an error reporting closure for convenience (less to pass)
1865   my $bad_slice_report_cref = sub {
1866     my ($msg, $r_idx, $c_idx) = @_;
1867     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1868       $msg,
1869       $cols->[$c_idx],
1870       do {
1871         require Data::Dumper::Concise;
1872         local $Data::Dumper::Maxdepth = 5;
1873         Data::Dumper::Concise::Dumper ({
1874           map { $cols->[$_] =>
1875             $data->[$r_idx][$_]
1876           } @col_range
1877         }),
1878       }
1879     );
1880   };
1881
1882   for my $col_idx (@col_range) {
1883     my $reference_val = $data->[0][$col_idx];
1884
1885     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
1886       my $val = $data->[$row_idx][$col_idx];
1887
1888       if (! exists $value_type_idx->{$col_idx}) { # literal no binds
1889         if (ref $val ne 'SCALAR') {
1890           $bad_slice_report_cref->(
1891             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
1892             $row_idx,
1893             $col_idx,
1894           );
1895         }
1896         elsif ($$val ne $$reference_val) {
1897           $bad_slice_report_cref->(
1898             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
1899             $row_idx,
1900             $col_idx,
1901           );
1902         }
1903       }
1904       elsif (! $value_type_idx->{$col_idx} ) {  # regular non-literal value
1905         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
1906           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
1907         }
1908       }
1909       else {  # binds from a \[], compare type and attrs
1910         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
1911           $bad_slice_report_cref->(
1912             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
1913             $row_idx,
1914             $col_idx,
1915           );
1916         }
1917         # start drilling down and bail out early on identical refs
1918         elsif (
1919           $reference_val != $val
1920             or
1921           $$reference_val != $$val
1922         ) {
1923           if (${$val}->[0] ne ${$reference_val}->[0]) {
1924             $bad_slice_report_cref->(
1925               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
1926               $row_idx,
1927               $col_idx,
1928             );
1929           }
1930           # need to check the bind attrs - a bind will happen only once for
1931           # the entire dataset, so any changes further down will be ignored.
1932           elsif (! Data::Compare::Compare(
1933             $value_type_idx->{$col_idx},
1934             [
1935               map
1936               { $_->[0] }
1937               @{$self->_resolve_bindattrs(
1938                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
1939               )}
1940             ],
1941           )) {
1942             $bad_slice_report_cref->(
1943               'Differing bind attributes on literal/bind values not supported',
1944               $row_idx,
1945               $col_idx,
1946             );
1947           }
1948         }
1949       }
1950     }
1951   }
1952
1953   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
1954   # are atomic (even if execute_for_fetch is a single call). Thus a safety
1955   # scope guard
1956   my $guard = $self->txn_scope_guard;
1957
1958   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
1959   my $sth = $self->_sth($sql);
1960   my $rv = do {
1961     if (@$proto_bind) {
1962       # proto bind contains the information on which pieces of $data to pull
1963       # $cols is passed in only for prettier error-reporting
1964       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
1965     }
1966     else {
1967       # bind_param_array doesn't work if there are no binds
1968       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
1969     }
1970   };
1971
1972   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
1973
1974   $guard->commit;
1975
1976   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
1977 }
1978
1979 # execute_for_fetch is capable of returning data just fine (it means it
1980 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
1981 # is the void-populate fast-path we will just ignore this altogether
1982 # for the time being.
1983 sub _dbh_execute_for_fetch {
1984   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
1985
1986   my @idx_range = ( 0 .. $#$proto_bind );
1987
1988   # If we have any bind attributes to take care of, we will bind the
1989   # proto-bind data (which will never be used by execute_for_fetch)
1990   # However since column bindtypes are "sticky", this is sufficient
1991   # to get the DBD to apply the bindtype to all values later on
1992
1993   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
1994
1995   for my $i (@idx_range) {
1996     $sth->bind_param (
1997       $i+1, # DBI bind indexes are 1-based
1998       $proto_bind->[$i][1],
1999       $bind_attrs->[$i],
2000     ) if defined $bind_attrs->[$i];
2001   }
2002
2003   # At this point $data slots named in the _bind_data_slice_idx of
2004   # each piece of $proto_bind are either \[]s or plain values to be
2005   # passed in. Construct the dispensing coderef. *NOTE* the order
2006   # of $data will differ from this of the ?s in the SQL (due to
2007   # alphabetical ordering by colname). We actually do want to
2008   # preserve this behavior so that prepare_cached has a better
2009   # chance of matching on unrelated calls
2010   my %data_reorder = map { $proto_bind->[$_][0]{_bind_data_slice_idx} => $_ } @idx_range;
2011
2012   my $fetch_row_idx = -1; # saner loop this way
2013   my $fetch_tuple = sub {
2014     return undef if ++$fetch_row_idx > $#$data;
2015
2016     return [ map
2017       { (ref $_ eq 'REF' and ref $$_ eq 'ARRAY')
2018         ? map { $_->[-1] } @{$$_}[1 .. $#$$_]
2019         : $_
2020       }
2021       map
2022         { $data->[$fetch_row_idx][$_]}
2023         sort
2024           { $data_reorder{$a} <=> $data_reorder{$b} }
2025           keys %data_reorder
2026     ];
2027   };
2028
2029   my $tuple_status = [];
2030   my ($rv, $err);
2031   try {
2032     $rv = $sth->execute_for_fetch(
2033       $fetch_tuple,
2034       $tuple_status,
2035     );
2036   }
2037   catch {
2038     $err = shift;
2039   };
2040
2041   # Not all DBDs are create equal. Some throw on error, some return
2042   # an undef $rv, and some set $sth->err - try whatever we can
2043   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2044     ! defined $err
2045       and
2046     ( !defined $rv or $sth->err )
2047   );
2048
2049   # Statement must finish even if there was an exception.
2050   try {
2051     $sth->finish
2052   }
2053   catch {
2054     $err = shift unless defined $err
2055   };
2056
2057   if (defined $err) {
2058     my $i = 0;
2059     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2060
2061     $self->throw_exception("Unexpected populate error: $err")
2062       if ($i > $#$tuple_status);
2063
2064     require Data::Dumper::Concise;
2065     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2066       ($tuple_status->[$i][1] || $err),
2067       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2068     );
2069   }
2070
2071   return $rv;
2072 }
2073
2074 sub _dbh_execute_inserts_with_no_binds {
2075   my ($self, $sth, $count) = @_;
2076
2077   my $err;
2078   try {
2079     my $dbh = $self->_get_dbh;
2080     local $dbh->{RaiseError} = 1;
2081     local $dbh->{PrintError} = 0;
2082
2083     $sth->execute foreach 1..$count;
2084   }
2085   catch {
2086     $err = shift;
2087   };
2088
2089   # Make sure statement is finished even if there was an exception.
2090   try {
2091     $sth->finish
2092   }
2093   catch {
2094     $err = shift unless defined $err;
2095   };
2096
2097   $self->throw_exception($err) if defined $err;
2098
2099   return $count;
2100 }
2101
2102 sub update {
2103   #my ($self, $source, @args) = @_;
2104   shift->_execute('update', @_);
2105 }
2106
2107
2108 sub delete {
2109   #my ($self, $source, @args) = @_;
2110   shift->_execute('delete', @_);
2111 }
2112
2113 sub _select {
2114   my $self = shift;
2115   $self->_execute($self->_select_args(@_));
2116 }
2117
2118 sub _select_args_to_query {
2119   my $self = shift;
2120
2121   $self->throw_exception(
2122     "Unable to generate limited query representation with 'software_limit' enabled"
2123   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2124
2125   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2126   #  = $self->_select_args($ident, $select, $cond, $attrs);
2127   my ($op, $ident, @args) =
2128     $self->_select_args(@_);
2129
2130   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2131   my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, \@args);
2132   $prepared_bind ||= [];
2133
2134   return wantarray
2135     ? ($sql, $prepared_bind)
2136     : \[ "($sql)", @$prepared_bind ]
2137   ;
2138 }
2139
2140 sub _select_args {
2141   my ($self, $ident, $select, $where, $attrs) = @_;
2142
2143   my $sql_maker = $self->sql_maker;
2144   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2145
2146   $attrs = {
2147     %$attrs,
2148     select => $select,
2149     from => $ident,
2150     where => $where,
2151     $rs_alias && $alias2source->{$rs_alias}
2152       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2153       : ()
2154     ,
2155   };
2156
2157   # Sanity check the attributes (SQLMaker does it too, but
2158   # in case of a software_limit we'll never reach there)
2159   if (defined $attrs->{offset}) {
2160     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2161       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2162   }
2163
2164   if (defined $attrs->{rows}) {
2165     $self->throw_exception("The rows attribute must be a positive integer if present")
2166       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2167   }
2168   elsif ($attrs->{offset}) {
2169     # MySQL actually recommends this approach.  I cringe.
2170     $attrs->{rows} = $sql_maker->__max_int;
2171   }
2172
2173   my @limit;
2174
2175   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2176   # storage, unless software limit was requested
2177   if (
2178     # limited collapsing has_many
2179     ( $attrs->{rows} && $attrs->{collapse} )
2180        ||
2181     # grouped prefetch (to satisfy group_by == select)
2182     ( $attrs->{group_by}
2183         &&
2184       @{$attrs->{group_by}}
2185         &&
2186       $attrs->{_prefetch_selector_range}
2187     )
2188   ) {
2189     ($ident, $select, $where, $attrs)
2190       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2191   }
2192   elsif (! $attrs->{software_limit} ) {
2193     push @limit, (
2194       $attrs->{rows} || (),
2195       $attrs->{offset} || (),
2196     );
2197   }
2198
2199   # try to simplify the joinmap further (prune unreferenced type-single joins)
2200   $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2201
2202 ###
2203   # This would be the point to deflate anything found in $where
2204   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2205   # expect a row object. And all we have is a resultsource (it is trivial
2206   # to extract deflator coderefs via $alias2source above).
2207   #
2208   # I don't see a way forward other than changing the way deflators are
2209   # invoked, and that's just bad...
2210 ###
2211
2212   return ('select', $ident, $select, $where, $attrs, @limit);
2213 }
2214
2215 # Returns a counting SELECT for a simple count
2216 # query. Abstracted so that a storage could override
2217 # this to { count => 'firstcol' } or whatever makes
2218 # sense as a performance optimization
2219 sub _count_select {
2220   #my ($self, $source, $rs_attrs) = @_;
2221   return { count => '*' };
2222 }
2223
2224 sub source_bind_attributes {
2225   shift->throw_exception(
2226     'source_bind_attributes() was never meant to be a callable public method - '
2227    .'please contact the DBIC dev-team and describe your use case so that a reasonable '
2228    .'solution can be provided'
2229    ."\nhttp://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT"
2230   );
2231 }
2232
2233 =head2 select
2234
2235 =over 4
2236
2237 =item Arguments: $ident, $select, $condition, $attrs
2238
2239 =back
2240
2241 Handle a SQL select statement.
2242
2243 =cut
2244
2245 sub select {
2246   my $self = shift;
2247   my ($ident, $select, $condition, $attrs) = @_;
2248   return $self->cursor_class->new($self, \@_, $attrs);
2249 }
2250
2251 sub select_single {
2252   my $self = shift;
2253   my ($rv, $sth, @bind) = $self->_select(@_);
2254   my @row = $sth->fetchrow_array;
2255   my @nextrow = $sth->fetchrow_array if @row;
2256   if(@row && @nextrow) {
2257     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2258   }
2259   # Need to call finish() to work round broken DBDs
2260   $sth->finish();
2261   return @row;
2262 }
2263
2264 =head2 sql_limit_dialect
2265
2266 This is an accessor for the default SQL limit dialect used by a particular
2267 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2268 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2269 see L<DBIx::Class::SQLMaker::LimitDialects>.
2270
2271 =cut
2272
2273 sub _dbh_sth {
2274   my ($self, $dbh, $sql) = @_;
2275
2276   # 3 is the if_active parameter which avoids active sth re-use
2277   my $sth = $self->disable_sth_caching
2278     ? $dbh->prepare($sql)
2279     : $dbh->prepare_cached($sql, {}, 3);
2280
2281   # XXX You would think RaiseError would make this impossible,
2282   #  but apparently that's not true :(
2283   $self->throw_exception(
2284     $dbh->errstr
2285       ||
2286     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
2287             .'an exception and/or setting $dbh->errstr',
2288       length ($sql) > 20
2289         ? substr($sql, 0, 20) . '...'
2290         : $sql
2291       ,
2292       'DBD::' . $dbh->{Driver}{Name},
2293     )
2294   ) if !$sth;
2295
2296   $sth;
2297 }
2298
2299 sub sth {
2300   carp_unique 'sth was mistakenly marked/documented as public, stop calling it (will be removed before DBIC v0.09)';
2301   shift->_sth(@_);
2302 }
2303
2304 sub _sth {
2305   my ($self, $sql) = @_;
2306   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2307 }
2308
2309 sub _dbh_columns_info_for {
2310   my ($self, $dbh, $table) = @_;
2311
2312   if ($dbh->can('column_info')) {
2313     my %result;
2314     my $caught;
2315     try {
2316       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2317       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2318       $sth->execute();
2319       while ( my $info = $sth->fetchrow_hashref() ){
2320         my %column_info;
2321         $column_info{data_type}   = $info->{TYPE_NAME};
2322         $column_info{size}      = $info->{COLUMN_SIZE};
2323         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2324         $column_info{default_value} = $info->{COLUMN_DEF};
2325         my $col_name = $info->{COLUMN_NAME};
2326         $col_name =~ s/^\"(.*)\"$/$1/;
2327
2328         $result{$col_name} = \%column_info;
2329       }
2330     } catch {
2331       $caught = 1;
2332     };
2333     return \%result if !$caught && scalar keys %result;
2334   }
2335
2336   my %result;
2337   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2338   $sth->execute;
2339   my @columns = @{$sth->{NAME_lc}};
2340   for my $i ( 0 .. $#columns ){
2341     my %column_info;
2342     $column_info{data_type} = $sth->{TYPE}->[$i];
2343     $column_info{size} = $sth->{PRECISION}->[$i];
2344     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2345
2346     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2347       $column_info{data_type} = $1;
2348       $column_info{size}    = $2;
2349     }
2350
2351     $result{$columns[$i]} = \%column_info;
2352   }
2353   $sth->finish;
2354
2355   foreach my $col (keys %result) {
2356     my $colinfo = $result{$col};
2357     my $type_num = $colinfo->{data_type};
2358     my $type_name;
2359     if(defined $type_num && $dbh->can('type_info')) {
2360       my $type_info = $dbh->type_info($type_num);
2361       $type_name = $type_info->{TYPE_NAME} if $type_info;
2362       $colinfo->{data_type} = $type_name if $type_name;
2363     }
2364   }
2365
2366   return \%result;
2367 }
2368
2369 sub columns_info_for {
2370   my ($self, $table) = @_;
2371   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2372 }
2373
2374 =head2 last_insert_id
2375
2376 Return the row id of the last insert.
2377
2378 =cut
2379
2380 sub _dbh_last_insert_id {
2381     my ($self, $dbh, $source, $col) = @_;
2382
2383     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2384
2385     return $id if defined $id;
2386
2387     my $class = ref $self;
2388     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2389 }
2390
2391 sub last_insert_id {
2392   my $self = shift;
2393   $self->_dbh_last_insert_id ($self->_dbh, @_);
2394 }
2395
2396 =head2 _native_data_type
2397
2398 =over 4
2399
2400 =item Arguments: $type_name
2401
2402 =back
2403
2404 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2405 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2406 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2407
2408 The default implementation returns C<undef>, implement in your Storage driver if
2409 you need this functionality.
2410
2411 Should map types from other databases to the native RDBMS type, for example
2412 C<VARCHAR2> to C<VARCHAR>.
2413
2414 Types with modifiers should map to the underlying data type. For example,
2415 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2416
2417 Composite types should map to the container type, for example
2418 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2419
2420 =cut
2421
2422 sub _native_data_type {
2423   #my ($self, $data_type) = @_;
2424   return undef
2425 }
2426
2427 # Check if placeholders are supported at all
2428 sub _determine_supports_placeholders {
2429   my $self = shift;
2430   my $dbh  = $self->_get_dbh;
2431
2432   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2433   # but it is inaccurate more often than not
2434   return try {
2435     local $dbh->{PrintError} = 0;
2436     local $dbh->{RaiseError} = 1;
2437     $dbh->do('select ?', {}, 1);
2438     1;
2439   }
2440   catch {
2441     0;
2442   };
2443 }
2444
2445 # Check if placeholders bound to non-string types throw exceptions
2446 #
2447 sub _determine_supports_typeless_placeholders {
2448   my $self = shift;
2449   my $dbh  = $self->_get_dbh;
2450
2451   return try {
2452     local $dbh->{PrintError} = 0;
2453     local $dbh->{RaiseError} = 1;
2454     # this specifically tests a bind that is NOT a string
2455     $dbh->do('select 1 where 1 = ?', {}, 1);
2456     1;
2457   }
2458   catch {
2459     0;
2460   };
2461 }
2462
2463 =head2 sqlt_type
2464
2465 Returns the database driver name.
2466
2467 =cut
2468
2469 sub sqlt_type {
2470   shift->_get_dbh->{Driver}->{Name};
2471 }
2472
2473 =head2 bind_attribute_by_data_type
2474
2475 Given a datatype from column info, returns a database specific bind
2476 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2477 let the database planner just handle it.
2478
2479 Generally only needed for special case column types, like bytea in postgres.
2480
2481 =cut
2482
2483 sub bind_attribute_by_data_type {
2484     return;
2485 }
2486
2487 =head2 is_datatype_numeric
2488
2489 Given a datatype from column_info, returns a boolean value indicating if
2490 the current RDBMS considers it a numeric value. This controls how
2491 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2492 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2493 be performed instead of the usual C<eq>.
2494
2495 =cut
2496
2497 sub is_datatype_numeric {
2498   #my ($self, $dt) = @_;
2499
2500   return 0 unless $_[1];
2501
2502   $_[1] =~ /^ (?:
2503     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2504   ) $/ix;
2505 }
2506
2507
2508 =head2 create_ddl_dir
2509
2510 =over 4
2511
2512 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
2513
2514 =back
2515
2516 Creates a SQL file based on the Schema, for each of the specified
2517 database engines in C<\@databases> in the given directory.
2518 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2519
2520 Given a previous version number, this will also create a file containing
2521 the ALTER TABLE statements to transform the previous schema into the
2522 current one. Note that these statements may contain C<DROP TABLE> or
2523 C<DROP COLUMN> statements that can potentially destroy data.
2524
2525 The file names are created using the C<ddl_filename> method below, please
2526 override this method in your schema if you would like a different file
2527 name format. For the ALTER file, the same format is used, replacing
2528 $version in the name with "$preversion-$version".
2529
2530 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2531 The most common value for this would be C<< { add_drop_table => 1 } >>
2532 to have the SQL produced include a C<DROP TABLE> statement for each table
2533 created. For quoting purposes supply C<quote_table_names> and
2534 C<quote_field_names>.
2535
2536 If no arguments are passed, then the following default values are assumed:
2537
2538 =over 4
2539
2540 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2541
2542 =item version    - $schema->schema_version
2543
2544 =item directory  - './'
2545
2546 =item preversion - <none>
2547
2548 =back
2549
2550 By default, C<\%sqlt_args> will have
2551
2552  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2553
2554 merged with the hash passed in. To disable any of those features, pass in a
2555 hashref like the following
2556
2557  { ignore_constraint_names => 0, # ... other options }
2558
2559
2560 WARNING: You are strongly advised to check all SQL files created, before applying
2561 them.
2562
2563 =cut
2564
2565 sub create_ddl_dir {
2566   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2567
2568   unless ($dir) {
2569     carp "No directory given, using ./\n";
2570     $dir = './';
2571   } else {
2572       -d $dir
2573         or
2574       (require File::Path and File::Path::make_path ("$dir"))  # make_path does not like objects (i.e. Path::Class::Dir)
2575         or
2576       $self->throw_exception(
2577         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2578       );
2579   }
2580
2581   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2582
2583   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2584   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2585
2586   my $schema_version = $schema->schema_version || '1.x';
2587   $version ||= $schema_version;
2588
2589   $sqltargs = {
2590     add_drop_table => 1,
2591     ignore_constraint_names => 1,
2592     ignore_index_names => 1,
2593     %{$sqltargs || {}}
2594   };
2595
2596   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2597     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2598   }
2599
2600   my $sqlt = SQL::Translator->new( $sqltargs );
2601
2602   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2603   my $sqlt_schema = $sqlt->translate({ data => $schema })
2604     or $self->throw_exception ($sqlt->error);
2605
2606   foreach my $db (@$databases) {
2607     $sqlt->reset();
2608     $sqlt->{schema} = $sqlt_schema;
2609     $sqlt->producer($db);
2610
2611     my $file;
2612     my $filename = $schema->ddl_filename($db, $version, $dir);
2613     if (-e $filename && ($version eq $schema_version )) {
2614       # if we are dumping the current version, overwrite the DDL
2615       carp "Overwriting existing DDL file - $filename";
2616       unlink($filename);
2617     }
2618
2619     my $output = $sqlt->translate;
2620     if(!$output) {
2621       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2622       next;
2623     }
2624     if(!open($file, ">$filename")) {
2625       $self->throw_exception("Can't open $filename for writing ($!)");
2626       next;
2627     }
2628     print $file $output;
2629     close($file);
2630
2631     next unless ($preversion);
2632
2633     require SQL::Translator::Diff;
2634
2635     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2636     if(!-e $prefilename) {
2637       carp("No previous schema file found ($prefilename)");
2638       next;
2639     }
2640
2641     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2642     if(-e $difffile) {
2643       carp("Overwriting existing diff file - $difffile");
2644       unlink($difffile);
2645     }
2646
2647     my $source_schema;
2648     {
2649       my $t = SQL::Translator->new($sqltargs);
2650       $t->debug( 0 );
2651       $t->trace( 0 );
2652
2653       $t->parser( $db )
2654         or $self->throw_exception ($t->error);
2655
2656       my $out = $t->translate( $prefilename )
2657         or $self->throw_exception ($t->error);
2658
2659       $source_schema = $t->schema;
2660
2661       $source_schema->name( $prefilename )
2662         unless ( $source_schema->name );
2663     }
2664
2665     # The "new" style of producers have sane normalization and can support
2666     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2667     # And we have to diff parsed SQL against parsed SQL.
2668     my $dest_schema = $sqlt_schema;
2669
2670     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2671       my $t = SQL::Translator->new($sqltargs);
2672       $t->debug( 0 );
2673       $t->trace( 0 );
2674
2675       $t->parser( $db )
2676         or $self->throw_exception ($t->error);
2677
2678       my $out = $t->translate( $filename )
2679         or $self->throw_exception ($t->error);
2680
2681       $dest_schema = $t->schema;
2682
2683       $dest_schema->name( $filename )
2684         unless $dest_schema->name;
2685     }
2686
2687     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2688                                                   $dest_schema,   $db,
2689                                                   $sqltargs
2690                                                  );
2691     if(!open $file, ">$difffile") {
2692       $self->throw_exception("Can't write to $difffile ($!)");
2693       next;
2694     }
2695     print $file $diff;
2696     close($file);
2697   }
2698 }
2699
2700 =head2 deployment_statements
2701
2702 =over 4
2703
2704 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2705
2706 =back
2707
2708 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2709
2710 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2711 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2712
2713 C<$directory> is used to return statements from files in a previously created
2714 L</create_ddl_dir> directory and is optional. The filenames are constructed
2715 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2716
2717 If no C<$directory> is specified then the statements are constructed on the
2718 fly using L<SQL::Translator> and C<$version> is ignored.
2719
2720 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2721
2722 =cut
2723
2724 sub deployment_statements {
2725   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2726   $type ||= $self->sqlt_type;
2727   $version ||= $schema->schema_version || '1.x';
2728   $dir ||= './';
2729   my $filename = $schema->ddl_filename($type, $version, $dir);
2730   if(-f $filename)
2731   {
2732       # FIXME replace this block when a proper sane sql parser is available
2733       my $file;
2734       open($file, "<$filename")
2735         or $self->throw_exception("Can't open $filename ($!)");
2736       my @rows = <$file>;
2737       close($file);
2738       return join('', @rows);
2739   }
2740
2741   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2742     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2743   }
2744
2745   # sources needs to be a parser arg, but for simplicty allow at top level
2746   # coming in
2747   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2748       if exists $sqltargs->{sources};
2749
2750   my $tr = SQL::Translator->new(
2751     producer => "SQL::Translator::Producer::${type}",
2752     %$sqltargs,
2753     parser => 'SQL::Translator::Parser::DBIx::Class',
2754     data => $schema,
2755   );
2756
2757   return preserve_context {
2758     $tr->translate
2759   } after => sub {
2760     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2761       unless defined $_[0];
2762   };
2763 }
2764
2765 # FIXME deploy() currently does not accurately report sql errors
2766 # Will always return true while errors are warned
2767 sub deploy {
2768   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2769   my $deploy = sub {
2770     my $line = shift;
2771     return if(!$line);
2772     return if($line =~ /^--/);
2773     # next if($line =~ /^DROP/m);
2774     return if($line =~ /^BEGIN TRANSACTION/m);
2775     return if($line =~ /^COMMIT/m);
2776     return if $line =~ /^\s+$/; # skip whitespace only
2777     $self->_query_start($line);
2778     try {
2779       # do a dbh_do cycle here, as we need some error checking in
2780       # place (even though we will ignore errors)
2781       $self->dbh_do (sub { $_[1]->do($line) });
2782     } catch {
2783       carp qq{$_ (running "${line}")};
2784     };
2785     $self->_query_end($line);
2786   };
2787   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2788   if (@statements > 1) {
2789     foreach my $statement (@statements) {
2790       $deploy->( $statement );
2791     }
2792   }
2793   elsif (@statements == 1) {
2794     # split on single line comments and end of statements
2795     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2796       $deploy->( $line );
2797     }
2798   }
2799 }
2800
2801 =head2 datetime_parser
2802
2803 Returns the datetime parser class
2804
2805 =cut
2806
2807 sub datetime_parser {
2808   my $self = shift;
2809   return $self->{datetime_parser} ||= do {
2810     $self->build_datetime_parser(@_);
2811   };
2812 }
2813
2814 =head2 datetime_parser_type
2815
2816 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2817
2818 =head2 build_datetime_parser
2819
2820 See L</datetime_parser>
2821
2822 =cut
2823
2824 sub build_datetime_parser {
2825   my $self = shift;
2826   my $type = $self->datetime_parser_type(@_);
2827   return $type;
2828 }
2829
2830
2831 =head2 is_replicating
2832
2833 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2834 replicate from a master database.  Default is undef, which is the result
2835 returned by databases that don't support replication.
2836
2837 =cut
2838
2839 sub is_replicating {
2840     return;
2841
2842 }
2843
2844 =head2 lag_behind_master
2845
2846 Returns a number that represents a certain amount of lag behind a master db
2847 when a given storage is replicating.  The number is database dependent, but
2848 starts at zero and increases with the amount of lag. Default in undef
2849
2850 =cut
2851
2852 sub lag_behind_master {
2853     return;
2854 }
2855
2856 =head2 relname_to_table_alias
2857
2858 =over 4
2859
2860 =item Arguments: $relname, $join_count
2861
2862 =back
2863
2864 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
2865 queries.
2866
2867 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
2868 way these aliases are named.
2869
2870 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
2871 otherwise C<"$relname">.
2872
2873 =cut
2874
2875 sub relname_to_table_alias {
2876   my ($self, $relname, $join_count) = @_;
2877
2878   my $alias = ($join_count && $join_count > 1 ?
2879     join('_', $relname, $join_count) : $relname);
2880
2881   return $alias;
2882 }
2883
2884 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
2885 # version and it may be necessary to amend or override it for a specific storage
2886 # if such binds are necessary.
2887 sub _max_column_bytesize {
2888   my ($self, $attr) = @_;
2889
2890   my $max_size;
2891
2892   if ($attr->{sqlt_datatype}) {
2893     my $data_type = lc($attr->{sqlt_datatype});
2894
2895     if ($attr->{sqlt_size}) {
2896
2897       # String/sized-binary types
2898       if ($data_type =~ /^(?:
2899           l? (?:var)? char(?:acter)? (?:\s*varying)?
2900             |
2901           (?:var)? binary (?:\s*varying)?
2902             |
2903           raw
2904         )\b/x
2905       ) {
2906         $max_size = $attr->{sqlt_size};
2907       }
2908       # Other charset/unicode types, assume scale of 4
2909       elsif ($data_type =~ /^(?:
2910           national \s* character (?:\s*varying)?
2911             |
2912           nchar
2913             |
2914           univarchar
2915             |
2916           nvarchar
2917         )\b/x
2918       ) {
2919         $max_size = $attr->{sqlt_size} * 4;
2920       }
2921     }
2922
2923     if (!$max_size and !$self->_is_lob_type($data_type)) {
2924       $max_size = 100 # for all other (numeric?) datatypes
2925     }
2926   }
2927
2928   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
2929 }
2930
2931 # Determine if a data_type is some type of BLOB
2932 sub _is_lob_type {
2933   my ($self, $data_type) = @_;
2934   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
2935     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
2936                                   |varchar|character\s*varying|nvarchar
2937                                   |national\s*character\s*varying))?\z/xi);
2938 }
2939
2940 sub _is_binary_lob_type {
2941   my ($self, $data_type) = @_;
2942   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
2943     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
2944 }
2945
2946 sub _is_text_lob_type {
2947   my ($self, $data_type) = @_;
2948   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
2949     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
2950                         |national\s*character\s*varying))\z/xi);
2951 }
2952
2953 1;
2954
2955 =head1 USAGE NOTES
2956
2957 =head2 DBIx::Class and AutoCommit
2958
2959 DBIx::Class can do some wonderful magic with handling exceptions,
2960 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2961 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
2962 transaction support.
2963
2964 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
2965 in an assumed transaction between commits, and you're telling us you'd
2966 like to manage that manually.  A lot of the magic protections offered by
2967 this module will go away.  We can't protect you from exceptions due to database
2968 disconnects because we don't know anything about how to restart your
2969 transactions.  You're on your own for handling all sorts of exceptional
2970 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
2971 be with raw DBI.
2972
2973
2974 =head1 AUTHORS
2975
2976 Matt S. Trout <mst@shadowcatsystems.co.uk>
2977
2978 Andy Grundman <andy@hybridized.org>
2979
2980 =head1 LICENSE
2981
2982 You may distribute this code under the same terms as Perl itself.
2983
2984 =cut