lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use Scalar::Util qw/blessed weaken/;
  13
  14 __PACKAGE__->mk_group_accessors('simple' =>
  15     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  16        _conn_pid _conn_tid disable_sth_caching cursor on_connect_do
  17        on_disconnect_do transaction_depth unsafe _dbh_autocommit/
  18 );
  19
  20 BEGIN {
  21
  22 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  23
  24 use base qw/SQL::Abstract::Limit/;
  25
  26 # This prevents the caching of $dbh in S::A::L, I believe
  27 sub new {
  28   my $self = shift->SUPER::new(@_);
  29
  30   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  31   #   it with what it resolves to:
  32   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  33     if ref $self->{limit_dialect};
  34
  35   $self;
  36 }
  37
  38 sub _RowNumberOver {
  39   my ($self, $sql, $order, $rows, $offset ) = @_;
  40
  41   $offset += 1;
  42   my $last = $rows + $offset;
  43   my ( $order_by ) = $self->_order_by( $order );
  44
  45   $sql = <<"";
  46 SELECT * FROM
  47 (
  48    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  49       $sql
  50       $order_by
  51    ) Q1
  52 ) Q2
  53 WHERE ROW_NUM BETWEEN $offset AND $last
  54
  55   return $sql;
  56 }
  57
  58
  59 # While we're at it, this should make LIMIT queries more efficient,
  60 #  without digging into things too deeply
  61 use Scalar::Util 'blessed';
  62 sub _find_syntax {
  63   my ($self, $syntax) = @_;
  64   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  65   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  66     return 'RowNumberOver';
  67   }
  68
  69   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  70 }
  71
  72 sub select {
  73   my ($self, $table, $fields, $where, $order, @rest) = @_;
  74   $table = $self->_quote($table) unless ref($table);
  75   local $self->{rownum_hack_count} = 1
  76     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  77   @rest = (-1) unless defined $rest[0];
  78   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  79     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  80   local $self->{having_bind} = [];
  81   my ($sql, @ret) = $self->SUPER::select(
  82     $table, $self->_recurse_fields($fields), $where, $order, @rest
  83   );
  84   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  85 }
  86
  87 sub insert {
  88   my $self = shift;
  89   my $table = shift;
  90   $table = $self->_quote($table) unless ref($table);
  91   $self->SUPER::insert($table, @_);
  92 }
  93
  94 sub update {
  95   my $self = shift;
  96   my $table = shift;
  97   $table = $self->_quote($table) unless ref($table);
  98   $self->SUPER::update($table, @_);
  99 }
 100
 101 sub delete {
 102   my $self = shift;
 103   my $table = shift;
 104   $table = $self->_quote($table) unless ref($table);
 105   $self->SUPER::delete($table, @_);
 106 }
 107
 108 sub _emulate_limit {
 109   my $self = shift;
 110   if ($_[3] == -1) {
 111     return $_[1].$self->_order_by($_[2]);
 112   } else {
 113     return $self->SUPER::_emulate_limit(@_);
 114   }
 115 }
 116
 117 sub _recurse_fields {
 118   my ($self, $fields, $params) = @_;
 119   my $ref = ref $fields;
 120   return $self->_quote($fields) unless $ref;
 121   return $$fields if $ref eq 'SCALAR';
 122
 123   if ($ref eq 'ARRAY') {
 124     return join(', ', map {
 125       $self->_recurse_fields($_)
 126         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 127           ? ' AS col'.$self->{rownum_hack_count}++
 128           : '')
 129       } @$fields);
 130   } elsif ($ref eq 'HASH') {
 131     foreach my $func (keys %$fields) {
 132       return $self->_sqlcase($func)
 133         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 134     }
 135   }
 136 }
 137
 138 sub _order_by {
 139   my $self = shift;
 140   my $ret = '';
 141   my @extra;
 142   if (ref $_[0] eq 'HASH') {
 143     if (defined $_[0]->{group_by}) {
 144       $ret = $self->_sqlcase(' group by ')
 145         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 146     }
 147     if (defined $_[0]->{having}) {
 148       my $frag;
 149       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 150       push(@{$self->{having_bind}}, @extra);
 151       $ret .= $self->_sqlcase(' having ').$frag;
 152     }
 153     if (defined $_[0]->{order_by}) {
 154       $ret .= $self->_order_by($_[0]->{order_by});
 155     }
 156   } elsif (ref $_[0] eq 'SCALAR') {
 157     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 158   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 159     my @order = @{+shift};
 160     $ret = $self->_sqlcase(' order by ')
 161           .join(', ', map {
 162                         my $r = $self->_order_by($_, @_);
 163                         $r =~ s/^ ?ORDER BY //i;
 164                         $r;
 165                       } @order);
 166   } else {
 167     $ret = $self->SUPER::_order_by(@_);
 168   }
 169   return $ret;
 170 }
 171
 172 sub _order_directions {
 173   my ($self, $order) = @_;
 174   $order = $order->{order_by} if ref $order eq 'HASH';
 175   return $self->SUPER::_order_directions($order);
 176 }
 177
 178 sub _table {
 179   my ($self, $from) = @_;
 180   if (ref $from eq 'ARRAY') {
 181     return $self->_recurse_from(@$from);
 182   } elsif (ref $from eq 'HASH') {
 183     return $self->_make_as($from);
 184   } else {
 185     return $from; # would love to quote here but _table ends up getting called
 186                   # twice during an ->select without a limit clause due to
 187                   # the way S::A::Limit->select works. should maybe consider
 188                   # bypassing this and doing S::A::select($self, ...) in
 189                   # our select method above. meantime, quoting shims have
 190                   # been added to select/insert/update/delete here
 191   }
 192 }
 193
 194 sub _recurse_from {
 195   my ($self, $from, @join) = @_;
 196   my @sqlf;
 197   push(@sqlf, $self->_make_as($from));
 198   foreach my $j (@join) {
 199     my ($to, $on) = @$j;
 200
 201     # check whether a join type exists
 202     my $join_clause = '';
 203     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 204     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 205       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 206     } else {
 207       $join_clause = ' JOIN ';
 208     }
 209     push(@sqlf, $join_clause);
 210
 211     if (ref $to eq 'ARRAY') {
 212       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 213     } else {
 214       push(@sqlf, $self->_make_as($to));
 215     }
 216     push(@sqlf, ' ON ', $self->_join_condition($on));
 217   }
 218   return join('', @sqlf);
 219 }
 220
 221 sub _make_as {
 222   my ($self, $from) = @_;
 223   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 224                      reverse each %{$self->_skip_options($from)});
 225 }
 226
 227 sub _skip_options {
 228   my ($self, $hash) = @_;
 229   my $clean_hash = {};
 230   $clean_hash->{$_} = $hash->{$_}
 231     for grep {!/^-/} keys %$hash;
 232   return $clean_hash;
 233 }
 234
 235 sub _join_condition {
 236   my ($self, $cond) = @_;
 237   if (ref $cond eq 'HASH') {
 238     my %j;
 239     for (keys %$cond) {
 240       my $v = $cond->{$_};
 241       if (ref $v) {
 242         # XXX no throw_exception() in this package and croak() fails with strange results
 243         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 244             if ref($v) ne 'SCALAR';
 245         $j{$_} = $v;
 246       }
 247       else {
 248         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 249       }
 250     };
 251     return scalar($self->_recurse_where(\%j));
 252   } elsif (ref $cond eq 'ARRAY') {
 253     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 254   } else {
 255     die "Can't handle this yet!";
 256   }
 257 }
 258
 259 sub _quote {
 260   my ($self, $label) = @_;
 261   return '' unless defined $label;
 262   return "*" if $label eq '*';
 263   return $label unless $self->{quote_char};
 264   if(ref $self->{quote_char} eq "ARRAY"){
 265     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 266       if !defined $self->{name_sep};
 267     my $sep = $self->{name_sep};
 268     return join($self->{name_sep},
 269         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 270        split(/\Q$sep\E/,$label));
 271   }
 272   return $self->SUPER::_quote($label);
 273 }
 274
 275 sub limit_dialect {
 276     my $self = shift;
 277     $self->{limit_dialect} = shift if @_;
 278     return $self->{limit_dialect};
 279 }
 280
 281 sub quote_char {
 282     my $self = shift;
 283     $self->{quote_char} = shift if @_;
 284     return $self->{quote_char};
 285 }
 286
 287 sub name_sep {
 288     my $self = shift;
 289     $self->{name_sep} = shift if @_;
 290     return $self->{name_sep};
 291 }
 292
 293 } # End of BEGIN block
 294
 295 =head1 NAME
 296
 297 DBIx::Class::Storage::DBI - DBI storage handler
 298
 299 =head1 SYNOPSIS
 300
 301 =head1 DESCRIPTION
 302
 303 This class represents the connection to an RDBMS via L<DBI>.  See
 304 L<DBIx::Class::Storage> for general information.  This pod only
 305 documents DBI-specific methods and behaviors.
 306
 307 =head1 METHODS
 308
 309 =cut
 310
 311 sub new {
 312   my $new = shift->next::method(@_);
 313
 314   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 315   $new->transaction_depth(0);
 316   $new->_sql_maker_opts({});
 317   $new->{_in_dbh_do} = 0;
 318   $new->{_dbh_gen} = 0;
 319
 320   $new;
 321 }
 322
 323 =head2 connect_info
 324
 325 The arguments of C<connect_info> are always a single array reference.
 326
 327 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 328 encapsulates its argument list in an arrayref before calling
 329 C<connect_info> here.
 330
 331 The arrayref can either contain the same set of arguments one would
 332 normally pass to L<DBI/connect>, or a lone code reference which returns
 333 a connected database handle.  Please note that the L<DBI> docs
 334 recommend that you always explicitly set C<AutoCommit> to either
 335 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 336 to C<1>, and that you perform transactions via our L</txn_do>
 337 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 338 set it to zero.  This is the default for most DBDs.  See below for more
 339 details.
 340
 341 In either case, if the final argument in your connect_info happens
 342 to be a hashref, C<connect_info> will look there for several
 343 connection-specific options:
 344
 345 =over 4
 346
 347 =item on_connect_do
 348
 349 This can be set to an arrayref containing literal sql statements and
 350 code references, which will be executed immediately after making the
 351 connection to the database every time we [re-]connect.
 352
 353 =item on_disconnect_do
 354
 355 As with L<on_connect_do>, this takes an arrayref of literal sql
 356 statements and code references, but these statements execute immediately
 357 before disconnecting from the database.
 358
 359 Note, this only runs if you explicitly call L<disconnect> on the
 360 storage object.
 361
 362 =item disable_sth_caching
 363
 364 If set to a true value, this option will disable the caching of
 365 statement handles via L<DBI/prepare_cached>.
 366
 367 =item limit_dialect
 368
 369 Sets the limit dialect. This is useful for JDBC-bridge among others
 370 where the remote SQL-dialect cannot be determined by the name of the
 371 driver alone.
 372
 373 =item quote_char
 374
 375 Specifies what characters to use to quote table and column names. If
 376 you use this you will want to specify L<name_sep> as well.
 377
 378 quote_char expects either a single character, in which case is it is placed
 379 on either side of the table/column, or an arrayref of length 2 in which case the
 380 table/column name is placed between the elements.
 381
 382 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 383 use C<quote_char =E<gt> [qw/[ ]/]>.
 384
 385 =item name_sep
 386
 387 This only needs to be used in conjunction with L<quote_char>, and is used to
 388 specify the charecter that seperates elements (schemas, tables, columns) from
 389 each other. In most cases this is simply a C<.>.
 390
 391 =item unsafe
 392
 393 This Storage driver normally installs its own C<HandleError>, sets
 394 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 395 all database handles, including those supplied by a coderef.  It does this
 396 so that it can have consistent and useful error behavior.
 397
 398 If you set this option to a true value, Storage will not do its usual
 399 modifications to the database handle's attributes, and instead relies on
 400 the settings in your connect_info DBI options (or the values you set in
 401 your connection coderef, in the case that you are connecting via coderef).
 402
 403 Note that your custom settings can cause Storage to malfunction,
 404 especially if you set a C<HandleError> handler that suppresses exceptions
 405 and/or disable C<RaiseError>.
 406
 407 =back
 408
 409 These options can be mixed in with your other L<DBI> connection attributes,
 410 or placed in a seperate hashref after all other normal L<DBI> connection
 411 arguments.
 412
 413 Every time C<connect_info> is invoked, any previous settings for
 414 these options will be cleared before setting the new ones, regardless of
 415 whether any options are specified in the new C<connect_info>.
 416
 417 Another Important Note:
 418
 419 DBIC can do some wonderful magic with handling exceptions,
 420 disconnections, and transactions when you use C<AutoCommit =&gt; 1>
 421 combined with C<txn_do> for transaction support.
 422
 423 If you set C<AutoCommit =&gt; 0> in your connect info, then you are always
 424 in an assumed transaction between commits, and you're telling us you'd
 425 like to manage that manually.  A lot of DBIC's magic protections
 426 go away.  We can't protect you from exceptions due to database
 427 disconnects because we don't know anything about how to restart your
 428 transactions.  You're on your own for handling all sorts of exceptional
 429 cases if you choose the C<AutoCommit =&gt 0> path, just as you would
 430 be with raw DBI.
 431
 432 Examples:
 433
 434   # Simple SQLite connection
 435   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 436
 437   # Connect via subref
 438   ->connect_info([ sub { DBI->connect(...) } ]);
 439
 440   # A bit more complicated
 441   ->connect_info(
 442     [
 443       'dbi:Pg:dbname=foo',
 444       'postgres',
 445       'my_pg_password',
 446       { AutoCommit => 1 },
 447       { quote_char => q{"}, name_sep => q{.} },
 448     ]
 449   );
 450
 451   # Equivalent to the previous example
 452   ->connect_info(
 453     [
 454       'dbi:Pg:dbname=foo',
 455       'postgres',
 456       'my_pg_password',
 457       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 458     ]
 459   );
 460
 461   # Subref + DBIC-specific connection options
 462   ->connect_info(
 463     [
 464       sub { DBI->connect(...) },
 465       {
 466           quote_char => q{`},
 467           name_sep => q{@},
 468           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 469           disable_sth_caching => 1,
 470       },
 471     ]
 472   );
 473
 474 =cut
 475
 476 sub connect_info {
 477   my ($self, $info_arg) = @_;
 478
 479   return $self->_connect_info if !$info_arg;
 480
 481   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 482   #  the new set of options
 483   $self->_sql_maker(undef);
 484   $self->_sql_maker_opts({});
 485   $self->_connect_info([@$info_arg]); # copy for _connect_info
 486
 487   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 488
 489   my $last_info = $dbi_info->[-1];
 490   if(ref $last_info eq 'HASH') {
 491     $last_info = { %$last_info }; # so delete is non-destructive
 492     my @storage_option =
 493        qw/on_connect_do on_disconnect_do disable_sth_caching unsafe/;
 494     for my $storage_opt (@storage_option) {
 495       if(my $value = delete $last_info->{$storage_opt}) {
 496         $self->$storage_opt($value);
 497       }
 498     }
 499     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 500       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 501         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 502       }
 503     }
 504     # re-insert modified hashref
 505     $dbi_info->[-1] = $last_info;
 506
 507     # Get rid of any trailing empty hashref
 508     pop(@$dbi_info) if !keys %$last_info;
 509   }
 510   $self->_dbi_connect_info($dbi_info);
 511
 512   $self->_connect_info;
 513 }
 514
 515 =head2 on_connect_do
 516
 517 This method is deprecated in favor of setting via L</connect_info>.
 518
 519 =head2 dbh_do
 520
 521 Arguments: $subref, @extra_coderef_args?
 522
 523 Execute the given subref using the new exception-based connection management.
 524
 525 The first two arguments will be the storage object that C<dbh_do> was called
 526 on and a database handle to use.  Any additional arguments will be passed
 527 verbatim to the called subref as arguments 2 and onwards.
 528
 529 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 530 exception handling and reconnection (or failover in future subclasses).
 531
 532 Your subref should have no side-effects outside of the database, as
 533 there is the potential for your subref to be partially double-executed
 534 if the database connection was stale/dysfunctional.
 535
 536 Example:
 537
 538   my @stuff = $schema->storage->dbh_do(
 539     sub {
 540       my ($storage, $dbh, @cols) = @_;
 541       my $cols = join(q{, }, @cols);
 542       $dbh->selectrow_array("SELECT $cols FROM foo");
 543     },
 544     @column_list
 545   );
 546
 547 =cut
 548
 549 sub dbh_do {
 550   my $self = shift;
 551   my $coderef = shift;
 552
 553   ref $coderef eq 'CODE' or $self->throw_exception
 554     ('$coderef must be a CODE reference');
 555
 556   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do}
 557       || $self->{transaction_depth};
 558
 559   local $self->{_in_dbh_do} = 1;
 560
 561   my @result;
 562   my $want_array = wantarray;
 563
 564   eval {
 565     $self->_verify_pid if $self->_dbh;
 566     $self->_populate_dbh if !$self->_dbh;
 567     if($want_array) {
 568         @result = $coderef->($self, $self->_dbh, @_);
 569     }
 570     elsif(defined $want_array) {
 571         $result[0] = $coderef->($self, $self->_dbh, @_);
 572     }
 573     else {
 574         $coderef->($self, $self->_dbh, @_);
 575     }
 576   };
 577
 578   my $exception = $@;
 579   if(!$exception) { return $want_array ? @result : $result[0] }
 580
 581   $self->throw_exception($exception) if $self->connected;
 582
 583   # We were not connected - reconnect and retry, but let any
 584   #  exception fall right through this time
 585   $self->_populate_dbh;
 586   $coderef->($self, $self->_dbh, @_);
 587 }
 588
 589 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 590 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 591 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 592 sub txn_do {
 593   my $self = shift;
 594   my $coderef = shift;
 595
 596   ref $coderef eq 'CODE' or $self->throw_exception
 597     ('$coderef must be a CODE reference');
 598
 599   return $coderef->(@_) if $self->{transaction_depth};
 600
 601   local $self->{_in_dbh_do} = 1;
 602
 603   my @result;
 604   my $want_array = wantarray;
 605
 606   my $tried = 0;
 607   while(1) {
 608     eval {
 609       $self->_verify_pid if $self->_dbh;
 610       $self->_populate_dbh if !$self->_dbh;
 611
 612       $self->txn_begin;
 613       if($want_array) {
 614           @result = $coderef->(@_);
 615       }
 616       elsif(defined $want_array) {
 617           $result[0] = $coderef->(@_);
 618       }
 619       else {
 620           $coderef->(@_);
 621       }
 622       $self->txn_commit;
 623     };
 624
 625     my $exception = $@;
 626     if(!$exception) { return $want_array ? @result : $result[0] }
 627
 628     if($tried++ > 0 || $self->connected) {
 629       eval { $self->txn_rollback };
 630       my $rollback_exception = $@;
 631       if($rollback_exception) {
 632         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 633         $self->throw_exception($exception)  # propagate nested rollback
 634           if $rollback_exception =~ /$exception_class/;
 635
 636         $self->throw_exception(
 637           "Transaction aborted: ${exception}. "
 638           . "Rollback failed: ${rollback_exception}"
 639         );
 640       }
 641       $self->throw_exception($exception)
 642     }
 643
 644     # We were not connected, and was first try - reconnect and retry
 645     # via the while loop
 646     $self->_populate_dbh;
 647   }
 648 }
 649
 650 =head2 disconnect
 651
 652 Our C<disconnect> method also performs a rollback first if the
 653 database is not in C<AutoCommit> mode.
 654
 655 =cut
 656
 657 sub disconnect {
 658   my ($self) = @_;
 659
 660   if( $self->connected ) {
 661     foreach (@{$self->on_disconnect_do || []}) {
 662       $self->_do_query($_);
 663     }
 664     $self->_dbh->rollback unless $self->_dbh_autocommit;
 665     $self->_dbh->disconnect;
 666     $self->_dbh(undef);
 667     $self->{_dbh_gen}++;
 668   }
 669 }
 670
 671 sub connected {
 672   my ($self) = @_;
 673
 674   if(my $dbh = $self->_dbh) {
 675       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 676           $self->_dbh(undef);
 677           $self->{_dbh_gen}++;
 678           return;
 679       }
 680       else {
 681           $self->_verify_pid;
 682       }
 683       return ($dbh->FETCH('Active') && $dbh->ping);
 684   }
 685
 686   return 0;
 687 }
 688
 689 # handle pid changes correctly
 690 #  NOTE: assumes $self->_dbh is a valid $dbh
 691 sub _verify_pid {
 692   my ($self) = @_;
 693
 694   return if $self->_conn_pid == $$;
 695
 696   $self->_dbh->{InactiveDestroy} = 1;
 697   $self->_dbh(undef);
 698   $self->{_dbh_gen}++;
 699
 700   return;
 701 }
 702
 703 sub ensure_connected {
 704   my ($self) = @_;
 705
 706   unless ($self->connected) {
 707     $self->_populate_dbh;
 708   }
 709 }
 710
 711 =head2 dbh
 712
 713 Returns the dbh - a data base handle of class L<DBI>.
 714
 715 =cut
 716
 717 sub dbh {
 718   my ($self) = @_;
 719
 720   $self->ensure_connected;
 721   return $self->_dbh;
 722 }
 723
 724 sub _sql_maker_args {
 725     my ($self) = @_;
 726
 727     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 728 }
 729
 730 sub sql_maker {
 731   my ($self) = @_;
 732   unless ($self->_sql_maker) {
 733     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 734   }
 735   return $self->_sql_maker;
 736 }
 737
 738 sub _populate_dbh {
 739   my ($self) = @_;
 740   my @info = @{$self->_dbi_connect_info || []};
 741   $self->_dbh($self->_connect(@info));
 742
 743   # Always set the transaction depth on connect, since
 744   #  there is no transaction in progress by definition
 745   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 746
 747   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 748     my $driver = $self->_dbh->{Driver}->{Name};
 749     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 750       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 751       $self->_rebless() if $self->can('_rebless');
 752     }
 753   }
 754
 755   foreach (@{$self->on_connect_do || []}) {
 756     $self->_do_query($_);
 757   }
 758
 759   $self->_conn_pid($$);
 760   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 761 }
 762
 763 sub _do_query {
 764   my ($self, $action) = @_;
 765
 766   # $action contains either an SQL string or a code ref
 767   if (ref $action) {
 768     $action->($self);
 769   }
 770   else {
 771     $self->debugobj->query_start($action) if $self->debug();
 772     $self->_dbh->do($action);
 773     $self->debugobj->query_end($action) if $self->debug();
 774   }
 775
 776   return $self;
 777 }
 778
 779 sub _connect {
 780   my ($self, @info) = @_;
 781
 782   $self->throw_exception("You failed to provide any connection info")
 783     if !@info;
 784
 785   my ($old_connect_via, $dbh);
 786
 787   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 788     $old_connect_via = $DBI::connect_via;
 789     $DBI::connect_via = 'connect';
 790   }
 791
 792   eval {
 793     if(ref $info[0] eq 'CODE') {
 794        $dbh = &{$info[0]}
 795     }
 796     else {
 797        $dbh = DBI->connect(@info);
 798     }
 799
 800     if(!$self->unsafe) {
 801       my $weak_self = $self;
 802       weaken($weak_self);
 803       $dbh->{HandleError} = sub {
 804           $weak_self->throw_exception("DBI Exception: $_[0]")
 805       };
 806       $dbh->{ShowErrorStatement} = 1;
 807       $dbh->{RaiseError} = 1;
 808       $dbh->{PrintError} = 0;
 809     }
 810   };
 811
 812   $DBI::connect_via = $old_connect_via if $old_connect_via;
 813
 814   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 815     if !$dbh || $@;
 816
 817   $self->_dbh_autocommit($dbh->{AutoCommit});
 818
 819   $dbh;
 820 }
 821
 822
 823 sub txn_begin {
 824   my $self = shift;
 825   $self->ensure_connected();
 826   if($self->{transaction_depth} == 0) {
 827     $self->debugobj->txn_begin()
 828       if $self->debug;
 829     # this isn't ->_dbh-> because
 830     #  we should reconnect on begin_work
 831     #  for AutoCommit users
 832     $self->dbh->begin_work;
 833   }
 834   $self->{transaction_depth}++;
 835 }
 836
 837 sub txn_commit {
 838   my $self = shift;
 839   if ($self->{transaction_depth} == 1) {
 840     my $dbh = $self->_dbh;
 841     $self->debugobj->txn_commit()
 842       if ($self->debug);
 843     $dbh->commit;
 844     $self->{transaction_depth} = 0
 845       if $self->_dbh_autocommit;
 846   }
 847   elsif($self->{transaction_depth} > 1) {
 848     $self->{transaction_depth}--
 849   }
 850 }
 851
 852 sub txn_rollback {
 853   my $self = shift;
 854   my $dbh = $self->_dbh;
 855   eval {
 856     if ($self->{transaction_depth} == 1) {
 857       $self->debugobj->txn_rollback()
 858         if ($self->debug);
 859       $self->{transaction_depth} = 0
 860         if $self->_dbh_autocommit;
 861       $dbh->rollback;
 862     }
 863     elsif($self->{transaction_depth} > 1) {
 864       $self->{transaction_depth}--;
 865     }
 866     else {
 867       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 868     }
 869   };
 870   if ($@) {
 871     my $error = $@;
 872     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 873     $error =~ /$exception_class/ and $self->throw_exception($error);
 874     # ensure that a failed rollback resets the transaction depth
 875     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 876     $self->throw_exception($error);
 877   }
 878 }
 879
 880 # This used to be the top-half of _execute.  It was split out to make it
 881 #  easier to override in NoBindVars without duping the rest.  It takes up
 882 #  all of _execute's args, and emits $sql, @bind.
 883 sub _prep_for_execute {
 884   my ($self, $op, $extra_bind, $ident, $args) = @_;
 885
 886   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 887   unshift(@bind,
 888     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 889       if $extra_bind;
 890
 891   return ($sql, \@bind);
 892 }
 893
 894 sub _dbh_execute {
 895   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 896
 897   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 898     $ident = $ident->from();
 899   }
 900
 901   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 902
 903   if ($self->debug) {
 904       my @debug_bind =
 905         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 906       $self->debugobj->query_start($sql, @debug_bind);
 907   }
 908
 909   my $sth = $self->sth($sql,$op);
 910
 911   my $placeholder_index = 1;
 912
 913   foreach my $bound (@$bind) {
 914     my $attributes = {};
 915     my($column_name, @data) = @$bound;
 916
 917     if ($bind_attributes) {
 918       $attributes = $bind_attributes->{$column_name}
 919       if defined $bind_attributes->{$column_name};
 920     }
 921
 922     foreach my $data (@data) {
 923       $data = ref $data ? ''.$data : $data; # stringify args
 924
 925       $sth->bind_param($placeholder_index, $data, $attributes);
 926       $placeholder_index++;
 927     }
 928   }
 929
 930   # Can this fail without throwing an exception anyways???
 931   my $rv = $sth->execute();
 932   $self->throw_exception($sth->errstr) if !$rv;
 933
 934   if ($self->debug) {
 935      my @debug_bind =
 936        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @$bind;
 937      $self->debugobj->query_end($sql, @debug_bind);
 938   }
 939
 940   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 941 }
 942
 943 sub _execute {
 944     my $self = shift;
 945     $self->dbh_do($self->can('_dbh_execute'), @_)
 946 }
 947
 948 sub insert {
 949   my ($self, $source, $to_insert) = @_;
 950
 951   my $ident = $source->from;
 952   my $bind_attributes = $self->source_bind_attributes($source);
 953
 954   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
 955
 956   return $to_insert;
 957 }
 958
 959 ## Still not quite perfect, and EXPERIMENTAL
 960 ## Currently it is assumed that all values passed will be "normal", i.e. not
 961 ## scalar refs, or at least, all the same type as the first set, the statement is
 962 ## only prepped once.
 963 sub insert_bulk {
 964   my ($self, $source, $cols, $data) = @_;
 965   my %colvalues;
 966   my $table = $source->from;
 967   @colvalues{@$cols} = (0..$#$cols);
 968   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 969
 970   if ($self->debug) {
 971       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 972       $self->debugobj->query_start($sql, @debug_bind);
 973   }
 974   my $sth = $self->sth($sql);
 975
 976 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 977
 978   ## This must be an arrayref, else nothing works!
 979
 980   my $tuple_status = [];
 981
 982   ##use Data::Dumper;
 983   ##print STDERR Dumper( $data, $sql, [@bind] );
 984
 985   my $time = time();
 986
 987   ## Get the bind_attributes, if any exist
 988   my $bind_attributes = $self->source_bind_attributes($source);
 989
 990   ## Bind the values and execute
 991   my $placeholder_index = 1;
 992
 993   foreach my $bound (@bind) {
 994
 995     my $attributes = {};
 996     my ($column_name, $data_index) = @$bound;
 997
 998     if( $bind_attributes ) {
 999       $attributes = $bind_attributes->{$column_name}
1000       if defined $bind_attributes->{$column_name};
1001     }
1002
1003     my @data = map { $_->[$data_index] } @$data;
1004
1005     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1006     $placeholder_index++;
1007   }
1008   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1009   $self->throw_exception($sth->errstr) if !$rv;
1010
1011   if ($self->debug) {
1012       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
1013       $self->debugobj->query_end($sql, @debug_bind);
1014   }
1015   return (wantarray ? ($rv, $sth, @bind) : $rv);
1016 }
1017
1018 sub update {
1019   my $self = shift @_;
1020   my $source = shift @_;
1021   my $bind_attributes = $self->source_bind_attributes($source);
1022
1023   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1024 }
1025
1026
1027 sub delete {
1028   my $self = shift @_;
1029   my $source = shift @_;
1030
1031   my $bind_attrs = {}; ## If ever it's needed...
1032
1033   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1034 }
1035
1036 sub _select {
1037   my ($self, $ident, $select, $condition, $attrs) = @_;
1038   my $order = $attrs->{order_by};
1039   if (ref $condition eq 'SCALAR') {
1040     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1041   }
1042   if (exists $attrs->{group_by} || $attrs->{having}) {
1043     $order = {
1044       group_by => $attrs->{group_by},
1045       having => $attrs->{having},
1046       ($order ? (order_by => $order) : ())
1047     };
1048   }
1049   my $bind_attrs = {}; ## Future support
1050   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1051   if ($attrs->{software_limit} ||
1052       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1053         $attrs->{software_limit} = 1;
1054   } else {
1055     $self->throw_exception("rows attribute must be positive if present")
1056       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1057     push @args, $attrs->{rows}, $attrs->{offset};
1058   }
1059   return $self->_execute(@args);
1060 }
1061
1062 sub source_bind_attributes {
1063   my ($self, $source) = @_;
1064
1065   my $bind_attributes;
1066   foreach my $column ($source->columns) {
1067
1068     my $data_type = $source->column_info($column)->{data_type} || '';
1069     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1070      if $data_type;
1071   }
1072
1073   return $bind_attributes;
1074 }
1075
1076 =head2 select
1077
1078 =over 4
1079
1080 =item Arguments: $ident, $select, $condition, $attrs
1081
1082 =back
1083
1084 Handle a SQL select statement.
1085
1086 =cut
1087
1088 sub select {
1089   my $self = shift;
1090   my ($ident, $select, $condition, $attrs) = @_;
1091   return $self->cursor->new($self, \@_, $attrs);
1092 }
1093
1094 sub select_single {
1095   my $self = shift;
1096   my ($rv, $sth, @bind) = $self->_select(@_);
1097   my @row = $sth->fetchrow_array;
1098   # Need to call finish() to work round broken DBDs
1099   $sth->finish();
1100   return @row;
1101 }
1102
1103 =head2 sth
1104
1105 =over 4
1106
1107 =item Arguments: $sql
1108
1109 =back
1110
1111 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1112
1113 =cut
1114
1115 sub _dbh_sth {
1116   my ($self, $dbh, $sql) = @_;
1117
1118   # 3 is the if_active parameter which avoids active sth re-use
1119   my $sth = $self->disable_sth_caching
1120     ? $dbh->prepare($sql)
1121     : $dbh->prepare_cached($sql, {}, 3);
1122
1123   # XXX You would think RaiseError would make this impossible,
1124   #  but apparently that's not true :(
1125   $self->throw_exception($dbh->errstr) if !$sth;
1126
1127   $sth;
1128 }
1129
1130 sub sth {
1131   my ($self, $sql) = @_;
1132   $self->dbh_do($self->can('_dbh_sth'), $sql);
1133 }
1134
1135 sub _dbh_columns_info_for {
1136   my ($self, $dbh, $table) = @_;
1137
1138   if ($dbh->can('column_info')) {
1139     my %result;
1140     eval {
1141       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1142       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1143       $sth->execute();
1144       while ( my $info = $sth->fetchrow_hashref() ){
1145         my %column_info;
1146         $column_info{data_type}   = $info->{TYPE_NAME};
1147         $column_info{size}      = $info->{COLUMN_SIZE};
1148         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1149         $column_info{default_value} = $info->{COLUMN_DEF};
1150         my $col_name = $info->{COLUMN_NAME};
1151         $col_name =~ s/^\"(.*)\"$/$1/;
1152
1153         $result{$col_name} = \%column_info;
1154       }
1155     };
1156     return \%result if !$@ && scalar keys %result;
1157   }
1158
1159   my %result;
1160   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1161   $sth->execute;
1162   my @columns = @{$sth->{NAME_lc}};
1163   for my $i ( 0 .. $#columns ){
1164     my %column_info;
1165     $column_info{data_type} = $sth->{TYPE}->[$i];
1166     $column_info{size} = $sth->{PRECISION}->[$i];
1167     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1168
1169     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1170       $column_info{data_type} = $1;
1171       $column_info{size}    = $2;
1172     }
1173
1174     $result{$columns[$i]} = \%column_info;
1175   }
1176   $sth->finish;
1177
1178   foreach my $col (keys %result) {
1179     my $colinfo = $result{$col};
1180     my $type_num = $colinfo->{data_type};
1181     my $type_name;
1182     if(defined $type_num && $dbh->can('type_info')) {
1183       my $type_info = $dbh->type_info($type_num);
1184       $type_name = $type_info->{TYPE_NAME} if $type_info;
1185       $colinfo->{data_type} = $type_name if $type_name;
1186     }
1187   }
1188
1189   return \%result;
1190 }
1191
1192 sub columns_info_for {
1193   my ($self, $table) = @_;
1194   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1195 }
1196
1197 =head2 last_insert_id
1198
1199 Return the row id of the last insert.
1200
1201 =cut
1202
1203 sub _dbh_last_insert_id {
1204     my ($self, $dbh, $source, $col) = @_;
1205     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1206     $dbh->func('last_insert_rowid');
1207 }
1208
1209 sub last_insert_id {
1210   my $self = shift;
1211   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1212 }
1213
1214 =head2 sqlt_type
1215
1216 Returns the database driver name.
1217
1218 =cut
1219
1220 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1221
1222 =head2 bind_attribute_by_data_type
1223
1224 Given a datatype from column info, returns a database specific bind attribute for
1225 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1226 just handle it.
1227
1228 Generally only needed for special case column types, like bytea in postgres.
1229
1230 =cut
1231
1232 sub bind_attribute_by_data_type {
1233     return;
1234 }
1235
1236 =head2 create_ddl_dir
1237
1238 =over 4
1239
1240 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1241
1242 =back
1243
1244 Creates a SQL file based on the Schema, for each of the specified
1245 database types, in the given directory.
1246
1247 =cut
1248
1249 sub create_ddl_dir
1250 {
1251   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1252
1253   if(!$dir || !-d $dir)
1254   {
1255     warn "No directory given, using ./\n";
1256     $dir = "./";
1257   }
1258   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1259   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1260   $version ||= $schema->VERSION || '1.x';
1261   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1262
1263   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.08: '}
1264       . $self->_check_sqlt_message . q{'})
1265           if !$self->_check_sqlt_version;
1266
1267   my $sqlt = SQL::Translator->new({
1268 #      debug => 1,
1269       add_drop_table => 1,
1270   });
1271   foreach my $db (@$databases)
1272   {
1273     $sqlt->reset();
1274     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1275 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1276     $sqlt = $self->configure_sqlt($sqlt, $db);
1277     $sqlt->data($schema);
1278     $sqlt->producer($db);
1279
1280     my $file;
1281     my $filename = $schema->ddl_filename($db, $dir, $version);
1282     if(-e $filename)
1283     {
1284       warn("$filename already exists, skipping $db");
1285       next;
1286     }
1287
1288     my $output = $sqlt->translate;
1289     if(!$output)
1290     {
1291       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1292       next;
1293     }
1294     if(!open($file, ">$filename"))
1295     {
1296         $self->throw_exception("Can't open $filename for writing ($!)");
1297         next;
1298     }
1299     print $file $output;
1300     close($file);
1301
1302     if($preversion)
1303     {
1304       require SQL::Translator::Diff;
1305
1306       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1307 #      print "Previous version $prefilename\n";
1308       if(!-e $prefilename)
1309       {
1310         warn("No previous schema file found ($prefilename)");
1311         next;
1312       }
1313       #### We need to reparse the SQLite file we just wrote, so that
1314       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1315       ##   FIXME: rip Diff to pieces!
1316 #      my $target_schema = $sqlt->schema;
1317 #      unless ( $target_schema->name ) {
1318 #        $target_schema->name( $filename );
1319 #      }
1320       my @input;
1321       push @input, {file => $prefilename, parser => $db};
1322       push @input, {file => $filename, parser => $db};
1323       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1324         my $file   = $_->{'file'};
1325         my $parser = $_->{'parser'};
1326
1327         my $t = SQL::Translator->new;
1328         $t->debug( 0 );
1329         $t->trace( 0 );
1330         $t->parser( $parser )            or die $t->error;
1331         my $out = $t->translate( $file ) or die $t->error;
1332         my $schema = $t->schema;
1333         unless ( $schema->name ) {
1334           $schema->name( $file );
1335         }
1336         ($schema, $parser);
1337       } @input;
1338
1339       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1340                                                     $target_schema, $db,
1341                                                     {}
1342                                                    );
1343       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1344       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1345       if(-e $difffile)
1346       {
1347         warn("$difffile already exists, skipping");
1348         next;
1349       }
1350       if(!open $file, ">$difffile")
1351       {
1352         $self->throw_exception("Can't write to $difffile ($!)");
1353         next;
1354       }
1355       print $file $diff;
1356       close($file);
1357     }
1358   }
1359 }
1360
1361 sub configure_sqlt() {
1362   my $self = shift;
1363   my $tr = shift;
1364   my $db = shift || $self->sqlt_type;
1365   if ($db eq 'PostgreSQL') {
1366     $tr->quote_table_names(0);
1367     $tr->quote_field_names(0);
1368   }
1369   return $tr;
1370 }
1371
1372 =head2 deployment_statements
1373
1374 =over 4
1375
1376 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1377
1378 =back
1379
1380 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1381 The database driver name is given by C<$type>, though the value from
1382 L</sqlt_type> is used if it is not specified.
1383
1384 C<$directory> is used to return statements from files in a previously created
1385 L</create_ddl_dir> directory and is optional. The filenames are constructed
1386 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1387
1388 If no C<$directory> is specified then the statements are constructed on the
1389 fly using L<SQL::Translator> and C<$version> is ignored.
1390
1391 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1392
1393 =cut
1394
1395 sub deployment_statements {
1396   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1397   # Need to be connected to get the correct sqlt_type
1398   $self->ensure_connected() unless $type;
1399   $type ||= $self->sqlt_type;
1400   $version ||= $schema->VERSION || '1.x';
1401   $dir ||= './';
1402   my $filename = $schema->ddl_filename($type, $dir, $version);
1403   if(-f $filename)
1404   {
1405       my $file;
1406       open($file, "<$filename")
1407         or $self->throw_exception("Can't open $filename ($!)");
1408       my @rows = <$file>;
1409       close($file);
1410       return join('', @rows);
1411   }
1412
1413   $self->throw_exception(q{Can't deploy without SQL::Translator 0.08: '}
1414       . $self->_check_sqlt_message . q{'})
1415           if !$self->_check_sqlt_version;
1416
1417   require SQL::Translator::Parser::DBIx::Class;
1418   eval qq{use SQL::Translator::Producer::${type}};
1419   $self->throw_exception($@) if $@;
1420
1421   # sources needs to be a parser arg, but for simplicty allow at top level
1422   # coming in
1423   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1424       if exists $sqltargs->{sources};
1425
1426   my $tr = SQL::Translator->new(%$sqltargs);
1427   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1428   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1429
1430   return;
1431
1432 }
1433
1434 sub deploy {
1435   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1436   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1437     foreach my $line ( split(";\n", $statement)) {
1438       next if($line =~ /^--/);
1439       next if(!$line);
1440 #      next if($line =~ /^DROP/m);
1441       next if($line =~ /^BEGIN TRANSACTION/m);
1442       next if($line =~ /^COMMIT/m);
1443       next if $line =~ /^\s+$/; # skip whitespace only
1444       $self->debugobj->query_start($line) if $self->debug;
1445       eval {
1446         $self->dbh->do($line); # shouldn't be using ->dbh ?
1447       };
1448       if ($@) {
1449         warn qq{$@ (running "${line}")};
1450       }
1451       $self->debugobj->query_end($line) if $self->debug;
1452     }
1453   }
1454 }
1455
1456 =head2 datetime_parser
1457
1458 Returns the datetime parser class
1459
1460 =cut
1461
1462 sub datetime_parser {
1463   my $self = shift;
1464   return $self->{datetime_parser} ||= do {
1465     $self->ensure_connected;
1466     $self->build_datetime_parser(@_);
1467   };
1468 }
1469
1470 =head2 datetime_parser_type
1471
1472 Defines (returns) the datetime parser class - currently hardwired to
1473 L<DateTime::Format::MySQL>
1474
1475 =cut
1476
1477 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1478
1479 =head2 build_datetime_parser
1480
1481 See L</datetime_parser>
1482
1483 =cut
1484
1485 sub build_datetime_parser {
1486   my $self = shift;
1487   my $type = $self->datetime_parser_type(@_);
1488   eval "use ${type}";
1489   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1490   return $type;
1491 }
1492
1493 {
1494     my $_check_sqlt_version; # private
1495     my $_check_sqlt_message; # private
1496     sub _check_sqlt_version {
1497         return $_check_sqlt_version if defined $_check_sqlt_version;
1498         eval 'use SQL::Translator 0.08';
1499         $_check_sqlt_message = $@ ? $@ : '';
1500         $_check_sqlt_version = $@ ? 0 : 1;
1501     }
1502
1503     sub _check_sqlt_message {
1504         _check_sqlt_version if !defined $_check_sqlt_message;
1505         $_check_sqlt_message;
1506     }
1507 }
1508
1509 sub DESTROY {
1510   my $self = shift;
1511   return if !$self->_dbh;
1512   $self->_verify_pid;
1513   $self->_dbh(undef);
1514 }
1515
1516 1;
1517
1518 =head1 SQL METHODS
1519
1520 The module defines a set of methods within the DBIC::SQL::Abstract
1521 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1522 SQL query functions.
1523
1524 The following methods are extended:-
1525
1526 =over 4
1527
1528 =item delete
1529
1530 =item insert
1531
1532 =item select
1533
1534 =item update
1535
1536 =item limit_dialect
1537
1538 See L</connect_info> for details.
1539 For setting, this method is deprecated in favor of L</connect_info>.
1540
1541 =item quote_char
1542
1543 See L</connect_info> for details.
1544 For setting, this method is deprecated in favor of L</connect_info>.
1545
1546 =item name_sep
1547
1548 See L</connect_info> for details.
1549 For setting, this method is deprecated in favor of L</connect_info>.
1550
1551 =back
1552
1553 =head1 AUTHORS
1554
1555 Matt S. Trout <mst@shadowcatsystems.co.uk>
1556
1557 Andy Grundman <andy@hybridized.org>
1558
1559 =head1 LICENSE
1560
1561 You may distribute this code under the same terms as Perl itself.
1562
1563 =cut