lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13 use Scalar::Util 'blessed';
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid disable_sth_caching cursor on_connect_do
  18        transaction_depth/
  19 );
  20
  21 BEGIN {
  22
  23 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  24
  25 use base qw/SQL::Abstract::Limit/;
  26
  27 # This prevents the caching of $dbh in S::A::L, I believe
  28 sub new {
  29   my $self = shift->SUPER::new(@_);
  30
  31   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  32   #   it with what it resolves to:
  33   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  34     if ref $self->{limit_dialect};
  35
  36   $self;
  37 }
  38
  39 sub _RowNumberOver {
  40   my ($self, $sql, $order, $rows, $offset ) = @_;
  41
  42   $offset += 1;
  43   my $last = $rows + $offset;
  44   my ( $order_by ) = $self->_order_by( $order );
  45
  46   $sql = <<"";
  47 SELECT * FROM
  48 (
  49    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  50       $sql
  51       $order_by
  52    ) Q1
  53 ) Q2
  54 WHERE ROW_NUM BETWEEN $offset AND $last
  55
  56   return $sql;
  57 }
  58
  59
  60 # While we're at it, this should make LIMIT queries more efficient,
  61 #  without digging into things too deeply
  62 use Scalar::Util 'blessed';
  63 sub _find_syntax {
  64   my ($self, $syntax) = @_;
  65   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  66   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  67     return 'RowNumberOver';
  68   }
  69
  70   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  71 }
  72
  73 sub select {
  74   my ($self, $table, $fields, $where, $order, @rest) = @_;
  75   $table = $self->_quote($table) unless ref($table);
  76   local $self->{rownum_hack_count} = 1
  77     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  78   @rest = (-1) unless defined $rest[0];
  79   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  80     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  81   local $self->{having_bind} = [];
  82   my ($sql, @ret) = $self->SUPER::select(
  83     $table, $self->_recurse_fields($fields), $where, $order, @rest
  84   );
  85   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  86 }
  87
  88 sub insert {
  89   my $self = shift;
  90   my $table = shift;
  91   $table = $self->_quote($table) unless ref($table);
  92   $self->SUPER::insert($table, @_);
  93 }
  94
  95 sub update {
  96   my $self = shift;
  97   my $table = shift;
  98   $table = $self->_quote($table) unless ref($table);
  99   $self->SUPER::update($table, @_);
 100 }
 101
 102 sub delete {
 103   my $self = shift;
 104   my $table = shift;
 105   $table = $self->_quote($table) unless ref($table);
 106   $self->SUPER::delete($table, @_);
 107 }
 108
 109 sub _emulate_limit {
 110   my $self = shift;
 111   if ($_[3] == -1) {
 112     return $_[1].$self->_order_by($_[2]);
 113   } else {
 114     return $self->SUPER::_emulate_limit(@_);
 115   }
 116 }
 117
 118 sub _recurse_fields {
 119   my ($self, $fields) = @_;
 120   my $ref = ref $fields;
 121   return $self->_quote($fields) unless $ref;
 122   return $$fields if $ref eq 'SCALAR';
 123
 124   if ($ref eq 'ARRAY') {
 125     return join(', ', map {
 126       $self->_recurse_fields($_)
 127       .(exists $self->{rownum_hack_count}
 128          ? ' AS col'.$self->{rownum_hack_count}++
 129          : '')
 130      } @$fields);
 131   } elsif ($ref eq 'HASH') {
 132     foreach my $func (keys %$fields) {
 133       return $self->_sqlcase($func)
 134         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 135     }
 136   }
 137 }
 138
 139 sub _order_by {
 140   my $self = shift;
 141   my $ret = '';
 142   my @extra;
 143   if (ref $_[0] eq 'HASH') {
 144     if (defined $_[0]->{group_by}) {
 145       $ret = $self->_sqlcase(' group by ')
 146                .$self->_recurse_fields($_[0]->{group_by});
 147     }
 148     if (defined $_[0]->{having}) {
 149       my $frag;
 150       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 151       push(@{$self->{having_bind}}, @extra);
 152       $ret .= $self->_sqlcase(' having ').$frag;
 153     }
 154     if (defined $_[0]->{order_by}) {
 155       $ret .= $self->_order_by($_[0]->{order_by});
 156     }
 157   } elsif (ref $_[0] eq 'SCALAR') {
 158     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 159   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 160     my @order = @{+shift};
 161     $ret = $self->_sqlcase(' order by ')
 162           .join(', ', map {
 163                         my $r = $self->_order_by($_, @_);
 164                         $r =~ s/^ ?ORDER BY //i;
 165                         $r;
 166                       } @order);
 167   } else {
 168     $ret = $self->SUPER::_order_by(@_);
 169   }
 170   return $ret;
 171 }
 172
 173 sub _order_directions {
 174   my ($self, $order) = @_;
 175   $order = $order->{order_by} if ref $order eq 'HASH';
 176   return $self->SUPER::_order_directions($order);
 177 }
 178
 179 sub _table {
 180   my ($self, $from) = @_;
 181   if (ref $from eq 'ARRAY') {
 182     return $self->_recurse_from(@$from);
 183   } elsif (ref $from eq 'HASH') {
 184     return $self->_make_as($from);
 185   } else {
 186     return $from; # would love to quote here but _table ends up getting called
 187                   # twice during an ->select without a limit clause due to
 188                   # the way S::A::Limit->select works. should maybe consider
 189                   # bypassing this and doing S::A::select($self, ...) in
 190                   # our select method above. meantime, quoting shims have
 191                   # been added to select/insert/update/delete here
 192   }
 193 }
 194
 195 sub _recurse_from {
 196   my ($self, $from, @join) = @_;
 197   my @sqlf;
 198   push(@sqlf, $self->_make_as($from));
 199   foreach my $j (@join) {
 200     my ($to, $on) = @$j;
 201
 202     # check whether a join type exists
 203     my $join_clause = '';
 204     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 205     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 206       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 207     } else {
 208       $join_clause = ' JOIN ';
 209     }
 210     push(@sqlf, $join_clause);
 211
 212     if (ref $to eq 'ARRAY') {
 213       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 214     } else {
 215       push(@sqlf, $self->_make_as($to));
 216     }
 217     push(@sqlf, ' ON ', $self->_join_condition($on));
 218   }
 219   return join('', @sqlf);
 220 }
 221
 222 sub _make_as {
 223   my ($self, $from) = @_;
 224   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 225                      reverse each %{$self->_skip_options($from)});
 226 }
 227
 228 sub _skip_options {
 229   my ($self, $hash) = @_;
 230   my $clean_hash = {};
 231   $clean_hash->{$_} = $hash->{$_}
 232     for grep {!/^-/} keys %$hash;
 233   return $clean_hash;
 234 }
 235
 236 sub _join_condition {
 237   my ($self, $cond) = @_;
 238   if (ref $cond eq 'HASH') {
 239     my %j;
 240     for (keys %$cond) {
 241       my $v = $cond->{$_};
 242       if (ref $v) {
 243         # XXX no throw_exception() in this package and croak() fails with strange results
 244         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 245             if ref($v) ne 'SCALAR';
 246         $j{$_} = $v;
 247       }
 248       else {
 249         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 250       }
 251     };
 252     return scalar($self->_recurse_where(\%j));
 253   } elsif (ref $cond eq 'ARRAY') {
 254     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 255   } else {
 256     die "Can't handle this yet!";
 257   }
 258 }
 259
 260 sub _quote {
 261   my ($self, $label) = @_;
 262   return '' unless defined $label;
 263   return "*" if $label eq '*';
 264   return $label unless $self->{quote_char};
 265   if(ref $self->{quote_char} eq "ARRAY"){
 266     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 267       if !defined $self->{name_sep};
 268     my $sep = $self->{name_sep};
 269     return join($self->{name_sep},
 270         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 271        split(/\Q$sep\E/,$label));
 272   }
 273   return $self->SUPER::_quote($label);
 274 }
 275
 276 sub limit_dialect {
 277     my $self = shift;
 278     $self->{limit_dialect} = shift if @_;
 279     return $self->{limit_dialect};
 280 }
 281
 282 sub quote_char {
 283     my $self = shift;
 284     $self->{quote_char} = shift if @_;
 285     return $self->{quote_char};
 286 }
 287
 288 sub name_sep {
 289     my $self = shift;
 290     $self->{name_sep} = shift if @_;
 291     return $self->{name_sep};
 292 }
 293
 294 } # End of BEGIN block
 295
 296 =head1 NAME
 297
 298 DBIx::Class::Storage::DBI - DBI storage handler
 299
 300 =head1 SYNOPSIS
 301
 302 =head1 DESCRIPTION
 303
 304 This class represents the connection to an RDBMS via L<DBI>.  See
 305 L<DBIx::Class::Storage> for general information.  This pod only
 306 documents DBI-specific methods and behaviors.
 307
 308 =head1 METHODS
 309
 310 =cut
 311
 312 sub new {
 313   my $new = shift->next::method(@_);
 314
 315   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 316   $new->transaction_depth(0);
 317   $new->_sql_maker_opts({});
 318   $new->{_in_dbh_do} = 0;
 319   $new->{_dbh_gen} = 0;
 320
 321   $new;
 322 }
 323
 324 =head2 connect_info
 325
 326 The arguments of C<connect_info> are always a single array reference.
 327
 328 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 329 encapsulates its argument list in an arrayref before calling
 330 C<connect_info> here.
 331
 332 The arrayref can either contain the same set of arguments one would
 333 normally pass to L<DBI/connect>, or a lone code reference which returns
 334 a connected database handle.  Please note that the L<DBI> docs
 335 recommend that you always explicitly set C<AutoCommit> to either
 336 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 337 to C<1>, and that you perform transactions via our L</txn_do>
 338 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 339 set it to zero.  This is the default for most DBDs.  See below for more
 340 details.
 341
 342 In either case, if the final argument in your connect_info happens
 343 to be a hashref, C<connect_info> will look there for several
 344 connection-specific options:
 345
 346 =over 4
 347
 348 =item on_connect_do
 349
 350 This can be set to an arrayref of literal sql statements, which will
 351 be executed immediately after making the connection to the database
 352 every time we [re-]connect.
 353
 354 =item disable_sth_caching
 355
 356 If set to a true value, this option will disable the caching of
 357 statement handles via L<DBI/prepare_cached>.
 358
 359 =item limit_dialect
 360
 361 Sets the limit dialect. This is useful for JDBC-bridge among others
 362 where the remote SQL-dialect cannot be determined by the name of the
 363 driver alone.
 364
 365 =item quote_char
 366
 367 Specifies what characters to use to quote table and column names. If
 368 you use this you will want to specify L<name_sep> as well.
 369
 370 quote_char expects either a single character, in which case is it is placed
 371 on either side of the table/column, or an arrayref of length 2 in which case the
 372 table/column name is placed between the elements.
 373
 374 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 375 use C<quote_char =E<gt> [qw/[ ]/]>.
 376
 377 =item name_sep
 378
 379 This only needs to be used in conjunction with L<quote_char>, and is used to
 380 specify the charecter that seperates elements (schemas, tables, columns) from
 381 each other. In most cases this is simply a C<.>.
 382
 383 =back
 384
 385 These options can be mixed in with your other L<DBI> connection attributes,
 386 or placed in a seperate hashref after all other normal L<DBI> connection
 387 arguments.
 388
 389 Every time C<connect_info> is invoked, any previous settings for
 390 these options will be cleared before setting the new ones, regardless of
 391 whether any options are specified in the new C<connect_info>.
 392
 393 Important note:  DBIC expects the returned database handle provided by
 394 a subref argument to have RaiseError set on it.  If it doesn't, things
 395 might not work very well, YMMV.  If you don't use a subref, DBIC will
 396 force this setting for you anyways.  Setting HandleError to anything
 397 other than simple exception object wrapper might cause problems too.
 398
 399 Another Important Note:
 400
 401 DBIC can do some wonderful magic with handling exceptions,
 402 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 403 combined with C<txn_do> for transaction support.
 404
 405 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 406 in an assumed transaction between commits, and you're telling us you'd
 407 like to manage that manually.  A lot of DBIC's magic protections
 408 go away.  We can't protect you from exceptions due to database
 409 disconnects because we don't know anything about how to restart your
 410 transactions.  You're on your own for handling all sorts of exceptional
 411 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 412 be with raw DBI.
 413
 414 Examples:
 415
 416   # Simple SQLite connection
 417   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 418
 419   # Connect via subref
 420   ->connect_info([ sub { DBI->connect(...) } ]);
 421
 422   # A bit more complicated
 423   ->connect_info(
 424     [
 425       'dbi:Pg:dbname=foo',
 426       'postgres',
 427       'my_pg_password',
 428       { AutoCommit => 1 },
 429       { quote_char => q{"}, name_sep => q{.} },
 430     ]
 431   );
 432
 433   # Equivalent to the previous example
 434   ->connect_info(
 435     [
 436       'dbi:Pg:dbname=foo',
 437       'postgres',
 438       'my_pg_password',
 439       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 440     ]
 441   );
 442
 443   # Subref + DBIC-specific connection options
 444   ->connect_info(
 445     [
 446       sub { DBI->connect(...) },
 447       {
 448           quote_char => q{`},
 449           name_sep => q{@},
 450           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 451           disable_sth_caching => 1,
 452       },
 453     ]
 454   );
 455
 456 =cut
 457
 458 sub connect_info {
 459   my ($self, $info_arg) = @_;
 460
 461   return $self->_connect_info if !$info_arg;
 462
 463   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 464   #  the new set of options
 465   $self->_sql_maker(undef);
 466   $self->_sql_maker_opts({});
 467   $self->_connect_info($info_arg);
 468
 469   my $dbi_info = [@$info_arg]; # copy for DBI
 470   my $last_info = $dbi_info->[-1];
 471   if(ref $last_info eq 'HASH') {
 472     for my $storage_opt (qw/on_connect_do disable_sth_caching/) {
 473       if(my $value = delete $last_info->{$storage_opt}) {
 474         $self->$storage_opt($value);
 475       }
 476     }
 477     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 478       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 479         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 480       }
 481     }
 482
 483     # Get rid of any trailing empty hashref
 484     pop(@$dbi_info) if !keys %$last_info;
 485   }
 486
 487   $self->_dbi_connect_info($dbi_info);
 488
 489   if(ref $dbi_info->[0] ne 'CODE') {
 490       # Extend to 3 arguments with undefs, if necessary
 491       while(scalar(@$dbi_info) < 3) { push(@$dbi_info, undef) }
 492
 493       # Complain if 4th argument is defined and is not a HASH
 494       if(defined $dbi_info->[3] && ref $dbi_info->[3] ne 'HASH') {
 495           warn "4th argument of DBI connect info is defined "
 496                . " but is not a hashref!";
 497       }
 498
 499       # Set AutoCommit to 1 if not specified manually
 500       else {
 501           $dbi_info->[3] ||= {};
 502           if(!defined $dbi_info->[3]->{AutoCommit}) {
 503               $dbi_info->[3]->{AutoCommit} = 1;
 504           }
 505       }
 506   }
 507
 508   $self->_connect_info;
 509 }
 510
 511 =head2 on_connect_do
 512
 513 This method is deprecated in favor of setting via L</connect_info>.
 514
 515 =head2 dbh_do
 516
 517 Arguments: $subref, @extra_coderef_args?
 518
 519 Execute the given subref using the new exception-based connection management.
 520
 521 The first two arguments will be the storage object that C<dbh_do> was called
 522 on and a database handle to use.  Any additional arguments will be passed
 523 verbatim to the called subref as arguments 2 and onwards.
 524
 525 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 526 exception handling and reconnection (or failover in future subclasses).
 527
 528 Your subref should have no side-effects outside of the database, as
 529 there is the potential for your subref to be partially double-executed
 530 if the database connection was stale/dysfunctional.
 531
 532 Example:
 533
 534   my @stuff = $schema->storage->dbh_do(
 535     sub {
 536       my ($storage, $dbh, @cols) = @_;
 537       my $cols = join(q{, }, @cols);
 538       $dbh->selectrow_array("SELECT $cols FROM foo");
 539     },
 540     @column_list
 541   );
 542
 543 =cut
 544
 545 sub dbh_do {
 546   my $self = shift;
 547   my $coderef = shift;
 548
 549   ref $coderef eq 'CODE' or $self->throw_exception
 550     ('$coderef must be a CODE reference');
 551
 552   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 553       || $self->{transaction_depth};
 554
 555   local $self->{_in_dbh_do} = 1;
 556
 557   my @result;
 558   my $want_array = wantarray;
 559
 560   eval {
 561     $self->_verify_pid if $self->_dbh;
 562     $self->_populate_dbh if !$self->_dbh;
 563     if($want_array) {
 564         @result = $coderef->($self, $self->_dbh, @_);
 565     }
 566     elsif(defined $want_array) {
 567         $result[0] = $coderef->($self, $self->_dbh, @_);
 568     }
 569     else {
 570         $coderef->($self, $self->_dbh, @_);
 571     }
 572   };
 573
 574   my $exception = $@;
 575   if(!$exception) { return $want_array ? @result : $result[0] }
 576
 577   $self->throw_exception($exception) if $self->connected;
 578
 579   # We were not connected - reconnect and retry, but let any
 580   #  exception fall right through this time
 581   $self->_populate_dbh;
 582   $coderef->($self, $self->_dbh, @_);
 583 }
 584
 585 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 586 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 587 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 588 sub txn_do {
 589   my $self = shift;
 590   my $coderef = shift;
 591
 592   ref $coderef eq 'CODE' or $self->throw_exception
 593     ('$coderef must be a CODE reference');
 594
 595   local $self->{_in_dbh_do} = 1;
 596
 597   my @result;
 598   my $want_array = wantarray;
 599
 600   my $tried = 0;
 601   while(1) {
 602     eval {
 603       $self->_verify_pid if $self->_dbh;
 604       $self->_populate_dbh if !$self->_dbh;
 605
 606       $self->txn_begin;
 607       if($want_array) {
 608           @result = $coderef->(@_);
 609       }
 610       elsif(defined $want_array) {
 611           $result[0] = $coderef->(@_);
 612       }
 613       else {
 614           $coderef->(@_);
 615       }
 616       $self->txn_commit;
 617     };
 618
 619     my $exception = $@;
 620     if(!$exception) { return $want_array ? @result : $result[0] }
 621
 622     if($tried++ > 0 || $self->connected) {
 623       eval { $self->txn_rollback };
 624       my $rollback_exception = $@;
 625       if($rollback_exception) {
 626         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 627         $self->throw_exception($exception)  # propagate nested rollback
 628           if $rollback_exception =~ /$exception_class/;
 629
 630         $self->throw_exception(
 631           "Transaction aborted: ${exception}. "
 632           . "Rollback failed: ${rollback_exception}"
 633         );
 634       }
 635       $self->throw_exception($exception)
 636     }
 637
 638     # We were not connected, and was first try - reconnect and retry
 639     # via the while loop
 640     $self->_populate_dbh;
 641   }
 642 }
 643
 644 =head2 disconnect
 645
 646 Our C<disconnect> method also performs a rollback first if the
 647 database is not in C<AutoCommit> mode.
 648
 649 =cut
 650
 651 sub disconnect {
 652   my ($self) = @_;
 653
 654   if( $self->connected ) {
 655     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 656     $self->_dbh->disconnect;
 657     $self->_dbh(undef);
 658     $self->{_dbh_gen}++;
 659   }
 660 }
 661
 662 sub connected {
 663   my ($self) = @_;
 664
 665   if(my $dbh = $self->_dbh) {
 666       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 667           $self->_dbh(undef);
 668           $self->{_dbh_gen}++;
 669           return;
 670       }
 671       else {
 672           $self->_verify_pid;
 673       }
 674       return ($dbh->FETCH('Active') && $dbh->ping);
 675   }
 676
 677   return 0;
 678 }
 679
 680 # handle pid changes correctly
 681 #  NOTE: assumes $self->_dbh is a valid $dbh
 682 sub _verify_pid {
 683   my ($self) = @_;
 684
 685   return if $self->_conn_pid == $$;
 686
 687   $self->_dbh->{InactiveDestroy} = 1;
 688   $self->_dbh(undef);
 689   $self->{_dbh_gen}++;
 690
 691   return;
 692 }
 693
 694 sub ensure_connected {
 695   my ($self) = @_;
 696
 697   unless ($self->connected) {
 698     $self->_populate_dbh;
 699   }
 700 }
 701
 702 =head2 dbh
 703
 704 Returns the dbh - a data base handle of class L<DBI>.
 705
 706 =cut
 707
 708 sub dbh {
 709   my ($self) = @_;
 710
 711   $self->ensure_connected;
 712   return $self->_dbh;
 713 }
 714
 715 sub _sql_maker_args {
 716     my ($self) = @_;
 717
 718     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 719 }
 720
 721 sub sql_maker {
 722   my ($self) = @_;
 723   unless ($self->_sql_maker) {
 724     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 725   }
 726   return $self->_sql_maker;
 727 }
 728
 729 sub _populate_dbh {
 730   my ($self) = @_;
 731   my @info = @{$self->_dbi_connect_info || []};
 732   $self->_dbh($self->_connect(@info));
 733
 734   # Always set the transaction depth on connect, since
 735   #  there is no transaction in progress by definition
 736   $self->{transaction_depth} = $self->_dbh->{AutoCommit} ? 0 : 1;
 737
 738   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 739     my $driver = $self->_dbh->{Driver}->{Name};
 740     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 741       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 742       $self->_rebless() if $self->can('_rebless');
 743     }
 744   }
 745
 746   # if on-connect sql statements are given execute them
 747   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 748     $self->debugobj->query_start($sql_statement) if $self->debug();
 749     $self->_dbh->do($sql_statement);
 750     $self->debugobj->query_end($sql_statement) if $self->debug();
 751   }
 752
 753   $self->_conn_pid($$);
 754   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 755 }
 756
 757 sub _connect {
 758   my ($self, @info) = @_;
 759
 760   $self->throw_exception("You failed to provide any connection info")
 761       if !@info;
 762
 763   my ($old_connect_via, $dbh);
 764
 765   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 766       $old_connect_via = $DBI::connect_via;
 767       $DBI::connect_via = 'connect';
 768   }
 769
 770   eval {
 771     if(ref $info[0] eq 'CODE') {
 772        $dbh = &{$info[0]}
 773     }
 774     else {
 775        $dbh = DBI->connect(@info);
 776        $dbh->{RaiseError} = 1;
 777        $dbh->{PrintError} = 0;
 778        $dbh->{PrintWarn} = 0;
 779     }
 780   };
 781
 782   $DBI::connect_via = $old_connect_via if $old_connect_via;
 783
 784   if (!$dbh || $@) {
 785     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 786   }
 787
 788   $dbh;
 789 }
 790
 791
 792 sub txn_begin {
 793   my $self = shift;
 794   if($self->{transaction_depth}++ == 0) {
 795     $self->debugobj->txn_begin()
 796       if $self->debug;
 797     # this isn't ->_dbh-> because
 798     #  we should reconnect on begin_work
 799     #  for AutoCommit users
 800     $self->dbh->begin_work;
 801   }
 802 }
 803
 804 sub txn_commit {
 805   my $self = shift;
 806   if ($self->{transaction_depth} == 1) {
 807     my $dbh = $self->_dbh;
 808     $self->debugobj->txn_commit()
 809       if ($self->debug);
 810     $dbh->commit;
 811     $self->{transaction_depth} = 0
 812       if $dbh->{AutoCommit};
 813   }
 814   elsif($self->{transaction_depth} > 1) {
 815     $self->{transaction_depth}--
 816   }
 817 }
 818
 819 sub txn_rollback {
 820   my $self = shift;
 821   my $dbh = $self->_dbh;
 822   my $autocommit;
 823   eval {
 824     $autocommit = $dbh->{AutoCommit};
 825     if ($self->{transaction_depth} == 1) {
 826       $self->debugobj->txn_rollback()
 827         if ($self->debug);
 828       $dbh->rollback;
 829       $self->{transaction_depth} = 0
 830         if $autocommit;
 831     }
 832     elsif($self->{transaction_depth} > 1) {
 833       $self->{transaction_depth}--;
 834     }
 835     else {
 836       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 837     }
 838   };
 839   if ($@) {
 840     my $error = $@;
 841     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 842     $error =~ /$exception_class/ and $self->throw_exception($error);
 843     # ensure that a failed rollback resets the transaction depth
 844     $self->{transaction_depth} = $autocommit ? 0 : 1;
 845     $self->throw_exception($error);
 846   }
 847 }
 848
 849 # This used to be the top-half of _execute.  It was split out to make it
 850 #  easier to override in NoBindVars without duping the rest.  It takes up
 851 #  all of _execute's args, and emits $sql, @bind.
 852 sub _prep_for_execute {
 853   my ($self, $op, $extra_bind, $ident, @args) = @_;
 854
 855   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 856   unshift(@bind,
 857     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 858       if $extra_bind;
 859   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 860
 861   return ($sql, @bind);
 862 }
 863
 864 sub _execute {
 865   my ($self, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 866
 867   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 868     $ident = $ident->from();
 869   }
 870
 871   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 872   unshift(@bind,
 873     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 874       if $extra_bind;
 875   if ($self->debug) {
 876       my @debug_bind =
 877         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 878       $self->debugobj->query_start($sql, @debug_bind);
 879   }
 880
 881   my ($rv, $sth);
 882   RETRY: while (1) {
 883     $sth = eval { $self->sth($sql,$op) };
 884
 885     if (!$sth || $@) {
 886       $self->throw_exception(
 887         'no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql"
 888       );
 889     }
 890
 891     if ($sth) {
 892       my $time = time();
 893       $rv = eval {
 894         my $placeholder_index = 1;
 895
 896         foreach my $bound (@bind) {
 897
 898           my $attributes = {};
 899           my($column_name, @data) = @$bound;
 900
 901           if( $bind_attributes ) {
 902             $attributes = $bind_attributes->{$column_name}
 903             if defined $bind_attributes->{$column_name};
 904           }
 905
 906           foreach my $data (@data)
 907           {
 908             $data = ref $data ? ''.$data : $data; # stringify args
 909
 910             $sth->bind_param($placeholder_index, $data, $attributes);
 911             $placeholder_index++;
 912           }
 913         }
 914         $sth->execute();
 915       };
 916
 917       if ($@ || !$rv) {
 918         $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr))
 919           if $self->connected;
 920         $self->_populate_dbh;
 921       } else {
 922         last RETRY;
 923       }
 924     } else {
 925       $self->throw_exception("'$sql' did not generate a statement.");
 926     }
 927   } # While(1) to retry if disconencted
 928
 929   if ($self->debug) {
 930      my @debug_bind =
 931        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 932      $self->debugobj->query_end($sql, @debug_bind);
 933   }
 934   return (wantarray ? ($rv, $sth, @bind) : $rv);
 935 }
 936
 937 sub insert {
 938   my ($self, $source, $to_insert) = @_;
 939
 940   my $ident = $source->from;
 941   my $bind_attributes = $self->source_bind_attributes($source);
 942
 943   $self->throw_exception(
 944     "Couldn't insert ".join(', ',
 945       map "$_ => $to_insert->{$_}", keys %$to_insert
 946     )." into ${ident}"
 947   ) unless ($self->_execute('insert' => [], $source, $bind_attributes, $to_insert));
 948   return $to_insert;
 949 }
 950
 951 ## Still not quite perfect, and EXPERIMENTAL
 952 ## Currently it is assumed that all values passed will be "normal", i.e. not
 953 ## scalar refs, or at least, all the same type as the first set, the statement is
 954 ## only prepped once.
 955 sub insert_bulk {
 956   my ($self, $source, $cols, $data) = @_;
 957   my %colvalues;
 958   my $table = $source->from;
 959   @colvalues{@$cols} = (0..$#$cols);
 960   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 961
 962   if ($self->debug) {
 963       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 964       $self->debugobj->query_start($sql, @debug_bind);
 965   }
 966   my $sth = $self->sth($sql);
 967
 968 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 969
 970   my $rv;
 971
 972   ## This must be an arrayref, else nothing works!
 973
 974   my $tuple_status = [];
 975
 976   ##use Data::Dumper;
 977   ##print STDERR Dumper( $data, $sql, [@bind] );
 978
 979   if ($sth) {
 980
 981     my $time = time();
 982
 983     ## Get the bind_attributes, if any exist
 984     my $bind_attributes = $self->source_bind_attributes($source);
 985
 986     ## Bind the values and execute
 987     $rv = eval {
 988
 989      my $placeholder_index = 1;
 990
 991         foreach my $bound (@bind) {
 992
 993           my $attributes = {};
 994           my ($column_name, $data_index) = @$bound;
 995
 996           if( $bind_attributes ) {
 997             $attributes = $bind_attributes->{$column_name}
 998             if defined $bind_attributes->{$column_name};
 999           }
1000
1001           my @data = map { $_->[$data_index] } @$data;
1002
1003           $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1004           $placeholder_index++;
1005       }
1006       $sth->execute_array( {ArrayTupleStatus => $tuple_status} );
1007
1008     };
1009
1010     if ($@ || !defined $rv) {
1011       my $errors = '';
1012       foreach my $tuple (@$tuple_status) {
1013           $errors .= "\n" . $tuple->[1] if(ref $tuple);
1014       }
1015       $self->throw_exception("Error executing '$sql': ".($@ || $errors));
1016     }
1017   } else {
1018     $self->throw_exception("'$sql' did not generate a statement.");
1019   }
1020   if ($self->debug) {
1021       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
1022       $self->debugobj->query_end($sql, @debug_bind);
1023   }
1024   return (wantarray ? ($rv, $sth, @bind) : $rv);
1025 }
1026
1027 sub update {
1028   my $self = shift @_;
1029   my $source = shift @_;
1030   my $bind_attributes = $self->source_bind_attributes($source);
1031
1032   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1033 }
1034
1035
1036 sub delete {
1037   my $self = shift @_;
1038   my $source = shift @_;
1039
1040   my $bind_attrs = {}; ## If ever it's needed...
1041
1042   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1043 }
1044
1045 sub _select {
1046   my ($self, $ident, $select, $condition, $attrs) = @_;
1047   my $order = $attrs->{order_by};
1048   if (ref $condition eq 'SCALAR') {
1049     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1050   }
1051   if (exists $attrs->{group_by} || $attrs->{having}) {
1052     $order = {
1053       group_by => $attrs->{group_by},
1054       having => $attrs->{having},
1055       ($order ? (order_by => $order) : ())
1056     };
1057   }
1058   my $bind_attrs = {}; ## Future support
1059   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1060   if ($attrs->{software_limit} ||
1061       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1062         $attrs->{software_limit} = 1;
1063   } else {
1064     $self->throw_exception("rows attribute must be positive if present")
1065       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1066     push @args, $attrs->{rows}, $attrs->{offset};
1067   }
1068   return $self->_execute(@args);
1069 }
1070
1071 sub source_bind_attributes {
1072   my ($self, $source) = @_;
1073
1074   my $bind_attributes;
1075   foreach my $column ($source->columns) {
1076
1077     my $data_type = $source->column_info($column)->{data_type} || '';
1078     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1079      if $data_type;
1080   }
1081
1082   return $bind_attributes;
1083 }
1084
1085 =head2 select
1086
1087 =over 4
1088
1089 =item Arguments: $ident, $select, $condition, $attrs
1090
1091 =back
1092
1093 Handle a SQL select statement.
1094
1095 =cut
1096
1097 sub select {
1098   my $self = shift;
1099   my ($ident, $select, $condition, $attrs) = @_;
1100   return $self->cursor->new($self, \@_, $attrs);
1101 }
1102
1103 sub select_single {
1104   my $self = shift;
1105   my ($rv, $sth, @bind) = $self->_select(@_);
1106   my @row = $sth->fetchrow_array;
1107   # Need to call finish() to work round broken DBDs
1108   $sth->finish();
1109   return @row;
1110 }
1111
1112 =head2 sth
1113
1114 =over 4
1115
1116 =item Arguments: $sql
1117
1118 =back
1119
1120 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1121
1122 =cut
1123
1124 sub _dbh_sth {
1125   my ($self, $dbh, $sql) = @_;
1126
1127   # 3 is the if_active parameter which avoids active sth re-use
1128   my $sth = $self->disable_sth_caching
1129     ? $dbh->prepare($sql)
1130     : $dbh->prepare_cached($sql, {}, 3);
1131
1132   $self->throw_exception(
1133     'no sth generated via sql (' . ($@ || $dbh->errstr) . "): $sql"
1134   ) if !$sth;
1135
1136   $sth;
1137 }
1138
1139 sub sth {
1140   my ($self, $sql) = @_;
1141   $self->dbh_do($self->can('_dbh_sth'), $sql);
1142 }
1143
1144 sub _dbh_columns_info_for {
1145   my ($self, $dbh, $table) = @_;
1146
1147   if ($dbh->can('column_info')) {
1148     my %result;
1149     eval {
1150       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1151       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1152       $sth->execute();
1153       while ( my $info = $sth->fetchrow_hashref() ){
1154         my %column_info;
1155         $column_info{data_type}   = $info->{TYPE_NAME};
1156         $column_info{size}      = $info->{COLUMN_SIZE};
1157         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1158         $column_info{default_value} = $info->{COLUMN_DEF};
1159         my $col_name = $info->{COLUMN_NAME};
1160         $col_name =~ s/^\"(.*)\"$/$1/;
1161
1162         $result{$col_name} = \%column_info;
1163       }
1164     };
1165     return \%result if !$@ && scalar keys %result;
1166   }
1167
1168   my %result;
1169   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1170   $sth->execute;
1171   my @columns = @{$sth->{NAME_lc}};
1172   for my $i ( 0 .. $#columns ){
1173     my %column_info;
1174     $column_info{data_type} = $sth->{TYPE}->[$i];
1175     $column_info{size} = $sth->{PRECISION}->[$i];
1176     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1177
1178     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1179       $column_info{data_type} = $1;
1180       $column_info{size}    = $2;
1181     }
1182
1183     $result{$columns[$i]} = \%column_info;
1184   }
1185   $sth->finish;
1186
1187   foreach my $col (keys %result) {
1188     my $colinfo = $result{$col};
1189     my $type_num = $colinfo->{data_type};
1190     my $type_name;
1191     if(defined $type_num && $dbh->can('type_info')) {
1192       my $type_info = $dbh->type_info($type_num);
1193       $type_name = $type_info->{TYPE_NAME} if $type_info;
1194       $colinfo->{data_type} = $type_name if $type_name;
1195     }
1196   }
1197
1198   return \%result;
1199 }
1200
1201 sub columns_info_for {
1202   my ($self, $table) = @_;
1203   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1204 }
1205
1206 =head2 last_insert_id
1207
1208 Return the row id of the last insert.
1209
1210 =cut
1211
1212 sub _dbh_last_insert_id {
1213     my ($self, $dbh, $source, $col) = @_;
1214     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1215     $dbh->func('last_insert_rowid');
1216 }
1217
1218 sub last_insert_id {
1219   my $self = shift;
1220   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1221 }
1222
1223 =head2 sqlt_type
1224
1225 Returns the database driver name.
1226
1227 =cut
1228
1229 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1230
1231 =head2 bind_attribute_by_data_type
1232
1233 Given a datatype from column info, returns a database specific bind attribute for
1234 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1235 just handle it.
1236
1237 Generally only needed for special case column types, like bytea in postgres.
1238
1239 =cut
1240
1241 sub bind_attribute_by_data_type {
1242     return;
1243 }
1244
1245 =head2 create_ddl_dir (EXPERIMENTAL)
1246
1247 =over 4
1248
1249 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1250
1251 =back
1252
1253 Creates a SQL file based on the Schema, for each of the specified
1254 database types, in the given directory.
1255
1256 Note that this feature is currently EXPERIMENTAL and may not work correctly
1257 across all databases, or fully handle complex relationships.
1258
1259 =cut
1260
1261 sub create_ddl_dir
1262 {
1263   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1264
1265   if(!$dir || !-d $dir)
1266   {
1267     warn "No directory given, using ./\n";
1268     $dir = "./";
1269   }
1270   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1271   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1272   $version ||= $schema->VERSION || '1.x';
1273   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1274
1275   eval "use SQL::Translator";
1276   $self->throw_exception("Can't create a ddl file without SQL::Translator: $@") if $@;
1277
1278   my $sqlt = SQL::Translator->new({
1279 #      debug => 1,
1280       add_drop_table => 1,
1281   });
1282   foreach my $db (@$databases)
1283   {
1284     $sqlt->reset();
1285     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1286 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1287     $sqlt = $self->configure_sqlt($sqlt, $db);
1288     $sqlt->data($schema);
1289     $sqlt->producer($db);
1290
1291     my $file;
1292     my $filename = $schema->ddl_filename($db, $dir, $version);
1293     if(-e $filename)
1294     {
1295       warn("$filename already exists, skipping $db");
1296       next;
1297     }
1298
1299     my $output = $sqlt->translate;
1300     if(!$output)
1301     {
1302       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1303       next;
1304     }
1305     if(!open($file, ">$filename"))
1306     {
1307         $self->throw_exception("Can't open $filename for writing ($!)");
1308         next;
1309     }
1310     print $file $output;
1311     close($file);
1312
1313     if($preversion)
1314     {
1315       eval "use SQL::Translator::Diff";
1316       if($@)
1317       {
1318         warn("Can't diff versions without SQL::Translator::Diff: $@");
1319         next;
1320       }
1321
1322       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1323 #      print "Previous version $prefilename\n";
1324       if(!-e $prefilename)
1325       {
1326         warn("No previous schema file found ($prefilename)");
1327         next;
1328       }
1329       #### We need to reparse the SQLite file we just wrote, so that
1330       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1331       ##   FIXME: rip Diff to pieces!
1332 #      my $target_schema = $sqlt->schema;
1333 #      unless ( $target_schema->name ) {
1334 #        $target_schema->name( $filename );
1335 #      }
1336       my @input;
1337       push @input, {file => $prefilename, parser => $db};
1338       push @input, {file => $filename, parser => $db};
1339       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1340         my $file   = $_->{'file'};
1341         my $parser = $_->{'parser'};
1342
1343         my $t = SQL::Translator->new;
1344         $t->debug( 0 );
1345         $t->trace( 0 );
1346         $t->parser( $parser )            or die $t->error;
1347         my $out = $t->translate( $file ) or die $t->error;
1348         my $schema = $t->schema;
1349         unless ( $schema->name ) {
1350           $schema->name( $file );
1351         }
1352         ($schema, $parser);
1353       } @input;
1354
1355       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1356                                                     $target_schema, $db,
1357                                                     {}
1358                                                    );
1359       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1360       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1361       if(-e $difffile)
1362       {
1363         warn("$difffile already exists, skipping");
1364         next;
1365       }
1366       if(!open $file, ">$difffile")
1367       {
1368         $self->throw_exception("Can't write to $difffile ($!)");
1369         next;
1370       }
1371       print $file $diff;
1372       close($file);
1373     }
1374   }
1375 }
1376
1377 sub configure_sqlt() {
1378   my $self = shift;
1379   my $tr = shift;
1380   my $db = shift || $self->sqlt_type;
1381   if ($db eq 'PostgreSQL') {
1382     $tr->quote_table_names(0);
1383     $tr->quote_field_names(0);
1384   }
1385   return $tr;
1386 }
1387
1388 =head2 deployment_statements
1389
1390 =over 4
1391
1392 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1393
1394 =back
1395
1396 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1397 The database driver name is given by C<$type>, though the value from
1398 L</sqlt_type> is used if it is not specified.
1399
1400 C<$directory> is used to return statements from files in a previously created
1401 L</create_ddl_dir> directory and is optional. The filenames are constructed
1402 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1403
1404 If no C<$directory> is specified then the statements are constructed on the
1405 fly using L<SQL::Translator> and C<$version> is ignored.
1406
1407 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1408
1409 =cut
1410
1411 sub deployment_statements {
1412   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1413   # Need to be connected to get the correct sqlt_type
1414   $self->ensure_connected() unless $type;
1415   $type ||= $self->sqlt_type;
1416   $version ||= $schema->VERSION || '1.x';
1417   $dir ||= './';
1418   my $filename = $schema->ddl_filename($type, $dir, $version);
1419   if(-f $filename)
1420   {
1421       my $file;
1422       open($file, "<$filename")
1423         or $self->throw_exception("Can't open $filename ($!)");
1424       my @rows = <$file>;
1425       close($file);
1426       return join('', @rows);
1427   }
1428
1429   eval "use SQL::Translator";
1430   if(!$@)
1431   {
1432     eval "use SQL::Translator::Parser::DBIx::Class;";
1433     $self->throw_exception($@) if $@;
1434     eval "use SQL::Translator::Producer::${type};";
1435     $self->throw_exception($@) if $@;
1436
1437     # sources needs to be a parser arg, but for simplicty allow at top level
1438     # coming in
1439     $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1440         if exists $sqltargs->{sources};
1441
1442     my $tr = SQL::Translator->new(%$sqltargs);
1443     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1444     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1445   }
1446
1447   $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
1448   return;
1449
1450 }
1451
1452 sub deploy {
1453   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1454   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1455     for ( split(";\n", $statement)) {
1456       next if($_ =~ /^--/);
1457       next if(!$_);
1458 #      next if($_ =~ /^DROP/m);
1459       next if($_ =~ /^BEGIN TRANSACTION/m);
1460       next if($_ =~ /^COMMIT/m);
1461       next if $_ =~ /^\s+$/; # skip whitespace only
1462       $self->debugobj->query_start($_) if $self->debug;
1463       $self->dbh->do($_) or warn "SQL was:\n $_"; # XXX exceptions?
1464       $self->debugobj->query_end($_) if $self->debug;
1465     }
1466   }
1467 }
1468
1469 =head2 datetime_parser
1470
1471 Returns the datetime parser class
1472
1473 =cut
1474
1475 sub datetime_parser {
1476   my $self = shift;
1477   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
1478 }
1479
1480 =head2 datetime_parser_type
1481
1482 Defines (returns) the datetime parser class - currently hardwired to
1483 L<DateTime::Format::MySQL>
1484
1485 =cut
1486
1487 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1488
1489 =head2 build_datetime_parser
1490
1491 See L</datetime_parser>
1492
1493 =cut
1494
1495 sub build_datetime_parser {
1496   my $self = shift;
1497   my $type = $self->datetime_parser_type(@_);
1498   eval "use ${type}";
1499   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1500   return $type;
1501 }
1502
1503 sub DESTROY {
1504   my $self = shift;
1505   return if !$self->_dbh;
1506   $self->_verify_pid;
1507   $self->_dbh(undef);
1508 }
1509
1510 1;
1511
1512 =head1 SQL METHODS
1513
1514 The module defines a set of methods within the DBIC::SQL::Abstract
1515 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1516 SQL query functions.
1517
1518 The following methods are extended:-
1519
1520 =over 4
1521
1522 =item delete
1523
1524 =item insert
1525
1526 =item select
1527
1528 =item update
1529
1530 =item limit_dialect
1531
1532 See L</connect_info> for details.
1533 For setting, this method is deprecated in favor of L</connect_info>.
1534
1535 =item quote_char
1536
1537 See L</connect_info> for details.
1538 For setting, this method is deprecated in favor of L</connect_info>.
1539
1540 =item name_sep
1541
1542 See L</connect_info> for details.
1543 For setting, this method is deprecated in favor of L</connect_info>.
1544
1545 =back
1546
1547 =head1 AUTHORS
1548
1549 Matt S. Trout <mst@shadowcatsystems.co.uk>
1550
1551 Andy Grundman <andy@hybridized.org>
1552
1553 =head1 LICENSE
1554
1555 You may distribute this code under the same terms as Perl itself.
1556
1557 =cut