lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Sub::Name 'subname';
  14 use Context::Preserve 'preserve_context';
  15 use Try::Tiny;
  16 use overload ();
  17 use Data::Compare (); # no imports!!! guard against insane architecture
  18 use namespace::clean;
  19
  20 # default cursor class, overridable in connect_info attributes
  21 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  22
  23 __PACKAGE__->mk_group_accessors('inherited' => qw/
  24   sql_limit_dialect sql_quote_char sql_name_sep
  25 /);
  26
  27 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  28
  29 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  30 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  31
  32 __PACKAGE__->sql_name_sep('.');
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/
  35   _connect_info _dbic_connect_attributes _driver_determined
  36   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  37   _perform_autoinc_retrieval _autoinc_supplied_for_op
  38 /);
  39
  40 # the values for these accessors are picked out (and deleted) from
  41 # the attribute hashref passed to connect_info
  42 my @storage_options = qw/
  43   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  44   disable_sth_caching unsafe auto_savepoint
  45 /;
  46 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  47
  48
  49 # capability definitions, using a 2-tiered accessor system
  50 # The rationale is:
  51 #
  52 # A driver/user may define _use_X, which blindly without any checks says:
  53 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  54 # type accessor)
  55 #
  56 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  57 # accessor, which in turn calls _determine_supports_X, and stores the return
  58 # in a special slot on the storage object, which is wiped every time a $dbh
  59 # reconnection takes place (it is not guaranteed that upon reconnection we
  60 # will get the same rdbms version). _determine_supports_X does not need to
  61 # exist on a driver, as we ->can for it before calling.
  62
  63 my @capabilities = (qw/
  64   insert_returning
  65   insert_returning_bound
  66
  67   multicolumn_in
  68
  69   placeholders
  70   typeless_placeholders
  71
  72   join_optimizer
  73 /);
  74 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  75 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  76
  77 # on by default, not strictly a capability (pending rewrite)
  78 __PACKAGE__->_use_join_optimizer (1);
  79 sub _determine_supports_join_optimizer { 1 };
  80
  81 # Each of these methods need _determine_driver called before itself
  82 # in order to function reliably. We also need to separate accessors
  83 # from plain old method calls, since an accessor called as a setter
  84 # does *not* need the driver determination loop fired (and in fact
  85 # can produce hard to find bugs, like e.g. losing on_connect_*
  86 # semantics on fresh connections)
  87 #
  88 # The construct below is simply a parameterized around()
  89 my $storage_accessor_idx = { map { $_ => 1 } qw(
  90   sqlt_type
  91   datetime_parser_type
  92
  93   sql_maker
  94   cursor_class
  95 )};
  96 for my $meth (keys %$storage_accessor_idx, qw(
  97   deployment_statements
  98
  99   build_datetime_parser
 100
 101   txn_begin
 102
 103   insert
 104   insert_bulk
 105   update
 106   delete
 107   select
 108   select_single
 109
 110   with_deferred_fk_checks
 111
 112   get_use_dbms_capability
 113   get_dbms_capability
 114
 115   _server_info
 116   _get_server_version
 117 )) {
 118
 119   my $orig = __PACKAGE__->can ($meth)
 120     or die "$meth is not a ::Storage::DBI method!";
 121
 122   no strict 'refs';
 123   no warnings 'redefine';
 124   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 125     if (
 126       # only fire when invoked on an instance, a valid class-based invocation
 127       # would e.g. be setting a default for an inherited accessor
 128       ref $_[0]
 129         and
 130       ! $_[0]->{_driver_determined}
 131         and
 132       ! $_[0]->{_in_determine_driver}
 133         and
 134       # if this is a known *setter* - just set it, no need to connect
 135       # and determine the driver
 136       ! ( $storage_accessor_idx->{$meth} and @_ > 1 )
 137         and
 138       # Only try to determine stuff if we have *something* that either is or can
 139       # provide a DSN. Allows for bare $schema's generated with a plain ->connect()
 140       # to still be marginally useful
 141       $_[0]->_dbi_connect_info->[0]
 142     ) {
 143       $_[0]->_determine_driver;
 144
 145       # This for some reason crashes and burns on perl 5.8.1
 146       # IFF the method ends up throwing an exception
 147       #goto $_[0]->can ($meth);
 148
 149       my $cref = $_[0]->can ($meth);
 150       goto $cref;
 151     }
 152
 153     goto $orig;
 154   };
 155 }
 156
 157 =head1 NAME
 158
 159 DBIx::Class::Storage::DBI - DBI storage handler
 160
 161 =head1 SYNOPSIS
 162
 163   my $schema = MySchema->connect('dbi:SQLite:my.db');
 164
 165   $schema->storage->debug(1);
 166
 167   my @stuff = $schema->storage->dbh_do(
 168     sub {
 169       my ($storage, $dbh, @args) = @_;
 170       $dbh->do("DROP TABLE authors");
 171     },
 172     @column_list
 173   );
 174
 175   $schema->resultset('Book')->search({
 176      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 177   });
 178
 179 =head1 DESCRIPTION
 180
 181 This class represents the connection to an RDBMS via L<DBI>.  See
 182 L<DBIx::Class::Storage> for general information.  This pod only
 183 documents DBI-specific methods and behaviors.
 184
 185 =head1 METHODS
 186
 187 =cut
 188
 189 sub new {
 190   my $new = shift->next::method(@_);
 191
 192   $new->_sql_maker_opts({});
 193   $new->_dbh_details({});
 194   $new->{_in_do_block} = 0;
 195
 196   # read below to see what this does
 197   $new->_arm_global_destructor;
 198
 199   $new;
 200 }
 201
 202 # This is hack to work around perl shooting stuff in random
 203 # order on exit(). If we do not walk the remaining storage
 204 # objects in an END block, there is a *small but real* chance
 205 # of a fork()ed child to kill the parent's shared DBI handle,
 206 # *before perl reaches the DESTROY in this package*
 207 # Yes, it is ugly and effective.
 208 # Additionally this registry is used by the CLONE method to
 209 # make sure no handles are shared between threads
 210 {
 211   my %seek_and_destroy;
 212
 213   sub _arm_global_destructor {
 214
 215     # quick "garbage collection" pass - prevents the registry
 216     # from slowly growing with a bunch of undef-valued keys
 217     defined $seek_and_destroy{$_} or delete $seek_and_destroy{$_}
 218       for keys %seek_and_destroy;
 219
 220     weaken (
 221       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 222     );
 223   }
 224
 225   END {
 226     local $?; # just in case the DBI destructor changes it somehow
 227
 228     # destroy just the object if not native to this process
 229     $_->_verify_pid for (grep
 230       { defined $_ }
 231       values %seek_and_destroy
 232     );
 233   }
 234
 235   sub CLONE {
 236     # As per DBI's recommendation, DBIC disconnects all handles as
 237     # soon as possible (DBIC will reconnect only on demand from within
 238     # the thread)
 239     my @instances = grep { defined $_ } values %seek_and_destroy;
 240     %seek_and_destroy = ();
 241
 242     for (@instances) {
 243       $_->_dbh(undef);
 244
 245       $_->transaction_depth(0);
 246       $_->savepoints([]);
 247
 248       # properly renumber existing refs
 249       $_->_arm_global_destructor
 250     }
 251   }
 252 }
 253
 254 sub DESTROY {
 255   my $self = shift;
 256
 257   # some databases spew warnings on implicit disconnect
 258   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 259   local $SIG{__WARN__} = sub {};
 260   $self->_dbh(undef);
 261
 262   # this op is necessary, since the very last perl runtime statement
 263   # triggers a global destruction shootout, and the $SIG localization
 264   # may very well be destroyed before perl actually gets to do the
 265   # $dbh undef
 266   1;
 267 }
 268
 269 # handle pid changes correctly - do not destroy parent's connection
 270 sub _verify_pid {
 271   my $self = shift;
 272
 273   my $pid = $self->_conn_pid;
 274   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 275     $dbh->{InactiveDestroy} = 1;
 276     $self->_dbh(undef);
 277     $self->transaction_depth(0);
 278     $self->savepoints([]);
 279   }
 280
 281   return;
 282 }
 283
 284 =head2 connect_info
 285
 286 This method is normally called by L<DBIx::Class::Schema/connection>, which
 287 encapsulates its argument list in an arrayref before passing them here.
 288
 289 The argument list may contain:
 290
 291 =over
 292
 293 =item *
 294
 295 The same 4-element argument set one would normally pass to
 296 L<DBI/connect>, optionally followed by
 297 L<extra attributes|/DBIx::Class specific connection attributes>
 298 recognized by DBIx::Class:
 299
 300   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 301
 302 =item *
 303
 304 A single code reference which returns a connected
 305 L<DBI database handle|DBI/connect> optionally followed by
 306 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 307 by DBIx::Class:
 308
 309   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 310
 311 =item *
 312
 313 A single hashref with all the attributes and the dsn/user/password
 314 mixed together:
 315
 316   $connect_info_args = [{
 317     dsn => $dsn,
 318     user => $user,
 319     password => $pass,
 320     %dbi_attributes,
 321     %extra_attributes,
 322   }];
 323
 324   $connect_info_args = [{
 325     dbh_maker => sub { DBI->connect (...) },
 326     %dbi_attributes,
 327     %extra_attributes,
 328   }];
 329
 330 This is particularly useful for L<Catalyst> based applications, allowing the
 331 following config (L<Config::General> style):
 332
 333   <Model::DB>
 334     schema_class   App::DB
 335     <connect_info>
 336       dsn          dbi:mysql:database=test
 337       user         testuser
 338       password     TestPass
 339       AutoCommit   1
 340     </connect_info>
 341   </Model::DB>
 342
 343 The C<dsn>/C<user>/C<password> combination can be substituted by the
 344 C<dbh_maker> key whose value is a coderef that returns a connected
 345 L<DBI database handle|DBI/connect>
 346
 347 =back
 348
 349 Please note that the L<DBI> docs recommend that you always explicitly
 350 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 351 recommends that it be set to I<1>, and that you perform transactions
 352 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 353 to I<1> if you do not do explicitly set it to zero.  This is the default
 354 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 355
 356 =head3 DBIx::Class specific connection attributes
 357
 358 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 359 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 360 the following connection options. These options can be mixed in with your other
 361 L<DBI> connection attributes, or placed in a separate hashref
 362 (C<\%extra_attributes>) as shown above.
 363
 364 Every time C<connect_info> is invoked, any previous settings for
 365 these options will be cleared before setting the new ones, regardless of
 366 whether any options are specified in the new C<connect_info>.
 367
 368
 369 =over
 370
 371 =item on_connect_do
 372
 373 Specifies things to do immediately after connecting or re-connecting to
 374 the database.  Its value may contain:
 375
 376 =over
 377
 378 =item a scalar
 379
 380 This contains one SQL statement to execute.
 381
 382 =item an array reference
 383
 384 This contains SQL statements to execute in order.  Each element contains
 385 a string or a code reference that returns a string.
 386
 387 =item a code reference
 388
 389 This contains some code to execute.  Unlike code references within an
 390 array reference, its return value is ignored.
 391
 392 =back
 393
 394 =item on_disconnect_do
 395
 396 Takes arguments in the same form as L</on_connect_do> and executes them
 397 immediately before disconnecting from the database.
 398
 399 Note, this only runs if you explicitly call L</disconnect> on the
 400 storage object.
 401
 402 =item on_connect_call
 403
 404 A more generalized form of L</on_connect_do> that calls the specified
 405 C<connect_call_METHOD> methods in your storage driver.
 406
 407   on_connect_do => 'select 1'
 408
 409 is equivalent to:
 410
 411   on_connect_call => [ [ do_sql => 'select 1' ] ]
 412
 413 Its values may contain:
 414
 415 =over
 416
 417 =item a scalar
 418
 419 Will call the C<connect_call_METHOD> method.
 420
 421 =item a code reference
 422
 423 Will execute C<< $code->($storage) >>
 424
 425 =item an array reference
 426
 427 Each value can be a method name or code reference.
 428
 429 =item an array of arrays
 430
 431 For each array, the first item is taken to be the C<connect_call_> method name
 432 or code reference, and the rest are parameters to it.
 433
 434 =back
 435
 436 Some predefined storage methods you may use:
 437
 438 =over
 439
 440 =item do_sql
 441
 442 Executes a SQL string or a code reference that returns a SQL string. This is
 443 what L</on_connect_do> and L</on_disconnect_do> use.
 444
 445 It can take:
 446
 447 =over
 448
 449 =item a scalar
 450
 451 Will execute the scalar as SQL.
 452
 453 =item an arrayref
 454
 455 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 456 attributes hashref and bind values.
 457
 458 =item a code reference
 459
 460 Will execute C<< $code->($storage) >> and execute the return array refs as
 461 above.
 462
 463 =back
 464
 465 =item datetime_setup
 466
 467 Execute any statements necessary to initialize the database session to return
 468 and accept datetime/timestamp values used with
 469 L<DBIx::Class::InflateColumn::DateTime>.
 470
 471 Only necessary for some databases, see your specific storage driver for
 472 implementation details.
 473
 474 =back
 475
 476 =item on_disconnect_call
 477
 478 Takes arguments in the same form as L</on_connect_call> and executes them
 479 immediately before disconnecting from the database.
 480
 481 Calls the C<disconnect_call_METHOD> methods as opposed to the
 482 C<connect_call_METHOD> methods called by L</on_connect_call>.
 483
 484 Note, this only runs if you explicitly call L</disconnect> on the
 485 storage object.
 486
 487 =item disable_sth_caching
 488
 489 If set to a true value, this option will disable the caching of
 490 statement handles via L<DBI/prepare_cached>.
 491
 492 =item limit_dialect
 493
 494 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 495 default L</sql_limit_dialect> setting of the storage (if any). For a list
 496 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 497
 498 =item quote_names
 499
 500 When true automatically sets L</quote_char> and L</name_sep> to the characters
 501 appropriate for your particular RDBMS. This option is preferred over specifying
 502 L</quote_char> directly.
 503
 504 =item quote_char
 505
 506 Specifies what characters to use to quote table and column names.
 507
 508 C<quote_char> expects either a single character, in which case is it
 509 is placed on either side of the table/column name, or an arrayref of length
 510 2 in which case the table/column name is placed between the elements.
 511
 512 For example under MySQL you should use C<< quote_char => '`' >>, and for
 513 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 514
 515 =item name_sep
 516
 517 This parameter is only useful in conjunction with C<quote_char>, and is used to
 518 specify the character that separates elements (schemas, tables, columns) from
 519 each other. If unspecified it defaults to the most commonly used C<.>.
 520
 521 =item unsafe
 522
 523 This Storage driver normally installs its own C<HandleError>, sets
 524 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 525 all database handles, including those supplied by a coderef.  It does this
 526 so that it can have consistent and useful error behavior.
 527
 528 If you set this option to a true value, Storage will not do its usual
 529 modifications to the database handle's attributes, and instead relies on
 530 the settings in your connect_info DBI options (or the values you set in
 531 your connection coderef, in the case that you are connecting via coderef).
 532
 533 Note that your custom settings can cause Storage to malfunction,
 534 especially if you set a C<HandleError> handler that suppresses exceptions
 535 and/or disable C<RaiseError>.
 536
 537 =item auto_savepoint
 538
 539 If this option is true, L<DBIx::Class> will use savepoints when nesting
 540 transactions, making it possible to recover from failure in the inner
 541 transaction without having to abort all outer transactions.
 542
 543 =item cursor_class
 544
 545 Use this argument to supply a cursor class other than the default
 546 L<DBIx::Class::Storage::DBI::Cursor>.
 547
 548 =back
 549
 550 Some real-life examples of arguments to L</connect_info> and
 551 L<DBIx::Class::Schema/connect>
 552
 553   # Simple SQLite connection
 554   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 555
 556   # Connect via subref
 557   ->connect_info([ sub { DBI->connect(...) } ]);
 558
 559   # Connect via subref in hashref
 560   ->connect_info([{
 561     dbh_maker => sub { DBI->connect(...) },
 562     on_connect_do => 'alter session ...',
 563   }]);
 564
 565   # A bit more complicated
 566   ->connect_info(
 567     [
 568       'dbi:Pg:dbname=foo',
 569       'postgres',
 570       'my_pg_password',
 571       { AutoCommit => 1 },
 572       { quote_char => q{"} },
 573     ]
 574   );
 575
 576   # Equivalent to the previous example
 577   ->connect_info(
 578     [
 579       'dbi:Pg:dbname=foo',
 580       'postgres',
 581       'my_pg_password',
 582       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 583     ]
 584   );
 585
 586   # Same, but with hashref as argument
 587   # See parse_connect_info for explanation
 588   ->connect_info(
 589     [{
 590       dsn         => 'dbi:Pg:dbname=foo',
 591       user        => 'postgres',
 592       password    => 'my_pg_password',
 593       AutoCommit  => 1,
 594       quote_char  => q{"},
 595       name_sep    => q{.},
 596     }]
 597   );
 598
 599   # Subref + DBIx::Class-specific connection options
 600   ->connect_info(
 601     [
 602       sub { DBI->connect(...) },
 603       {
 604           quote_char => q{`},
 605           name_sep => q{@},
 606           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 607           disable_sth_caching => 1,
 608       },
 609     ]
 610   );
 611
 612
 613
 614 =cut
 615
 616 sub connect_info {
 617   my ($self, $info) = @_;
 618
 619   return $self->_connect_info if !$info;
 620
 621   $self->_connect_info($info); # copy for _connect_info
 622
 623   $info = $self->_normalize_connect_info($info)
 624     if ref $info eq 'ARRAY';
 625
 626   my %attrs = (
 627     %{ $self->_default_dbi_connect_attributes || {} },
 628     %{ $info->{attributes} || {} },
 629   );
 630
 631   my @args = @{ $info->{arguments} };
 632
 633   if (keys %attrs and ref $args[0] ne 'CODE') {
 634     carp_unique (
 635         'You provided explicit AutoCommit => 0 in your connection_info. '
 636       . 'This is almost universally a bad idea (see the footnotes of '
 637       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 638       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 639       . 'this warning.'
 640     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 641
 642     push @args, \%attrs if keys %attrs;
 643   }
 644
 645   # this is the authoritative "always an arrayref" thing fed to DBI->connect
 646   # OR a single-element coderef-based $dbh factory
 647   $self->_dbi_connect_info(\@args);
 648
 649   # extract the individual storage options
 650   for my $storage_opt (keys %{ $info->{storage_options} }) {
 651     my $value = $info->{storage_options}{$storage_opt};
 652
 653     $self->$storage_opt($value);
 654   }
 655
 656   # Extract the individual sqlmaker options
 657   #
 658   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 659   #  the new set of options
 660   $self->_sql_maker(undef);
 661   $self->_sql_maker_opts({});
 662
 663   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 664     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 665
 666     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 667   }
 668
 669   # FIXME - dirty:
 670   # save attributes in a separate accessor so they are always
 671   # introspectable, even in case of a CODE $dbhmaker
 672   $self->_dbic_connect_attributes (\%attrs);
 673
 674   return $self->_connect_info;
 675 }
 676
 677 sub _dbi_connect_info {
 678   my $self = shift;
 679
 680   return $self->{_dbi_connect_info} = $_[0]
 681     if @_;
 682
 683   my $conninfo = $self->{_dbi_connect_info} || [];
 684
 685   # last ditch effort to grab a DSN
 686   if ( ! defined $conninfo->[0] and $ENV{DBI_DSN} ) {
 687     my @new_conninfo = @$conninfo;
 688     $new_conninfo[0] = $ENV{DBI_DSN};
 689     $conninfo = \@new_conninfo;
 690   }
 691
 692   return $conninfo;
 693 }
 694
 695
 696 sub _normalize_connect_info {
 697   my ($self, $info_arg) = @_;
 698   my %info;
 699
 700   my @args = @$info_arg;  # take a shallow copy for further mutilation
 701
 702   # combine/pre-parse arguments depending on invocation style
 703
 704   my %attrs;
 705   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 706     %attrs = %{ $args[1] || {} };
 707     @args = $args[0];
 708   }
 709   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 710     %attrs = %{$args[0]};
 711     @args = ();
 712     if (my $code = delete $attrs{dbh_maker}) {
 713       @args = $code;
 714
 715       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 716       if (@ignored) {
 717         carp sprintf (
 718             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 719           . "to the result of 'dbh_maker'",
 720
 721           join (', ', map { "'$_'" } (@ignored) ),
 722         );
 723       }
 724     }
 725     else {
 726       @args = delete @attrs{qw/dsn user password/};
 727     }
 728   }
 729   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 730     %attrs = (
 731       % { $args[3] || {} },
 732       % { $args[4] || {} },
 733     );
 734     @args = @args[0,1,2];
 735   }
 736
 737   $info{arguments} = \@args;
 738
 739   my @storage_opts = grep exists $attrs{$_},
 740     @storage_options, 'cursor_class';
 741
 742   @{ $info{storage_options} }{@storage_opts} =
 743     delete @attrs{@storage_opts} if @storage_opts;
 744
 745   my @sql_maker_opts = grep exists $attrs{$_},
 746     qw/limit_dialect quote_char name_sep quote_names/;
 747
 748   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 749     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 750
 751   $info{attributes} = \%attrs if %attrs;
 752
 753   return \%info;
 754 }
 755
 756 sub _default_dbi_connect_attributes () {
 757   +{
 758     AutoCommit => 1,
 759     PrintError => 0,
 760     RaiseError => 1,
 761     ShowErrorStatement => 1,
 762   };
 763 }
 764
 765 =head2 on_connect_do
 766
 767 This method is deprecated in favour of setting via L</connect_info>.
 768
 769 =cut
 770
 771 =head2 on_disconnect_do
 772
 773 This method is deprecated in favour of setting via L</connect_info>.
 774
 775 =cut
 776
 777 sub _parse_connect_do {
 778   my ($self, $type) = @_;
 779
 780   my $val = $self->$type;
 781   return () if not defined $val;
 782
 783   my @res;
 784
 785   if (not ref($val)) {
 786     push @res, [ 'do_sql', $val ];
 787   } elsif (ref($val) eq 'CODE') {
 788     push @res, $val;
 789   } elsif (ref($val) eq 'ARRAY') {
 790     push @res, map { [ 'do_sql', $_ ] } @$val;
 791   } else {
 792     $self->throw_exception("Invalid type for $type: ".ref($val));
 793   }
 794
 795   return \@res;
 796 }
 797
 798 =head2 dbh_do
 799
 800 Arguments: ($subref | $method_name), @extra_coderef_args?
 801
 802 Execute the given $subref or $method_name using the new exception-based
 803 connection management.
 804
 805 The first two arguments will be the storage object that C<dbh_do> was called
 806 on and a database handle to use.  Any additional arguments will be passed
 807 verbatim to the called subref as arguments 2 and onwards.
 808
 809 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 810 exception handling and reconnection (or failover in future subclasses).
 811
 812 Your subref should have no side-effects outside of the database, as
 813 there is the potential for your subref to be partially double-executed
 814 if the database connection was stale/dysfunctional.
 815
 816 Example:
 817
 818   my @stuff = $schema->storage->dbh_do(
 819     sub {
 820       my ($storage, $dbh, @cols) = @_;
 821       my $cols = join(q{, }, @cols);
 822       $dbh->selectrow_array("SELECT $cols FROM foo");
 823     },
 824     @column_list
 825   );
 826
 827 =cut
 828
 829 sub dbh_do {
 830   my $self = shift;
 831   my $run_target = shift; # either a coderef or a method name
 832
 833   # short circuit when we know there is no need for a runner
 834   #
 835   # FIXME - assumption may be wrong
 836   # the rationale for the txn_depth check is that if this block is a part
 837   # of a larger transaction, everything up to that point is screwed anyway
 838   return $self->$run_target($self->_get_dbh, @_)
 839     if $self->{_in_do_block} or $self->transaction_depth;
 840
 841   # take a ref instead of a copy, to preserve @_ aliasing
 842   # semantics within the coderef, but only if needed
 843   # (pseudoforking doesn't like this trick much)
 844   my $args = @_ ? \@_ : [];
 845
 846   DBIx::Class::Storage::BlockRunner->new(
 847     storage => $self,
 848     wrap_txn => 0,
 849     retry_handler => sub {
 850       $_[0]->failed_attempt_count == 1
 851         and
 852       ! $_[0]->storage->connected
 853     },
 854   )->run(sub {
 855     $self->$run_target ($self->_get_dbh, @$args )
 856   });
 857 }
 858
 859 sub txn_do {
 860   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 861   shift->next::method(@_);
 862 }
 863
 864 =head2 disconnect
 865
 866 Our C<disconnect> method also performs a rollback first if the
 867 database is not in C<AutoCommit> mode.
 868
 869 =cut
 870
 871 sub disconnect {
 872   my ($self) = @_;
 873
 874   if( $self->_dbh ) {
 875     my @actions;
 876
 877     push @actions, ( $self->on_disconnect_call || () );
 878     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 879
 880     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 881
 882     # stops the "implicit rollback on disconnect" warning
 883     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 884
 885     %{ $self->_dbh->{CachedKids} } = ();
 886     $self->_dbh->disconnect;
 887     $self->_dbh(undef);
 888   }
 889 }
 890
 891 =head2 with_deferred_fk_checks
 892
 893 =over 4
 894
 895 =item Arguments: C<$coderef>
 896
 897 =item Return Value: The return value of $coderef
 898
 899 =back
 900
 901 Storage specific method to run the code ref with FK checks deferred or
 902 in MySQL's case disabled entirely.
 903
 904 =cut
 905
 906 # Storage subclasses should override this
 907 sub with_deferred_fk_checks {
 908   my ($self, $sub) = @_;
 909   $sub->();
 910 }
 911
 912 =head2 connected
 913
 914 =over
 915
 916 =item Arguments: none
 917
 918 =item Return Value: 1|0
 919
 920 =back
 921
 922 Verifies that the current database handle is active and ready to execute
 923 an SQL statement (e.g. the connection did not get stale, server is still
 924 answering, etc.) This method is used internally by L</dbh>.
 925
 926 =cut
 927
 928 sub connected {
 929   my $self = shift;
 930   return 0 unless $self->_seems_connected;
 931
 932   #be on the safe side
 933   local $self->_dbh->{RaiseError} = 1;
 934
 935   return $self->_ping;
 936 }
 937
 938 sub _seems_connected {
 939   my $self = shift;
 940
 941   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 942
 943   my $dbh = $self->_dbh
 944     or return 0;
 945
 946   return $dbh->FETCH('Active');
 947 }
 948
 949 sub _ping {
 950   my $self = shift;
 951
 952   my $dbh = $self->_dbh or return 0;
 953
 954   return $dbh->ping;
 955 }
 956
 957 sub ensure_connected {
 958   my ($self) = @_;
 959
 960   unless ($self->connected) {
 961     $self->_populate_dbh;
 962   }
 963 }
 964
 965 =head2 dbh
 966
 967 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 968 is guaranteed to be healthy by implicitly calling L</connected>, and if
 969 necessary performing a reconnection before returning. Keep in mind that this
 970 is very B<expensive> on some database engines. Consider using L</dbh_do>
 971 instead.
 972
 973 =cut
 974
 975 sub dbh {
 976   my ($self) = @_;
 977
 978   if (not $self->_dbh) {
 979     $self->_populate_dbh;
 980   } else {
 981     $self->ensure_connected;
 982   }
 983   return $self->_dbh;
 984 }
 985
 986 # this is the internal "get dbh or connect (don't check)" method
 987 sub _get_dbh {
 988   my $self = shift;
 989   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 990   $self->_populate_dbh unless $self->_dbh;
 991   return $self->_dbh;
 992 }
 993
 994 # *DELIBERATELY* not a setter (for the time being)
 995 # Too intertwined with everything else for any kind of sanity
 996 sub sql_maker {
 997   my $self = shift;
 998
 999   $self->throw_exception('sql_maker() is not a setter method') if @_;
1000
1001   unless ($self->_sql_maker) {
1002     my $sql_maker_class = $self->sql_maker_class;
1003
1004     my %opts = %{$self->_sql_maker_opts||{}};
1005     my $dialect =
1006       $opts{limit_dialect}
1007         ||
1008       $self->sql_limit_dialect
1009         ||
1010       do {
1011         my $s_class = (ref $self) || $self;
1012         carp_unique (
1013           "Your storage class ($s_class) does not set sql_limit_dialect and you "
1014         . 'have not supplied an explicit limit_dialect in your connection_info. '
1015         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
1016         . 'databases but can be (and often is) painfully slow. '
1017         . "Please file an RT ticket against '$s_class'"
1018         ) if $self->_dbi_connect_info->[0];
1019
1020         'GenericSubQ';
1021       }
1022     ;
1023
1024     my ($quote_char, $name_sep);
1025
1026     if ($opts{quote_names}) {
1027       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
1028         my $s_class = (ref $self) || $self;
1029         carp_unique (
1030           "You requested 'quote_names' but your storage class ($s_class) does "
1031         . 'not explicitly define a default sql_quote_char and you have not '
1032         . 'supplied a quote_char as part of your connection_info. DBIC will '
1033         .q{default to the ANSI SQL standard quote '"', which works most of }
1034         . "the time. Please file an RT ticket against '$s_class'."
1035         );
1036
1037         '"'; # RV
1038       };
1039
1040       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
1041     }
1042
1043     $self->_sql_maker($sql_maker_class->new(
1044       bindtype=>'columns',
1045       array_datatypes => 1,
1046       limit_dialect => $dialect,
1047       ($quote_char ? (quote_char => $quote_char) : ()),
1048       name_sep => ($name_sep || '.'),
1049       %opts,
1050     ));
1051   }
1052   return $self->_sql_maker;
1053 }
1054
1055 # nothing to do by default
1056 sub _rebless {}
1057 sub _init {}
1058
1059 sub _populate_dbh {
1060   my ($self) = @_;
1061
1062   $self->_dbh(undef); # in case ->connected failed we might get sent here
1063   $self->_dbh_details({}); # reset everything we know
1064   $self->_sql_maker(undef); # this may also end up being different
1065
1066   $self->_dbh($self->_connect);
1067
1068   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1069
1070   $self->_determine_driver;
1071
1072   # Always set the transaction depth on connect, since
1073   #  there is no transaction in progress by definition
1074   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1075
1076   $self->_run_connection_actions unless $self->{_in_determine_driver};
1077 }
1078
1079 sub _run_connection_actions {
1080   my $self = shift;
1081   my @actions;
1082
1083   push @actions, ( $self->on_connect_call || () );
1084   push @actions, $self->_parse_connect_do ('on_connect_do');
1085
1086   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1087 }
1088
1089
1090
1091 sub set_use_dbms_capability {
1092   $_[0]->set_inherited ($_[1], $_[2]);
1093 }
1094
1095 sub get_use_dbms_capability {
1096   my ($self, $capname) = @_;
1097
1098   my $use = $self->get_inherited ($capname);
1099   return defined $use
1100     ? $use
1101     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1102   ;
1103 }
1104
1105 sub set_dbms_capability {
1106   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1107 }
1108
1109 sub get_dbms_capability {
1110   my ($self, $capname) = @_;
1111
1112   my $cap = $self->_dbh_details->{capability}{$capname};
1113
1114   unless (defined $cap) {
1115     if (my $meth = $self->can ("_determine$capname")) {
1116       $cap = $self->$meth ? 1 : 0;
1117     }
1118     else {
1119       $cap = 0;
1120     }
1121
1122     $self->set_dbms_capability ($capname, $cap);
1123   }
1124
1125   return $cap;
1126 }
1127
1128 sub _server_info {
1129   my $self = shift;
1130
1131   my $info;
1132   unless ($info = $self->_dbh_details->{info}) {
1133
1134     $info = {};
1135
1136     my $server_version = try {
1137       $self->_get_server_version
1138     } catch {
1139       # driver determination *may* use this codepath
1140       # in which case we must rethrow
1141       $self->throw_exception($_) if $self->{_in_determine_driver};
1142
1143       # $server_version on failure
1144       undef;
1145     };
1146
1147     if (defined $server_version) {
1148       $info->{dbms_version} = $server_version;
1149
1150       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1151       my @verparts = split (/\./, $numeric_version);
1152       if (
1153         @verparts
1154           &&
1155         $verparts[0] <= 999
1156       ) {
1157         # consider only up to 3 version parts, iff not more than 3 digits
1158         my @use_parts;
1159         while (@verparts && @use_parts < 3) {
1160           my $p = shift @verparts;
1161           last if $p > 999;
1162           push @use_parts, $p;
1163         }
1164         push @use_parts, 0 while @use_parts < 3;
1165
1166         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1167       }
1168     }
1169
1170     $self->_dbh_details->{info} = $info;
1171   }
1172
1173   return $info;
1174 }
1175
1176 sub _get_server_version {
1177   shift->_dbh_get_info('SQL_DBMS_VER');
1178 }
1179
1180 sub _dbh_get_info {
1181   my ($self, $info) = @_;
1182
1183   if ($info =~ /[^0-9]/) {
1184     require DBI::Const::GetInfoType;
1185     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1186     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1187       unless defined $info;
1188   }
1189
1190   $self->_get_dbh->get_info($info);
1191 }
1192
1193 sub _describe_connection {
1194   require DBI::Const::GetInfoReturn;
1195
1196   my $self = shift;
1197
1198   my $drv;
1199   try {
1200     $drv = $self->_extract_driver_from_connect_info;
1201     $self->ensure_connected;
1202   };
1203
1204   $drv = "DBD::$drv" if $drv;
1205
1206   my $res = {
1207     DBIC_DSN => $self->_dbi_connect_info->[0],
1208     DBI_VER => DBI->VERSION,
1209     DBIC_VER => DBIx::Class->VERSION,
1210     DBIC_DRIVER => ref $self,
1211     $drv ? (
1212       DBD => $drv,
1213       DBD_VER => try { $drv->VERSION },
1214     ) : (),
1215   };
1216
1217   # try to grab data even if we never managed to connect
1218   # will cover us in cases of an oddly broken half-connect
1219   for my $inf (
1220     #keys %DBI::Const::GetInfoType::GetInfoType,
1221     qw/
1222       SQL_CURSOR_COMMIT_BEHAVIOR
1223       SQL_CURSOR_ROLLBACK_BEHAVIOR
1224       SQL_CURSOR_SENSITIVITY
1225       SQL_DATA_SOURCE_NAME
1226       SQL_DBMS_NAME
1227       SQL_DBMS_VER
1228       SQL_DEFAULT_TXN_ISOLATION
1229       SQL_DM_VER
1230       SQL_DRIVER_NAME
1231       SQL_DRIVER_ODBC_VER
1232       SQL_DRIVER_VER
1233       SQL_EXPRESSIONS_IN_ORDERBY
1234       SQL_GROUP_BY
1235       SQL_IDENTIFIER_CASE
1236       SQL_IDENTIFIER_QUOTE_CHAR
1237       SQL_MAX_CATALOG_NAME_LEN
1238       SQL_MAX_COLUMN_NAME_LEN
1239       SQL_MAX_IDENTIFIER_LEN
1240       SQL_MAX_TABLE_NAME_LEN
1241       SQL_MULTIPLE_ACTIVE_TXN
1242       SQL_MULT_RESULT_SETS
1243       SQL_NEED_LONG_DATA_LEN
1244       SQL_NON_NULLABLE_COLUMNS
1245       SQL_ODBC_VER
1246       SQL_QUALIFIER_NAME_SEPARATOR
1247       SQL_QUOTED_IDENTIFIER_CASE
1248       SQL_TXN_CAPABLE
1249       SQL_TXN_ISOLATION_OPTION
1250     /
1251   ) {
1252     # some drivers barf on things they do not know about instead
1253     # of returning undef
1254     my $v = try { $self->_dbh_get_info($inf) };
1255     next unless defined $v;
1256
1257     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1258     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1259     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1260   }
1261
1262   $res;
1263 }
1264
1265 sub _determine_driver {
1266   my ($self) = @_;
1267
1268   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1269     my $started_connected = 0;
1270     local $self->{_in_determine_driver} = 1;
1271
1272     if (ref($self) eq __PACKAGE__) {
1273       my $driver;
1274       if ($self->_dbh) { # we are connected
1275         $driver = $self->_dbh->{Driver}{Name};
1276         $started_connected = 1;
1277       }
1278       else {
1279         $driver = $self->_extract_driver_from_connect_info;
1280       }
1281
1282       if ($driver) {
1283         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1284         if ($self->load_optional_class($storage_class)) {
1285           mro::set_mro($storage_class, 'c3');
1286           bless $self, $storage_class;
1287           $self->_rebless();
1288         }
1289         else {
1290           $self->_warn_undetermined_driver(
1291             'This version of DBIC does not yet seem to supply a driver for '
1292           . "your particular RDBMS and/or connection method ('$driver')."
1293           );
1294         }
1295       }
1296       else {
1297         $self->_warn_undetermined_driver(
1298           'Unable to extract a driver name from connect info - this '
1299         . 'should not have happened.'
1300         );
1301       }
1302     }
1303
1304     $self->_driver_determined(1);
1305
1306     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1307
1308     if ($self->can('source_bind_attributes')) {
1309       $self->throw_exception(
1310         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1311       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1312       . 'If you are not sure how to proceed please contact the development team via '
1313       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1314       );
1315     }
1316
1317     $self->_init; # run driver-specific initializations
1318
1319     $self->_run_connection_actions
1320         if !$started_connected && defined $self->_dbh;
1321   }
1322 }
1323
1324 sub _extract_driver_from_connect_info {
1325   my $self = shift;
1326
1327   my $drv;
1328
1329   # if connect_info is a CODEREF, we have no choice but to connect
1330   if (
1331     ref $self->_dbi_connect_info->[0]
1332       and
1333     reftype $self->_dbi_connect_info->[0] eq 'CODE'
1334   ) {
1335     $self->_populate_dbh;
1336     $drv = $self->_dbh->{Driver}{Name};
1337   }
1338   else {
1339     # try to use dsn to not require being connected, the driver may still
1340     # force a connection later in _rebless to determine version
1341     # (dsn may not be supplied at all if all we do is make a mock-schema)
1342     ($drv) = ($self->_dbi_connect_info->[0] || '') =~ /^dbi:([^:]+):/i;
1343     $drv ||= $ENV{DBI_DRIVER};
1344   }
1345
1346   return $drv;
1347 }
1348
1349 sub _determine_connector_driver {
1350   my ($self, $conn) = @_;
1351
1352   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1353
1354   if (not $dbtype) {
1355     $self->_warn_undetermined_driver(
1356       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1357     . "$conn connector - this should not have happened."
1358     );
1359     return;
1360   }
1361
1362   $dbtype =~ s/\W/_/gi;
1363
1364   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1365   return if $self->isa($subclass);
1366
1367   if ($self->load_optional_class($subclass)) {
1368     bless $self, $subclass;
1369     $self->_rebless;
1370   }
1371   else {
1372     $self->_warn_undetermined_driver(
1373       'This version of DBIC does not yet seem to supply a driver for '
1374     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1375     );
1376   }
1377 }
1378
1379 sub _warn_undetermined_driver {
1380   my ($self, $msg) = @_;
1381
1382   require Data::Dumper::Concise;
1383
1384   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1385   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1386   . "does not go away, file a bugreport including the following info:\n"
1387   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1388   );
1389 }
1390
1391 sub _do_connection_actions {
1392   my $self          = shift;
1393   my $method_prefix = shift;
1394   my $call          = shift;
1395
1396   if (not ref($call)) {
1397     my $method = $method_prefix . $call;
1398     $self->$method(@_);
1399   } elsif (ref($call) eq 'CODE') {
1400     $self->$call(@_);
1401   } elsif (ref($call) eq 'ARRAY') {
1402     if (ref($call->[0]) ne 'ARRAY') {
1403       $self->_do_connection_actions($method_prefix, $_) for @$call;
1404     } else {
1405       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1406     }
1407   } else {
1408     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1409   }
1410
1411   return $self;
1412 }
1413
1414 sub connect_call_do_sql {
1415   my $self = shift;
1416   $self->_do_query(@_);
1417 }
1418
1419 sub disconnect_call_do_sql {
1420   my $self = shift;
1421   $self->_do_query(@_);
1422 }
1423
1424 # override in db-specific backend when necessary
1425 sub connect_call_datetime_setup { 1 }
1426
1427 sub _do_query {
1428   my ($self, $action) = @_;
1429
1430   if (ref $action eq 'CODE') {
1431     $action = $action->($self);
1432     $self->_do_query($_) foreach @$action;
1433   }
1434   else {
1435     # Most debuggers expect ($sql, @bind), so we need to exclude
1436     # the attribute hash which is the second argument to $dbh->do
1437     # furthermore the bind values are usually to be presented
1438     # as named arrayref pairs, so wrap those here too
1439     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1440     my $sql = shift @do_args;
1441     my $attrs = shift @do_args;
1442     my @bind = map { [ undef, $_ ] } @do_args;
1443
1444     $self->dbh_do(sub {
1445       $_[0]->_query_start($sql, \@bind);
1446       $_[1]->do($sql, $attrs, @do_args);
1447       $_[0]->_query_end($sql, \@bind);
1448     });
1449   }
1450
1451   return $self;
1452 }
1453
1454 sub _connect {
1455   my $self = shift;
1456
1457   my $info = $self->_dbi_connect_info;
1458
1459   $self->throw_exception("You did not provide any connection_info")
1460     unless defined $info->[0];
1461
1462   my ($old_connect_via, $dbh);
1463
1464   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1465
1466   # this odd anonymous coderef dereference is in fact really
1467   # necessary to avoid the unwanted effect described in perl5
1468   # RT#75792
1469   #
1470   # in addition the coderef itself can't reside inside the try{} block below
1471   # as it somehow triggers a leak under perl -d
1472   my $dbh_error_handler_installer = sub {
1473     weaken (my $weak_self = $_[0]);
1474
1475     # the coderef is blessed so we can distinguish it from externally
1476     # supplied handles (which must be preserved)
1477     $_[1]->{HandleError} = bless sub {
1478       if ($weak_self) {
1479         $weak_self->throw_exception("DBI Exception: $_[0]");
1480       }
1481       else {
1482         # the handler may be invoked by something totally out of
1483         # the scope of DBIC
1484         DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1485       }
1486     }, '__DBIC__DBH__ERROR__HANDLER__';
1487   };
1488
1489   try {
1490     if(ref $info->[0] eq 'CODE') {
1491       $dbh = $info->[0]->();
1492     }
1493     else {
1494       require DBI;
1495       $dbh = DBI->connect(@$info);
1496     }
1497
1498     die $DBI::errstr unless $dbh;
1499
1500     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1501       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1502       . 'not continue',
1503       ref $info->[0] eq 'CODE'
1504         ? "Connection coderef $info->[0] returned a"
1505         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1506     ) unless $dbh->FETCH('Active');
1507
1508     # sanity checks unless asked otherwise
1509     unless ($self->unsafe) {
1510
1511       $self->throw_exception(
1512         'Refusing clobbering of {HandleError} installed on externally supplied '
1513        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1514       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1515
1516       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1517       # request, or an external handle. Complain and set anyway
1518       unless ($dbh->{RaiseError}) {
1519         carp( ref $info->[0] eq 'CODE'
1520
1521           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1522            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1523            .'attribute has been supplied'
1524
1525           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1526            .'unsafe => 1. Toggling RaiseError back to true'
1527         );
1528
1529         $dbh->{RaiseError} = 1;
1530       }
1531
1532       $dbh_error_handler_installer->($self, $dbh);
1533     }
1534   }
1535   catch {
1536     $self->throw_exception("DBI Connection failed: $_")
1537   };
1538
1539   $self->_dbh_autocommit($dbh->{AutoCommit});
1540   return $dbh;
1541 }
1542
1543 sub txn_begin {
1544   my $self = shift;
1545
1546   # this means we have not yet connected and do not know the AC status
1547   # (e.g. coderef $dbh), need a full-fledged connection check
1548   if (! defined $self->_dbh_autocommit) {
1549     $self->ensure_connected;
1550   }
1551   # Otherwise simply connect or re-connect on pid changes
1552   else {
1553     $self->_get_dbh;
1554   }
1555
1556   $self->next::method(@_);
1557 }
1558
1559 sub _exec_txn_begin {
1560   my $self = shift;
1561
1562   # if the user is utilizing txn_do - good for him, otherwise we need to
1563   # ensure that the $dbh is healthy on BEGIN.
1564   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1565   # will be replaced by a failure of begin_work itself (which will be
1566   # then retried on reconnect)
1567   if ($self->{_in_do_block}) {
1568     $self->_dbh->begin_work;
1569   } else {
1570     $self->dbh_do(sub { $_[1]->begin_work });
1571   }
1572 }
1573
1574 sub txn_commit {
1575   my $self = shift;
1576
1577   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1578   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1579     unless $self->_dbh;
1580
1581   # esoteric case for folks using external $dbh handles
1582   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1583     carp "Storage transaction_depth 0 does not match "
1584         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1585     $self->transaction_depth(1);
1586   }
1587
1588   $self->next::method(@_);
1589
1590   # if AutoCommit is disabled txn_depth never goes to 0
1591   # as a new txn is started immediately on commit
1592   $self->transaction_depth(1) if (
1593     !$self->transaction_depth
1594       and
1595     defined $self->_dbh_autocommit
1596       and
1597     ! $self->_dbh_autocommit
1598   );
1599 }
1600
1601 sub _exec_txn_commit {
1602   shift->_dbh->commit;
1603 }
1604
1605 sub txn_rollback {
1606   my $self = shift;
1607
1608   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1609   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1610     unless $self->_dbh;
1611
1612   # esoteric case for folks using external $dbh handles
1613   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1614     carp "Storage transaction_depth 0 does not match "
1615         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1616     $self->transaction_depth(1);
1617   }
1618
1619   $self->next::method(@_);
1620
1621   # if AutoCommit is disabled txn_depth never goes to 0
1622   # as a new txn is started immediately on commit
1623   $self->transaction_depth(1) if (
1624     !$self->transaction_depth
1625       and
1626     defined $self->_dbh_autocommit
1627       and
1628     ! $self->_dbh_autocommit
1629   );
1630 }
1631
1632 sub _exec_txn_rollback {
1633   shift->_dbh->rollback;
1634 }
1635
1636 # generate some identical methods
1637 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1638   no strict qw/refs/;
1639   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1640     my $self = shift;
1641     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1642     $self->throw_exception("Unable to $meth() on a disconnected storage")
1643       unless $self->_dbh;
1644     $self->next::method(@_);
1645   };
1646 }
1647
1648 # This used to be the top-half of _execute.  It was split out to make it
1649 #  easier to override in NoBindVars without duping the rest.  It takes up
1650 #  all of _execute's args, and emits $sql, @bind.
1651 sub _prep_for_execute {
1652   #my ($self, $op, $ident, $args) = @_;
1653   return shift->_gen_sql_bind(@_)
1654 }
1655
1656 sub _gen_sql_bind {
1657   my ($self, $op, $ident, $args) = @_;
1658
1659   my ($colinfos, $from);
1660   if ( blessed($ident) ) {
1661     $from = $ident->from;
1662     $colinfos = $ident->columns_info;
1663   }
1664
1665   my ($sql, $bind);
1666   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1667
1668   $bind = $self->_resolve_bindattrs(
1669     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1670   );
1671
1672   if (
1673     ! $ENV{DBIC_DT_SEARCH_OK}
1674       and
1675     $op eq 'select'
1676       and
1677     first {
1678       length ref $_->[1]
1679         and
1680       blessed($_->[1])
1681         and
1682       $_->[1]->isa('DateTime')
1683     } @$bind
1684   ) {
1685     carp_unique 'DateTime objects passed to search() are not supported '
1686       . 'properly (InflateColumn::DateTime formats and settings are not '
1687       . 'respected.) See "Formatting DateTime objects in queries" in '
1688       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1689       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1690   }
1691
1692   return( $sql, $bind );
1693 }
1694
1695 sub _resolve_bindattrs {
1696   my ($self, $ident, $bind, $colinfos) = @_;
1697
1698   my $resolve_bindinfo = sub {
1699     #my $infohash = shift;
1700
1701     $colinfos ||= { %{ $self->_resolve_column_info($ident) } };
1702
1703     my $ret;
1704     if (my $col = $_[0]->{dbic_colname}) {
1705       $ret = { %{$_[0]} };
1706
1707       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1708         if $colinfos->{$col}{data_type};
1709
1710       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1711         if $colinfos->{$col}{size};
1712     }
1713
1714     $ret || $_[0];
1715   };
1716
1717   return [ map {
1718     my $resolved =
1719       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1720     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1721     : (ref $_->[0] eq 'HASH')           ? [(
1722                                             ! keys %{$_->[0]}
1723                                               or
1724                                             exists $_->[0]{dbd_attrs}
1725                                               or
1726                                             $_->[0]{sqlt_datatype}
1727                                            ) ? $_->[0]
1728                                              : $resolve_bindinfo->($_->[0])
1729                                            , $_->[1]
1730                                           ]
1731     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1732     :                                     [ $resolve_bindinfo->(
1733                                               { dbic_colname => $_->[0] }
1734                                             ), $_->[1] ]
1735     ;
1736
1737     if (
1738       ! exists $resolved->[0]{dbd_attrs}
1739         and
1740       ! $resolved->[0]{sqlt_datatype}
1741         and
1742       length ref $resolved->[1]
1743         and
1744       ! overload::Method($resolved->[1], '""')
1745     ) {
1746       require Data::Dumper;
1747       local $Data::Dumper::Maxdepth = 1;
1748       local $Data::Dumper::Terse = 1;
1749       local $Data::Dumper::Useqq = 1;
1750       local $Data::Dumper::Indent = 0;
1751       local $Data::Dumper::Pad = ' ';
1752       $self->throw_exception(
1753         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1754       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1755       );
1756     }
1757
1758     $resolved;
1759
1760   } @$bind ];
1761 }
1762
1763 sub _format_for_trace {
1764   #my ($self, $bind) = @_;
1765
1766   ### Turn @bind from something like this:
1767   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1768   ### to this:
1769   ###   ( "'1'", "'3'" )
1770
1771   map {
1772     defined( $_ && $_->[1] )
1773       ? qq{'$_->[1]'}
1774       : q{NULL}
1775   } @{$_[1] || []};
1776 }
1777
1778 sub _query_start {
1779   my ( $self, $sql, $bind ) = @_;
1780
1781   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1782     if $self->debug;
1783 }
1784
1785 sub _query_end {
1786   my ( $self, $sql, $bind ) = @_;
1787
1788   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1789     if $self->debug;
1790 }
1791
1792 sub _dbi_attrs_for_bind {
1793   my ($self, $ident, $bind) = @_;
1794
1795   my @attrs;
1796
1797   for (map { $_->[0] } @$bind) {
1798     push @attrs, do {
1799       if (exists $_->{dbd_attrs}) {
1800         $_->{dbd_attrs}
1801       }
1802       elsif($_->{sqlt_datatype}) {
1803         # cache the result in the dbh_details hash, as it can not change unless
1804         # we connect to something else
1805         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1806         if (not exists $cache->{$_->{sqlt_datatype}}) {
1807           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1808         }
1809         $cache->{$_->{sqlt_datatype}};
1810       }
1811       else {
1812         undef;  # always push something at this position
1813       }
1814     }
1815   }
1816
1817   return \@attrs;
1818 }
1819
1820 sub _execute {
1821   my ($self, $op, $ident, @args) = @_;
1822
1823   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1824
1825   # not even a PID check - we do not care about the state of the _dbh.
1826   # All we need is to get the appropriate drivers loaded if they aren't
1827   # already so that the assumption in ad7c50fc26e holds
1828   $self->_populate_dbh unless $self->_dbh;
1829
1830   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1831     $sql,
1832     $bind,
1833     $self->_dbi_attrs_for_bind($ident, $bind),
1834   );
1835 }
1836
1837 sub _dbh_execute {
1838   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1839
1840   $self->_query_start( $sql, $bind );
1841
1842   my $sth = $self->_bind_sth_params(
1843     $self->_prepare_sth($dbh, $sql),
1844     $bind,
1845     $bind_attrs,
1846   );
1847
1848   # Can this fail without throwing an exception anyways???
1849   my $rv = $sth->execute();
1850   $self->throw_exception(
1851     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1852   ) if !$rv;
1853
1854   $self->_query_end( $sql, $bind );
1855
1856   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1857 }
1858
1859 sub _prepare_sth {
1860   my ($self, $dbh, $sql) = @_;
1861
1862   # 3 is the if_active parameter which avoids active sth re-use
1863   my $sth = $self->disable_sth_caching
1864     ? $dbh->prepare($sql)
1865     : $dbh->prepare_cached($sql, {}, 3);
1866
1867   # XXX You would think RaiseError would make this impossible,
1868   #  but apparently that's not true :(
1869   $self->throw_exception(
1870     $dbh->errstr
1871       ||
1872     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1873             .'an exception and/or setting $dbh->errstr',
1874       length ($sql) > 20
1875         ? substr($sql, 0, 20) . '...'
1876         : $sql
1877       ,
1878       'DBD::' . $dbh->{Driver}{Name},
1879     )
1880   ) if !$sth;
1881
1882   $sth;
1883 }
1884
1885 sub _bind_sth_params {
1886   my ($self, $sth, $bind, $bind_attrs) = @_;
1887
1888   for my $i (0 .. $#$bind) {
1889     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1890       $sth->bind_param_inout(
1891         $i + 1, # bind params counts are 1-based
1892         $bind->[$i][1],
1893         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1894         $bind_attrs->[$i],
1895       );
1896     }
1897     else {
1898       # FIXME SUBOPTIMAL - most likely this is not necessary at all
1899       # confirm with dbi-dev whether explicit stringification is needed
1900       my $v = ( length ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""') )
1901         ? "$bind->[$i][1]"
1902         : $bind->[$i][1]
1903       ;
1904       $sth->bind_param(
1905         $i + 1,
1906         $v,
1907         $bind_attrs->[$i],
1908       );
1909     }
1910   }
1911
1912   $sth;
1913 }
1914
1915 sub _prefetch_autovalues {
1916   my ($self, $source, $colinfo, $to_insert) = @_;
1917
1918   my %values;
1919   for my $col (keys %$colinfo) {
1920     if (
1921       $colinfo->{$col}{auto_nextval}
1922         and
1923       (
1924         ! exists $to_insert->{$col}
1925           or
1926         ref $to_insert->{$col} eq 'SCALAR'
1927           or
1928         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1929       )
1930     ) {
1931       $values{$col} = $self->_sequence_fetch(
1932         'NEXTVAL',
1933         ( $colinfo->{$col}{sequence} ||=
1934             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1935         ),
1936       );
1937     }
1938   }
1939
1940   \%values;
1941 }
1942
1943 sub insert {
1944   my ($self, $source, $to_insert) = @_;
1945
1946   my $col_infos = $source->columns_info;
1947
1948   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1949
1950   # fuse the values, but keep a separate list of prefetched_values so that
1951   # they can be fused once again with the final return
1952   $to_insert = { %$to_insert, %$prefetched_values };
1953
1954   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1955   # Investigate what does it take to s/defined/exists/
1956   my %pcols = map { $_ => 1 } $source->primary_columns;
1957   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1958   for my $col ($source->columns) {
1959     if ($col_infos->{$col}{is_auto_increment}) {
1960       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1961       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1962     }
1963
1964     # nothing to retrieve when explicit values are supplied
1965     next if (defined $to_insert->{$col} and ! (
1966       ref $to_insert->{$col} eq 'SCALAR'
1967         or
1968       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1969     ));
1970
1971     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1972     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1973       $pcols{$col}
1974         or
1975       $col_infos->{$col}{retrieve_on_insert}
1976     );
1977   };
1978
1979   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1980   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1981
1982   my ($sqla_opts, @ir_container);
1983   if (%retrieve_cols and $self->_use_insert_returning) {
1984     $sqla_opts->{returning_container} = \@ir_container
1985       if $self->_use_insert_returning_bound;
1986
1987     $sqla_opts->{returning} = [
1988       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1989     ];
1990   }
1991
1992   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1993
1994   my %returned_cols = %$to_insert;
1995   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1996     @ir_container = try {
1997       local $SIG{__WARN__} = sub {};
1998       my @r = $sth->fetchrow_array;
1999       $sth->finish;
2000       @r;
2001     } unless @ir_container;
2002
2003     @returned_cols{@$retlist} = @ir_container if @ir_container;
2004   }
2005   else {
2006     # pull in PK if needed and then everything else
2007     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
2008
2009       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
2010         unless $self->can('last_insert_id');
2011
2012       my @pri_values = $self->last_insert_id($source, @missing_pri);
2013
2014       $self->throw_exception( "Can't get last insert id" )
2015         unless (@pri_values == @missing_pri);
2016
2017       @returned_cols{@missing_pri} = @pri_values;
2018       delete @retrieve_cols{@missing_pri};
2019     }
2020
2021     # if there is more left to pull
2022     if (%retrieve_cols) {
2023       $self->throw_exception(
2024         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
2025       ) unless %pcols;
2026
2027       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
2028
2029       my $cur = DBIx::Class::ResultSet->new($source, {
2030         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
2031         select => \@left_to_fetch,
2032       })->cursor;
2033
2034       @returned_cols{@left_to_fetch} = $cur->next;
2035
2036       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
2037         if scalar $cur->next;
2038     }
2039   }
2040
2041   return { %$prefetched_values, %returned_cols };
2042 }
2043
2044 sub insert_bulk {
2045   my ($self, $source, $cols, $data) = @_;
2046
2047   my @col_range = (0..$#$cols);
2048
2049   # FIXME SUBOPTIMAL - most likely this is not necessary at all
2050   # confirm with dbi-dev whether explicit stringification is needed
2051   #
2052   # forcibly stringify whatever is stringifiable
2053   # ResultSet::populate() hands us a copy - safe to mangle
2054   for my $r (0 .. $#$data) {
2055     for my $c (0 .. $#{$data->[$r]}) {
2056       $data->[$r][$c] = "$data->[$r][$c]"
2057         if ( length ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
2058     }
2059   }
2060
2061   my $colinfos = $source->columns_info($cols);
2062
2063   local $self->{_autoinc_supplied_for_op} =
2064     (first { $_->{is_auto_increment} } values %$colinfos)
2065       ? 1
2066       : 0
2067   ;
2068
2069   # get a slice type index based on first row of data
2070   # a "column" in this context may refer to more than one bind value
2071   # e.g. \[ '?, ?', [...], [...] ]
2072   #
2073   # construct the value type index - a description of values types for every
2074   # per-column slice of $data:
2075   #
2076   # nonexistent - nonbind literal
2077   # 0 - regular value
2078   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
2079   #
2080   # also construct the column hash to pass to the SQL generator. For plain
2081   # (non literal) values - convert the members of the first row into a
2082   # literal+bind combo, with extra positional info in the bind attr hashref.
2083   # This will allow us to match the order properly, and is so contrived
2084   # because a user-supplied literal/bind (or something else specific to a
2085   # resultsource and/or storage driver) can inject extra binds along the
2086   # way, so one can't rely on "shift positions" ordering at all. Also we
2087   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
2088   # can be later matched up by address), because we want to supply a real
2089   # value on which perhaps e.g. datatype checks will be performed
2090   my ($proto_data, $value_type_by_col_idx);
2091   for my $i (@col_range) {
2092     my $colname = $cols->[$i];
2093     if (ref $data->[0][$i] eq 'SCALAR') {
2094       # no bind value at all - no type
2095
2096       $proto_data->{$colname} = $data->[0][$i];
2097     }
2098     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
2099       # repack, so we don't end up mangling the original \[]
2100       my ($sql, @bind) = @${$data->[0][$i]};
2101
2102       # normalization of user supplied stuff
2103       my $resolved_bind = $self->_resolve_bindattrs(
2104         $source, \@bind, $colinfos,
2105       );
2106
2107       # store value-less (attrs only) bind info - we will be comparing all
2108       # supplied binds against this for sanity
2109       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
2110
2111       $proto_data->{$colname} = \[ $sql, map { [
2112         # inject slice order to use for $proto_bind construction
2113           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
2114             =>
2115           $resolved_bind->[$_][1]
2116         ] } (0 .. $#bind)
2117       ];
2118     }
2119     else {
2120       $value_type_by_col_idx->{$i} = undef;
2121
2122       $proto_data->{$colname} = \[ '?', [
2123         { dbic_colname => $colname, _bind_data_slice_idx => $i }
2124           =>
2125         $data->[0][$i]
2126       ] ];
2127     }
2128   }
2129
2130   my ($sql, $proto_bind) = $self->_prep_for_execute (
2131     'insert',
2132     $source,
2133     [ $proto_data ],
2134   );
2135
2136   if (! @$proto_bind and keys %$value_type_by_col_idx) {
2137     # if the bindlist is empty and we had some dynamic binds, this means the
2138     # storage ate them away (e.g. the NoBindVars component) and interpolated
2139     # them directly into the SQL. This obviously can't be good for multi-inserts
2140     $self->throw_exception('Cannot insert_bulk without support for placeholders');
2141   }
2142
2143   # sanity checks
2144   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2145   #
2146   # use an error reporting closure for convenience (less to pass)
2147   my $bad_slice_report_cref = sub {
2148     my ($msg, $r_idx, $c_idx) = @_;
2149     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2150       $msg,
2151       $cols->[$c_idx],
2152       do {
2153         require Data::Dumper::Concise;
2154         local $Data::Dumper::Maxdepth = 5;
2155         Data::Dumper::Concise::Dumper ({
2156           map { $cols->[$_] =>
2157             $data->[$r_idx][$_]
2158           } @col_range
2159         }),
2160       }
2161     );
2162   };
2163
2164   for my $col_idx (@col_range) {
2165     my $reference_val = $data->[0][$col_idx];
2166
2167     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2168       my $val = $data->[$row_idx][$col_idx];
2169
2170       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2171         if (ref $val ne 'SCALAR') {
2172           $bad_slice_report_cref->(
2173             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2174             $row_idx,
2175             $col_idx,
2176           );
2177         }
2178         elsif ($$val ne $$reference_val) {
2179           $bad_slice_report_cref->(
2180             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2181             $row_idx,
2182             $col_idx,
2183           );
2184         }
2185       }
2186       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2187         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2188           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2189         }
2190       }
2191       else {  # binds from a \[], compare type and attrs
2192         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2193           $bad_slice_report_cref->(
2194             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2195             $row_idx,
2196             $col_idx,
2197           );
2198         }
2199         # start drilling down and bail out early on identical refs
2200         elsif (
2201           $reference_val != $val
2202             or
2203           $$reference_val != $$val
2204         ) {
2205           if (${$val}->[0] ne ${$reference_val}->[0]) {
2206             $bad_slice_report_cref->(
2207               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2208               $row_idx,
2209               $col_idx,
2210             );
2211           }
2212           # need to check the bind attrs - a bind will happen only once for
2213           # the entire dataset, so any changes further down will be ignored.
2214           elsif (! Data::Compare::Compare(
2215             $value_type_by_col_idx->{$col_idx},
2216             [
2217               map
2218               { $_->[0] }
2219               @{$self->_resolve_bindattrs(
2220                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2221               )}
2222             ],
2223           )) {
2224             $bad_slice_report_cref->(
2225               'Differing bind attributes on literal/bind values not supported',
2226               $row_idx,
2227               $col_idx,
2228             );
2229           }
2230         }
2231       }
2232     }
2233   }
2234
2235   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2236   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2237   # scope guard
2238   my $guard = $self->txn_scope_guard;
2239
2240   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2241   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2242   my $rv = do {
2243     if (@$proto_bind) {
2244       # proto bind contains the information on which pieces of $data to pull
2245       # $cols is passed in only for prettier error-reporting
2246       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2247     }
2248     else {
2249       # bind_param_array doesn't work if there are no binds
2250       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2251     }
2252   };
2253
2254   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2255
2256   $guard->commit;
2257
2258   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2259 }
2260
2261 # execute_for_fetch is capable of returning data just fine (it means it
2262 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2263 # is the void-populate fast-path we will just ignore this altogether
2264 # for the time being.
2265 sub _dbh_execute_for_fetch {
2266   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2267
2268   my @idx_range = ( 0 .. $#$proto_bind );
2269
2270   # If we have any bind attributes to take care of, we will bind the
2271   # proto-bind data (which will never be used by execute_for_fetch)
2272   # However since column bindtypes are "sticky", this is sufficient
2273   # to get the DBD to apply the bindtype to all values later on
2274
2275   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2276
2277   for my $i (@idx_range) {
2278     $sth->bind_param (
2279       $i+1, # DBI bind indexes are 1-based
2280       $proto_bind->[$i][1],
2281       $bind_attrs->[$i],
2282     ) if defined $bind_attrs->[$i];
2283   }
2284
2285   # At this point $data slots named in the _bind_data_slice_idx of
2286   # each piece of $proto_bind are either \[]s or plain values to be
2287   # passed in. Construct the dispensing coderef. *NOTE* the order
2288   # of $data will differ from this of the ?s in the SQL (due to
2289   # alphabetical ordering by colname). We actually do want to
2290   # preserve this behavior so that prepare_cached has a better
2291   # chance of matching on unrelated calls
2292
2293   my $fetch_row_idx = -1; # saner loop this way
2294   my $fetch_tuple = sub {
2295     return undef if ++$fetch_row_idx > $#$data;
2296
2297     return [ map {
2298       ! defined $_->{_literal_bind_subindex}
2299
2300         ? $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2301
2302         # There are no attributes to resolve here - we already did everything
2303         # when we constructed proto_bind. However we still want to sanity-check
2304         # what the user supplied, so pass stuff through to the resolver *anyway*
2305         : $self->_resolve_bindattrs (
2306             undef,  # a fake rsrc
2307             [ ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}->[ $_->{_literal_bind_subindex} ] ],
2308             {},     # a fake column_info bag
2309           )->[0][1]
2310
2311     } map { $_->[0] } @$proto_bind ];
2312   };
2313
2314   my $tuple_status = [];
2315   my ($rv, $err);
2316   try {
2317     $rv = $sth->execute_for_fetch(
2318       $fetch_tuple,
2319       $tuple_status,
2320     );
2321   }
2322   catch {
2323     $err = shift;
2324   };
2325
2326   # Not all DBDs are create equal. Some throw on error, some return
2327   # an undef $rv, and some set $sth->err - try whatever we can
2328   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2329     ! defined $err
2330       and
2331     ( !defined $rv or $sth->err )
2332   );
2333
2334   # Statement must finish even if there was an exception.
2335   try {
2336     $sth->finish
2337   }
2338   catch {
2339     $err = shift unless defined $err
2340   };
2341
2342   if (defined $err) {
2343     my $i = 0;
2344     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2345
2346     $self->throw_exception("Unexpected populate error: $err")
2347       if ($i > $#$tuple_status);
2348
2349     require Data::Dumper::Concise;
2350     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2351       ($tuple_status->[$i][1] || $err),
2352       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2353     );
2354   }
2355
2356   return $rv;
2357 }
2358
2359 sub _dbh_execute_inserts_with_no_binds {
2360   my ($self, $sth, $count) = @_;
2361
2362   my $err;
2363   try {
2364     my $dbh = $self->_get_dbh;
2365     local $dbh->{RaiseError} = 1;
2366     local $dbh->{PrintError} = 0;
2367
2368     $sth->execute foreach 1..$count;
2369   }
2370   catch {
2371     $err = shift;
2372   };
2373
2374   # Make sure statement is finished even if there was an exception.
2375   try {
2376     $sth->finish
2377   }
2378   catch {
2379     $err = shift unless defined $err;
2380   };
2381
2382   $self->throw_exception($err) if defined $err;
2383
2384   return $count;
2385 }
2386
2387 sub update {
2388   #my ($self, $source, @args) = @_;
2389   shift->_execute('update', @_);
2390 }
2391
2392
2393 sub delete {
2394   #my ($self, $source, @args) = @_;
2395   shift->_execute('delete', @_);
2396 }
2397
2398 sub _select {
2399   my $self = shift;
2400   $self->_execute($self->_select_args(@_));
2401 }
2402
2403 sub _select_args_to_query {
2404   my $self = shift;
2405
2406   $self->throw_exception(
2407     "Unable to generate limited query representation with 'software_limit' enabled"
2408   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2409
2410   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2411   #  = $self->_select_args($ident, $select, $cond, $attrs);
2412   my ($op, $ident, @args) =
2413     $self->_select_args(@_);
2414
2415   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2416   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2417
2418   # reuse the bind arrayref
2419   unshift @{$bind}, "($sql)";
2420   \$bind;
2421 }
2422
2423 sub _select_args {
2424   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2425
2426   # FIXME - that kind of caching would be nice to have
2427   # however currently we *may* pass the same $orig_attrs
2428   # with different ident/select/where
2429   # the whole interface needs to be rethought, since it
2430   # was centered around the flawed SQLA API. We can do
2431   # soooooo much better now. But that is also another
2432   # battle...
2433   #return (
2434   #  'select', $orig_attrs->{!args_as_stored_at_the_end_of_this_method!}
2435   #) if $orig_attrs->{!args_as_stored_at_the_end_of_this_method!};
2436
2437   my $sql_maker = $self->sql_maker;
2438   my $alias2source = $self->_resolve_ident_sources ($ident);
2439
2440   my $attrs = {
2441     %$orig_attrs,
2442     select => $select,
2443     from => $ident,
2444     where => $where,
2445
2446     # limit dialects use this stuff
2447     # yes, some CDBICompat crap does not supply an {alias} >.<
2448     ( $orig_attrs->{alias} and $alias2source->{$orig_attrs->{alias}} )
2449       ? ( _rsroot_rsrc => $alias2source->{$orig_attrs->{alias}} )
2450       : ()
2451     ,
2452   };
2453
2454   # Sanity check the attributes (SQLMaker does it too, but
2455   # in case of a software_limit we'll never reach there)
2456   if (defined $attrs->{offset}) {
2457     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2458       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2459   }
2460
2461   if (defined $attrs->{rows}) {
2462     $self->throw_exception("The rows attribute must be a positive integer if present")
2463       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2464   }
2465   elsif ($attrs->{offset}) {
2466     # MySQL actually recommends this approach.  I cringe.
2467     $attrs->{rows} = $sql_maker->__max_int;
2468   }
2469
2470   # see if we will need to tear the prefetch apart to satisfy group_by == select
2471   # this is *extremely tricky* to get right, I am still not sure I did
2472   #
2473   my ($prefetch_needs_subquery, @limit_args);
2474
2475   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2476     # we already know there is a valid group_by (we made it) and we know it is
2477     # intended to be based *only* on non-multi stuff
2478     # short circuit the group_by parsing below
2479     $prefetch_needs_subquery = 1;
2480   }
2481   elsif (
2482     # The rationale is that even if we do *not* have collapse, we still
2483     # need to wrap the core grouped select/group_by in a subquery
2484     # so that databases that care about group_by/select equivalence
2485     # are happy (this includes MySQL in strict_mode)
2486     # If any of the other joined tables are referenced in the group_by
2487     # however - the user is on their own
2488     ( $prefetch_needs_subquery or $attrs->{_related_results_construction} )
2489       and
2490     $attrs->{group_by}
2491       and
2492     @{$attrs->{group_by}}
2493       and
2494     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2495       $self->_resolve_aliastypes_from_select_args({ from => $attrs->{from}, group_by => $attrs->{group_by} })
2496     }
2497   ) {
2498     # no aliases other than our own in group_by
2499     # if there are - do not allow subquery even if limit is present
2500     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2501   }
2502   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2503     # active collapse with a limit - that one is a no-brainer unless
2504     # overruled by a group_by above
2505     $prefetch_needs_subquery = 1;
2506   }
2507
2508   if ($prefetch_needs_subquery) {
2509     $attrs = $self->_adjust_select_args_for_complex_prefetch ($attrs);
2510   }
2511   elsif (! $attrs->{software_limit} ) {
2512     push @limit_args, (
2513       $attrs->{rows} || (),
2514       $attrs->{offset} || (),
2515     );
2516   }
2517
2518   # try to simplify the joinmap further (prune unreferenced type-single joins)
2519   if (
2520     ! $prefetch_needs_subquery  # already pruned
2521       and
2522     ref $attrs->{from}
2523       and
2524     reftype $attrs->{from} eq 'ARRAY'
2525       and
2526     @{$attrs->{from}} != 1
2527   ) {
2528     ($attrs->{from}, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($attrs);
2529   }
2530
2531   # FIXME this is a gross, inefficient, largely incorrect and fragile hack
2532   # during the result inflation stage we *need* to know what was the aliastype
2533   # map as sqla saw it when the final pieces of SQL were being assembled
2534   # Originally we simply carried around the entirety of $attrs, but this
2535   # resulted in resultsets that are being reused growing continuously, as
2536   # the hash in question grew deeper and deeper.
2537   # Instead hand-pick what to take with us here (we actually don't need much
2538   # at this point just the map itself)
2539   $orig_attrs->{_last_sqlmaker_alias_map} = $attrs->{_aliastypes};
2540
2541 ###
2542   # This would be the point to deflate anything found in $attrs->{where}
2543   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2544   # expect a result object. And all we have is a resultsource (it is trivial
2545   # to extract deflator coderefs via $alias2source above).
2546   #
2547   # I don't see a way forward other than changing the way deflators are
2548   # invoked, and that's just bad...
2549 ###
2550
2551   return ( 'select', @{$attrs}{qw(from select where)}, $attrs, @limit_args );
2552 }
2553
2554 # Returns a counting SELECT for a simple count
2555 # query. Abstracted so that a storage could override
2556 # this to { count => 'firstcol' } or whatever makes
2557 # sense as a performance optimization
2558 sub _count_select {
2559   #my ($self, $source, $rs_attrs) = @_;
2560   return { count => '*' };
2561 }
2562
2563 =head2 select
2564
2565 =over 4
2566
2567 =item Arguments: $ident, $select, $condition, $attrs
2568
2569 =back
2570
2571 Handle a SQL select statement.
2572
2573 =cut
2574
2575 sub select {
2576   my $self = shift;
2577   my ($ident, $select, $condition, $attrs) = @_;
2578   return $self->cursor_class->new($self, \@_, $attrs);
2579 }
2580
2581 sub select_single {
2582   my $self = shift;
2583   my ($rv, $sth, @bind) = $self->_select(@_);
2584   my @row = $sth->fetchrow_array;
2585   my @nextrow = $sth->fetchrow_array if @row;
2586   if(@row && @nextrow) {
2587     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2588   }
2589   # Need to call finish() to work round broken DBDs
2590   $sth->finish();
2591   return @row;
2592 }
2593
2594 =head2 sql_limit_dialect
2595
2596 This is an accessor for the default SQL limit dialect used by a particular
2597 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2598 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2599 see L<DBIx::Class::SQLMaker::LimitDialects>.
2600
2601 =cut
2602
2603 sub _dbh_columns_info_for {
2604   my ($self, $dbh, $table) = @_;
2605
2606   if ($dbh->can('column_info')) {
2607     my %result;
2608     my $caught;
2609     try {
2610       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2611       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2612       $sth->execute();
2613       while ( my $info = $sth->fetchrow_hashref() ){
2614         my %column_info;
2615         $column_info{data_type}   = $info->{TYPE_NAME};
2616         $column_info{size}      = $info->{COLUMN_SIZE};
2617         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2618         $column_info{default_value} = $info->{COLUMN_DEF};
2619         my $col_name = $info->{COLUMN_NAME};
2620         $col_name =~ s/^\"(.*)\"$/$1/;
2621
2622         $result{$col_name} = \%column_info;
2623       }
2624     } catch {
2625       $caught = 1;
2626     };
2627     return \%result if !$caught && scalar keys %result;
2628   }
2629
2630   my %result;
2631   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2632   $sth->execute;
2633   my @columns = @{$sth->{NAME_lc}};
2634   for my $i ( 0 .. $#columns ){
2635     my %column_info;
2636     $column_info{data_type} = $sth->{TYPE}->[$i];
2637     $column_info{size} = $sth->{PRECISION}->[$i];
2638     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2639
2640     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2641       $column_info{data_type} = $1;
2642       $column_info{size}    = $2;
2643     }
2644
2645     $result{$columns[$i]} = \%column_info;
2646   }
2647   $sth->finish;
2648
2649   foreach my $col (keys %result) {
2650     my $colinfo = $result{$col};
2651     my $type_num = $colinfo->{data_type};
2652     my $type_name;
2653     if(defined $type_num && $dbh->can('type_info')) {
2654       my $type_info = $dbh->type_info($type_num);
2655       $type_name = $type_info->{TYPE_NAME} if $type_info;
2656       $colinfo->{data_type} = $type_name if $type_name;
2657     }
2658   }
2659
2660   return \%result;
2661 }
2662
2663 sub columns_info_for {
2664   my ($self, $table) = @_;
2665   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2666 }
2667
2668 =head2 last_insert_id
2669
2670 Return the row id of the last insert.
2671
2672 =cut
2673
2674 sub _dbh_last_insert_id {
2675     my ($self, $dbh, $source, $col) = @_;
2676
2677     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2678
2679     return $id if defined $id;
2680
2681     my $class = ref $self;
2682     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2683 }
2684
2685 sub last_insert_id {
2686   my $self = shift;
2687   $self->_dbh_last_insert_id ($self->_dbh, @_);
2688 }
2689
2690 =head2 _native_data_type
2691
2692 =over 4
2693
2694 =item Arguments: $type_name
2695
2696 =back
2697
2698 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2699 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2700 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2701
2702 The default implementation returns C<undef>, implement in your Storage driver if
2703 you need this functionality.
2704
2705 Should map types from other databases to the native RDBMS type, for example
2706 C<VARCHAR2> to C<VARCHAR>.
2707
2708 Types with modifiers should map to the underlying data type. For example,
2709 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2710
2711 Composite types should map to the container type, for example
2712 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2713
2714 =cut
2715
2716 sub _native_data_type {
2717   #my ($self, $data_type) = @_;
2718   return undef
2719 }
2720
2721 # Check if placeholders are supported at all
2722 sub _determine_supports_placeholders {
2723   my $self = shift;
2724   my $dbh  = $self->_get_dbh;
2725
2726   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2727   # but it is inaccurate more often than not
2728   return try {
2729     local $dbh->{PrintError} = 0;
2730     local $dbh->{RaiseError} = 1;
2731     $dbh->do('select ?', {}, 1);
2732     1;
2733   }
2734   catch {
2735     0;
2736   };
2737 }
2738
2739 # Check if placeholders bound to non-string types throw exceptions
2740 #
2741 sub _determine_supports_typeless_placeholders {
2742   my $self = shift;
2743   my $dbh  = $self->_get_dbh;
2744
2745   return try {
2746     local $dbh->{PrintError} = 0;
2747     local $dbh->{RaiseError} = 1;
2748     # this specifically tests a bind that is NOT a string
2749     $dbh->do('select 1 where 1 = ?', {}, 1);
2750     1;
2751   }
2752   catch {
2753     0;
2754   };
2755 }
2756
2757 =head2 sqlt_type
2758
2759 Returns the database driver name.
2760
2761 =cut
2762
2763 sub sqlt_type {
2764   shift->_get_dbh->{Driver}->{Name};
2765 }
2766
2767 =head2 bind_attribute_by_data_type
2768
2769 Given a datatype from column info, returns a database specific bind
2770 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2771 let the database planner just handle it.
2772
2773 This method is always called after the driver has been determined and a DBI
2774 connection has been established. Therefore you can refer to C<DBI::$constant>
2775 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2776 the correct modules.
2777
2778 =cut
2779
2780 sub bind_attribute_by_data_type {
2781     return;
2782 }
2783
2784 =head2 is_datatype_numeric
2785
2786 Given a datatype from column_info, returns a boolean value indicating if
2787 the current RDBMS considers it a numeric value. This controls how
2788 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2789 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2790 be performed instead of the usual C<eq>.
2791
2792 =cut
2793
2794 sub is_datatype_numeric {
2795   #my ($self, $dt) = @_;
2796
2797   return 0 unless $_[1];
2798
2799   $_[1] =~ /^ (?:
2800     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2801   ) $/ix;
2802 }
2803
2804
2805 =head2 create_ddl_dir
2806
2807 =over 4
2808
2809 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2810
2811 =back
2812
2813 Creates a SQL file based on the Schema, for each of the specified
2814 database engines in C<\@databases> in the given directory.
2815 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2816
2817 Given a previous version number, this will also create a file containing
2818 the ALTER TABLE statements to transform the previous schema into the
2819 current one. Note that these statements may contain C<DROP TABLE> or
2820 C<DROP COLUMN> statements that can potentially destroy data.
2821
2822 The file names are created using the C<ddl_filename> method below, please
2823 override this method in your schema if you would like a different file
2824 name format. For the ALTER file, the same format is used, replacing
2825 $version in the name with "$preversion-$version".
2826
2827 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2828 The most common value for this would be C<< { add_drop_table => 1 } >>
2829 to have the SQL produced include a C<DROP TABLE> statement for each table
2830 created. For quoting purposes supply C<quote_identifiers>.
2831
2832 If no arguments are passed, then the following default values are assumed:
2833
2834 =over 4
2835
2836 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2837
2838 =item version    - $schema->schema_version
2839
2840 =item directory  - './'
2841
2842 =item preversion - <none>
2843
2844 =back
2845
2846 By default, C<\%sqlt_args> will have
2847
2848  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2849
2850 merged with the hash passed in. To disable any of those features, pass in a
2851 hashref like the following
2852
2853  { ignore_constraint_names => 0, # ... other options }
2854
2855
2856 WARNING: You are strongly advised to check all SQL files created, before applying
2857 them.
2858
2859 =cut
2860
2861 sub create_ddl_dir {
2862   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2863
2864   unless ($dir) {
2865     carp "No directory given, using ./\n";
2866     $dir = './';
2867   } else {
2868       -d $dir
2869         or
2870       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2871         or
2872       $self->throw_exception(
2873         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2874       );
2875   }
2876
2877   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2878
2879   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2880   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2881
2882   my $schema_version = $schema->schema_version || '1.x';
2883   $version ||= $schema_version;
2884
2885   $sqltargs = {
2886     add_drop_table => 1,
2887     ignore_constraint_names => 1,
2888     ignore_index_names => 1,
2889     %{$sqltargs || {}}
2890   };
2891
2892   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2893     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2894   }
2895
2896   my $sqlt = SQL::Translator->new( $sqltargs );
2897
2898   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2899   my $sqlt_schema = $sqlt->translate({ data => $schema })
2900     or $self->throw_exception ($sqlt->error);
2901
2902   foreach my $db (@$databases) {
2903     $sqlt->reset();
2904     $sqlt->{schema} = $sqlt_schema;
2905     $sqlt->producer($db);
2906
2907     my $file;
2908     my $filename = $schema->ddl_filename($db, $version, $dir);
2909     if (-e $filename && ($version eq $schema_version )) {
2910       # if we are dumping the current version, overwrite the DDL
2911       carp "Overwriting existing DDL file - $filename";
2912       unlink($filename);
2913     }
2914
2915     my $output = $sqlt->translate;
2916     if(!$output) {
2917       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2918       next;
2919     }
2920     if(!open($file, ">$filename")) {
2921       $self->throw_exception("Can't open $filename for writing ($!)");
2922       next;
2923     }
2924     print $file $output;
2925     close($file);
2926
2927     next unless ($preversion);
2928
2929     require SQL::Translator::Diff;
2930
2931     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2932     if(!-e $prefilename) {
2933       carp("No previous schema file found ($prefilename)");
2934       next;
2935     }
2936
2937     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2938     if(-e $difffile) {
2939       carp("Overwriting existing diff file - $difffile");
2940       unlink($difffile);
2941     }
2942
2943     my $source_schema;
2944     {
2945       my $t = SQL::Translator->new($sqltargs);
2946       $t->debug( 0 );
2947       $t->trace( 0 );
2948
2949       $t->parser( $db )
2950         or $self->throw_exception ($t->error);
2951
2952       my $out = $t->translate( $prefilename )
2953         or $self->throw_exception ($t->error);
2954
2955       $source_schema = $t->schema;
2956
2957       $source_schema->name( $prefilename )
2958         unless ( $source_schema->name );
2959     }
2960
2961     # The "new" style of producers have sane normalization and can support
2962     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2963     # And we have to diff parsed SQL against parsed SQL.
2964     my $dest_schema = $sqlt_schema;
2965
2966     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2967       my $t = SQL::Translator->new($sqltargs);
2968       $t->debug( 0 );
2969       $t->trace( 0 );
2970
2971       $t->parser( $db )
2972         or $self->throw_exception ($t->error);
2973
2974       my $out = $t->translate( $filename )
2975         or $self->throw_exception ($t->error);
2976
2977       $dest_schema = $t->schema;
2978
2979       $dest_schema->name( $filename )
2980         unless $dest_schema->name;
2981     }
2982
2983     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2984                                                   $dest_schema,   $db,
2985                                                   $sqltargs
2986                                                  );
2987     if(!open $file, ">$difffile") {
2988       $self->throw_exception("Can't write to $difffile ($!)");
2989       next;
2990     }
2991     print $file $diff;
2992     close($file);
2993   }
2994 }
2995
2996 =head2 deployment_statements
2997
2998 =over 4
2999
3000 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
3001
3002 =back
3003
3004 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
3005
3006 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
3007 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
3008
3009 C<$directory> is used to return statements from files in a previously created
3010 L</create_ddl_dir> directory and is optional. The filenames are constructed
3011 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
3012
3013 If no C<$directory> is specified then the statements are constructed on the
3014 fly using L<SQL::Translator> and C<$version> is ignored.
3015
3016 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
3017
3018 =cut
3019
3020 sub deployment_statements {
3021   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
3022   $type ||= $self->sqlt_type;
3023   $version ||= $schema->schema_version || '1.x';
3024   $dir ||= './';
3025   my $filename = $schema->ddl_filename($type, $version, $dir);
3026   if(-f $filename)
3027   {
3028       # FIXME replace this block when a proper sane sql parser is available
3029       my $file;
3030       open($file, "<$filename")
3031         or $self->throw_exception("Can't open $filename ($!)");
3032       my @rows = <$file>;
3033       close($file);
3034       return join('', @rows);
3035   }
3036
3037   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
3038     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
3039   }
3040
3041   # sources needs to be a parser arg, but for simplicity allow at top level
3042   # coming in
3043   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
3044       if exists $sqltargs->{sources};
3045
3046   my $tr = SQL::Translator->new(
3047     producer => "SQL::Translator::Producer::${type}",
3048     %$sqltargs,
3049     parser => 'SQL::Translator::Parser::DBIx::Class',
3050     data => $schema,
3051   );
3052
3053   return preserve_context {
3054     $tr->translate
3055   } after => sub {
3056     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
3057       unless defined $_[0];
3058   };
3059 }
3060
3061 # FIXME deploy() currently does not accurately report sql errors
3062 # Will always return true while errors are warned
3063 sub deploy {
3064   my ($self, $schema, $type, $sqltargs, $dir) = @_;
3065   my $deploy = sub {
3066     my $line = shift;
3067     return if(!$line);
3068     return if($line =~ /^--/);
3069     # next if($line =~ /^DROP/m);
3070     return if($line =~ /^BEGIN TRANSACTION/m);
3071     return if($line =~ /^COMMIT/m);
3072     return if $line =~ /^\s+$/; # skip whitespace only
3073     $self->_query_start($line);
3074     try {
3075       # do a dbh_do cycle here, as we need some error checking in
3076       # place (even though we will ignore errors)
3077       $self->dbh_do (sub { $_[1]->do($line) });
3078     } catch {
3079       carp qq{$_ (running "${line}")};
3080     };
3081     $self->_query_end($line);
3082   };
3083   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
3084   if (@statements > 1) {
3085     foreach my $statement (@statements) {
3086       $deploy->( $statement );
3087     }
3088   }
3089   elsif (@statements == 1) {
3090     # split on single line comments and end of statements
3091     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
3092       $deploy->( $line );
3093     }
3094   }
3095 }
3096
3097 =head2 datetime_parser
3098
3099 Returns the datetime parser class
3100
3101 =cut
3102
3103 sub datetime_parser {
3104   my $self = shift;
3105   return $self->{datetime_parser} ||= do {
3106     $self->build_datetime_parser(@_);
3107   };
3108 }
3109
3110 =head2 datetime_parser_type
3111
3112 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3113
3114 =head2 build_datetime_parser
3115
3116 See L</datetime_parser>
3117
3118 =cut
3119
3120 sub build_datetime_parser {
3121   my $self = shift;
3122   my $type = $self->datetime_parser_type(@_);
3123   return $type;
3124 }
3125
3126
3127 =head2 is_replicating
3128
3129 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3130 replicate from a master database.  Default is undef, which is the result
3131 returned by databases that don't support replication.
3132
3133 =cut
3134
3135 sub is_replicating {
3136     return;
3137
3138 }
3139
3140 =head2 lag_behind_master
3141
3142 Returns a number that represents a certain amount of lag behind a master db
3143 when a given storage is replicating.  The number is database dependent, but
3144 starts at zero and increases with the amount of lag. Default in undef
3145
3146 =cut
3147
3148 sub lag_behind_master {
3149     return;
3150 }
3151
3152 =head2 relname_to_table_alias
3153
3154 =over 4
3155
3156 =item Arguments: $relname, $join_count
3157
3158 =item Return Value: $alias
3159
3160 =back
3161
3162 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3163 queries.
3164
3165 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3166 way these aliases are named.
3167
3168 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3169 otherwise C<"$relname">.
3170
3171 =cut
3172
3173 sub relname_to_table_alias {
3174   my ($self, $relname, $join_count) = @_;
3175
3176   my $alias = ($join_count && $join_count > 1 ?
3177     join('_', $relname, $join_count) : $relname);
3178
3179   return $alias;
3180 }
3181
3182 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3183 # version and it may be necessary to amend or override it for a specific storage
3184 # if such binds are necessary.
3185 sub _max_column_bytesize {
3186   my ($self, $attr) = @_;
3187
3188   my $max_size;
3189
3190   if ($attr->{sqlt_datatype}) {
3191     my $data_type = lc($attr->{sqlt_datatype});
3192
3193     if ($attr->{sqlt_size}) {
3194
3195       # String/sized-binary types
3196       if ($data_type =~ /^(?:
3197           l? (?:var)? char(?:acter)? (?:\s*varying)?
3198             |
3199           (?:var)? binary (?:\s*varying)?
3200             |
3201           raw
3202         )\b/x
3203       ) {
3204         $max_size = $attr->{sqlt_size};
3205       }
3206       # Other charset/unicode types, assume scale of 4
3207       elsif ($data_type =~ /^(?:
3208           national \s* character (?:\s*varying)?
3209             |
3210           nchar
3211             |
3212           univarchar
3213             |
3214           nvarchar
3215         )\b/x
3216       ) {
3217         $max_size = $attr->{sqlt_size} * 4;
3218       }
3219     }
3220
3221     if (!$max_size and !$self->_is_lob_type($data_type)) {
3222       $max_size = 100 # for all other (numeric?) datatypes
3223     }
3224   }
3225
3226   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3227 }
3228
3229 # Determine if a data_type is some type of BLOB
3230 sub _is_lob_type {
3231   my ($self, $data_type) = @_;
3232   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3233     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3234                                   |varchar|character\s*varying|nvarchar
3235                                   |national\s*character\s*varying))?\z/xi);
3236 }
3237
3238 sub _is_binary_lob_type {
3239   my ($self, $data_type) = @_;
3240   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3241     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3242 }
3243
3244 sub _is_text_lob_type {
3245   my ($self, $data_type) = @_;
3246   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3247     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3248                         |national\s*character\s*varying))\z/xi);
3249 }
3250
3251 # Determine if a data_type is some type of a binary type
3252 sub _is_binary_type {
3253   my ($self, $data_type) = @_;
3254   $data_type && ($self->_is_binary_lob_type($data_type)
3255     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3256 }
3257
3258 1;
3259
3260 =head1 USAGE NOTES
3261
3262 =head2 DBIx::Class and AutoCommit
3263
3264 DBIx::Class can do some wonderful magic with handling exceptions,
3265 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3266 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3267 transaction support.
3268
3269 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3270 in an assumed transaction between commits, and you're telling us you'd
3271 like to manage that manually.  A lot of the magic protections offered by
3272 this module will go away.  We can't protect you from exceptions due to database
3273 disconnects because we don't know anything about how to restart your
3274 transactions.  You're on your own for handling all sorts of exceptional
3275 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3276 be with raw DBI.
3277
3278
3279 =head1 AUTHOR AND CONTRIBUTORS
3280
3281 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3282
3283 =head1 LICENSE
3284
3285 You may distribute this code under the same terms as Perl itself.
3286
3287 =cut