lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use DBI;
   9 use SQL::Abstract::Limit;
  10 use DBIx::Class::Storage::DBI::Cursor;
  11 use DBIx::Class::Storage::Statistics;
  12 use IO::File;
  13
  14 __PACKAGE__->mk_group_accessors(
  15   'simple' =>
  16     qw/_connect_info _dbh _sql_maker _sql_maker_opts _conn_pid _conn_tid
  17        disable_sth_caching cursor on_connect_do transaction_depth/
  18 );
  19
  20 BEGIN {
  21
  22 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  23
  24 use base qw/SQL::Abstract::Limit/;
  25
  26 # This prevents the caching of $dbh in S::A::L, I believe
  27 sub new {
  28   my $self = shift->SUPER::new(@_);
  29
  30   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  31   #   it with what it resolves to:
  32   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  33     if ref $self->{limit_dialect};
  34
  35   $self;
  36 }
  37
  38 sub _RowNumberOver {
  39   my ($self, $sql, $order, $rows, $offset ) = @_;
  40
  41   $offset += 1;
  42   my $last = $rows + $offset;
  43   my ( $order_by ) = $self->_order_by( $order );
  44
  45   $sql = <<"";
  46 SELECT * FROM
  47 (
  48    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  49       $sql
  50       $order_by
  51    ) Q1
  52 ) Q2
  53 WHERE ROW_NUM BETWEEN $offset AND $last
  54
  55   return $sql;
  56 }
  57
  58
  59 # While we're at it, this should make LIMIT queries more efficient,
  60 #  without digging into things too deeply
  61 use Scalar::Util 'blessed';
  62 sub _find_syntax {
  63   my ($self, $syntax) = @_;
  64   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  65   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  66     return 'RowNumberOver';
  67   }
  68
  69   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  70 }
  71
  72 sub select {
  73   my ($self, $table, $fields, $where, $order, @rest) = @_;
  74   $table = $self->_quote($table) unless ref($table);
  75   local $self->{rownum_hack_count} = 1
  76     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  77   @rest = (-1) unless defined $rest[0];
  78   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  79     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  80   local $self->{having_bind} = [];
  81   my ($sql, @ret) = $self->SUPER::select(
  82     $table, $self->_recurse_fields($fields), $where, $order, @rest
  83   );
  84   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
  85 }
  86
  87 sub insert {
  88   my $self = shift;
  89   my $table = shift;
  90   $table = $self->_quote($table) unless ref($table);
  91   $self->SUPER::insert($table, @_);
  92 }
  93
  94 sub update {
  95   my $self = shift;
  96   my $table = shift;
  97   $table = $self->_quote($table) unless ref($table);
  98   $self->SUPER::update($table, @_);
  99 }
 100
 101 sub delete {
 102   my $self = shift;
 103   my $table = shift;
 104   $table = $self->_quote($table) unless ref($table);
 105   $self->SUPER::delete($table, @_);
 106 }
 107
 108 sub _emulate_limit {
 109   my $self = shift;
 110   if ($_[3] == -1) {
 111     return $_[1].$self->_order_by($_[2]);
 112   } else {
 113     return $self->SUPER::_emulate_limit(@_);
 114   }
 115 }
 116
 117 sub _recurse_fields {
 118   my ($self, $fields) = @_;
 119   my $ref = ref $fields;
 120   return $self->_quote($fields) unless $ref;
 121   return $$fields if $ref eq 'SCALAR';
 122
 123   if ($ref eq 'ARRAY') {
 124     return join(', ', map {
 125       $self->_recurse_fields($_)
 126       .(exists $self->{rownum_hack_count}
 127          ? ' AS col'.$self->{rownum_hack_count}++
 128          : '')
 129      } @$fields);
 130   } elsif ($ref eq 'HASH') {
 131     foreach my $func (keys %$fields) {
 132       return $self->_sqlcase($func)
 133         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 134     }
 135   }
 136 }
 137
 138 sub _order_by {
 139   my $self = shift;
 140   my $ret = '';
 141   my @extra;
 142   if (ref $_[0] eq 'HASH') {
 143     if (defined $_[0]->{group_by}) {
 144       $ret = $self->_sqlcase(' group by ')
 145                .$self->_recurse_fields($_[0]->{group_by});
 146     }
 147     if (defined $_[0]->{having}) {
 148       my $frag;
 149       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 150       push(@{$self->{having_bind}}, @extra);
 151       $ret .= $self->_sqlcase(' having ').$frag;
 152     }
 153     if (defined $_[0]->{order_by}) {
 154       $ret .= $self->_order_by($_[0]->{order_by});
 155     }
 156   } elsif (ref $_[0] eq 'SCALAR') {
 157     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 158   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 159     my @order = @{+shift};
 160     $ret = $self->_sqlcase(' order by ')
 161           .join(', ', map {
 162                         my $r = $self->_order_by($_, @_);
 163                         $r =~ s/^ ?ORDER BY //i;
 164                         $r;
 165                       } @order);
 166   } else {
 167     $ret = $self->SUPER::_order_by(@_);
 168   }
 169   return $ret;
 170 }
 171
 172 sub _order_directions {
 173   my ($self, $order) = @_;
 174   $order = $order->{order_by} if ref $order eq 'HASH';
 175   return $self->SUPER::_order_directions($order);
 176 }
 177
 178 sub _table {
 179   my ($self, $from) = @_;
 180   if (ref $from eq 'ARRAY') {
 181     return $self->_recurse_from(@$from);
 182   } elsif (ref $from eq 'HASH') {
 183     return $self->_make_as($from);
 184   } else {
 185     return $from; # would love to quote here but _table ends up getting called
 186                   # twice during an ->select without a limit clause due to
 187                   # the way S::A::Limit->select works. should maybe consider
 188                   # bypassing this and doing S::A::select($self, ...) in
 189                   # our select method above. meantime, quoting shims have
 190                   # been added to select/insert/update/delete here
 191   }
 192 }
 193
 194 sub _recurse_from {
 195   my ($self, $from, @join) = @_;
 196   my @sqlf;
 197   push(@sqlf, $self->_make_as($from));
 198   foreach my $j (@join) {
 199     my ($to, $on) = @$j;
 200
 201     # check whether a join type exists
 202     my $join_clause = '';
 203     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 204     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 205       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 206     } else {
 207       $join_clause = ' JOIN ';
 208     }
 209     push(@sqlf, $join_clause);
 210
 211     if (ref $to eq 'ARRAY') {
 212       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 213     } else {
 214       push(@sqlf, $self->_make_as($to));
 215     }
 216     push(@sqlf, ' ON ', $self->_join_condition($on));
 217   }
 218   return join('', @sqlf);
 219 }
 220
 221 sub _make_as {
 222   my ($self, $from) = @_;
 223   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 224                      reverse each %{$self->_skip_options($from)});
 225 }
 226
 227 sub _skip_options {
 228   my ($self, $hash) = @_;
 229   my $clean_hash = {};
 230   $clean_hash->{$_} = $hash->{$_}
 231     for grep {!/^-/} keys %$hash;
 232   return $clean_hash;
 233 }
 234
 235 sub _join_condition {
 236   my ($self, $cond) = @_;
 237   if (ref $cond eq 'HASH') {
 238     my %j;
 239     for (keys %$cond) {
 240       my $v = $cond->{$_};
 241       if (ref $v) {
 242         # XXX no throw_exception() in this package and croak() fails with strange results
 243         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 244             if ref($v) ne 'SCALAR';
 245         $j{$_} = $v;
 246       }
 247       else {
 248         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 249       }
 250     };
 251     return scalar($self->_recurse_where(\%j));
 252   } elsif (ref $cond eq 'ARRAY') {
 253     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 254   } else {
 255     die "Can't handle this yet!";
 256   }
 257 }
 258
 259 sub _quote {
 260   my ($self, $label) = @_;
 261   return '' unless defined $label;
 262   return "*" if $label eq '*';
 263   return $label unless $self->{quote_char};
 264   if(ref $self->{quote_char} eq "ARRAY"){
 265     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 266       if !defined $self->{name_sep};
 267     my $sep = $self->{name_sep};
 268     return join($self->{name_sep},
 269         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 270        split(/\Q$sep\E/,$label));
 271   }
 272   return $self->SUPER::_quote($label);
 273 }
 274
 275 sub limit_dialect {
 276     my $self = shift;
 277     $self->{limit_dialect} = shift if @_;
 278     return $self->{limit_dialect};
 279 }
 280
 281 sub quote_char {
 282     my $self = shift;
 283     $self->{quote_char} = shift if @_;
 284     return $self->{quote_char};
 285 }
 286
 287 sub name_sep {
 288     my $self = shift;
 289     $self->{name_sep} = shift if @_;
 290     return $self->{name_sep};
 291 }
 292
 293 } # End of BEGIN block
 294
 295 =head1 NAME
 296
 297 DBIx::Class::Storage::DBI - DBI storage handler
 298
 299 =head1 SYNOPSIS
 300
 301 =head1 DESCRIPTION
 302
 303 This class represents the connection to an RDBMS via L<DBI>.  See
 304 L<DBIx::Class::Storage> for general information.  This pod only
 305 documents DBI-specific methods and behaviors.
 306
 307 =head1 METHODS
 308
 309 =cut
 310
 311 sub new {
 312   my $new = shift->next::method(@_);
 313
 314   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
 315   $new->transaction_depth(0);
 316   $new->_sql_maker_opts({});
 317   $new->{_in_dbh_do} = 0;
 318   $new->{_dbh_gen} = 0;
 319
 320   $new;
 321 }
 322
 323 =head2 connect_info
 324
 325 The arguments of C<connect_info> are always a single array reference.
 326
 327 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 328 encapsulates its argument list in an arrayref before calling
 329 C<connect_info> here.
 330
 331 The arrayref can either contain the same set of arguments one would
 332 normally pass to L<DBI/connect>, or a lone code reference which returns
 333 a connected database handle.
 334
 335 In either case, if the final argument in your connect_info happens
 336 to be a hashref, C<connect_info> will look there for several
 337 connection-specific options:
 338
 339 =over 4
 340
 341 =item on_connect_do
 342
 343 This can be set to an arrayref of literal sql statements, which will
 344 be executed immediately after making the connection to the database
 345 every time we [re-]connect.
 346
 347 =item disable_sth_caching
 348
 349 If set to a true value, this option will disable the caching of
 350 statement handles via L<DBI/prepare_cached>.
 351
 352 =item limit_dialect
 353
 354 Sets the limit dialect. This is useful for JDBC-bridge among others
 355 where the remote SQL-dialect cannot be determined by the name of the
 356 driver alone.
 357
 358 =item quote_char
 359
 360 Specifies what characters to use to quote table and column names. If
 361 you use this you will want to specify L<name_sep> as well.
 362
 363 quote_char expects either a single character, in which case is it is placed
 364 on either side of the table/column, or an arrayref of length 2 in which case the
 365 table/column name is placed between the elements.
 366
 367 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 368 use C<quote_char =E<gt> [qw/[ ]/]>.
 369
 370 =item name_sep
 371
 372 This only needs to be used in conjunction with L<quote_char>, and is used to
 373 specify the charecter that seperates elements (schemas, tables, columns) from
 374 each other. In most cases this is simply a C<.>.
 375
 376 =back
 377
 378 These options can be mixed in with your other L<DBI> connection attributes,
 379 or placed in a seperate hashref after all other normal L<DBI> connection
 380 arguments.
 381
 382 Every time C<connect_info> is invoked, any previous settings for
 383 these options will be cleared before setting the new ones, regardless of
 384 whether any options are specified in the new C<connect_info>.
 385
 386 Important note:  DBIC expects the returned database handle provided by
 387 a subref argument to have RaiseError set on it.  If it doesn't, things
 388 might not work very well, YMMV.  If you don't use a subref, DBIC will
 389 force this setting for you anyways.  Setting HandleError to anything
 390 other than simple exception object wrapper might cause problems too.
 391
 392 Examples:
 393
 394   # Simple SQLite connection
 395   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 396
 397   # Connect via subref
 398   ->connect_info([ sub { DBI->connect(...) } ]);
 399
 400   # A bit more complicated
 401   ->connect_info(
 402     [
 403       'dbi:Pg:dbname=foo',
 404       'postgres',
 405       'my_pg_password',
 406       { AutoCommit => 0 },
 407       { quote_char => q{"}, name_sep => q{.} },
 408     ]
 409   );
 410
 411   # Equivalent to the previous example
 412   ->connect_info(
 413     [
 414       'dbi:Pg:dbname=foo',
 415       'postgres',
 416       'my_pg_password',
 417       { AutoCommit => 0, quote_char => q{"}, name_sep => q{.} },
 418     ]
 419   );
 420
 421   # Subref + DBIC-specific connection options
 422   ->connect_info(
 423     [
 424       sub { DBI->connect(...) },
 425       {
 426           quote_char => q{`},
 427           name_sep => q{@},
 428           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 429           disable_sth_caching => 1,
 430       },
 431     ]
 432   );
 433
 434 =cut
 435
 436 sub connect_info {
 437   my ($self, $info_arg) = @_;
 438
 439   return $self->_connect_info if !$info_arg;
 440
 441   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 442   #  the new set of options
 443   $self->_sql_maker(undef);
 444   $self->_sql_maker_opts({});
 445
 446   my $info = [ @$info_arg ]; # copy because we can alter it
 447   my $last_info = $info->[-1];
 448   if(ref $last_info eq 'HASH') {
 449     for my $storage_opt (qw/on_connect_do disable_sth_caching/) {
 450       if(my $value = delete $last_info->{$storage_opt}) {
 451         $self->$storage_opt($value);
 452       }
 453     }
 454     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 455       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 456         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 457       }
 458     }
 459
 460     # Get rid of any trailing empty hashref
 461     pop(@$info) if !keys %$last_info;
 462   }
 463
 464   $self->_connect_info($info);
 465 }
 466
 467 =head2 on_connect_do
 468
 469 This method is deprecated in favor of setting via L</connect_info>.
 470
 471 =head2 dbh_do
 472
 473 Arguments: $subref, @extra_coderef_args?
 474
 475 Execute the given subref using the new exception-based connection management.
 476
 477 The first two arguments will be the storage object that C<dbh_do> was called
 478 on and a database handle to use.  Any additional arguments will be passed
 479 verbatim to the called subref as arguments 2 and onwards.
 480
 481 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 482 exception handling and reconnection (or failover in future subclasses).
 483
 484 Your subref should have no side-effects outside of the database, as
 485 there is the potential for your subref to be partially double-executed
 486 if the database connection was stale/dysfunctional.
 487
 488 Example:
 489
 490   my @stuff = $schema->storage->dbh_do(
 491     sub {
 492       my ($storage, $dbh, @cols) = @_;
 493       my $cols = join(q{, }, @cols);
 494       $dbh->selectrow_array("SELECT $cols FROM foo");
 495     },
 496     @column_list
 497   );
 498
 499 =cut
 500
 501 sub dbh_do {
 502   my $self = shift;
 503   my $coderef = shift;
 504
 505   ref $coderef eq 'CODE' or $self->throw_exception
 506     ('$coderef must be a CODE reference');
 507
 508   return $coderef->($self, $self->_dbh, @_) if $self->{_in_dbh_do};
 509   local $self->{_in_dbh_do} = 1;
 510
 511   my @result;
 512   my $want_array = wantarray;
 513
 514   eval {
 515     $self->_verify_pid if $self->_dbh;
 516     $self->_populate_dbh if !$self->_dbh;
 517     if($want_array) {
 518         @result = $coderef->($self, $self->_dbh, @_);
 519     }
 520     elsif(defined $want_array) {
 521         $result[0] = $coderef->($self, $self->_dbh, @_);
 522     }
 523     else {
 524         $coderef->($self, $self->_dbh, @_);
 525     }
 526   };
 527
 528   my $exception = $@;
 529   if(!$exception) { return $want_array ? @result : $result[0] }
 530
 531   $self->throw_exception($exception) if $self->connected;
 532
 533   # We were not connected - reconnect and retry, but let any
 534   #  exception fall right through this time
 535   $self->_populate_dbh;
 536   $coderef->($self, $self->_dbh, @_);
 537 }
 538
 539 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 540 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 541 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 542 sub txn_do {
 543   my $self = shift;
 544   my $coderef = shift;
 545
 546   ref $coderef eq 'CODE' or $self->throw_exception
 547     ('$coderef must be a CODE reference');
 548
 549   local $self->{_in_dbh_do} = 1;
 550
 551   my @result;
 552   my $want_array = wantarray;
 553
 554   my $tried = 0;
 555   while(1) {
 556     eval {
 557       $self->_verify_pid if $self->_dbh;
 558       $self->_populate_dbh if !$self->_dbh;
 559
 560       $self->txn_begin;
 561       if($want_array) {
 562           @result = $coderef->(@_);
 563       }
 564       elsif(defined $want_array) {
 565           $result[0] = $coderef->(@_);
 566       }
 567       else {
 568           $coderef->(@_);
 569       }
 570       $self->txn_commit;
 571     };
 572
 573     my $exception = $@;
 574     if(!$exception) { return $want_array ? @result : $result[0] }
 575
 576     if($tried++ > 0 || $self->connected) {
 577       eval { $self->txn_rollback };
 578       my $rollback_exception = $@;
 579       if($rollback_exception) {
 580         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 581         $self->throw_exception($exception)  # propagate nested rollback
 582           if $rollback_exception =~ /$exception_class/;
 583
 584         $self->throw_exception(
 585           "Transaction aborted: ${exception}. "
 586           . "Rollback failed: ${rollback_exception}"
 587         );
 588       }
 589       $self->throw_exception($exception)
 590     }
 591
 592     # We were not connected, and was first try - reconnect and retry
 593     # via the while loop
 594     $self->_populate_dbh;
 595   }
 596 }
 597
 598 =head2 disconnect
 599
 600 Our C<disconnect> method also performs a rollback first if the
 601 database is not in C<AutoCommit> mode.
 602
 603 =cut
 604
 605 sub disconnect {
 606   my ($self) = @_;
 607
 608   if( $self->connected ) {
 609     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
 610     $self->_dbh->disconnect;
 611     $self->_dbh(undef);
 612     $self->{_dbh_gen}++;
 613   }
 614 }
 615
 616 sub connected {
 617   my ($self) = @_;
 618
 619   if(my $dbh = $self->_dbh) {
 620       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 621           $self->_dbh(undef);
 622           $self->{_dbh_gen}++;
 623           return;
 624       }
 625       else {
 626           $self->_verify_pid;
 627       }
 628       return ($dbh->FETCH('Active') && $dbh->ping);
 629   }
 630
 631   return 0;
 632 }
 633
 634 # handle pid changes correctly
 635 #  NOTE: assumes $self->_dbh is a valid $dbh
 636 sub _verify_pid {
 637   my ($self) = @_;
 638
 639   return if $self->_conn_pid == $$;
 640
 641   $self->_dbh->{InactiveDestroy} = 1;
 642   $self->_dbh(undef);
 643   $self->{_dbh_gen}++;
 644
 645   return;
 646 }
 647
 648 sub ensure_connected {
 649   my ($self) = @_;
 650
 651   unless ($self->connected) {
 652     $self->_populate_dbh;
 653   }
 654 }
 655
 656 =head2 dbh
 657
 658 Returns the dbh - a data base handle of class L<DBI>.
 659
 660 =cut
 661
 662 sub dbh {
 663   my ($self) = @_;
 664
 665   $self->ensure_connected;
 666   return $self->_dbh;
 667 }
 668
 669 sub _sql_maker_args {
 670     my ($self) = @_;
 671
 672     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 673 }
 674
 675 sub sql_maker {
 676   my ($self) = @_;
 677   unless ($self->_sql_maker) {
 678     $self->_sql_maker(new DBIC::SQL::Abstract( $self->_sql_maker_args ));
 679   }
 680   return $self->_sql_maker;
 681 }
 682
 683 sub _populate_dbh {
 684   my ($self) = @_;
 685   my @info = @{$self->_connect_info || []};
 686   $self->_dbh($self->_connect(@info));
 687
 688   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 689     my $driver = $self->_dbh->{Driver}->{Name};
 690     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 691       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 692       $self->_rebless() if $self->can('_rebless');
 693     }
 694   }
 695
 696   # if on-connect sql statements are given execute them
 697   foreach my $sql_statement (@{$self->on_connect_do || []}) {
 698     $self->debugobj->query_start($sql_statement) if $self->debug();
 699     $self->_dbh->do($sql_statement);
 700     $self->debugobj->query_end($sql_statement) if $self->debug();
 701   }
 702
 703   $self->_conn_pid($$);
 704   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 705 }
 706
 707 sub _connect {
 708   my ($self, @info) = @_;
 709
 710   $self->throw_exception("You failed to provide any connection info")
 711       if !@info;
 712
 713   my ($old_connect_via, $dbh);
 714
 715   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 716       $old_connect_via = $DBI::connect_via;
 717       $DBI::connect_via = 'connect';
 718   }
 719
 720   eval {
 721     if(ref $info[0] eq 'CODE') {
 722        $dbh = &{$info[0]}
 723     }
 724     else {
 725        $dbh = DBI->connect(@info);
 726        $dbh->{RaiseError} = 1;
 727        $dbh->{PrintError} = 0;
 728        $dbh->{PrintWarn} = 0;
 729     }
 730   };
 731
 732   $DBI::connect_via = $old_connect_via if $old_connect_via;
 733
 734   if (!$dbh || $@) {
 735     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
 736   }
 737
 738   $dbh;
 739 }
 740
 741 sub _dbh_txn_begin {
 742   my ($self, $dbh) = @_;
 743   if ($dbh->{AutoCommit}) {
 744     $self->debugobj->txn_begin()
 745       if ($self->debug);
 746     $dbh->begin_work;
 747   }
 748 }
 749
 750 sub txn_begin {
 751   my $self = shift;
 752   $self->dbh_do($self->can('_dbh_txn_begin'))
 753     if $self->{transaction_depth}++ == 0;
 754 }
 755
 756 sub _dbh_txn_commit {
 757   my ($self, $dbh) = @_;
 758   if ($self->{transaction_depth} == 0) {
 759     unless ($dbh->{AutoCommit}) {
 760       $self->debugobj->txn_commit()
 761         if ($self->debug);
 762       $dbh->commit;
 763     }
 764   }
 765   else {
 766     if (--$self->{transaction_depth} == 0) {
 767       $self->debugobj->txn_commit()
 768         if ($self->debug);
 769       $dbh->commit;
 770     }
 771   }
 772 }
 773
 774 sub txn_commit {
 775   my $self = shift;
 776   $self->dbh_do($self->can('_dbh_txn_commit'));
 777 }
 778
 779 sub _dbh_txn_rollback {
 780   my ($self, $dbh) = @_;
 781   if ($self->{transaction_depth} == 0) {
 782     unless ($dbh->{AutoCommit}) {
 783       $self->debugobj->txn_rollback()
 784         if ($self->debug);
 785       $dbh->rollback;
 786     }
 787   }
 788   else {
 789     if (--$self->{transaction_depth} == 0) {
 790       $self->debugobj->txn_rollback()
 791         if ($self->debug);
 792       $dbh->rollback;
 793     }
 794     else {
 795       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 796     }
 797   }
 798 }
 799
 800 sub txn_rollback {
 801   my $self = shift;
 802
 803   eval { $self->dbh_do($self->can('_dbh_txn_rollback')) };
 804   if ($@) {
 805     my $error = $@;
 806     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 807     $error =~ /$exception_class/ and $self->throw_exception($error);
 808     $self->{transaction_depth} = 0;          # ensure that a failed rollback
 809     $self->throw_exception($error);          # resets the transaction depth
 810   }
 811 }
 812
 813 # This used to be the top-half of _execute.  It was split out to make it
 814 #  easier to override in NoBindVars without duping the rest.  It takes up
 815 #  all of _execute's args, and emits $sql, @bind.
 816 sub _prep_for_execute {
 817   my ($self, $op, $extra_bind, $ident, @args) = @_;
 818
 819   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 820   unshift(@bind,
 821     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 822       if $extra_bind;
 823   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 824
 825   return ($sql, @bind);
 826 }
 827
 828 sub _execute {
 829   my ($self, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 830
 831   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
 832   unshift(@bind,
 833     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 834       if $extra_bind;
 835   if ($self->debug) {
 836       my @debug_bind =
 837         map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 838       $self->debugobj->query_start($sql, @debug_bind);
 839   }
 840   my $sth = eval { $self->sth($sql,$op) };
 841
 842   if (!$sth || $@) {
 843     $self->throw_exception(
 844       'no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql"
 845     );
 846   }
 847
 848   my $rv;
 849   if ($sth) {
 850     my $time = time();
 851
 852     $rv = eval {
 853
 854       my $placeholder_index = 1;
 855
 856       foreach my $bound (@bind) {
 857
 858         my $attributes = {};
 859         my($column_name, @data) = @$bound;
 860
 861         if( $bind_attributes ) {
 862           $attributes = $bind_attributes->{$column_name}
 863           if defined $bind_attributes->{$column_name};
 864         }
 865
 866                 foreach my $data (@data)
 867                 {
 868           $data = ref $data ? ''.$data : $data; # stringify args
 869
 870           $sth->bind_param($placeholder_index, $data, $attributes);
 871           $placeholder_index++;
 872                 }
 873       }
 874       $sth->execute();
 875     };
 876
 877     if ($@ || !$rv) {
 878       $self->throw_exception("Error executing '$sql': ".($@ || $sth->errstr));
 879     }
 880   } else {
 881     $self->throw_exception("'$sql' did not generate a statement.");
 882   }
 883   if ($self->debug) {
 884      my @debug_bind =
 885        map { defined ($_ && $_->[1]) ? qq{'$_->[1]'} : q{'NULL'} } @bind;
 886      $self->debugobj->query_end($sql, @debug_bind);
 887   }
 888   return (wantarray ? ($rv, $sth, @bind) : $rv);
 889 }
 890
 891 sub insert {
 892   my ($self, $source, $to_insert) = @_;
 893
 894   my $ident = $source->from;
 895   my $bind_attributes;
 896   foreach my $column ($source->columns) {
 897
 898     my $data_type = $source->column_info($column)->{data_type} || '';
 899     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
 900          if $data_type;
 901   }
 902
 903   $self->throw_exception(
 904     "Couldn't insert ".join(', ',
 905       map "$_ => $to_insert->{$_}", keys %$to_insert
 906     )." into ${ident}"
 907   ) unless ($self->_execute('insert' => [], $ident, $bind_attributes, $to_insert));
 908   return $to_insert;
 909 }
 910
 911 ## Still not quite perfect, and EXPERIMENTAL
 912 ## Currently it is assumed that all values passed will be "normal", i.e. not
 913 ## scalar refs, or at least, all the same type as the first set, the statement is
 914 ## only prepped once.
 915 sub insert_bulk {
 916   my ($self, $source, $cols, $data) = @_;
 917   my %colvalues;
 918   my $table = $source->from;
 919   @colvalues{@$cols} = (0..$#$cols);
 920   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 921
 922   if ($self->debug) {
 923       my @debug_bind = map { defined $_->[1] ? qq{$_->[1]} : q{'NULL'} } @bind;
 924       $self->debugobj->query_start($sql, @debug_bind);
 925   }
 926   my $sth = $self->sth($sql);
 927
 928 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
 929
 930   my $rv;
 931
 932   ## This must be an arrayref, else nothing works!
 933
 934   my $tuple_status = [];
 935
 936   ##use Data::Dumper;
 937   ##print STDERR Dumper( $data, $sql, [@bind] );
 938
 939   if ($sth) {
 940
 941     my $time = time();
 942
 943     #$rv = eval {
 944         #
 945         #  $sth->execute_array({
 946
 947         #    ArrayTupleFetch => sub {
 948
 949         #      my $values = shift @$data;
 950     #      return if !$values;
 951     #      return [ @{$values}[@bind] ];
 952         #    },
 953
 954         #    ArrayTupleStatus => $tuple_status,
 955         #  })
 956     #};
 957
 958         ## Get the bind_attributes, if any exist
 959
 960     my $bind_attributes;
 961     foreach my $column ($source->columns) {
 962
 963       my $data_type = $source->column_info($column)->{data_type} || '';
 964       $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
 965            if $data_type;
 966     }
 967
 968         ## Bind the values and execute
 969
 970         $rv = eval {
 971
 972      my $placeholder_index = 1;
 973
 974         foreach my $bound (@bind) {
 975
 976           my $attributes = {};
 977           my ($column_name, $data_index) = @$bound;
 978
 979           if( $bind_attributes ) {
 980             $attributes = $bind_attributes->{$column_name}
 981             if defined $bind_attributes->{$column_name};
 982           }
 983
 984                   my @data = map { $_->[$data_index] } @$data;
 985
 986           $sth->bind_param_array( $placeholder_index, [@data], $attributes );
 987           $placeholder_index++;
 988       }
 989           $sth->execute_array( {ArrayTupleStatus => $tuple_status} );
 990
 991         };
 992
 993 #print STDERR Dumper($tuple_status);
 994 #print STDERR "RV: $rv\n";
 995
 996     if ($@ || !defined $rv) {
 997       my $errors = '';
 998       foreach my $tuple (@$tuple_status)
 999       {
1000           $errors .= "\n" . $tuple->[1] if(ref $tuple);
1001       }
1002       $self->throw_exception("Error executing '$sql': ".($@ || $errors));
1003     }
1004   } else {
1005     $self->throw_exception("'$sql' did not generate a statement.");
1006   }
1007   if ($self->debug) {
1008       my @debug_bind = map { defined $_ ? qq{`$_'} : q{`NULL'} } @bind;
1009       $self->debugobj->query_end($sql, @debug_bind);
1010   }
1011   return (wantarray ? ($rv, $sth, @bind) : $rv);
1012 }
1013
1014 sub update {
1015   my $self = shift @_;
1016   my $source = shift @_;
1017
1018   my $bind_attributes;
1019   foreach my $column ($source->columns) {
1020
1021     my $data_type = $source->column_info($column)->{data_type} || '';
1022     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1023          if $data_type;
1024   }
1025
1026   my $ident = $source->from;
1027   return $self->_execute('update' => [], $ident, $bind_attributes, @_);
1028 }
1029
1030
1031 sub delete {
1032   my $self = shift @_;
1033   my $source = shift @_;
1034
1035   my $bind_attrs = {}; ## If ever it's needed...
1036   my $ident = $source->from;
1037
1038   return $self->_execute('delete' => [], $ident, $bind_attrs, @_);
1039 }
1040
1041 sub _select {
1042   my ($self, $ident, $select, $condition, $attrs) = @_;
1043   my $order = $attrs->{order_by};
1044   if (ref $condition eq 'SCALAR') {
1045     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1046   }
1047   if (exists $attrs->{group_by} || $attrs->{having}) {
1048     $order = {
1049       group_by => $attrs->{group_by},
1050       having => $attrs->{having},
1051       ($order ? (order_by => $order) : ())
1052     };
1053   }
1054   my $bind_attrs = {}; ## Future support
1055   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1056   if ($attrs->{software_limit} ||
1057       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1058         $attrs->{software_limit} = 1;
1059   } else {
1060     $self->throw_exception("rows attribute must be positive if present")
1061       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1062     push @args, $attrs->{rows}, $attrs->{offset};
1063   }
1064   return $self->_execute(@args);
1065 }
1066
1067 =head2 select
1068
1069 =over 4
1070
1071 =item Arguments: $ident, $select, $condition, $attrs
1072
1073 =back
1074
1075 Handle a SQL select statement.
1076
1077 =cut
1078
1079 sub select {
1080   my $self = shift;
1081   my ($ident, $select, $condition, $attrs) = @_;
1082   return $self->cursor->new($self, \@_, $attrs);
1083 }
1084
1085 sub select_single {
1086   my $self = shift;
1087   my ($rv, $sth, @bind) = $self->_select(@_);
1088   my @row = $sth->fetchrow_array;
1089   # Need to call finish() to work round broken DBDs
1090   $sth->finish();
1091   return @row;
1092 }
1093
1094 =head2 sth
1095
1096 =over 4
1097
1098 =item Arguments: $sql
1099
1100 =back
1101
1102 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1103
1104 =cut
1105
1106 sub _dbh_sth {
1107   my ($self, $dbh, $sql) = @_;
1108
1109   # 3 is the if_active parameter which avoids active sth re-use
1110   my $sth = $self->disable_sth_caching
1111     ? $dbh->prepare($sql)
1112     : $dbh->prepare_cached($sql, {}, 3);
1113
1114   $self->throw_exception(
1115     'no sth generated via sql (' . ($@ || $dbh->errstr) . "): $sql"
1116   ) if !$sth;
1117
1118   $sth;
1119 }
1120
1121 sub sth {
1122   my ($self, $sql) = @_;
1123   $self->dbh_do($self->can('_dbh_sth'), $sql);
1124 }
1125
1126 sub _dbh_columns_info_for {
1127   my ($self, $dbh, $table) = @_;
1128
1129   if ($dbh->can('column_info')) {
1130     my %result;
1131     eval {
1132       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1133       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1134       $sth->execute();
1135       while ( my $info = $sth->fetchrow_hashref() ){
1136         my %column_info;
1137         $column_info{data_type}   = $info->{TYPE_NAME};
1138         $column_info{size}      = $info->{COLUMN_SIZE};
1139         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1140         $column_info{default_value} = $info->{COLUMN_DEF};
1141         my $col_name = $info->{COLUMN_NAME};
1142         $col_name =~ s/^\"(.*)\"$/$1/;
1143
1144         $result{$col_name} = \%column_info;
1145       }
1146     };
1147     return \%result if !$@ && scalar keys %result;
1148   }
1149
1150   my %result;
1151   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
1152   $sth->execute;
1153   my @columns = @{$sth->{NAME_lc}};
1154   for my $i ( 0 .. $#columns ){
1155     my %column_info;
1156     my $type_num = $sth->{TYPE}->[$i];
1157     my $type_name;
1158     if(defined $type_num && $dbh->can('type_info')) {
1159       my $type_info = $dbh->type_info($type_num);
1160       $type_name = $type_info->{TYPE_NAME} if $type_info;
1161     }
1162     $column_info{data_type} = $type_name ? $type_name : $type_num;
1163     $column_info{size} = $sth->{PRECISION}->[$i];
1164     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1165
1166     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1167       $column_info{data_type} = $1;
1168       $column_info{size}    = $2;
1169     }
1170
1171     $result{$columns[$i]} = \%column_info;
1172   }
1173
1174   return \%result;
1175 }
1176
1177 sub columns_info_for {
1178   my ($self, $table) = @_;
1179   $self->dbh_do($self->can('_dbh_columns_info_for'), $table);
1180 }
1181
1182 =head2 last_insert_id
1183
1184 Return the row id of the last insert.
1185
1186 =cut
1187
1188 sub _dbh_last_insert_id {
1189     my ($self, $dbh, $source, $col) = @_;
1190     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1191     $dbh->func('last_insert_rowid');
1192 }
1193
1194 sub last_insert_id {
1195   my $self = shift;
1196   $self->dbh_do($self->can('_dbh_last_insert_id'), @_);
1197 }
1198
1199 =head2 sqlt_type
1200
1201 Returns the database driver name.
1202
1203 =cut
1204
1205 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1206
1207 =head2 bind_attribute_by_data_type
1208
1209 Given a datatype from column info, returns a database specific bind attribute for
1210 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1211 just handle it.
1212
1213 Generally only needed for special case column types, like bytea in postgres.
1214
1215 =cut
1216
1217 sub bind_attribute_by_data_type {
1218     return;
1219 }
1220
1221 =head2 create_ddl_dir (EXPERIMENTAL)
1222
1223 =over 4
1224
1225 =item Arguments: $schema \@databases, $version, $directory, $preversion, $sqlt_args
1226
1227 =back
1228
1229 Creates a SQL file based on the Schema, for each of the specified
1230 database types, in the given directory.
1231
1232 Note that this feature is currently EXPERIMENTAL and may not work correctly
1233 across all databases, or fully handle complex relationships.
1234
1235 =cut
1236
1237 sub create_ddl_dir
1238 {
1239   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1240
1241   if(!$dir || !-d $dir)
1242   {
1243     warn "No directory given, using ./\n";
1244     $dir = "./";
1245   }
1246   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1247   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1248   $version ||= $schema->VERSION || '1.x';
1249   $sqltargs = { ( add_drop_table => 1 ), %{$sqltargs || {}} };
1250
1251   eval "use SQL::Translator";
1252   $self->throw_exception("Can't create a ddl file without SQL::Translator: $@") if $@;
1253
1254   my $sqlt = SQL::Translator->new({
1255 #      debug => 1,
1256       add_drop_table => 1,
1257   });
1258   foreach my $db (@$databases)
1259   {
1260     $sqlt->reset();
1261     $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1262 #    $sqlt->parser_args({'DBIx::Class' => $schema);
1263     $sqlt = $self->configure_sqlt($sqlt, $db);
1264     $sqlt->data($schema);
1265     $sqlt->producer($db);
1266
1267     my $file;
1268     my $filename = $schema->ddl_filename($db, $dir, $version);
1269     if(-e $filename)
1270     {
1271       warn("$filename already exists, skipping $db");
1272       next;
1273     }
1274
1275     my $output = $sqlt->translate;
1276     if(!$output)
1277     {
1278       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1279       next;
1280     }
1281     if(!open($file, ">$filename"))
1282     {
1283         $self->throw_exception("Can't open $filename for writing ($!)");
1284         next;
1285     }
1286     print $file $output;
1287     close($file);
1288
1289     if($preversion)
1290     {
1291       eval "use SQL::Translator::Diff";
1292       if($@)
1293       {
1294         warn("Can't diff versions without SQL::Translator::Diff: $@");
1295         next;
1296       }
1297
1298       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1299 #      print "Previous version $prefilename\n";
1300       if(!-e $prefilename)
1301       {
1302         warn("No previous schema file found ($prefilename)");
1303         next;
1304       }
1305       #### We need to reparse the SQLite file we just wrote, so that
1306       ##   Diff doesnt get all confoosed, and Diff is *very* confused.
1307       ##   FIXME: rip Diff to pieces!
1308 #      my $target_schema = $sqlt->schema;
1309 #      unless ( $target_schema->name ) {
1310 #        $target_schema->name( $filename );
1311 #      }
1312       my @input;
1313       push @input, {file => $prefilename, parser => $db};
1314       push @input, {file => $filename, parser => $db};
1315       my ( $source_schema, $source_db, $target_schema, $target_db ) = map {
1316         my $file   = $_->{'file'};
1317         my $parser = $_->{'parser'};
1318
1319         my $t = SQL::Translator->new;
1320         $t->debug( 0 );
1321         $t->trace( 0 );
1322         $t->parser( $parser )            or die $t->error;
1323         my $out = $t->translate( $file ) or die $t->error;
1324         my $schema = $t->schema;
1325         unless ( $schema->name ) {
1326           $schema->name( $file );
1327         }
1328         ($schema, $parser);
1329       } @input;
1330
1331       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1332                                                     $target_schema, $db,
1333                                                     {}
1334                                                    );
1335       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1336       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1337       if(-e $difffile)
1338       {
1339         warn("$difffile already exists, skipping");
1340         next;
1341       }
1342       if(!open $file, ">$difffile")
1343       {
1344         $self->throw_exception("Can't write to $difffile ($!)");
1345         next;
1346       }
1347       print $file $diff;
1348       close($file);
1349     }
1350   }
1351 }
1352
1353 sub configure_sqlt() {
1354   my $self = shift;
1355   my $tr = shift;
1356   my $db = shift || $self->sqlt_type;
1357   if ($db eq 'PostgreSQL') {
1358     $tr->quote_table_names(0);
1359     $tr->quote_field_names(0);
1360   }
1361   return $tr;
1362 }
1363
1364 =head2 deployment_statements
1365
1366 =over 4
1367
1368 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1369
1370 =back
1371
1372 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1373 The database driver name is given by C<$type>, though the value from
1374 L</sqlt_type> is used if it is not specified.
1375
1376 C<$directory> is used to return statements from files in a previously created
1377 L</create_ddl_dir> directory and is optional. The filenames are constructed
1378 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1379
1380 If no C<$directory> is specified then the statements are constructed on the
1381 fly using L<SQL::Translator> and C<$version> is ignored.
1382
1383 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1384
1385 =cut
1386
1387 sub deployment_statements {
1388   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1389   # Need to be connected to get the correct sqlt_type
1390   $self->ensure_connected() unless $type;
1391   $type ||= $self->sqlt_type;
1392   $version ||= $schema->VERSION || '1.x';
1393   $dir ||= './';
1394   my $filename = $schema->ddl_filename($type, $dir, $version);
1395   if(-f $filename)
1396   {
1397       my $file;
1398       open($file, "<$filename")
1399         or $self->throw_exception("Can't open $filename ($!)");
1400       my @rows = <$file>;
1401       close($file);
1402       return join('', @rows);
1403   }
1404
1405   eval "use SQL::Translator";
1406   if(!$@)
1407   {
1408     eval "use SQL::Translator::Parser::DBIx::Class;";
1409     $self->throw_exception($@) if $@;
1410     eval "use SQL::Translator::Producer::${type};";
1411     $self->throw_exception($@) if $@;
1412
1413     # sources needs to be a parser arg, but for simplicty allow at top level
1414     # coming in
1415     $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1416         if exists $sqltargs->{sources};
1417
1418     my $tr = SQL::Translator->new(%$sqltargs);
1419     SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1420     return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1421   }
1422
1423   $self->throw_exception("No SQL::Translator, and no Schema file found, aborting deploy");
1424   return;
1425
1426 }
1427
1428 sub deploy {
1429   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1430   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1431     for ( split(";\n", $statement)) {
1432       next if($_ =~ /^--/);
1433       next if(!$_);
1434 #      next if($_ =~ /^DROP/m);
1435       next if($_ =~ /^BEGIN TRANSACTION/m);
1436       next if($_ =~ /^COMMIT/m);
1437       next if $_ =~ /^\s+$/; # skip whitespace only
1438       $self->debugobj->query_start($_) if $self->debug;
1439       $self->dbh->do($_) or warn "SQL was:\n $_"; # XXX exceptions?
1440       $self->debugobj->query_end($_) if $self->debug;
1441     }
1442   }
1443 }
1444
1445 =head2 datetime_parser
1446
1447 Returns the datetime parser class
1448
1449 =cut
1450
1451 sub datetime_parser {
1452   my $self = shift;
1453   return $self->{datetime_parser} ||= $self->build_datetime_parser(@_);
1454 }
1455
1456 =head2 datetime_parser_type
1457
1458 Defines (returns) the datetime parser class - currently hardwired to
1459 L<DateTime::Format::MySQL>
1460
1461 =cut
1462
1463 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1464
1465 =head2 build_datetime_parser
1466
1467 See L</datetime_parser>
1468
1469 =cut
1470
1471 sub build_datetime_parser {
1472   my $self = shift;
1473   my $type = $self->datetime_parser_type(@_);
1474   eval "use ${type}";
1475   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1476   return $type;
1477 }
1478
1479 sub DESTROY {
1480   my $self = shift;
1481   return if !$self->_dbh;
1482   $self->_verify_pid;
1483   $self->_dbh(undef);
1484 }
1485
1486 1;
1487
1488 =head1 SQL METHODS
1489
1490 The module defines a set of methods within the DBIC::SQL::Abstract
1491 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1492 SQL query functions.
1493
1494 The following methods are extended:-
1495
1496 =over 4
1497
1498 =item delete
1499
1500 =item insert
1501
1502 =item select
1503
1504 =item update
1505
1506 =item limit_dialect
1507
1508 See L</connect_info> for details.
1509 For setting, this method is deprecated in favor of L</connect_info>.
1510
1511 =item quote_char
1512
1513 See L</connect_info> for details.
1514 For setting, this method is deprecated in favor of L</connect_info>.
1515
1516 =item name_sep
1517
1518 See L</connect_info> for details.
1519 For setting, this method is deprecated in favor of L</connect_info>.
1520
1521 =back
1522
1523 =head1 AUTHORS
1524
1525 Matt S. Trout <mst@shadowcatsystems.co.uk>
1526
1527 Andy Grundman <andy@hybridized.org>
1528
1529 =head1 LICENSE
1530
1531 You may distribute this code under the same terms as Perl itself.
1532
1533 =cut