lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util qw/blessed weaken/;
  13
  14 __PACKAGE__->mk_group_accessors('simple' =>
  15     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  16        _conn_pid _conn_tid disable_sth_caching cursor on_connect_do
  17        transaction_depth unsafe/
  18 );
  19
  20 BEGIN {
  21
  22 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  23
  24 use base qw/SQL::Abstract::Limit/;
  25
  26 # This prevents the caching of $dbh in S::A::L, I believe
  27 sub new {
  28   my $self = shift->SUPER::new(@_);
  29
  30   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  31   #   it with what it resolves to:
  32   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  33     if ref $self->{limit_dialect};
  34
  35   $self;
  36 }
  37
  38 sub _RowNumberOver {
  39   my ($self, $sql, $order, $rows, $offset ) = @_;
  40
  41   $offset += 1;
  42   my $last = $rows + $offset;
  43   my ( $order_by ) = $self->_order_by( $order );
  44
  45   $sql = <<"";
  46 SELECT * FROM
  47 (
  48    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  49       $sql
  50       $order_by
  51    ) Q1
  52 ) Q2
  53 WHERE ROW_NUM BETWEEN $offset AND $last
  54
  55   return $sql;
  56 }
  57
  58
  59 # While we're at it, this should make LIMIT queries more efficient,
  60 #  without digging into things too deeply
  61 use Scalar::Util 'blessed';
  62 sub _find_syntax {
  63   my ($self, $syntax) = @_;
  64   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  65   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  66     return 'RowNumberOver';
  67   }
  68
  69   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  70 }
  71
  72 sub select {
  73   my ($self, $table, $fields, $where, $order, @rest) = @_;
  74   $table = $self->_quote($table) unless ref($table);
  75   local $self->{rownum_hack_count} = 1
  76     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  77   @rest = (-1) unless defined $rest[0];
  78   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  79     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  80   local $self->{having_bind} = [];
  81   my ($sql, @ret) = $self->SUPER::select(
  82     $table, $self->_recurse_fields($fields), $where, $order, @rest
  83   );
  84   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  85 }
  86
  87 sub insert {
  88   my $self = shift;
  89   my $table = shift;
  90   $table = $self->_quote($table) unless ref($table);
  91   $self->SUPER::insert($table, @_);
  92 }
  93
  94 sub update {
  95   my $self = shift;
  96   my $table = shift;
  97   $table = $self->_quote($table) unless ref($table);
  98   $self->SUPER::update($table, @_);
  99 }
 100
 101 sub delete {
 102   my $self = shift;
 103   my $table = shift;
 104   $table = $self->_quote($table) unless ref($table);
 105   $self->SUPER::delete($table, @_);
 106 }
 107
 108 sub _emulate_limit {
 109   my $self = shift;
 110   if ($_[3] == -1) {
 111     return $_[1].$self->_order_by($_[2]);
 112   } else {
 113     return $self->SUPER::_emulate_limit(@_);
 114   }
 115 }
 116
 117 sub _recurse_fields {
 118   my ($self, $fields) = @_;
 119   my $ref = ref $fields;
 120   return $self->_quote($fields) unless $ref;
 121   return $$fields if $ref eq 'SCALAR';
 122
 123   if ($ref eq 'ARRAY') {
 124     return join(', ', map {
 125       $self->_recurse_fields($_)
 126       .(exists $self->{rownum_hack_count}
 127          ? ' AS col'.$self->{rownum_hack_count}++
 128          : '')
 129      } @$fields);
 130   } elsif ($ref eq 'HASH') {
 131     foreach my $func (keys %$fields) {
 132       return $self->_sqlcase($func)
 133         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 134     }
 135   }
 136 }
 137
 138 sub _order_by {
 139   my $self = shift;
 140   my $ret = '';
 141   my @extra;
 142   if (ref $_[0] eq 'HASH') {
 143     if (defined $_[0]->{group_by}) {
 144       $ret = $self->_sqlcase(' group by ')
 145                .$self->_recurse_fields($_[0]->{group_by});
 146     }
 147     if (defined $_[0]->{having}) {
 148       my $frag;
 149       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 150       push(@{$self->{having_bind}}, @extra);
 151       $ret .= $self->_sqlcase(' having ').$frag;
 152     }
 153     if (defined $_[0]->{order_by}) {
 154       $ret .= $self->_order_by($_[0]->{order_by});
 155     }
 156   } elsif (ref $_[0] eq 'SCALAR') {
 157     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 158   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 159     my @order = @{+shift};
 160     $ret = $self->_sqlcase(' order by ')
 161           .join(', ', map {
 162                         my $r = $self->_order_by($_, @_);
 163                         $r =~ s/^ ?ORDER BY //i;
 164                         $r;
 165                       } @order);
 166   } else {
 167     $ret = $self->SUPER::_order_by(@_);
 168   }
 169   return $ret;
 170 }
 171
 172 sub _order_directions {
 173   my ($self, $order) = @_;
 174   $order = $order->{order_by} if ref $order eq 'HASH';
 175   return $self->SUPER::_order_directions($order);
 176 }
 177
 178 sub _table {
 179   my ($self, $from) = @_;
 180   if (ref $from eq 'ARRAY') {
 181     return $self->_recurse_from(@$from);
 182   } elsif (ref $from eq 'HASH') {
 183     return $self->_make_as($from);
 184   } else {
 185     return $from; # would love to quote here but _table ends up getting called
 186                   # twice during an ->select without a limit clause due to
 187                   # the way S::A::Limit->select works. should maybe consider
 188                   # bypassing this and doing S::A::select($self, ...) in
 189                   # our select method above. meantime, quoting shims have
 190                   # been added to select/insert/update/delete here
 191   }
 192 }
 193
 194 sub _recurse_from {
 195   my ($self, $from, @join) = @_;
 196   my @sqlf;
 197   push(@sqlf, $self->_make_as($from));
 198   foreach my $j (@join) {
 199     my ($to, $on) = @$j;
 200
 201     # check whether a join type exists
 202     my $join_clause = '';
 203     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 204     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 205       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 206     } else {
 207       $join_clause = ' JOIN ';
 208     }
 209     push(@sqlf, $join_clause);
 210
 211     if (ref $to eq 'ARRAY') {
 212       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 213     } else {
 214       push(@sqlf, $self->_make_as($to));
 215     }
 216     push(@sqlf, ' ON ', $self->_join_condition($on));
 217   }
 218   return join('', @sqlf);
 219 }
 220
 221 sub _make_as {
 222   my ($self, $from) = @_;
 223   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 224                      reverse each %{$self->_skip_options($from)});
 225 }
 226
 227 sub _skip_options {
 228   my ($self, $hash) = @_;
 229   my $clean_hash = {};
 230   $clean_hash->{$_} = $hash->{$_}
 231     for grep {!/^-/} keys %$hash;
 232   return $clean_hash;
 233 }
 234
 235 sub _join_condition {
 236   my ($self, $cond) = @_;
 237   if (ref $cond eq 'HASH') {
 238     my %j;
 239     for (keys %$cond) {
 240       my $v = $cond->{$_};
 241       if (ref $v) {
 242         # XXX no throw_exception() in this package and croak() fails with strange results
 243         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 244             if ref($v) ne 'SCALAR';
 245         $j{$_} = $v;
 246       }
 247       else {
 248         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 249       }
 250     };
 251     return scalar($self->_recurse_where(\%j));
 252   } elsif (ref $cond eq 'ARRAY') {
 253     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 254   } else {
 255     die "Can't handle this yet!";
 256   }
 257 }
 258
 259 sub _quote {
 260   my ($self, $label) = @_;
 261   return '' unless defined $label;
 262   return "*" if $label eq '*';
 263   return $label unless $self->{quote_char};
 264   if(ref $self->{quote_char} eq "ARRAY"){
 265     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 266       if !defined $self->{name_sep};
 267     my $sep = $self->{name_sep};
 268     return join($self->{name_sep},
 269         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 270        split(/\Q$sep\E/,$label));
 271   }
 272   return $self->SUPER::_quote($label);
 273 }
 274
 275 sub limit_dialect {
 276     my $self = shift;
 277     $self->{limit_dialect} = shift if @_;
 278     return $self->{limit_dialect};
 279 }
 280
 281 sub quote_char {
 282     my $self = shift;
 283     $self->{quote_char} = shift if @_;
 284     return $self->{quote_char};
 285 }
 286
 287 sub name_sep {
 288     my $self = shift;
 289     $self->{name_sep} = shift if @_;
 290     return $self->{name_sep};
 291 }
 292
 293 } # End of BEGIN block
 294
 295 =head1 NAME
 296
 297 DBIx::Class::Storage::DBI - DBI storage handler
 298
 299 =head1 SYNOPSIS
 300
 301 =head1 DESCRIPTION
 302
 303 This class represents the connection to an RDBMS via L<DBI>.  See
 304 L<DBIx::Class::Storage> for general information.  This pod only
 305 documents DBI-specific methods and behaviors.
 306
 307 =head1 METHODS
 308
 309 =cut
 310
 311 sub new {
 312   my $new = shift->next::method(@_);
 313
 314   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 315   $new->transaction_depth(0);
 316   $new->_sql_maker_opts({});
 317   $new->{_in_dbh_do} = 0;
 318   $new->{_dbh_gen} = 0;
 319
 320   $new;
 321 }
 322
 323 =head2 connect_info
 324
 325 The arguments of C<connect_info> are always a single array reference.
 326
 327 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 328 encapsulates its argument list in an arrayref before calling
 329 C<connect_info> here.
 330
 331 The arrayref can either contain the same set of arguments one would
 332 normally pass to L<DBI/connect>, or a lone code reference which returns
 333 a connected database handle.  Please note that the L<DBI> docs
 334 recommend that you always explicitly set C<AutoCommit> to either
 335 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 336 to C<1>, and that you perform transactions via our L</txn_do>
 337 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 338 set it to zero.  This is the default for most DBDs.  See below for more
 339 details.
 340
 341 In either case, if the final argument in your connect_info happens
 342 to be a hashref, C<connect_info> will look there for several
 343 connection-specific options:
 344
 345 =over 4
 346
 347 =item on_connect_do
 348
 349 This can be set to an arrayref of literal sql statements, which will
 350 be executed immediately after making the connection to the database
 351 every time we [re-]connect.
 352
 353 =item disable_sth_caching
 354
 355 If set to a true value, this option will disable the caching of
 356 statement handles via L<DBI/prepare_cached>.
 357
 358 =item limit_dialect
 359
 360 Sets the limit dialect. This is useful for JDBC-bridge among others
 361 where the remote SQL-dialect cannot be determined by the name of the
 362 driver alone.
 363
 364 =item quote_char
 365
 366 Specifies what characters to use to quote table and column names. If
 367 you use this you will want to specify L<name_sep> as well.
 368
 369 quote_char expects either a single character, in which case is it is placed
 370 on either side of the table/column, or an arrayref of length 2 in which case the
 371 table/column name is placed between the elements.
 372
 373 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 374 use C<quote_char =E<gt> [qw/[ ]/]>.
 375
 376 =item name_sep
 377
 378 This only needs to be used in conjunction with L<quote_char>, and is used to
 379 specify the charecter that seperates elements (schemas, tables, columns) from
 380 each other. In most cases this is simply a C<.>.
 381
 382 =item unsafe
 383
 384 This Storage driver normally installs its own C<HandleError>, sets
 385 C<RaiseError> on, and sets C<PrintError> off on all database handles,
 386 including those supplied by a coderef.  It does this so that it can
 387 have consistent and useful error behavior.
 388
 389 If you set this option to a true value, Storage will not do its usual
 390 modifications to the database handle's C<RaiseError>, C<PrintError>, and
 391 C<HandleError> attributes, and instead relies on the settings in your
 392 connect_info DBI options (or the values you set in your connection
 393 coderef, in the case that you are connecting via coderef).
 394
 395 Note that your custom settings can cause Storage to malfunction,
 396 especially if you set a C<HandleError> handler that suppresses exceptions
 397 and/or disable C<RaiseError>.
 398
 399 =back
 400
 401 These options can be mixed in with your other L<DBI> connection attributes,
 402 or placed in a seperate hashref after all other normal L<DBI> connection
 403 arguments.
 404
 405 Every time C<connect_info> is invoked, any previous settings for
 406 these options will be cleared before setting the new ones, regardless of
 407 whether any options are specified in the new C<connect_info>.
 408
 409 Another Important Note:
 410
 411 DBIC can do some wonderful magic with handling exceptions,
 412 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 413 combined with C<txn_do> for transaction support.
 414
 415 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 416 in an assumed transaction between commits, and you're telling us you'd
 417 like to manage that manually.  A lot of DBIC's magic protections
 418 go away.  We can't protect you from exceptions due to database
 419 disconnects because we don't know anything about how to restart your
 420 transactions.  You're on your own for handling all sorts of exceptional
 421 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 422 be with raw DBI.
 423
 424 Examples:
 425
 426   # Simple SQLite connection
 427   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 428
 429   # Connect via subref
 430   ->connect_info([ sub { DBI->connect(...) } ]);
 431
 432   # A bit more complicated
 433   ->connect_info(
 434     [
 435       'dbi:Pg:dbname=foo',
 436       'postgres',
 437       'my_pg_password',
 438       { AutoCommit => 1 },
 439       { quote_char => q{"}, name_sep => q{.} },
 440     ]
 441   );
 442
 443   # Equivalent to the previous example
 444   ->connect_info(
 445     [
 446       'dbi:Pg:dbname=foo',
 447       'postgres',
 448       'my_pg_password',
 449       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 450     ]
 451   );
 452
 453   # Subref + DBIC-specific connection options
 454   ->connect_info(
 455     [
 456       sub { DBI->connect(...) },
 457       {
 458           quote_char => q{`},
 459           name_sep => q{@},
 460           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 461           disable_sth_caching => 1,
 462       },
 463     ]
 464   );
 465
 466 =cut
 467
 468 sub connect_info {
 469   my ($self, $info_arg) = @_;
 470
 471   return $self->_connect_info if !$info_arg;
 472
 473   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 474   #  the new set of options
 475   $self->_sql_maker(undef);
 476   $self->_sql_maker_opts({});
 477   $self->_connect_info([@$info_arg]); # copy for _connect_info
 478
 479   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 480
 481   my $last_info = $dbi_info->[-1];
 482   if(ref $last_info eq 'HASH') {
 483     for my $storage_opt (qw/on_connect_do disable_sth_caching unsafe/) {
 484       if(my $value = delete $last_info->{$storage_opt}) {
 485         $self->$storage_opt($value);
 486       }
 487     }
 488     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 489       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 490         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 491       }
 492     }
 493
 494     # Get rid of any trailing empty hashref
 495     pop(@$dbi_info) if !keys %$last_info;
 496   }
 497   $self->_dbi_connect_info($dbi_info);
 498
 499   $self->_connect_info;
 500 }
 501
 502 =head2 on_connect_do
 503
 504 This method is deprecated in favor of setting via L</connect_info>.
 505
 506 =head2 dbh_do
 507
 508 Arguments: $subref, @extra_coderef_args?
 509
 510 Execute the given subref using the new exception-based connection management.
 511
 512 The first two arguments will be the storage object that C<dbh_do> was called
 513 on and a database handle to use.  Any additional arguments will be passed
 514 verbatim to the called subref as arguments 2 and onwards.
 515
 516 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 517 exception handling and reconnection (or failover in future subclasses).
 518
 519 Your subref should have no side-effects outside of the database, as
 520 there is the potential for your subref to be partially double-executed
 521 if the database connection was stale/dysfunctional.
 522
 523 Example:
 524
 525   my @stuff = $schema->storage->dbh_do(
 526     sub {
 527       my ($storage, $dbh, @cols) = @_;
 528       my $cols = join(q{, }, @cols);
 529       $dbh->selectrow_array("SELECT $cols FROM foo");
 530     },
 531     @column_list
 532   );
 533
 534 =cut
 535
 536 sub dbh_do {
 537   my $self = shift;
 538   my $coderef = shift;
 539
 540   ref $coderef eq 'CODE' or $self->throw_exception
 541     ('$coderef must be a CODE reference');
 542
 543   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 544       || $self->{transaction_depth};
 545
 546   local $self->{_in_dbh_do} = 1;
 547
 548   my @result;
 549   my $want_array = wantarray;
 550
 551   eval {
 552     $self->_verify_pid if $self->_dbh;
 553     $self->_populate_dbh if !$self->_dbh;
 554     if($want_array) {
 555         @result = $coderef->($self, $self->_dbh, @_);
 556     }
 557     elsif(defined $want_array) {
 558         $result[0] = $coderef->($self, $self->_dbh, @_);
 559     }
 560     else {
 561         $coderef->($self, $self->_dbh, @_);
 562     }
 563   };
 564
 565   my $exception = $@;
 566   if(!$exception) { return $want_array ? @result : $result[0] }
 567
 568   $self->throw_exception($exception) if $self->connected;
 569
 570   # We were not connected - reconnect and retry, but let any
 571   #  exception fall right through this time
 572   $self->_populate_dbh;
 573   $coderef->($self, $self->_dbh, @_);
 574 }
 575
 576 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 577 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 578 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 579 sub txn_do {
 580   my $self = shift;
 581   my $coderef = shift;
 582
 583   ref $coderef eq 'CODE' or $self->throw_exception
 584     ('$coderef must be a CODE reference');
 585
 586   local $self->{_in_dbh_do} = 1;
 587
 588   my @result;
 589   my $want_array = wantarray;
 590
 591   my $tried = 0;
 592   while(1) {
 593     eval {
 594       $self->_verify_pid if $self->_dbh;
 595       $self->_populate_dbh if !$self->_dbh;
 596
 597       $self->txn_begin;
 598       if($want_array) {
 599           @result = $coderef->(@_);
 600       }
 601       elsif(defined $want_array) {
 602           $result[0] = $coderef->(@_);
 603       }
 604       else {
 605           $coderef->(@_);
 606       }
 607       $self->txn_commit;
 608     };
 609
 610     my $exception = $@;
 611     if(!$exception) { return $want_array ? @result : $result[0] }
 612
 613     if($tried++ > 0 || $self->connected) {
 614       eval { $self->txn_rollback };
 615       my $rollback_exception = $@;
 616       if($rollback_exception) {
 617         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 618         $self->throw_exception($exception)  # propagate nested rollback
 619           if $rollback_exception =~ /$exception_class/;
 620
 621         $self->throw_exception(
 622           "Transaction aborted: ${exception}. "
 623           . "Rollback failed: ${rollback_exception}"
 624         );
 625       }
 626       $self->throw_exception($exception)
 627     }
 628
 629     # We were not connected, and was first try - reconnect and retry
 630     # via the while loop
 631     $self->_populate_dbh;
 632   }
 633 }
 634
 635 =head2 disconnect
 636
 637 Our C<disconnect> method also performs a rollback first if the
 638 database is not in C<AutoCommit> mode.
 639
 640 =cut
 641
 642 sub disconnect {
 643   my ($self) = @_;
 644
 645   if( $self->connected ) {
 646     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 647     $self->_dbh->disconnect;
 648     $self->_dbh(undef);
 649     $self->{_dbh_gen}++;
 650   }
 651 }
 652
 653 sub connected {
 654   my ($self) = @_;
 655
 656   if(my $dbh = $self->_dbh) {
 657       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 658           $self->_dbh(undef);
 659           $self->{_dbh_gen}++;
 660           return;
 661       }
 662       else {
 663           $self->_verify_pid;
 664       }
 665       return ($dbh->FETCH('Active') && $dbh->ping);
 666   }
 667
 668   return 0;
 669 }
 670
 671 # handle pid changes correctly
 672 #  NOTE: assumes $self->_dbh is a valid $dbh
 673 sub _verify_pid {
 674   my ($self) = @_;
 675
 676   return if $self->_conn_pid == $$;
 677
 678   $self->_dbh->{InactiveDestroy} = 1;
 679   $self->_dbh(undef);
 680   $self->{_dbh_gen}++;
 681
 682   return;
 683 }
 684
 685 sub ensure_connected {
 686   my ($self) = @_;
 687
 688   unless ($self->connected) {
 689     $self->_populate_dbh;
 690   }
 691 }
 692
 693 =head2 dbh
 694
 695 Returns the dbh - a data base handle of class L<DBI>.
 696
 697 =cut
 698
 699 sub dbh {
 700   my ($self) = @_;
 701
 702   $self->ensure_connected;
 703   return $self->_dbh;
 704 }
 705
 706 sub _sql_maker_args {
 707     my ($self) = @_;
 708
 709     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 710 }
 711
 712 sub sql_maker {
 713   my ($self) = @_;
 714   unless ($self->_sql_maker) {
 715     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 716   }
 717   return $self->_sql_maker;
 718 }
 719
 720 sub _populate_dbh {
 721   my ($self) = @_;
 722   my @info = @{$self->_dbi_connect_info || []};
 723   $self->_dbh($self->_connect(@info));
 724
 725   # Always set the transaction depth on connect, since
 726   #  there is no transaction in progress by definition
 727   $self->{transaction_depth} = $self->_dbh->{AutoCommit} ? 0 : 1;
 728
 729   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 730     my $driver = $self->_dbh->{Driver}->{Name};
 731     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 732       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 733       $self->_rebless() if $self->can('_rebless');
 734     }
 735   }
 736
 737   # if on-connect sql statements are given execute them
 738   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 739     $self->debugobj->query_start($sql_statement) if $self->debug();
 740     $self->_dbh->do($sql_statement);
 741     $self->debugobj->query_end($sql_statement) if $self->debug();
 742   }
 743
 744   $self->_conn_pid($$);
 745   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 746 }
 747
 748 sub _connect {
 749   my ($self, @info) = @_;
 750
 751   $self->throw_exception("You failed to provide any connection info")
 752     if !@info;
 753
 754   my ($old_connect_via, $dbh);
 755
 756   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 757     $old_connect_via = $DBI::connect_via;
 758     $DBI::connect_via = 'connect';
 759   }
 760
 761   eval {
 762     if(ref $info[0] eq 'CODE') {
 763        $dbh = &{$info[0]}
 764     }
 765     else {
 766        $dbh = DBI->connect(@info);
 767     }
 768
 769     if(!$self->unsafe) {
 770       my $weak_self = $self;
 771       weaken($weak_self);
 772       $dbh->{HandleError} = sub {
 773           $weak_self->throw_exception("DBI Exception: $_[0]")
 774       };
 775       $dbh->{RaiseError} = 1;
 776       $dbh->{PrintError} = 0;
 777     }
 778   };
 779
 780   $DBI::connect_via = $old_connect_via if $old_connect_via;
 781
 782   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 783     if !$dbh || $@;
 784
 785   $dbh;
 786 }
 787
 788
 789 sub txn_begin {
 790   my $self = shift;
 791   $self->ensure_connected();
 792   if($self->{transaction_depth}++ == 0) {
 793     $self->debugobj->txn_begin()
 794       if $self->debug;
 795     # this isn't ->_dbh-> because
 796     #  we should reconnect on begin_work
 797     #  for AutoCommit users
 798     $self->dbh->begin_work;
 799   }
 800 }
 801
 802 sub txn_commit {
 803   my $self = shift;
 804   if ($self->{transaction_depth} == 1) {
 805     my $dbh = $self->_dbh;
 806     $self->debugobj->txn_commit()
 807       if ($self->debug);
 808     $dbh->commit;
 809     $self->{transaction_depth} = 0
 810       if $dbh->{AutoCommit};
 811   }
 812   elsif($self->{transaction_depth} > 1) {
 813     $self->{transaction_depth}--
 814   }
 815 }
 816
 817 sub txn_rollback {
 818   my $self = shift;
 819   my $dbh = $self->_dbh;
 820   my $autocommit;
 821   eval {
 822     $autocommit = $dbh->{AutoCommit};
 823     if ($self->{transaction_depth} == 1) {
 824       $self->debugobj->txn_rollback()
 825         if ($self->debug);
 826       $dbh->rollback;
 827       $self->{transaction_depth} = 0
 828         if $autocommit;
 829     }
 830     elsif($self->{transaction_depth} > 1) {
 831       $self->{transaction_depth}--;
 832     }
 833     else {
 834       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 835     }
 836   };
 837   if ($@) {
 838     my $error = $@;
 839     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 840     $error =~ /$exception_class/ and $self->throw_exception($error);
 841     # ensure that a failed rollback resets the transaction depth
 842     $self->{transaction_depth} = $autocommit ? 0 : 1;
 843     $self->throw_exception($error);
 844   }
 845 }
 846
 847 # This used to be the top-half of _execute.  It was split out to make it
 848 #  easier to override in NoBindVars without duping the rest.  It takes up
 849 #  all of _execute's args, and emits $sql, @bind.
 850 sub _prep_for_execute {
 851   my ($self, $op, $extra_bind, $ident, $args) = @_;
 852
 853   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 854   unshift(@bind,
 855     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 856       if $extra_bind;
 857
 858   return ($sql, \@bind);
 859 }
 860
 861 sub _dbh_execute {
 862   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 863
 864   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 865     $ident = $ident->from();
 866   }
 867
 868   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 869
 870   if ($self->debug) {
 871       my @debug_bind =
 872         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 873       $self->debugobj->query_start($sql, @debug_bind);
 874   }
 875
 876   my $sth = $self->sth($sql,$op);
 877
 878   my $placeholder_index = 1;
 879
 880   foreach my $bound (@$bind) {
 881     my $attributes = {};
 882     my($column_name, @data) = @$bound;
 883
 884     if ($bind_attributes) {
 885       $attributes = $bind_attributes->{$column_name}
 886       if defined $bind_attributes->{$column_name};
 887     }
 888
 889     foreach my $data (@data) {
 890       $data = ref $data ? ''.$data : $data; # stringify args
 891
 892       $sth->bind_param($placeholder_index, $data, $attributes);
 893       $placeholder_index++;
 894     }
 895   }
 896
 897   # Can this fail without throwing an exception anyways???
 898   my $rv = $sth->execute();
 899   $self->throw_exception($sth->errstr) if !$rv;
 900
 901   if ($self->debug) {
 902      my @debug_bind =
 903        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 904      $self->debugobj->query_end($sql, @debug_bind);
 905   }
 906
 907   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 908 }
 909
 910 sub _execute {
 911     my $self = shift;
 912     $self->dbh_do($self->can('_dbh_execute'), @_)
 913 }
 914
 915 sub insert {
 916   my ($self, $source, $to_insert) = @_;
 917
 918   my $ident = $source->from;
 919   my $bind_attributes = $self->source_bind_attributes($source);
 920
 921   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
 922
 923   return $to_insert;
 924 }
 925
 926 ## Still not quite perfect, and EXPERIMENTAL
 927 ## Currently it is assumed that all values passed will be "normal", i.e. not
 928 ## scalar refs, or at least, all the same type as the first set, the statement is
 929 ## only prepped once.
 930 sub insert_bulk {
 931   my ($self, $source, $cols, $data) = @_;
 932   my %colvalues;
 933   my $table = $source->from;
 934   @colvalues{@$cols} = (0..$#$cols);
 935   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 936
 937   if ($self->debug) {
 938       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 939       $self->debugobj->query_start($sql, @debug_bind);
 940   }
 941   my $sth = $self->sth($sql);
 942
 943 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 944
 945   ## This must be an arrayref, else nothing works!
 946
 947   my $tuple_status = [];
 948
 949   ##use Data::Dumper;
 950   ##print STDERR Dumper( $data, $sql, [@bind] );
 951
 952   my $time = time();
 953
 954   ## Get the bind_attributes, if any exist
 955   my $bind_attributes = $self->source_bind_attributes($source);
 956
 957   ## Bind the values and execute
 958   my $placeholder_index = 1;
 959
 960   foreach my $bound (@bind) {
 961
 962     my $attributes = {};
 963     my ($column_name, $data_index) = @$bound;
 964
 965     if( $bind_attributes ) {
 966       $attributes = $bind_attributes->{$column_name}
 967       if defined $bind_attributes->{$column_name};
 968     }
 969
 970     my @data = map { $_->[$data_index] } @$data;
 971
 972     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
 973     $placeholder_index++;
 974   }
 975   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
 976   $self->throw_exception($sth->errstr) if !$rv;
 977
 978   if ($self->debug) {
 979       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
 980       $self->debugobj->query_end($sql, @debug_bind);
 981   }
 982   return (wantarray ? ($rv, $sth, @bind) : $rv);
 983 }
 984
 985 sub update {
 986   my $self = shift @_;
 987   my $source = shift @_;
 988   my $bind_attributes = $self->source_bind_attributes($source);
 989
 990   return $self->_execute('update' => [], $source, $bind_attributes, @_);
 991 }
 992
 993
 994 sub delete {
 995   my $self = shift @_;
 996   my $source = shift @_;
 997
 998   my $bind_attrs = {}; ## If ever it's needed...
 999
1000   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1001 }
1002
1003 sub _select {
1004   my ($self, $ident, $select, $condition, $attrs) = @_;
1005   my $order = $attrs->{order_by};
1006   if (ref $condition eq 'SCALAR') {
1007     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1008   }
1009   if (exists $attrs->{group_by} || $attrs->{having}) {
1010     $order = {
1011       group_by => $attrs->{group_by},
1012       having => $attrs->{having},
1013       ($order ? (order_by => $order) : ())
1014     };
1015   }
1016   my $bind_attrs = {}; ## Future support
1017   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1018   if ($attrs->{software_limit} ||
1019       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1020         $attrs->{software_limit} = 1;
1021   } else {
1022     $self->throw_exception("rows attribute must be positive if present")
1023       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1024     push @args, $attrs->{rows}, $attrs->{offset};
1025   }
1026   return $self->_execute(@args);
1027 }
1028
1029 sub source_bind_attributes {
1030   my ($self, $source) = @_;
1031
1032   my $bind_attributes;
1033   foreach my $column ($source->columns) {
1034
1035     my $data_type = $source->column_info($column)->{data_type} || '';
1036     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1037      if $data_type;
1038   }
1039
1040   return $bind_attributes;
1041 }
1042
1043 =head2 select
1044
1045 =over 4
1046
1047 =item Arguments: $ident, $select, $condition, $attrs
1048
1049 =back
1050
1051 Handle a SQL select statement.
1052
1053 =cut
1054
1055 sub select {
1056   my $self = shift;
1057   my ($ident, $select, $condition, $attrs) = @_;
1058   return $self->cursor->new($self, \@_, $attrs);
1059 }
1060
1061 sub select_single {
1062   my $self = shift;
1063   my ($rv, $sth, @bind) = $self->_select(@_);
1064   my @row = $sth->fetchrow_array;
1065   # Need to call finish() to work round broken DBDs
1066   $sth->finish();
1067   return @row;
1068 }
1069
1070 =head2 sth
1071
1072 =over 4
1073
1074 =item Arguments: $sql
1075
1076 =back
1077
1078 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1079
1080 =cut
1081
1082 sub _dbh_sth {
1083   my ($self, $dbh, $sql) = @_;
1084
1085   # 3 is the if_active parameter which avoids active sth re-use
1086   my $sth = $self->disable_sth_caching
1087     ? $dbh->prepare($sql)
1088     : $dbh->prepare_cached($sql, {}, 3);
1089
1090   # XXX You would think RaiseError would make this impossible,
1091   #  but apparently that's not true :(
1092   $self->throw_exception($dbh->errstr) if !$sth;
1093
1094   $sth;
1095 }
1096
1097 sub sth {
1098   my ($self, $sql) = @_;
1099   $self->dbh_do($self->can('_dbh_sth'), $sql);
1100 }
1101
1102 sub _dbh_columns_info_for {
1103   my ($self, $dbh, $table) = @_;
1104
1105   if ($dbh->can('column_info')) {
1106     my %result;
1107     eval {
1108       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1109       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1110       $sth->execute();
1111       while ( my $info = $sth->fetchrow_hashref() ){
1112         my %column_info;
1113         $column_info{data_type}   = $info->{TYPE_NAME};
1114         $column_info{size}      = $info->{COLUMN_SIZE};
1115         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1116         $column_info{default_value} = $info->{COLUMN_DEF};
1117         my $col_name = $info->{COLUMN_NAME};
1118         $col_name =~ s/^\"(.*)\"$/$1/;
1119
1120         $result{$col_name} = \%column_info;
1121       }
1122     };
1123     return \%result if !$@ && scalar keys %result;
1124   }
1125
1126   my %result;
1127   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1128   $sth->execute;
1129   my @columns = @{$sth->{NAME_lc}};
1130   for my $i ( 0 .. $#columns ){
1131     my %column_info;
1132     $column_info{data_type} = $sth->{TYPE}->[$i];
1133     $column_info{size} = $sth->{PRECISION}->[$i];
1134     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1135
1136     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1137       $column_info{data_type} = $1;
1138       $column_info{size}    = $2;
1139     }
1140
1141     $result{$columns[$i]} = \%column_info;
1142   }
1143   $sth->finish;
1144
1145   foreach my $col (keys %result) {
1146     my $colinfo = $result{$col};
1147     my $type_num = $colinfo->{data_type};
1148     my $type_name;
1149     if(defined $type_num && $dbh->can('type_info')) {
1150       my $type_info = $dbh->type_info($type_num);
1151       $type_name = $type_info->{TYPE_NAME} if $type_info;
1152       $colinfo->{data_type} = $type_name if $type_name;
1153     }
1154   }
1155
1156   return \%result;
1157 }
1158
1159 sub columns_info_for {
1160   my ($self, $table) = @_;
1161   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1162 }
1163
1164 =head2 last_insert_id
1165
1166 Return the row id of the last insert.
1167
1168 =cut
1169
1170 sub _dbh_last_insert_id {
1171     my ($self, $dbh, $source, $col) = @_;
1172     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1173     $dbh->func('last_insert_rowid');
1174 }
1175
1176 sub last_insert_id {
1177   my $self = shift;
1178   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1179 }
1180
1181 =head2 sqlt_type
1182
1183 Returns the database driver name.
1184
1185 =cut
1186
1187 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1188
1189 =head2 bind_attribute_by_data_type
1190
1191 Given a datatype from column info, returns a database specific bind attribute for
1192 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1193 just handle it.
1194
1195 Generally only needed for special case column types, like bytea in postgres.
1196
1197 =cut
1198
1199 sub bind_attribute_by_data_type {
1200     return;
1201 }
1202
1203 =head2 create_ddl_dir (EXPERIMENTAL)
1204
1205 =over 4
1206
1207 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1208
1209 =back
1210
1211 Creates a SQL file based on the Schema, for each of the specified
1212 database types, in the given directory.
1213
1214 Note that this feature is currently EXPERIMENTAL and may not work correctly
1215 across all databases, or fully handle complex relationships.
1216
1217 =cut
1218
1219 sub create_ddl_dir
1220 {
1221   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1222
1223   if(!$dir || !-d $dir)
1224   {
1225     warn "No directory given, using ./\n";
1226     $dir = "./";
1227   }
1228   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1229   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1230   $version ||= $schema->VERSION || '1.x';
1231   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1232
1233   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.08: '}
1234       . $self->_check_sqlt_message . q{'})
1235           if !$self->_check_sqlt_version;
1236
1237   my $sqlt = SQL::Translator->new({
1238 #      debug => 1,
1239       add_drop_table => 1,
1240   });
1241   foreach my $db (@$databases)
1242   {
1243     $sqlt->reset();
1244     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1245 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1246     $sqlt = $self->configure_sqlt($sqlt, $db);
1247     $sqlt->data($schema);
1248     $sqlt->producer($db);
1249
1250     my $file;
1251     my $filename = $schema->ddl_filename($db, $dir, $version);
1252     if(-e $filename)
1253     {
1254       warn("$filename already exists, skipping $db");
1255       next;
1256     }
1257
1258     my $output = $sqlt->translate;
1259     if(!$output)
1260     {
1261       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1262       next;
1263     }
1264     if(!open($file, ">$filename"))
1265     {
1266         $self->throw_exception("Can't open $filename for writing ($!)");
1267         next;
1268     }
1269     print $file $output;
1270     close($file);
1271
1272     if($preversion)
1273     {
1274       require SQL::Translator::Diff;
1275
1276       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1277 #      print "Previous version $prefilename\n";
1278       if(!-e $prefilename)
1279       {
1280         warn("No previous schema file found ($prefilename)");
1281         next;
1282       }
1283       #### We need to reparse the SQLite file we just wrote, so that
1284       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1285       ##   FIXME: rip Diff to pieces!
1286 #      my $target_schema = $sqlt->schema;
1287 #      unless ( $target_schema->name ) {
1288 #        $target_schema->name( $filename );
1289 #      }
1290       my @input;
1291       push @input, {file => $prefilename, parser => $db};
1292       push @input, {file => $filename, parser => $db};
1293       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1294         my $file   = $_->{'file'};
1295         my $parser = $_->{'parser'};
1296
1297         my $t = SQL::Translator->new;
1298         $t->debug( 0 );
1299         $t->trace( 0 );
1300         $t->parser( $parser )            or die $t->error;
1301         my $out = $t->translate( $file ) or die $t->error;
1302         my $schema = $t->schema;
1303         unless ( $schema->name ) {
1304           $schema->name( $file );
1305         }
1306         ($schema, $parser);
1307       } @input;
1308
1309       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1310                                                     $target_schema, $db,
1311                                                     {}
1312                                                    );
1313       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1314       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1315       if(-e $difffile)
1316       {
1317         warn("$difffile already exists, skipping");
1318         next;
1319       }
1320       if(!open $file, ">$difffile")
1321       {
1322         $self->throw_exception("Can't write to $difffile ($!)");
1323         next;
1324       }
1325       print $file $diff;
1326       close($file);
1327     }
1328   }
1329 }
1330
1331 sub configure_sqlt() {
1332   my $self = shift;
1333   my $tr = shift;
1334   my $db = shift || $self->sqlt_type;
1335   if ($db eq 'PostgreSQL') {
1336     $tr->quote_table_names(0);
1337     $tr->quote_field_names(0);
1338   }
1339   return $tr;
1340 }
1341
1342 =head2 deployment_statements
1343
1344 =over 4
1345
1346 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1347
1348 =back
1349
1350 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1351 The database driver name is given by C<$type>, though the value from
1352 L</sqlt_type> is used if it is not specified.
1353
1354 C<$directory> is used to return statements from files in a previously created
1355 L</create_ddl_dir> directory and is optional. The filenames are constructed
1356 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1357
1358 If no C<$directory> is specified then the statements are constructed on the
1359 fly using L<SQL::Translator> and C<$version> is ignored.
1360
1361 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1362
1363 =cut
1364
1365 sub deployment_statements {
1366   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1367   # Need to be connected to get the correct sqlt_type
1368   $self->ensure_connected() unless $type;
1369   $type ||= $self->sqlt_type;
1370   $version ||= $schema->VERSION || '1.x';
1371   $dir ||= './';
1372   my $filename = $schema->ddl_filename($type, $dir, $version);
1373   if(-f $filename)
1374   {
1375       my $file;
1376       open($file, "<$filename")
1377         or $self->throw_exception("Can't open $filename ($!)");
1378       my @rows = <$file>;
1379       close($file);
1380       return join('', @rows);
1381   }
1382
1383   $self->throw_exception(q{Can't deploy without SQL::Translator 0.08: '}
1384       . $self->_check_sqlt_message . q{'})
1385           if !$self->_check_sqlt_version;
1386
1387   require SQL::Translator::Parser::DBIx::Class;
1388   eval qq{use SQL::Translator::Producer::${type}};
1389   $self->throw_exception($@) if $@;
1390
1391   # sources needs to be a parser arg, but for simplicty allow at top level
1392   # coming in
1393   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1394       if exists $sqltargs->{sources};
1395
1396   my $tr = SQL::Translator->new(%$sqltargs);
1397   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1398   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1399
1400   return;
1401
1402 }
1403
1404 sub deploy {
1405   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1406   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1407     foreach my $line ( split(";\n", $statement)) {
1408       next if($line =~ /^--/);
1409       next if(!$line);
1410 #      next if($line =~ /^DROP/m);
1411       next if($line =~ /^BEGIN TRANSACTION/m);
1412       next if($line =~ /^COMMIT/m);
1413       next if $line =~ /^\s+$/; # skip whitespace only
1414       $self->debugobj->query_start($line) if $self->debug;
1415       eval {
1416         $self->dbh->do($line); # shouldn't be using ->dbh ?
1417       };
1418       if ($@) {
1419         warn qq{$@ (running "${line}")};
1420       }
1421       $self->debugobj->query_end($line) if $self->debug;
1422     }
1423   }
1424 }
1425
1426 =head2 datetime_parser
1427
1428 Returns the datetime parser class
1429
1430 =cut
1431
1432 sub datetime_parser {
1433   my $self = shift;
1434   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
1435 }
1436
1437 =head2 datetime_parser_type
1438
1439 Defines (returns) the datetime parser class - currently hardwired to
1440 L<DateTime::Format::MySQL>
1441
1442 =cut
1443
1444 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1445
1446 =head2 build_datetime_parser
1447
1448 See L</datetime_parser>
1449
1450 =cut
1451
1452 sub build_datetime_parser {
1453   my $self = shift;
1454   my $type = $self->datetime_parser_type(@_);
1455   eval "use ${type}";
1456   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1457   return $type;
1458 }
1459
1460 {
1461     my $_check_sqlt_version; # private
1462     my $_check_sqlt_message; # private
1463     sub _check_sqlt_version {
1464         return $_check_sqlt_version if defined $_check_sqlt_version;
1465         eval 'use SQL::Translator 0.08';
1466         $_check_sqlt_message = $@ ? $@ : '';
1467         $_check_sqlt_version = $@ ? 0 : 1;
1468     }
1469
1470     sub _check_sqlt_message {
1471         _check_sqlt_version if !defined $_check_sqlt_message;
1472         $_check_sqlt_message;
1473     }
1474 }
1475
1476 sub DESTROY {
1477   my $self = shift;
1478   return if !$self->_dbh;
1479   $self->_verify_pid;
1480   $self->_dbh(undef);
1481 }
1482
1483 1;
1484
1485 =head1 SQL METHODS
1486
1487 The module defines a set of methods within the DBIC::SQL::Abstract
1488 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1489 SQL query functions.
1490
1491 The following methods are extended:-
1492
1493 =over 4
1494
1495 =item delete
1496
1497 =item insert
1498
1499 =item select
1500
1501 =item update
1502
1503 =item limit_dialect
1504
1505 See L</connect_info> for details.
1506 For setting, this method is deprecated in favor of L</connect_info>.
1507
1508 =item quote_char
1509
1510 See L</connect_info> for details.
1511 For setting, this method is deprecated in favor of L</connect_info>.
1512
1513 =item name_sep
1514
1515 See L</connect_info> for details.
1516 For setting, this method is deprecated in favor of L</connect_info>.
1517
1518 =back
1519
1520 =head1 AUTHORS
1521
1522 Matt S. Trout <mst@shadowcatsystems.co.uk>
1523
1524 Andy Grundman <andy@hybridized.org>
1525
1526 =head1 LICENSE
1527
1528 You may distribute this code under the same terms as Perl itself.
1529
1530 =cut