lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid transaction_depth _dbh_autocommit savepoints/
  18 );
  19
  20 # the values for these accessors are picked out (and deleted) from
  21 # the attribute hashref passed to connect_info
  22 my @storage_options = qw/
  23   on_connect_do on_disconnect_do disable_sth_caching unsafe auto_savepoint
  24 /;
  25 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  26
  27
  28 # default cursor class, overridable in connect_info attributes
  29 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  30
  31 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  32 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  33
  34 BEGIN {
  35
  36 package # Hide from PAUSE
  37   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  38
  39 use base qw/SQL::Abstract::Limit/;
  40
  41 # This prevents the caching of $dbh in S::A::L, I believe
  42 sub new {
  43   my $self = shift->SUPER::new(@_);
  44
  45   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  46   #   it with what it resolves to:
  47   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  48     if ref $self->{limit_dialect};
  49
  50   $self;
  51 }
  52
  53 sub _RowNumberOver {
  54   my ($self, $sql, $order, $rows, $offset ) = @_;
  55
  56   $offset += 1;
  57   my $last = $rows + $offset;
  58   my ( $order_by ) = $self->_order_by( $order );
  59
  60   $sql = <<"";
  61 SELECT * FROM
  62 (
  63    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  64       $sql
  65       $order_by
  66    ) Q1
  67 ) Q2
  68 WHERE ROW_NUM BETWEEN $offset AND $last
  69
  70   return $sql;
  71 }
  72
  73
  74 # While we're at it, this should make LIMIT queries more efficient,
  75 #  without digging into things too deeply
  76 use Scalar::Util 'blessed';
  77 sub _find_syntax {
  78   my ($self, $syntax) = @_;
  79   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  80   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  81     return 'RowNumberOver';
  82   }
  83
  84   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  85 }
  86
  87 sub select {
  88   my ($self, $table, $fields, $where, $order, @rest) = @_;
  89   $table = $self->_quote($table) unless ref($table);
  90   local $self->{rownum_hack_count} = 1
  91     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  92   @rest = (-1) unless defined $rest[0];
  93   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  94     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  95   local $self->{having_bind} = [];
  96   my ($sql, @ret) = $self->SUPER::select(
  97     $table, $self->_recurse_fields($fields), $where, $order, @rest
  98   );
  99   $sql .=
 100     $self->{for} ?
 101     (
 102       $self->{for} eq 'update' ? ' FOR UPDATE' :
 103       $self->{for} eq 'shared' ? ' FOR SHARE'  :
 104       ''
 105     ) :
 106     ''
 107   ;
 108   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
 109 }
 110
 111 sub insert {
 112   my $self = shift;
 113   my $table = shift;
 114   $table = $self->_quote($table) unless ref($table);
 115   $self->SUPER::insert($table, @_);
 116 }
 117
 118 sub update {
 119   my $self = shift;
 120   my $table = shift;
 121   $table = $self->_quote($table) unless ref($table);
 122   $self->SUPER::update($table, @_);
 123 }
 124
 125 sub delete {
 126   my $self = shift;
 127   my $table = shift;
 128   $table = $self->_quote($table) unless ref($table);
 129   $self->SUPER::delete($table, @_);
 130 }
 131
 132 sub _emulate_limit {
 133   my $self = shift;
 134   if ($_[3] == -1) {
 135     return $_[1].$self->_order_by($_[2]);
 136   } else {
 137     return $self->SUPER::_emulate_limit(@_);
 138   }
 139 }
 140
 141 sub _recurse_fields {
 142   my ($self, $fields, $params) = @_;
 143   my $ref = ref $fields;
 144   return $self->_quote($fields) unless $ref;
 145   return $$fields if $ref eq 'SCALAR';
 146
 147   if ($ref eq 'ARRAY') {
 148     return join(', ', map {
 149       $self->_recurse_fields($_)
 150         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 151           ? ' AS col'.$self->{rownum_hack_count}++
 152           : '')
 153       } @$fields);
 154   } elsif ($ref eq 'HASH') {
 155     foreach my $func (keys %$fields) {
 156       return $self->_sqlcase($func)
 157         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 158     }
 159   }
 160 }
 161
 162 sub _order_by {
 163   my $self = shift;
 164   my $ret = '';
 165   my @extra;
 166   if (ref $_[0] eq 'HASH') {
 167     if (defined $_[0]->{group_by}) {
 168       $ret = $self->_sqlcase(' group by ')
 169         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 170     }
 171     if (defined $_[0]->{having}) {
 172       my $frag;
 173       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 174       push(@{$self->{having_bind}}, @extra);
 175       $ret .= $self->_sqlcase(' having ').$frag;
 176     }
 177     if (defined $_[0]->{order_by}) {
 178       $ret .= $self->_order_by($_[0]->{order_by});
 179     }
 180   } elsif (ref $_[0] eq 'SCALAR') {
 181     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 182   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 183     my @order = @{+shift};
 184     $ret = $self->_sqlcase(' order by ')
 185           .join(', ', map {
 186                         my $r = $self->_order_by($_, @_);
 187                         $r =~ s/^ ?ORDER BY //i;
 188                         $r;
 189                       } @order);
 190   } else {
 191     $ret = $self->SUPER::_order_by(@_);
 192   }
 193   return $ret;
 194 }
 195
 196 sub _order_directions {
 197   my ($self, $order) = @_;
 198   $order = $order->{order_by} if ref $order eq 'HASH';
 199   return $self->SUPER::_order_directions($order);
 200 }
 201
 202 sub _table {
 203   my ($self, $from) = @_;
 204   if (ref $from eq 'ARRAY') {
 205     return $self->_recurse_from(@$from);
 206   } elsif (ref $from eq 'HASH') {
 207     return $self->_make_as($from);
 208   } else {
 209     return $from; # would love to quote here but _table ends up getting called
 210                   # twice during an ->select without a limit clause due to
 211                   # the way S::A::Limit->select works. should maybe consider
 212                   # bypassing this and doing S::A::select($self, ...) in
 213                   # our select method above. meantime, quoting shims have
 214                   # been added to select/insert/update/delete here
 215   }
 216 }
 217
 218 sub _recurse_from {
 219   my ($self, $from, @join) = @_;
 220   my @sqlf;
 221   push(@sqlf, $self->_make_as($from));
 222   foreach my $j (@join) {
 223     my ($to, $on) = @$j;
 224
 225     # check whether a join type exists
 226     my $join_clause = '';
 227     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 228     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 229       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 230     } else {
 231       $join_clause = ' JOIN ';
 232     }
 233     push(@sqlf, $join_clause);
 234
 235     if (ref $to eq 'ARRAY') {
 236       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 237     } else {
 238       push(@sqlf, $self->_make_as($to));
 239     }
 240     push(@sqlf, ' ON ', $self->_join_condition($on));
 241   }
 242   return join('', @sqlf);
 243 }
 244
 245 sub _make_as {
 246   my ($self, $from) = @_;
 247   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 248                      reverse each %{$self->_skip_options($from)});
 249 }
 250
 251 sub _skip_options {
 252   my ($self, $hash) = @_;
 253   my $clean_hash = {};
 254   $clean_hash->{$_} = $hash->{$_}
 255     for grep {!/^-/} keys %$hash;
 256   return $clean_hash;
 257 }
 258
 259 sub _join_condition {
 260   my ($self, $cond) = @_;
 261   if (ref $cond eq 'HASH') {
 262     my %j;
 263     for (keys %$cond) {
 264       my $v = $cond->{$_};
 265       if (ref $v) {
 266         # XXX no throw_exception() in this package and croak() fails with strange results
 267         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 268             if ref($v) ne 'SCALAR';
 269         $j{$_} = $v;
 270       }
 271       else {
 272         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 273       }
 274     };
 275     return scalar($self->_recurse_where(\%j));
 276   } elsif (ref $cond eq 'ARRAY') {
 277     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 278   } else {
 279     die "Can't handle this yet!";
 280   }
 281 }
 282
 283 sub _quote {
 284   my ($self, $label) = @_;
 285   return '' unless defined $label;
 286   return "*" if $label eq '*';
 287   return $label unless $self->{quote_char};
 288   if(ref $self->{quote_char} eq "ARRAY"){
 289     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 290       if !defined $self->{name_sep};
 291     my $sep = $self->{name_sep};
 292     return join($self->{name_sep},
 293         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 294        split(/\Q$sep\E/,$label));
 295   }
 296   return $self->SUPER::_quote($label);
 297 }
 298
 299 sub limit_dialect {
 300     my $self = shift;
 301     $self->{limit_dialect} = shift if @_;
 302     return $self->{limit_dialect};
 303 }
 304
 305 sub quote_char {
 306     my $self = shift;
 307     $self->{quote_char} = shift if @_;
 308     return $self->{quote_char};
 309 }
 310
 311 sub name_sep {
 312     my $self = shift;
 313     $self->{name_sep} = shift if @_;
 314     return $self->{name_sep};
 315 }
 316
 317 } # End of BEGIN block
 318
 319 =head1 NAME
 320
 321 DBIx::Class::Storage::DBI - DBI storage handler
 322
 323 =head1 SYNOPSIS
 324
 325 =head1 DESCRIPTION
 326
 327 This class represents the connection to an RDBMS via L<DBI>.  See
 328 L<DBIx::Class::Storage> for general information.  This pod only
 329 documents DBI-specific methods and behaviors.
 330
 331 =head1 METHODS
 332
 333 =cut
 334
 335 sub new {
 336   my $new = shift->next::method(@_);
 337
 338   $new->transaction_depth(0);
 339   $new->_sql_maker_opts({});
 340   $new->{savepoints} = [];
 341   $new->{_in_dbh_do} = 0;
 342   $new->{_dbh_gen} = 0;
 343
 344   $new;
 345 }
 346
 347 =head2 connect_info
 348
 349 This method is normally called by L<DBIx::Class::Schema/connection>, which
 350 encapsulates its argument list in an arrayref before passing them here.
 351
 352 The argument list may contain:
 353
 354 =over
 355
 356 =item *
 357
 358 The same 4-element argument set one would normally pass to L<DBI/connect>,
 359 optionally followed by L<extra attributes|/DBIx::Class specific connection attributes>
 360 recognized by DBIx::Class:
 361
 362   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes, \%extra_attributes ];
 363
 364 =item *
 365
 366 A single code reference which returns a connected L<DBI database handle|DBI/connect>
 367 optinally followed by L<extra attributes|/DBIx::Class specific connection attributes>
 368 recognized by DBIx::Class:
 369
 370   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes ];
 371
 372 =item *
 373
 374 A single hashref with all the attributes and the dsn/user/password mixed together:
 375
 376   $connect_info_args = [{
 377     dsn => $dsn,
 378     user => $user,
 379     password => $pass,
 380     %dbi_attributes,
 381     %extra_attributes,
 382   }];
 383
 384 This is particularly useful for L<Catalyst> based applications, allowing the
 385 following config:
 386
 387   <Model::DB>
 388     schema_class   App::DB
 389     <connect_info>
 390       dsn          dbi:mysql:database=test
 391       user         testuser
 392       password     TestPass
 393       AutoCommit   1
 394     </connect_info>
 395   </Model::DB>
 396
 397 =back
 398
 399 Please note that the L<DBI> docs
 400 recommend that you always explicitly set C<AutoCommit> to either
 401 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 402 to C<1>, and that you perform transactions via our L</txn_do>
 403 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 404 set it to zero.  This is the default for most DBDs. See
 405 L</DBIx::Class and AutoCommit> for details.
 406
 407 =head3 DBIx::Class specific connection attributes
 408
 409 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 410 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 411 the following connection options. These options can be mixed in with your other
 412 L<DBI> connection attributes, or placed in a seperate hashref
 413 (C<\%extra_attributes>) as shown above.
 414
 415 Every time C<connect_info> is invoked, any previous settings for
 416 these options will be cleared before setting the new ones, regardless of
 417 whether any options are specified in the new C<connect_info>.
 418
 419
 420 =over 4
 421
 422 =item on_connect_do
 423
 424 Specifies things to do immediately after connecting or re-connecting to
 425 the database.  Its value may contain:
 426
 427 =over
 428
 429 =item an array reference
 430
 431 This contains SQL statements to execute in order.  Each element contains
 432 a string or a code reference that returns a string.
 433
 434 =item a code reference
 435
 436 This contains some code to execute.  Unlike code references within an
 437 array reference, its return value is ignored.
 438
 439 =back
 440
 441 =item on_disconnect_do
 442
 443 Takes arguments in the same form as L<on_connect_do> and executes them
 444 immediately before disconnecting from the database.
 445
 446 Note, this only runs if you explicitly call L<disconnect> on the
 447 storage object.
 448
 449 =item disable_sth_caching
 450
 451 If set to a true value, this option will disable the caching of
 452 statement handles via L<DBI/prepare_cached>.
 453
 454 =item limit_dialect
 455
 456 Sets the limit dialect. This is useful for JDBC-bridge among others
 457 where the remote SQL-dialect cannot be determined by the name of the
 458 driver alone.
 459
 460 =item quote_char
 461
 462 Specifies what characters to use to quote table and column names. If
 463 you use this you will want to specify L<name_sep> as well.
 464
 465 quote_char expects either a single character, in which case is it is placed
 466 on either side of the table/column, or an arrayref of length 2 in which case the
 467 table/column name is placed between the elements.
 468
 469 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 470 use C<quote_char =E<gt> [qw/[ ]/]>.
 471
 472 =item name_sep
 473
 474 This only needs to be used in conjunction with L<quote_char>, and is used to
 475 specify the charecter that seperates elements (schemas, tables, columns) from
 476 each other. In most cases this is simply a C<.>.
 477
 478 =item unsafe
 479
 480 This Storage driver normally installs its own C<HandleError>, sets
 481 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 482 all database handles, including those supplied by a coderef.  It does this
 483 so that it can have consistent and useful error behavior.
 484
 485 If you set this option to a true value, Storage will not do its usual
 486 modifications to the database handle's attributes, and instead relies on
 487 the settings in your connect_info DBI options (or the values you set in
 488 your connection coderef, in the case that you are connecting via coderef).
 489
 490 Note that your custom settings can cause Storage to malfunction,
 491 especially if you set a C<HandleError> handler that suppresses exceptions
 492 and/or disable C<RaiseError>.
 493
 494 =item auto_savepoint
 495
 496 If this option is true, L<DBIx::Class> will use savepoints when nesting
 497 transactions, making it possible to recover from failure in the inner
 498 transaction without having to abort all outer transactions.
 499
 500 =item cursor_class
 501
 502 Use this argument to supply a cursor class other than the default
 503 L<DBIx::Class::Storage::DBI::Cursor>.
 504
 505 =back
 506
 507 Some real-life examples of arguments to L</connect_info> and L<DBIx::Class::Schema/connect>
 508
 509   # Simple SQLite connection
 510   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 511
 512   # Connect via subref
 513   ->connect_info([ sub { DBI->connect(...) } ]);
 514
 515   # A bit more complicated
 516   ->connect_info(
 517     [
 518       'dbi:Pg:dbname=foo',
 519       'postgres',
 520       'my_pg_password',
 521       { AutoCommit => 1 },
 522       { quote_char => q{"}, name_sep => q{.} },
 523     ]
 524   );
 525
 526   # Equivalent to the previous example
 527   ->connect_info(
 528     [
 529       'dbi:Pg:dbname=foo',
 530       'postgres',
 531       'my_pg_password',
 532       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 533     ]
 534   );
 535
 536   # Same, but with hashref as argument
 537   # See C<parse_connect_info> for explanation
 538   ->connect_info(
 539     [{
 540       dsn         => 'dbi:Pg:dbname=foo',
 541       user        => 'postgres',
 542       password    => 'my_pg_password',
 543       AutoCommit  => 1,
 544       quote_char  => q{"},
 545       name_sep    => q{.},
 546     }]
 547   );
 548
 549   # Subref + DBIx::Class-specific connection options
 550   ->connect_info(
 551     [
 552       sub { DBI->connect(...) },
 553       {
 554           quote_char => q{`},
 555           name_sep => q{@},
 556           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 557           disable_sth_caching => 1,
 558       },
 559     ]
 560   );
 561
 562
 563
 564 =cut
 565
 566 sub connect_info {
 567   my ($self, $info_arg) = @_;
 568
 569   return $self->_connect_info if !$info_arg;
 570
 571   my @args = @$info_arg;  # take a shallow copy for further mutilation
 572   $self->_connect_info([@args]); # copy for _connect_info
 573
 574
 575   # combine/pre-parse arguments depending on invocation style
 576
 577   my %attrs;
 578   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 579     %attrs = %{ $args[1] || {} };
 580     @args = $args[0];
 581   }
 582   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 583     %attrs = %{$args[0]};
 584     @args = ();
 585     for (qw/password user dsn/) {
 586       unshift @args, delete $attrs{$_};
 587     }
 588   }
 589   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 590     %attrs = (
 591       % { $args[3] || {} },
 592       % { $args[4] || {} },
 593     );
 594     @args = @args[0,1,2];
 595   }
 596
 597   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 598   #  the new set of options
 599   $self->_sql_maker(undef);
 600   $self->_sql_maker_opts({});
 601
 602   if(keys %attrs) {
 603     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 604       if(my $value = delete $attrs{$storage_opt}) {
 605         $self->$storage_opt($value);
 606       }
 607     }
 608     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 609       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 610         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 611       }
 612     }
 613   }
 614
 615   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 616
 617   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 618   $self->_connect_info;
 619 }
 620
 621 =head2 on_connect_do
 622
 623 This method is deprecated in favor of setting via L</connect_info>.
 624
 625
 626 =head2 dbh_do
 627
 628 Arguments: ($subref | $method_name), @extra_coderef_args?
 629
 630 Execute the given $subref or $method_name using the new exception-based
 631 connection management.
 632
 633 The first two arguments will be the storage object that C<dbh_do> was called
 634 on and a database handle to use.  Any additional arguments will be passed
 635 verbatim to the called subref as arguments 2 and onwards.
 636
 637 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 638 exception handling and reconnection (or failover in future subclasses).
 639
 640 Your subref should have no side-effects outside of the database, as
 641 there is the potential for your subref to be partially double-executed
 642 if the database connection was stale/dysfunctional.
 643
 644 Example:
 645
 646   my @stuff = $schema->storage->dbh_do(
 647     sub {
 648       my ($storage, $dbh, @cols) = @_;
 649       my $cols = join(q{, }, @cols);
 650       $dbh->selectrow_array("SELECT $cols FROM foo");
 651     },
 652     @column_list
 653   );
 654
 655 =cut
 656
 657 sub dbh_do {
 658   my $self = shift;
 659   my $code = shift;
 660
 661   my $dbh = $self->_dbh;
 662
 663   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 664       || $self->{transaction_depth};
 665
 666   local $self->{_in_dbh_do} = 1;
 667
 668   my @result;
 669   my $want_array = wantarray;
 670
 671   eval {
 672     $self->_verify_pid if $dbh;
 673     if(!$self->_dbh) {
 674         $self->_populate_dbh;
 675         $dbh = $self->_dbh;
 676     }
 677
 678     if($want_array) {
 679         @result = $self->$code($dbh, @_);
 680     }
 681     elsif(defined $want_array) {
 682         $result[0] = $self->$code($dbh, @_);
 683     }
 684     else {
 685         $self->$code($dbh, @_);
 686     }
 687   };
 688
 689   my $exception = $@;
 690   if(!$exception) { return $want_array ? @result : $result[0] }
 691
 692   $self->throw_exception($exception) if $self->connected;
 693
 694   # We were not connected - reconnect and retry, but let any
 695   #  exception fall right through this time
 696   $self->_populate_dbh;
 697   $self->$code($self->_dbh, @_);
 698 }
 699
 700 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 701 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 702 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 703 sub txn_do {
 704   my $self = shift;
 705   my $coderef = shift;
 706
 707   ref $coderef eq 'CODE' or $self->throw_exception
 708     ('$coderef must be a CODE reference');
 709
 710   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 711
 712   local $self->{_in_dbh_do} = 1;
 713
 714   my @result;
 715   my $want_array = wantarray;
 716
 717   my $tried = 0;
 718   while(1) {
 719     eval {
 720       $self->_verify_pid if $self->_dbh;
 721       $self->_populate_dbh if !$self->_dbh;
 722
 723       $self->txn_begin;
 724       if($want_array) {
 725           @result = $coderef->(@_);
 726       }
 727       elsif(defined $want_array) {
 728           $result[0] = $coderef->(@_);
 729       }
 730       else {
 731           $coderef->(@_);
 732       }
 733       $self->txn_commit;
 734     };
 735
 736     my $exception = $@;
 737     if(!$exception) { return $want_array ? @result : $result[0] }
 738
 739     if($tried++ > 0 || $self->connected) {
 740       eval { $self->txn_rollback };
 741       my $rollback_exception = $@;
 742       if($rollback_exception) {
 743         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 744         $self->throw_exception($exception)  # propagate nested rollback
 745           if $rollback_exception =~ /$exception_class/;
 746
 747         $self->throw_exception(
 748           "Transaction aborted: ${exception}. "
 749           . "Rollback failed: ${rollback_exception}"
 750         );
 751       }
 752       $self->throw_exception($exception)
 753     }
 754
 755     # We were not connected, and was first try - reconnect and retry
 756     # via the while loop
 757     $self->_populate_dbh;
 758   }
 759 }
 760
 761 =head2 disconnect
 762
 763 Our C<disconnect> method also performs a rollback first if the
 764 database is not in C<AutoCommit> mode.
 765
 766 =cut
 767
 768 sub disconnect {
 769   my ($self) = @_;
 770
 771   if( $self->connected ) {
 772     my $connection_do = $self->on_disconnect_do;
 773     $self->_do_connection_actions($connection_do) if ref($connection_do);
 774
 775     $self->_dbh->rollback unless $self->_dbh_autocommit;
 776     $self->_dbh->disconnect;
 777     $self->_dbh(undef);
 778     $self->{_dbh_gen}++;
 779   }
 780 }
 781
 782 =head2 with_deferred_fk_checks
 783
 784 =over 4
 785
 786 =item Arguments: C<$coderef>
 787
 788 =item Return Value: The return value of $coderef
 789
 790 =back
 791
 792 Storage specific method to run the code ref with FK checks deferred or
 793 in MySQL's case disabled entirely.
 794
 795 =cut
 796
 797 # Storage subclasses should override this
 798 sub with_deferred_fk_checks {
 799   my ($self, $sub) = @_;
 800
 801   $sub->();
 802 }
 803
 804 sub connected {
 805   my ($self) = @_;
 806
 807   if(my $dbh = $self->_dbh) {
 808       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 809           $self->_dbh(undef);
 810           $self->{_dbh_gen}++;
 811           return;
 812       }
 813       else {
 814           $self->_verify_pid;
 815           return 0 if !$self->_dbh;
 816       }
 817       return ($dbh->FETCH('Active') && $dbh->ping);
 818   }
 819
 820   return 0;
 821 }
 822
 823 # handle pid changes correctly
 824 #  NOTE: assumes $self->_dbh is a valid $dbh
 825 sub _verify_pid {
 826   my ($self) = @_;
 827
 828   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 829
 830   $self->_dbh->{InactiveDestroy} = 1;
 831   $self->_dbh(undef);
 832   $self->{_dbh_gen}++;
 833
 834   return;
 835 }
 836
 837 sub ensure_connected {
 838   my ($self) = @_;
 839
 840   unless ($self->connected) {
 841     $self->_populate_dbh;
 842   }
 843 }
 844
 845 =head2 dbh
 846
 847 Returns the dbh - a data base handle of class L<DBI>.
 848
 849 =cut
 850
 851 sub dbh {
 852   my ($self) = @_;
 853
 854   $self->ensure_connected;
 855   return $self->_dbh;
 856 }
 857
 858 sub _sql_maker_args {
 859     my ($self) = @_;
 860
 861     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 862 }
 863
 864 sub sql_maker {
 865   my ($self) = @_;
 866   unless ($self->_sql_maker) {
 867     my $sql_maker_class = $self->sql_maker_class;
 868     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 869   }
 870   return $self->_sql_maker;
 871 }
 872
 873 sub _rebless {}
 874
 875 sub _populate_dbh {
 876   my ($self) = @_;
 877   my @info = @{$self->_dbi_connect_info || []};
 878   $self->_dbh($self->_connect(@info));
 879
 880   # Always set the transaction depth on connect, since
 881   #  there is no transaction in progress by definition
 882   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 883
 884   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 885     my $driver = $self->_dbh->{Driver}->{Name};
 886     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 887       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 888       $self->_rebless();
 889     }
 890   }
 891
 892   my $connection_do = $self->on_connect_do;
 893   $self->_do_connection_actions($connection_do) if ref($connection_do);
 894
 895   $self->_conn_pid($$);
 896   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 897 }
 898
 899 sub _do_connection_actions {
 900   my $self = shift;
 901   my $connection_do = shift;
 902
 903   if (ref $connection_do eq 'ARRAY') {
 904     $self->_do_query($_) foreach @$connection_do;
 905   }
 906   elsif (ref $connection_do eq 'CODE') {
 907     $connection_do->();
 908   }
 909
 910   return $self;
 911 }
 912
 913 sub _do_query {
 914   my ($self, $action) = @_;
 915
 916   if (ref $action eq 'CODE') {
 917     $action = $action->($self);
 918     $self->_do_query($_) foreach @$action;
 919   }
 920   else {
 921     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 922     $self->_query_start(@to_run);
 923     $self->_dbh->do(@to_run);
 924     $self->_query_end(@to_run);
 925   }
 926
 927   return $self;
 928 }
 929
 930 sub _connect {
 931   my ($self, @info) = @_;
 932
 933   $self->throw_exception("You failed to provide any connection info")
 934     if !@info;
 935
 936   my ($old_connect_via, $dbh);
 937
 938   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 939     $old_connect_via = $DBI::connect_via;
 940     $DBI::connect_via = 'connect';
 941   }
 942
 943   eval {
 944     if(ref $info[0] eq 'CODE') {
 945        $dbh = &{$info[0]}
 946     }
 947     else {
 948        $dbh = DBI->connect(@info);
 949     }
 950
 951     if($dbh && !$self->unsafe) {
 952       my $weak_self = $self;
 953       weaken($weak_self);
 954       $dbh->{HandleError} = sub {
 955           if ($weak_self) {
 956             $weak_self->throw_exception("DBI Exception: $_[0]");
 957           }
 958           else {
 959             croak ("DBI Exception: $_[0]");
 960           }
 961       };
 962       $dbh->{ShowErrorStatement} = 1;
 963       $dbh->{RaiseError} = 1;
 964       $dbh->{PrintError} = 0;
 965     }
 966   };
 967
 968   $DBI::connect_via = $old_connect_via if $old_connect_via;
 969
 970   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 971     if !$dbh || $@;
 972
 973   $self->_dbh_autocommit($dbh->{AutoCommit});
 974
 975   $dbh;
 976 }
 977
 978 sub svp_begin {
 979   my ($self, $name) = @_;
 980
 981   $name = $self->_svp_generate_name
 982     unless defined $name;
 983
 984   $self->throw_exception ("You can't use savepoints outside a transaction")
 985     if $self->{transaction_depth} == 0;
 986
 987   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 988     unless $self->can('_svp_begin');
 989
 990   push @{ $self->{savepoints} }, $name;
 991
 992   $self->debugobj->svp_begin($name) if $self->debug;
 993
 994   return $self->_svp_begin($name);
 995 }
 996
 997 sub svp_release {
 998   my ($self, $name) = @_;
 999
1000   $self->throw_exception ("You can't use savepoints outside a transaction")
1001     if $self->{transaction_depth} == 0;
1002
1003   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1004     unless $self->can('_svp_release');
1005
1006   if (defined $name) {
1007     $self->throw_exception ("Savepoint '$name' does not exist")
1008       unless grep { $_ eq $name } @{ $self->{savepoints} };
1009
1010     # Dig through the stack until we find the one we are releasing.  This keeps
1011     # the stack up to date.
1012     my $svp;
1013
1014     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1015   } else {
1016     $name = pop @{ $self->{savepoints} };
1017   }
1018
1019   $self->debugobj->svp_release($name) if $self->debug;
1020
1021   return $self->_svp_release($name);
1022 }
1023
1024 sub svp_rollback {
1025   my ($self, $name) = @_;
1026
1027   $self->throw_exception ("You can't use savepoints outside a transaction")
1028     if $self->{transaction_depth} == 0;
1029
1030   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1031     unless $self->can('_svp_rollback');
1032
1033   if (defined $name) {
1034       # If they passed us a name, verify that it exists in the stack
1035       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1036           $self->throw_exception("Savepoint '$name' does not exist!");
1037       }
1038
1039       # Dig through the stack until we find the one we are releasing.  This keeps
1040       # the stack up to date.
1041       while(my $s = pop(@{ $self->{savepoints} })) {
1042           last if($s eq $name);
1043       }
1044       # Add the savepoint back to the stack, as a rollback doesn't remove the
1045       # named savepoint, only everything after it.
1046       push(@{ $self->{savepoints} }, $name);
1047   } else {
1048       # We'll assume they want to rollback to the last savepoint
1049       $name = $self->{savepoints}->[-1];
1050   }
1051
1052   $self->debugobj->svp_rollback($name) if $self->debug;
1053
1054   return $self->_svp_rollback($name);
1055 }
1056
1057 sub _svp_generate_name {
1058     my ($self) = @_;
1059
1060     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1061 }
1062
1063 sub txn_begin {
1064   my $self = shift;
1065   $self->ensure_connected();
1066   if($self->{transaction_depth} == 0) {
1067     $self->debugobj->txn_begin()
1068       if $self->debug;
1069     # this isn't ->_dbh-> because
1070     #  we should reconnect on begin_work
1071     #  for AutoCommit users
1072     $self->dbh->begin_work;
1073   } elsif ($self->auto_savepoint) {
1074     $self->svp_begin;
1075   }
1076   $self->{transaction_depth}++;
1077 }
1078
1079 sub txn_commit {
1080   my $self = shift;
1081   if ($self->{transaction_depth} == 1) {
1082     my $dbh = $self->_dbh;
1083     $self->debugobj->txn_commit()
1084       if ($self->debug);
1085     $dbh->commit;
1086     $self->{transaction_depth} = 0
1087       if $self->_dbh_autocommit;
1088   }
1089   elsif($self->{transaction_depth} > 1) {
1090     $self->{transaction_depth}--;
1091     $self->svp_release
1092       if $self->auto_savepoint;
1093   }
1094 }
1095
1096 sub txn_rollback {
1097   my $self = shift;
1098   my $dbh = $self->_dbh;
1099   eval {
1100     if ($self->{transaction_depth} == 1) {
1101       $self->debugobj->txn_rollback()
1102         if ($self->debug);
1103       $self->{transaction_depth} = 0
1104         if $self->_dbh_autocommit;
1105       $dbh->rollback;
1106     }
1107     elsif($self->{transaction_depth} > 1) {
1108       $self->{transaction_depth}--;
1109       if ($self->auto_savepoint) {
1110         $self->svp_rollback;
1111         $self->svp_release;
1112       }
1113     }
1114     else {
1115       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1116     }
1117   };
1118   if ($@) {
1119     my $error = $@;
1120     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1121     $error =~ /$exception_class/ and $self->throw_exception($error);
1122     # ensure that a failed rollback resets the transaction depth
1123     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1124     $self->throw_exception($error);
1125   }
1126 }
1127
1128 # This used to be the top-half of _execute.  It was split out to make it
1129 #  easier to override in NoBindVars without duping the rest.  It takes up
1130 #  all of _execute's args, and emits $sql, @bind.
1131 sub _prep_for_execute {
1132   my ($self, $op, $extra_bind, $ident, $args) = @_;
1133
1134   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1135   unshift(@bind,
1136     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1137       if $extra_bind;
1138
1139   return ($sql, \@bind);
1140 }
1141
1142 sub _fix_bind_params {
1143     my ($self, @bind) = @_;
1144
1145     ### Turn @bind from something like this:
1146     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1147     ### to this:
1148     ###   ( "'1'", "'1'", "'3'" )
1149     return
1150         map {
1151             if ( defined( $_ && $_->[1] ) ) {
1152                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1153             }
1154             else { q{'NULL'}; }
1155         } @bind;
1156 }
1157
1158 sub _query_start {
1159     my ( $self, $sql, @bind ) = @_;
1160
1161     if ( $self->debug ) {
1162         @bind = $self->_fix_bind_params(@bind);
1163
1164         $self->debugobj->query_start( $sql, @bind );
1165     }
1166 }
1167
1168 sub _query_end {
1169     my ( $self, $sql, @bind ) = @_;
1170
1171     if ( $self->debug ) {
1172         @bind = $self->_fix_bind_params(@bind);
1173         $self->debugobj->query_end( $sql, @bind );
1174     }
1175 }
1176
1177 sub _dbh_execute {
1178   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1179
1180   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1181     $ident = $ident->from();
1182   }
1183
1184   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1185
1186   $self->_query_start( $sql, @$bind );
1187
1188   my $sth = $self->sth($sql,$op);
1189
1190   my $placeholder_index = 1;
1191
1192   foreach my $bound (@$bind) {
1193     my $attributes = {};
1194     my($column_name, @data) = @$bound;
1195
1196     if ($bind_attributes) {
1197       $attributes = $bind_attributes->{$column_name}
1198       if defined $bind_attributes->{$column_name};
1199     }
1200
1201     foreach my $data (@data) {
1202       $data = ref $data ? ''.$data : $data; # stringify args
1203
1204       $sth->bind_param($placeholder_index, $data, $attributes);
1205       $placeholder_index++;
1206     }
1207   }
1208
1209   # Can this fail without throwing an exception anyways???
1210   my $rv = $sth->execute();
1211   $self->throw_exception($sth->errstr) if !$rv;
1212
1213   $self->_query_end( $sql, @$bind );
1214
1215   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1216 }
1217
1218 sub _execute {
1219     my $self = shift;
1220     $self->dbh_do('_dbh_execute', @_)
1221 }
1222
1223 sub insert {
1224   my ($self, $source, $to_insert) = @_;
1225
1226   my $ident = $source->from;
1227   my $bind_attributes = $self->source_bind_attributes($source);
1228
1229   $self->ensure_connected;
1230   foreach my $col ( $source->columns ) {
1231     if ( !defined $to_insert->{$col} ) {
1232       my $col_info = $source->column_info($col);
1233
1234       if ( $col_info->{auto_nextval} ) {
1235         $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1236       }
1237     }
1238   }
1239
1240   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1241
1242   return $to_insert;
1243 }
1244
1245 ## Still not quite perfect, and EXPERIMENTAL
1246 ## Currently it is assumed that all values passed will be "normal", i.e. not
1247 ## scalar refs, or at least, all the same type as the first set, the statement is
1248 ## only prepped once.
1249 sub insert_bulk {
1250   my ($self, $source, $cols, $data) = @_;
1251   my %colvalues;
1252   my $table = $source->from;
1253   @colvalues{@$cols} = (0..$#$cols);
1254   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1255
1256   $self->_query_start( $sql, @bind );
1257   my $sth = $self->sth($sql);
1258
1259 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1260
1261   ## This must be an arrayref, else nothing works!
1262
1263   my $tuple_status = [];
1264
1265   ##use Data::Dumper;
1266   ##print STDERR Dumper( $data, $sql, [@bind] );
1267
1268   my $time = time();
1269
1270   ## Get the bind_attributes, if any exist
1271   my $bind_attributes = $self->source_bind_attributes($source);
1272
1273   ## Bind the values and execute
1274   my $placeholder_index = 1;
1275
1276   foreach my $bound (@bind) {
1277
1278     my $attributes = {};
1279     my ($column_name, $data_index) = @$bound;
1280
1281     if( $bind_attributes ) {
1282       $attributes = $bind_attributes->{$column_name}
1283       if defined $bind_attributes->{$column_name};
1284     }
1285
1286     my @data = map { $_->[$data_index] } @$data;
1287
1288     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1289     $placeholder_index++;
1290   }
1291   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1292   $self->throw_exception($sth->errstr) if !$rv;
1293
1294   $self->_query_end( $sql, @bind );
1295   return (wantarray ? ($rv, $sth, @bind) : $rv);
1296 }
1297
1298 sub update {
1299   my $self = shift @_;
1300   my $source = shift @_;
1301   my $bind_attributes = $self->source_bind_attributes($source);
1302
1303   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1304 }
1305
1306
1307 sub delete {
1308   my $self = shift @_;
1309   my $source = shift @_;
1310
1311   my $bind_attrs = {}; ## If ever it's needed...
1312
1313   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1314 }
1315
1316 sub _select {
1317   my ($self, $ident, $select, $condition, $attrs) = @_;
1318   my $order = $attrs->{order_by};
1319
1320   if (ref $condition eq 'SCALAR') {
1321     my $unwrap = ${$condition};
1322     if ($unwrap =~ s/ORDER BY (.*)$//i) {
1323       $order = $1;
1324       $condition = \$unwrap;
1325     }
1326   }
1327
1328   my $for = delete $attrs->{for};
1329   my $sql_maker = $self->sql_maker;
1330   local $sql_maker->{for} = $for;
1331
1332   if (exists $attrs->{group_by} || $attrs->{having}) {
1333     $order = {
1334       group_by => $attrs->{group_by},
1335       having => $attrs->{having},
1336       ($order ? (order_by => $order) : ())
1337     };
1338   }
1339   my $bind_attrs = {}; ## Future support
1340   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1341   if ($attrs->{software_limit} ||
1342       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1343         $attrs->{software_limit} = 1;
1344   } else {
1345     $self->throw_exception("rows attribute must be positive if present")
1346       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1347
1348     # MySQL actually recommends this approach.  I cringe.
1349     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1350     push @args, $attrs->{rows}, $attrs->{offset};
1351   }
1352
1353   return $self->_execute(@args);
1354 }
1355
1356 sub source_bind_attributes {
1357   my ($self, $source) = @_;
1358
1359   my $bind_attributes;
1360   foreach my $column ($source->columns) {
1361
1362     my $data_type = $source->column_info($column)->{data_type} || '';
1363     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1364      if $data_type;
1365   }
1366
1367   return $bind_attributes;
1368 }
1369
1370 =head2 select
1371
1372 =over 4
1373
1374 =item Arguments: $ident, $select, $condition, $attrs
1375
1376 =back
1377
1378 Handle a SQL select statement.
1379
1380 =cut
1381
1382 sub select {
1383   my $self = shift;
1384   my ($ident, $select, $condition, $attrs) = @_;
1385   return $self->cursor_class->new($self, \@_, $attrs);
1386 }
1387
1388 sub select_single {
1389   my $self = shift;
1390   my ($rv, $sth, @bind) = $self->_select(@_);
1391   my @row = $sth->fetchrow_array;
1392   if(@row && $sth->fetchrow_array) {
1393     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1394   }
1395   # Need to call finish() to work round broken DBDs
1396   $sth->finish();
1397   return @row;
1398 }
1399
1400 =head2 sth
1401
1402 =over 4
1403
1404 =item Arguments: $sql
1405
1406 =back
1407
1408 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1409
1410 =cut
1411
1412 sub _dbh_sth {
1413   my ($self, $dbh, $sql) = @_;
1414
1415   # 3 is the if_active parameter which avoids active sth re-use
1416   my $sth = $self->disable_sth_caching
1417     ? $dbh->prepare($sql)
1418     : $dbh->prepare_cached($sql, {}, 3);
1419
1420   # XXX You would think RaiseError would make this impossible,
1421   #  but apparently that's not true :(
1422   $self->throw_exception($dbh->errstr) if !$sth;
1423
1424   $sth;
1425 }
1426
1427 sub sth {
1428   my ($self, $sql) = @_;
1429   $self->dbh_do('_dbh_sth', $sql);
1430 }
1431
1432 sub _dbh_columns_info_for {
1433   my ($self, $dbh, $table) = @_;
1434
1435   if ($dbh->can('column_info')) {
1436     my %result;
1437     eval {
1438       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1439       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1440       $sth->execute();
1441       while ( my $info = $sth->fetchrow_hashref() ){
1442         my %column_info;
1443         $column_info{data_type}   = $info->{TYPE_NAME};
1444         $column_info{size}      = $info->{COLUMN_SIZE};
1445         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1446         $column_info{default_value} = $info->{COLUMN_DEF};
1447         my $col_name = $info->{COLUMN_NAME};
1448         $col_name =~ s/^\"(.*)\"$/$1/;
1449
1450         $result{$col_name} = \%column_info;
1451       }
1452     };
1453     return \%result if !$@ && scalar keys %result;
1454   }
1455
1456   my %result;
1457   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1458   $sth->execute;
1459   my @columns = @{$sth->{NAME_lc}};
1460   for my $i ( 0 .. $#columns ){
1461     my %column_info;
1462     $column_info{data_type} = $sth->{TYPE}->[$i];
1463     $column_info{size} = $sth->{PRECISION}->[$i];
1464     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1465
1466     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1467       $column_info{data_type} = $1;
1468       $column_info{size}    = $2;
1469     }
1470
1471     $result{$columns[$i]} = \%column_info;
1472   }
1473   $sth->finish;
1474
1475   foreach my $col (keys %result) {
1476     my $colinfo = $result{$col};
1477     my $type_num = $colinfo->{data_type};
1478     my $type_name;
1479     if(defined $type_num && $dbh->can('type_info')) {
1480       my $type_info = $dbh->type_info($type_num);
1481       $type_name = $type_info->{TYPE_NAME} if $type_info;
1482       $colinfo->{data_type} = $type_name if $type_name;
1483     }
1484   }
1485
1486   return \%result;
1487 }
1488
1489 sub columns_info_for {
1490   my ($self, $table) = @_;
1491   $self->dbh_do('_dbh_columns_info_for', $table);
1492 }
1493
1494 =head2 last_insert_id
1495
1496 Return the row id of the last insert.
1497
1498 =cut
1499
1500 sub _dbh_last_insert_id {
1501     my ($self, $dbh, $source, $col) = @_;
1502     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1503     $dbh->func('last_insert_rowid');
1504 }
1505
1506 sub last_insert_id {
1507   my $self = shift;
1508   $self->dbh_do('_dbh_last_insert_id', @_);
1509 }
1510
1511 =head2 sqlt_type
1512
1513 Returns the database driver name.
1514
1515 =cut
1516
1517 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1518
1519 =head2 bind_attribute_by_data_type
1520
1521 Given a datatype from column info, returns a database specific bind attribute for
1522 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1523 just handle it.
1524
1525 Generally only needed for special case column types, like bytea in postgres.
1526
1527 =cut
1528
1529 sub bind_attribute_by_data_type {
1530     return;
1531 }
1532
1533 =head2 create_ddl_dir
1534
1535 =over 4
1536
1537 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1538
1539 =back
1540
1541 Creates a SQL file based on the Schema, for each of the specified
1542 database types, in the given directory.
1543
1544 By default, C<\%sqlt_args> will have
1545
1546  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1547
1548 merged with the hash passed in. To disable any of those features, pass in a
1549 hashref like the following
1550
1551  { ignore_constraint_names => 0, # ... other options }
1552
1553 =cut
1554
1555 sub create_ddl_dir {
1556   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1557
1558   if(!$dir || !-d $dir) {
1559     warn "No directory given, using ./\n";
1560     $dir = "./";
1561   }
1562   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1563   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1564   $version ||= $schema->VERSION || '1.x';
1565   $sqltargs = {
1566     add_drop_table => 1,
1567     ignore_constraint_names => 1,
1568     ignore_index_names => 1,
1569     %{$sqltargs || {}}
1570   };
1571
1572   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09: '}
1573       . $self->_check_sqlt_message . q{'})
1574           if !$self->_check_sqlt_version;
1575
1576   my $sqlt = SQL::Translator->new( $sqltargs );
1577
1578   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1579   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1580
1581   foreach my $db (@$databases) {
1582     $sqlt->reset();
1583     $sqlt = $self->configure_sqlt($sqlt, $db);
1584     $sqlt->{schema} = $sqlt_schema;
1585     $sqlt->producer($db);
1586
1587     my $file;
1588     my $filename = $schema->ddl_filename($db, $version, $dir);
1589     if (-e $filename && (!$version || ($version == $schema->schema_version()))) {
1590       # if we are dumping the current version, overwrite the DDL
1591       warn "Overwriting existing DDL file - $filename";
1592       unlink($filename);
1593     }
1594
1595     my $output = $sqlt->translate;
1596     if(!$output) {
1597       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1598       next;
1599     }
1600     if(!open($file, ">$filename")) {
1601       $self->throw_exception("Can't open $filename for writing ($!)");
1602       next;
1603     }
1604     print $file $output;
1605     close($file);
1606
1607     next unless ($preversion);
1608
1609     require SQL::Translator::Diff;
1610
1611     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1612     if(!-e $prefilename) {
1613       warn("No previous schema file found ($prefilename)");
1614       next;
1615     }
1616
1617     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1618     if(-e $difffile) {
1619       warn("Overwriting existing diff file - $difffile");
1620       unlink($difffile);
1621     }
1622
1623     my $source_schema;
1624     {
1625       my $t = SQL::Translator->new($sqltargs);
1626       $t->debug( 0 );
1627       $t->trace( 0 );
1628       $t->parser( $db )                       or die $t->error;
1629       $t = $self->configure_sqlt($t, $db);
1630       my $out = $t->translate( $prefilename ) or die $t->error;
1631       $source_schema = $t->schema;
1632       unless ( $source_schema->name ) {
1633         $source_schema->name( $prefilename );
1634       }
1635     }
1636
1637     # The "new" style of producers have sane normalization and can support
1638     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1639     # And we have to diff parsed SQL against parsed SQL.
1640     my $dest_schema = $sqlt_schema;
1641
1642     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1643       my $t = SQL::Translator->new($sqltargs);
1644       $t->debug( 0 );
1645       $t->trace( 0 );
1646       $t->parser( $db )                    or die $t->error;
1647       $t = $self->configure_sqlt($t, $db);
1648       my $out = $t->translate( $filename ) or die $t->error;
1649       $dest_schema = $t->schema;
1650       $dest_schema->name( $filename )
1651         unless $dest_schema->name;
1652     }
1653
1654     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1655                                                   $dest_schema,   $db,
1656                                                   $sqltargs
1657                                                  );
1658     if(!open $file, ">$difffile") {
1659       $self->throw_exception("Can't write to $difffile ($!)");
1660       next;
1661     }
1662     print $file $diff;
1663     close($file);
1664   }
1665 }
1666
1667 sub configure_sqlt() {
1668   my $self = shift;
1669   my $tr = shift;
1670   my $db = shift || $self->sqlt_type;
1671   if ($db eq 'PostgreSQL') {
1672     $tr->quote_table_names(0);
1673     $tr->quote_field_names(0);
1674   }
1675   return $tr;
1676 }
1677
1678 =head2 deployment_statements
1679
1680 =over 4
1681
1682 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1683
1684 =back
1685
1686 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1687 The database driver name is given by C<$type>, though the value from
1688 L</sqlt_type> is used if it is not specified.
1689
1690 C<$directory> is used to return statements from files in a previously created
1691 L</create_ddl_dir> directory and is optional. The filenames are constructed
1692 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1693
1694 If no C<$directory> is specified then the statements are constructed on the
1695 fly using L<SQL::Translator> and C<$version> is ignored.
1696
1697 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1698
1699 =cut
1700
1701 sub deployment_statements {
1702   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1703   # Need to be connected to get the correct sqlt_type
1704   $self->ensure_connected() unless $type;
1705   $type ||= $self->sqlt_type;
1706   $version ||= $schema->VERSION || '1.x';
1707   $dir ||= './';
1708   my $filename = $schema->ddl_filename($type, $dir, $version);
1709   if(-f $filename)
1710   {
1711       my $file;
1712       open($file, "<$filename")
1713         or $self->throw_exception("Can't open $filename ($!)");
1714       my @rows = <$file>;
1715       close($file);
1716       return join('', @rows);
1717   }
1718
1719   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09: '}
1720       . $self->_check_sqlt_message . q{'})
1721           if !$self->_check_sqlt_version;
1722
1723   require SQL::Translator::Parser::DBIx::Class;
1724   eval qq{use SQL::Translator::Producer::${type}};
1725   $self->throw_exception($@) if $@;
1726
1727   # sources needs to be a parser arg, but for simplicty allow at top level
1728   # coming in
1729   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1730       if exists $sqltargs->{sources};
1731
1732   my $tr = SQL::Translator->new(%$sqltargs);
1733   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1734   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1735 }
1736
1737 sub deploy {
1738   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1739   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1740     foreach my $line ( split(";\n", $statement)) {
1741       next if($line =~ /^--/);
1742       next if(!$line);
1743 #      next if($line =~ /^DROP/m);
1744       next if($line =~ /^BEGIN TRANSACTION/m);
1745       next if($line =~ /^COMMIT/m);
1746       next if $line =~ /^\s+$/; # skip whitespace only
1747       $self->_query_start($line);
1748       eval {
1749         $self->dbh->do($line); # shouldn't be using ->dbh ?
1750       };
1751       if ($@) {
1752         warn qq{$@ (running "${line}")};
1753       }
1754       $self->_query_end($line);
1755     }
1756   }
1757 }
1758
1759 =head2 datetime_parser
1760
1761 Returns the datetime parser class
1762
1763 =cut
1764
1765 sub datetime_parser {
1766   my $self = shift;
1767   return $self->{datetime_parser} ||= do {
1768     $self->ensure_connected;
1769     $self->build_datetime_parser(@_);
1770   };
1771 }
1772
1773 =head2 datetime_parser_type
1774
1775 Defines (returns) the datetime parser class - currently hardwired to
1776 L<DateTime::Format::MySQL>
1777
1778 =cut
1779
1780 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1781
1782 =head2 build_datetime_parser
1783
1784 See L</datetime_parser>
1785
1786 =cut
1787
1788 sub build_datetime_parser {
1789   my $self = shift;
1790   my $type = $self->datetime_parser_type(@_);
1791   eval "use ${type}";
1792   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1793   return $type;
1794 }
1795
1796 {
1797     my $_check_sqlt_version; # private
1798     my $_check_sqlt_message; # private
1799     sub _check_sqlt_version {
1800         return $_check_sqlt_version if defined $_check_sqlt_version;
1801         eval 'use SQL::Translator "0.09"';
1802         $_check_sqlt_message = $@ || '';
1803         $_check_sqlt_version = !$@;
1804     }
1805
1806     sub _check_sqlt_message {
1807         _check_sqlt_version if !defined $_check_sqlt_message;
1808         $_check_sqlt_message;
1809     }
1810 }
1811
1812 =head2 is_replicating
1813
1814 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1815 replicate from a master database.  Default is undef, which is the result
1816 returned by databases that don't support replication.
1817
1818 =cut
1819
1820 sub is_replicating {
1821     return;
1822
1823 }
1824
1825 =head2 lag_behind_master
1826
1827 Returns a number that represents a certain amount of lag behind a master db
1828 when a given storage is replicating.  The number is database dependent, but
1829 starts at zero and increases with the amount of lag. Default in undef
1830
1831 =cut
1832
1833 sub lag_behind_master {
1834     return;
1835 }
1836
1837 sub DESTROY {
1838   my $self = shift;
1839   return if !$self->_dbh;
1840   $self->_verify_pid;
1841   $self->_dbh(undef);
1842 }
1843
1844 1;
1845
1846 =head1 USAGE NOTES
1847
1848 =head2 DBIx::Class and AutoCommit
1849
1850 DBIx::Class can do some wonderful magic with handling exceptions,
1851 disconnections, and transactions when you use C<< AutoCommit => 1 >>
1852 combined with C<txn_do> for transaction support.
1853
1854 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
1855 in an assumed transaction between commits, and you're telling us you'd
1856 like to manage that manually.  A lot of the magic protections offered by
1857 this module will go away.  We can't protect you from exceptions due to database
1858 disconnects because we don't know anything about how to restart your
1859 transactions.  You're on your own for handling all sorts of exceptional
1860 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
1861 be with raw DBI.
1862
1863
1864 =head1 SQL METHODS
1865
1866 The module defines a set of methods within the DBIC::SQL::Abstract
1867 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1868 SQL query functions.
1869
1870 The following methods are extended:-
1871
1872 =over 4
1873
1874 =item delete
1875
1876 =item insert
1877
1878 =item select
1879
1880 =item update
1881
1882 =item limit_dialect
1883
1884 See L</connect_info> for details.
1885 For setting, this method is deprecated in favor of L</connect_info>.
1886
1887 =item quote_char
1888
1889 See L</connect_info> for details.
1890 For setting, this method is deprecated in favor of L</connect_info>.
1891
1892 =item name_sep
1893
1894 See L</connect_info> for details.
1895 For setting, this method is deprecated in favor of L</connect_info>.
1896
1897 =back
1898
1899 =head1 AUTHORS
1900
1901 Matt S. Trout <mst@shadowcatsystems.co.uk>
1902
1903 Andy Grundman <andy@hybridized.org>
1904
1905 =head1 LICENSE
1906
1907 You may distribute this code under the same terms as Perl itself.
1908
1909 =cut