lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util();
  13 use List::Util();
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid transaction_depth _dbh_autocommit _on_connect_do
  18        _on_disconnect_do savepoints/
  19 );
  20
  21 # the values for these accessors are picked out (and deleted) from
  22 # the attribute hashref passed to connect_info
  23 my @storage_options = qw/
  24   on_connect_call on_disconnect_call disable_sth_caching unsafe auto_savepoint
  25 /;
  26 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  27
  28
  29 # default cursor class, overridable in connect_info attributes
  30 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  31
  32 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  33 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  34
  35
  36 =head1 NAME
  37
  38 DBIx::Class::Storage::DBI - DBI storage handler
  39
  40 =head1 SYNOPSIS
  41
  42   my $schema = MySchema->connect('dbi:SQLite:my.db');
  43
  44   $schema->storage->debug(1);
  45   $schema->dbh_do("DROP TABLE authors");
  46
  47   $schema->resultset('Book')->search({
  48      written_on => $schema->storage->datetime_parser(DateTime->now)
  49   });
  50
  51 =head1 DESCRIPTION
  52
  53 This class represents the connection to an RDBMS via L<DBI>.  See
  54 L<DBIx::Class::Storage> for general information.  This pod only
  55 documents DBI-specific methods and behaviors.
  56
  57 =head1 METHODS
  58
  59 =cut
  60
  61 sub new {
  62   my $new = shift->next::method(@_);
  63
  64   $new->transaction_depth(0);
  65   $new->_sql_maker_opts({});
  66   $new->{savepoints} = [];
  67   $new->{_in_dbh_do} = 0;
  68   $new->{_dbh_gen} = 0;
  69
  70   $new;
  71 }
  72
  73 =head2 connect_info
  74
  75 This method is normally called by L<DBIx::Class::Schema/connection>, which
  76 encapsulates its argument list in an arrayref before passing them here.
  77
  78 The argument list may contain:
  79
  80 =over
  81
  82 =item *
  83
  84 The same 4-element argument set one would normally pass to
  85 L<DBI/connect>, optionally followed by
  86 L<extra attributes|/DBIx::Class specific connection attributes>
  87 recognized by DBIx::Class:
  88
  89   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
  90
  91 =item *
  92
  93 A single code reference which returns a connected
  94 L<DBI database handle|DBI/connect> optionally followed by
  95 L<extra attributes|/DBIx::Class specific connection attributes> recognized
  96 by DBIx::Class:
  97
  98   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
  99
 100 =item *
 101
 102 A single hashref with all the attributes and the dsn/user/password
 103 mixed together:
 104
 105   $connect_info_args = [{
 106     dsn => $dsn,
 107     user => $user,
 108     password => $pass,
 109     %dbi_attributes,
 110     %extra_attributes,
 111   }];
 112
 113 This is particularly useful for L<Catalyst> based applications, allowing the
 114 following config (L<Config::General> style):
 115
 116   <Model::DB>
 117     schema_class   App::DB
 118     <connect_info>
 119       dsn          dbi:mysql:database=test
 120       user         testuser
 121       password     TestPass
 122       AutoCommit   1
 123     </connect_info>
 124   </Model::DB>
 125
 126 =back
 127
 128 Please note that the L<DBI> docs recommend that you always explicitly
 129 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 130 recommends that it be set to I<1>, and that you perform transactions
 131 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 132 to I<1> if you do not do explicitly set it to zero.  This is the default
 133 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 134
 135 =head3 DBIx::Class specific connection attributes
 136
 137 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 138 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 139 the following connection options. These options can be mixed in with your other
 140 L<DBI> connection attributes, or placed in a seperate hashref
 141 (C<\%extra_attributes>) as shown above.
 142
 143 Every time C<connect_info> is invoked, any previous settings for
 144 these options will be cleared before setting the new ones, regardless of
 145 whether any options are specified in the new C<connect_info>.
 146
 147
 148 =over
 149
 150 =item on_connect_do
 151
 152 Specifies things to do immediately after connecting or re-connecting to
 153 the database.  Its value may contain:
 154
 155 =over
 156
 157 =item a scalar
 158
 159 This contains one SQL statement to execute.
 160
 161 =item an array reference
 162
 163 This contains SQL statements to execute in order.  Each element contains
 164 a string or a code reference that returns a string.
 165
 166 =item a code reference
 167
 168 This contains some code to execute.  Unlike code references within an
 169 array reference, its return value is ignored.
 170
 171 =back
 172
 173 =item on_disconnect_do
 174
 175 Takes arguments in the same form as L</on_connect_do> and executes them
 176 immediately before disconnecting from the database.
 177
 178 Note, this only runs if you explicitly call L</disconnect> on the
 179 storage object.
 180
 181 =item on_connect_call
 182
 183 A more generalized form of L</on_connect_do> that calls the specified
 184 C<connect_call_METHOD> methods in your storage driver.
 185
 186   on_connect_do => 'select 1'
 187
 188 is equivalent to:
 189
 190   on_connect_call => [ [ do_sql => 'select 1' ] ]
 191
 192 Its values may contain:
 193
 194 =over
 195
 196 =item a scalar
 197
 198 Will call the C<connect_call_METHOD> method.
 199
 200 =item a code reference
 201
 202 Will execute C<< $code->($storage) >>
 203
 204 =item an array reference
 205
 206 Each value can be a method name or code reference.
 207
 208 =item an array of arrays
 209
 210 For each array, the first item is taken to be the C<connect_call_> method name
 211 or code reference, and the rest are parameters to it.
 212
 213 =back
 214
 215 Some predefined storage methods you may use:
 216
 217 =over
 218
 219 =item do_sql
 220
 221 Executes a SQL string or a code reference that returns a SQL string. This is
 222 what L</on_connect_do> and L</on_disconnect_do> use.
 223
 224 It can take:
 225
 226 =over
 227
 228 =item a scalar
 229
 230 Will execute the scalar as SQL.
 231
 232 =item an arrayref
 233
 234 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 235 attributes hashref and bind values.
 236
 237 =item a code reference
 238
 239 Will execute C<< $code->($storage) >> and execute the return array refs as
 240 above.
 241
 242 =back
 243
 244 =item set_datetime_format
 245
 246 Execute any statements necessary to initialize the database session to return
 247 and accept datetime/timestamp values used with
 248 L<DBIx::Class::InflateColumn::DateTime>.
 249
 250 =back
 251
 252 =item on_disconnect_call
 253
 254 Takes arguments in the same form as L</on_connect_call> and executes them
 255 immediately before disconnecting from the database.
 256
 257 Calls the C<disconnect_call_METHOD> methods as opposed to the
 258 C<connect_call_METHOD> methods called by L</on_connect_call>.
 259
 260 Note, this only runs if you explicitly call L</disconnect> on the
 261 storage object.
 262
 263 =item disable_sth_caching
 264
 265 If set to a true value, this option will disable the caching of
 266 statement handles via L<DBI/prepare_cached>.
 267
 268 =item limit_dialect
 269
 270 Sets the limit dialect. This is useful for JDBC-bridge among others
 271 where the remote SQL-dialect cannot be determined by the name of the
 272 driver alone. See also L<SQL::Abstract::Limit>.
 273
 274 =item quote_char
 275
 276 Specifies what characters to use to quote table and column names. If
 277 you use this you will want to specify L</name_sep> as well.
 278
 279 C<quote_char> expects either a single character, in which case is it
 280 is placed on either side of the table/column name, or an arrayref of length
 281 2 in which case the table/column name is placed between the elements.
 282
 283 For example under MySQL you should use C<< quote_char => '`' >>, and for
 284 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 285
 286 =item name_sep
 287
 288 This only needs to be used in conjunction with C<quote_char>, and is used to
 289 specify the charecter that seperates elements (schemas, tables, columns) from
 290 each other. In most cases this is simply a C<.>.
 291
 292 The consequences of not supplying this value is that L<SQL::Abstract>
 293 will assume DBIx::Class' uses of aliases to be complete column
 294 names. The output will look like I<"me.name"> when it should actually
 295 be I<"me"."name">.
 296
 297 =item unsafe
 298
 299 This Storage driver normally installs its own C<HandleError>, sets
 300 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 301 all database handles, including those supplied by a coderef.  It does this
 302 so that it can have consistent and useful error behavior.
 303
 304 If you set this option to a true value, Storage will not do its usual
 305 modifications to the database handle's attributes, and instead relies on
 306 the settings in your connect_info DBI options (or the values you set in
 307 your connection coderef, in the case that you are connecting via coderef).
 308
 309 Note that your custom settings can cause Storage to malfunction,
 310 especially if you set a C<HandleError> handler that suppresses exceptions
 311 and/or disable C<RaiseError>.
 312
 313 =item auto_savepoint
 314
 315 If this option is true, L<DBIx::Class> will use savepoints when nesting
 316 transactions, making it possible to recover from failure in the inner
 317 transaction without having to abort all outer transactions.
 318
 319 =item cursor_class
 320
 321 Use this argument to supply a cursor class other than the default
 322 L<DBIx::Class::Storage::DBI::Cursor>.
 323
 324 =back
 325
 326 Some real-life examples of arguments to L</connect_info> and
 327 L<DBIx::Class::Schema/connect>
 328
 329   # Simple SQLite connection
 330   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 331
 332   # Connect via subref
 333   ->connect_info([ sub { DBI->connect(...) } ]);
 334
 335   # A bit more complicated
 336   ->connect_info(
 337     [
 338       'dbi:Pg:dbname=foo',
 339       'postgres',
 340       'my_pg_password',
 341       { AutoCommit => 1 },
 342       { quote_char => q{"}, name_sep => q{.} },
 343     ]
 344   );
 345
 346   # Equivalent to the previous example
 347   ->connect_info(
 348     [
 349       'dbi:Pg:dbname=foo',
 350       'postgres',
 351       'my_pg_password',
 352       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 353     ]
 354   );
 355
 356   # Same, but with hashref as argument
 357   # See parse_connect_info for explanation
 358   ->connect_info(
 359     [{
 360       dsn         => 'dbi:Pg:dbname=foo',
 361       user        => 'postgres',
 362       password    => 'my_pg_password',
 363       AutoCommit  => 1,
 364       quote_char  => q{"},
 365       name_sep    => q{.},
 366     }]
 367   );
 368
 369   # Subref + DBIx::Class-specific connection options
 370   ->connect_info(
 371     [
 372       sub { DBI->connect(...) },
 373       {
 374           quote_char => q{`},
 375           name_sep => q{@},
 376           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 377           disable_sth_caching => 1,
 378       },
 379     ]
 380   );
 381
 382
 383
 384 =cut
 385
 386 sub connect_info {
 387   my ($self, $info_arg) = @_;
 388
 389   return $self->_connect_info if !$info_arg;
 390
 391   my @args = @$info_arg;  # take a shallow copy for further mutilation
 392   $self->_connect_info([@args]); # copy for _connect_info
 393
 394
 395   # combine/pre-parse arguments depending on invocation style
 396
 397   my %attrs;
 398   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 399     %attrs = %{ $args[1] || {} };
 400     @args = $args[0];
 401   }
 402   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 403     %attrs = %{$args[0]};
 404     @args = ();
 405     for (qw/password user dsn/) {
 406       unshift @args, delete $attrs{$_};
 407     }
 408   }
 409   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 410     %attrs = (
 411       % { $args[3] || {} },
 412       % { $args[4] || {} },
 413     );
 414     @args = @args[0,1,2];
 415   }
 416
 417   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 418   #  the new set of options
 419   $self->_sql_maker(undef);
 420   $self->_sql_maker_opts({});
 421
 422   if(keys %attrs) {
 423     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 424       if(my $value = delete $attrs{$storage_opt}) {
 425         $self->$storage_opt($value);
 426       }
 427     }
 428     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 429       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 430         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 431       }
 432     }
 433     for my $connect_do_opt (qw/on_connect_do on_disconnect_do/) {
 434       if(my $opt_val = delete $attrs{$connect_do_opt}) {
 435         $self->$connect_do_opt($opt_val);
 436       }
 437     }
 438   }
 439
 440   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 441
 442   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 443   $self->_connect_info;
 444 }
 445
 446 =head2 on_connect_do
 447
 448 This method is deprecated in favour of setting via L</connect_info>.
 449
 450 =cut
 451
 452 sub on_connect_do {
 453   my $self = shift;
 454   $self->_setup_connect_do(on_connect_do => @_);
 455 }
 456
 457 =head2 on_disconnect_do
 458
 459 This method is deprecated in favour of setting via L</connect_info>.
 460
 461 =cut
 462
 463 sub on_disconnect_do {
 464   my $self = shift;
 465   $self->_setup_connect_do(on_disconnect_do => @_);
 466 }
 467
 468 sub _setup_connect_do {
 469   my ($self, $opt) = (shift, shift);
 470
 471   my $accessor = "_$opt";
 472
 473   return $self->$accessor if not @_;
 474
 475   my $val = shift;
 476
 477   (my $call = $opt) =~ s/_do\z/_call/;
 478
 479   if (ref($self->$call) ne 'ARRAY') {
 480     $self->$call([
 481       defined $self->$call ?  $self->$call : ()
 482     ]);
 483   }
 484
 485   if (not ref($val)) {
 486     push @{ $self->$call }, [ 'do_sql', $val ];
 487   } elsif (ref($val) eq 'CODE') {
 488     push @{ $self->$call }, $val;
 489   } elsif (ref($val) eq 'ARRAY') {
 490     push @{ $self->$call },
 491     map [ 'do_sql', $_ ], @$val;
 492   } else {
 493     $self->throw_exception("Invalid type for $opt ".ref($val));
 494   }
 495
 496   $self->$accessor($val);
 497 }
 498
 499 =head2 dbh_do
 500
 501 Arguments: ($subref | $method_name), @extra_coderef_args?
 502
 503 Execute the given $subref or $method_name using the new exception-based
 504 connection management.
 505
 506 The first two arguments will be the storage object that C<dbh_do> was called
 507 on and a database handle to use.  Any additional arguments will be passed
 508 verbatim to the called subref as arguments 2 and onwards.
 509
 510 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 511 exception handling and reconnection (or failover in future subclasses).
 512
 513 Your subref should have no side-effects outside of the database, as
 514 there is the potential for your subref to be partially double-executed
 515 if the database connection was stale/dysfunctional.
 516
 517 Example:
 518
 519   my @stuff = $schema->storage->dbh_do(
 520     sub {
 521       my ($storage, $dbh, @cols) = @_;
 522       my $cols = join(q{, }, @cols);
 523       $dbh->selectrow_array("SELECT $cols FROM foo");
 524     },
 525     @column_list
 526   );
 527
 528 =cut
 529
 530 sub dbh_do {
 531   my $self = shift;
 532   my $code = shift;
 533
 534   my $dbh = $self->_dbh;
 535
 536   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 537       || $self->{transaction_depth};
 538
 539   local $self->{_in_dbh_do} = 1;
 540
 541   my @result;
 542   my $want_array = wantarray;
 543
 544   eval {
 545     $self->_verify_pid if $dbh;
 546     if(!$self->_dbh) {
 547         $self->_populate_dbh;
 548         $dbh = $self->_dbh;
 549     }
 550
 551     if($want_array) {
 552         @result = $self->$code($dbh, @_);
 553     }
 554     elsif(defined $want_array) {
 555         $result[0] = $self->$code($dbh, @_);
 556     }
 557     else {
 558         $self->$code($dbh, @_);
 559     }
 560   };
 561
 562   my $exception = $@;
 563   if(!$exception) { return $want_array ? @result : $result[0] }
 564
 565   $self->throw_exception($exception) if $self->connected;
 566
 567   # We were not connected - reconnect and retry, but let any
 568   #  exception fall right through this time
 569   $self->_populate_dbh;
 570   $self->$code($self->_dbh, @_);
 571 }
 572
 573 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 574 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 575 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 576 sub txn_do {
 577   my $self = shift;
 578   my $coderef = shift;
 579
 580   ref $coderef eq 'CODE' or $self->throw_exception
 581     ('$coderef must be a CODE reference');
 582
 583   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 584
 585   local $self->{_in_dbh_do} = 1;
 586
 587   my @result;
 588   my $want_array = wantarray;
 589
 590   my $tried = 0;
 591   while(1) {
 592     eval {
 593       $self->_verify_pid if $self->_dbh;
 594       $self->_populate_dbh if !$self->_dbh;
 595
 596       $self->txn_begin;
 597       if($want_array) {
 598           @result = $coderef->(@_);
 599       }
 600       elsif(defined $want_array) {
 601           $result[0] = $coderef->(@_);
 602       }
 603       else {
 604           $coderef->(@_);
 605       }
 606       $self->txn_commit;
 607     };
 608
 609     my $exception = $@;
 610     if(!$exception) { return $want_array ? @result : $result[0] }
 611
 612     if($tried++ > 0 || $self->connected) {
 613       eval { $self->txn_rollback };
 614       my $rollback_exception = $@;
 615       if($rollback_exception) {
 616         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 617         $self->throw_exception($exception)  # propagate nested rollback
 618           if $rollback_exception =~ /$exception_class/;
 619
 620         $self->throw_exception(
 621           "Transaction aborted: ${exception}. "
 622           . "Rollback failed: ${rollback_exception}"
 623         );
 624       }
 625       $self->throw_exception($exception)
 626     }
 627
 628     # We were not connected, and was first try - reconnect and retry
 629     # via the while loop
 630     $self->_populate_dbh;
 631   }
 632 }
 633
 634 =head2 disconnect
 635
 636 Our C<disconnect> method also performs a rollback first if the
 637 database is not in C<AutoCommit> mode.
 638
 639 =cut
 640
 641 sub disconnect {
 642   my ($self) = @_;
 643
 644   if( $self->connected ) {
 645     my $connection_call = $self->on_disconnect_call;
 646     $self->_do_connection_actions(disconnect_call_ => $connection_call)
 647       if $connection_call;
 648
 649     $self->_dbh->rollback unless $self->_dbh_autocommit;
 650     $self->_dbh->disconnect;
 651     $self->_dbh(undef);
 652     $self->{_dbh_gen}++;
 653   }
 654 }
 655
 656 =head2 with_deferred_fk_checks
 657
 658 =over 4
 659
 660 =item Arguments: C<$coderef>
 661
 662 =item Return Value: The return value of $coderef
 663
 664 =back
 665
 666 Storage specific method to run the code ref with FK checks deferred or
 667 in MySQL's case disabled entirely.
 668
 669 =cut
 670
 671 # Storage subclasses should override this
 672 sub with_deferred_fk_checks {
 673   my ($self, $sub) = @_;
 674
 675   $sub->();
 676 }
 677
 678 sub connected {
 679   my ($self) = @_;
 680
 681   if(my $dbh = $self->_dbh) {
 682       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 683           $self->_dbh(undef);
 684           $self->{_dbh_gen}++;
 685           return;
 686       }
 687       else {
 688           $self->_verify_pid;
 689           return 0 if !$self->_dbh;
 690       }
 691       return ($dbh->FETCH('Active') && $dbh->ping);
 692   }
 693
 694   return 0;
 695 }
 696
 697 # handle pid changes correctly
 698 #  NOTE: assumes $self->_dbh is a valid $dbh
 699 sub _verify_pid {
 700   my ($self) = @_;
 701
 702   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 703
 704   $self->_dbh->{InactiveDestroy} = 1;
 705   $self->_dbh(undef);
 706   $self->{_dbh_gen}++;
 707
 708   return;
 709 }
 710
 711 sub ensure_connected {
 712   my ($self) = @_;
 713
 714   unless ($self->connected) {
 715     $self->_populate_dbh;
 716   }
 717 }
 718
 719 =head2 dbh
 720
 721 Returns the dbh - a data base handle of class L<DBI>.
 722
 723 =cut
 724
 725 sub dbh {
 726   my ($self) = @_;
 727
 728   $self->ensure_connected;
 729   return $self->_dbh;
 730 }
 731
 732 sub _sql_maker_args {
 733     my ($self) = @_;
 734
 735     return ( bindtype=>'columns', array_datatypes => 1, limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 736 }
 737
 738 sub sql_maker {
 739   my ($self) = @_;
 740   unless ($self->_sql_maker) {
 741     my $sql_maker_class = $self->sql_maker_class;
 742     $self->ensure_class_loaded ($sql_maker_class);
 743     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 744   }
 745   return $self->_sql_maker;
 746 }
 747
 748 sub _rebless {}
 749
 750 sub _populate_dbh {
 751   my ($self) = @_;
 752   my @info = @{$self->_dbi_connect_info || []};
 753   $self->_dbh($self->_connect(@info));
 754
 755   $self->_conn_pid($$);
 756   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 757
 758   $self->_determine_driver;
 759
 760   # Always set the transaction depth on connect, since
 761   #  there is no transaction in progress by definition
 762   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 763
 764   my $connection_call = $self->on_connect_call;
 765   $self->_do_connection_actions(connect_call_ => $connection_call)
 766     if $connection_call;
 767 }
 768
 769 sub _determine_driver {
 770   my ($self) = @_;
 771
 772   if (ref $self eq 'DBIx::Class::Storage::DBI') {
 773     my $driver;
 774
 775     if ($self->_dbh) { # we are connected
 776       $driver = $self->_dbh->{Driver}{Name};
 777     } else {
 778       # try to use dsn to not require being connected, the driver may still
 779       # force a connection in _rebless to determine version
 780       ($driver) = $self->_dbi_connect_info->[0] =~ /dbi:([^:]+):/i;
 781     }
 782
 783     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 784       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 785       $self->_rebless();
 786     }
 787   }
 788 }
 789
 790 sub _do_connection_actions {
 791   my $self          = shift;
 792   my $method_prefix = shift;
 793   my $call          = shift;
 794
 795   if (not ref($call)) {
 796     my $method = $method_prefix . $call;
 797     $self->$method(@_);
 798   } elsif (ref($call) eq 'CODE') {
 799     $self->$call(@_);
 800   } elsif (ref($call) eq 'ARRAY') {
 801     if (ref($call->[0]) ne 'ARRAY') {
 802       $self->_do_connection_actions($method_prefix, $_) for @$call;
 803     } else {
 804       $self->_do_connection_actions($method_prefix, @$_) for @$call;
 805     }
 806   } else {
 807     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
 808   }
 809
 810   return $self;
 811 }
 812
 813 sub connect_call_do_sql {
 814   my $self = shift;
 815   $self->_do_query(@_);
 816 }
 817
 818 sub disconnect_call_do_sql {
 819   my $self = shift;
 820   $self->_do_query(@_);
 821 }
 822
 823 # override in db-specific backend when necessary
 824 sub connect_call_set_datetime_format { 1 }
 825
 826 sub _do_query {
 827   my ($self, $action) = @_;
 828
 829   if (ref $action eq 'CODE') {
 830     $action = $action->($self);
 831     $self->_do_query($_) foreach @$action;
 832   }
 833   else {
 834     # Most debuggers expect ($sql, @bind), so we need to exclude
 835     # the attribute hash which is the second argument to $dbh->do
 836     # furthermore the bind values are usually to be presented
 837     # as named arrayref pairs, so wrap those here too
 838     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 839     my $sql = shift @do_args;
 840     my $attrs = shift @do_args;
 841     my @bind = map { [ undef, $_ ] } @do_args;
 842
 843     $self->_query_start($sql, @bind);
 844     $self->_dbh->do($sql, $attrs, @do_args);
 845     $self->_query_end($sql, @bind);
 846   }
 847
 848   return $self;
 849 }
 850
 851 sub _connect {
 852   my ($self, @info) = @_;
 853
 854   $self->throw_exception("You failed to provide any connection info")
 855     if !@info;
 856
 857   my ($old_connect_via, $dbh);
 858
 859   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 860     $old_connect_via = $DBI::connect_via;
 861     $DBI::connect_via = 'connect';
 862   }
 863
 864   eval {
 865     if(ref $info[0] eq 'CODE') {
 866        $dbh = &{$info[0]}
 867     }
 868     else {
 869        $dbh = DBI->connect(@info);
 870     }
 871
 872     if($dbh && !$self->unsafe) {
 873       my $weak_self = $self;
 874       Scalar::Util::weaken($weak_self);
 875       $dbh->{HandleError} = sub {
 876           if ($weak_self) {
 877             $weak_self->throw_exception("DBI Exception: $_[0]");
 878           }
 879           else {
 880             croak ("DBI Exception: $_[0]");
 881           }
 882       };
 883       $dbh->{ShowErrorStatement} = 1;
 884       $dbh->{RaiseError} = 1;
 885       $dbh->{PrintError} = 0;
 886     }
 887   };
 888
 889   $DBI::connect_via = $old_connect_via if $old_connect_via;
 890
 891   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 892     if !$dbh || $@;
 893
 894   $self->_dbh_autocommit($dbh->{AutoCommit});
 895
 896   $dbh;
 897 }
 898
 899 sub svp_begin {
 900   my ($self, $name) = @_;
 901
 902   $name = $self->_svp_generate_name
 903     unless defined $name;
 904
 905   $self->throw_exception ("You can't use savepoints outside a transaction")
 906     if $self->{transaction_depth} == 0;
 907
 908   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 909     unless $self->can('_svp_begin');
 910
 911   push @{ $self->{savepoints} }, $name;
 912
 913   $self->debugobj->svp_begin($name) if $self->debug;
 914
 915   return $self->_svp_begin($name);
 916 }
 917
 918 sub svp_release {
 919   my ($self, $name) = @_;
 920
 921   $self->throw_exception ("You can't use savepoints outside a transaction")
 922     if $self->{transaction_depth} == 0;
 923
 924   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 925     unless $self->can('_svp_release');
 926
 927   if (defined $name) {
 928     $self->throw_exception ("Savepoint '$name' does not exist")
 929       unless grep { $_ eq $name } @{ $self->{savepoints} };
 930
 931     # Dig through the stack until we find the one we are releasing.  This keeps
 932     # the stack up to date.
 933     my $svp;
 934
 935     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
 936   } else {
 937     $name = pop @{ $self->{savepoints} };
 938   }
 939
 940   $self->debugobj->svp_release($name) if $self->debug;
 941
 942   return $self->_svp_release($name);
 943 }
 944
 945 sub svp_rollback {
 946   my ($self, $name) = @_;
 947
 948   $self->throw_exception ("You can't use savepoints outside a transaction")
 949     if $self->{transaction_depth} == 0;
 950
 951   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 952     unless $self->can('_svp_rollback');
 953
 954   if (defined $name) {
 955       # If they passed us a name, verify that it exists in the stack
 956       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
 957           $self->throw_exception("Savepoint '$name' does not exist!");
 958       }
 959
 960       # Dig through the stack until we find the one we are releasing.  This keeps
 961       # the stack up to date.
 962       while(my $s = pop(@{ $self->{savepoints} })) {
 963           last if($s eq $name);
 964       }
 965       # Add the savepoint back to the stack, as a rollback doesn't remove the
 966       # named savepoint, only everything after it.
 967       push(@{ $self->{savepoints} }, $name);
 968   } else {
 969       # We'll assume they want to rollback to the last savepoint
 970       $name = $self->{savepoints}->[-1];
 971   }
 972
 973   $self->debugobj->svp_rollback($name) if $self->debug;
 974
 975   return $self->_svp_rollback($name);
 976 }
 977
 978 sub _svp_generate_name {
 979     my ($self) = @_;
 980
 981     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
 982 }
 983
 984 sub txn_begin {
 985   my $self = shift;
 986   $self->ensure_connected();
 987   if($self->{transaction_depth} == 0) {
 988     $self->debugobj->txn_begin()
 989       if $self->debug;
 990     # this isn't ->_dbh-> because
 991     #  we should reconnect on begin_work
 992     #  for AutoCommit users
 993     $self->dbh->begin_work;
 994   } elsif ($self->auto_savepoint) {
 995     $self->svp_begin;
 996   }
 997   $self->{transaction_depth}++;
 998 }
 999
1000 sub txn_commit {
1001   my $self = shift;
1002   if ($self->{transaction_depth} == 1) {
1003     my $dbh = $self->_dbh;
1004     $self->debugobj->txn_commit()
1005       if ($self->debug);
1006     $dbh->commit;
1007     $self->{transaction_depth} = 0
1008       if $self->_dbh_autocommit;
1009   }
1010   elsif($self->{transaction_depth} > 1) {
1011     $self->{transaction_depth}--;
1012     $self->svp_release
1013       if $self->auto_savepoint;
1014   }
1015 }
1016
1017 sub txn_rollback {
1018   my $self = shift;
1019   my $dbh = $self->_dbh;
1020   eval {
1021     if ($self->{transaction_depth} == 1) {
1022       $self->debugobj->txn_rollback()
1023         if ($self->debug);
1024       $self->{transaction_depth} = 0
1025         if $self->_dbh_autocommit;
1026       $dbh->rollback;
1027     }
1028     elsif($self->{transaction_depth} > 1) {
1029       $self->{transaction_depth}--;
1030       if ($self->auto_savepoint) {
1031         $self->svp_rollback;
1032         $self->svp_release;
1033       }
1034     }
1035     else {
1036       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1037     }
1038   };
1039   if ($@) {
1040     my $error = $@;
1041     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1042     $error =~ /$exception_class/ and $self->throw_exception($error);
1043     # ensure that a failed rollback resets the transaction depth
1044     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1045     $self->throw_exception($error);
1046   }
1047 }
1048
1049 # This used to be the top-half of _execute.  It was split out to make it
1050 #  easier to override in NoBindVars without duping the rest.  It takes up
1051 #  all of _execute's args, and emits $sql, @bind.
1052 sub _prep_for_execute {
1053   my ($self, $op, $extra_bind, $ident, $args) = @_;
1054
1055   if( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1056     $ident = $ident->from();
1057   }
1058
1059   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1060
1061   unshift(@bind,
1062     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1063       if $extra_bind;
1064   return ($sql, \@bind);
1065 }
1066
1067
1068 sub _fix_bind_params {
1069     my ($self, @bind) = @_;
1070
1071     ### Turn @bind from something like this:
1072     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1073     ### to this:
1074     ###   ( "'1'", "'1'", "'3'" )
1075     return
1076         map {
1077             if ( defined( $_ && $_->[1] ) ) {
1078                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1079             }
1080             else { q{'NULL'}; }
1081         } @bind;
1082 }
1083
1084 sub _query_start {
1085     my ( $self, $sql, @bind ) = @_;
1086
1087     if ( $self->debug ) {
1088         @bind = $self->_fix_bind_params(@bind);
1089
1090         $self->debugobj->query_start( $sql, @bind );
1091     }
1092 }
1093
1094 sub _query_end {
1095     my ( $self, $sql, @bind ) = @_;
1096
1097     if ( $self->debug ) {
1098         @bind = $self->_fix_bind_params(@bind);
1099         $self->debugobj->query_end( $sql, @bind );
1100     }
1101 }
1102
1103 sub _dbh_execute {
1104   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1105
1106   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1107
1108   $self->_query_start( $sql, @$bind );
1109
1110   my $sth = $self->sth($sql,$op);
1111
1112   my $placeholder_index = 1;
1113
1114   foreach my $bound (@$bind) {
1115     my $attributes = {};
1116     my($column_name, @data) = @$bound;
1117
1118     if ($bind_attributes) {
1119       $attributes = $bind_attributes->{$column_name}
1120       if defined $bind_attributes->{$column_name};
1121     }
1122
1123     foreach my $data (@data) {
1124       my $ref = ref $data;
1125       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
1126
1127       $sth->bind_param($placeholder_index, $data, $attributes);
1128       $placeholder_index++;
1129     }
1130   }
1131
1132   # Can this fail without throwing an exception anyways???
1133   my $rv = $sth->execute();
1134   $self->throw_exception($sth->errstr) if !$rv;
1135
1136   $self->_query_end( $sql, @$bind );
1137
1138   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1139 }
1140
1141 sub _execute {
1142     my $self = shift;
1143     $self->dbh_do('_dbh_execute', @_)
1144 }
1145
1146 sub insert {
1147   my ($self, $source, $to_insert) = @_;
1148
1149   my $ident = $source->from;
1150   my $bind_attributes = $self->source_bind_attributes($source);
1151
1152   my $updated_cols = {};
1153
1154   $self->ensure_connected;
1155   foreach my $col ( $source->columns ) {
1156     if ( !defined $to_insert->{$col} ) {
1157       my $col_info = $source->column_info($col);
1158
1159       if ( $col_info->{auto_nextval} ) {
1160         $updated_cols->{$col} = $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1161       }
1162     }
1163   }
1164
1165   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1166
1167   return $updated_cols;
1168 }
1169
1170 ## Still not quite perfect, and EXPERIMENTAL
1171 ## Currently it is assumed that all values passed will be "normal", i.e. not
1172 ## scalar refs, or at least, all the same type as the first set, the statement is
1173 ## only prepped once.
1174 sub insert_bulk {
1175   my ($self, $source, $cols, $data) = @_;
1176   my %colvalues;
1177   my $table = $source->from;
1178   @colvalues{@$cols} = (0..$#$cols);
1179   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1180
1181   $self->_query_start( $sql, @bind );
1182   my $sth = $self->sth($sql);
1183
1184 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1185
1186   ## This must be an arrayref, else nothing works!
1187   my $tuple_status = [];
1188
1189   ## Get the bind_attributes, if any exist
1190   my $bind_attributes = $self->source_bind_attributes($source);
1191
1192   ## Bind the values and execute
1193   my $placeholder_index = 1;
1194
1195   foreach my $bound (@bind) {
1196
1197     my $attributes = {};
1198     my ($column_name, $data_index) = @$bound;
1199
1200     if( $bind_attributes ) {
1201       $attributes = $bind_attributes->{$column_name}
1202       if defined $bind_attributes->{$column_name};
1203     }
1204
1205     my @data = map { $_->[$data_index] } @$data;
1206
1207     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1208     $placeholder_index++;
1209   }
1210   my $rv = eval { $sth->execute_array({ArrayTupleStatus => $tuple_status}) };
1211   if (my $err = $@) {
1212     my $i = 0;
1213     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
1214
1215     $self->throw_exception($sth->errstr || "Unexpected populate error: $err")
1216       if ($i > $#$tuple_status);
1217
1218     require Data::Dumper;
1219     local $Data::Dumper::Terse = 1;
1220     local $Data::Dumper::Indent = 1;
1221     local $Data::Dumper::Useqq = 1;
1222     local $Data::Dumper::Quotekeys = 0;
1223
1224     $self->throw_exception(sprintf "%s for populate slice:\n%s",
1225       $tuple_status->[$i][1],
1226       Data::Dumper::Dumper(
1227         { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) }
1228       ),
1229     );
1230   }
1231   $self->throw_exception($sth->errstr) if !$rv;
1232
1233   $self->_query_end( $sql, @bind );
1234   return (wantarray ? ($rv, $sth, @bind) : $rv);
1235 }
1236
1237 sub update {
1238   my $self = shift @_;
1239   my $source = shift @_;
1240   my $bind_attributes = $self->source_bind_attributes($source);
1241
1242   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1243 }
1244
1245
1246 sub delete {
1247   my $self = shift @_;
1248   my $source = shift @_;
1249
1250   my $bind_attrs = $self->source_bind_attributes($source);
1251
1252   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1253 }
1254
1255 # We were sent here because the $rs contains a complex search
1256 # which will require a subquery to select the correct rows
1257 # (i.e. joined or limited resultsets)
1258 #
1259 # Genarating a single PK column subquery is trivial and supported
1260 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1261 # Look at _multipk_update_delete()
1262 sub _subq_update_delete {
1263   my $self = shift;
1264   my ($rs, $op, $values) = @_;
1265
1266   my $rsrc = $rs->result_source;
1267
1268   # we already check this, but double check naively just in case. Should be removed soon
1269   my $sel = $rs->_resolved_attrs->{select};
1270   $sel = [ $sel ] unless ref $sel eq 'ARRAY';
1271   my @pcols = $rsrc->primary_columns;
1272   if (@$sel != @pcols) {
1273     $self->throw_exception (
1274       'Subquery update/delete can not be called on resultsets selecting a'
1275      .' number of columns different than the number of primary keys'
1276     );
1277   }
1278
1279   if (@pcols == 1) {
1280     return $self->$op (
1281       $rsrc,
1282       $op eq 'update' ? $values : (),
1283       { $pcols[0] => { -in => $rs->as_query } },
1284     );
1285   }
1286
1287   else {
1288     return $self->_multipk_update_delete (@_);
1289   }
1290 }
1291
1292 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1293 # resultset update/delete involving subqueries. So by default resort
1294 # to simple (and inefficient) delete_all style per-row opearations,
1295 # while allowing specific storages to override this with a faster
1296 # implementation.
1297 #
1298 sub _multipk_update_delete {
1299   return shift->_per_row_update_delete (@_);
1300 }
1301
1302 # This is the default loop used to delete/update rows for multi PK
1303 # resultsets, and used by mysql exclusively (because it can't do anything
1304 # else).
1305 #
1306 # We do not use $row->$op style queries, because resultset update/delete
1307 # is not expected to cascade (this is what delete_all/update_all is for).
1308 #
1309 # There should be no race conditions as the entire operation is rolled
1310 # in a transaction.
1311 #
1312 sub _per_row_update_delete {
1313   my $self = shift;
1314   my ($rs, $op, $values) = @_;
1315
1316   my $rsrc = $rs->result_source;
1317   my @pcols = $rsrc->primary_columns;
1318
1319   my $guard = $self->txn_scope_guard;
1320
1321   # emulate the return value of $sth->execute for non-selects
1322   my $row_cnt = '0E0';
1323
1324   my $subrs_cur = $rs->cursor;
1325   while (my @pks = $subrs_cur->next) {
1326
1327     my $cond;
1328     for my $i (0.. $#pcols) {
1329       $cond->{$pcols[$i]} = $pks[$i];
1330     }
1331
1332     $self->$op (
1333       $rsrc,
1334       $op eq 'update' ? $values : (),
1335       $cond,
1336     );
1337
1338     $row_cnt++;
1339   }
1340
1341   $guard->commit;
1342
1343   return $row_cnt;
1344 }
1345
1346 sub _select {
1347   my $self = shift;
1348   my $sql_maker = $self->sql_maker;
1349   local $sql_maker->{for};
1350   return $self->_execute($self->_select_args(@_));
1351 }
1352
1353 sub _select_args_to_query {
1354   my $self = shift;
1355
1356   my $sql_maker = $self->sql_maker;
1357   local $sql_maker->{for};
1358
1359   # my ($op, $bind, $ident, $bind_attrs, $select, $cond, $order, $rows, $offset)
1360   #  = $self->_select_args($ident, $select, $cond, $attrs);
1361   my ($op, $bind, $ident, $bind_attrs, @args) =
1362     $self->_select_args(@_);
1363
1364   # my ($sql, $bind) = $self->_prep_for_execute($op, $bind, $ident, [ $select, $cond, $order, $rows, $offset ]);
1365   my ($sql, $prepared_bind) = $self->_prep_for_execute($op, $bind, $ident, \@args);
1366
1367   return \[ "($sql)", @{ $prepared_bind || [] }];
1368 }
1369
1370 sub _select_args {
1371   my ($self, $ident, $select, $condition, $attrs) = @_;
1372
1373   my $for = delete $attrs->{for};
1374   my $sql_maker = $self->sql_maker;
1375   $sql_maker->{for} = $for;
1376
1377   my $order = { map
1378     { $attrs->{$_} ? ( $_ => $attrs->{$_} ) : ()  }
1379     (qw/order_by group_by having _virtual_order_by/ )
1380   };
1381
1382
1383   my $bind_attrs = {};
1384
1385   my $alias2source = $self->_resolve_ident_sources ($ident);
1386
1387   for my $alias (keys %$alias2source) {
1388     my $bindtypes = $self->source_bind_attributes ($alias2source->{$alias}) || {};
1389     for my $col (keys %$bindtypes) {
1390
1391       my $fqcn = join ('.', $alias, $col);
1392       $bind_attrs->{$fqcn} = $bindtypes->{$col} if $bindtypes->{$col};
1393
1394       # so that unqualified searches can be bound too
1395       $bind_attrs->{$col} = $bind_attrs->{$fqcn} if $alias eq 'me';
1396     }
1397   }
1398
1399   # This would be the point to deflate anything found in $condition
1400   # (and leave $attrs->{bind} intact). Problem is - inflators historically
1401   # expect a row object. And all we have is a resultsource (it is trivial
1402   # to extract deflator coderefs via $alias2source above).
1403   #
1404   # I don't see a way forward other than changing the way deflators are
1405   # invoked, and that's just bad...
1406
1407   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1408   if ($attrs->{software_limit} ||
1409       $sql_maker->_default_limit_syntax eq "GenericSubQ") {
1410         $attrs->{software_limit} = 1;
1411   } else {
1412     $self->throw_exception("rows attribute must be positive if present")
1413       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1414
1415     # MySQL actually recommends this approach.  I cringe.
1416     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1417     push @args, $attrs->{rows}, $attrs->{offset};
1418   }
1419   return @args;
1420 }
1421
1422 sub _resolve_ident_sources {
1423   my ($self, $ident) = @_;
1424
1425   my $alias2source = {};
1426
1427   # the reason this is so contrived is that $ident may be a {from}
1428   # structure, specifying multiple tables to join
1429   if ( Scalar::Util::blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1430     # this is compat mode for insert/update/delete which do not deal with aliases
1431     $alias2source->{me} = $ident;
1432   }
1433   elsif (ref $ident eq 'ARRAY') {
1434
1435     for (@$ident) {
1436       my $tabinfo;
1437       if (ref $_ eq 'HASH') {
1438         $tabinfo = $_;
1439       }
1440       if (ref $_ eq 'ARRAY' and ref $_->[0] eq 'HASH') {
1441         $tabinfo = $_->[0];
1442       }
1443
1444       $alias2source->{$tabinfo->{-alias}} = $tabinfo->{-result_source}
1445         if ($tabinfo->{-result_source});
1446     }
1447   }
1448
1449   return $alias2source;
1450 }
1451
1452 sub count {
1453   my ($self, $source, $attrs) = @_;
1454
1455   my $tmp_attrs = { %$attrs };
1456
1457   # take off any pagers, record_filter is cdbi, and no point of ordering a count
1458   delete $tmp_attrs->{$_} for (qw/select as rows offset page order_by record_filter/);
1459
1460   # overwrite the selector
1461   $tmp_attrs->{select} = { count => '*' };
1462
1463   my $tmp_rs = $source->resultset_class->new($source, $tmp_attrs);
1464   my ($count) = $tmp_rs->cursor->next;
1465
1466   # if the offset/rows attributes are still present, we did not use
1467   # a subquery, so we need to make the calculations in software
1468   $count -= $attrs->{offset} if $attrs->{offset};
1469   $count = $attrs->{rows} if $attrs->{rows} and $attrs->{rows} < $count;
1470   $count = 0 if ($count < 0);
1471
1472   return $count;
1473 }
1474
1475 sub count_grouped {
1476   my ($self, $source, $attrs) = @_;
1477
1478   # copy for the subquery, we need to do some adjustments to it too
1479   my $sub_attrs = { %$attrs };
1480
1481   # these can not go in the subquery, and there is no point of ordering it
1482   delete $sub_attrs->{$_} for qw/prefetch collapse select as order_by/;
1483
1484   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1485   # simply deleting group_by suffices, as the code below will re-fill it
1486   # Note: we check $attrs, as $sub_attrs has collapse deleted
1487   if (ref $attrs->{collapse} and keys %{$attrs->{collapse}} ) {
1488     delete $sub_attrs->{group_by};
1489   }
1490
1491   $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($source->primary_columns) ];
1492   $sub_attrs->{select} = $self->_grouped_count_select ($source, $sub_attrs);
1493
1494   $attrs->{from} = [{
1495     count_subq => $source->resultset_class->new ($source, $sub_attrs )->as_query
1496   }];
1497
1498   # the subquery replaces this
1499   delete $attrs->{$_} for qw/where bind prefetch collapse group_by having having_bind rows offset page pager/;
1500
1501   return $self->count ($source, $attrs);
1502 }
1503
1504 #
1505 # Returns a SELECT to go with a supplied GROUP BY
1506 # (caled by count_grouped so a group_by is present)
1507 # Most databases expect them to match, but some
1508 # choke in various ways.
1509 #
1510 sub _grouped_count_select {
1511   my ($self, $source, $rs_args) = @_;
1512   return $rs_args->{group_by};
1513 }
1514
1515 sub source_bind_attributes {
1516   my ($self, $source) = @_;
1517
1518   my $bind_attributes;
1519   foreach my $column ($source->columns) {
1520
1521     my $data_type = $source->column_info($column)->{data_type} || '';
1522     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1523      if $data_type;
1524   }
1525
1526   return $bind_attributes;
1527 }
1528
1529 =head2 select
1530
1531 =over 4
1532
1533 =item Arguments: $ident, $select, $condition, $attrs
1534
1535 =back
1536
1537 Handle a SQL select statement.
1538
1539 =cut
1540
1541 sub select {
1542   my $self = shift;
1543   my ($ident, $select, $condition, $attrs) = @_;
1544   return $self->cursor_class->new($self, \@_, $attrs);
1545 }
1546
1547 sub select_single {
1548   my $self = shift;
1549   my ($rv, $sth, @bind) = $self->_select(@_);
1550   my @row = $sth->fetchrow_array;
1551   my @nextrow = $sth->fetchrow_array if @row;
1552   if(@row && @nextrow) {
1553     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1554   }
1555   # Need to call finish() to work round broken DBDs
1556   $sth->finish();
1557   return @row;
1558 }
1559
1560 =head2 sth
1561
1562 =over 4
1563
1564 =item Arguments: $sql
1565
1566 =back
1567
1568 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1569
1570 =cut
1571
1572 sub _dbh_sth {
1573   my ($self, $dbh, $sql) = @_;
1574
1575   # 3 is the if_active parameter which avoids active sth re-use
1576   my $sth = $self->disable_sth_caching
1577     ? $dbh->prepare($sql)
1578     : $dbh->prepare_cached($sql, {}, 3);
1579
1580   # XXX You would think RaiseError would make this impossible,
1581   #  but apparently that's not true :(
1582   $self->throw_exception($dbh->errstr) if !$sth;
1583
1584   $sth;
1585 }
1586
1587 sub sth {
1588   my ($self, $sql) = @_;
1589   $self->dbh_do('_dbh_sth', $sql);
1590 }
1591
1592 sub _dbh_columns_info_for {
1593   my ($self, $dbh, $table) = @_;
1594
1595   if ($dbh->can('column_info')) {
1596     my %result;
1597     eval {
1598       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1599       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1600       $sth->execute();
1601       while ( my $info = $sth->fetchrow_hashref() ){
1602         my %column_info;
1603         $column_info{data_type}   = $info->{TYPE_NAME};
1604         $column_info{size}      = $info->{COLUMN_SIZE};
1605         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1606         $column_info{default_value} = $info->{COLUMN_DEF};
1607         my $col_name = $info->{COLUMN_NAME};
1608         $col_name =~ s/^\"(.*)\"$/$1/;
1609
1610         $result{$col_name} = \%column_info;
1611       }
1612     };
1613     return \%result if !$@ && scalar keys %result;
1614   }
1615
1616   my %result;
1617   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1618   $sth->execute;
1619   my @columns = @{$sth->{NAME_lc}};
1620   for my $i ( 0 .. $#columns ){
1621     my %column_info;
1622     $column_info{data_type} = $sth->{TYPE}->[$i];
1623     $column_info{size} = $sth->{PRECISION}->[$i];
1624     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1625
1626     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1627       $column_info{data_type} = $1;
1628       $column_info{size}    = $2;
1629     }
1630
1631     $result{$columns[$i]} = \%column_info;
1632   }
1633   $sth->finish;
1634
1635   foreach my $col (keys %result) {
1636     my $colinfo = $result{$col};
1637     my $type_num = $colinfo->{data_type};
1638     my $type_name;
1639     if(defined $type_num && $dbh->can('type_info')) {
1640       my $type_info = $dbh->type_info($type_num);
1641       $type_name = $type_info->{TYPE_NAME} if $type_info;
1642       $colinfo->{data_type} = $type_name if $type_name;
1643     }
1644   }
1645
1646   return \%result;
1647 }
1648
1649 sub columns_info_for {
1650   my ($self, $table) = @_;
1651   $self->dbh_do('_dbh_columns_info_for', $table);
1652 }
1653
1654 =head2 last_insert_id
1655
1656 Return the row id of the last insert.
1657
1658 =cut
1659
1660 sub _dbh_last_insert_id {
1661     # All Storage's need to register their own _dbh_last_insert_id
1662     # the old SQLite-based method was highly inappropriate
1663
1664     my $self = shift;
1665     my $class = ref $self;
1666     $self->throw_exception (<<EOE);
1667
1668 No _dbh_last_insert_id() method found in $class.
1669 Since the method of obtaining the autoincrement id of the last insert
1670 operation varies greatly between different databases, this method must be
1671 individually implemented for every storage class.
1672 EOE
1673 }
1674
1675 sub last_insert_id {
1676   my $self = shift;
1677   $self->dbh_do('_dbh_last_insert_id', @_);
1678 }
1679
1680 =head2 sqlt_type
1681
1682 Returns the database driver name.
1683
1684 =cut
1685
1686 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1687
1688 =head2 bind_attribute_by_data_type
1689
1690 Given a datatype from column info, returns a database specific bind
1691 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
1692 let the database planner just handle it.
1693
1694 Generally only needed for special case column types, like bytea in postgres.
1695
1696 =cut
1697
1698 sub bind_attribute_by_data_type {
1699     return;
1700 }
1701
1702 =head2 is_datatype_numeric
1703
1704 Given a datatype from column_info, returns a boolean value indicating if
1705 the current RDBMS considers it a numeric value. This controls how
1706 L<DBIx::Class::Row/set_column> decides whether to mark the column as
1707 dirty - when the datatype is deemed numeric a C<< != >> comparison will
1708 be performed instead of the usual C<eq>.
1709
1710 =cut
1711
1712 sub is_datatype_numeric {
1713   my ($self, $dt) = @_;
1714
1715   return 0 unless $dt;
1716
1717   return $dt =~ /^ (?:
1718     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
1719   ) $/ix;
1720 }
1721
1722
1723 =head2 create_ddl_dir (EXPERIMENTAL)
1724
1725 =over 4
1726
1727 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1728
1729 =back
1730
1731 Creates a SQL file based on the Schema, for each of the specified
1732 database engines in C<\@databases> in the given directory.
1733 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
1734
1735 Given a previous version number, this will also create a file containing
1736 the ALTER TABLE statements to transform the previous schema into the
1737 current one. Note that these statements may contain C<DROP TABLE> or
1738 C<DROP COLUMN> statements that can potentially destroy data.
1739
1740 The file names are created using the C<ddl_filename> method below, please
1741 override this method in your schema if you would like a different file
1742 name format. For the ALTER file, the same format is used, replacing
1743 $version in the name with "$preversion-$version".
1744
1745 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
1746 The most common value for this would be C<< { add_drop_table => 1 } >>
1747 to have the SQL produced include a C<DROP TABLE> statement for each table
1748 created. For quoting purposes supply C<quote_table_names> and
1749 C<quote_field_names>.
1750
1751 If no arguments are passed, then the following default values are assumed:
1752
1753 =over 4
1754
1755 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
1756
1757 =item version    - $schema->schema_version
1758
1759 =item directory  - './'
1760
1761 =item preversion - <none>
1762
1763 =back
1764
1765 By default, C<\%sqlt_args> will have
1766
1767  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1768
1769 merged with the hash passed in. To disable any of those features, pass in a
1770 hashref like the following
1771
1772  { ignore_constraint_names => 0, # ... other options }
1773
1774
1775 Note that this feature is currently EXPERIMENTAL and may not work correctly
1776 across all databases, or fully handle complex relationships.
1777
1778 WARNING: Please check all SQL files created, before applying them.
1779
1780 =cut
1781
1782 sub create_ddl_dir {
1783   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1784
1785   if(!$dir || !-d $dir) {
1786     carp "No directory given, using ./\n";
1787     $dir = "./";
1788   }
1789   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1790   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1791
1792   my $schema_version = $schema->schema_version || '1.x';
1793   $version ||= $schema_version;
1794
1795   $sqltargs = {
1796     add_drop_table => 1,
1797     ignore_constraint_names => 1,
1798     ignore_index_names => 1,
1799     %{$sqltargs || {}}
1800   };
1801
1802   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09003: '}
1803       . $self->_check_sqlt_message . q{'})
1804           if !$self->_check_sqlt_version;
1805
1806   my $sqlt = SQL::Translator->new( $sqltargs );
1807
1808   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1809   my $sqlt_schema = $sqlt->translate({ data => $schema })
1810     or $self->throw_exception ($sqlt->error);
1811
1812   foreach my $db (@$databases) {
1813     $sqlt->reset();
1814     $sqlt->{schema} = $sqlt_schema;
1815     $sqlt->producer($db);
1816
1817     my $file;
1818     my $filename = $schema->ddl_filename($db, $version, $dir);
1819     if (-e $filename && ($version eq $schema_version )) {
1820       # if we are dumping the current version, overwrite the DDL
1821       carp "Overwriting existing DDL file - $filename";
1822       unlink($filename);
1823     }
1824
1825     my $output = $sqlt->translate;
1826     if(!$output) {
1827       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1828       next;
1829     }
1830     if(!open($file, ">$filename")) {
1831       $self->throw_exception("Can't open $filename for writing ($!)");
1832       next;
1833     }
1834     print $file $output;
1835     close($file);
1836
1837     next unless ($preversion);
1838
1839     require SQL::Translator::Diff;
1840
1841     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1842     if(!-e $prefilename) {
1843       carp("No previous schema file found ($prefilename)");
1844       next;
1845     }
1846
1847     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1848     if(-e $difffile) {
1849       carp("Overwriting existing diff file - $difffile");
1850       unlink($difffile);
1851     }
1852
1853     my $source_schema;
1854     {
1855       my $t = SQL::Translator->new($sqltargs);
1856       $t->debug( 0 );
1857       $t->trace( 0 );
1858
1859       $t->parser( $db )
1860         or $self->throw_exception ($t->error);
1861
1862       my $out = $t->translate( $prefilename )
1863         or $self->throw_exception ($t->error);
1864
1865       $source_schema = $t->schema;
1866
1867       $source_schema->name( $prefilename )
1868         unless ( $source_schema->name );
1869     }
1870
1871     # The "new" style of producers have sane normalization and can support
1872     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1873     # And we have to diff parsed SQL against parsed SQL.
1874     my $dest_schema = $sqlt_schema;
1875
1876     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1877       my $t = SQL::Translator->new($sqltargs);
1878       $t->debug( 0 );
1879       $t->trace( 0 );
1880
1881       $t->parser( $db )
1882         or $self->throw_exception ($t->error);
1883
1884       my $out = $t->translate( $filename )
1885         or $self->throw_exception ($t->error);
1886
1887       $dest_schema = $t->schema;
1888
1889       $dest_schema->name( $filename )
1890         unless $dest_schema->name;
1891     }
1892
1893     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1894                                                   $dest_schema,   $db,
1895                                                   $sqltargs
1896                                                  );
1897     if(!open $file, ">$difffile") {
1898       $self->throw_exception("Can't write to $difffile ($!)");
1899       next;
1900     }
1901     print $file $diff;
1902     close($file);
1903   }
1904 }
1905
1906 =head2 deployment_statements
1907
1908 =over 4
1909
1910 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1911
1912 =back
1913
1914 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1915
1916 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
1917 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
1918
1919 C<$directory> is used to return statements from files in a previously created
1920 L</create_ddl_dir> directory and is optional. The filenames are constructed
1921 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1922
1923 If no C<$directory> is specified then the statements are constructed on the
1924 fly using L<SQL::Translator> and C<$version> is ignored.
1925
1926 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1927
1928 =cut
1929
1930 sub deployment_statements {
1931   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1932   # Need to be connected to get the correct sqlt_type
1933   $self->ensure_connected() unless $type;
1934   $type ||= $self->sqlt_type;
1935   $version ||= $schema->schema_version || '1.x';
1936   $dir ||= './';
1937   my $filename = $schema->ddl_filename($type, $version, $dir);
1938   if(-f $filename)
1939   {
1940       my $file;
1941       open($file, "<$filename")
1942         or $self->throw_exception("Can't open $filename ($!)");
1943       my @rows = <$file>;
1944       close($file);
1945       return join('', @rows);
1946   }
1947
1948   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09003: '}
1949       . $self->_check_sqlt_message . q{'})
1950           if !$self->_check_sqlt_version;
1951
1952   require SQL::Translator::Parser::DBIx::Class;
1953   eval qq{use SQL::Translator::Producer::${type}};
1954   $self->throw_exception($@) if $@;
1955
1956   # sources needs to be a parser arg, but for simplicty allow at top level
1957   # coming in
1958   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1959       if exists $sqltargs->{sources};
1960
1961   my $tr = SQL::Translator->new(%$sqltargs);
1962   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1963   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1964 }
1965
1966 sub deploy {
1967   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1968   my $deploy = sub {
1969     my $line = shift;
1970     return if($line =~ /^--/);
1971     return if(!$line);
1972     # next if($line =~ /^DROP/m);
1973     return if($line =~ /^BEGIN TRANSACTION/m);
1974     return if($line =~ /^COMMIT/m);
1975     return if $line =~ /^\s+$/; # skip whitespace only
1976     $self->_query_start($line);
1977     eval {
1978       $self->dbh->do($line); # shouldn't be using ->dbh ?
1979     };
1980     if ($@) {
1981       carp qq{$@ (running "${line}")};
1982     }
1983     $self->_query_end($line);
1984   };
1985   my @statements = $self->deployment_statements($schema, $type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
1986   if (@statements > 1) {
1987     foreach my $statement (@statements) {
1988       $deploy->( $statement );
1989     }
1990   }
1991   elsif (@statements == 1) {
1992     foreach my $line ( split(";\n", $statements[0])) {
1993       $deploy->( $line );
1994     }
1995   }
1996 }
1997
1998 =head2 datetime_parser
1999
2000 Returns the datetime parser class
2001
2002 =cut
2003
2004 sub datetime_parser {
2005   my $self = shift;
2006   return $self->{datetime_parser} ||= do {
2007     $self->ensure_connected;
2008     $self->build_datetime_parser(@_);
2009   };
2010 }
2011
2012 =head2 datetime_parser_type
2013
2014 Defines (returns) the datetime parser class - currently hardwired to
2015 L<DateTime::Format::MySQL>
2016
2017 =cut
2018
2019 sub datetime_parser_type { "DateTime::Format::MySQL"; }
2020
2021 =head2 build_datetime_parser
2022
2023 See L</datetime_parser>
2024
2025 =cut
2026
2027 sub build_datetime_parser {
2028   my $self = shift;
2029   my $type = $self->datetime_parser_type(@_);
2030   eval "use ${type}";
2031   $self->throw_exception("Couldn't load ${type}: $@") if $@;
2032   return $type;
2033 }
2034
2035 {
2036     my $_check_sqlt_version; # private
2037     my $_check_sqlt_message; # private
2038     sub _check_sqlt_version {
2039         return $_check_sqlt_version if defined $_check_sqlt_version;
2040         eval 'use SQL::Translator "0.09003"';
2041         $_check_sqlt_message = $@ || '';
2042         $_check_sqlt_version = !$@;
2043     }
2044
2045     sub _check_sqlt_message {
2046         _check_sqlt_version if !defined $_check_sqlt_message;
2047         $_check_sqlt_message;
2048     }
2049 }
2050
2051 =head2 is_replicating
2052
2053 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
2054 replicate from a master database.  Default is undef, which is the result
2055 returned by databases that don't support replication.
2056
2057 =cut
2058
2059 sub is_replicating {
2060     return;
2061
2062 }
2063
2064 =head2 lag_behind_master
2065
2066 Returns a number that represents a certain amount of lag behind a master db
2067 when a given storage is replicating.  The number is database dependent, but
2068 starts at zero and increases with the amount of lag. Default in undef
2069
2070 =cut
2071
2072 sub lag_behind_master {
2073     return;
2074 }
2075
2076 sub DESTROY {
2077   my $self = shift;
2078   return if !$self->_dbh;
2079   $self->_verify_pid;
2080   $self->_dbh(undef);
2081 }
2082
2083 1;
2084
2085 =head1 USAGE NOTES
2086
2087 =head2 DBIx::Class and AutoCommit
2088
2089 DBIx::Class can do some wonderful magic with handling exceptions,
2090 disconnections, and transactions when you use C<< AutoCommit => 1 >>
2091 combined with C<txn_do> for transaction support.
2092
2093 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
2094 in an assumed transaction between commits, and you're telling us you'd
2095 like to manage that manually.  A lot of the magic protections offered by
2096 this module will go away.  We can't protect you from exceptions due to database
2097 disconnects because we don't know anything about how to restart your
2098 transactions.  You're on your own for handling all sorts of exceptional
2099 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
2100 be with raw DBI.
2101
2102
2103
2104 =head1 AUTHORS
2105
2106 Matt S. Trout <mst@shadowcatsystems.co.uk>
2107
2108 Andy Grundman <andy@hybridized.org>
2109
2110 =head1 LICENSE
2111
2112 You may distribute this code under the same terms as Perl itself.
2113
2114 =cut