lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use DBIx::Class::Exception;
  12 use Scalar::Util qw/refaddr weaken reftype blessed/;
  13 use List::Util qw/first/;
  14 use Sub::Name 'subname';
  15 use Context::Preserve 'preserve_context';
  16 use Try::Tiny;
  17 use overload ();
  18 use Data::Compare (); # no imports!!! guard against insane architecture
  19 use DBI::Const::GetInfoType (); # no import of retarded global hash
  20 use namespace::clean;
  21
  22 # default cursor class, overridable in connect_info attributes
  23 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  24
  25 __PACKAGE__->mk_group_accessors('inherited' => qw/
  26   sql_limit_dialect sql_quote_char sql_name_sep
  27 /);
  28
  29 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  30
  31 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  32 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  33
  34 __PACKAGE__->sql_name_sep('.');
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/
  37   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  38   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  39   _perform_autoinc_retrieval _autoinc_supplied_for_op
  40 /);
  41
  42 # the values for these accessors are picked out (and deleted) from
  43 # the attribute hashref passed to connect_info
  44 my @storage_options = qw/
  45   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  46   disable_sth_caching unsafe auto_savepoint
  47 /;
  48 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  49
  50
  51 # capability definitions, using a 2-tiered accessor system
  52 # The rationale is:
  53 #
  54 # A driver/user may define _use_X, which blindly without any checks says:
  55 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  56 # type accessor)
  57 #
  58 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  59 # accessor, which in turn calls _determine_supports_X, and stores the return
  60 # in a special slot on the storage object, which is wiped every time a $dbh
  61 # reconnection takes place (it is not guaranteed that upon reconnection we
  62 # will get the same rdbms version). _determine_supports_X does not need to
  63 # exist on a driver, as we ->can for it before calling.
  64
  65 my @capabilities = (qw/
  66   insert_returning
  67   insert_returning_bound
  68
  69   multicolumn_in
  70
  71   placeholders
  72   typeless_placeholders
  73
  74   join_optimizer
  75 /);
  76 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  77 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  78
  79 # on by default, not strictly a capability (pending rewrite)
  80 __PACKAGE__->_use_join_optimizer (1);
  81 sub _determine_supports_join_optimizer { 1 };
  82
  83 # Each of these methods need _determine_driver called before itself
  84 # in order to function reliably. This is a purely DRY optimization
  85 #
  86 # get_(use)_dbms_capability need to be called on the correct Storage
  87 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  88 # _determine_supports_X which obv. needs a correct driver as well
  89 my @rdbms_specific_methods = qw/
  90   deployment_statements
  91   sqlt_type
  92   sql_maker
  93   build_datetime_parser
  94   datetime_parser_type
  95
  96   txn_begin
  97   insert
  98   insert_bulk
  99   update
 100   delete
 101   select
 102   select_single
 103   with_deferred_fk_checks
 104
 105   get_use_dbms_capability
 106   get_dbms_capability
 107
 108   _server_info
 109   _get_server_version
 110 /;
 111
 112 for my $meth (@rdbms_specific_methods) {
 113
 114   my $orig = __PACKAGE__->can ($meth)
 115     or die "$meth is not a ::Storage::DBI method!";
 116
 117   no strict qw/refs/;
 118   no warnings qw/redefine/;
 119   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 120     if (
 121       # only fire when invoked on an instance, a valid class-based invocation
 122       # would e.g. be setting a default for an inherited accessor
 123       ref $_[0]
 124         and
 125       ! $_[0]->_driver_determined
 126         and
 127       ! $_[0]->{_in_determine_driver}
 128     ) {
 129       $_[0]->_determine_driver;
 130
 131       # This for some reason crashes and burns on perl 5.8.1
 132       # IFF the method ends up throwing an exception
 133       #goto $_[0]->can ($meth);
 134
 135       my $cref = $_[0]->can ($meth);
 136       goto $cref;
 137     }
 138
 139     goto $orig;
 140   };
 141 }
 142
 143 =head1 NAME
 144
 145 DBIx::Class::Storage::DBI - DBI storage handler
 146
 147 =head1 SYNOPSIS
 148
 149   my $schema = MySchema->connect('dbi:SQLite:my.db');
 150
 151   $schema->storage->debug(1);
 152
 153   my @stuff = $schema->storage->dbh_do(
 154     sub {
 155       my ($storage, $dbh, @args) = @_;
 156       $dbh->do("DROP TABLE authors");
 157     },
 158     @column_list
 159   );
 160
 161   $schema->resultset('Book')->search({
 162      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 163   });
 164
 165 =head1 DESCRIPTION
 166
 167 This class represents the connection to an RDBMS via L<DBI>.  See
 168 L<DBIx::Class::Storage> for general information.  This pod only
 169 documents DBI-specific methods and behaviors.
 170
 171 =head1 METHODS
 172
 173 =cut
 174
 175 sub new {
 176   my $new = shift->next::method(@_);
 177
 178   $new->_sql_maker_opts({});
 179   $new->_dbh_details({});
 180   $new->{_in_do_block} = 0;
 181   $new->{_dbh_gen} = 0;
 182
 183   # read below to see what this does
 184   $new->_arm_global_destructor;
 185
 186   $new;
 187 }
 188
 189 # This is hack to work around perl shooting stuff in random
 190 # order on exit(). If we do not walk the remaining storage
 191 # objects in an END block, there is a *small but real* chance
 192 # of a fork()ed child to kill the parent's shared DBI handle,
 193 # *before perl reaches the DESTROY in this package*
 194 # Yes, it is ugly and effective.
 195 # Additionally this registry is used by the CLONE method to
 196 # make sure no handles are shared between threads
 197 {
 198   my %seek_and_destroy;
 199
 200   sub _arm_global_destructor {
 201     weaken (
 202       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 203     );
 204   }
 205
 206   END {
 207     local $?; # just in case the DBI destructor changes it somehow
 208
 209     # destroy just the object if not native to this process
 210     $_->_verify_pid for (grep
 211       { defined $_ }
 212       values %seek_and_destroy
 213     );
 214   }
 215
 216   sub CLONE {
 217     # As per DBI's recommendation, DBIC disconnects all handles as
 218     # soon as possible (DBIC will reconnect only on demand from within
 219     # the thread)
 220     my @instances = grep { defined $_ } values %seek_and_destroy;
 221     for (@instances) {
 222       $_->{_dbh_gen}++;  # so that existing cursors will drop as well
 223       $_->_dbh(undef);
 224
 225       $_->transaction_depth(0);
 226       $_->savepoints([]);
 227     }
 228
 229     # properly renumber all existing refs
 230     %seek_and_destroy = ();
 231     $_->_arm_global_destructor for @instances;
 232   }
 233 }
 234
 235 sub DESTROY {
 236   my $self = shift;
 237
 238   # some databases spew warnings on implicit disconnect
 239   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 240   local $SIG{__WARN__} = sub {};
 241   $self->_dbh(undef);
 242
 243   # this op is necessary, since the very last perl runtime statement
 244   # triggers a global destruction shootout, and the $SIG localization
 245   # may very well be destroyed before perl actually gets to do the
 246   # $dbh undef
 247   1;
 248 }
 249
 250 # handle pid changes correctly - do not destroy parent's connection
 251 sub _verify_pid {
 252   my $self = shift;
 253
 254   my $pid = $self->_conn_pid;
 255   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 256     $dbh->{InactiveDestroy} = 1;
 257     $self->{_dbh_gen}++;
 258     $self->_dbh(undef);
 259     $self->transaction_depth(0);
 260     $self->savepoints([]);
 261   }
 262
 263   return;
 264 }
 265
 266 =head2 connect_info
 267
 268 This method is normally called by L<DBIx::Class::Schema/connection>, which
 269 encapsulates its argument list in an arrayref before passing them here.
 270
 271 The argument list may contain:
 272
 273 =over
 274
 275 =item *
 276
 277 The same 4-element argument set one would normally pass to
 278 L<DBI/connect>, optionally followed by
 279 L<extra attributes|/DBIx::Class specific connection attributes>
 280 recognized by DBIx::Class:
 281
 282   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 283
 284 =item *
 285
 286 A single code reference which returns a connected
 287 L<DBI database handle|DBI/connect> optionally followed by
 288 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 289 by DBIx::Class:
 290
 291   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 292
 293 =item *
 294
 295 A single hashref with all the attributes and the dsn/user/password
 296 mixed together:
 297
 298   $connect_info_args = [{
 299     dsn => $dsn,
 300     user => $user,
 301     password => $pass,
 302     %dbi_attributes,
 303     %extra_attributes,
 304   }];
 305
 306   $connect_info_args = [{
 307     dbh_maker => sub { DBI->connect (...) },
 308     %dbi_attributes,
 309     %extra_attributes,
 310   }];
 311
 312 This is particularly useful for L<Catalyst> based applications, allowing the
 313 following config (L<Config::General> style):
 314
 315   <Model::DB>
 316     schema_class   App::DB
 317     <connect_info>
 318       dsn          dbi:mysql:database=test
 319       user         testuser
 320       password     TestPass
 321       AutoCommit   1
 322     </connect_info>
 323   </Model::DB>
 324
 325 The C<dsn>/C<user>/C<password> combination can be substituted by the
 326 C<dbh_maker> key whose value is a coderef that returns a connected
 327 L<DBI database handle|DBI/connect>
 328
 329 =back
 330
 331 Please note that the L<DBI> docs recommend that you always explicitly
 332 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 333 recommends that it be set to I<1>, and that you perform transactions
 334 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 335 to I<1> if you do not do explicitly set it to zero.  This is the default
 336 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 337
 338 =head3 DBIx::Class specific connection attributes
 339
 340 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 341 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 342 the following connection options. These options can be mixed in with your other
 343 L<DBI> connection attributes, or placed in a separate hashref
 344 (C<\%extra_attributes>) as shown above.
 345
 346 Every time C<connect_info> is invoked, any previous settings for
 347 these options will be cleared before setting the new ones, regardless of
 348 whether any options are specified in the new C<connect_info>.
 349
 350
 351 =over
 352
 353 =item on_connect_do
 354
 355 Specifies things to do immediately after connecting or re-connecting to
 356 the database.  Its value may contain:
 357
 358 =over
 359
 360 =item a scalar
 361
 362 This contains one SQL statement to execute.
 363
 364 =item an array reference
 365
 366 This contains SQL statements to execute in order.  Each element contains
 367 a string or a code reference that returns a string.
 368
 369 =item a code reference
 370
 371 This contains some code to execute.  Unlike code references within an
 372 array reference, its return value is ignored.
 373
 374 =back
 375
 376 =item on_disconnect_do
 377
 378 Takes arguments in the same form as L</on_connect_do> and executes them
 379 immediately before disconnecting from the database.
 380
 381 Note, this only runs if you explicitly call L</disconnect> on the
 382 storage object.
 383
 384 =item on_connect_call
 385
 386 A more generalized form of L</on_connect_do> that calls the specified
 387 C<connect_call_METHOD> methods in your storage driver.
 388
 389   on_connect_do => 'select 1'
 390
 391 is equivalent to:
 392
 393   on_connect_call => [ [ do_sql => 'select 1' ] ]
 394
 395 Its values may contain:
 396
 397 =over
 398
 399 =item a scalar
 400
 401 Will call the C<connect_call_METHOD> method.
 402
 403 =item a code reference
 404
 405 Will execute C<< $code->($storage) >>
 406
 407 =item an array reference
 408
 409 Each value can be a method name or code reference.
 410
 411 =item an array of arrays
 412
 413 For each array, the first item is taken to be the C<connect_call_> method name
 414 or code reference, and the rest are parameters to it.
 415
 416 =back
 417
 418 Some predefined storage methods you may use:
 419
 420 =over
 421
 422 =item do_sql
 423
 424 Executes a SQL string or a code reference that returns a SQL string. This is
 425 what L</on_connect_do> and L</on_disconnect_do> use.
 426
 427 It can take:
 428
 429 =over
 430
 431 =item a scalar
 432
 433 Will execute the scalar as SQL.
 434
 435 =item an arrayref
 436
 437 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 438 attributes hashref and bind values.
 439
 440 =item a code reference
 441
 442 Will execute C<< $code->($storage) >> and execute the return array refs as
 443 above.
 444
 445 =back
 446
 447 =item datetime_setup
 448
 449 Execute any statements necessary to initialize the database session to return
 450 and accept datetime/timestamp values used with
 451 L<DBIx::Class::InflateColumn::DateTime>.
 452
 453 Only necessary for some databases, see your specific storage driver for
 454 implementation details.
 455
 456 =back
 457
 458 =item on_disconnect_call
 459
 460 Takes arguments in the same form as L</on_connect_call> and executes them
 461 immediately before disconnecting from the database.
 462
 463 Calls the C<disconnect_call_METHOD> methods as opposed to the
 464 C<connect_call_METHOD> methods called by L</on_connect_call>.
 465
 466 Note, this only runs if you explicitly call L</disconnect> on the
 467 storage object.
 468
 469 =item disable_sth_caching
 470
 471 If set to a true value, this option will disable the caching of
 472 statement handles via L<DBI/prepare_cached>.
 473
 474 =item limit_dialect
 475
 476 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 477 default L</sql_limit_dialect> setting of the storage (if any). For a list
 478 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 479
 480 =item quote_names
 481
 482 When true automatically sets L</quote_char> and L</name_sep> to the characters
 483 appropriate for your particular RDBMS. This option is preferred over specifying
 484 L</quote_char> directly.
 485
 486 =item quote_char
 487
 488 Specifies what characters to use to quote table and column names.
 489
 490 C<quote_char> expects either a single character, in which case is it
 491 is placed on either side of the table/column name, or an arrayref of length
 492 2 in which case the table/column name is placed between the elements.
 493
 494 For example under MySQL you should use C<< quote_char => '`' >>, and for
 495 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 496
 497 =item name_sep
 498
 499 This parameter is only useful in conjunction with C<quote_char>, and is used to
 500 specify the character that separates elements (schemas, tables, columns) from
 501 each other. If unspecified it defaults to the most commonly used C<.>.
 502
 503 =item unsafe
 504
 505 This Storage driver normally installs its own C<HandleError>, sets
 506 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 507 all database handles, including those supplied by a coderef.  It does this
 508 so that it can have consistent and useful error behavior.
 509
 510 If you set this option to a true value, Storage will not do its usual
 511 modifications to the database handle's attributes, and instead relies on
 512 the settings in your connect_info DBI options (or the values you set in
 513 your connection coderef, in the case that you are connecting via coderef).
 514
 515 Note that your custom settings can cause Storage to malfunction,
 516 especially if you set a C<HandleError> handler that suppresses exceptions
 517 and/or disable C<RaiseError>.
 518
 519 =item auto_savepoint
 520
 521 If this option is true, L<DBIx::Class> will use savepoints when nesting
 522 transactions, making it possible to recover from failure in the inner
 523 transaction without having to abort all outer transactions.
 524
 525 =item cursor_class
 526
 527 Use this argument to supply a cursor class other than the default
 528 L<DBIx::Class::Storage::DBI::Cursor>.
 529
 530 =back
 531
 532 Some real-life examples of arguments to L</connect_info> and
 533 L<DBIx::Class::Schema/connect>
 534
 535   # Simple SQLite connection
 536   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 537
 538   # Connect via subref
 539   ->connect_info([ sub { DBI->connect(...) } ]);
 540
 541   # Connect via subref in hashref
 542   ->connect_info([{
 543     dbh_maker => sub { DBI->connect(...) },
 544     on_connect_do => 'alter session ...',
 545   }]);
 546
 547   # A bit more complicated
 548   ->connect_info(
 549     [
 550       'dbi:Pg:dbname=foo',
 551       'postgres',
 552       'my_pg_password',
 553       { AutoCommit => 1 },
 554       { quote_char => q{"} },
 555     ]
 556   );
 557
 558   # Equivalent to the previous example
 559   ->connect_info(
 560     [
 561       'dbi:Pg:dbname=foo',
 562       'postgres',
 563       'my_pg_password',
 564       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 565     ]
 566   );
 567
 568   # Same, but with hashref as argument
 569   # See parse_connect_info for explanation
 570   ->connect_info(
 571     [{
 572       dsn         => 'dbi:Pg:dbname=foo',
 573       user        => 'postgres',
 574       password    => 'my_pg_password',
 575       AutoCommit  => 1,
 576       quote_char  => q{"},
 577       name_sep    => q{.},
 578     }]
 579   );
 580
 581   # Subref + DBIx::Class-specific connection options
 582   ->connect_info(
 583     [
 584       sub { DBI->connect(...) },
 585       {
 586           quote_char => q{`},
 587           name_sep => q{@},
 588           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 589           disable_sth_caching => 1,
 590       },
 591     ]
 592   );
 593
 594
 595
 596 =cut
 597
 598 sub connect_info {
 599   my ($self, $info) = @_;
 600
 601   return $self->_connect_info if !$info;
 602
 603   $self->_connect_info($info); # copy for _connect_info
 604
 605   $info = $self->_normalize_connect_info($info)
 606     if ref $info eq 'ARRAY';
 607
 608   for my $storage_opt (keys %{ $info->{storage_options} }) {
 609     my $value = $info->{storage_options}{$storage_opt};
 610
 611     $self->$storage_opt($value);
 612   }
 613
 614   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 615   #  the new set of options
 616   $self->_sql_maker(undef);
 617   $self->_sql_maker_opts({});
 618
 619   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 620     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 621
 622     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 623   }
 624
 625   my %attrs = (
 626     %{ $self->_default_dbi_connect_attributes || {} },
 627     %{ $info->{attributes} || {} },
 628   );
 629
 630   my @args = @{ $info->{arguments} };
 631
 632   if (keys %attrs and ref $args[0] ne 'CODE') {
 633     carp
 634         'You provided explicit AutoCommit => 0 in your connection_info. '
 635       . 'This is almost universally a bad idea (see the footnotes of '
 636       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 637       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 638       . 'this warning.'
 639       if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 640
 641     push @args, \%attrs if keys %attrs;
 642   }
 643   $self->_dbi_connect_info(\@args);
 644
 645   # FIXME - dirty:
 646   # save attributes them in a separate accessor so they are always
 647   # introspectable, even in case of a CODE $dbhmaker
 648   $self->_dbic_connect_attributes (\%attrs);
 649
 650   return $self->_connect_info;
 651 }
 652
 653 sub _normalize_connect_info {
 654   my ($self, $info_arg) = @_;
 655   my %info;
 656
 657   my @args = @$info_arg;  # take a shallow copy for further mutilation
 658
 659   # combine/pre-parse arguments depending on invocation style
 660
 661   my %attrs;
 662   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 663     %attrs = %{ $args[1] || {} };
 664     @args = $args[0];
 665   }
 666   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 667     %attrs = %{$args[0]};
 668     @args = ();
 669     if (my $code = delete $attrs{dbh_maker}) {
 670       @args = $code;
 671
 672       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 673       if (@ignored) {
 674         carp sprintf (
 675             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 676           . "to the result of 'dbh_maker'",
 677
 678           join (', ', map { "'$_'" } (@ignored) ),
 679         );
 680       }
 681     }
 682     else {
 683       @args = delete @attrs{qw/dsn user password/};
 684     }
 685   }
 686   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 687     %attrs = (
 688       % { $args[3] || {} },
 689       % { $args[4] || {} },
 690     );
 691     @args = @args[0,1,2];
 692   }
 693
 694   $info{arguments} = \@args;
 695
 696   my @storage_opts = grep exists $attrs{$_},
 697     @storage_options, 'cursor_class';
 698
 699   @{ $info{storage_options} }{@storage_opts} =
 700     delete @attrs{@storage_opts} if @storage_opts;
 701
 702   my @sql_maker_opts = grep exists $attrs{$_},
 703     qw/limit_dialect quote_char name_sep quote_names/;
 704
 705   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 706     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 707
 708   $info{attributes} = \%attrs if %attrs;
 709
 710   return \%info;
 711 }
 712
 713 sub _default_dbi_connect_attributes () {
 714   +{
 715     AutoCommit => 1,
 716     PrintError => 0,
 717     RaiseError => 1,
 718     ShowErrorStatement => 1,
 719   };
 720 }
 721
 722 =head2 on_connect_do
 723
 724 This method is deprecated in favour of setting via L</connect_info>.
 725
 726 =cut
 727
 728 =head2 on_disconnect_do
 729
 730 This method is deprecated in favour of setting via L</connect_info>.
 731
 732 =cut
 733
 734 sub _parse_connect_do {
 735   my ($self, $type) = @_;
 736
 737   my $val = $self->$type;
 738   return () if not defined $val;
 739
 740   my @res;
 741
 742   if (not ref($val)) {
 743     push @res, [ 'do_sql', $val ];
 744   } elsif (ref($val) eq 'CODE') {
 745     push @res, $val;
 746   } elsif (ref($val) eq 'ARRAY') {
 747     push @res, map { [ 'do_sql', $_ ] } @$val;
 748   } else {
 749     $self->throw_exception("Invalid type for $type: ".ref($val));
 750   }
 751
 752   return \@res;
 753 }
 754
 755 =head2 dbh_do
 756
 757 Arguments: ($subref | $method_name), @extra_coderef_args?
 758
 759 Execute the given $subref or $method_name using the new exception-based
 760 connection management.
 761
 762 The first two arguments will be the storage object that C<dbh_do> was called
 763 on and a database handle to use.  Any additional arguments will be passed
 764 verbatim to the called subref as arguments 2 and onwards.
 765
 766 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 767 exception handling and reconnection (or failover in future subclasses).
 768
 769 Your subref should have no side-effects outside of the database, as
 770 there is the potential for your subref to be partially double-executed
 771 if the database connection was stale/dysfunctional.
 772
 773 Example:
 774
 775   my @stuff = $schema->storage->dbh_do(
 776     sub {
 777       my ($storage, $dbh, @cols) = @_;
 778       my $cols = join(q{, }, @cols);
 779       $dbh->selectrow_array("SELECT $cols FROM foo");
 780     },
 781     @column_list
 782   );
 783
 784 =cut
 785
 786 sub dbh_do {
 787   my $self = shift;
 788   my $run_target = shift;
 789
 790   # short circuit when we know there is no need for a runner
 791   #
 792   # FIXME - asumption may be wrong
 793   # the rationale for the txn_depth check is that if this block is a part
 794   # of a larger transaction, everything up to that point is screwed anyway
 795   return $self->$run_target($self->_get_dbh, @_)
 796     if $self->{_in_do_block} or $self->transaction_depth;
 797
 798   my $args = \@_;
 799
 800   DBIx::Class::Storage::BlockRunner->new(
 801     storage => $self,
 802     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 803     wrap_txn => 0,
 804     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 805   )->run;
 806 }
 807
 808 sub txn_do {
 809   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 810   shift->next::method(@_);
 811 }
 812
 813 =head2 disconnect
 814
 815 Our C<disconnect> method also performs a rollback first if the
 816 database is not in C<AutoCommit> mode.
 817
 818 =cut
 819
 820 sub disconnect {
 821   my ($self) = @_;
 822
 823   if( $self->_dbh ) {
 824     my @actions;
 825
 826     push @actions, ( $self->on_disconnect_call || () );
 827     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 828
 829     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 830
 831     # stops the "implicit rollback on disconnect" warning
 832     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 833
 834     %{ $self->_dbh->{CachedKids} } = ();
 835     $self->_dbh->disconnect;
 836     $self->_dbh(undef);
 837     $self->{_dbh_gen}++;
 838   }
 839 }
 840
 841 =head2 with_deferred_fk_checks
 842
 843 =over 4
 844
 845 =item Arguments: C<$coderef>
 846
 847 =item Return Value: The return value of $coderef
 848
 849 =back
 850
 851 Storage specific method to run the code ref with FK checks deferred or
 852 in MySQL's case disabled entirely.
 853
 854 =cut
 855
 856 # Storage subclasses should override this
 857 sub with_deferred_fk_checks {
 858   my ($self, $sub) = @_;
 859   $sub->();
 860 }
 861
 862 =head2 connected
 863
 864 =over
 865
 866 =item Arguments: none
 867
 868 =item Return Value: 1|0
 869
 870 =back
 871
 872 Verifies that the current database handle is active and ready to execute
 873 an SQL statement (e.g. the connection did not get stale, server is still
 874 answering, etc.) This method is used internally by L</dbh>.
 875
 876 =cut
 877
 878 sub connected {
 879   my $self = shift;
 880   return 0 unless $self->_seems_connected;
 881
 882   #be on the safe side
 883   local $self->_dbh->{RaiseError} = 1;
 884
 885   return $self->_ping;
 886 }
 887
 888 sub _seems_connected {
 889   my $self = shift;
 890
 891   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 892
 893   my $dbh = $self->_dbh
 894     or return 0;
 895
 896   return $dbh->FETCH('Active');
 897 }
 898
 899 sub _ping {
 900   my $self = shift;
 901
 902   my $dbh = $self->_dbh or return 0;
 903
 904   return $dbh->ping;
 905 }
 906
 907 sub ensure_connected {
 908   my ($self) = @_;
 909
 910   unless ($self->connected) {
 911     $self->_populate_dbh;
 912   }
 913 }
 914
 915 =head2 dbh
 916
 917 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 918 is guaranteed to be healthy by implicitly calling L</connected>, and if
 919 necessary performing a reconnection before returning. Keep in mind that this
 920 is very B<expensive> on some database engines. Consider using L</dbh_do>
 921 instead.
 922
 923 =cut
 924
 925 sub dbh {
 926   my ($self) = @_;
 927
 928   if (not $self->_dbh) {
 929     $self->_populate_dbh;
 930   } else {
 931     $self->ensure_connected;
 932   }
 933   return $self->_dbh;
 934 }
 935
 936 # this is the internal "get dbh or connect (don't check)" method
 937 sub _get_dbh {
 938   my $self = shift;
 939   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 940   $self->_populate_dbh unless $self->_dbh;
 941   return $self->_dbh;
 942 }
 943
 944 sub sql_maker {
 945   my ($self) = @_;
 946   unless ($self->_sql_maker) {
 947     my $sql_maker_class = $self->sql_maker_class;
 948
 949     my %opts = %{$self->_sql_maker_opts||{}};
 950     my $dialect =
 951       $opts{limit_dialect}
 952         ||
 953       $self->sql_limit_dialect
 954         ||
 955       do {
 956         my $s_class = (ref $self) || $self;
 957         carp (
 958           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 959         . 'have not supplied an explicit limit_dialect in your connection_info. '
 960         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 961         . 'databases but can be (and often is) painfully slow. '
 962         . "Please file an RT ticket against '$s_class' ."
 963         );
 964
 965         'GenericSubQ';
 966       }
 967     ;
 968
 969     my ($quote_char, $name_sep);
 970
 971     if ($opts{quote_names}) {
 972       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 973         my $s_class = (ref $self) || $self;
 974         carp (
 975           "You requested 'quote_names' but your storage class ($s_class) does "
 976         . 'not explicitly define a default sql_quote_char and you have not '
 977         . 'supplied a quote_char as part of your connection_info. DBIC will '
 978         .q{default to the ANSI SQL standard quote '"', which works most of }
 979         . "the time. Please file an RT ticket against '$s_class'."
 980         );
 981
 982         '"'; # RV
 983       };
 984
 985       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 986     }
 987
 988     $self->_sql_maker($sql_maker_class->new(
 989       bindtype => 'columns',
 990       array_datatypes => 1,
 991       limit_dialect => $dialect,
 992       ($quote_char ? (quote_char => $quote_char) : ()),
 993       name_sep => ($name_sep || '.'),
 994       storage => $self,
 995       %opts,
 996     ));
 997
 998     weaken($self->_sql_maker->{storage});
 999   }
1000
1001   return $self->_sql_maker;
1002 }
1003
1004 # nothing to do by default
1005 sub _rebless {}
1006 sub _init {}
1007
1008 sub _populate_dbh {
1009   my ($self) = @_;
1010
1011   my @info = @{$self->_dbi_connect_info || []};
1012   $self->_dbh(undef); # in case ->connected failed we might get sent here
1013   $self->_dbh_details({}); # reset everything we know
1014
1015   $self->_dbh($self->_connect(@info));
1016
1017   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1018
1019   $self->_determine_driver;
1020
1021   # Always set the transaction depth on connect, since
1022   #  there is no transaction in progress by definition
1023   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1024
1025   $self->_run_connection_actions unless $self->{_in_determine_driver};
1026 }
1027
1028 sub _run_connection_actions {
1029   my $self = shift;
1030   my @actions;
1031
1032   push @actions, ( $self->on_connect_call || () );
1033   push @actions, $self->_parse_connect_do ('on_connect_do');
1034
1035   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1036 }
1037
1038
1039
1040 sub set_use_dbms_capability {
1041   $_[0]->set_inherited ($_[1], $_[2]);
1042 }
1043
1044 sub get_use_dbms_capability {
1045   my ($self, $capname) = @_;
1046
1047   my $use = $self->get_inherited ($capname);
1048   return defined $use
1049     ? $use
1050     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1051   ;
1052 }
1053
1054 sub set_dbms_capability {
1055   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1056 }
1057
1058 sub get_dbms_capability {
1059   my ($self, $capname) = @_;
1060
1061   my $cap = $self->_dbh_details->{capability}{$capname};
1062
1063   unless (defined $cap) {
1064     if (my $meth = $self->can ("_determine$capname")) {
1065       $cap = $self->$meth ? 1 : 0;
1066     }
1067     else {
1068       $cap = 0;
1069     }
1070
1071     $self->set_dbms_capability ($capname, $cap);
1072   }
1073
1074   return $cap;
1075 }
1076
1077 sub _server_info {
1078   my $self = shift;
1079
1080   my $info;
1081   unless ($info = $self->_dbh_details->{info}) {
1082
1083     $info = {};
1084
1085     my $server_version = try {
1086       $self->_get_server_version
1087     } catch {
1088       # driver determination *may* use this codepath
1089       # in which case we must rethrow
1090       $self->throw_exception($_) if $self->{_in_determine_driver};
1091
1092       # $server_version on failure
1093       undef;
1094     };
1095
1096     if (defined $server_version) {
1097       $info->{dbms_version} = $server_version;
1098
1099       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1100       my @verparts = split (/\./, $numeric_version);
1101       if (
1102         @verparts
1103           &&
1104         $verparts[0] <= 999
1105       ) {
1106         # consider only up to 3 version parts, iff not more than 3 digits
1107         my @use_parts;
1108         while (@verparts && @use_parts < 3) {
1109           my $p = shift @verparts;
1110           last if $p > 999;
1111           push @use_parts, $p;
1112         }
1113         push @use_parts, 0 while @use_parts < 3;
1114
1115         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1116       }
1117     }
1118
1119     $self->_dbh_details->{info} = $info;
1120   }
1121
1122   return $info;
1123 }
1124
1125 sub _get_server_version {
1126   shift->_dbh_get_info('SQL_DBMS_VER');
1127 }
1128
1129 sub _dbh_get_info {
1130   my ($self, $info) = @_;
1131
1132   if ($info =~ /[^0-9]/) {
1133     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1134     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1135       unless defined $info;
1136   }
1137
1138   return $self->_get_dbh->get_info($info);
1139 }
1140
1141 sub _describe_connection {
1142   require DBI::Const::GetInfoReturn;
1143
1144   my $self = shift;
1145   $self->ensure_connected;
1146
1147   my $res = {
1148     DBIC_DSN => $self->_dbi_connect_info->[0],
1149     DBI_VER => DBI->VERSION,
1150     DBIC_VER => DBIx::Class->VERSION,
1151     DBIC_DRIVER => ref $self,
1152   };
1153
1154   for my $inf (
1155     #keys %DBI::Const::GetInfoType::GetInfoType,
1156     qw/
1157       SQL_CURSOR_COMMIT_BEHAVIOR
1158       SQL_CURSOR_ROLLBACK_BEHAVIOR
1159       SQL_CURSOR_SENSITIVITY
1160       SQL_DATA_SOURCE_NAME
1161       SQL_DBMS_NAME
1162       SQL_DBMS_VER
1163       SQL_DEFAULT_TXN_ISOLATION
1164       SQL_DM_VER
1165       SQL_DRIVER_NAME
1166       SQL_DRIVER_ODBC_VER
1167       SQL_DRIVER_VER
1168       SQL_EXPRESSIONS_IN_ORDERBY
1169       SQL_GROUP_BY
1170       SQL_IDENTIFIER_CASE
1171       SQL_IDENTIFIER_QUOTE_CHAR
1172       SQL_MAX_CATALOG_NAME_LEN
1173       SQL_MAX_COLUMN_NAME_LEN
1174       SQL_MAX_IDENTIFIER_LEN
1175       SQL_MAX_TABLE_NAME_LEN
1176       SQL_MULTIPLE_ACTIVE_TXN
1177       SQL_MULT_RESULT_SETS
1178       SQL_NEED_LONG_DATA_LEN
1179       SQL_NON_NULLABLE_COLUMNS
1180       SQL_ODBC_VER
1181       SQL_QUALIFIER_NAME_SEPARATOR
1182       SQL_QUOTED_IDENTIFIER_CASE
1183       SQL_TXN_CAPABLE
1184       SQL_TXN_ISOLATION_OPTION
1185     /
1186   ) {
1187     my $v = $self->_dbh_get_info($inf);
1188     next unless defined $v;
1189
1190     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1191     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1192     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1193   }
1194
1195   $res;
1196 }
1197
1198 sub _determine_driver {
1199   my ($self) = @_;
1200
1201   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1202     my $started_connected = 0;
1203     local $self->{_in_determine_driver} = 1;
1204
1205     if (ref($self) eq __PACKAGE__) {
1206       my $driver;
1207       if ($self->_dbh) { # we are connected
1208         $driver = $self->_dbh->{Driver}{Name};
1209         $started_connected = 1;
1210       }
1211       else {
1212         # if connect_info is a CODEREF, we have no choice but to connect
1213         if (ref $self->_dbi_connect_info->[0] &&
1214             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1215           $self->_populate_dbh;
1216           $driver = $self->_dbh->{Driver}{Name};
1217         }
1218         else {
1219           # try to use dsn to not require being connected, the driver may still
1220           # force a connection in _rebless to determine version
1221           # (dsn may not be supplied at all if all we do is make a mock-schema)
1222           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1223           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1224           $driver ||= $ENV{DBI_DRIVER};
1225         }
1226       }
1227
1228       if ($driver) {
1229         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1230         if ($self->load_optional_class($storage_class)) {
1231           mro::set_mro($storage_class, 'c3');
1232           bless $self, $storage_class;
1233           $self->_rebless();
1234         }
1235         else {
1236           $self->_warn_undetermined_driver(
1237             'This version of DBIC does not yet seem to supply a driver for '
1238           . "your particular RDBMS and/or connection method ('$driver')."
1239           );
1240         }
1241       }
1242       else {
1243         $self->_warn_undetermined_driver(
1244           'Unable to extract a driver name from connect info - this '
1245         . 'should not have happened.'
1246         );
1247       }
1248     }
1249
1250     $self->_driver_determined(1);
1251
1252     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1253
1254     $self->_init; # run driver-specific initializations
1255
1256     $self->_run_connection_actions
1257         if !$started_connected && defined $self->_dbh;
1258   }
1259 }
1260
1261 sub _determine_connector_driver {
1262   my ($self, $conn) = @_;
1263
1264   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1265
1266   if (not $dbtype) {
1267     $self->_warn_undetermined_driver(
1268       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1269     . "$conn connector - this should not have happened."
1270     );
1271     return;
1272   }
1273
1274   $dbtype =~ s/\W/_/gi;
1275
1276   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1277   return if $self->isa($subclass);
1278
1279   if ($self->load_optional_class($subclass)) {
1280     bless $self, $subclass;
1281     $self->_rebless;
1282   }
1283   else {
1284     $self->_warn_undetermined_driver(
1285       'This version of DBIC does not yet seem to supply a driver for '
1286     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1287     );
1288   }
1289 }
1290
1291 sub _warn_undetermined_driver {
1292   my ($self, $msg) = @_;
1293
1294   require Data::Dumper::Concise;
1295
1296   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1297   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1298   . "does not go away, file a bugreport including the following info:\n"
1299   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1300   );
1301 }
1302
1303 sub _do_connection_actions {
1304   my $self          = shift;
1305   my $method_prefix = shift;
1306   my $call          = shift;
1307
1308   if (not ref($call)) {
1309     my $method = $method_prefix . $call;
1310     $self->$method(@_);
1311   } elsif (ref($call) eq 'CODE') {
1312     $self->$call(@_);
1313   } elsif (ref($call) eq 'ARRAY') {
1314     if (ref($call->[0]) ne 'ARRAY') {
1315       $self->_do_connection_actions($method_prefix, $_) for @$call;
1316     } else {
1317       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1318     }
1319   } else {
1320     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1321   }
1322
1323   return $self;
1324 }
1325
1326 sub connect_call_do_sql {
1327   my $self = shift;
1328   $self->_do_query(@_);
1329 }
1330
1331 sub disconnect_call_do_sql {
1332   my $self = shift;
1333   $self->_do_query(@_);
1334 }
1335
1336 # override in db-specific backend when necessary
1337 sub connect_call_datetime_setup { 1 }
1338
1339 sub _do_query {
1340   my ($self, $action) = @_;
1341
1342   if (ref $action eq 'CODE') {
1343     $action = $action->($self);
1344     $self->_do_query($_) foreach @$action;
1345   }
1346   else {
1347     # Most debuggers expect ($sql, @bind), so we need to exclude
1348     # the attribute hash which is the second argument to $dbh->do
1349     # furthermore the bind values are usually to be presented
1350     # as named arrayref pairs, so wrap those here too
1351     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1352     my $sql = shift @do_args;
1353     my $attrs = shift @do_args;
1354     my @bind = map { [ undef, $_ ] } @do_args;
1355
1356     $self->dbh_do(sub {
1357       $_[0]->_query_start($sql, \@bind);
1358       $_[1]->do($sql, $attrs, @do_args);
1359       $_[0]->_query_end($sql, \@bind);
1360     });
1361   }
1362
1363   return $self;
1364 }
1365
1366 sub _connect {
1367   my ($self, @info) = @_;
1368
1369   $self->throw_exception("You failed to provide any connection info")
1370     if !@info;
1371
1372   my ($old_connect_via, $dbh);
1373
1374   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1375
1376   try {
1377     if(ref $info[0] eq 'CODE') {
1378       $dbh = $info[0]->();
1379     }
1380     else {
1381       require DBI;
1382       $dbh = DBI->connect(@info);
1383     }
1384
1385     if (!$dbh) {
1386       die $DBI::errstr;
1387     }
1388
1389     unless ($self->unsafe) {
1390
1391       $self->throw_exception(
1392         'Refusing clobbering of {HandleError} installed on externally supplied '
1393        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1394       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1395
1396       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1397       # request, or an external handle. Complain and set anyway
1398       unless ($dbh->{RaiseError}) {
1399         carp( ref $info[0] eq 'CODE'
1400
1401           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1402            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1403            .'attribute has been supplied'
1404
1405           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1406            .'unsafe => 1. Toggling RaiseError back to true'
1407         );
1408
1409         $dbh->{RaiseError} = 1;
1410       }
1411
1412       # this odd anonymous coderef dereference is in fact really
1413       # necessary to avoid the unwanted effect described in perl5
1414       # RT#75792
1415       sub {
1416         my $weak_self = $_[0];
1417         weaken $weak_self;
1418
1419         # the coderef is blessed so we can distinguish it from externally
1420         # supplied handles (which must be preserved)
1421         $_[1]->{HandleError} = bless sub {
1422           if ($weak_self) {
1423             $weak_self->throw_exception("DBI Exception: $_[0]");
1424           }
1425           else {
1426             # the handler may be invoked by something totally out of
1427             # the scope of DBIC
1428             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1429           }
1430         }, '__DBIC__DBH__ERROR__HANDLER__';
1431       }->($self, $dbh);
1432     }
1433   }
1434   catch {
1435     $self->throw_exception("DBI Connection failed: $_")
1436   };
1437
1438   $self->_dbh_autocommit($dbh->{AutoCommit});
1439   $dbh;
1440 }
1441
1442 sub txn_begin {
1443   my $self = shift;
1444
1445   # this means we have not yet connected and do not know the AC status
1446   # (e.g. coderef $dbh), need a full-fledged connection check
1447   if (! defined $self->_dbh_autocommit) {
1448     $self->ensure_connected;
1449   }
1450   # Otherwise simply connect or re-connect on pid changes
1451   else {
1452     $self->_get_dbh;
1453   }
1454
1455   $self->next::method(@_);
1456 }
1457
1458 sub _exec_txn_begin {
1459   my $self = shift;
1460
1461   # if the user is utilizing txn_do - good for him, otherwise we need to
1462   # ensure that the $dbh is healthy on BEGIN.
1463   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1464   # will be replaced by a failure of begin_work itself (which will be
1465   # then retried on reconnect)
1466   if ($self->{_in_do_block}) {
1467     $self->_dbh->begin_work;
1468   } else {
1469     $self->dbh_do(sub { $_[1]->begin_work });
1470   }
1471 }
1472
1473 sub txn_commit {
1474   my $self = shift;
1475
1476   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1477   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1478     unless $self->_dbh;
1479
1480   # esoteric case for folks using external $dbh handles
1481   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1482     carp "Storage transaction_depth 0 does not match "
1483         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1484     $self->transaction_depth(1);
1485   }
1486
1487   $self->next::method(@_);
1488
1489   # if AutoCommit is disabled txn_depth never goes to 0
1490   # as a new txn is started immediately on commit
1491   $self->transaction_depth(1) if (
1492     !$self->transaction_depth
1493       and
1494     defined $self->_dbh_autocommit
1495       and
1496     ! $self->_dbh_autocommit
1497   );
1498 }
1499
1500 sub _exec_txn_commit {
1501   shift->_dbh->commit;
1502 }
1503
1504 sub txn_rollback {
1505   my $self = shift;
1506
1507   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1508   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1509     unless $self->_dbh;
1510
1511   # esoteric case for folks using external $dbh handles
1512   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1513     carp "Storage transaction_depth 0 does not match "
1514         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1515     $self->transaction_depth(1);
1516   }
1517
1518   $self->next::method(@_);
1519
1520   # if AutoCommit is disabled txn_depth never goes to 0
1521   # as a new txn is started immediately on commit
1522   $self->transaction_depth(1) if (
1523     !$self->transaction_depth
1524       and
1525     defined $self->_dbh_autocommit
1526       and
1527     ! $self->_dbh_autocommit
1528   );
1529 }
1530
1531 sub _exec_txn_rollback {
1532   shift->_dbh->rollback;
1533 }
1534
1535 # generate some identical methods
1536 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1537   no strict qw/refs/;
1538   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1539     my $self = shift;
1540     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1541     $self->throw_exception("Unable to $meth() on a disconnected storage")
1542       unless $self->_dbh;
1543     $self->next::method(@_);
1544   };
1545 }
1546
1547 # This used to be the top-half of _execute.  It was split out to make it
1548 #  easier to override in NoBindVars without duping the rest.  It takes up
1549 #  all of _execute's args, and emits $sql, @bind.
1550 sub _prep_for_execute {
1551   #my ($self, $op, $ident, $args) = @_;
1552   return shift->_gen_sql_bind(@_)
1553 }
1554
1555 sub _gen_sql_bind {
1556   my ($self, $op, $ident, $args) = @_;
1557
1558   my ($sql, @bind) = $self->sql_maker->$op(
1559     blessed($ident) ? $ident->from : $ident,
1560     @$args,
1561   );
1562
1563   if (
1564     ! $ENV{DBIC_DT_SEARCH_OK}
1565       and
1566     $op eq 'select'
1567       and
1568     first { blessed($_->[1]) && $_->[1]->isa('DateTime') } @bind
1569   ) {
1570     carp_unique 'DateTime objects passed to search() are not supported '
1571       . 'properly (InflateColumn::DateTime formats and settings are not '
1572       . 'respected.) See "Formatting DateTime objects in queries" in '
1573       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1574       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1575   }
1576
1577   return( $sql, $self->_resolve_bindattrs(
1578     $ident, [ @{$args->[2]{bind}||[]}, @bind ]
1579   ));
1580 }
1581
1582 sub _resolve_bindattrs {
1583   my ($self, $ident, $bind, $colinfos) = @_;
1584
1585   $colinfos ||= {};
1586
1587   my $resolve_bindinfo = sub {
1588     #my $infohash = shift;
1589
1590     %$colinfos = %{ $self->_resolve_column_info($ident) }
1591       unless keys %$colinfos;
1592
1593     my $ret;
1594     if (my $col = $_[0]->{dbic_colname}) {
1595       $ret = { %{$_[0]} };
1596
1597       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1598         if $colinfos->{$col}{data_type};
1599
1600       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1601         if $colinfos->{$col}{size};
1602     }
1603
1604     $ret || $_[0];
1605   };
1606
1607   return [ map {
1608     if (ref $_ ne 'ARRAY') {
1609       [{}, $_]
1610     }
1611     elsif (! defined $_->[0]) {
1612       [{}, $_->[1]]
1613     }
1614     elsif (ref $_->[0] eq 'HASH') {
1615       [
1616         ($_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype}) ? $_->[0] : $resolve_bindinfo->($_->[0]),
1617         $_->[1]
1618       ]
1619     }
1620     elsif (ref $_->[0] eq 'SCALAR') {
1621       [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1622     }
1623     else {
1624       [ $resolve_bindinfo->({ dbic_colname => $_->[0] }), $_->[1] ]
1625     }
1626   } @$bind ];
1627 }
1628
1629 sub _format_for_trace {
1630   #my ($self, $bind) = @_;
1631
1632   ### Turn @bind from something like this:
1633   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1634   ### to this:
1635   ###   ( "'1'", "'3'" )
1636
1637   map {
1638     defined( $_ && $_->[1] )
1639       ? qq{'$_->[1]'}
1640       : q{NULL}
1641   } @{$_[1] || []};
1642 }
1643
1644 sub _query_start {
1645   my ( $self, $sql, $bind ) = @_;
1646
1647   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1648     if $self->debug;
1649 }
1650
1651 sub _query_end {
1652   my ( $self, $sql, $bind ) = @_;
1653
1654   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1655     if $self->debug;
1656 }
1657
1658 my $sba_compat;
1659 sub _dbi_attrs_for_bind {
1660   my ($self, $ident, $bind) = @_;
1661
1662   if (! defined $sba_compat) {
1663     $self->_determine_driver;
1664     $sba_compat = $self->can('source_bind_attributes') == \&source_bind_attributes
1665       ? 0
1666       : 1
1667     ;
1668   }
1669
1670   my $sba_attrs;
1671   if ($sba_compat) {
1672     my $class = ref $self;
1673     carp_unique (
1674       "The source_bind_attributes() override in $class relies on a deprecated codepath. "
1675      .'You are strongly advised to switch your code to override bind_attribute_by_datatype() '
1676      .'instead. This legacy compat shim will also disappear some time before DBIC 0.09'
1677     );
1678
1679     my $sba_attrs = $self->source_bind_attributes
1680   }
1681
1682   my @attrs;
1683
1684   for (map { $_->[0] } @$bind) {
1685     push @attrs, do {
1686       if (exists $_->{dbd_attrs}) {
1687         $_->{dbd_attrs}
1688       }
1689       elsif($_->{sqlt_datatype}) {
1690         # cache the result in the dbh_details hash, as it can not change unless
1691         # we connect to something else
1692         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1693         if (not exists $cache->{$_->{sqlt_datatype}}) {
1694           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1695         }
1696         $cache->{$_->{sqlt_datatype}};
1697       }
1698       elsif ($sba_attrs and $_->{dbic_colname}) {
1699         $sba_attrs->{$_->{dbic_colname}} || undef;
1700       }
1701       else {
1702         undef;  # always push something at this position
1703       }
1704     }
1705   }
1706
1707   return \@attrs;
1708 }
1709
1710 sub _execute {
1711   my ($self, $op, $ident, @args) = @_;
1712
1713   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1714
1715   shift->dbh_do(    # retry over disconnects
1716     '_dbh_execute',
1717     $sql,
1718     $bind,
1719     $self->_dbi_attrs_for_bind($ident, $bind)
1720   );
1721 }
1722
1723 sub _dbh_execute {
1724   my ($self, undef, $sql, $bind, $bind_attrs) = @_;
1725
1726   $self->_query_start( $sql, $bind );
1727   my $sth = $self->_sth($sql);
1728
1729   for my $i (0 .. $#$bind) {
1730     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1731       $sth->bind_param_inout(
1732         $i + 1, # bind params counts are 1-based
1733         $bind->[$i][1],
1734         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1735         $bind_attrs->[$i],
1736       );
1737     }
1738     else {
1739       $sth->bind_param(
1740         $i + 1,
1741         (ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""'))
1742           ? "$bind->[$i][1]"
1743           : $bind->[$i][1]
1744         ,
1745         $bind_attrs->[$i],
1746       );
1747     }
1748   }
1749
1750   # Can this fail without throwing an exception anyways???
1751   my $rv = $sth->execute();
1752   $self->throw_exception(
1753     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1754   ) if !$rv;
1755
1756   $self->_query_end( $sql, $bind );
1757
1758   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1759 }
1760
1761 sub _prefetch_autovalues {
1762   my ($self, $source, $to_insert) = @_;
1763
1764   my $colinfo = $source->columns_info;
1765
1766   my %values;
1767   for my $col (keys %$colinfo) {
1768     if (
1769       $colinfo->{$col}{auto_nextval}
1770         and
1771       (
1772         ! exists $to_insert->{$col}
1773           or
1774         ref $to_insert->{$col} eq 'SCALAR'
1775           or
1776         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1777       )
1778     ) {
1779       $values{$col} = $self->_sequence_fetch(
1780         'NEXTVAL',
1781         ( $colinfo->{$col}{sequence} ||=
1782             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1783         ),
1784       );
1785     }
1786   }
1787
1788   \%values;
1789 }
1790
1791 sub insert {
1792   my ($self, $source, $to_insert) = @_;
1793
1794   my $prefetched_values = $self->_prefetch_autovalues($source, $to_insert);
1795
1796   # fuse the values, but keep a separate list of prefetched_values so that
1797   # they can be fused once again with the final return
1798   $to_insert = { %$to_insert, %$prefetched_values };
1799
1800   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1801   # Investigate what does it take to s/defined/exists/
1802   my $col_infos = $source->columns_info;
1803   my %pcols = map { $_ => 1 } $source->primary_columns;
1804   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1805   for my $col ($source->columns) {
1806     if ($col_infos->{$col}{is_auto_increment}) {
1807       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1808       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1809     }
1810
1811     # nothing to retrieve when explicit values are supplied
1812     next if (defined $to_insert->{$col} and ! (
1813       ref $to_insert->{$col} eq 'SCALAR'
1814         or
1815       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1816     ));
1817
1818     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1819     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1820       $pcols{$col}
1821         or
1822       $col_infos->{$col}{retrieve_on_insert}
1823     );
1824   };
1825
1826   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1827   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1828
1829   my ($sqla_opts, @ir_container);
1830   if (%retrieve_cols and $self->_use_insert_returning) {
1831     $sqla_opts->{returning_container} = \@ir_container
1832       if $self->_use_insert_returning_bound;
1833
1834     $sqla_opts->{returning} = [
1835       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1836     ];
1837   }
1838
1839   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1840
1841   my %returned_cols = %$to_insert;
1842   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1843     @ir_container = try {
1844       local $SIG{__WARN__} = sub {};
1845       my @r = $sth->fetchrow_array;
1846       $sth->finish;
1847       @r;
1848     } unless @ir_container;
1849
1850     @returned_cols{@$retlist} = @ir_container if @ir_container;
1851   }
1852   else {
1853     # pull in PK if needed and then everything else
1854     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1855
1856       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1857         unless $self->can('last_insert_id');
1858
1859       my @pri_values = $self->last_insert_id($source, @missing_pri);
1860
1861       $self->throw_exception( "Can't get last insert id" )
1862         unless (@pri_values == @missing_pri);
1863
1864       @returned_cols{@missing_pri} = @pri_values;
1865       delete $retrieve_cols{$_} for @missing_pri;
1866     }
1867
1868     # if there is more left to pull
1869     if (%retrieve_cols) {
1870       $self->throw_exception(
1871         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1872       ) unless %pcols;
1873
1874       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1875
1876       my $cur = DBIx::Class::ResultSet->new($source, {
1877         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1878         select => \@left_to_fetch,
1879       })->cursor;
1880
1881       @returned_cols{@left_to_fetch} = $cur->next;
1882
1883       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1884         if scalar $cur->next;
1885     }
1886   }
1887
1888   return { %$prefetched_values, %returned_cols };
1889 }
1890
1891 sub insert_bulk {
1892   my ($self, $source, $cols, $data) = @_;
1893
1894   my @col_range = (0..$#$cols);
1895
1896   # FIXME - perhaps this is not even needed? does DBI stringify?
1897   #
1898   # forcibly stringify whatever is stringifiable
1899   # ResultSet::populate() hands us a copy - safe to mangle
1900   for my $r (0 .. $#$data) {
1901     for my $c (0 .. $#{$data->[$r]}) {
1902       $data->[$r][$c] = "$data->[$r][$c]"
1903         if ( ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1904     }
1905   }
1906
1907   my $colinfos = $source->columns_info($cols);
1908
1909   local $self->{_autoinc_supplied_for_op} =
1910     (first { $_->{is_auto_increment} } values %$colinfos)
1911       ? 1
1912       : 0
1913   ;
1914
1915   # get a slice type index based on first row of data
1916   # a "column" in this context may refer to more than one bind value
1917   # e.g. \[ '?, ?', [...], [...] ]
1918   #
1919   # construct the value type index - a description of values types for every
1920   # per-column slice of $data:
1921   #
1922   # nonexistent - nonbind literal
1923   # 0 - regular value
1924   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1925   #
1926   # also construct the column hash to pass to the SQL generator. For plain
1927   # (non literal) values - convert the members of the first row into a
1928   # literal+bind combo, with extra positional info in the bind attr hashref.
1929   # This will allow us to match the order properly, and is so contrived
1930   # because a user-supplied literal/bind (or something else specific to a
1931   # resultsource and/or storage driver) can inject extra binds along the
1932   # way, so one can't rely on "shift positions" ordering at all. Also we
1933   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1934   # can be later matched up by address), because we want to supply a real
1935   # value on which perhaps e.g. datatype checks will be performed
1936   my ($proto_data, $value_type_idx);
1937   for my $i (@col_range) {
1938     my $colname = $cols->[$i];
1939     if (ref $data->[0][$i] eq 'SCALAR') {
1940       # no bind value at all - no type
1941
1942       $proto_data->{$colname} = $data->[0][$i];
1943     }
1944     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
1945       # repack, so we don't end up mangling the original \[]
1946       my ($sql, @bind) = @${$data->[0][$i]};
1947
1948       # normalization of user supplied stuff
1949       my $resolved_bind = $self->_resolve_bindattrs(
1950         $source, \@bind, $colinfos,
1951       );
1952
1953       # store value-less (attrs only) bind info - we will be comparing all
1954       # supplied binds against this for sanity
1955       $value_type_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
1956
1957       $proto_data->{$colname} = \[ $sql, map { [
1958         # inject slice order to use for $proto_bind construction
1959           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i }
1960             =>
1961           $resolved_bind->[$_][1]
1962         ] } (0 .. $#bind)
1963       ];
1964     }
1965     else {
1966       $value_type_idx->{$i} = 0;
1967
1968       $proto_data->{$colname} = \[ '?', [
1969         { dbic_colname => $colname, _bind_data_slice_idx => $i }
1970           =>
1971         $data->[0][$i]
1972       ] ];
1973     }
1974   }
1975
1976   my ($sql, $proto_bind) = $self->_prep_for_execute (
1977     'insert',
1978     $source,
1979     [ $proto_data ],
1980   );
1981
1982   if (! @$proto_bind and keys %$value_type_idx) {
1983     # if the bindlist is empty and we had some dynamic binds, this means the
1984     # storage ate them away (e.g. the NoBindVars component) and interpolated
1985     # them directly into the SQL. This obviously can't be good for multi-inserts
1986     $self->throw_exception('Cannot insert_bulk without support for placeholders');
1987   }
1988
1989   # sanity checks
1990   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
1991   #
1992   # use an error reporting closure for convenience (less to pass)
1993   my $bad_slice_report_cref = sub {
1994     my ($msg, $r_idx, $c_idx) = @_;
1995     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
1996       $msg,
1997       $cols->[$c_idx],
1998       do {
1999         require Data::Dumper::Concise;
2000         local $Data::Dumper::Maxdepth = 5;
2001         Data::Dumper::Concise::Dumper ({
2002           map { $cols->[$_] =>
2003             $data->[$r_idx][$_]
2004           } @col_range
2005         }),
2006       }
2007     );
2008   };
2009
2010   for my $col_idx (@col_range) {
2011     my $reference_val = $data->[0][$col_idx];
2012
2013     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2014       my $val = $data->[$row_idx][$col_idx];
2015
2016       if (! exists $value_type_idx->{$col_idx}) { # literal no binds
2017         if (ref $val ne 'SCALAR') {
2018           $bad_slice_report_cref->(
2019             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2020             $row_idx,
2021             $col_idx,
2022           );
2023         }
2024         elsif ($$val ne $$reference_val) {
2025           $bad_slice_report_cref->(
2026             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2027             $row_idx,
2028             $col_idx,
2029           );
2030         }
2031       }
2032       elsif (! $value_type_idx->{$col_idx} ) {  # regular non-literal value
2033         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2034           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2035         }
2036       }
2037       else {  # binds from a \[], compare type and attrs
2038         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2039           $bad_slice_report_cref->(
2040             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2041             $row_idx,
2042             $col_idx,
2043           );
2044         }
2045         # start drilling down and bail out early on identical refs
2046         elsif (
2047           $reference_val != $val
2048             or
2049           $$reference_val != $$val
2050         ) {
2051           if (${$val}->[0] ne ${$reference_val}->[0]) {
2052             $bad_slice_report_cref->(
2053               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2054               $row_idx,
2055               $col_idx,
2056             );
2057           }
2058           # need to check the bind attrs - a bind will happen only once for
2059           # the entire dataset, so any changes further down will be ignored.
2060           elsif (! Data::Compare::Compare(
2061             $value_type_idx->{$col_idx},
2062             [
2063               map
2064               { $_->[0] }
2065               @{$self->_resolve_bindattrs(
2066                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2067               )}
2068             ],
2069           )) {
2070             $bad_slice_report_cref->(
2071               'Differing bind attributes on literal/bind values not supported',
2072               $row_idx,
2073               $col_idx,
2074             );
2075           }
2076         }
2077       }
2078     }
2079   }
2080
2081   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2082   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2083   # scope guard
2084   my $guard = $self->txn_scope_guard;
2085
2086   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2087   my $sth = $self->_sth($sql);
2088   my $rv = do {
2089     if (@$proto_bind) {
2090       # proto bind contains the information on which pieces of $data to pull
2091       # $cols is passed in only for prettier error-reporting
2092       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2093     }
2094     else {
2095       # bind_param_array doesn't work if there are no binds
2096       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2097     }
2098   };
2099
2100   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2101
2102   $guard->commit;
2103
2104   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2105 }
2106
2107 # execute_for_fetch is capable of returning data just fine (it means it
2108 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2109 # is the void-populate fast-path we will just ignore this altogether
2110 # for the time being.
2111 sub _dbh_execute_for_fetch {
2112   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2113
2114   my @idx_range = ( 0 .. $#$proto_bind );
2115
2116   # If we have any bind attributes to take care of, we will bind the
2117   # proto-bind data (which will never be used by execute_for_fetch)
2118   # However since column bindtypes are "sticky", this is sufficient
2119   # to get the DBD to apply the bindtype to all values later on
2120
2121   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2122
2123   for my $i (@idx_range) {
2124     $sth->bind_param (
2125       $i+1, # DBI bind indexes are 1-based
2126       $proto_bind->[$i][1],
2127       $bind_attrs->[$i],
2128     ) if defined $bind_attrs->[$i];
2129   }
2130
2131   # At this point $data slots named in the _bind_data_slice_idx of
2132   # each piece of $proto_bind are either \[]s or plain values to be
2133   # passed in. Construct the dispensing coderef. *NOTE* the order
2134   # of $data will differ from this of the ?s in the SQL (due to
2135   # alphabetical ordering by colname). We actually do want to
2136   # preserve this behavior so that prepare_cached has a better
2137   # chance of matching on unrelated calls
2138   my %data_reorder = map { $proto_bind->[$_][0]{_bind_data_slice_idx} => $_ } @idx_range;
2139
2140   my $fetch_row_idx = -1; # saner loop this way
2141   my $fetch_tuple = sub {
2142     return undef if ++$fetch_row_idx > $#$data;
2143
2144     return [ map
2145       { (ref $_ eq 'REF' and ref $$_ eq 'ARRAY')
2146         ? map { $_->[-1] } @{$$_}[1 .. $#$$_]
2147         : $_
2148       }
2149       map
2150         { $data->[$fetch_row_idx][$_]}
2151         sort
2152           { $data_reorder{$a} <=> $data_reorder{$b} }
2153           keys %data_reorder
2154     ];
2155   };
2156
2157   my $tuple_status = [];
2158   my ($rv, $err);
2159   try {
2160     $rv = $sth->execute_for_fetch(
2161       $fetch_tuple,
2162       $tuple_status,
2163     );
2164   }
2165   catch {
2166     $err = shift;
2167   };
2168
2169   # Not all DBDs are create equal. Some throw on error, some return
2170   # an undef $rv, and some set $sth->err - try whatever we can
2171   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2172     ! defined $err
2173       and
2174     ( !defined $rv or $sth->err )
2175   );
2176
2177   # Statement must finish even if there was an exception.
2178   try {
2179     $sth->finish
2180   }
2181   catch {
2182     $err = shift unless defined $err
2183   };
2184
2185   if (defined $err) {
2186     my $i = 0;
2187     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2188
2189     $self->throw_exception("Unexpected populate error: $err")
2190       if ($i > $#$tuple_status);
2191
2192     require Data::Dumper::Concise;
2193     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2194       ($tuple_status->[$i][1] || $err),
2195       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2196     );
2197   }
2198
2199   return $rv;
2200 }
2201
2202 sub _dbh_execute_inserts_with_no_binds {
2203   my ($self, $sth, $count) = @_;
2204
2205   my $err;
2206   try {
2207     my $dbh = $self->_get_dbh;
2208     local $dbh->{RaiseError} = 1;
2209     local $dbh->{PrintError} = 0;
2210
2211     $sth->execute foreach 1..$count;
2212   }
2213   catch {
2214     $err = shift;
2215   };
2216
2217   # Make sure statement is finished even if there was an exception.
2218   try {
2219     $sth->finish
2220   }
2221   catch {
2222     $err = shift unless defined $err;
2223   };
2224
2225   $self->throw_exception($err) if defined $err;
2226
2227   return $count;
2228 }
2229
2230 sub update {
2231   #my ($self, $source, @args) = @_;
2232   shift->_execute('update', @_);
2233 }
2234
2235
2236 sub delete {
2237   #my ($self, $source, @args) = @_;
2238   shift->_execute('delete', @_);
2239 }
2240
2241 sub _select {
2242   my $self = shift;
2243   $self->_execute($self->_select_args(@_));
2244 }
2245
2246 sub _select_args_to_query {
2247   my $self = shift;
2248
2249   $self->throw_exception(
2250     "Unable to generate limited query representation with 'software_limit' enabled"
2251   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2252
2253   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2254   #  = $self->_select_args($ident, $select, $cond, $attrs);
2255   my ($op, $ident, @args) =
2256     $self->_select_args(@_);
2257
2258   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2259   my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, \@args);
2260   $prepared_bind ||= [];
2261
2262   return wantarray
2263     ? ($sql, $prepared_bind)
2264     : \[ "($sql)", @$prepared_bind ]
2265   ;
2266 }
2267
2268 sub _select_args {
2269   my ($self, $ident, $select, $where, $attrs) = @_;
2270
2271   my $sql_maker = $self->sql_maker;
2272   my ($alias2source, $rs_alias) = $self->_resolve_ident_sources ($ident);
2273
2274   $attrs = {
2275     %$attrs,
2276     select => $select,
2277     from => $ident,
2278     where => $where,
2279     $rs_alias && $alias2source->{$rs_alias}
2280       ? ( _rsroot_rsrc => $alias2source->{$rs_alias} )
2281       : ()
2282     ,
2283   };
2284
2285   # Sanity check the attributes (SQLMaker does it too, but
2286   # in case of a software_limit we'll never reach there)
2287   if (defined $attrs->{offset}) {
2288     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2289       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2290   }
2291
2292   if (defined $attrs->{rows}) {
2293     $self->throw_exception("The rows attribute must be a positive integer if present")
2294       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2295   }
2296   elsif ($attrs->{offset}) {
2297     # MySQL actually recommends this approach.  I cringe.
2298     $attrs->{rows} = $sql_maker->__max_int;
2299   }
2300
2301   my @limit;
2302
2303   # see if we need to tear the prefetch apart otherwise delegate the limiting to the
2304   # storage, unless software limit was requested
2305   if (
2306     #limited has_many
2307     ( $attrs->{rows} && keys %{$attrs->{collapse}} )
2308        ||
2309     # grouped prefetch (to satisfy group_by == select)
2310     ( $attrs->{group_by}
2311         &&
2312       @{$attrs->{group_by}}
2313         &&
2314       $attrs->{_prefetch_selector_range}
2315     )
2316   ) {
2317     ($ident, $select, $where, $attrs)
2318       = $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2319   }
2320   elsif (! $attrs->{software_limit} ) {
2321     push @limit, (
2322       $attrs->{rows} || (),
2323       $attrs->{offset} || (),
2324     );
2325   }
2326
2327   # try to simplify the joinmap further (prune unreferenced type-single joins)
2328   if (
2329     ref $ident
2330       and
2331     reftype $ident eq 'ARRAY'
2332       and
2333     @$ident != 1
2334   ) {
2335     $ident = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2336   }
2337
2338 ###
2339   # This would be the point to deflate anything found in $where
2340   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2341   # expect a result object. And all we have is a resultsource (it is trivial
2342   # to extract deflator coderefs via $alias2source above).
2343   #
2344   # I don't see a way forward other than changing the way deflators are
2345   # invoked, and that's just bad...
2346 ###
2347
2348   return ('select', $ident, $select, $where, $attrs, @limit);
2349 }
2350
2351 # Returns a counting SELECT for a simple count
2352 # query. Abstracted so that a storage could override
2353 # this to { count => 'firstcol' } or whatever makes
2354 # sense as a performance optimization
2355 sub _count_select {
2356   #my ($self, $source, $rs_attrs) = @_;
2357   return { count => '*' };
2358 }
2359
2360 sub source_bind_attributes {
2361   shift->throw_exception(
2362     'source_bind_attributes() was never meant to be a callable public method - '
2363    .'please contact the DBIC dev-team and describe your use case so that a reasonable '
2364    .'solution can be provided'
2365    ."\nhttp://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT"
2366   );
2367 }
2368
2369 =head2 select
2370
2371 =over 4
2372
2373 =item Arguments: $ident, $select, $condition, $attrs
2374
2375 =back
2376
2377 Handle a SQL select statement.
2378
2379 =cut
2380
2381 sub select {
2382   my $self = shift;
2383   my ($ident, $select, $condition, $attrs) = @_;
2384   return $self->cursor_class->new($self, \@_, $attrs);
2385 }
2386
2387 sub select_single {
2388   my $self = shift;
2389   my ($rv, $sth, @bind) = $self->_select(@_);
2390   my @row = $sth->fetchrow_array;
2391   my @nextrow = $sth->fetchrow_array if @row;
2392   if(@row && @nextrow) {
2393     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2394   }
2395   # Need to call finish() to work round broken DBDs
2396   $sth->finish();
2397   return @row;
2398 }
2399
2400 =head2 sql_limit_dialect
2401
2402 This is an accessor for the default SQL limit dialect used by a particular
2403 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2404 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2405 see L<DBIx::Class::SQLMaker::LimitDialects>.
2406
2407 =cut
2408
2409 sub _dbh_sth {
2410   my ($self, $dbh, $sql) = @_;
2411
2412   # 3 is the if_active parameter which avoids active sth re-use
2413   my $sth = $self->disable_sth_caching
2414     ? $dbh->prepare($sql)
2415     : $dbh->prepare_cached($sql, {}, 3);
2416
2417   # XXX You would think RaiseError would make this impossible,
2418   #  but apparently that's not true :(
2419   $self->throw_exception(
2420     $dbh->errstr
2421       ||
2422     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
2423             .'an exception and/or setting $dbh->errstr',
2424       length ($sql) > 20
2425         ? substr($sql, 0, 20) . '...'
2426         : $sql
2427       ,
2428       'DBD::' . $dbh->{Driver}{Name},
2429     )
2430   ) if !$sth;
2431
2432   $sth;
2433 }
2434
2435 sub sth {
2436   carp_unique 'sth was mistakenly marked/documented as public, stop calling it (will be removed before DBIC v0.09)';
2437   shift->_sth(@_);
2438 }
2439
2440 sub _sth {
2441   my ($self, $sql) = @_;
2442   $self->dbh_do('_dbh_sth', $sql);  # retry over disconnects
2443 }
2444
2445 sub _dbh_columns_info_for {
2446   my ($self, $dbh, $table) = @_;
2447
2448   if ($dbh->can('column_info')) {
2449     my %result;
2450     my $caught;
2451     try {
2452       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2453       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2454       $sth->execute();
2455       while ( my $info = $sth->fetchrow_hashref() ){
2456         my %column_info;
2457         $column_info{data_type}   = $info->{TYPE_NAME};
2458         $column_info{size}      = $info->{COLUMN_SIZE};
2459         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2460         $column_info{default_value} = $info->{COLUMN_DEF};
2461         my $col_name = $info->{COLUMN_NAME};
2462         $col_name =~ s/^\"(.*)\"$/$1/;
2463
2464         $result{$col_name} = \%column_info;
2465       }
2466     } catch {
2467       $caught = 1;
2468     };
2469     return \%result if !$caught && scalar keys %result;
2470   }
2471
2472   my %result;
2473   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2474   $sth->execute;
2475   my @columns = @{$sth->{NAME_lc}};
2476   for my $i ( 0 .. $#columns ){
2477     my %column_info;
2478     $column_info{data_type} = $sth->{TYPE}->[$i];
2479     $column_info{size} = $sth->{PRECISION}->[$i];
2480     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2481
2482     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2483       $column_info{data_type} = $1;
2484       $column_info{size}    = $2;
2485     }
2486
2487     $result{$columns[$i]} = \%column_info;
2488   }
2489   $sth->finish;
2490
2491   foreach my $col (keys %result) {
2492     my $colinfo = $result{$col};
2493     my $type_num = $colinfo->{data_type};
2494     my $type_name;
2495     if(defined $type_num && $dbh->can('type_info')) {
2496       my $type_info = $dbh->type_info($type_num);
2497       $type_name = $type_info->{TYPE_NAME} if $type_info;
2498       $colinfo->{data_type} = $type_name if $type_name;
2499     }
2500   }
2501
2502   return \%result;
2503 }
2504
2505 sub columns_info_for {
2506   my ($self, $table) = @_;
2507   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2508 }
2509
2510 =head2 last_insert_id
2511
2512 Return the row id of the last insert.
2513
2514 =cut
2515
2516 sub _dbh_last_insert_id {
2517     my ($self, $dbh, $source, $col) = @_;
2518
2519     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2520
2521     return $id if defined $id;
2522
2523     my $class = ref $self;
2524     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2525 }
2526
2527 sub last_insert_id {
2528   my $self = shift;
2529   $self->_dbh_last_insert_id ($self->_dbh, @_);
2530 }
2531
2532 =head2 _native_data_type
2533
2534 =over 4
2535
2536 =item Arguments: $type_name
2537
2538 =back
2539
2540 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2541 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2542 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2543
2544 The default implementation returns C<undef>, implement in your Storage driver if
2545 you need this functionality.
2546
2547 Should map types from other databases to the native RDBMS type, for example
2548 C<VARCHAR2> to C<VARCHAR>.
2549
2550 Types with modifiers should map to the underlying data type. For example,
2551 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2552
2553 Composite types should map to the container type, for example
2554 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2555
2556 =cut
2557
2558 sub _native_data_type {
2559   #my ($self, $data_type) = @_;
2560   return undef
2561 }
2562
2563 # Check if placeholders are supported at all
2564 sub _determine_supports_placeholders {
2565   my $self = shift;
2566   my $dbh  = $self->_get_dbh;
2567
2568   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2569   # but it is inaccurate more often than not
2570   return try {
2571     local $dbh->{PrintError} = 0;
2572     local $dbh->{RaiseError} = 1;
2573     $dbh->do('select ?', {}, 1);
2574     1;
2575   }
2576   catch {
2577     0;
2578   };
2579 }
2580
2581 # Check if placeholders bound to non-string types throw exceptions
2582 #
2583 sub _determine_supports_typeless_placeholders {
2584   my $self = shift;
2585   my $dbh  = $self->_get_dbh;
2586
2587   return try {
2588     local $dbh->{PrintError} = 0;
2589     local $dbh->{RaiseError} = 1;
2590     # this specifically tests a bind that is NOT a string
2591     $dbh->do('select 1 where 1 = ?', {}, 1);
2592     1;
2593   }
2594   catch {
2595     0;
2596   };
2597 }
2598
2599 =head2 sqlt_type
2600
2601 Returns the database driver name.
2602
2603 =cut
2604
2605 sub sqlt_type {
2606   shift->_get_dbh->{Driver}->{Name};
2607 }
2608
2609 =head2 bind_attribute_by_data_type
2610
2611 Given a datatype from column info, returns a database specific bind
2612 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2613 let the database planner just handle it.
2614
2615 Generally only needed for special case column types, like bytea in postgres.
2616
2617 =cut
2618
2619 sub bind_attribute_by_data_type {
2620     return;
2621 }
2622
2623 =head2 is_datatype_numeric
2624
2625 Given a datatype from column_info, returns a boolean value indicating if
2626 the current RDBMS considers it a numeric value. This controls how
2627 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2628 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2629 be performed instead of the usual C<eq>.
2630
2631 =cut
2632
2633 sub is_datatype_numeric {
2634   #my ($self, $dt) = @_;
2635
2636   return 0 unless $_[1];
2637
2638   $_[1] =~ /^ (?:
2639     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2640   ) $/ix;
2641 }
2642
2643
2644 =head2 create_ddl_dir
2645
2646 =over 4
2647
2648 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2649
2650 =back
2651
2652 Creates a SQL file based on the Schema, for each of the specified
2653 database engines in C<\@databases> in the given directory.
2654 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2655
2656 Given a previous version number, this will also create a file containing
2657 the ALTER TABLE statements to transform the previous schema into the
2658 current one. Note that these statements may contain C<DROP TABLE> or
2659 C<DROP COLUMN> statements that can potentially destroy data.
2660
2661 The file names are created using the C<ddl_filename> method below, please
2662 override this method in your schema if you would like a different file
2663 name format. For the ALTER file, the same format is used, replacing
2664 $version in the name with "$preversion-$version".
2665
2666 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2667 The most common value for this would be C<< { add_drop_table => 1 } >>
2668 to have the SQL produced include a C<DROP TABLE> statement for each table
2669 created. For quoting purposes supply C<quote_table_names> and
2670 C<quote_field_names>.
2671
2672 If no arguments are passed, then the following default values are assumed:
2673
2674 =over 4
2675
2676 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2677
2678 =item version    - $schema->schema_version
2679
2680 =item directory  - './'
2681
2682 =item preversion - <none>
2683
2684 =back
2685
2686 By default, C<\%sqlt_args> will have
2687
2688  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2689
2690 merged with the hash passed in. To disable any of those features, pass in a
2691 hashref like the following
2692
2693  { ignore_constraint_names => 0, # ... other options }
2694
2695
2696 WARNING: You are strongly advised to check all SQL files created, before applying
2697 them.
2698
2699 =cut
2700
2701 sub create_ddl_dir {
2702   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2703
2704   unless ($dir) {
2705     carp "No directory given, using ./\n";
2706     $dir = './';
2707   } else {
2708       -d $dir
2709         or
2710       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2711         or
2712       $self->throw_exception(
2713         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2714       );
2715   }
2716
2717   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2718
2719   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2720   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2721
2722   my $schema_version = $schema->schema_version || '1.x';
2723   $version ||= $schema_version;
2724
2725   $sqltargs = {
2726     add_drop_table => 1,
2727     ignore_constraint_names => 1,
2728     ignore_index_names => 1,
2729     %{$sqltargs || {}}
2730   };
2731
2732   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2733     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2734   }
2735
2736   my $sqlt = SQL::Translator->new( $sqltargs );
2737
2738   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2739   my $sqlt_schema = $sqlt->translate({ data => $schema })
2740     or $self->throw_exception ($sqlt->error);
2741
2742   foreach my $db (@$databases) {
2743     $sqlt->reset();
2744     $sqlt->{schema} = $sqlt_schema;
2745     $sqlt->producer($db);
2746
2747     my $file;
2748     my $filename = $schema->ddl_filename($db, $version, $dir);
2749     if (-e $filename && ($version eq $schema_version )) {
2750       # if we are dumping the current version, overwrite the DDL
2751       carp "Overwriting existing DDL file - $filename";
2752       unlink($filename);
2753     }
2754
2755     my $output = $sqlt->translate;
2756     if(!$output) {
2757       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2758       next;
2759     }
2760     if(!open($file, ">$filename")) {
2761       $self->throw_exception("Can't open $filename for writing ($!)");
2762       next;
2763     }
2764     print $file $output;
2765     close($file);
2766
2767     next unless ($preversion);
2768
2769     require SQL::Translator::Diff;
2770
2771     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2772     if(!-e $prefilename) {
2773       carp("No previous schema file found ($prefilename)");
2774       next;
2775     }
2776
2777     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2778     if(-e $difffile) {
2779       carp("Overwriting existing diff file - $difffile");
2780       unlink($difffile);
2781     }
2782
2783     my $source_schema;
2784     {
2785       my $t = SQL::Translator->new($sqltargs);
2786       $t->debug( 0 );
2787       $t->trace( 0 );
2788
2789       $t->parser( $db )
2790         or $self->throw_exception ($t->error);
2791
2792       my $out = $t->translate( $prefilename )
2793         or $self->throw_exception ($t->error);
2794
2795       $source_schema = $t->schema;
2796
2797       $source_schema->name( $prefilename )
2798         unless ( $source_schema->name );
2799     }
2800
2801     # The "new" style of producers have sane normalization and can support
2802     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2803     # And we have to diff parsed SQL against parsed SQL.
2804     my $dest_schema = $sqlt_schema;
2805
2806     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2807       my $t = SQL::Translator->new($sqltargs);
2808       $t->debug( 0 );
2809       $t->trace( 0 );
2810
2811       $t->parser( $db )
2812         or $self->throw_exception ($t->error);
2813
2814       my $out = $t->translate( $filename )
2815         or $self->throw_exception ($t->error);
2816
2817       $dest_schema = $t->schema;
2818
2819       $dest_schema->name( $filename )
2820         unless $dest_schema->name;
2821     }
2822
2823     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2824                                                   $dest_schema,   $db,
2825                                                   $sqltargs
2826                                                  );
2827     if(!open $file, ">$difffile") {
2828       $self->throw_exception("Can't write to $difffile ($!)");
2829       next;
2830     }
2831     print $file $diff;
2832     close($file);
2833   }
2834 }
2835
2836 =head2 deployment_statements
2837
2838 =over 4
2839
2840 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2841
2842 =back
2843
2844 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2845
2846 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2847 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2848
2849 C<$directory> is used to return statements from files in a previously created
2850 L</create_ddl_dir> directory and is optional. The filenames are constructed
2851 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2852
2853 If no C<$directory> is specified then the statements are constructed on the
2854 fly using L<SQL::Translator> and C<$version> is ignored.
2855
2856 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2857
2858 =cut
2859
2860 sub deployment_statements {
2861   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2862   $type ||= $self->sqlt_type;
2863   $version ||= $schema->schema_version || '1.x';
2864   $dir ||= './';
2865   my $filename = $schema->ddl_filename($type, $version, $dir);
2866   if(-f $filename)
2867   {
2868       # FIXME replace this block when a proper sane sql parser is available
2869       my $file;
2870       open($file, "<$filename")
2871         or $self->throw_exception("Can't open $filename ($!)");
2872       my @rows = <$file>;
2873       close($file);
2874       return join('', @rows);
2875   }
2876
2877   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2878     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2879   }
2880
2881   # sources needs to be a parser arg, but for simplicty allow at top level
2882   # coming in
2883   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2884       if exists $sqltargs->{sources};
2885
2886   my $tr = SQL::Translator->new(
2887     producer => "SQL::Translator::Producer::${type}",
2888     %$sqltargs,
2889     parser => 'SQL::Translator::Parser::DBIx::Class',
2890     data => $schema,
2891   );
2892
2893   return preserve_context {
2894     $tr->translate
2895   } after => sub {
2896     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2897       unless defined $_[0];
2898   };
2899 }
2900
2901 # FIXME deploy() currently does not accurately report sql errors
2902 # Will always return true while errors are warned
2903 sub deploy {
2904   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2905   my $deploy = sub {
2906     my $line = shift;
2907     return if(!$line);
2908     return if($line =~ /^--/);
2909     # next if($line =~ /^DROP/m);
2910     return if($line =~ /^BEGIN TRANSACTION/m);
2911     return if($line =~ /^COMMIT/m);
2912     return if $line =~ /^\s+$/; # skip whitespace only
2913     $self->_query_start($line);
2914     try {
2915       # do a dbh_do cycle here, as we need some error checking in
2916       # place (even though we will ignore errors)
2917       $self->dbh_do (sub { $_[1]->do($line) });
2918     } catch {
2919       carp qq{$_ (running "${line}")};
2920     };
2921     $self->_query_end($line);
2922   };
2923   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2924   if (@statements > 1) {
2925     foreach my $statement (@statements) {
2926       $deploy->( $statement );
2927     }
2928   }
2929   elsif (@statements == 1) {
2930     # split on single line comments and end of statements
2931     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2932       $deploy->( $line );
2933     }
2934   }
2935 }
2936
2937 =head2 datetime_parser
2938
2939 Returns the datetime parser class
2940
2941 =cut
2942
2943 sub datetime_parser {
2944   my $self = shift;
2945   return $self->{datetime_parser} ||= do {
2946     $self->build_datetime_parser(@_);
2947   };
2948 }
2949
2950 =head2 datetime_parser_type
2951
2952 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
2953
2954 =head2 build_datetime_parser
2955
2956 See L</datetime_parser>
2957
2958 =cut
2959
2960 sub build_datetime_parser {
2961   my $self = shift;
2962   my $type = $self->datetime_parser_type(@_);
2963   return $type;
2964 }
2965
2966
2967 =head2 is_replicating
2968
2969 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2970 replicate from a master database.  Default is undef, which is the result
2971 returned by databases that don't support replication.
2972
2973 =cut
2974
2975 sub is_replicating {
2976     return;
2977
2978 }
2979
2980 =head2 lag_behind_master
2981
2982 Returns a number that represents a certain amount of lag behind a master db
2983 when a given storage is replicating.  The number is database dependent, but
2984 starts at zero and increases with the amount of lag. Default in undef
2985
2986 =cut
2987
2988 sub lag_behind_master {
2989     return;
2990 }
2991
2992 =head2 relname_to_table_alias
2993
2994 =over 4
2995
2996 =item Arguments: $relname, $join_count
2997
2998 =item Return Value: $alias
2999
3000 =back
3001
3002 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3003 queries.
3004
3005 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3006 way these aliases are named.
3007
3008 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3009 otherwise C<"$relname">.
3010
3011 =cut
3012
3013 sub relname_to_table_alias {
3014   my ($self, $relname, $join_count) = @_;
3015
3016   my $alias = ($join_count && $join_count > 1 ?
3017     join('_', $relname, $join_count) : $relname);
3018
3019   return $alias;
3020 }
3021
3022 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3023 # version and it may be necessary to amend or override it for a specific storage
3024 # if such binds are necessary.
3025 sub _max_column_bytesize {
3026   my ($self, $attr) = @_;
3027
3028   my $max_size;
3029
3030   if ($attr->{sqlt_datatype}) {
3031     my $data_type = lc($attr->{sqlt_datatype});
3032
3033     if ($attr->{sqlt_size}) {
3034
3035       # String/sized-binary types
3036       if ($data_type =~ /^(?:
3037           l? (?:var)? char(?:acter)? (?:\s*varying)?
3038             |
3039           (?:var)? binary (?:\s*varying)?
3040             |
3041           raw
3042         )\b/x
3043       ) {
3044         $max_size = $attr->{sqlt_size};
3045       }
3046       # Other charset/unicode types, assume scale of 4
3047       elsif ($data_type =~ /^(?:
3048           national \s* character (?:\s*varying)?
3049             |
3050           nchar
3051             |
3052           univarchar
3053             |
3054           nvarchar
3055         )\b/x
3056       ) {
3057         $max_size = $attr->{sqlt_size} * 4;
3058       }
3059     }
3060
3061     if (!$max_size and !$self->_is_lob_type($data_type)) {
3062       $max_size = 100 # for all other (numeric?) datatypes
3063     }
3064   }
3065
3066   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3067 }
3068
3069 # Determine if a data_type is some type of BLOB
3070 sub _is_lob_type {
3071   my ($self, $data_type) = @_;
3072   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3073     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3074                                   |varchar|character\s*varying|nvarchar
3075                                   |national\s*character\s*varying))?\z/xi);
3076 }
3077
3078 sub _is_binary_lob_type {
3079   my ($self, $data_type) = @_;
3080   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3081     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3082 }
3083
3084 sub _is_text_lob_type {
3085   my ($self, $data_type) = @_;
3086   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3087     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3088                         |national\s*character\s*varying))\z/xi);
3089 }
3090
3091 # Determine if a data_type is some type of a binary type
3092 sub _is_binary_type {
3093   my ($self, $data_type) = @_;
3094   $data_type && ($self->_is_binary_lob_type($data_type)
3095     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3096 }
3097
3098 1;
3099
3100 =head1 USAGE NOTES
3101
3102 =head2 DBIx::Class and AutoCommit
3103
3104 DBIx::Class can do some wonderful magic with handling exceptions,
3105 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3106 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3107 transaction support.
3108
3109 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3110 in an assumed transaction between commits, and you're telling us you'd
3111 like to manage that manually.  A lot of the magic protections offered by
3112 this module will go away.  We can't protect you from exceptions due to database
3113 disconnects because we don't know anything about how to restart your
3114 transactions.  You're on your own for handling all sorts of exceptional
3115 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3116 be with raw DBI.
3117
3118
3119 =head1 AUTHOR AND CONTRIBUTORS
3120
3121 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3122
3123 =head1 LICENSE
3124
3125 You may distribute this code under the same terms as Perl itself.
3126
3127 =cut