lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid disable_sth_caching on_connect_do
  18        on_disconnect_do transaction_depth unsafe _dbh_autocommit
  19        auto_savepoint savepoints/
  20 );
  21
  22 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  23
  24 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  25 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  26
  27 BEGIN {
  28
  29 package # Hide from PAUSE
  30   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  31
  32 use base qw/SQL::Abstract::Limit/;
  33
  34 # This prevents the caching of $dbh in S::A::L, I believe
  35 sub new {
  36   my $self = shift->SUPER::new(@_);
  37
  38   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  39   #   it with what it resolves to:
  40   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  41     if ref $self->{limit_dialect};
  42
  43   $self;
  44 }
  45
  46 sub _RowNumberOver {
  47   my ($self, $sql, $order, $rows, $offset ) = @_;
  48
  49   $offset += 1;
  50   my $last = $rows + $offset;
  51   my ( $order_by ) = $self->_order_by( $order );
  52
  53   $sql = <<"";
  54 SELECT * FROM
  55 (
  56    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  57       $sql
  58       $order_by
  59    ) Q1
  60 ) Q2
  61 WHERE ROW_NUM BETWEEN $offset AND $last
  62
  63   return $sql;
  64 }
  65
  66
  67 # While we're at it, this should make LIMIT queries more efficient,
  68 #  without digging into things too deeply
  69 use Scalar::Util 'blessed';
  70 sub _find_syntax {
  71   my ($self, $syntax) = @_;
  72   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  73   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  74     return 'RowNumberOver';
  75   }
  76
  77   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  78 }
  79
  80 sub select {
  81   my ($self, $table, $fields, $where, $order, @rest) = @_;
  82   $table = $self->_quote($table) unless ref($table);
  83   local $self->{rownum_hack_count} = 1
  84     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  85   @rest = (-1) unless defined $rest[0];
  86   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  87     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  88   local $self->{having_bind} = [];
  89   my ($sql, @ret) = $self->SUPER::select(
  90     $table, $self->_recurse_fields($fields), $where, $order, @rest
  91   );
  92   $sql .=
  93     $self->{for} ?
  94     (
  95       $self->{for} eq 'update' ? ' FOR UPDATE' :
  96       $self->{for} eq 'shared' ? ' FOR SHARE'  :
  97       ''
  98     ) :
  99     ''
 100   ;
 101   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
 102 }
 103
 104 sub insert {
 105   my $self = shift;
 106   my $table = shift;
 107   $table = $self->_quote($table) unless ref($table);
 108   $self->SUPER::insert($table, @_);
 109 }
 110
 111 sub update {
 112   my $self = shift;
 113   my $table = shift;
 114   $table = $self->_quote($table) unless ref($table);
 115   $self->SUPER::update($table, @_);
 116 }
 117
 118 sub delete {
 119   my $self = shift;
 120   my $table = shift;
 121   $table = $self->_quote($table) unless ref($table);
 122   $self->SUPER::delete($table, @_);
 123 }
 124
 125 sub _emulate_limit {
 126   my $self = shift;
 127   if ($_[3] == -1) {
 128     return $_[1].$self->_order_by($_[2]);
 129   } else {
 130     return $self->SUPER::_emulate_limit(@_);
 131   }
 132 }
 133
 134 sub _recurse_fields {
 135   my ($self, $fields, $params) = @_;
 136   my $ref = ref $fields;
 137   return $self->_quote($fields) unless $ref;
 138   return $$fields if $ref eq 'SCALAR';
 139
 140   if ($ref eq 'ARRAY') {
 141     return join(', ', map {
 142       $self->_recurse_fields($_)
 143         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 144           ? ' AS col'.$self->{rownum_hack_count}++
 145           : '')
 146       } @$fields);
 147   } elsif ($ref eq 'HASH') {
 148     foreach my $func (keys %$fields) {
 149       return $self->_sqlcase($func)
 150         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 151     }
 152   }
 153 }
 154
 155 sub _order_by {
 156   my $self = shift;
 157   my $ret = '';
 158   my @extra;
 159   if (ref $_[0] eq 'HASH') {
 160     if (defined $_[0]->{group_by}) {
 161       $ret = $self->_sqlcase(' group by ')
 162         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 163     }
 164     if (defined $_[0]->{having}) {
 165       my $frag;
 166       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 167       push(@{$self->{having_bind}}, @extra);
 168       $ret .= $self->_sqlcase(' having ').$frag;
 169     }
 170     if (defined $_[0]->{order_by}) {
 171       $ret .= $self->_order_by($_[0]->{order_by});
 172     }
 173   } elsif (ref $_[0] eq 'SCALAR') {
 174     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 175   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 176     my @order = @{+shift};
 177     $ret = $self->_sqlcase(' order by ')
 178           .join(', ', map {
 179                         my $r = $self->_order_by($_, @_);
 180                         $r =~ s/^ ?ORDER BY //i;
 181                         $r;
 182                       } @order);
 183   } else {
 184     $ret = $self->SUPER::_order_by(@_);
 185   }
 186   return $ret;
 187 }
 188
 189 sub _order_directions {
 190   my ($self, $order) = @_;
 191   $order = $order->{order_by} if ref $order eq 'HASH';
 192   return $self->SUPER::_order_directions($order);
 193 }
 194
 195 sub _table {
 196   my ($self, $from) = @_;
 197   if (ref $from eq 'ARRAY') {
 198     return $self->_recurse_from(@$from);
 199   } elsif (ref $from eq 'HASH') {
 200     return $self->_make_as($from);
 201   } else {
 202     return $from; # would love to quote here but _table ends up getting called
 203                   # twice during an ->select without a limit clause due to
 204                   # the way S::A::Limit->select works. should maybe consider
 205                   # bypassing this and doing S::A::select($self, ...) in
 206                   # our select method above. meantime, quoting shims have
 207                   # been added to select/insert/update/delete here
 208   }
 209 }
 210
 211 sub _recurse_from {
 212   my ($self, $from, @join) = @_;
 213   my @sqlf;
 214   push(@sqlf, $self->_make_as($from));
 215   foreach my $j (@join) {
 216     my ($to, $on) = @$j;
 217
 218     # check whether a join type exists
 219     my $join_clause = '';
 220     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 221     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 222       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 223     } else {
 224       $join_clause = ' JOIN ';
 225     }
 226     push(@sqlf, $join_clause);
 227
 228     if (ref $to eq 'ARRAY') {
 229       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 230     } else {
 231       push(@sqlf, $self->_make_as($to));
 232     }
 233     push(@sqlf, ' ON ', $self->_join_condition($on));
 234   }
 235   return join('', @sqlf);
 236 }
 237
 238 sub _make_as {
 239   my ($self, $from) = @_;
 240   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 241                      reverse each %{$self->_skip_options($from)});
 242 }
 243
 244 sub _skip_options {
 245   my ($self, $hash) = @_;
 246   my $clean_hash = {};
 247   $clean_hash->{$_} = $hash->{$_}
 248     for grep {!/^-/} keys %$hash;
 249   return $clean_hash;
 250 }
 251
 252 sub _join_condition {
 253   my ($self, $cond) = @_;
 254   if (ref $cond eq 'HASH') {
 255     my %j;
 256     for (keys %$cond) {
 257       my $v = $cond->{$_};
 258       if (ref $v) {
 259         # XXX no throw_exception() in this package and croak() fails with strange results
 260         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 261             if ref($v) ne 'SCALAR';
 262         $j{$_} = $v;
 263       }
 264       else {
 265         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 266       }
 267     };
 268     return scalar($self->_recurse_where(\%j));
 269   } elsif (ref $cond eq 'ARRAY') {
 270     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 271   } else {
 272     die "Can't handle this yet!";
 273   }
 274 }
 275
 276 sub _quote {
 277   my ($self, $label) = @_;
 278   return '' unless defined $label;
 279   return "*" if $label eq '*';
 280   return $label unless $self->{quote_char};
 281   if(ref $self->{quote_char} eq "ARRAY"){
 282     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 283       if !defined $self->{name_sep};
 284     my $sep = $self->{name_sep};
 285     return join($self->{name_sep},
 286         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 287        split(/\Q$sep\E/,$label));
 288   }
 289   return $self->SUPER::_quote($label);
 290 }
 291
 292 sub limit_dialect {
 293     my $self = shift;
 294     $self->{limit_dialect} = shift if @_;
 295     return $self->{limit_dialect};
 296 }
 297
 298 sub quote_char {
 299     my $self = shift;
 300     $self->{quote_char} = shift if @_;
 301     return $self->{quote_char};
 302 }
 303
 304 sub name_sep {
 305     my $self = shift;
 306     $self->{name_sep} = shift if @_;
 307     return $self->{name_sep};
 308 }
 309
 310 } # End of BEGIN block
 311
 312 =head1 NAME
 313
 314 DBIx::Class::Storage::DBI - DBI storage handler
 315
 316 =head1 SYNOPSIS
 317
 318 =head1 DESCRIPTION
 319
 320 This class represents the connection to an RDBMS via L<DBI>.  See
 321 L<DBIx::Class::Storage> for general information.  This pod only
 322 documents DBI-specific methods and behaviors.
 323
 324 =head1 METHODS
 325
 326 =cut
 327
 328 sub new {
 329   my $new = shift->next::method(@_);
 330
 331   $new->transaction_depth(0);
 332   $new->_sql_maker_opts({});
 333   $new->{savepoints} = [];
 334   $new->{_in_dbh_do} = 0;
 335   $new->{_dbh_gen} = 0;
 336
 337   $new;
 338 }
 339
 340 =head2 connect_info
 341
 342 The arguments of C<connect_info> are always a single array reference.
 343
 344 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 345 encapsulates its argument list in an arrayref before calling
 346 C<connect_info> here.
 347
 348 The arrayref can either contain the same set of arguments one would
 349 normally pass to L<DBI/connect>, or a lone code reference which returns
 350 a connected database handle.  Please note that the L<DBI> docs
 351 recommend that you always explicitly set C<AutoCommit> to either
 352 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 353 to C<1>, and that you perform transactions via our L</txn_do>
 354 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 355 set it to zero.  This is the default for most DBDs.  See below for more
 356 details.
 357
 358 In either case, if the final argument in your connect_info happens
 359 to be a hashref, C<connect_info> will look there for several
 360 connection-specific options:
 361
 362 =over 4
 363
 364 =item on_connect_do
 365
 366 Specifies things to do immediately after connecting or re-connecting to
 367 the database.  Its value may contain:
 368
 369 =over
 370
 371 =item an array reference
 372
 373 This contains SQL statements to execute in order.  Each element contains
 374 a string or a code reference that returns a string.
 375
 376 =item a code reference
 377
 378 This contains some code to execute.  Unlike code references within an
 379 array reference, its return value is ignored.
 380
 381 =back
 382
 383 =item on_disconnect_do
 384
 385 Takes arguments in the same form as L<on_connect_do> and executes them
 386 immediately before disconnecting from the database.
 387
 388 Note, this only runs if you explicitly call L<disconnect> on the
 389 storage object.
 390
 391 =item disable_sth_caching
 392
 393 If set to a true value, this option will disable the caching of
 394 statement handles via L<DBI/prepare_cached>.
 395
 396 =item limit_dialect
 397
 398 Sets the limit dialect. This is useful for JDBC-bridge among others
 399 where the remote SQL-dialect cannot be determined by the name of the
 400 driver alone.
 401
 402 =item quote_char
 403
 404 Specifies what characters to use to quote table and column names. If
 405 you use this you will want to specify L<name_sep> as well.
 406
 407 quote_char expects either a single character, in which case is it is placed
 408 on either side of the table/column, or an arrayref of length 2 in which case the
 409 table/column name is placed between the elements.
 410
 411 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 412 use C<quote_char =E<gt> [qw/[ ]/]>.
 413
 414 =item name_sep
 415
 416 This only needs to be used in conjunction with L<quote_char>, and is used to
 417 specify the charecter that seperates elements (schemas, tables, columns) from
 418 each other. In most cases this is simply a C<.>.
 419
 420 =item unsafe
 421
 422 This Storage driver normally installs its own C<HandleError>, sets
 423 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 424 all database handles, including those supplied by a coderef.  It does this
 425 so that it can have consistent and useful error behavior.
 426
 427 If you set this option to a true value, Storage will not do its usual
 428 modifications to the database handle's attributes, and instead relies on
 429 the settings in your connect_info DBI options (or the values you set in
 430 your connection coderef, in the case that you are connecting via coderef).
 431
 432 Note that your custom settings can cause Storage to malfunction,
 433 especially if you set a C<HandleError> handler that suppresses exceptions
 434 and/or disable C<RaiseError>.
 435
 436 =item auto_savepoint
 437
 438 If this option is true, L<DBIx::Class> will use savepoints when nesting
 439 transactions, making it possible to recover from failure in the inner
 440 transaction without having to abort all outer transactions.
 441
 442 =back
 443
 444 These options can be mixed in with your other L<DBI> connection attributes,
 445 or placed in a seperate hashref after all other normal L<DBI> connection
 446 arguments.
 447
 448 Every time C<connect_info> is invoked, any previous settings for
 449 these options will be cleared before setting the new ones, regardless of
 450 whether any options are specified in the new C<connect_info>.
 451
 452 Another Important Note:
 453
 454 DBIC can do some wonderful magic with handling exceptions,
 455 disconnections, and transactions when you use C<< AutoCommit => 1 >>
 456 combined with C<txn_do> for transaction support.
 457
 458 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
 459 in an assumed transaction between commits, and you're telling us you'd
 460 like to manage that manually.  A lot of DBIC's magic protections
 461 go away.  We can't protect you from exceptions due to database
 462 disconnects because we don't know anything about how to restart your
 463 transactions.  You're on your own for handling all sorts of exceptional
 464 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
 465 be with raw DBI.
 466
 467 Examples:
 468
 469   # Simple SQLite connection
 470   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 471
 472   # Connect via subref
 473   ->connect_info([ sub { DBI->connect(...) } ]);
 474
 475   # A bit more complicated
 476   ->connect_info(
 477     [
 478       'dbi:Pg:dbname=foo',
 479       'postgres',
 480       'my_pg_password',
 481       { AutoCommit => 1 },
 482       { quote_char => q{"}, name_sep => q{.} },
 483     ]
 484   );
 485
 486   # Equivalent to the previous example
 487   ->connect_info(
 488     [
 489       'dbi:Pg:dbname=foo',
 490       'postgres',
 491       'my_pg_password',
 492       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 493     ]
 494   );
 495
 496   # Subref + DBIC-specific connection options
 497   ->connect_info(
 498     [
 499       sub { DBI->connect(...) },
 500       {
 501           quote_char => q{`},
 502           name_sep => q{@},
 503           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 504           disable_sth_caching => 1,
 505       },
 506     ]
 507   );
 508
 509 =cut
 510
 511 sub connect_info {
 512   my ($self, $info_arg) = @_;
 513
 514   return $self->_connect_info if !$info_arg;
 515
 516   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 517   #  the new set of options
 518   $self->_sql_maker(undef);
 519   $self->_sql_maker_opts({});
 520   $self->_connect_info([@$info_arg]); # copy for _connect_info
 521
 522   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 523
 524   my $last_info = $dbi_info->[-1];
 525   if(ref $last_info eq 'HASH') {
 526     $last_info = { %$last_info }; # so delete is non-destructive
 527     my @storage_option = qw(
 528       on_connect_do on_disconnect_do disable_sth_caching unsafe cursor_class
 529       auto_savepoint
 530     );
 531     for my $storage_opt (@storage_option) {
 532       if(my $value = delete $last_info->{$storage_opt}) {
 533         $self->$storage_opt($value);
 534       }
 535     }
 536     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 537       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 538         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 539       }
 540     }
 541     # re-insert modified hashref
 542     $dbi_info->[-1] = $last_info;
 543
 544     # Get rid of any trailing empty hashref
 545     pop(@$dbi_info) if !keys %$last_info;
 546   }
 547   $self->_dbi_connect_info($dbi_info);
 548
 549   $self->_connect_info;
 550 }
 551
 552 =head2 on_connect_do
 553
 554 This method is deprecated in favor of setting via L</connect_info>.
 555
 556 =head2 dbh_do
 557
 558 Arguments: ($subref | $method_name), @extra_coderef_args?
 559
 560 Execute the given $subref or $method_name using the new exception-based
 561 connection management.
 562
 563 The first two arguments will be the storage object that C<dbh_do> was called
 564 on and a database handle to use.  Any additional arguments will be passed
 565 verbatim to the called subref as arguments 2 and onwards.
 566
 567 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 568 exception handling and reconnection (or failover in future subclasses).
 569
 570 Your subref should have no side-effects outside of the database, as
 571 there is the potential for your subref to be partially double-executed
 572 if the database connection was stale/dysfunctional.
 573
 574 Example:
 575
 576   my @stuff = $schema->storage->dbh_do(
 577     sub {
 578       my ($storage, $dbh, @cols) = @_;
 579       my $cols = join(q{, }, @cols);
 580       $dbh->selectrow_array("SELECT $cols FROM foo");
 581     },
 582     @column_list
 583   );
 584
 585 =cut
 586
 587 sub dbh_do {
 588   my $self = shift;
 589   my $code = shift;
 590
 591   my $dbh = $self->_dbh;
 592
 593   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 594       || $self->{transaction_depth};
 595
 596   local $self->{_in_dbh_do} = 1;
 597
 598   my @result;
 599   my $want_array = wantarray;
 600
 601   eval {
 602     $self->_verify_pid if $dbh;
 603     if(!$self->_dbh) {
 604         $self->_populate_dbh;
 605         $dbh = $self->_dbh;
 606     }
 607
 608     if($want_array) {
 609         @result = $self->$code($dbh, @_);
 610     }
 611     elsif(defined $want_array) {
 612         $result[0] = $self->$code($dbh, @_);
 613     }
 614     else {
 615         $self->$code($dbh, @_);
 616     }
 617   };
 618
 619   my $exception = $@;
 620   if(!$exception) { return $want_array ? @result : $result[0] }
 621
 622   $self->throw_exception($exception) if $self->connected;
 623
 624   # We were not connected - reconnect and retry, but let any
 625   #  exception fall right through this time
 626   $self->_populate_dbh;
 627   $self->$code($self->_dbh, @_);
 628 }
 629
 630 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 631 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 632 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 633 sub txn_do {
 634   my $self = shift;
 635   my $coderef = shift;
 636
 637   ref $coderef eq 'CODE' or $self->throw_exception
 638     ('$coderef must be a CODE reference');
 639
 640   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 641
 642   local $self->{_in_dbh_do} = 1;
 643
 644   my @result;
 645   my $want_array = wantarray;
 646
 647   my $tried = 0;
 648   while(1) {
 649     eval {
 650       $self->_verify_pid if $self->_dbh;
 651       $self->_populate_dbh if !$self->_dbh;
 652
 653       $self->txn_begin;
 654       if($want_array) {
 655           @result = $coderef->(@_);
 656       }
 657       elsif(defined $want_array) {
 658           $result[0] = $coderef->(@_);
 659       }
 660       else {
 661           $coderef->(@_);
 662       }
 663       $self->txn_commit;
 664     };
 665
 666     my $exception = $@;
 667     if(!$exception) { return $want_array ? @result : $result[0] }
 668
 669     if($tried++ > 0 || $self->connected) {
 670       eval { $self->txn_rollback };
 671       my $rollback_exception = $@;
 672       if($rollback_exception) {
 673         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 674         $self->throw_exception($exception)  # propagate nested rollback
 675           if $rollback_exception =~ /$exception_class/;
 676
 677         $self->throw_exception(
 678           "Transaction aborted: ${exception}. "
 679           . "Rollback failed: ${rollback_exception}"
 680         );
 681       }
 682       $self->throw_exception($exception)
 683     }
 684
 685     # We were not connected, and was first try - reconnect and retry
 686     # via the while loop
 687     $self->_populate_dbh;
 688   }
 689 }
 690
 691 =head2 disconnect
 692
 693 Our C<disconnect> method also performs a rollback first if the
 694 database is not in C<AutoCommit> mode.
 695
 696 =cut
 697
 698 sub disconnect {
 699   my ($self) = @_;
 700
 701   if( $self->connected ) {
 702     my $connection_do = $self->on_disconnect_do;
 703     $self->_do_connection_actions($connection_do) if ref($connection_do);
 704
 705     $self->_dbh->rollback unless $self->_dbh_autocommit;
 706
 707     # SQLite is evil/brainded and must be DESTROYed without disconnecting: http://www.perlmonks.org/?node_id=666210
 708     $self->_dbh->disconnect if $self->_dbh->get_info(17) ne 'SQLite';
 709
 710     $self->_dbh(undef);
 711     $self->{_dbh_gen}++;
 712   }
 713 }
 714
 715 =head2 with_deferred_fk_checks
 716
 717 =over 4
 718
 719 =item Arguments: C<$coderef>
 720
 721 =item Return Value: The return value of $coderef
 722
 723 =back
 724
 725 Storage specific method to run the code ref with FK checks deferred or
 726 in MySQL's case disabled entirely.
 727
 728 =cut
 729
 730 # Storage subclasses should override this
 731 sub with_deferred_fk_checks {
 732   my ($self, $sub) = @_;
 733
 734   $sub->();
 735 }
 736
 737 sub connected {
 738   my ($self) = @_;
 739
 740   if(my $dbh = $self->_dbh) {
 741       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 742           $self->_dbh(undef);
 743           $self->{_dbh_gen}++;
 744           return;
 745       }
 746       else {
 747           $self->_verify_pid;
 748           return 0 if !$self->_dbh;
 749       }
 750       return ($dbh->FETCH('Active') && $dbh->ping);
 751   }
 752
 753   return 0;
 754 }
 755
 756 # handle pid changes correctly
 757 #  NOTE: assumes $self->_dbh is a valid $dbh
 758 sub _verify_pid {
 759   my ($self) = @_;
 760
 761   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 762
 763   $self->_dbh->{InactiveDestroy} = 1;
 764   $self->_dbh(undef);
 765   $self->{_dbh_gen}++;
 766
 767   return;
 768 }
 769
 770 sub ensure_connected {
 771   my ($self) = @_;
 772
 773   unless ($self->connected) {
 774     $self->_populate_dbh;
 775   }
 776 }
 777
 778 =head2 dbh
 779
 780 Returns the dbh - a data base handle of class L<DBI>.
 781
 782 =cut
 783
 784 sub dbh {
 785   my ($self) = @_;
 786
 787   $self->ensure_connected;
 788   return $self->_dbh;
 789 }
 790
 791 sub _sql_maker_args {
 792     my ($self) = @_;
 793
 794     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 795 }
 796
 797 sub sql_maker {
 798   my ($self) = @_;
 799   unless ($self->_sql_maker) {
 800     my $sql_maker_class = $self->sql_maker_class;
 801     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 802   }
 803   return $self->_sql_maker;
 804 }
 805
 806 sub _rebless {}
 807
 808 sub _populate_dbh {
 809   my ($self) = @_;
 810   my @info = @{$self->_dbi_connect_info || []};
 811   $self->_dbh($self->_connect(@info));
 812
 813   # Always set the transaction depth on connect, since
 814   #  there is no transaction in progress by definition
 815   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 816
 817   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 818     my $driver = $self->_dbh->{Driver}->{Name};
 819     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 820       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 821       $self->_rebless();
 822     }
 823   }
 824
 825   my $connection_do = $self->on_connect_do;
 826   $self->_do_connection_actions($connection_do) if ref($connection_do);
 827
 828   $self->_conn_pid($$);
 829   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 830 }
 831
 832 sub _do_connection_actions {
 833   my $self = shift;
 834   my $connection_do = shift;
 835
 836   if (ref $connection_do eq 'ARRAY') {
 837     $self->_do_query($_) foreach @$connection_do;
 838   }
 839   elsif (ref $connection_do eq 'CODE') {
 840     $connection_do->();
 841   }
 842
 843   return $self;
 844 }
 845
 846 sub _do_query {
 847   my ($self, $action) = @_;
 848
 849   if (ref $action eq 'CODE') {
 850     $action = $action->($self);
 851     $self->_do_query($_) foreach @$action;
 852   }
 853   else {
 854     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 855     $self->_query_start(@to_run);
 856     $self->_dbh->do(@to_run);
 857     $self->_query_end(@to_run);
 858   }
 859
 860   return $self;
 861 }
 862
 863 sub _connect {
 864   my ($self, @info) = @_;
 865
 866   $self->throw_exception("You failed to provide any connection info")
 867     if !@info;
 868
 869   my ($old_connect_via, $dbh);
 870
 871   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 872     $old_connect_via = $DBI::connect_via;
 873     $DBI::connect_via = 'connect';
 874   }
 875
 876   eval {
 877     if(ref $info[0] eq 'CODE') {
 878        $dbh = &{$info[0]}
 879     }
 880     else {
 881        $dbh = DBI->connect(@info);
 882     }
 883
 884     if($dbh && !$self->unsafe) {
 885       my $weak_self = $self;
 886       weaken($weak_self);
 887       $dbh->{HandleError} = sub {
 888           $weak_self->throw_exception("DBI Exception: $_[0]")
 889       };
 890       $dbh->{ShowErrorStatement} = 1;
 891       $dbh->{RaiseError} = 1;
 892       $dbh->{PrintError} = 0;
 893     }
 894   };
 895
 896   $DBI::connect_via = $old_connect_via if $old_connect_via;
 897
 898   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 899     if !$dbh || $@;
 900
 901   $self->_dbh_autocommit($dbh->{AutoCommit});
 902
 903   $dbh;
 904 }
 905
 906 sub svp_begin {
 907   my ($self, $name) = @_;
 908
 909   $name = $self->_svp_generate_name
 910     unless defined $name;
 911
 912   $self->throw_exception ("You can't use savepoints outside a transaction")
 913     if $self->{transaction_depth} == 0;
 914
 915   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 916     unless $self->can('_svp_begin');
 917
 918   push @{ $self->{savepoints} }, $name;
 919
 920   $self->debugobj->svp_begin($name) if $self->debug;
 921
 922   return $self->_svp_begin($name);
 923 }
 924
 925 sub svp_release {
 926   my ($self, $name) = @_;
 927
 928   $self->throw_exception ("You can't use savepoints outside a transaction")
 929     if $self->{transaction_depth} == 0;
 930
 931   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 932     unless $self->can('_svp_release');
 933
 934   if (defined $name) {
 935     $self->throw_exception ("Savepoint '$name' does not exist")
 936       unless grep { $_ eq $name } @{ $self->{savepoints} };
 937
 938     # Dig through the stack until we find the one we are releasing.  This keeps
 939     # the stack up to date.
 940     my $svp;
 941
 942     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
 943   } else {
 944     $name = pop @{ $self->{savepoints} };
 945   }
 946
 947   $self->debugobj->svp_release($name) if $self->debug;
 948
 949   return $self->_svp_release($name);
 950 }
 951
 952 sub svp_rollback {
 953   my ($self, $name) = @_;
 954
 955   $self->throw_exception ("You can't use savepoints outside a transaction")
 956     if $self->{transaction_depth} == 0;
 957
 958   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 959     unless $self->can('_svp_rollback');
 960
 961   if (defined $name) {
 962       # If they passed us a name, verify that it exists in the stack
 963       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
 964           $self->throw_exception("Savepoint '$name' does not exist!");
 965       }
 966
 967       # Dig through the stack until we find the one we are releasing.  This keeps
 968       # the stack up to date.
 969       while(my $s = pop(@{ $self->{savepoints} })) {
 970           last if($s eq $name);
 971       }
 972       # Add the savepoint back to the stack, as a rollback doesn't remove the
 973       # named savepoint, only everything after it.
 974       push(@{ $self->{savepoints} }, $name);
 975   } else {
 976       # We'll assume they want to rollback to the last savepoint
 977       $name = $self->{savepoints}->[-1];
 978   }
 979
 980   $self->debugobj->svp_rollback($name) if $self->debug;
 981
 982   return $self->_svp_rollback($name);
 983 }
 984
 985 sub _svp_generate_name {
 986     my ($self) = @_;
 987
 988     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
 989 }
 990
 991 sub txn_begin {
 992   my $self = shift;
 993   $self->ensure_connected();
 994   if($self->{transaction_depth} == 0) {
 995     $self->debugobj->txn_begin()
 996       if $self->debug;
 997     # this isn't ->_dbh-> because
 998     #  we should reconnect on begin_work
 999     #  for AutoCommit users
1000     $self->dbh->begin_work;
1001   } elsif ($self->auto_savepoint) {
1002     $self->svp_begin;
1003   }
1004   $self->{transaction_depth}++;
1005 }
1006
1007 sub txn_commit {
1008   my $self = shift;
1009   if ($self->{transaction_depth} == 1) {
1010     my $dbh = $self->_dbh;
1011     $self->debugobj->txn_commit()
1012       if ($self->debug);
1013     $dbh->commit;
1014     $self->{transaction_depth} = 0
1015       if $self->_dbh_autocommit;
1016   }
1017   elsif($self->{transaction_depth} > 1) {
1018     $self->{transaction_depth}--;
1019     $self->svp_release
1020       if $self->auto_savepoint;
1021   }
1022 }
1023
1024 sub txn_rollback {
1025   my $self = shift;
1026   my $dbh = $self->_dbh;
1027   eval {
1028     if ($self->{transaction_depth} == 1) {
1029       $self->debugobj->txn_rollback()
1030         if ($self->debug);
1031       $self->{transaction_depth} = 0
1032         if $self->_dbh_autocommit;
1033       $dbh->rollback;
1034     }
1035     elsif($self->{transaction_depth} > 1) {
1036       $self->{transaction_depth}--;
1037       if ($self->auto_savepoint) {
1038         $self->svp_rollback;
1039         $self->svp_release;
1040       }
1041     }
1042     else {
1043       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1044     }
1045   };
1046   if ($@) {
1047     my $error = $@;
1048     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1049     $error =~ /$exception_class/ and $self->throw_exception($error);
1050     # ensure that a failed rollback resets the transaction depth
1051     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1052     $self->throw_exception($error);
1053   }
1054 }
1055
1056 # This used to be the top-half of _execute.  It was split out to make it
1057 #  easier to override in NoBindVars without duping the rest.  It takes up
1058 #  all of _execute's args, and emits $sql, @bind.
1059 sub _prep_for_execute {
1060   my ($self, $op, $extra_bind, $ident, $args) = @_;
1061
1062   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1063   unshift(@bind,
1064     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1065       if $extra_bind;
1066
1067   return ($sql, \@bind);
1068 }
1069
1070 sub _fix_bind_params {
1071     my ($self, @bind) = @_;
1072
1073     ### Turn @bind from something like this:
1074     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1075     ### to this:
1076     ###   ( "'1'", "'1'", "'3'" )
1077     return
1078         map {
1079             if ( defined( $_ && $_->[1] ) ) {
1080                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1081             }
1082             else { q{'NULL'}; }
1083         } @bind;
1084 }
1085
1086 sub _query_start {
1087     my ( $self, $sql, @bind ) = @_;
1088
1089     if ( $self->debug ) {
1090         @bind = $self->_fix_bind_params(@bind);
1091
1092         $self->debugobj->query_start( $sql, @bind );
1093     }
1094 }
1095
1096 sub _query_end {
1097     my ( $self, $sql, @bind ) = @_;
1098
1099     if ( $self->debug ) {
1100         @bind = $self->_fix_bind_params(@bind);
1101         $self->debugobj->query_end( $sql, @bind );
1102     }
1103 }
1104
1105 sub _dbh_execute {
1106   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1107
1108   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1109     $ident = $ident->from();
1110   }
1111
1112   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1113
1114   $self->_query_start( $sql, @$bind );
1115
1116   my $sth = $self->sth($sql,$op);
1117
1118   my $placeholder_index = 1;
1119
1120   foreach my $bound (@$bind) {
1121     my $attributes = {};
1122     my($column_name, @data) = @$bound;
1123
1124     if ($bind_attributes) {
1125       $attributes = $bind_attributes->{$column_name}
1126       if defined $bind_attributes->{$column_name};
1127     }
1128
1129     foreach my $data (@data) {
1130       $data = ref $data ? ''.$data : $data; # stringify args
1131
1132       $sth->bind_param($placeholder_index, $data, $attributes);
1133       $placeholder_index++;
1134     }
1135   }
1136
1137   # Can this fail without throwing an exception anyways???
1138   my $rv = $sth->execute();
1139   $self->throw_exception($sth->errstr) if !$rv;
1140
1141   $self->_query_end( $sql, @$bind );
1142
1143   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1144 }
1145
1146 sub _execute {
1147     my $self = shift;
1148     $self->dbh_do('_dbh_execute', @_)
1149 }
1150
1151 sub insert {
1152   my ($self, $source, $to_insert) = @_;
1153
1154   my $ident = $source->from;
1155   my $bind_attributes = $self->source_bind_attributes($source);
1156
1157   $self->ensure_connected;
1158   foreach my $col ( $source->columns ) {
1159     if ( !defined $to_insert->{$col} ) {
1160       my $col_info = $source->column_info($col);
1161
1162       if ( $col_info->{auto_nextval} ) {
1163         $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1164       }
1165     }
1166   }
1167
1168   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1169
1170   return $to_insert;
1171 }
1172
1173 ## Still not quite perfect, and EXPERIMENTAL
1174 ## Currently it is assumed that all values passed will be "normal", i.e. not
1175 ## scalar refs, or at least, all the same type as the first set, the statement is
1176 ## only prepped once.
1177 sub insert_bulk {
1178   my ($self, $source, $cols, $data) = @_;
1179   my %colvalues;
1180   my $table = $source->from;
1181   @colvalues{@$cols} = (0..$#$cols);
1182   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1183
1184   $self->_query_start( $sql, @bind );
1185   my $sth = $self->sth($sql);
1186
1187 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1188
1189   ## This must be an arrayref, else nothing works!
1190
1191   my $tuple_status = [];
1192
1193   ##use Data::Dumper;
1194   ##print STDERR Dumper( $data, $sql, [@bind] );
1195
1196   my $time = time();
1197
1198   ## Get the bind_attributes, if any exist
1199   my $bind_attributes = $self->source_bind_attributes($source);
1200
1201   ## Bind the values and execute
1202   my $placeholder_index = 1;
1203
1204   foreach my $bound (@bind) {
1205
1206     my $attributes = {};
1207     my ($column_name, $data_index) = @$bound;
1208
1209     if( $bind_attributes ) {
1210       $attributes = $bind_attributes->{$column_name}
1211       if defined $bind_attributes->{$column_name};
1212     }
1213
1214     my @data = map { $_->[$data_index] } @$data;
1215
1216     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1217     $placeholder_index++;
1218   }
1219   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1220   $self->throw_exception($sth->errstr) if !$rv;
1221
1222   $self->_query_end( $sql, @bind );
1223   return (wantarray ? ($rv, $sth, @bind) : $rv);
1224 }
1225
1226 sub update {
1227   my $self = shift @_;
1228   my $source = shift @_;
1229   my $bind_attributes = $self->source_bind_attributes($source);
1230
1231   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1232 }
1233
1234
1235 sub delete {
1236   my $self = shift @_;
1237   my $source = shift @_;
1238
1239   my $bind_attrs = {}; ## If ever it's needed...
1240
1241   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1242 }
1243
1244 sub _select {
1245   my ($self, $ident, $select, $condition, $attrs) = @_;
1246   my $order = $attrs->{order_by};
1247
1248   if (ref $condition eq 'SCALAR') {
1249     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1250   }
1251
1252   my $for = delete $attrs->{for};
1253   my $sql_maker = $self->sql_maker;
1254   local $sql_maker->{for} = $for;
1255
1256   if (exists $attrs->{group_by} || $attrs->{having}) {
1257     $order = {
1258       group_by => $attrs->{group_by},
1259       having => $attrs->{having},
1260       ($order ? (order_by => $order) : ())
1261     };
1262   }
1263   my $bind_attrs = {}; ## Future support
1264   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1265   if ($attrs->{software_limit} ||
1266       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1267         $attrs->{software_limit} = 1;
1268   } else {
1269     $self->throw_exception("rows attribute must be positive if present")
1270       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1271
1272     # MySQL actually recommends this approach.  I cringe.
1273     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1274     push @args, $attrs->{rows}, $attrs->{offset};
1275   }
1276
1277   return $self->_execute(@args);
1278 }
1279
1280 sub source_bind_attributes {
1281   my ($self, $source) = @_;
1282
1283   my $bind_attributes;
1284   foreach my $column ($source->columns) {
1285
1286     my $data_type = $source->column_info($column)->{data_type} || '';
1287     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1288      if $data_type;
1289   }
1290
1291   return $bind_attributes;
1292 }
1293
1294 =head2 select
1295
1296 =over 4
1297
1298 =item Arguments: $ident, $select, $condition, $attrs
1299
1300 =back
1301
1302 Handle a SQL select statement.
1303
1304 =cut
1305
1306 sub select {
1307   my $self = shift;
1308   my ($ident, $select, $condition, $attrs) = @_;
1309   return $self->cursor_class->new($self, \@_, $attrs);
1310 }
1311
1312 sub select_single {
1313   my $self = shift;
1314   my ($rv, $sth, @bind) = $self->_select(@_);
1315   my @row = $sth->fetchrow_array;
1316   if(@row && $sth->fetchrow_array) {
1317     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1318   }
1319   # Need to call finish() to work round broken DBDs
1320   $sth->finish();
1321   return @row;
1322 }
1323
1324 =head2 sth
1325
1326 =over 4
1327
1328 =item Arguments: $sql
1329
1330 =back
1331
1332 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1333
1334 =cut
1335
1336 sub _dbh_sth {
1337   my ($self, $dbh, $sql) = @_;
1338
1339   # 3 is the if_active parameter which avoids active sth re-use
1340   my $sth = $self->disable_sth_caching
1341     ? $dbh->prepare($sql)
1342     : $dbh->prepare_cached($sql, {}, 3);
1343
1344   # XXX You would think RaiseError would make this impossible,
1345   #  but apparently that's not true :(
1346   $self->throw_exception($dbh->errstr) if !$sth;
1347
1348   $sth;
1349 }
1350
1351 sub sth {
1352   my ($self, $sql) = @_;
1353   $self->dbh_do('_dbh_sth', $sql);
1354 }
1355
1356 sub _dbh_columns_info_for {
1357   my ($self, $dbh, $table) = @_;
1358
1359   if ($dbh->can('column_info')) {
1360     my %result;
1361     eval {
1362       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1363       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1364       $sth->execute();
1365       while ( my $info = $sth->fetchrow_hashref() ){
1366         my %column_info;
1367         $column_info{data_type}   = $info->{TYPE_NAME};
1368         $column_info{size}      = $info->{COLUMN_SIZE};
1369         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1370         $column_info{default_value} = $info->{COLUMN_DEF};
1371         my $col_name = $info->{COLUMN_NAME};
1372         $col_name =~ s/^\"(.*)\"$/$1/;
1373
1374         $result{$col_name} = \%column_info;
1375       }
1376     };
1377     return \%result if !$@ && scalar keys %result;
1378   }
1379
1380   my %result;
1381   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1382   $sth->execute;
1383   my @columns = @{$sth->{NAME_lc}};
1384   for my $i ( 0 .. $#columns ){
1385     my %column_info;
1386     $column_info{data_type} = $sth->{TYPE}->[$i];
1387     $column_info{size} = $sth->{PRECISION}->[$i];
1388     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1389
1390     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1391       $column_info{data_type} = $1;
1392       $column_info{size}    = $2;
1393     }
1394
1395     $result{$columns[$i]} = \%column_info;
1396   }
1397   $sth->finish;
1398
1399   foreach my $col (keys %result) {
1400     my $colinfo = $result{$col};
1401     my $type_num = $colinfo->{data_type};
1402     my $type_name;
1403     if(defined $type_num && $dbh->can('type_info')) {
1404       my $type_info = $dbh->type_info($type_num);
1405       $type_name = $type_info->{TYPE_NAME} if $type_info;
1406       $colinfo->{data_type} = $type_name if $type_name;
1407     }
1408   }
1409
1410   return \%result;
1411 }
1412
1413 sub columns_info_for {
1414   my ($self, $table) = @_;
1415   $self->dbh_do('_dbh_columns_info_for', $table);
1416 }
1417
1418 =head2 last_insert_id
1419
1420 Return the row id of the last insert.
1421
1422 =cut
1423
1424 sub _dbh_last_insert_id {
1425     my ($self, $dbh, $source, $col) = @_;
1426     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1427     $dbh->func('last_insert_rowid');
1428 }
1429
1430 sub last_insert_id {
1431   my $self = shift;
1432   $self->dbh_do('_dbh_last_insert_id', @_);
1433 }
1434
1435 =head2 sqlt_type
1436
1437 Returns the database driver name.
1438
1439 =cut
1440
1441 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1442
1443 =head2 bind_attribute_by_data_type
1444
1445 Given a datatype from column info, returns a database specific bind attribute for
1446 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1447 just handle it.
1448
1449 Generally only needed for special case column types, like bytea in postgres.
1450
1451 =cut
1452
1453 sub bind_attribute_by_data_type {
1454     return;
1455 }
1456
1457 =head2 create_ddl_dir
1458
1459 =over 4
1460
1461 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1462
1463 =back
1464
1465 Creates a SQL file based on the Schema, for each of the specified
1466 database types, in the given directory.
1467
1468 By default, C<\%sqlt_args> will have
1469
1470  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1471
1472 merged with the hash passed in. To disable any of those features, pass in a
1473 hashref like the following
1474
1475  { ignore_constraint_names => 0, # ... other options }
1476
1477 =cut
1478
1479 sub create_ddl_dir {
1480   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1481
1482   if(!$dir || !-d $dir) {
1483     warn "No directory given, using ./\n";
1484     $dir = "./";
1485   }
1486   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1487   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1488   $version ||= $schema->VERSION || '1.x';
1489   $sqltargs = {
1490     add_drop_table => 1,
1491     ignore_constraint_names => 1,
1492     ignore_index_names => 1,
1493     %{$sqltargs || {}}
1494   };
1495
1496   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09: '}
1497       . $self->_check_sqlt_message . q{'})
1498           if !$self->_check_sqlt_version;
1499
1500   my $sqlt = SQL::Translator->new( $sqltargs );
1501
1502   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1503   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1504
1505   foreach my $db (@$databases) {
1506     $sqlt->reset();
1507     $sqlt = $self->configure_sqlt($sqlt, $db);
1508     $sqlt->{schema} = $sqlt_schema;
1509     $sqlt->producer($db);
1510
1511     my $file;
1512     my $filename = $schema->ddl_filename($db, $version, $dir);
1513     if (-e $filename && (!$version || ($version == $schema->schema_version()))) {
1514       # if we are dumping the current version, overwrite the DDL
1515       warn "Overwriting existing DDL file - $filename";
1516       unlink($filename);
1517     }
1518
1519     my $output = $sqlt->translate;
1520     if(!$output) {
1521       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1522       next;
1523     }
1524     if(!open($file, ">$filename")) {
1525       $self->throw_exception("Can't open $filename for writing ($!)");
1526       next;
1527     }
1528     print $file $output;
1529     close($file);
1530
1531     next unless ($preversion);
1532
1533     require SQL::Translator::Diff;
1534
1535     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1536     if(!-e $prefilename) {
1537       warn("No previous schema file found ($prefilename)");
1538       next;
1539     }
1540
1541     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1542     if(-e $difffile) {
1543       warn("Overwriting existing diff file - $difffile");
1544       unlink($difffile);
1545     }
1546
1547     my $source_schema;
1548     {
1549       my $t = SQL::Translator->new($sqltargs);
1550       $t->debug( 0 );
1551       $t->trace( 0 );
1552       $t->parser( $db )                       or die $t->error;
1553       $t = $self->configure_sqlt($t, $db);
1554       my $out = $t->translate( $prefilename ) or die $t->error;
1555       $source_schema = $t->schema;
1556       unless ( $source_schema->name ) {
1557         $source_schema->name( $prefilename );
1558       }
1559     }
1560
1561     # The "new" style of producers have sane normalization and can support
1562     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1563     # And we have to diff parsed SQL against parsed SQL.
1564     my $dest_schema = $sqlt_schema;
1565
1566     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1567       my $t = SQL::Translator->new($sqltargs);
1568       $t->debug( 0 );
1569       $t->trace( 0 );
1570       $t->parser( $db )                    or die $t->error;
1571       $t = $self->configure_sqlt($t, $db);
1572       my $out = $t->translate( $filename ) or die $t->error;
1573       $dest_schema = $t->schema;
1574       $dest_schema->name( $filename )
1575         unless $dest_schema->name;
1576     }
1577
1578     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1579                                                   $dest_schema,   $db,
1580                                                   $sqltargs
1581                                                  );
1582     if(!open $file, ">$difffile") {
1583       $self->throw_exception("Can't write to $difffile ($!)");
1584       next;
1585     }
1586     print $file $diff;
1587     close($file);
1588   }
1589 }
1590
1591 sub configure_sqlt() {
1592   my $self = shift;
1593   my $tr = shift;
1594   my $db = shift || $self->sqlt_type;
1595   if ($db eq 'PostgreSQL') {
1596     $tr->quote_table_names(0);
1597     $tr->quote_field_names(0);
1598   }
1599   return $tr;
1600 }
1601
1602 =head2 deployment_statements
1603
1604 =over 4
1605
1606 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1607
1608 =back
1609
1610 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1611 The database driver name is given by C<$type>, though the value from
1612 L</sqlt_type> is used if it is not specified.
1613
1614 C<$directory> is used to return statements from files in a previously created
1615 L</create_ddl_dir> directory and is optional. The filenames are constructed
1616 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1617
1618 If no C<$directory> is specified then the statements are constructed on the
1619 fly using L<SQL::Translator> and C<$version> is ignored.
1620
1621 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1622
1623 =cut
1624
1625 sub deployment_statements {
1626   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1627   # Need to be connected to get the correct sqlt_type
1628   $self->ensure_connected() unless $type;
1629   $type ||= $self->sqlt_type;
1630   $version ||= $schema->VERSION || '1.x';
1631   $dir ||= './';
1632   my $filename = $schema->ddl_filename($type, $dir, $version);
1633   if(-f $filename)
1634   {
1635       my $file;
1636       open($file, "<$filename")
1637         or $self->throw_exception("Can't open $filename ($!)");
1638       my @rows = <$file>;
1639       close($file);
1640       return join('', @rows);
1641   }
1642
1643   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09: '}
1644       . $self->_check_sqlt_message . q{'})
1645           if !$self->_check_sqlt_version;
1646
1647   require SQL::Translator::Parser::DBIx::Class;
1648   eval qq{use SQL::Translator::Producer::${type}};
1649   $self->throw_exception($@) if $@;
1650
1651   # sources needs to be a parser arg, but for simplicty allow at top level
1652   # coming in
1653   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1654       if exists $sqltargs->{sources};
1655
1656   my $tr = SQL::Translator->new(%$sqltargs);
1657   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1658   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1659 }
1660
1661 sub deploy {
1662   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1663   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1664     foreach my $line ( split(";\n", $statement)) {
1665       next if($line =~ /^--/);
1666       next if(!$line);
1667 #      next if($line =~ /^DROP/m);
1668       next if($line =~ /^BEGIN TRANSACTION/m);
1669       next if($line =~ /^COMMIT/m);
1670       next if $line =~ /^\s+$/; # skip whitespace only
1671       $self->_query_start($line);
1672       eval {
1673         $self->dbh->do($line); # shouldn't be using ->dbh ?
1674       };
1675       if ($@) {
1676         warn qq{$@ (running "${line}")};
1677       }
1678       $self->_query_end($line);
1679     }
1680   }
1681 }
1682
1683 =head2 datetime_parser
1684
1685 Returns the datetime parser class
1686
1687 =cut
1688
1689 sub datetime_parser {
1690   my $self = shift;
1691   return $self->{datetime_parser} ||= do {
1692     $self->ensure_connected;
1693     $self->build_datetime_parser(@_);
1694   };
1695 }
1696
1697 =head2 datetime_parser_type
1698
1699 Defines (returns) the datetime parser class - currently hardwired to
1700 L<DateTime::Format::MySQL>
1701
1702 =cut
1703
1704 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1705
1706 =head2 build_datetime_parser
1707
1708 See L</datetime_parser>
1709
1710 =cut
1711
1712 sub build_datetime_parser {
1713   my $self = shift;
1714   my $type = $self->datetime_parser_type(@_);
1715   eval "use ${type}";
1716   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1717   return $type;
1718 }
1719
1720 {
1721     my $_check_sqlt_version; # private
1722     my $_check_sqlt_message; # private
1723     sub _check_sqlt_version {
1724         return $_check_sqlt_version if defined $_check_sqlt_version;
1725         eval 'use SQL::Translator "0.09"';
1726         $_check_sqlt_message = $@ || '';
1727         $_check_sqlt_version = !$@;
1728     }
1729
1730     sub _check_sqlt_message {
1731         _check_sqlt_version if !defined $_check_sqlt_message;
1732         $_check_sqlt_message;
1733     }
1734 }
1735
1736 =head2 is_replicating
1737
1738 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1739 replicate from a master database.  Default is undef, which is the result
1740 returned by databases that don't support replication.
1741
1742 =cut
1743
1744 sub is_replicating {
1745     return;
1746
1747 }
1748
1749 =head2 lag_behind_master
1750
1751 Returns a number that represents a certain amount of lag behind a master db
1752 when a given storage is replicating.  The number is database dependent, but
1753 starts at zero and increases with the amount of lag. Default in undef
1754
1755 =cut
1756
1757 sub lag_behind_master {
1758     return;
1759 }
1760
1761 sub DESTROY {
1762   my $self = shift;
1763   return if !$self->_dbh;
1764   $self->_verify_pid;
1765   $self->_dbh(undef);
1766 }
1767
1768 1;
1769
1770 =head1 SQL METHODS
1771
1772 The module defines a set of methods within the DBIC::SQL::Abstract
1773 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1774 SQL query functions.
1775
1776 The following methods are extended:-
1777
1778 =over 4
1779
1780 =item delete
1781
1782 =item insert
1783
1784 =item select
1785
1786 =item update
1787
1788 =item limit_dialect
1789
1790 See L</connect_info> for details.
1791 For setting, this method is deprecated in favor of L</connect_info>.
1792
1793 =item quote_char
1794
1795 See L</connect_info> for details.
1796 For setting, this method is deprecated in favor of L</connect_info>.
1797
1798 =item name_sep
1799
1800 See L</connect_info> for details.
1801 For setting, this method is deprecated in favor of L</connect_info>.
1802
1803 =back
1804
1805 =head1 AUTHORS
1806
1807 Matt S. Trout <mst@shadowcatsystems.co.uk>
1808
1809 Andy Grundman <andy@hybridized.org>
1810
1811 =head1 LICENSE
1812
1813 You may distribute this code under the same terms as Perl itself.
1814
1815 =cut