lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid disable_sth_caching on_connect_do
  18        on_disconnect_do transaction_depth unsafe _dbh_autocommit
  19        auto_savepoint savepoints/
  20 );
  21
  22 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  23
  24 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  25 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  26
  27 BEGIN {
  28
  29 package # Hide from PAUSE
  30   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  31
  32 use base qw/SQL::Abstract::Limit/;
  33
  34 # This prevents the caching of $dbh in S::A::L, I believe
  35 sub new {
  36   my $self = shift->SUPER::new(@_);
  37
  38   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  39   #   it with what it resolves to:
  40   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  41     if ref $self->{limit_dialect};
  42
  43   $self;
  44 }
  45
  46 sub _RowNumberOver {
  47   my ($self, $sql, $order, $rows, $offset ) = @_;
  48
  49   $offset += 1;
  50   my $last = $rows + $offset;
  51   my ( $order_by ) = $self->_order_by( $order );
  52
  53   $sql = <<"";
  54 SELECT * FROM
  55 (
  56    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  57       $sql
  58       $order_by
  59    ) Q1
  60 ) Q2
  61 WHERE ROW_NUM BETWEEN $offset AND $last
  62
  63   return $sql;
  64 }
  65
  66
  67 # While we're at it, this should make LIMIT queries more efficient,
  68 #  without digging into things too deeply
  69 use Scalar::Util 'blessed';
  70 sub _find_syntax {
  71   my ($self, $syntax) = @_;
  72   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  73   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  74     return 'RowNumberOver';
  75   }
  76
  77   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  78 }
  79
  80 sub select {
  81   my ($self, $table, $fields, $where, $order, @rest) = @_;
  82   $table = $self->_quote($table) unless ref($table);
  83   local $self->{rownum_hack_count} = 1
  84     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  85   @rest = (-1) unless defined $rest[0];
  86   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  87     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  88   local $self->{having_bind} = [];
  89   my ($sql, @ret) = $self->SUPER::select(
  90     $table, $self->_recurse_fields($fields), $where, $order, @rest
  91   );
  92   $sql .=
  93     $self->{for} ?
  94     (
  95       $self->{for} eq 'update' ? ' FOR UPDATE' :
  96       $self->{for} eq 'shared' ? ' FOR SHARE'  :
  97       ''
  98     ) :
  99     ''
 100   ;
 101   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
 102 }
 103
 104 sub insert {
 105   my $self = shift;
 106   my $table = shift;
 107   $table = $self->_quote($table) unless ref($table);
 108   $self->SUPER::insert($table, @_);
 109 }
 110
 111 sub update {
 112   my $self = shift;
 113   my $table = shift;
 114   $table = $self->_quote($table) unless ref($table);
 115   $self->SUPER::update($table, @_);
 116 }
 117
 118 sub delete {
 119   my $self = shift;
 120   my $table = shift;
 121   $table = $self->_quote($table) unless ref($table);
 122   $self->SUPER::delete($table, @_);
 123 }
 124
 125 sub _emulate_limit {
 126   my $self = shift;
 127   if ($_[3] == -1) {
 128     return $_[1].$self->_order_by($_[2]);
 129   } else {
 130     return $self->SUPER::_emulate_limit(@_);
 131   }
 132 }
 133
 134 sub _recurse_fields {
 135   my ($self, $fields, $params) = @_;
 136   my $ref = ref $fields;
 137   return $self->_quote($fields) unless $ref;
 138   return $$fields if $ref eq 'SCALAR';
 139
 140   if ($ref eq 'ARRAY') {
 141     return join(', ', map {
 142       $self->_recurse_fields($_)
 143         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 144           ? ' AS col'.$self->{rownum_hack_count}++
 145           : '')
 146       } @$fields);
 147   } elsif ($ref eq 'HASH') {
 148     foreach my $func (keys %$fields) {
 149       return $self->_sqlcase($func)
 150         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 151     }
 152   }
 153 }
 154
 155 sub _order_by {
 156   my $self = shift;
 157   my $ret = '';
 158   my @extra;
 159   if (ref $_[0] eq 'HASH') {
 160     if (defined $_[0]->{group_by}) {
 161       $ret = $self->_sqlcase(' group by ')
 162         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 163     }
 164     if (defined $_[0]->{having}) {
 165       my $frag;
 166       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 167       push(@{$self->{having_bind}}, @extra);
 168       $ret .= $self->_sqlcase(' having ').$frag;
 169     }
 170     if (defined $_[0]->{order_by}) {
 171       $ret .= $self->_order_by($_[0]->{order_by});
 172     }
 173   } elsif (ref $_[0] eq 'SCALAR') {
 174     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 175   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 176     my @order = @{+shift};
 177     $ret = $self->_sqlcase(' order by ')
 178           .join(', ', map {
 179                         my $r = $self->_order_by($_, @_);
 180                         $r =~ s/^ ?ORDER BY //i;
 181                         $r;
 182                       } @order);
 183   } else {
 184     $ret = $self->SUPER::_order_by(@_);
 185   }
 186   return $ret;
 187 }
 188
 189 sub _order_directions {
 190   my ($self, $order) = @_;
 191   $order = $order->{order_by} if ref $order eq 'HASH';
 192   return $self->SUPER::_order_directions($order);
 193 }
 194
 195 sub _table {
 196   my ($self, $from) = @_;
 197   if (ref $from eq 'ARRAY') {
 198     return $self->_recurse_from(@$from);
 199   } elsif (ref $from eq 'HASH') {
 200     return $self->_make_as($from);
 201   } else {
 202     return $from; # would love to quote here but _table ends up getting called
 203                   # twice during an ->select without a limit clause due to
 204                   # the way S::A::Limit->select works. should maybe consider
 205                   # bypassing this and doing S::A::select($self, ...) in
 206                   # our select method above. meantime, quoting shims have
 207                   # been added to select/insert/update/delete here
 208   }
 209 }
 210
 211 sub _recurse_from {
 212   my ($self, $from, @join) = @_;
 213   my @sqlf;
 214   push(@sqlf, $self->_make_as($from));
 215   foreach my $j (@join) {
 216     my ($to, $on) = @$j;
 217
 218     # check whether a join type exists
 219     my $join_clause = '';
 220     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 221     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 222       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 223     } else {
 224       $join_clause = ' JOIN ';
 225     }
 226     push(@sqlf, $join_clause);
 227
 228     if (ref $to eq 'ARRAY') {
 229       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 230     } else {
 231       push(@sqlf, $self->_make_as($to));
 232     }
 233     push(@sqlf, ' ON ', $self->_join_condition($on));
 234   }
 235   return join('', @sqlf);
 236 }
 237
 238 sub _make_as {
 239   my ($self, $from) = @_;
 240   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 241                      reverse each %{$self->_skip_options($from)});
 242 }
 243
 244 sub _skip_options {
 245   my ($self, $hash) = @_;
 246   my $clean_hash = {};
 247   $clean_hash->{$_} = $hash->{$_}
 248     for grep {!/^-/} keys %$hash;
 249   return $clean_hash;
 250 }
 251
 252 sub _join_condition {
 253   my ($self, $cond) = @_;
 254   if (ref $cond eq 'HASH') {
 255     my %j;
 256     for (keys %$cond) {
 257       my $v = $cond->{$_};
 258       if (ref $v) {
 259         # XXX no throw_exception() in this package and croak() fails with strange results
 260         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 261             if ref($v) ne 'SCALAR';
 262         $j{$_} = $v;
 263       }
 264       else {
 265         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 266       }
 267     };
 268     return scalar($self->_recurse_where(\%j));
 269   } elsif (ref $cond eq 'ARRAY') {
 270     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 271   } else {
 272     die "Can't handle this yet!";
 273   }
 274 }
 275
 276 sub _quote {
 277   my ($self, $label) = @_;
 278   return '' unless defined $label;
 279   return "*" if $label eq '*';
 280   return $label unless $self->{quote_char};
 281   if(ref $self->{quote_char} eq "ARRAY"){
 282     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 283       if !defined $self->{name_sep};
 284     my $sep = $self->{name_sep};
 285     return join($self->{name_sep},
 286         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 287        split(/\Q$sep\E/,$label));
 288   }
 289   return $self->SUPER::_quote($label);
 290 }
 291
 292 sub limit_dialect {
 293     my $self = shift;
 294     $self->{limit_dialect} = shift if @_;
 295     return $self->{limit_dialect};
 296 }
 297
 298 sub quote_char {
 299     my $self = shift;
 300     $self->{quote_char} = shift if @_;
 301     return $self->{quote_char};
 302 }
 303
 304 sub name_sep {
 305     my $self = shift;
 306     $self->{name_sep} = shift if @_;
 307     return $self->{name_sep};
 308 }
 309
 310 } # End of BEGIN block
 311
 312 =head1 NAME
 313
 314 DBIx::Class::Storage::DBI - DBI storage handler
 315
 316 =head1 SYNOPSIS
 317
 318 =head1 DESCRIPTION
 319
 320 This class represents the connection to an RDBMS via L<DBI>.  See
 321 L<DBIx::Class::Storage> for general information.  This pod only
 322 documents DBI-specific methods and behaviors.
 323
 324 =head1 METHODS
 325
 326 =cut
 327
 328 sub new {
 329   my $new = shift->next::method(@_);
 330
 331   $new->transaction_depth(0);
 332   $new->_sql_maker_opts({});
 333   $new->{savepoints} = [];
 334   $new->{_in_dbh_do} = 0;
 335   $new->{_dbh_gen} = 0;
 336
 337   $new;
 338 }
 339
 340 =head2 connect_info
 341
 342 The arguments of C<connect_info> are always a single array reference.
 343
 344 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 345 encapsulates its argument list in an arrayref before calling
 346 C<connect_info> here.
 347
 348 The arrayref can either contain the same set of arguments one would
 349 normally pass to L<DBI/connect>, or a lone code reference which returns
 350 a connected database handle.  Please note that the L<DBI> docs
 351 recommend that you always explicitly set C<AutoCommit> to either
 352 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 353 to C<1>, and that you perform transactions via our L</txn_do>
 354 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 355 set it to zero.  This is the default for most DBDs.  See below for more
 356 details.
 357
 358 In either case, if the final argument in your connect_info happens
 359 to be a hashref, C<connect_info> will look there for several
 360 connection-specific options:
 361
 362 =over 4
 363
 364 =item on_connect_do
 365
 366 Specifies things to do immediately after connecting or re-connecting to
 367 the database.  Its value may contain:
 368
 369 =over
 370
 371 =item an array reference
 372
 373 This contains SQL statements to execute in order.  Each element contains
 374 a string or a code reference that returns a string.
 375
 376 =item a code reference
 377
 378 This contains some code to execute.  Unlike code references within an
 379 array reference, its return value is ignored.
 380
 381 =back
 382
 383 =item on_disconnect_do
 384
 385 Takes arguments in the same form as L<on_connect_do> and executes them
 386 immediately before disconnecting from the database.
 387
 388 Note, this only runs if you explicitly call L<disconnect> on the
 389 storage object.
 390
 391 =item disable_sth_caching
 392
 393 If set to a true value, this option will disable the caching of
 394 statement handles via L<DBI/prepare_cached>.
 395
 396 =item limit_dialect
 397
 398 Sets the limit dialect. This is useful for JDBC-bridge among others
 399 where the remote SQL-dialect cannot be determined by the name of the
 400 driver alone.
 401
 402 =item quote_char
 403
 404 Specifies what characters to use to quote table and column names. If
 405 you use this you will want to specify L<name_sep> as well.
 406
 407 quote_char expects either a single character, in which case is it is placed
 408 on either side of the table/column, or an arrayref of length 2 in which case the
 409 table/column name is placed between the elements.
 410
 411 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 412 use C<quote_char =E<gt> [qw/[ ]/]>.
 413
 414 =item name_sep
 415
 416 This only needs to be used in conjunction with L<quote_char>, and is used to
 417 specify the charecter that seperates elements (schemas, tables, columns) from
 418 each other. In most cases this is simply a C<.>.
 419
 420 =item unsafe
 421
 422 This Storage driver normally installs its own C<HandleError>, sets
 423 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 424 all database handles, including those supplied by a coderef.  It does this
 425 so that it can have consistent and useful error behavior.
 426
 427 If you set this option to a true value, Storage will not do its usual
 428 modifications to the database handle's attributes, and instead relies on
 429 the settings in your connect_info DBI options (or the values you set in
 430 your connection coderef, in the case that you are connecting via coderef).
 431
 432 Note that your custom settings can cause Storage to malfunction,
 433 especially if you set a C<HandleError> handler that suppresses exceptions
 434 and/or disable C<RaiseError>.
 435
 436 =item auto_savepoint
 437
 438 If this option is true, L<DBIx::Class> will use savepoints when nesting
 439 transactions, making it possible to recover from failure in the inner
 440 transaction without having to abort all outer transactions.
 441
 442 =back
 443
 444 These options can be mixed in with your other L<DBI> connection attributes,
 445 or placed in a seperate hashref after all other normal L<DBI> connection
 446 arguments.
 447
 448 Every time C<connect_info> is invoked, any previous settings for
 449 these options will be cleared before setting the new ones, regardless of
 450 whether any options are specified in the new C<connect_info>.
 451
 452 Another Important Note:
 453
 454 DBIC can do some wonderful magic with handling exceptions,
 455 disconnections, and transactions when you use C<< AutoCommit => 1 >>
 456 combined with C<txn_do> for transaction support.
 457
 458 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
 459 in an assumed transaction between commits, and you're telling us you'd
 460 like to manage that manually.  A lot of DBIC's magic protections
 461 go away.  We can't protect you from exceptions due to database
 462 disconnects because we don't know anything about how to restart your
 463 transactions.  You're on your own for handling all sorts of exceptional
 464 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
 465 be with raw DBI.
 466
 467 Examples:
 468
 469   # Simple SQLite connection
 470   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 471
 472   # Connect via subref
 473   ->connect_info([ sub { DBI->connect(...) } ]);
 474
 475   # A bit more complicated
 476   ->connect_info(
 477     [
 478       'dbi:Pg:dbname=foo',
 479       'postgres',
 480       'my_pg_password',
 481       { AutoCommit => 1 },
 482       { quote_char => q{"}, name_sep => q{.} },
 483     ]
 484   );
 485
 486   # Equivalent to the previous example
 487   ->connect_info(
 488     [
 489       'dbi:Pg:dbname=foo',
 490       'postgres',
 491       'my_pg_password',
 492       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 493     ]
 494   );
 495
 496   # Subref + DBIC-specific connection options
 497   ->connect_info(
 498     [
 499       sub { DBI->connect(...) },
 500       {
 501           quote_char => q{`},
 502           name_sep => q{@},
 503           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 504           disable_sth_caching => 1,
 505       },
 506     ]
 507   );
 508
 509 =cut
 510
 511 sub connect_info {
 512   my ($self, $info_arg) = @_;
 513
 514   return $self->_connect_info if !$info_arg;
 515
 516   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 517   #  the new set of options
 518   $self->_sql_maker(undef);
 519   $self->_sql_maker_opts({});
 520   $self->_connect_info([@$info_arg]); # copy for _connect_info
 521
 522   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 523
 524   my $last_info = $dbi_info->[-1];
 525   if(ref $last_info eq 'HASH') {
 526     $last_info = { %$last_info }; # so delete is non-destructive
 527     my @storage_option = qw(
 528       on_connect_do on_disconnect_do disable_sth_caching unsafe cursor_class
 529       auto_savepoint
 530     );
 531     for my $storage_opt (@storage_option) {
 532       if(my $value = delete $last_info->{$storage_opt}) {
 533         $self->$storage_opt($value);
 534       }
 535     }
 536     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 537       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 538         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 539       }
 540     }
 541     # re-insert modified hashref
 542     $dbi_info->[-1] = $last_info;
 543
 544     # Get rid of any trailing empty hashref
 545     pop(@$dbi_info) if !keys %$last_info;
 546   }
 547   $self->_dbi_connect_info($dbi_info);
 548
 549   $self->_connect_info;
 550 }
 551
 552 =head2 on_connect_do
 553
 554 This method is deprecated in favor of setting via L</connect_info>.
 555
 556 =head2 dbh_do
 557
 558 Arguments: ($subref | $method_name), @extra_coderef_args?
 559
 560 Execute the given $subref or $method_name using the new exception-based
 561 connection management.
 562
 563 The first two arguments will be the storage object that C<dbh_do> was called
 564 on and a database handle to use.  Any additional arguments will be passed
 565 verbatim to the called subref as arguments 2 and onwards.
 566
 567 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 568 exception handling and reconnection (or failover in future subclasses).
 569
 570 Your subref should have no side-effects outside of the database, as
 571 there is the potential for your subref to be partially double-executed
 572 if the database connection was stale/dysfunctional.
 573
 574 Example:
 575
 576   my @stuff = $schema->storage->dbh_do(
 577     sub {
 578       my ($storage, $dbh, @cols) = @_;
 579       my $cols = join(q{, }, @cols);
 580       $dbh->selectrow_array("SELECT $cols FROM foo");
 581     },
 582     @column_list
 583   );
 584
 585 =cut
 586
 587 sub dbh_do {
 588   my $self = shift;
 589   my $code = shift;
 590
 591   my $dbh = $self->_dbh;
 592
 593   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 594       || $self->{transaction_depth};
 595
 596   local $self->{_in_dbh_do} = 1;
 597
 598   my @result;
 599   my $want_array = wantarray;
 600
 601   eval {
 602     $self->_verify_pid if $dbh;
 603     if(!$self->_dbh) {
 604         $self->_populate_dbh;
 605         $dbh = $self->_dbh;
 606     }
 607
 608     if($want_array) {
 609         @result = $self->$code($dbh, @_);
 610     }
 611     elsif(defined $want_array) {
 612         $result[0] = $self->$code($dbh, @_);
 613     }
 614     else {
 615         $self->$code($dbh, @_);
 616     }
 617   };
 618
 619   my $exception = $@;
 620   if(!$exception) { return $want_array ? @result : $result[0] }
 621
 622   $self->throw_exception($exception) if $self->connected;
 623
 624   # We were not connected - reconnect and retry, but let any
 625   #  exception fall right through this time
 626   $self->_populate_dbh;
 627   $self->$code($self->_dbh, @_);
 628 }
 629
 630 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 631 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 632 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 633 sub txn_do {
 634   my $self = shift;
 635   my $coderef = shift;
 636
 637   ref $coderef eq 'CODE' or $self->throw_exception
 638     ('$coderef must be a CODE reference');
 639
 640   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 641
 642   local $self->{_in_dbh_do} = 1;
 643
 644   my @result;
 645   my $want_array = wantarray;
 646
 647   my $tried = 0;
 648   while(1) {
 649     eval {
 650       $self->_verify_pid if $self->_dbh;
 651       $self->_populate_dbh if !$self->_dbh;
 652
 653       $self->txn_begin;
 654       if($want_array) {
 655           @result = $coderef->(@_);
 656       }
 657       elsif(defined $want_array) {
 658           $result[0] = $coderef->(@_);
 659       }
 660       else {
 661           $coderef->(@_);
 662       }
 663       $self->txn_commit;
 664     };
 665
 666     my $exception = $@;
 667     if(!$exception) { return $want_array ? @result : $result[0] }
 668
 669     if($tried++ > 0 || $self->connected) {
 670       eval { $self->txn_rollback };
 671       my $rollback_exception = $@;
 672       if($rollback_exception) {
 673         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 674         $self->throw_exception($exception)  # propagate nested rollback
 675           if $rollback_exception =~ /$exception_class/;
 676
 677         $self->throw_exception(
 678           "Transaction aborted: ${exception}. "
 679           . "Rollback failed: ${rollback_exception}"
 680         );
 681       }
 682       $self->throw_exception($exception)
 683     }
 684
 685     # We were not connected, and was first try - reconnect and retry
 686     # via the while loop
 687     $self->_populate_dbh;
 688   }
 689 }
 690
 691 =head2 disconnect
 692
 693 Our C<disconnect> method also performs a rollback first if the
 694 database is not in C<AutoCommit> mode.
 695
 696 =cut
 697
 698 sub disconnect {
 699   my ($self) = @_;
 700
 701   if( $self->connected ) {
 702     my $connection_do = $self->on_disconnect_do;
 703     $self->_do_connection_actions($connection_do) if ref($connection_do);
 704
 705     $self->_dbh->rollback unless $self->_dbh_autocommit;
 706     $self->_dbh->disconnect;
 707     $self->_dbh(undef);
 708     $self->{_dbh_gen}++;
 709   }
 710 }
 711
 712 =head2 with_deferred_fk_checks
 713
 714 =over 4
 715
 716 =item Arguments: C<$coderef>
 717
 718 =item Return Value: The return value of $coderef
 719
 720 =back
 721
 722 Storage specific method to run the code ref with FK checks deferred or
 723 in MySQL's case disabled entirely.
 724
 725 =cut
 726
 727 # Storage subclasses should override this
 728 sub with_deferred_fk_checks {
 729   my ($self, $sub) = @_;
 730
 731   $sub->();
 732 }
 733
 734 sub connected {
 735   my ($self) = @_;
 736
 737   if(my $dbh = $self->_dbh) {
 738       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 739           $self->_dbh(undef);
 740           $self->{_dbh_gen}++;
 741           return;
 742       }
 743       else {
 744           $self->_verify_pid;
 745           return 0 if !$self->_dbh;
 746       }
 747       return ($dbh->FETCH('Active') && $dbh->ping);
 748   }
 749
 750   return 0;
 751 }
 752
 753 # handle pid changes correctly
 754 #  NOTE: assumes $self->_dbh is a valid $dbh
 755 sub _verify_pid {
 756   my ($self) = @_;
 757
 758   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 759
 760   $self->_dbh->{InactiveDestroy} = 1;
 761   $self->_dbh(undef);
 762   $self->{_dbh_gen}++;
 763
 764   return;
 765 }
 766
 767 sub ensure_connected {
 768   my ($self) = @_;
 769
 770   unless ($self->connected) {
 771     $self->_populate_dbh;
 772   }
 773 }
 774
 775 =head2 dbh
 776
 777 Returns the dbh - a data base handle of class L<DBI>.
 778
 779 =cut
 780
 781 sub dbh {
 782   my ($self) = @_;
 783
 784   $self->ensure_connected;
 785   return $self->_dbh;
 786 }
 787
 788 sub _sql_maker_args {
 789     my ($self) = @_;
 790
 791     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 792 }
 793
 794 sub sql_maker {
 795   my ($self) = @_;
 796   unless ($self->_sql_maker) {
 797     my $sql_maker_class = $self->sql_maker_class;
 798     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 799   }
 800   return $self->_sql_maker;
 801 }
 802
 803 sub _rebless {}
 804
 805 sub _populate_dbh {
 806   my ($self) = @_;
 807   my @info = @{$self->_dbi_connect_info || []};
 808   $self->_dbh($self->_connect(@info));
 809
 810   # Always set the transaction depth on connect, since
 811   #  there is no transaction in progress by definition
 812   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 813
 814   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 815     my $driver = $self->_dbh->{Driver}->{Name};
 816     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 817       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 818       $self->_rebless();
 819     }
 820   }
 821
 822   my $connection_do = $self->on_connect_do;
 823   $self->_do_connection_actions($connection_do) if ref($connection_do);
 824
 825   $self->_conn_pid($$);
 826   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 827 }
 828
 829 sub _do_connection_actions {
 830   my $self = shift;
 831   my $connection_do = shift;
 832
 833   if (ref $connection_do eq 'ARRAY') {
 834     $self->_do_query($_) foreach @$connection_do;
 835   }
 836   elsif (ref $connection_do eq 'CODE') {
 837     $connection_do->();
 838   }
 839
 840   return $self;
 841 }
 842
 843 sub _do_query {
 844   my ($self, $action) = @_;
 845
 846   if (ref $action eq 'CODE') {
 847     $action = $action->($self);
 848     $self->_do_query($_) foreach @$action;
 849   }
 850   else {
 851     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 852     $self->_query_start(@to_run);
 853     $self->_dbh->do(@to_run);
 854     $self->_query_end(@to_run);
 855   }
 856
 857   return $self;
 858 }
 859
 860 sub _connect {
 861   my ($self, @info) = @_;
 862
 863   $self->throw_exception("You failed to provide any connection info")
 864     if !@info;
 865
 866   my ($old_connect_via, $dbh);
 867
 868   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 869     $old_connect_via = $DBI::connect_via;
 870     $DBI::connect_via = 'connect';
 871   }
 872
 873   eval {
 874     if(ref $info[0] eq 'CODE') {
 875        $dbh = &{$info[0]}
 876     }
 877     else {
 878        $dbh = DBI->connect(@info);
 879     }
 880
 881     if($dbh && !$self->unsafe) {
 882       my $weak_self = $self;
 883       weaken($weak_self);
 884       $dbh->{HandleError} = sub {
 885           if ($weak_self) {
 886             $weak_self->throw_exception("DBI Exception: $_[0]");
 887           }
 888           else {
 889             croak ("DBI Exception: $_[0]");
 890           }
 891       };
 892       $dbh->{ShowErrorStatement} = 1;
 893       $dbh->{RaiseError} = 1;
 894       $dbh->{PrintError} = 0;
 895     }
 896   };
 897
 898   $DBI::connect_via = $old_connect_via if $old_connect_via;
 899
 900   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 901     if !$dbh || $@;
 902
 903   $self->_dbh_autocommit($dbh->{AutoCommit});
 904
 905   $dbh;
 906 }
 907
 908 sub svp_begin {
 909   my ($self, $name) = @_;
 910
 911   $name = $self->_svp_generate_name
 912     unless defined $name;
 913
 914   $self->throw_exception ("You can't use savepoints outside a transaction")
 915     if $self->{transaction_depth} == 0;
 916
 917   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 918     unless $self->can('_svp_begin');
 919
 920   push @{ $self->{savepoints} }, $name;
 921
 922   $self->debugobj->svp_begin($name) if $self->debug;
 923
 924   return $self->_svp_begin($name);
 925 }
 926
 927 sub svp_release {
 928   my ($self, $name) = @_;
 929
 930   $self->throw_exception ("You can't use savepoints outside a transaction")
 931     if $self->{transaction_depth} == 0;
 932
 933   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 934     unless $self->can('_svp_release');
 935
 936   if (defined $name) {
 937     $self->throw_exception ("Savepoint '$name' does not exist")
 938       unless grep { $_ eq $name } @{ $self->{savepoints} };
 939
 940     # Dig through the stack until we find the one we are releasing.  This keeps
 941     # the stack up to date.
 942     my $svp;
 943
 944     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
 945   } else {
 946     $name = pop @{ $self->{savepoints} };
 947   }
 948
 949   $self->debugobj->svp_release($name) if $self->debug;
 950
 951   return $self->_svp_release($name);
 952 }
 953
 954 sub svp_rollback {
 955   my ($self, $name) = @_;
 956
 957   $self->throw_exception ("You can't use savepoints outside a transaction")
 958     if $self->{transaction_depth} == 0;
 959
 960   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 961     unless $self->can('_svp_rollback');
 962
 963   if (defined $name) {
 964       # If they passed us a name, verify that it exists in the stack
 965       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
 966           $self->throw_exception("Savepoint '$name' does not exist!");
 967       }
 968
 969       # Dig through the stack until we find the one we are releasing.  This keeps
 970       # the stack up to date.
 971       while(my $s = pop(@{ $self->{savepoints} })) {
 972           last if($s eq $name);
 973       }
 974       # Add the savepoint back to the stack, as a rollback doesn't remove the
 975       # named savepoint, only everything after it.
 976       push(@{ $self->{savepoints} }, $name);
 977   } else {
 978       # We'll assume they want to rollback to the last savepoint
 979       $name = $self->{savepoints}->[-1];
 980   }
 981
 982   $self->debugobj->svp_rollback($name) if $self->debug;
 983
 984   return $self->_svp_rollback($name);
 985 }
 986
 987 sub _svp_generate_name {
 988     my ($self) = @_;
 989
 990     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
 991 }
 992
 993 sub txn_begin {
 994   my $self = shift;
 995   $self->ensure_connected();
 996   if($self->{transaction_depth} == 0) {
 997     $self->debugobj->txn_begin()
 998       if $self->debug;
 999     # this isn't ->_dbh-> because
1000     #  we should reconnect on begin_work
1001     #  for AutoCommit users
1002     $self->dbh->begin_work;
1003   } elsif ($self->auto_savepoint) {
1004     $self->svp_begin;
1005   }
1006   $self->{transaction_depth}++;
1007 }
1008
1009 sub txn_commit {
1010   my $self = shift;
1011   if ($self->{transaction_depth} == 1) {
1012     my $dbh = $self->_dbh;
1013     $self->debugobj->txn_commit()
1014       if ($self->debug);
1015     $dbh->commit;
1016     $self->{transaction_depth} = 0
1017       if $self->_dbh_autocommit;
1018   }
1019   elsif($self->{transaction_depth} > 1) {
1020     $self->{transaction_depth}--;
1021     $self->svp_release
1022       if $self->auto_savepoint;
1023   }
1024 }
1025
1026 sub txn_rollback {
1027   my $self = shift;
1028   my $dbh = $self->_dbh;
1029   eval {
1030     if ($self->{transaction_depth} == 1) {
1031       $self->debugobj->txn_rollback()
1032         if ($self->debug);
1033       $self->{transaction_depth} = 0
1034         if $self->_dbh_autocommit;
1035       $dbh->rollback;
1036     }
1037     elsif($self->{transaction_depth} > 1) {
1038       $self->{transaction_depth}--;
1039       if ($self->auto_savepoint) {
1040         $self->svp_rollback;
1041         $self->svp_release;
1042       }
1043     }
1044     else {
1045       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1046     }
1047   };
1048   if ($@) {
1049     my $error = $@;
1050     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1051     $error =~ /$exception_class/ and $self->throw_exception($error);
1052     # ensure that a failed rollback resets the transaction depth
1053     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1054     $self->throw_exception($error);
1055   }
1056 }
1057
1058 # This used to be the top-half of _execute.  It was split out to make it
1059 #  easier to override in NoBindVars without duping the rest.  It takes up
1060 #  all of _execute's args, and emits $sql, @bind.
1061 sub _prep_for_execute {
1062   my ($self, $op, $extra_bind, $ident, $args) = @_;
1063
1064   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1065   unshift(@bind,
1066     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1067       if $extra_bind;
1068
1069   return ($sql, \@bind);
1070 }
1071
1072 sub _fix_bind_params {
1073     my ($self, @bind) = @_;
1074
1075     ### Turn @bind from something like this:
1076     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1077     ### to this:
1078     ###   ( "'1'", "'1'", "'3'" )
1079     return
1080         map {
1081             if ( defined( $_ && $_->[1] ) ) {
1082                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1083             }
1084             else { q{'NULL'}; }
1085         } @bind;
1086 }
1087
1088 sub _query_start {
1089     my ( $self, $sql, @bind ) = @_;
1090
1091     if ( $self->debug ) {
1092         @bind = $self->_fix_bind_params(@bind);
1093
1094         $self->debugobj->query_start( $sql, @bind );
1095     }
1096 }
1097
1098 sub _query_end {
1099     my ( $self, $sql, @bind ) = @_;
1100
1101     if ( $self->debug ) {
1102         @bind = $self->_fix_bind_params(@bind);
1103         $self->debugobj->query_end( $sql, @bind );
1104     }
1105 }
1106
1107 sub _dbh_execute {
1108   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1109
1110   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1111     $ident = $ident->from();
1112   }
1113
1114   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1115
1116   $self->_query_start( $sql, @$bind );
1117
1118   my $sth = $self->sth($sql,$op);
1119
1120   my $placeholder_index = 1;
1121
1122   foreach my $bound (@$bind) {
1123     my $attributes = {};
1124     my($column_name, @data) = @$bound;
1125
1126     if ($bind_attributes) {
1127       $attributes = $bind_attributes->{$column_name}
1128       if defined $bind_attributes->{$column_name};
1129     }
1130
1131     foreach my $data (@data) {
1132       $data = ref $data ? ''.$data : $data; # stringify args
1133
1134       $sth->bind_param($placeholder_index, $data, $attributes);
1135       $placeholder_index++;
1136     }
1137   }
1138
1139   # Can this fail without throwing an exception anyways???
1140   my $rv = $sth->execute();
1141   $self->throw_exception($sth->errstr) if !$rv;
1142
1143   $self->_query_end( $sql, @$bind );
1144
1145   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1146 }
1147
1148 sub _execute {
1149     my $self = shift;
1150     $self->dbh_do('_dbh_execute', @_)
1151 }
1152
1153 sub insert {
1154   my ($self, $source, $to_insert) = @_;
1155
1156   my $ident = $source->from;
1157   my $bind_attributes = $self->source_bind_attributes($source);
1158
1159   $self->ensure_connected;
1160   foreach my $col ( $source->columns ) {
1161     if ( !defined $to_insert->{$col} ) {
1162       my $col_info = $source->column_info($col);
1163
1164       if ( $col_info->{auto_nextval} ) {
1165         $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1166       }
1167     }
1168   }
1169
1170   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1171
1172   return $to_insert;
1173 }
1174
1175 ## Still not quite perfect, and EXPERIMENTAL
1176 ## Currently it is assumed that all values passed will be "normal", i.e. not
1177 ## scalar refs, or at least, all the same type as the first set, the statement is
1178 ## only prepped once.
1179 sub insert_bulk {
1180   my ($self, $source, $cols, $data) = @_;
1181   my %colvalues;
1182   my $table = $source->from;
1183   @colvalues{@$cols} = (0..$#$cols);
1184   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1185
1186   $self->_query_start( $sql, @bind );
1187   my $sth = $self->sth($sql);
1188
1189 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1190
1191   ## This must be an arrayref, else nothing works!
1192
1193   my $tuple_status = [];
1194
1195   ##use Data::Dumper;
1196   ##print STDERR Dumper( $data, $sql, [@bind] );
1197
1198   my $time = time();
1199
1200   ## Get the bind_attributes, if any exist
1201   my $bind_attributes = $self->source_bind_attributes($source);
1202
1203   ## Bind the values and execute
1204   my $placeholder_index = 1;
1205
1206   foreach my $bound (@bind) {
1207
1208     my $attributes = {};
1209     my ($column_name, $data_index) = @$bound;
1210
1211     if( $bind_attributes ) {
1212       $attributes = $bind_attributes->{$column_name}
1213       if defined $bind_attributes->{$column_name};
1214     }
1215
1216     my @data = map { $_->[$data_index] } @$data;
1217
1218     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1219     $placeholder_index++;
1220   }
1221   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1222   $self->throw_exception($sth->errstr) if !$rv;
1223
1224   $self->_query_end( $sql, @bind );
1225   return (wantarray ? ($rv, $sth, @bind) : $rv);
1226 }
1227
1228 sub update {
1229   my $self = shift @_;
1230   my $source = shift @_;
1231   my $bind_attributes = $self->source_bind_attributes($source);
1232
1233   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1234 }
1235
1236
1237 sub delete {
1238   my $self = shift @_;
1239   my $source = shift @_;
1240
1241   my $bind_attrs = {}; ## If ever it's needed...
1242
1243   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1244 }
1245
1246 sub _select {
1247   my ($self, $ident, $select, $condition, $attrs) = @_;
1248   my $order = $attrs->{order_by};
1249
1250   if (ref $condition eq 'SCALAR') {
1251     my $unwrap = ${$condition};
1252     if ($unwrap =~ s/ORDER BY (.*)$//i) {
1253       $order = $1;
1254       $condition = \$unwrap;
1255     }
1256   }
1257
1258   my $for = delete $attrs->{for};
1259   my $sql_maker = $self->sql_maker;
1260   local $sql_maker->{for} = $for;
1261
1262   if (exists $attrs->{group_by} || $attrs->{having}) {
1263     $order = {
1264       group_by => $attrs->{group_by},
1265       having => $attrs->{having},
1266       ($order ? (order_by => $order) : ())
1267     };
1268   }
1269   my $bind_attrs = {}; ## Future support
1270   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1271   if ($attrs->{software_limit} ||
1272       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1273         $attrs->{software_limit} = 1;
1274   } else {
1275     $self->throw_exception("rows attribute must be positive if present")
1276       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1277
1278     # MySQL actually recommends this approach.  I cringe.
1279     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1280     push @args, $attrs->{rows}, $attrs->{offset};
1281   }
1282
1283   return $self->_execute(@args);
1284 }
1285
1286 sub source_bind_attributes {
1287   my ($self, $source) = @_;
1288
1289   my $bind_attributes;
1290   foreach my $column ($source->columns) {
1291
1292     my $data_type = $source->column_info($column)->{data_type} || '';
1293     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1294      if $data_type;
1295   }
1296
1297   return $bind_attributes;
1298 }
1299
1300 =head2 select
1301
1302 =over 4
1303
1304 =item Arguments: $ident, $select, $condition, $attrs
1305
1306 =back
1307
1308 Handle a SQL select statement.
1309
1310 =cut
1311
1312 sub select {
1313   my $self = shift;
1314   my ($ident, $select, $condition, $attrs) = @_;
1315   return $self->cursor_class->new($self, \@_, $attrs);
1316 }
1317
1318 sub select_single {
1319   my $self = shift;
1320   my ($rv, $sth, @bind) = $self->_select(@_);
1321   my @row = $sth->fetchrow_array;
1322   if(@row && $sth->fetchrow_array) {
1323     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1324   }
1325   # Need to call finish() to work round broken DBDs
1326   $sth->finish();
1327   return @row;
1328 }
1329
1330 =head2 sth
1331
1332 =over 4
1333
1334 =item Arguments: $sql
1335
1336 =back
1337
1338 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1339
1340 =cut
1341
1342 sub _dbh_sth {
1343   my ($self, $dbh, $sql) = @_;
1344
1345   # 3 is the if_active parameter which avoids active sth re-use
1346   my $sth = $self->disable_sth_caching
1347     ? $dbh->prepare($sql)
1348     : $dbh->prepare_cached($sql, {}, 3);
1349
1350   # XXX You would think RaiseError would make this impossible,
1351   #  but apparently that's not true :(
1352   $self->throw_exception($dbh->errstr) if !$sth;
1353
1354   $sth;
1355 }
1356
1357 sub sth {
1358   my ($self, $sql) = @_;
1359   $self->dbh_do('_dbh_sth', $sql);
1360 }
1361
1362 sub _dbh_columns_info_for {
1363   my ($self, $dbh, $table) = @_;
1364
1365   if ($dbh->can('column_info')) {
1366     my %result;
1367     eval {
1368       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1369       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1370       $sth->execute();
1371       while ( my $info = $sth->fetchrow_hashref() ){
1372         my %column_info;
1373         $column_info{data_type}   = $info->{TYPE_NAME};
1374         $column_info{size}      = $info->{COLUMN_SIZE};
1375         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1376         $column_info{default_value} = $info->{COLUMN_DEF};
1377         my $col_name = $info->{COLUMN_NAME};
1378         $col_name =~ s/^\"(.*)\"$/$1/;
1379
1380         $result{$col_name} = \%column_info;
1381       }
1382     };
1383     return \%result if !$@ && scalar keys %result;
1384   }
1385
1386   my %result;
1387   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1388   $sth->execute;
1389   my @columns = @{$sth->{NAME_lc}};
1390   for my $i ( 0 .. $#columns ){
1391     my %column_info;
1392     $column_info{data_type} = $sth->{TYPE}->[$i];
1393     $column_info{size} = $sth->{PRECISION}->[$i];
1394     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1395
1396     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1397       $column_info{data_type} = $1;
1398       $column_info{size}    = $2;
1399     }
1400
1401     $result{$columns[$i]} = \%column_info;
1402   }
1403   $sth->finish;
1404
1405   foreach my $col (keys %result) {
1406     my $colinfo = $result{$col};
1407     my $type_num = $colinfo->{data_type};
1408     my $type_name;
1409     if(defined $type_num && $dbh->can('type_info')) {
1410       my $type_info = $dbh->type_info($type_num);
1411       $type_name = $type_info->{TYPE_NAME} if $type_info;
1412       $colinfo->{data_type} = $type_name if $type_name;
1413     }
1414   }
1415
1416   return \%result;
1417 }
1418
1419 sub columns_info_for {
1420   my ($self, $table) = @_;
1421   $self->dbh_do('_dbh_columns_info_for', $table);
1422 }
1423
1424 =head2 last_insert_id
1425
1426 Return the row id of the last insert.
1427
1428 =cut
1429
1430 sub _dbh_last_insert_id {
1431     my ($self, $dbh, $source, $col) = @_;
1432     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1433     $dbh->func('last_insert_rowid');
1434 }
1435
1436 sub last_insert_id {
1437   my $self = shift;
1438   $self->dbh_do('_dbh_last_insert_id', @_);
1439 }
1440
1441 =head2 sqlt_type
1442
1443 Returns the database driver name.
1444
1445 =cut
1446
1447 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1448
1449 =head2 bind_attribute_by_data_type
1450
1451 Given a datatype from column info, returns a database specific bind attribute for
1452 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1453 just handle it.
1454
1455 Generally only needed for special case column types, like bytea in postgres.
1456
1457 =cut
1458
1459 sub bind_attribute_by_data_type {
1460     return;
1461 }
1462
1463 =head2 create_ddl_dir
1464
1465 =over 4
1466
1467 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1468
1469 =back
1470
1471 Creates a SQL file based on the Schema, for each of the specified
1472 database types, in the given directory.
1473
1474 By default, C<\%sqlt_args> will have
1475
1476  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1477
1478 merged with the hash passed in. To disable any of those features, pass in a
1479 hashref like the following
1480
1481  { ignore_constraint_names => 0, # ... other options }
1482
1483 =cut
1484
1485 sub create_ddl_dir {
1486   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1487
1488   if(!$dir || !-d $dir) {
1489     warn "No directory given, using ./\n";
1490     $dir = "./";
1491   }
1492   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1493   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1494   $version ||= $schema->VERSION || '1.x';
1495   $sqltargs = {
1496     add_drop_table => 1,
1497     ignore_constraint_names => 1,
1498     ignore_index_names => 1,
1499     %{$sqltargs || {}}
1500   };
1501
1502   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09: '}
1503       . $self->_check_sqlt_message . q{'})
1504           if !$self->_check_sqlt_version;
1505
1506   my $sqlt = SQL::Translator->new( $sqltargs );
1507
1508   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1509   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1510
1511   foreach my $db (@$databases) {
1512     $sqlt->reset();
1513     $sqlt = $self->configure_sqlt($sqlt, $db);
1514     $sqlt->{schema} = $sqlt_schema;
1515     $sqlt->producer($db);
1516
1517     my $file;
1518     my $filename = $schema->ddl_filename($db, $version, $dir);
1519     if (-e $filename && (!$version || ($version == $schema->schema_version()))) {
1520       # if we are dumping the current version, overwrite the DDL
1521       warn "Overwriting existing DDL file - $filename";
1522       unlink($filename);
1523     }
1524
1525     my $output = $sqlt->translate;
1526     if(!$output) {
1527       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1528       next;
1529     }
1530     if(!open($file, ">$filename")) {
1531       $self->throw_exception("Can't open $filename for writing ($!)");
1532       next;
1533     }
1534     print $file $output;
1535     close($file);
1536
1537     next unless ($preversion);
1538
1539     require SQL::Translator::Diff;
1540
1541     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1542     if(!-e $prefilename) {
1543       warn("No previous schema file found ($prefilename)");
1544       next;
1545     }
1546
1547     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1548     if(-e $difffile) {
1549       warn("Overwriting existing diff file - $difffile");
1550       unlink($difffile);
1551     }
1552
1553     my $source_schema;
1554     {
1555       my $t = SQL::Translator->new($sqltargs);
1556       $t->debug( 0 );
1557       $t->trace( 0 );
1558       $t->parser( $db )                       or die $t->error;
1559       $t = $self->configure_sqlt($t, $db);
1560       my $out = $t->translate( $prefilename ) or die $t->error;
1561       $source_schema = $t->schema;
1562       unless ( $source_schema->name ) {
1563         $source_schema->name( $prefilename );
1564       }
1565     }
1566
1567     # The "new" style of producers have sane normalization and can support
1568     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1569     # And we have to diff parsed SQL against parsed SQL.
1570     my $dest_schema = $sqlt_schema;
1571
1572     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1573       my $t = SQL::Translator->new($sqltargs);
1574       $t->debug( 0 );
1575       $t->trace( 0 );
1576       $t->parser( $db )                    or die $t->error;
1577       $t = $self->configure_sqlt($t, $db);
1578       my $out = $t->translate( $filename ) or die $t->error;
1579       $dest_schema = $t->schema;
1580       $dest_schema->name( $filename )
1581         unless $dest_schema->name;
1582     }
1583
1584     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1585                                                   $dest_schema,   $db,
1586                                                   $sqltargs
1587                                                  );
1588     if(!open $file, ">$difffile") {
1589       $self->throw_exception("Can't write to $difffile ($!)");
1590       next;
1591     }
1592     print $file $diff;
1593     close($file);
1594   }
1595 }
1596
1597 sub configure_sqlt() {
1598   my $self = shift;
1599   my $tr = shift;
1600   my $db = shift || $self->sqlt_type;
1601   if ($db eq 'PostgreSQL') {
1602     $tr->quote_table_names(0);
1603     $tr->quote_field_names(0);
1604   }
1605   return $tr;
1606 }
1607
1608 =head2 deployment_statements
1609
1610 =over 4
1611
1612 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1613
1614 =back
1615
1616 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1617 The database driver name is given by C<$type>, though the value from
1618 L</sqlt_type> is used if it is not specified.
1619
1620 C<$directory> is used to return statements from files in a previously created
1621 L</create_ddl_dir> directory and is optional. The filenames are constructed
1622 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1623
1624 If no C<$directory> is specified then the statements are constructed on the
1625 fly using L<SQL::Translator> and C<$version> is ignored.
1626
1627 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1628
1629 =cut
1630
1631 sub deployment_statements {
1632   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1633   # Need to be connected to get the correct sqlt_type
1634   $self->ensure_connected() unless $type;
1635   $type ||= $self->sqlt_type;
1636   $version ||= $schema->VERSION || '1.x';
1637   $dir ||= './';
1638   my $filename = $schema->ddl_filename($type, $dir, $version);
1639   if(-f $filename)
1640   {
1641       my $file;
1642       open($file, "<$filename")
1643         or $self->throw_exception("Can't open $filename ($!)");
1644       my @rows = <$file>;
1645       close($file);
1646       return join('', @rows);
1647   }
1648
1649   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09: '}
1650       . $self->_check_sqlt_message . q{'})
1651           if !$self->_check_sqlt_version;
1652
1653   require SQL::Translator::Parser::DBIx::Class;
1654   eval qq{use SQL::Translator::Producer::${type}};
1655   $self->throw_exception($@) if $@;
1656
1657   # sources needs to be a parser arg, but for simplicty allow at top level
1658   # coming in
1659   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1660       if exists $sqltargs->{sources};
1661
1662   my $tr = SQL::Translator->new(%$sqltargs);
1663   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1664   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1665 }
1666
1667 sub deploy {
1668   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1669   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1670     foreach my $line ( split(";\n", $statement)) {
1671       next if($line =~ /^--/);
1672       next if(!$line);
1673 #      next if($line =~ /^DROP/m);
1674       next if($line =~ /^BEGIN TRANSACTION/m);
1675       next if($line =~ /^COMMIT/m);
1676       next if $line =~ /^\s+$/; # skip whitespace only
1677       $self->_query_start($line);
1678       eval {
1679         $self->dbh->do($line); # shouldn't be using ->dbh ?
1680       };
1681       if ($@) {
1682         warn qq{$@ (running "${line}")};
1683       }
1684       $self->_query_end($line);
1685     }
1686   }
1687 }
1688
1689 =head2 datetime_parser
1690
1691 Returns the datetime parser class
1692
1693 =cut
1694
1695 sub datetime_parser {
1696   my $self = shift;
1697   return $self->{datetime_parser} ||= do {
1698     $self->ensure_connected;
1699     $self->build_datetime_parser(@_);
1700   };
1701 }
1702
1703 =head2 datetime_parser_type
1704
1705 Defines (returns) the datetime parser class - currently hardwired to
1706 L<DateTime::Format::MySQL>
1707
1708 =cut
1709
1710 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1711
1712 =head2 build_datetime_parser
1713
1714 See L</datetime_parser>
1715
1716 =cut
1717
1718 sub build_datetime_parser {
1719   my $self = shift;
1720   my $type = $self->datetime_parser_type(@_);
1721   eval "use ${type}";
1722   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1723   return $type;
1724 }
1725
1726 {
1727     my $_check_sqlt_version; # private
1728     my $_check_sqlt_message; # private
1729     sub _check_sqlt_version {
1730         return $_check_sqlt_version if defined $_check_sqlt_version;
1731         eval 'use SQL::Translator "0.09"';
1732         $_check_sqlt_message = $@ || '';
1733         $_check_sqlt_version = !$@;
1734     }
1735
1736     sub _check_sqlt_message {
1737         _check_sqlt_version if !defined $_check_sqlt_message;
1738         $_check_sqlt_message;
1739     }
1740 }
1741
1742 =head2 is_replicating
1743
1744 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1745 replicate from a master database.  Default is undef, which is the result
1746 returned by databases that don't support replication.
1747
1748 =cut
1749
1750 sub is_replicating {
1751     return;
1752
1753 }
1754
1755 =head2 lag_behind_master
1756
1757 Returns a number that represents a certain amount of lag behind a master db
1758 when a given storage is replicating.  The number is database dependent, but
1759 starts at zero and increases with the amount of lag. Default in undef
1760
1761 =cut
1762
1763 sub lag_behind_master {
1764     return;
1765 }
1766
1767 sub DESTROY {
1768   my $self = shift;
1769   return if !$self->_dbh;
1770   $self->_verify_pid;
1771   $self->_dbh(undef);
1772 }
1773
1774 1;
1775
1776 =head1 SQL METHODS
1777
1778 The module defines a set of methods within the DBIC::SQL::Abstract
1779 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1780 SQL query functions.
1781
1782 The following methods are extended:-
1783
1784 =over 4
1785
1786 =item delete
1787
1788 =item insert
1789
1790 =item select
1791
1792 =item update
1793
1794 =item limit_dialect
1795
1796 See L</connect_info> for details.
1797 For setting, this method is deprecated in favor of L</connect_info>.
1798
1799 =item quote_char
1800
1801 See L</connect_info> for details.
1802 For setting, this method is deprecated in favor of L</connect_info>.
1803
1804 =item name_sep
1805
1806 See L</connect_info> for details.
1807 For setting, this method is deprecated in favor of L</connect_info>.
1808
1809 =back
1810
1811 =head1 AUTHORS
1812
1813 Matt S. Trout <mst@shadowcatsystems.co.uk>
1814
1815 Andy Grundman <andy@hybridized.org>
1816
1817 =head1 LICENSE
1818
1819 You may distribute this code under the same terms as Perl itself.
1820
1821 =cut