lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid transaction_depth _dbh_autocommit savepoints/
  18 );
  19
  20 # the values for these accessors are picked out (and deleted) from
  21 # the attribute hashref passed to connect_info
  22 my @storage_options = qw/
  23   on_connect_do on_disconnect_do disable_sth_caching unsafe auto_savepoint
  24 /;
  25 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  26
  27
  28 # default cursor class, overridable in connect_info attributes
  29 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  30
  31 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  32 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  33
  34 BEGIN {
  35
  36 package # Hide from PAUSE
  37   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  38
  39 use base qw/SQL::Abstract::Limit/;
  40 use Carp::Clan qw/^DBIx::Class/;
  41
  42 sub new {
  43   my $self = shift->SUPER::new(@_);
  44
  45   # This prevents the caching of $dbh in S::A::L, I believe
  46   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  47   #   it with what it resolves to:
  48   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  49     if ref $self->{limit_dialect};
  50
  51   $self;
  52 }
  53
  54
  55
  56 # Some databases (sqlite) do not handle multiple parenthesis
  57 # around in/between arguments. A tentative x IN ( ( 1, 2 ,3) )
  58 # is interpreted as x IN 1 or something similar.
  59 #
  60 # Since we currently do not have access to the SQLA AST, resort
  61 # to barbaric mutilation of any SQL supplied in literal form
  62
  63 sub _strip_outer_paren {
  64   my ($self, $arg) = @_;
  65
  66   return $self->_SWITCH_refkind ($arg, {
  67     ARRAYREFREF => sub {
  68       $$arg->[0] = __strip_outer_paren ($$arg->[0]);
  69       return $arg;
  70     },
  71     SCALARREF => sub {
  72       return \__strip_outer_paren( $$arg );
  73     },
  74     FALLBACK => sub {
  75       return $arg
  76     },
  77   });
  78 }
  79
  80 sub __strip_outer_paren {
  81   my $sql = shift;
  82
  83   if ($sql and not ref $sql) {
  84     while ($sql =~ /^ \s* \( (.*) \) \s* $/x ) {
  85       $sql = $1;
  86     }
  87   }
  88
  89   return $sql;
  90 }
  91
  92 sub _where_field_IN {
  93   my ($self, $lhs, $op, $rhs) = @_;
  94   $rhs = $self->_strip_outer_paren ($rhs);
  95   return $self->SUPER::_where_field_IN ($lhs, $op, $rhs);
  96 }
  97
  98 sub _where_field_BETWEEN {
  99   my ($self, $lhs, $op, $rhs) = @_;
 100   $rhs = $self->_strip_outer_paren ($rhs);
 101   return $self->SUPER::_where_field_BETWEEN ($lhs, $op, $rhs);
 102 }
 103
 104
 105
 106 # DB2 is the only remaining DB using this. Even though we are not sure if
 107 # RowNumberOver is still needed here (should be part of SQLA) leave the
 108 # code in place
 109 sub _RowNumberOver {
 110   my ($self, $sql, $order, $rows, $offset ) = @_;
 111
 112   $offset += 1;
 113   my $last = $rows + $offset;
 114   my ( $order_by ) = $self->_order_by( $order );
 115
 116   $sql = <<"SQL";
 117 SELECT * FROM
 118 (
 119    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
 120       $sql
 121       $order_by
 122    ) Q1
 123 ) Q2
 124 WHERE ROW_NUM BETWEEN $offset AND $last
 125
 126 SQL
 127
 128   return $sql;
 129 }
 130
 131
 132 # While we're at it, this should make LIMIT queries more efficient,
 133 #  without digging into things too deeply
 134 use Scalar::Util 'blessed';
 135 sub _find_syntax {
 136   my ($self, $syntax) = @_;
 137
 138   # DB2 is the only remaining DB using this. Even though we are not sure if
 139   # RowNumberOver is still needed here (should be part of SQLA) leave the
 140   # code in place
 141   my $dbhname = blessed($syntax) ? $syntax->{Driver}{Name} : $syntax;
 142   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
 143     return 'RowNumberOver';
 144   }
 145
 146   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
 147 }
 148
 149 sub select {
 150   my ($self, $table, $fields, $where, $order, @rest) = @_;
 151   local $self->{having_bind} = [];
 152   local $self->{from_bind} = [];
 153
 154   if (ref $table eq 'SCALAR') {
 155     $table = $$table;
 156   }
 157   elsif (not ref $table) {
 158     $table = $self->_quote($table);
 159   }
 160   local $self->{rownum_hack_count} = 1
 161     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
 162   @rest = (-1) unless defined $rest[0];
 163   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
 164     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
 165   my ($sql, @where_bind) = $self->SUPER::select(
 166     $table, $self->_recurse_fields($fields), $where, $order, @rest
 167   );
 168   $sql .=
 169     $self->{for} ?
 170     (
 171       $self->{for} eq 'update' ? ' FOR UPDATE' :
 172       $self->{for} eq 'shared' ? ' FOR SHARE'  :
 173       ''
 174     ) :
 175     ''
 176   ;
 177   return wantarray ? ($sql, @{$self->{from_bind}}, @where_bind, @{$self->{having_bind}}) : $sql;
 178 }
 179
 180 sub insert {
 181   my $self = shift;
 182   my $table = shift;
 183   $table = $self->_quote($table) unless ref($table);
 184   $self->SUPER::insert($table, @_);
 185 }
 186
 187 sub update {
 188   my $self = shift;
 189   my $table = shift;
 190   $table = $self->_quote($table) unless ref($table);
 191   $self->SUPER::update($table, @_);
 192 }
 193
 194 sub delete {
 195   my $self = shift;
 196   my $table = shift;
 197   $table = $self->_quote($table) unless ref($table);
 198   $self->SUPER::delete($table, @_);
 199 }
 200
 201 sub _emulate_limit {
 202   my $self = shift;
 203   if ($_[3] == -1) {
 204     return $_[1].$self->_order_by($_[2]);
 205   } else {
 206     return $self->SUPER::_emulate_limit(@_);
 207   }
 208 }
 209
 210 sub _recurse_fields {
 211   my ($self, $fields, $params) = @_;
 212   my $ref = ref $fields;
 213   return $self->_quote($fields) unless $ref;
 214   return $$fields if $ref eq 'SCALAR';
 215
 216   if ($ref eq 'ARRAY') {
 217     return join(', ', map {
 218       $self->_recurse_fields($_)
 219         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 220           ? ' AS col'.$self->{rownum_hack_count}++
 221           : '')
 222       } @$fields);
 223   } elsif ($ref eq 'HASH') {
 224     foreach my $func (keys %$fields) {
 225       if ($func eq 'distinct') {
 226         my $_fields = $fields->{$func};
 227         if (ref $_fields eq 'ARRAY' && @{$_fields} > 1) {
 228           die "Unsupported syntax, please use " .
 229               "{ group_by => [ qw/" . (join ' ', @$_fields) . "/ ] }" .
 230               " or " .
 231               "{ select => [ qw/" . (join ' ', @$_fields) . "/ ], distinct => 1 }";
 232         }
 233         else {
 234           $_fields = @{$_fields}[0] if ref $_fields eq 'ARRAY';
 235           carp "This syntax will be deprecated in 09, please use " .
 236                "{ group_by => '${_fields}' }" .
 237                " or " .
 238                "{ select => '${_fields}', distinct => 1 }";
 239         }
 240       }
 241
 242       return $self->_sqlcase($func)
 243         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 244     }
 245   }
 246   # Is the second check absolutely necessary?
 247   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 248     return $self->_fold_sqlbind( $fields );
 249   }
 250   else {
 251     Carp::croak($ref . qq{ unexpected in _recurse_fields()})
 252   }
 253 }
 254
 255 sub _order_by {
 256   my $self = shift;
 257   my $ret = '';
 258   my @extra;
 259   if (ref $_[0] eq 'HASH') {
 260     if (defined $_[0]->{group_by}) {
 261       $ret = $self->_sqlcase(' group by ')
 262         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 263     }
 264     if (defined $_[0]->{having}) {
 265       my $frag;
 266       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 267       push(@{$self->{having_bind}}, @extra);
 268       $ret .= $self->_sqlcase(' having ').$frag;
 269     }
 270     if (defined $_[0]->{order_by}) {
 271       $ret .= $self->_order_by($_[0]->{order_by});
 272     }
 273     if (grep { $_ =~ /^-(desc|asc)/i } keys %{$_[0]}) {
 274       return $self->SUPER::_order_by($_[0]);
 275     }
 276   } elsif (ref $_[0] eq 'SCALAR') {
 277     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 278   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 279     my @order = @{+shift};
 280     $ret = $self->_sqlcase(' order by ')
 281           .join(', ', map {
 282                         my $r = $self->_order_by($_, @_);
 283                         $r =~ s/^ ?ORDER BY //i;
 284                         $r;
 285                       } @order);
 286   } else {
 287     $ret = $self->SUPER::_order_by(@_);
 288   }
 289   return $ret;
 290 }
 291
 292 sub _order_directions {
 293   my ($self, $order) = @_;
 294   $order = $order->{order_by} if ref $order eq 'HASH';
 295   return $self->SUPER::_order_directions($order);
 296 }
 297
 298 sub _table {
 299   my ($self, $from) = @_;
 300   if (ref $from eq 'ARRAY') {
 301     return $self->_recurse_from(@$from);
 302   } elsif (ref $from eq 'HASH') {
 303     return $self->_make_as($from);
 304   } else {
 305     return $from; # would love to quote here but _table ends up getting called
 306                   # twice during an ->select without a limit clause due to
 307                   # the way S::A::Limit->select works. should maybe consider
 308                   # bypassing this and doing S::A::select($self, ...) in
 309                   # our select method above. meantime, quoting shims have
 310                   # been added to select/insert/update/delete here
 311   }
 312 }
 313
 314 sub _recurse_from {
 315   my ($self, $from, @join) = @_;
 316   my @sqlf;
 317   push(@sqlf, $self->_make_as($from));
 318   foreach my $j (@join) {
 319     my ($to, $on) = @$j;
 320
 321     # check whether a join type exists
 322     my $join_clause = '';
 323     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 324     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 325       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 326     } else {
 327       $join_clause = ' JOIN ';
 328     }
 329     push(@sqlf, $join_clause);
 330
 331     if (ref $to eq 'ARRAY') {
 332       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 333     } else {
 334       push(@sqlf, $self->_make_as($to));
 335     }
 336     push(@sqlf, ' ON ', $self->_join_condition($on));
 337   }
 338   return join('', @sqlf);
 339 }
 340
 341 sub _fold_sqlbind {
 342   my ($self, $sqlbind) = @_;
 343   my $sql = shift @$$sqlbind;
 344   push @{$self->{from_bind}}, @$$sqlbind;
 345   return $sql;
 346 }
 347
 348 sub _make_as {
 349   my ($self, $from) = @_;
 350   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_
 351                         : ref $_ eq 'REF'    ? $self->_fold_sqlbind($_)
 352                         : $self->_quote($_))
 353                        } reverse each %{$self->_skip_options($from)});
 354 }
 355
 356 sub _skip_options {
 357   my ($self, $hash) = @_;
 358   my $clean_hash = {};
 359   $clean_hash->{$_} = $hash->{$_}
 360     for grep {!/^-/} keys %$hash;
 361   return $clean_hash;
 362 }
 363
 364 sub _join_condition {
 365   my ($self, $cond) = @_;
 366   if (ref $cond eq 'HASH') {
 367     my %j;
 368     for (keys %$cond) {
 369       my $v = $cond->{$_};
 370       if (ref $v) {
 371         # XXX no throw_exception() in this package and croak() fails with strange results
 372         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 373             if ref($v) ne 'SCALAR';
 374         $j{$_} = $v;
 375       }
 376       else {
 377         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 378       }
 379     };
 380     return scalar($self->_recurse_where(\%j));
 381   } elsif (ref $cond eq 'ARRAY') {
 382     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 383   } else {
 384     die "Can't handle this yet!";
 385   }
 386 }
 387
 388 sub _quote {
 389   my ($self, $label) = @_;
 390   return '' unless defined $label;
 391   return "*" if $label eq '*';
 392   return $label unless $self->{quote_char};
 393   if(ref $self->{quote_char} eq "ARRAY"){
 394     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 395       if !defined $self->{name_sep};
 396     my $sep = $self->{name_sep};
 397     return join($self->{name_sep},
 398         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 399        split(/\Q$sep\E/,$label));
 400   }
 401   return $self->SUPER::_quote($label);
 402 }
 403
 404 sub limit_dialect {
 405     my $self = shift;
 406     $self->{limit_dialect} = shift if @_;
 407     return $self->{limit_dialect};
 408 }
 409
 410 sub quote_char {
 411     my $self = shift;
 412     $self->{quote_char} = shift if @_;
 413     return $self->{quote_char};
 414 }
 415
 416 sub name_sep {
 417     my $self = shift;
 418     $self->{name_sep} = shift if @_;
 419     return $self->{name_sep};
 420 }
 421
 422 } # End of BEGIN block
 423
 424 =head1 NAME
 425
 426 DBIx::Class::Storage::DBI - DBI storage handler
 427
 428 =head1 SYNOPSIS
 429
 430   my $schema = MySchema->connect('dbi:SQLite:my.db');
 431
 432   $schema->storage->debug(1);
 433   $schema->dbh_do("DROP TABLE authors");
 434
 435   $schema->resultset('Book')->search({
 436      written_on => $schema->storage->datetime_parser(DateTime->now)
 437   });
 438
 439 =head1 DESCRIPTION
 440
 441 This class represents the connection to an RDBMS via L<DBI>.  See
 442 L<DBIx::Class::Storage> for general information.  This pod only
 443 documents DBI-specific methods and behaviors.
 444
 445 =head1 METHODS
 446
 447 =cut
 448
 449 sub new {
 450   my $new = shift->next::method(@_);
 451
 452   $new->transaction_depth(0);
 453   $new->_sql_maker_opts({});
 454   $new->{savepoints} = [];
 455   $new->{_in_dbh_do} = 0;
 456   $new->{_dbh_gen} = 0;
 457
 458   $new;
 459 }
 460
 461 =head2 connect_info
 462
 463 This method is normally called by L<DBIx::Class::Schema/connection>, which
 464 encapsulates its argument list in an arrayref before passing them here.
 465
 466 The argument list may contain:
 467
 468 =over
 469
 470 =item *
 471
 472 The same 4-element argument set one would normally pass to
 473 L<DBI/connect>, optionally followed by
 474 L<extra attributes|/DBIx::Class specific connection attributes>
 475 recognized by DBIx::Class:
 476
 477   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 478
 479 =item *
 480
 481 A single code reference which returns a connected
 482 L<DBI database handle|DBI/connect> optionally followed by
 483 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 484 by DBIx::Class:
 485
 486   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 487
 488 =item *
 489
 490 A single hashref with all the attributes and the dsn/user/password
 491 mixed together:
 492
 493   $connect_info_args = [{
 494     dsn => $dsn,
 495     user => $user,
 496     password => $pass,
 497     %dbi_attributes,
 498     %extra_attributes,
 499   }];
 500
 501 This is particularly useful for L<Catalyst> based applications, allowing the
 502 following config (L<Config::General> style):
 503
 504   <Model::DB>
 505     schema_class   App::DB
 506     <connect_info>
 507       dsn          dbi:mysql:database=test
 508       user         testuser
 509       password     TestPass
 510       AutoCommit   1
 511     </connect_info>
 512   </Model::DB>
 513
 514 =back
 515
 516 Please note that the L<DBI> docs recommend that you always explicitly
 517 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 518 recommends that it be set to I<1>, and that you perform transactions
 519 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 520 to I<1> if you do not do explicitly set it to zero.  This is the default
 521 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 522
 523 =head3 DBIx::Class specific connection attributes
 524
 525 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 526 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 527 the following connection options. These options can be mixed in with your other
 528 L<DBI> connection attributes, or placed in a seperate hashref
 529 (C<\%extra_attributes>) as shown above.
 530
 531 Every time C<connect_info> is invoked, any previous settings for
 532 these options will be cleared before setting the new ones, regardless of
 533 whether any options are specified in the new C<connect_info>.
 534
 535
 536 =over
 537
 538 =item on_connect_do
 539
 540 Specifies things to do immediately after connecting or re-connecting to
 541 the database.  Its value may contain:
 542
 543 =over
 544
 545 =item an array reference
 546
 547 This contains SQL statements to execute in order.  Each element contains
 548 a string or a code reference that returns a string.
 549
 550 =item a code reference
 551
 552 This contains some code to execute.  Unlike code references within an
 553 array reference, its return value is ignored.
 554
 555 =back
 556
 557 =item on_disconnect_do
 558
 559 Takes arguments in the same form as L</on_connect_do> and executes them
 560 immediately before disconnecting from the database.
 561
 562 Note, this only runs if you explicitly call L</disconnect> on the
 563 storage object.
 564
 565 =item disable_sth_caching
 566
 567 If set to a true value, this option will disable the caching of
 568 statement handles via L<DBI/prepare_cached>.
 569
 570 =item limit_dialect
 571
 572 Sets the limit dialect. This is useful for JDBC-bridge among others
 573 where the remote SQL-dialect cannot be determined by the name of the
 574 driver alone. See also L<SQL::Abstract::Limit>.
 575
 576 =item quote_char
 577
 578 Specifies what characters to use to quote table and column names. If
 579 you use this you will want to specify L</name_sep> as well.
 580
 581 C<quote_char> expects either a single character, in which case is it
 582 is placed on either side of the table/column name, or an arrayref of length
 583 2 in which case the table/column name is placed between the elements.
 584
 585 For example under MySQL you should use C<< quote_char => '`' >>, and for
 586 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 587
 588 =item name_sep
 589
 590 This only needs to be used in conjunction with C<quote_char>, and is used to
 591 specify the charecter that seperates elements (schemas, tables, columns) from
 592 each other. In most cases this is simply a C<.>.
 593
 594 The consequences of not supplying this value is that L<SQL::Abstract>
 595 will assume DBIx::Class' uses of aliases to be complete column
 596 names. The output will look like I<"me.name"> when it should actually
 597 be I<"me"."name">.
 598
 599 =item unsafe
 600
 601 This Storage driver normally installs its own C<HandleError>, sets
 602 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 603 all database handles, including those supplied by a coderef.  It does this
 604 so that it can have consistent and useful error behavior.
 605
 606 If you set this option to a true value, Storage will not do its usual
 607 modifications to the database handle's attributes, and instead relies on
 608 the settings in your connect_info DBI options (or the values you set in
 609 your connection coderef, in the case that you are connecting via coderef).
 610
 611 Note that your custom settings can cause Storage to malfunction,
 612 especially if you set a C<HandleError> handler that suppresses exceptions
 613 and/or disable C<RaiseError>.
 614
 615 =item auto_savepoint
 616
 617 If this option is true, L<DBIx::Class> will use savepoints when nesting
 618 transactions, making it possible to recover from failure in the inner
 619 transaction without having to abort all outer transactions.
 620
 621 =item cursor_class
 622
 623 Use this argument to supply a cursor class other than the default
 624 L<DBIx::Class::Storage::DBI::Cursor>.
 625
 626 =back
 627
 628 Some real-life examples of arguments to L</connect_info> and
 629 L<DBIx::Class::Schema/connect>
 630
 631   # Simple SQLite connection
 632   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 633
 634   # Connect via subref
 635   ->connect_info([ sub { DBI->connect(...) } ]);
 636
 637   # A bit more complicated
 638   ->connect_info(
 639     [
 640       'dbi:Pg:dbname=foo',
 641       'postgres',
 642       'my_pg_password',
 643       { AutoCommit => 1 },
 644       { quote_char => q{"}, name_sep => q{.} },
 645     ]
 646   );
 647
 648   # Equivalent to the previous example
 649   ->connect_info(
 650     [
 651       'dbi:Pg:dbname=foo',
 652       'postgres',
 653       'my_pg_password',
 654       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 655     ]
 656   );
 657
 658   # Same, but with hashref as argument
 659   # See parse_connect_info for explanation
 660   ->connect_info(
 661     [{
 662       dsn         => 'dbi:Pg:dbname=foo',
 663       user        => 'postgres',
 664       password    => 'my_pg_password',
 665       AutoCommit  => 1,
 666       quote_char  => q{"},
 667       name_sep    => q{.},
 668     }]
 669   );
 670
 671   # Subref + DBIx::Class-specific connection options
 672   ->connect_info(
 673     [
 674       sub { DBI->connect(...) },
 675       {
 676           quote_char => q{`},
 677           name_sep => q{@},
 678           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 679           disable_sth_caching => 1,
 680       },
 681     ]
 682   );
 683
 684
 685
 686 =cut
 687
 688 sub connect_info {
 689   my ($self, $info_arg) = @_;
 690
 691   return $self->_connect_info if !$info_arg;
 692
 693   my @args = @$info_arg;  # take a shallow copy for further mutilation
 694   $self->_connect_info([@args]); # copy for _connect_info
 695
 696
 697   # combine/pre-parse arguments depending on invocation style
 698
 699   my %attrs;
 700   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 701     %attrs = %{ $args[1] || {} };
 702     @args = $args[0];
 703   }
 704   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 705     %attrs = %{$args[0]};
 706     @args = ();
 707     for (qw/password user dsn/) {
 708       unshift @args, delete $attrs{$_};
 709     }
 710   }
 711   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 712     %attrs = (
 713       % { $args[3] || {} },
 714       % { $args[4] || {} },
 715     );
 716     @args = @args[0,1,2];
 717   }
 718
 719   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 720   #  the new set of options
 721   $self->_sql_maker(undef);
 722   $self->_sql_maker_opts({});
 723
 724   if(keys %attrs) {
 725     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 726       if(my $value = delete $attrs{$storage_opt}) {
 727         $self->$storage_opt($value);
 728       }
 729     }
 730     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 731       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 732         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 733       }
 734     }
 735   }
 736
 737   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 738
 739   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 740   $self->_connect_info;
 741 }
 742
 743 =head2 on_connect_do
 744
 745 This method is deprecated in favour of setting via L</connect_info>.
 746
 747
 748 =head2 dbh_do
 749
 750 Arguments: ($subref | $method_name), @extra_coderef_args?
 751
 752 Execute the given $subref or $method_name using the new exception-based
 753 connection management.
 754
 755 The first two arguments will be the storage object that C<dbh_do> was called
 756 on and a database handle to use.  Any additional arguments will be passed
 757 verbatim to the called subref as arguments 2 and onwards.
 758
 759 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 760 exception handling and reconnection (or failover in future subclasses).
 761
 762 Your subref should have no side-effects outside of the database, as
 763 there is the potential for your subref to be partially double-executed
 764 if the database connection was stale/dysfunctional.
 765
 766 Example:
 767
 768   my @stuff = $schema->storage->dbh_do(
 769     sub {
 770       my ($storage, $dbh, @cols) = @_;
 771       my $cols = join(q{, }, @cols);
 772       $dbh->selectrow_array("SELECT $cols FROM foo");
 773     },
 774     @column_list
 775   );
 776
 777 =cut
 778
 779 sub dbh_do {
 780   my $self = shift;
 781   my $code = shift;
 782
 783   my $dbh = $self->_dbh;
 784
 785   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 786       || $self->{transaction_depth};
 787
 788   local $self->{_in_dbh_do} = 1;
 789
 790   my @result;
 791   my $want_array = wantarray;
 792
 793   eval {
 794     $self->_verify_pid if $dbh;
 795     if(!$self->_dbh) {
 796         $self->_populate_dbh;
 797         $dbh = $self->_dbh;
 798     }
 799
 800     if($want_array) {
 801         @result = $self->$code($dbh, @_);
 802     }
 803     elsif(defined $want_array) {
 804         $result[0] = $self->$code($dbh, @_);
 805     }
 806     else {
 807         $self->$code($dbh, @_);
 808     }
 809   };
 810
 811   my $exception = $@;
 812   if(!$exception) { return $want_array ? @result : $result[0] }
 813
 814   $self->throw_exception($exception) if $self->connected;
 815
 816   # We were not connected - reconnect and retry, but let any
 817   #  exception fall right through this time
 818   $self->_populate_dbh;
 819   $self->$code($self->_dbh, @_);
 820 }
 821
 822 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 823 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 824 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 825 sub txn_do {
 826   my $self = shift;
 827   my $coderef = shift;
 828
 829   ref $coderef eq 'CODE' or $self->throw_exception
 830     ('$coderef must be a CODE reference');
 831
 832   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 833
 834   local $self->{_in_dbh_do} = 1;
 835
 836   my @result;
 837   my $want_array = wantarray;
 838
 839   my $tried = 0;
 840   while(1) {
 841     eval {
 842       $self->_verify_pid if $self->_dbh;
 843       $self->_populate_dbh if !$self->_dbh;
 844
 845       $self->txn_begin;
 846       if($want_array) {
 847           @result = $coderef->(@_);
 848       }
 849       elsif(defined $want_array) {
 850           $result[0] = $coderef->(@_);
 851       }
 852       else {
 853           $coderef->(@_);
 854       }
 855       $self->txn_commit;
 856     };
 857
 858     my $exception = $@;
 859     if(!$exception) { return $want_array ? @result : $result[0] }
 860
 861     if($tried++ > 0 || $self->connected) {
 862       eval { $self->txn_rollback };
 863       my $rollback_exception = $@;
 864       if($rollback_exception) {
 865         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 866         $self->throw_exception($exception)  # propagate nested rollback
 867           if $rollback_exception =~ /$exception_class/;
 868
 869         $self->throw_exception(
 870           "Transaction aborted: ${exception}. "
 871           . "Rollback failed: ${rollback_exception}"
 872         );
 873       }
 874       $self->throw_exception($exception)
 875     }
 876
 877     # We were not connected, and was first try - reconnect and retry
 878     # via the while loop
 879     $self->_populate_dbh;
 880   }
 881 }
 882
 883 =head2 disconnect
 884
 885 Our C<disconnect> method also performs a rollback first if the
 886 database is not in C<AutoCommit> mode.
 887
 888 =cut
 889
 890 sub disconnect {
 891   my ($self) = @_;
 892
 893   if( $self->connected ) {
 894     my $connection_do = $self->on_disconnect_do;
 895     $self->_do_connection_actions($connection_do) if ref($connection_do);
 896
 897     $self->_dbh->rollback unless $self->_dbh_autocommit;
 898     $self->_dbh->disconnect;
 899     $self->_dbh(undef);
 900     $self->{_dbh_gen}++;
 901   }
 902 }
 903
 904 =head2 with_deferred_fk_checks
 905
 906 =over 4
 907
 908 =item Arguments: C<$coderef>
 909
 910 =item Return Value: The return value of $coderef
 911
 912 =back
 913
 914 Storage specific method to run the code ref with FK checks deferred or
 915 in MySQL's case disabled entirely.
 916
 917 =cut
 918
 919 # Storage subclasses should override this
 920 sub with_deferred_fk_checks {
 921   my ($self, $sub) = @_;
 922
 923   $sub->();
 924 }
 925
 926 sub connected {
 927   my ($self) = @_;
 928
 929   if(my $dbh = $self->_dbh) {
 930       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 931           $self->_dbh(undef);
 932           $self->{_dbh_gen}++;
 933           return;
 934       }
 935       else {
 936           $self->_verify_pid;
 937           return 0 if !$self->_dbh;
 938       }
 939       return ($dbh->FETCH('Active') && $dbh->ping);
 940   }
 941
 942   return 0;
 943 }
 944
 945 # handle pid changes correctly
 946 #  NOTE: assumes $self->_dbh is a valid $dbh
 947 sub _verify_pid {
 948   my ($self) = @_;
 949
 950   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 951
 952   $self->_dbh->{InactiveDestroy} = 1;
 953   $self->_dbh(undef);
 954   $self->{_dbh_gen}++;
 955
 956   return;
 957 }
 958
 959 sub ensure_connected {
 960   my ($self) = @_;
 961
 962   unless ($self->connected) {
 963     $self->_populate_dbh;
 964   }
 965 }
 966
 967 =head2 dbh
 968
 969 Returns the dbh - a data base handle of class L<DBI>.
 970
 971 =cut
 972
 973 sub dbh {
 974   my ($self) = @_;
 975
 976   $self->ensure_connected;
 977   return $self->_dbh;
 978 }
 979
 980 sub _sql_maker_args {
 981     my ($self) = @_;
 982
 983     return ( bindtype=>'columns', array_datatypes => 1, limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 984 }
 985
 986 sub sql_maker {
 987   my ($self) = @_;
 988   unless ($self->_sql_maker) {
 989     my $sql_maker_class = $self->sql_maker_class;
 990     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 991   }
 992   return $self->_sql_maker;
 993 }
 994
 995 sub _rebless {}
 996
 997 sub _populate_dbh {
 998   my ($self) = @_;
 999   my @info = @{$self->_dbi_connect_info || []};
1000   $self->_dbh($self->_connect(@info));
1001
1002   # Always set the transaction depth on connect, since
1003   #  there is no transaction in progress by definition
1004   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1005
1006   if(ref $self eq 'DBIx::Class::Storage::DBI') {
1007     my $driver = $self->_dbh->{Driver}->{Name};
1008     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
1009       bless $self, "DBIx::Class::Storage::DBI::${driver}";
1010       $self->_rebless();
1011     }
1012   }
1013
1014   $self->_conn_pid($$);
1015   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
1016
1017   my $connection_do = $self->on_connect_do;
1018   $self->_do_connection_actions($connection_do) if ref($connection_do);
1019 }
1020
1021 sub _do_connection_actions {
1022   my $self = shift;
1023   my $connection_do = shift;
1024
1025   if (ref $connection_do eq 'ARRAY') {
1026     $self->_do_query($_) foreach @$connection_do;
1027   }
1028   elsif (ref $connection_do eq 'CODE') {
1029     $connection_do->($self);
1030   }
1031
1032   return $self;
1033 }
1034
1035 sub _do_query {
1036   my ($self, $action) = @_;
1037
1038   if (ref $action eq 'CODE') {
1039     $action = $action->($self);
1040     $self->_do_query($_) foreach @$action;
1041   }
1042   else {
1043     # Most debuggers expect ($sql, @bind), so we need to exclude
1044     # the attribute hash which is the second argument to $dbh->do
1045     # furthermore the bind values are usually to be presented
1046     # as named arrayref pairs, so wrap those here too
1047     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1048     my $sql = shift @do_args;
1049     my $attrs = shift @do_args;
1050     my @bind = map { [ undef, $_ ] } @do_args;
1051
1052     $self->_query_start($sql, @bind);
1053     $self->_dbh->do($sql, $attrs, @do_args);
1054     $self->_query_end($sql, @bind);
1055   }
1056
1057   return $self;
1058 }
1059
1060 sub _connect {
1061   my ($self, @info) = @_;
1062
1063   $self->throw_exception("You failed to provide any connection info")
1064     if !@info;
1065
1066   my ($old_connect_via, $dbh);
1067
1068   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
1069     $old_connect_via = $DBI::connect_via;
1070     $DBI::connect_via = 'connect';
1071   }
1072
1073   eval {
1074     if(ref $info[0] eq 'CODE') {
1075        $dbh = &{$info[0]}
1076     }
1077     else {
1078        $dbh = DBI->connect(@info);
1079     }
1080
1081     if($dbh && !$self->unsafe) {
1082       my $weak_self = $self;
1083       weaken($weak_self);
1084       $dbh->{HandleError} = sub {
1085           if ($weak_self) {
1086             $weak_self->throw_exception("DBI Exception: $_[0]");
1087           }
1088           else {
1089             croak ("DBI Exception: $_[0]");
1090           }
1091       };
1092       $dbh->{ShowErrorStatement} = 1;
1093       $dbh->{RaiseError} = 1;
1094       $dbh->{PrintError} = 0;
1095     }
1096   };
1097
1098   $DBI::connect_via = $old_connect_via if $old_connect_via;
1099
1100   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
1101     if !$dbh || $@;
1102
1103   $self->_dbh_autocommit($dbh->{AutoCommit});
1104
1105   $dbh;
1106 }
1107
1108 sub svp_begin {
1109   my ($self, $name) = @_;
1110
1111   $name = $self->_svp_generate_name
1112     unless defined $name;
1113
1114   $self->throw_exception ("You can't use savepoints outside a transaction")
1115     if $self->{transaction_depth} == 0;
1116
1117   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1118     unless $self->can('_svp_begin');
1119
1120   push @{ $self->{savepoints} }, $name;
1121
1122   $self->debugobj->svp_begin($name) if $self->debug;
1123
1124   return $self->_svp_begin($name);
1125 }
1126
1127 sub svp_release {
1128   my ($self, $name) = @_;
1129
1130   $self->throw_exception ("You can't use savepoints outside a transaction")
1131     if $self->{transaction_depth} == 0;
1132
1133   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1134     unless $self->can('_svp_release');
1135
1136   if (defined $name) {
1137     $self->throw_exception ("Savepoint '$name' does not exist")
1138       unless grep { $_ eq $name } @{ $self->{savepoints} };
1139
1140     # Dig through the stack until we find the one we are releasing.  This keeps
1141     # the stack up to date.
1142     my $svp;
1143
1144     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1145   } else {
1146     $name = pop @{ $self->{savepoints} };
1147   }
1148
1149   $self->debugobj->svp_release($name) if $self->debug;
1150
1151   return $self->_svp_release($name);
1152 }
1153
1154 sub svp_rollback {
1155   my ($self, $name) = @_;
1156
1157   $self->throw_exception ("You can't use savepoints outside a transaction")
1158     if $self->{transaction_depth} == 0;
1159
1160   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1161     unless $self->can('_svp_rollback');
1162
1163   if (defined $name) {
1164       # If they passed us a name, verify that it exists in the stack
1165       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1166           $self->throw_exception("Savepoint '$name' does not exist!");
1167       }
1168
1169       # Dig through the stack until we find the one we are releasing.  This keeps
1170       # the stack up to date.
1171       while(my $s = pop(@{ $self->{savepoints} })) {
1172           last if($s eq $name);
1173       }
1174       # Add the savepoint back to the stack, as a rollback doesn't remove the
1175       # named savepoint, only everything after it.
1176       push(@{ $self->{savepoints} }, $name);
1177   } else {
1178       # We'll assume they want to rollback to the last savepoint
1179       $name = $self->{savepoints}->[-1];
1180   }
1181
1182   $self->debugobj->svp_rollback($name) if $self->debug;
1183
1184   return $self->_svp_rollback($name);
1185 }
1186
1187 sub _svp_generate_name {
1188     my ($self) = @_;
1189
1190     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1191 }
1192
1193 sub txn_begin {
1194   my $self = shift;
1195   $self->ensure_connected();
1196   if($self->{transaction_depth} == 0) {
1197     $self->debugobj->txn_begin()
1198       if $self->debug;
1199     # this isn't ->_dbh-> because
1200     #  we should reconnect on begin_work
1201     #  for AutoCommit users
1202     $self->dbh->begin_work;
1203   } elsif ($self->auto_savepoint) {
1204     $self->svp_begin;
1205   }
1206   $self->{transaction_depth}++;
1207 }
1208
1209 sub txn_commit {
1210   my $self = shift;
1211   if ($self->{transaction_depth} == 1) {
1212     my $dbh = $self->_dbh;
1213     $self->debugobj->txn_commit()
1214       if ($self->debug);
1215     $dbh->commit;
1216     $self->{transaction_depth} = 0
1217       if $self->_dbh_autocommit;
1218   }
1219   elsif($self->{transaction_depth} > 1) {
1220     $self->{transaction_depth}--;
1221     $self->svp_release
1222       if $self->auto_savepoint;
1223   }
1224 }
1225
1226 sub txn_rollback {
1227   my $self = shift;
1228   my $dbh = $self->_dbh;
1229   eval {
1230     if ($self->{transaction_depth} == 1) {
1231       $self->debugobj->txn_rollback()
1232         if ($self->debug);
1233       $self->{transaction_depth} = 0
1234         if $self->_dbh_autocommit;
1235       $dbh->rollback;
1236     }
1237     elsif($self->{transaction_depth} > 1) {
1238       $self->{transaction_depth}--;
1239       if ($self->auto_savepoint) {
1240         $self->svp_rollback;
1241         $self->svp_release;
1242       }
1243     }
1244     else {
1245       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1246     }
1247   };
1248   if ($@) {
1249     my $error = $@;
1250     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1251     $error =~ /$exception_class/ and $self->throw_exception($error);
1252     # ensure that a failed rollback resets the transaction depth
1253     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1254     $self->throw_exception($error);
1255   }
1256 }
1257
1258 # This used to be the top-half of _execute.  It was split out to make it
1259 #  easier to override in NoBindVars without duping the rest.  It takes up
1260 #  all of _execute's args, and emits $sql, @bind.
1261 sub _prep_for_execute {
1262   my ($self, $op, $extra_bind, $ident, $args) = @_;
1263
1264   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1265     $ident = $ident->from();
1266   }
1267
1268   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1269
1270   unshift(@bind,
1271     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1272       if $extra_bind;
1273   return ($sql, \@bind);
1274 }
1275
1276 sub _fix_bind_params {
1277     my ($self, @bind) = @_;
1278
1279     ### Turn @bind from something like this:
1280     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1281     ### to this:
1282     ###   ( "'1'", "'1'", "'3'" )
1283     return
1284         map {
1285             if ( defined( $_ && $_->[1] ) ) {
1286                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1287             }
1288             else { q{'NULL'}; }
1289         } @bind;
1290 }
1291
1292 sub _query_start {
1293     my ( $self, $sql, @bind ) = @_;
1294
1295     if ( $self->debug ) {
1296         @bind = $self->_fix_bind_params(@bind);
1297
1298         $self->debugobj->query_start( $sql, @bind );
1299     }
1300 }
1301
1302 sub _query_end {
1303     my ( $self, $sql, @bind ) = @_;
1304
1305     if ( $self->debug ) {
1306         @bind = $self->_fix_bind_params(@bind);
1307         $self->debugobj->query_end( $sql, @bind );
1308     }
1309 }
1310
1311 sub _dbh_execute {
1312   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1313
1314   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1315
1316   $self->_query_start( $sql, @$bind );
1317
1318   my $sth = $self->sth($sql,$op);
1319
1320   my $placeholder_index = 1;
1321
1322   foreach my $bound (@$bind) {
1323     my $attributes = {};
1324     my($column_name, @data) = @$bound;
1325
1326     if ($bind_attributes) {
1327       $attributes = $bind_attributes->{$column_name}
1328       if defined $bind_attributes->{$column_name};
1329     }
1330
1331     foreach my $data (@data) {
1332       my $ref = ref $data;
1333       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1334
1335       $sth->bind_param($placeholder_index, $data, $attributes);
1336       $placeholder_index++;
1337     }
1338   }
1339
1340   # Can this fail without throwing an exception anyways???
1341   my $rv = $sth->execute();
1342   $self->throw_exception($sth->errstr) if !$rv;
1343
1344   $self->_query_end( $sql, @$bind );
1345
1346   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1347 }
1348
1349 sub _execute {
1350     my $self = shift;
1351     $self->dbh_do('_dbh_execute', @_)
1352 }
1353
1354 sub insert {
1355   my ($self, $source, $to_insert) = @_;
1356
1357   my $ident = $source->from;
1358   my $bind_attributes = $self->source_bind_attributes($source);
1359
1360   my $updated_cols = {};
1361
1362   $self->ensure_connected;
1363   foreach my $col ( $source->columns ) {
1364     if ( !defined $to_insert->{$col} ) {
1365       my $col_info = $source->column_info($col);
1366
1367       if ( $col_info->{auto_nextval} ) {
1368         $updated_cols->{$col} = $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1369       }
1370     }
1371   }
1372
1373   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1374
1375   return $updated_cols;
1376 }
1377
1378 ## Still not quite perfect, and EXPERIMENTAL
1379 ## Currently it is assumed that all values passed will be "normal", i.e. not
1380 ## scalar refs, or at least, all the same type as the first set, the statement is
1381 ## only prepped once.
1382 sub insert_bulk {
1383   my ($self, $source, $cols, $data) = @_;
1384   my %colvalues;
1385   my $table = $source->from;
1386   @colvalues{@$cols} = (0..$#$cols);
1387   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1388
1389   $self->_query_start( $sql, @bind );
1390   my $sth = $self->sth($sql);
1391
1392 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1393
1394   ## This must be an arrayref, else nothing works!
1395   my $tuple_status = [];
1396
1397   ## Get the bind_attributes, if any exist
1398   my $bind_attributes = $self->source_bind_attributes($source);
1399
1400   ## Bind the values and execute
1401   my $placeholder_index = 1;
1402
1403   foreach my $bound (@bind) {
1404
1405     my $attributes = {};
1406     my ($column_name, $data_index) = @$bound;
1407
1408     if( $bind_attributes ) {
1409       $attributes = $bind_attributes->{$column_name}
1410       if defined $bind_attributes->{$column_name};
1411     }
1412
1413     my @data = map { $_->[$data_index] } @$data;
1414
1415     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1416     $placeholder_index++;
1417   }
1418   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1419   $self->throw_exception($sth->errstr) if !$rv;
1420
1421   $self->_query_end( $sql, @bind );
1422   return (wantarray ? ($rv, $sth, @bind) : $rv);
1423 }
1424
1425 sub update {
1426   my $self = shift @_;
1427   my $source = shift @_;
1428   my $bind_attributes = $self->source_bind_attributes($source);
1429
1430   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1431 }
1432
1433
1434 sub delete {
1435   my $self = shift @_;
1436   my $source = shift @_;
1437
1438   my $bind_attrs = {}; ## If ever it's needed...
1439
1440   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1441 }
1442
1443 sub _select {
1444   my $self = shift;
1445   my $sql_maker = $self->sql_maker;
1446   local $sql_maker->{for};
1447   return $self->_execute($self->_select_args(@_));
1448 }
1449
1450 sub _select_args {
1451   my ($self, $ident, $select, $condition, $attrs) = @_;
1452   my $order = $attrs->{order_by};
1453
1454   my $for = delete $attrs->{for};
1455   my $sql_maker = $self->sql_maker;
1456   $sql_maker->{for} = $for;
1457
1458   if (exists $attrs->{group_by} || $attrs->{having}) {
1459     $order = {
1460       group_by => $attrs->{group_by},
1461       having => $attrs->{having},
1462       ($order ? (order_by => $order) : ())
1463     };
1464   }
1465   my $bind_attrs = {}; ## Future support
1466   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1467   if ($attrs->{software_limit} ||
1468       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1469         $attrs->{software_limit} = 1;
1470   } else {
1471     $self->throw_exception("rows attribute must be positive if present")
1472       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1473
1474     # MySQL actually recommends this approach.  I cringe.
1475     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1476     push @args, $attrs->{rows}, $attrs->{offset};
1477   }
1478   return @args;
1479 }
1480
1481 sub source_bind_attributes {
1482   my ($self, $source) = @_;
1483
1484   my $bind_attributes;
1485   foreach my $column ($source->columns) {
1486
1487     my $data_type = $source->column_info($column)->{data_type} || '';
1488     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1489      if $data_type;
1490   }
1491
1492   return $bind_attributes;
1493 }
1494
1495 =head2 select
1496
1497 =over 4
1498
1499 =item Arguments: $ident, $select, $condition, $attrs
1500
1501 =back
1502
1503 Handle a SQL select statement.
1504
1505 =cut
1506
1507 sub select {
1508   my $self = shift;
1509   my ($ident, $select, $condition, $attrs) = @_;
1510   return $self->cursor_class->new($self, \@_, $attrs);
1511 }
1512
1513 sub select_single {
1514   my $self = shift;
1515   my ($rv, $sth, @bind) = $self->_select(@_);
1516   my @row = $sth->fetchrow_array;
1517   my @nextrow = $sth->fetchrow_array if @row;
1518   if(@row && @nextrow) {
1519     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1520   }
1521   # Need to call finish() to work round broken DBDs
1522   $sth->finish();
1523   return @row;
1524 }
1525
1526 =head2 sth
1527
1528 =over 4
1529
1530 =item Arguments: $sql
1531
1532 =back
1533
1534 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1535
1536 =cut
1537
1538 sub _dbh_sth {
1539   my ($self, $dbh, $sql) = @_;
1540
1541   # 3 is the if_active parameter which avoids active sth re-use
1542   my $sth = $self->disable_sth_caching
1543     ? $dbh->prepare($sql)
1544     : $dbh->prepare_cached($sql, {}, 3);
1545
1546   # XXX You would think RaiseError would make this impossible,
1547   #  but apparently that's not true :(
1548   $self->throw_exception($dbh->errstr) if !$sth;
1549
1550   $sth;
1551 }
1552
1553 sub sth {
1554   my ($self, $sql) = @_;
1555   $self->dbh_do('_dbh_sth', $sql);
1556 }
1557
1558 sub _dbh_columns_info_for {
1559   my ($self, $dbh, $table) = @_;
1560
1561   if ($dbh->can('column_info')) {
1562     my %result;
1563     eval {
1564       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1565       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1566       $sth->execute();
1567       while ( my $info = $sth->fetchrow_hashref() ){
1568         my %column_info;
1569         $column_info{data_type}   = $info->{TYPE_NAME};
1570         $column_info{size}      = $info->{COLUMN_SIZE};
1571         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1572         $column_info{default_value} = $info->{COLUMN_DEF};
1573         my $col_name = $info->{COLUMN_NAME};
1574         $col_name =~ s/^\"(.*)\"$/$1/;
1575
1576         $result{$col_name} = \%column_info;
1577       }
1578     };
1579     return \%result if !$@ && scalar keys %result;
1580   }
1581
1582   my %result;
1583   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1584   $sth->execute;
1585   my @columns = @{$sth->{NAME_lc}};
1586   for my $i ( 0 .. $#columns ){
1587     my %column_info;
1588     $column_info{data_type} = $sth->{TYPE}->[$i];
1589     $column_info{size} = $sth->{PRECISION}->[$i];
1590     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1591
1592     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1593       $column_info{data_type} = $1;
1594       $column_info{size}    = $2;
1595     }
1596
1597     $result{$columns[$i]} = \%column_info;
1598   }
1599   $sth->finish;
1600
1601   foreach my $col (keys %result) {
1602     my $colinfo = $result{$col};
1603     my $type_num = $colinfo->{data_type};
1604     my $type_name;
1605     if(defined $type_num && $dbh->can('type_info')) {
1606       my $type_info = $dbh->type_info($type_num);
1607       $type_name = $type_info->{TYPE_NAME} if $type_info;
1608       $colinfo->{data_type} = $type_name if $type_name;
1609     }
1610   }
1611
1612   return \%result;
1613 }
1614
1615 sub columns_info_for {
1616   my ($self, $table) = @_;
1617   $self->dbh_do('_dbh_columns_info_for', $table);
1618 }
1619
1620 =head2 last_insert_id
1621
1622 Return the row id of the last insert.
1623
1624 =cut
1625
1626 sub _dbh_last_insert_id {
1627     # All Storage's need to register their own _dbh_last_insert_id
1628     # the old SQLite-based method was highly inappropriate
1629
1630     my $self = shift;
1631     my $class = ref $self;
1632     $self->throw_exception (<<EOE);
1633
1634 No _dbh_last_insert_id() method found in $class.
1635 Since the method of obtaining the autoincrement id of the last insert
1636 operation varies greatly between different databases, this method must be
1637 individually implemented for every storage class.
1638 EOE
1639 }
1640
1641 sub last_insert_id {
1642   my $self = shift;
1643   $self->dbh_do('_dbh_last_insert_id', @_);
1644 }
1645
1646 =head2 sqlt_type
1647
1648 Returns the database driver name.
1649
1650 =cut
1651
1652 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1653
1654 =head2 bind_attribute_by_data_type
1655
1656 Given a datatype from column info, returns a database specific bind
1657 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
1658 let the database planner just handle it.
1659
1660 Generally only needed for special case column types, like bytea in postgres.
1661
1662 =cut
1663
1664 sub bind_attribute_by_data_type {
1665     return;
1666 }
1667
1668 =head2 create_ddl_dir
1669
1670 =over 4
1671
1672 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1673
1674 =back
1675
1676 Creates a SQL file based on the Schema, for each of the specified
1677 database types, in the given directory.
1678
1679 By default, C<\%sqlt_args> will have
1680
1681  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1682
1683 merged with the hash passed in. To disable any of those features, pass in a
1684 hashref like the following
1685
1686  { ignore_constraint_names => 0, # ... other options }
1687
1688 =cut
1689
1690 sub create_ddl_dir {
1691   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1692
1693   if(!$dir || !-d $dir) {
1694     warn "No directory given, using ./\n";
1695     $dir = "./";
1696   }
1697   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1698   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1699
1700   my $schema_version = $schema->schema_version || '1.x';
1701   $version ||= $schema_version;
1702
1703   $sqltargs = {
1704     add_drop_table => 1,
1705     ignore_constraint_names => 1,
1706     ignore_index_names => 1,
1707     %{$sqltargs || {}}
1708   };
1709
1710   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09003: '}
1711       . $self->_check_sqlt_message . q{'})
1712           if !$self->_check_sqlt_version;
1713
1714   my $sqlt = SQL::Translator->new( $sqltargs );
1715
1716   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1717   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1718
1719   foreach my $db (@$databases) {
1720     $sqlt->reset();
1721     $sqlt->{schema} = $sqlt_schema;
1722     $sqlt->producer($db);
1723
1724     my $file;
1725     my $filename = $schema->ddl_filename($db, $version, $dir);
1726     if (-e $filename && ($version eq $schema_version )) {
1727       # if we are dumping the current version, overwrite the DDL
1728       warn "Overwriting existing DDL file - $filename";
1729       unlink($filename);
1730     }
1731
1732     my $output = $sqlt->translate;
1733     if(!$output) {
1734       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1735       next;
1736     }
1737     if(!open($file, ">$filename")) {
1738       $self->throw_exception("Can't open $filename for writing ($!)");
1739       next;
1740     }
1741     print $file $output;
1742     close($file);
1743
1744     next unless ($preversion);
1745
1746     require SQL::Translator::Diff;
1747
1748     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1749     if(!-e $prefilename) {
1750       warn("No previous schema file found ($prefilename)");
1751       next;
1752     }
1753
1754     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1755     if(-e $difffile) {
1756       warn("Overwriting existing diff file - $difffile");
1757       unlink($difffile);
1758     }
1759
1760     my $source_schema;
1761     {
1762       my $t = SQL::Translator->new($sqltargs);
1763       $t->debug( 0 );
1764       $t->trace( 0 );
1765       $t->parser( $db )                       or die $t->error;
1766       my $out = $t->translate( $prefilename ) or die $t->error;
1767       $source_schema = $t->schema;
1768       unless ( $source_schema->name ) {
1769         $source_schema->name( $prefilename );
1770       }
1771     }
1772
1773     # The "new" style of producers have sane normalization and can support
1774     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1775     # And we have to diff parsed SQL against parsed SQL.
1776     my $dest_schema = $sqlt_schema;
1777
1778     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1779       my $t = SQL::Translator->new($sqltargs);
1780       $t->debug( 0 );
1781       $t->trace( 0 );
1782       $t->parser( $db )                    or die $t->error;
1783       my $out = $t->translate( $filename ) or die $t->error;
1784       $dest_schema = $t->schema;
1785       $dest_schema->name( $filename )
1786         unless $dest_schema->name;
1787     }
1788
1789     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1790                                                   $dest_schema,   $db,
1791                                                   $sqltargs
1792                                                  );
1793     if(!open $file, ">$difffile") {
1794       $self->throw_exception("Can't write to $difffile ($!)");
1795       next;
1796     }
1797     print $file $diff;
1798     close($file);
1799   }
1800 }
1801
1802 =head2 deployment_statements
1803
1804 =over 4
1805
1806 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1807
1808 =back
1809
1810 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1811 The database driver name is given by C<$type>, though the value from
1812 L</sqlt_type> is used if it is not specified.
1813
1814 C<$directory> is used to return statements from files in a previously created
1815 L</create_ddl_dir> directory and is optional. The filenames are constructed
1816 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1817
1818 If no C<$directory> is specified then the statements are constructed on the
1819 fly using L<SQL::Translator> and C<$version> is ignored.
1820
1821 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1822
1823 =cut
1824
1825 sub deployment_statements {
1826   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1827   # Need to be connected to get the correct sqlt_type
1828   $self->ensure_connected() unless $type;
1829   $type ||= $self->sqlt_type;
1830   $version ||= $schema->schema_version || '1.x';
1831   $dir ||= './';
1832   my $filename = $schema->ddl_filename($type, $version, $dir);
1833   if(-f $filename)
1834   {
1835       my $file;
1836       open($file, "<$filename")
1837         or $self->throw_exception("Can't open $filename ($!)");
1838       my @rows = <$file>;
1839       close($file);
1840       return join('', @rows);
1841   }
1842
1843   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09003: '}
1844       . $self->_check_sqlt_message . q{'})
1845           if !$self->_check_sqlt_version;
1846
1847   require SQL::Translator::Parser::DBIx::Class;
1848   eval qq{use SQL::Translator::Producer::${type}};
1849   $self->throw_exception($@) if $@;
1850
1851   # sources needs to be a parser arg, but for simplicty allow at top level
1852   # coming in
1853   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1854       if exists $sqltargs->{sources};
1855
1856   my $tr = SQL::Translator->new(%$sqltargs);
1857   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1858   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1859 }
1860
1861 sub deploy {
1862   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1863   my $deploy = sub {
1864     my $line = shift;
1865     return if($line =~ /^--/);
1866     return if(!$line);
1867     # next if($line =~ /^DROP/m);
1868     return if($line =~ /^BEGIN TRANSACTION/m);
1869     return if($line =~ /^COMMIT/m);
1870     return if $line =~ /^\s+$/; # skip whitespace only
1871     $self->_query_start($line);
1872     eval {
1873       $self->dbh->do($line); # shouldn't be using ->dbh ?
1874     };
1875     if ($@) {
1876       warn qq{$@ (running "${line}")};
1877     }
1878     $self->_query_end($line);
1879   };
1880   my @statements = $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } );
1881   if (@statements > 1) {
1882     foreach my $statement (@statements) {
1883       $deploy->( $statement );
1884     }
1885   }
1886   elsif (@statements == 1) {
1887     foreach my $line ( split(";\n", $statements[0])) {
1888       $deploy->( $line );
1889     }
1890   }
1891 }
1892
1893 =head2 datetime_parser
1894
1895 Returns the datetime parser class
1896
1897 =cut
1898
1899 sub datetime_parser {
1900   my $self = shift;
1901   return $self->{datetime_parser} ||= do {
1902     $self->ensure_connected;
1903     $self->build_datetime_parser(@_);
1904   };
1905 }
1906
1907 =head2 datetime_parser_type
1908
1909 Defines (returns) the datetime parser class - currently hardwired to
1910 L<DateTime::Format::MySQL>
1911
1912 =cut
1913
1914 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1915
1916 =head2 build_datetime_parser
1917
1918 See L</datetime_parser>
1919
1920 =cut
1921
1922 sub build_datetime_parser {
1923   my $self = shift;
1924   my $type = $self->datetime_parser_type(@_);
1925   eval "use ${type}";
1926   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1927   return $type;
1928 }
1929
1930 {
1931     my $_check_sqlt_version; # private
1932     my $_check_sqlt_message; # private
1933     sub _check_sqlt_version {
1934         return $_check_sqlt_version if defined $_check_sqlt_version;
1935         eval 'use SQL::Translator "0.09003"';
1936         $_check_sqlt_message = $@ || '';
1937         $_check_sqlt_version = !$@;
1938     }
1939
1940     sub _check_sqlt_message {
1941         _check_sqlt_version if !defined $_check_sqlt_message;
1942         $_check_sqlt_message;
1943     }
1944 }
1945
1946 =head2 is_replicating
1947
1948 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1949 replicate from a master database.  Default is undef, which is the result
1950 returned by databases that don't support replication.
1951
1952 =cut
1953
1954 sub is_replicating {
1955     return;
1956
1957 }
1958
1959 =head2 lag_behind_master
1960
1961 Returns a number that represents a certain amount of lag behind a master db
1962 when a given storage is replicating.  The number is database dependent, but
1963 starts at zero and increases with the amount of lag. Default in undef
1964
1965 =cut
1966
1967 sub lag_behind_master {
1968     return;
1969 }
1970
1971 sub DESTROY {
1972   my $self = shift;
1973   return if !$self->_dbh;
1974   $self->_verify_pid;
1975   $self->_dbh(undef);
1976 }
1977
1978 1;
1979
1980 =head1 USAGE NOTES
1981
1982 =head2 DBIx::Class and AutoCommit
1983
1984 DBIx::Class can do some wonderful magic with handling exceptions,
1985 disconnections, and transactions when you use C<< AutoCommit => 1 >>
1986 combined with C<txn_do> for transaction support.
1987
1988 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
1989 in an assumed transaction between commits, and you're telling us you'd
1990 like to manage that manually.  A lot of the magic protections offered by
1991 this module will go away.  We can't protect you from exceptions due to database
1992 disconnects because we don't know anything about how to restart your
1993 transactions.  You're on your own for handling all sorts of exceptional
1994 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
1995 be with raw DBI.
1996
1997
1998 =head1 SQL METHODS
1999
2000 The module defines a set of methods within the DBIC::SQL::Abstract
2001 namespace.  These build on L<SQL::Abstract::Limit> to provide the
2002 SQL query functions.
2003
2004 The following methods are extended:-
2005
2006 =over 4
2007
2008 =item delete
2009
2010 =item insert
2011
2012 =item select
2013
2014 =item update
2015
2016 =item limit_dialect
2017
2018 See L</connect_info> for details.
2019
2020 =item quote_char
2021
2022 See L</connect_info> for details.
2023
2024 =item name_sep
2025
2026 See L</connect_info> for details.
2027
2028 =back
2029
2030 =head1 AUTHORS
2031
2032 Matt S. Trout <mst@shadowcatsystems.co.uk>
2033
2034 Andy Grundman <andy@hybridized.org>
2035
2036 =head1 LICENSE
2037
2038 You may distribute this code under the same terms as Perl itself.
2039
2040 =cut