lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/DBIx::Class::Storage::DBIHacks DBIx::Class::Storage/;
   8 use mro 'c3';
   9
  10 use DBIx::Class::Carp;
  11 use Scalar::Util qw/refaddr weaken reftype blessed/;
  12 use List::Util qw/first/;
  13 use Sub::Name 'subname';
  14 use Context::Preserve 'preserve_context';
  15 use Try::Tiny;
  16 use overload ();
  17 use Data::Compare (); # no imports!!! guard against insane architecture
  18 use namespace::clean;
  19
  20 # default cursor class, overridable in connect_info attributes
  21 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  22
  23 __PACKAGE__->mk_group_accessors('inherited' => qw/
  24   sql_limit_dialect sql_quote_char sql_name_sep
  25 /);
  26
  27 __PACKAGE__->mk_group_accessors('component_class' => qw/sql_maker_class datetime_parser_type/);
  28
  29 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker');
  30 __PACKAGE__->datetime_parser_type('DateTime::Format::MySQL'); # historic default
  31
  32 __PACKAGE__->sql_name_sep('.');
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/
  35   _connect_info _dbi_connect_info _dbic_connect_attributes _driver_determined
  36   _dbh _dbh_details _conn_pid _sql_maker _sql_maker_opts _dbh_autocommit
  37   _perform_autoinc_retrieval _autoinc_supplied_for_op
  38 /);
  39
  40 # the values for these accessors are picked out (and deleted) from
  41 # the attribute hashref passed to connect_info
  42 my @storage_options = qw/
  43   on_connect_call on_disconnect_call on_connect_do on_disconnect_do
  44   disable_sth_caching unsafe auto_savepoint
  45 /;
  46 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  47
  48
  49 # capability definitions, using a 2-tiered accessor system
  50 # The rationale is:
  51 #
  52 # A driver/user may define _use_X, which blindly without any checks says:
  53 # "(do not) use this capability", (use_dbms_capability is an "inherited"
  54 # type accessor)
  55 #
  56 # If _use_X is undef, _supports_X is then queried. This is a "simple" style
  57 # accessor, which in turn calls _determine_supports_X, and stores the return
  58 # in a special slot on the storage object, which is wiped every time a $dbh
  59 # reconnection takes place (it is not guaranteed that upon reconnection we
  60 # will get the same rdbms version). _determine_supports_X does not need to
  61 # exist on a driver, as we ->can for it before calling.
  62
  63 my @capabilities = (qw/
  64   insert_returning
  65   insert_returning_bound
  66
  67   multicolumn_in
  68
  69   placeholders
  70   typeless_placeholders
  71
  72   join_optimizer
  73 /);
  74 __PACKAGE__->mk_group_accessors( dbms_capability => map { "_supports_$_" } @capabilities );
  75 __PACKAGE__->mk_group_accessors( use_dbms_capability => map { "_use_$_" } (@capabilities ) );
  76
  77 # on by default, not strictly a capability (pending rewrite)
  78 __PACKAGE__->_use_join_optimizer (1);
  79 sub _determine_supports_join_optimizer { 1 };
  80
  81 # Each of these methods need _determine_driver called before itself
  82 # in order to function reliably. This is a purely DRY optimization
  83 #
  84 # get_(use)_dbms_capability need to be called on the correct Storage
  85 # class, as _use_X may be hardcoded class-wide, and _supports_X calls
  86 # _determine_supports_X which obv. needs a correct driver as well
  87 my @rdbms_specific_methods = qw/
  88   sqlt_type
  89   sql_maker
  90   build_datetime_parser
  91   datetime_parser_type
  92
  93   txn_begin
  94   insert
  95   insert_bulk
  96   update
  97   delete
  98   select
  99   select_single
 100   with_deferred_fk_checks
 101
 102   get_use_dbms_capability
 103   get_dbms_capability
 104
 105   _server_info
 106   _get_server_version
 107 /;
 108
 109 for my $meth (@rdbms_specific_methods) {
 110
 111   my $orig = __PACKAGE__->can ($meth)
 112     or die "$meth is not a ::Storage::DBI method!";
 113
 114   no strict qw/refs/;
 115   no warnings qw/redefine/;
 116   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
 117     if (
 118       # only fire when invoked on an instance, a valid class-based invocation
 119       # would e.g. be setting a default for an inherited accessor
 120       ref $_[0]
 121         and
 122       ! $_[0]->{_driver_determined}
 123         and
 124       ! $_[0]->{_in_determine_driver}
 125         and
 126       ($_[0]->_dbi_connect_info||[])->[0]
 127     ) {
 128       $_[0]->_determine_driver;
 129
 130       # This for some reason crashes and burns on perl 5.8.1
 131       # IFF the method ends up throwing an exception
 132       #goto $_[0]->can ($meth);
 133
 134       my $cref = $_[0]->can ($meth);
 135       goto $cref;
 136     }
 137
 138     goto $orig;
 139   };
 140 }
 141
 142 =head1 NAME
 143
 144 DBIx::Class::Storage::DBI - DBI storage handler
 145
 146 =head1 SYNOPSIS
 147
 148   my $schema = MySchema->connect('dbi:SQLite:my.db');
 149
 150   $schema->storage->debug(1);
 151
 152   my @stuff = $schema->storage->dbh_do(
 153     sub {
 154       my ($storage, $dbh, @args) = @_;
 155       $dbh->do("DROP TABLE authors");
 156     },
 157     @column_list
 158   );
 159
 160   $schema->resultset('Book')->search({
 161      written_on => $schema->storage->datetime_parser->format_datetime(DateTime->now)
 162   });
 163
 164 =head1 DESCRIPTION
 165
 166 This class represents the connection to an RDBMS via L<DBI>.  See
 167 L<DBIx::Class::Storage> for general information.  This pod only
 168 documents DBI-specific methods and behaviors.
 169
 170 =head1 METHODS
 171
 172 =cut
 173
 174 sub new {
 175   my $new = shift->next::method(@_);
 176
 177   $new->_sql_maker_opts({});
 178   $new->_dbh_details({});
 179   $new->{_in_do_block} = 0;
 180
 181   # read below to see what this does
 182   $new->_arm_global_destructor;
 183
 184   $new;
 185 }
 186
 187 # This is hack to work around perl shooting stuff in random
 188 # order on exit(). If we do not walk the remaining storage
 189 # objects in an END block, there is a *small but real* chance
 190 # of a fork()ed child to kill the parent's shared DBI handle,
 191 # *before perl reaches the DESTROY in this package*
 192 # Yes, it is ugly and effective.
 193 # Additionally this registry is used by the CLONE method to
 194 # make sure no handles are shared between threads
 195 {
 196   my %seek_and_destroy;
 197
 198   sub _arm_global_destructor {
 199     weaken (
 200       $seek_and_destroy{ refaddr($_[0]) } = $_[0]
 201     );
 202   }
 203
 204   END {
 205     local $?; # just in case the DBI destructor changes it somehow
 206
 207     # destroy just the object if not native to this process
 208     $_->_verify_pid for (grep
 209       { defined $_ }
 210       values %seek_and_destroy
 211     );
 212   }
 213
 214   sub CLONE {
 215     # As per DBI's recommendation, DBIC disconnects all handles as
 216     # soon as possible (DBIC will reconnect only on demand from within
 217     # the thread)
 218     my @instances = grep { defined $_ } values %seek_and_destroy;
 219     %seek_and_destroy = ();
 220
 221     for (@instances) {
 222       $_->_dbh(undef);
 223
 224       $_->transaction_depth(0);
 225       $_->savepoints([]);
 226
 227       # properly renumber existing refs
 228       $_->_arm_global_destructor
 229     }
 230   }
 231 }
 232
 233 sub DESTROY {
 234   my $self = shift;
 235
 236   # some databases spew warnings on implicit disconnect
 237   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 238   local $SIG{__WARN__} = sub {};
 239   $self->_dbh(undef);
 240
 241   # this op is necessary, since the very last perl runtime statement
 242   # triggers a global destruction shootout, and the $SIG localization
 243   # may very well be destroyed before perl actually gets to do the
 244   # $dbh undef
 245   1;
 246 }
 247
 248 # handle pid changes correctly - do not destroy parent's connection
 249 sub _verify_pid {
 250   my $self = shift;
 251
 252   my $pid = $self->_conn_pid;
 253   if( defined $pid and $pid != $$ and my $dbh = $self->_dbh ) {
 254     $dbh->{InactiveDestroy} = 1;
 255     $self->_dbh(undef);
 256     $self->transaction_depth(0);
 257     $self->savepoints([]);
 258   }
 259
 260   return;
 261 }
 262
 263 =head2 connect_info
 264
 265 This method is normally called by L<DBIx::Class::Schema/connection>, which
 266 encapsulates its argument list in an arrayref before passing them here.
 267
 268 The argument list may contain:
 269
 270 =over
 271
 272 =item *
 273
 274 The same 4-element argument set one would normally pass to
 275 L<DBI/connect>, optionally followed by
 276 L<extra attributes|/DBIx::Class specific connection attributes>
 277 recognized by DBIx::Class:
 278
 279   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 280
 281 =item *
 282
 283 A single code reference which returns a connected
 284 L<DBI database handle|DBI/connect> optionally followed by
 285 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 286 by DBIx::Class:
 287
 288   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 289
 290 =item *
 291
 292 A single hashref with all the attributes and the dsn/user/password
 293 mixed together:
 294
 295   $connect_info_args = [{
 296     dsn => $dsn,
 297     user => $user,
 298     password => $pass,
 299     %dbi_attributes,
 300     %extra_attributes,
 301   }];
 302
 303   $connect_info_args = [{
 304     dbh_maker => sub { DBI->connect (...) },
 305     %dbi_attributes,
 306     %extra_attributes,
 307   }];
 308
 309 This is particularly useful for L<Catalyst> based applications, allowing the
 310 following config (L<Config::General> style):
 311
 312   <Model::DB>
 313     schema_class   App::DB
 314     <connect_info>
 315       dsn          dbi:mysql:database=test
 316       user         testuser
 317       password     TestPass
 318       AutoCommit   1
 319     </connect_info>
 320   </Model::DB>
 321
 322 The C<dsn>/C<user>/C<password> combination can be substituted by the
 323 C<dbh_maker> key whose value is a coderef that returns a connected
 324 L<DBI database handle|DBI/connect>
 325
 326 =back
 327
 328 Please note that the L<DBI> docs recommend that you always explicitly
 329 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 330 recommends that it be set to I<1>, and that you perform transactions
 331 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 332 to I<1> if you do not do explicitly set it to zero.  This is the default
 333 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 334
 335 =head3 DBIx::Class specific connection attributes
 336
 337 In addition to the standard L<DBI|DBI/ATTRIBUTES COMMON TO ALL HANDLES>
 338 L<connection|DBI/Database Handle Attributes> attributes, DBIx::Class recognizes
 339 the following connection options. These options can be mixed in with your other
 340 L<DBI> connection attributes, or placed in a separate hashref
 341 (C<\%extra_attributes>) as shown above.
 342
 343 Every time C<connect_info> is invoked, any previous settings for
 344 these options will be cleared before setting the new ones, regardless of
 345 whether any options are specified in the new C<connect_info>.
 346
 347
 348 =over
 349
 350 =item on_connect_do
 351
 352 Specifies things to do immediately after connecting or re-connecting to
 353 the database.  Its value may contain:
 354
 355 =over
 356
 357 =item a scalar
 358
 359 This contains one SQL statement to execute.
 360
 361 =item an array reference
 362
 363 This contains SQL statements to execute in order.  Each element contains
 364 a string or a code reference that returns a string.
 365
 366 =item a code reference
 367
 368 This contains some code to execute.  Unlike code references within an
 369 array reference, its return value is ignored.
 370
 371 =back
 372
 373 =item on_disconnect_do
 374
 375 Takes arguments in the same form as L</on_connect_do> and executes them
 376 immediately before disconnecting from the database.
 377
 378 Note, this only runs if you explicitly call L</disconnect> on the
 379 storage object.
 380
 381 =item on_connect_call
 382
 383 A more generalized form of L</on_connect_do> that calls the specified
 384 C<connect_call_METHOD> methods in your storage driver.
 385
 386   on_connect_do => 'select 1'
 387
 388 is equivalent to:
 389
 390   on_connect_call => [ [ do_sql => 'select 1' ] ]
 391
 392 Its values may contain:
 393
 394 =over
 395
 396 =item a scalar
 397
 398 Will call the C<connect_call_METHOD> method.
 399
 400 =item a code reference
 401
 402 Will execute C<< $code->($storage) >>
 403
 404 =item an array reference
 405
 406 Each value can be a method name or code reference.
 407
 408 =item an array of arrays
 409
 410 For each array, the first item is taken to be the C<connect_call_> method name
 411 or code reference, and the rest are parameters to it.
 412
 413 =back
 414
 415 Some predefined storage methods you may use:
 416
 417 =over
 418
 419 =item do_sql
 420
 421 Executes a SQL string or a code reference that returns a SQL string. This is
 422 what L</on_connect_do> and L</on_disconnect_do> use.
 423
 424 It can take:
 425
 426 =over
 427
 428 =item a scalar
 429
 430 Will execute the scalar as SQL.
 431
 432 =item an arrayref
 433
 434 Taken to be arguments to L<DBI/do>, the SQL string optionally followed by the
 435 attributes hashref and bind values.
 436
 437 =item a code reference
 438
 439 Will execute C<< $code->($storage) >> and execute the return array refs as
 440 above.
 441
 442 =back
 443
 444 =item datetime_setup
 445
 446 Execute any statements necessary to initialize the database session to return
 447 and accept datetime/timestamp values used with
 448 L<DBIx::Class::InflateColumn::DateTime>.
 449
 450 Only necessary for some databases, see your specific storage driver for
 451 implementation details.
 452
 453 =back
 454
 455 =item on_disconnect_call
 456
 457 Takes arguments in the same form as L</on_connect_call> and executes them
 458 immediately before disconnecting from the database.
 459
 460 Calls the C<disconnect_call_METHOD> methods as opposed to the
 461 C<connect_call_METHOD> methods called by L</on_connect_call>.
 462
 463 Note, this only runs if you explicitly call L</disconnect> on the
 464 storage object.
 465
 466 =item disable_sth_caching
 467
 468 If set to a true value, this option will disable the caching of
 469 statement handles via L<DBI/prepare_cached>.
 470
 471 =item limit_dialect
 472
 473 Sets a specific SQL::Abstract::Limit-style limit dialect, overriding the
 474 default L</sql_limit_dialect> setting of the storage (if any). For a list
 475 of available limit dialects see L<DBIx::Class::SQLMaker::LimitDialects>.
 476
 477 =item quote_names
 478
 479 When true automatically sets L</quote_char> and L</name_sep> to the characters
 480 appropriate for your particular RDBMS. This option is preferred over specifying
 481 L</quote_char> directly.
 482
 483 =item quote_char
 484
 485 Specifies what characters to use to quote table and column names.
 486
 487 C<quote_char> expects either a single character, in which case is it
 488 is placed on either side of the table/column name, or an arrayref of length
 489 2 in which case the table/column name is placed between the elements.
 490
 491 For example under MySQL you should use C<< quote_char => '`' >>, and for
 492 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 493
 494 =item name_sep
 495
 496 This parameter is only useful in conjunction with C<quote_char>, and is used to
 497 specify the character that separates elements (schemas, tables, columns) from
 498 each other. If unspecified it defaults to the most commonly used C<.>.
 499
 500 =item unsafe
 501
 502 This Storage driver normally installs its own C<HandleError>, sets
 503 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 504 all database handles, including those supplied by a coderef.  It does this
 505 so that it can have consistent and useful error behavior.
 506
 507 If you set this option to a true value, Storage will not do its usual
 508 modifications to the database handle's attributes, and instead relies on
 509 the settings in your connect_info DBI options (or the values you set in
 510 your connection coderef, in the case that you are connecting via coderef).
 511
 512 Note that your custom settings can cause Storage to malfunction,
 513 especially if you set a C<HandleError> handler that suppresses exceptions
 514 and/or disable C<RaiseError>.
 515
 516 =item auto_savepoint
 517
 518 If this option is true, L<DBIx::Class> will use savepoints when nesting
 519 transactions, making it possible to recover from failure in the inner
 520 transaction without having to abort all outer transactions.
 521
 522 =item cursor_class
 523
 524 Use this argument to supply a cursor class other than the default
 525 L<DBIx::Class::Storage::DBI::Cursor>.
 526
 527 =back
 528
 529 Some real-life examples of arguments to L</connect_info> and
 530 L<DBIx::Class::Schema/connect>
 531
 532   # Simple SQLite connection
 533   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 534
 535   # Connect via subref
 536   ->connect_info([ sub { DBI->connect(...) } ]);
 537
 538   # Connect via subref in hashref
 539   ->connect_info([{
 540     dbh_maker => sub { DBI->connect(...) },
 541     on_connect_do => 'alter session ...',
 542   }]);
 543
 544   # A bit more complicated
 545   ->connect_info(
 546     [
 547       'dbi:Pg:dbname=foo',
 548       'postgres',
 549       'my_pg_password',
 550       { AutoCommit => 1 },
 551       { quote_char => q{"} },
 552     ]
 553   );
 554
 555   # Equivalent to the previous example
 556   ->connect_info(
 557     [
 558       'dbi:Pg:dbname=foo',
 559       'postgres',
 560       'my_pg_password',
 561       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 562     ]
 563   );
 564
 565   # Same, but with hashref as argument
 566   # See parse_connect_info for explanation
 567   ->connect_info(
 568     [{
 569       dsn         => 'dbi:Pg:dbname=foo',
 570       user        => 'postgres',
 571       password    => 'my_pg_password',
 572       AutoCommit  => 1,
 573       quote_char  => q{"},
 574       name_sep    => q{.},
 575     }]
 576   );
 577
 578   # Subref + DBIx::Class-specific connection options
 579   ->connect_info(
 580     [
 581       sub { DBI->connect(...) },
 582       {
 583           quote_char => q{`},
 584           name_sep => q{@},
 585           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 586           disable_sth_caching => 1,
 587       },
 588     ]
 589   );
 590
 591
 592
 593 =cut
 594
 595 sub connect_info {
 596   my ($self, $info) = @_;
 597
 598   return $self->_connect_info if !$info;
 599
 600   $self->_connect_info($info); # copy for _connect_info
 601
 602   $info = $self->_normalize_connect_info($info)
 603     if ref $info eq 'ARRAY';
 604
 605   for my $storage_opt (keys %{ $info->{storage_options} }) {
 606     my $value = $info->{storage_options}{$storage_opt};
 607
 608     $self->$storage_opt($value);
 609   }
 610
 611   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 612   #  the new set of options
 613   $self->_sql_maker(undef);
 614   $self->_sql_maker_opts({});
 615
 616   for my $sql_maker_opt (keys %{ $info->{sql_maker_options} }) {
 617     my $value = $info->{sql_maker_options}{$sql_maker_opt};
 618
 619     $self->_sql_maker_opts->{$sql_maker_opt} = $value;
 620   }
 621
 622   my %attrs = (
 623     %{ $self->_default_dbi_connect_attributes || {} },
 624     %{ $info->{attributes} || {} },
 625   );
 626
 627   my @args = @{ $info->{arguments} };
 628
 629   if (keys %attrs and ref $args[0] ne 'CODE') {
 630     carp_unique (
 631         'You provided explicit AutoCommit => 0 in your connection_info. '
 632       . 'This is almost universally a bad idea (see the footnotes of '
 633       . 'DBIx::Class::Storage::DBI for more info). If you still want to '
 634       . 'do this you can set $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK} to disable '
 635       . 'this warning.'
 636     ) if ! $attrs{AutoCommit} and ! $ENV{DBIC_UNSAFE_AUTOCOMMIT_OK};
 637
 638     push @args, \%attrs if keys %attrs;
 639   }
 640   $self->_dbi_connect_info(\@args);
 641
 642   # FIXME - dirty:
 643   # save attributes them in a separate accessor so they are always
 644   # introspectable, even in case of a CODE $dbhmaker
 645   $self->_dbic_connect_attributes (\%attrs);
 646
 647   return $self->_connect_info;
 648 }
 649
 650 sub _normalize_connect_info {
 651   my ($self, $info_arg) = @_;
 652   my %info;
 653
 654   my @args = @$info_arg;  # take a shallow copy for further mutilation
 655
 656   # combine/pre-parse arguments depending on invocation style
 657
 658   my %attrs;
 659   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 660     %attrs = %{ $args[1] || {} };
 661     @args = $args[0];
 662   }
 663   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 664     %attrs = %{$args[0]};
 665     @args = ();
 666     if (my $code = delete $attrs{dbh_maker}) {
 667       @args = $code;
 668
 669       my @ignored = grep { delete $attrs{$_} } (qw/dsn user password/);
 670       if (@ignored) {
 671         carp sprintf (
 672             'Attribute(s) %s in connect_info were ignored, as they can not be applied '
 673           . "to the result of 'dbh_maker'",
 674
 675           join (', ', map { "'$_'" } (@ignored) ),
 676         );
 677       }
 678     }
 679     else {
 680       @args = delete @attrs{qw/dsn user password/};
 681     }
 682   }
 683   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 684     %attrs = (
 685       % { $args[3] || {} },
 686       % { $args[4] || {} },
 687     );
 688     @args = @args[0,1,2];
 689   }
 690
 691   $info{arguments} = \@args;
 692
 693   my @storage_opts = grep exists $attrs{$_},
 694     @storage_options, 'cursor_class';
 695
 696   @{ $info{storage_options} }{@storage_opts} =
 697     delete @attrs{@storage_opts} if @storage_opts;
 698
 699   my @sql_maker_opts = grep exists $attrs{$_},
 700     qw/limit_dialect quote_char name_sep quote_names/;
 701
 702   @{ $info{sql_maker_options} }{@sql_maker_opts} =
 703     delete @attrs{@sql_maker_opts} if @sql_maker_opts;
 704
 705   $info{attributes} = \%attrs if %attrs;
 706
 707   return \%info;
 708 }
 709
 710 sub _default_dbi_connect_attributes () {
 711   +{
 712     AutoCommit => 1,
 713     PrintError => 0,
 714     RaiseError => 1,
 715     ShowErrorStatement => 1,
 716   };
 717 }
 718
 719 =head2 on_connect_do
 720
 721 This method is deprecated in favour of setting via L</connect_info>.
 722
 723 =cut
 724
 725 =head2 on_disconnect_do
 726
 727 This method is deprecated in favour of setting via L</connect_info>.
 728
 729 =cut
 730
 731 sub _parse_connect_do {
 732   my ($self, $type) = @_;
 733
 734   my $val = $self->$type;
 735   return () if not defined $val;
 736
 737   my @res;
 738
 739   if (not ref($val)) {
 740     push @res, [ 'do_sql', $val ];
 741   } elsif (ref($val) eq 'CODE') {
 742     push @res, $val;
 743   } elsif (ref($val) eq 'ARRAY') {
 744     push @res, map { [ 'do_sql', $_ ] } @$val;
 745   } else {
 746     $self->throw_exception("Invalid type for $type: ".ref($val));
 747   }
 748
 749   return \@res;
 750 }
 751
 752 =head2 dbh_do
 753
 754 Arguments: ($subref | $method_name), @extra_coderef_args?
 755
 756 Execute the given $subref or $method_name using the new exception-based
 757 connection management.
 758
 759 The first two arguments will be the storage object that C<dbh_do> was called
 760 on and a database handle to use.  Any additional arguments will be passed
 761 verbatim to the called subref as arguments 2 and onwards.
 762
 763 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 764 exception handling and reconnection (or failover in future subclasses).
 765
 766 Your subref should have no side-effects outside of the database, as
 767 there is the potential for your subref to be partially double-executed
 768 if the database connection was stale/dysfunctional.
 769
 770 Example:
 771
 772   my @stuff = $schema->storage->dbh_do(
 773     sub {
 774       my ($storage, $dbh, @cols) = @_;
 775       my $cols = join(q{, }, @cols);
 776       $dbh->selectrow_array("SELECT $cols FROM foo");
 777     },
 778     @column_list
 779   );
 780
 781 =cut
 782
 783 sub dbh_do {
 784   my $self = shift;
 785   my $run_target = shift;
 786
 787   # short circuit when we know there is no need for a runner
 788   #
 789   # FIXME - asumption may be wrong
 790   # the rationale for the txn_depth check is that if this block is a part
 791   # of a larger transaction, everything up to that point is screwed anyway
 792   return $self->$run_target($self->_get_dbh, @_)
 793     if $self->{_in_do_block} or $self->transaction_depth;
 794
 795   # take a ref instead of a copy, to preserve @_ aliasing
 796   # semantics within the coderef, but only if needed
 797   # (pseudoforking doesn't like this trick much)
 798   my $args = @_ ? \@_ : [];
 799
 800   DBIx::Class::Storage::BlockRunner->new(
 801     storage => $self,
 802     run_code => sub { $self->$run_target ($self->_get_dbh, @$args ) },
 803     wrap_txn => 0,
 804     retry_handler => sub { ! ( $_[0]->retried_count or $_[0]->storage->connected ) },
 805   )->run;
 806 }
 807
 808 sub txn_do {
 809   $_[0]->_get_dbh; # connects or reconnects on pid change, necessary to grab correct txn_depth
 810   shift->next::method(@_);
 811 }
 812
 813 =head2 disconnect
 814
 815 Our C<disconnect> method also performs a rollback first if the
 816 database is not in C<AutoCommit> mode.
 817
 818 =cut
 819
 820 sub disconnect {
 821   my ($self) = @_;
 822
 823   if( $self->_dbh ) {
 824     my @actions;
 825
 826     push @actions, ( $self->on_disconnect_call || () );
 827     push @actions, $self->_parse_connect_do ('on_disconnect_do');
 828
 829     $self->_do_connection_actions(disconnect_call_ => $_) for @actions;
 830
 831     # stops the "implicit rollback on disconnect" warning
 832     $self->_exec_txn_rollback unless $self->_dbh_autocommit;
 833
 834     %{ $self->_dbh->{CachedKids} } = ();
 835     $self->_dbh->disconnect;
 836     $self->_dbh(undef);
 837   }
 838 }
 839
 840 =head2 with_deferred_fk_checks
 841
 842 =over 4
 843
 844 =item Arguments: C<$coderef>
 845
 846 =item Return Value: The return value of $coderef
 847
 848 =back
 849
 850 Storage specific method to run the code ref with FK checks deferred or
 851 in MySQL's case disabled entirely.
 852
 853 =cut
 854
 855 # Storage subclasses should override this
 856 sub with_deferred_fk_checks {
 857   my ($self, $sub) = @_;
 858   $sub->();
 859 }
 860
 861 =head2 connected
 862
 863 =over
 864
 865 =item Arguments: none
 866
 867 =item Return Value: 1|0
 868
 869 =back
 870
 871 Verifies that the current database handle is active and ready to execute
 872 an SQL statement (e.g. the connection did not get stale, server is still
 873 answering, etc.) This method is used internally by L</dbh>.
 874
 875 =cut
 876
 877 sub connected {
 878   my $self = shift;
 879   return 0 unless $self->_seems_connected;
 880
 881   #be on the safe side
 882   local $self->_dbh->{RaiseError} = 1;
 883
 884   return $self->_ping;
 885 }
 886
 887 sub _seems_connected {
 888   my $self = shift;
 889
 890   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 891
 892   my $dbh = $self->_dbh
 893     or return 0;
 894
 895   return $dbh->FETCH('Active');
 896 }
 897
 898 sub _ping {
 899   my $self = shift;
 900
 901   my $dbh = $self->_dbh or return 0;
 902
 903   return $dbh->ping;
 904 }
 905
 906 sub ensure_connected {
 907   my ($self) = @_;
 908
 909   unless ($self->connected) {
 910     $self->_populate_dbh;
 911   }
 912 }
 913
 914 =head2 dbh
 915
 916 Returns a C<$dbh> - a data base handle of class L<DBI>. The returned handle
 917 is guaranteed to be healthy by implicitly calling L</connected>, and if
 918 necessary performing a reconnection before returning. Keep in mind that this
 919 is very B<expensive> on some database engines. Consider using L</dbh_do>
 920 instead.
 921
 922 =cut
 923
 924 sub dbh {
 925   my ($self) = @_;
 926
 927   if (not $self->_dbh) {
 928     $self->_populate_dbh;
 929   } else {
 930     $self->ensure_connected;
 931   }
 932   return $self->_dbh;
 933 }
 934
 935 # this is the internal "get dbh or connect (don't check)" method
 936 sub _get_dbh {
 937   my $self = shift;
 938   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
 939   $self->_populate_dbh unless $self->_dbh;
 940   return $self->_dbh;
 941 }
 942
 943 sub sql_maker {
 944   my ($self) = @_;
 945   unless ($self->_sql_maker) {
 946     my $sql_maker_class = $self->sql_maker_class;
 947
 948     my %opts = %{$self->_sql_maker_opts||{}};
 949     my $dialect =
 950       $opts{limit_dialect}
 951         ||
 952       $self->sql_limit_dialect
 953         ||
 954       do {
 955         my $s_class = (ref $self) || $self;
 956         carp_unique (
 957           "Your storage class ($s_class) does not set sql_limit_dialect and you "
 958         . 'have not supplied an explicit limit_dialect in your connection_info. '
 959         . 'DBIC will attempt to use the GenericSubQ dialect, which works on most '
 960         . 'databases but can be (and often is) painfully slow. '
 961         . "Please file an RT ticket against '$s_class'"
 962         ) if $self->_dbi_connect_info->[0];
 963
 964         'GenericSubQ';
 965       }
 966     ;
 967
 968     my ($quote_char, $name_sep);
 969
 970     if ($opts{quote_names}) {
 971       $quote_char = (delete $opts{quote_char}) || $self->sql_quote_char || do {
 972         my $s_class = (ref $self) || $self;
 973         carp_unique (
 974           "You requested 'quote_names' but your storage class ($s_class) does "
 975         . 'not explicitly define a default sql_quote_char and you have not '
 976         . 'supplied a quote_char as part of your connection_info. DBIC will '
 977         .q{default to the ANSI SQL standard quote '"', which works most of }
 978         . "the time. Please file an RT ticket against '$s_class'."
 979         );
 980
 981         '"'; # RV
 982       };
 983
 984       $name_sep = (delete $opts{name_sep}) || $self->sql_name_sep;
 985     }
 986
 987     $self->_sql_maker($sql_maker_class->new(
 988       bindtype=>'columns',
 989       array_datatypes => 1,
 990       limit_dialect => $dialect,
 991       ($quote_char ? (quote_char => $quote_char) : ()),
 992       name_sep => ($name_sep || '.'),
 993       %opts,
 994     ));
 995   }
 996   return $self->_sql_maker;
 997 }
 998
 999 # nothing to do by default
1000 sub _rebless {}
1001 sub _init {}
1002
1003 sub _populate_dbh {
1004   my ($self) = @_;
1005
1006   my @info = @{$self->_dbi_connect_info || []};
1007   $self->_dbh(undef); # in case ->connected failed we might get sent here
1008   $self->_dbh_details({}); # reset everything we know
1009
1010   $self->_dbh($self->_connect(@info));
1011
1012   $self->_conn_pid($$) unless DBIx::Class::_ENV_::BROKEN_FORK; # on win32 these are in fact threads
1013
1014   $self->_determine_driver;
1015
1016   # Always set the transaction depth on connect, since
1017   #  there is no transaction in progress by definition
1018   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1019
1020   $self->_run_connection_actions unless $self->{_in_determine_driver};
1021 }
1022
1023 sub _run_connection_actions {
1024   my $self = shift;
1025   my @actions;
1026
1027   push @actions, ( $self->on_connect_call || () );
1028   push @actions, $self->_parse_connect_do ('on_connect_do');
1029
1030   $self->_do_connection_actions(connect_call_ => $_) for @actions;
1031 }
1032
1033
1034
1035 sub set_use_dbms_capability {
1036   $_[0]->set_inherited ($_[1], $_[2]);
1037 }
1038
1039 sub get_use_dbms_capability {
1040   my ($self, $capname) = @_;
1041
1042   my $use = $self->get_inherited ($capname);
1043   return defined $use
1044     ? $use
1045     : do { $capname =~ s/^_use_/_supports_/; $self->get_dbms_capability ($capname) }
1046   ;
1047 }
1048
1049 sub set_dbms_capability {
1050   $_[0]->_dbh_details->{capability}{$_[1]} = $_[2];
1051 }
1052
1053 sub get_dbms_capability {
1054   my ($self, $capname) = @_;
1055
1056   my $cap = $self->_dbh_details->{capability}{$capname};
1057
1058   unless (defined $cap) {
1059     if (my $meth = $self->can ("_determine$capname")) {
1060       $cap = $self->$meth ? 1 : 0;
1061     }
1062     else {
1063       $cap = 0;
1064     }
1065
1066     $self->set_dbms_capability ($capname, $cap);
1067   }
1068
1069   return $cap;
1070 }
1071
1072 sub _server_info {
1073   my $self = shift;
1074
1075   my $info;
1076   unless ($info = $self->_dbh_details->{info}) {
1077
1078     $info = {};
1079
1080     my $server_version = try {
1081       $self->_get_server_version
1082     } catch {
1083       # driver determination *may* use this codepath
1084       # in which case we must rethrow
1085       $self->throw_exception($_) if $self->{_in_determine_driver};
1086
1087       # $server_version on failure
1088       undef;
1089     };
1090
1091     if (defined $server_version) {
1092       $info->{dbms_version} = $server_version;
1093
1094       my ($numeric_version) = $server_version =~ /^([\d\.]+)/;
1095       my @verparts = split (/\./, $numeric_version);
1096       if (
1097         @verparts
1098           &&
1099         $verparts[0] <= 999
1100       ) {
1101         # consider only up to 3 version parts, iff not more than 3 digits
1102         my @use_parts;
1103         while (@verparts && @use_parts < 3) {
1104           my $p = shift @verparts;
1105           last if $p > 999;
1106           push @use_parts, $p;
1107         }
1108         push @use_parts, 0 while @use_parts < 3;
1109
1110         $info->{normalized_dbms_version} = sprintf "%d.%03d%03d", @use_parts;
1111       }
1112     }
1113
1114     $self->_dbh_details->{info} = $info;
1115   }
1116
1117   return $info;
1118 }
1119
1120 sub _get_server_version {
1121   shift->_dbh_get_info('SQL_DBMS_VER');
1122 }
1123
1124 sub _dbh_get_info {
1125   my ($self, $info) = @_;
1126
1127   if ($info =~ /[^0-9]/) {
1128     require DBI::Const::GetInfoType;
1129     $info = $DBI::Const::GetInfoType::GetInfoType{$info};
1130     $self->throw_exception("Info type '$_[1]' not provided by DBI::Const::GetInfoType")
1131       unless defined $info;
1132   }
1133
1134   $self->_get_dbh->get_info($info);
1135 }
1136
1137 sub _describe_connection {
1138   require DBI::Const::GetInfoReturn;
1139
1140   my $self = shift;
1141   $self->ensure_connected;
1142
1143   my $res = {
1144     DBIC_DSN => $self->_dbi_connect_info->[0],
1145     DBI_VER => DBI->VERSION,
1146     DBIC_VER => DBIx::Class->VERSION,
1147     DBIC_DRIVER => ref $self,
1148   };
1149
1150   for my $inf (
1151     #keys %DBI::Const::GetInfoType::GetInfoType,
1152     qw/
1153       SQL_CURSOR_COMMIT_BEHAVIOR
1154       SQL_CURSOR_ROLLBACK_BEHAVIOR
1155       SQL_CURSOR_SENSITIVITY
1156       SQL_DATA_SOURCE_NAME
1157       SQL_DBMS_NAME
1158       SQL_DBMS_VER
1159       SQL_DEFAULT_TXN_ISOLATION
1160       SQL_DM_VER
1161       SQL_DRIVER_NAME
1162       SQL_DRIVER_ODBC_VER
1163       SQL_DRIVER_VER
1164       SQL_EXPRESSIONS_IN_ORDERBY
1165       SQL_GROUP_BY
1166       SQL_IDENTIFIER_CASE
1167       SQL_IDENTIFIER_QUOTE_CHAR
1168       SQL_MAX_CATALOG_NAME_LEN
1169       SQL_MAX_COLUMN_NAME_LEN
1170       SQL_MAX_IDENTIFIER_LEN
1171       SQL_MAX_TABLE_NAME_LEN
1172       SQL_MULTIPLE_ACTIVE_TXN
1173       SQL_MULT_RESULT_SETS
1174       SQL_NEED_LONG_DATA_LEN
1175       SQL_NON_NULLABLE_COLUMNS
1176       SQL_ODBC_VER
1177       SQL_QUALIFIER_NAME_SEPARATOR
1178       SQL_QUOTED_IDENTIFIER_CASE
1179       SQL_TXN_CAPABLE
1180       SQL_TXN_ISOLATION_OPTION
1181     /
1182   ) {
1183     # some drivers barf on things they do not know about instead
1184     # of returning undef
1185     my $v = try { $self->_dbh_get_info($inf) };
1186     next unless defined $v;
1187
1188     #my $key = sprintf( '%s(%s)', $inf, $DBI::Const::GetInfoType::GetInfoType{$inf} );
1189     my $expl = DBI::Const::GetInfoReturn::Explain($inf, $v);
1190     $res->{$inf} = DBI::Const::GetInfoReturn::Format($inf, $v) . ( $expl ? " ($expl)" : '' );
1191   }
1192
1193   $res;
1194 }
1195
1196 sub _determine_driver {
1197   my ($self) = @_;
1198
1199   if ((not $self->_driver_determined) && (not $self->{_in_determine_driver})) {
1200     my $started_connected = 0;
1201     local $self->{_in_determine_driver} = 1;
1202
1203     if (ref($self) eq __PACKAGE__) {
1204       my $driver;
1205       if ($self->_dbh) { # we are connected
1206         $driver = $self->_dbh->{Driver}{Name};
1207         $started_connected = 1;
1208       }
1209       else {
1210         # if connect_info is a CODEREF, we have no choice but to connect
1211         if (ref $self->_dbi_connect_info->[0] &&
1212             reftype $self->_dbi_connect_info->[0] eq 'CODE') {
1213           $self->_populate_dbh;
1214           $driver = $self->_dbh->{Driver}{Name};
1215         }
1216         else {
1217           # try to use dsn to not require being connected, the driver may still
1218           # force a connection in _rebless to determine version
1219           # (dsn may not be supplied at all if all we do is make a mock-schema)
1220           my $dsn = $self->_dbi_connect_info->[0] || $ENV{DBI_DSN} || '';
1221           ($driver) = $dsn =~ /dbi:([^:]+):/i;
1222           $driver ||= $ENV{DBI_DRIVER};
1223         }
1224       }
1225
1226       if ($driver) {
1227         my $storage_class = "DBIx::Class::Storage::DBI::${driver}";
1228         if ($self->load_optional_class($storage_class)) {
1229           mro::set_mro($storage_class, 'c3');
1230           bless $self, $storage_class;
1231           $self->_rebless();
1232         }
1233         else {
1234           $self->_warn_undetermined_driver(
1235             'This version of DBIC does not yet seem to supply a driver for '
1236           . "your particular RDBMS and/or connection method ('$driver')."
1237           );
1238         }
1239       }
1240       else {
1241         $self->_warn_undetermined_driver(
1242           'Unable to extract a driver name from connect info - this '
1243         . 'should not have happened.'
1244         );
1245       }
1246     }
1247
1248     $self->_driver_determined(1);
1249
1250     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
1251
1252     if ($self->can('source_bind_attributes')) {
1253       $self->throw_exception(
1254         "Your storage subclass @{[ ref $self ]} provides (or inherits) the method "
1255       . 'source_bind_attributes() for which support has been removed as of Jan 2013. '
1256       . 'If you are not sure how to proceed please contact the development team via '
1257       . 'http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class.pm#GETTING_HELP/SUPPORT'
1258       );
1259     }
1260
1261     $self->_init; # run driver-specific initializations
1262
1263     $self->_run_connection_actions
1264         if !$started_connected && defined $self->_dbh;
1265   }
1266 }
1267
1268 sub _determine_connector_driver {
1269   my ($self, $conn) = @_;
1270
1271   my $dbtype = $self->_dbh_get_info('SQL_DBMS_NAME');
1272
1273   if (not $dbtype) {
1274     $self->_warn_undetermined_driver(
1275       'Unable to retrieve RDBMS type (SQL_DBMS_NAME) of the engine behind your '
1276     . "$conn connector - this should not have happened."
1277     );
1278     return;
1279   }
1280
1281   $dbtype =~ s/\W/_/gi;
1282
1283   my $subclass = "DBIx::Class::Storage::DBI::${conn}::${dbtype}";
1284   return if $self->isa($subclass);
1285
1286   if ($self->load_optional_class($subclass)) {
1287     bless $self, $subclass;
1288     $self->_rebless;
1289   }
1290   else {
1291     $self->_warn_undetermined_driver(
1292       'This version of DBIC does not yet seem to supply a driver for '
1293     . "your particular RDBMS and/or connection method ('$conn/$dbtype')."
1294     );
1295   }
1296 }
1297
1298 sub _warn_undetermined_driver {
1299   my ($self, $msg) = @_;
1300
1301   require Data::Dumper::Concise;
1302
1303   carp_once ($msg . ' While we will attempt to continue anyway, the results '
1304   . 'are likely to be underwhelming. Please upgrade DBIC, and if this message '
1305   . "does not go away, file a bugreport including the following info:\n"
1306   . Data::Dumper::Concise::Dumper($self->_describe_connection)
1307   );
1308 }
1309
1310 sub _do_connection_actions {
1311   my $self          = shift;
1312   my $method_prefix = shift;
1313   my $call          = shift;
1314
1315   if (not ref($call)) {
1316     my $method = $method_prefix . $call;
1317     $self->$method(@_);
1318   } elsif (ref($call) eq 'CODE') {
1319     $self->$call(@_);
1320   } elsif (ref($call) eq 'ARRAY') {
1321     if (ref($call->[0]) ne 'ARRAY') {
1322       $self->_do_connection_actions($method_prefix, $_) for @$call;
1323     } else {
1324       $self->_do_connection_actions($method_prefix, @$_) for @$call;
1325     }
1326   } else {
1327     $self->throw_exception (sprintf ("Don't know how to process conection actions of type '%s'", ref($call)) );
1328   }
1329
1330   return $self;
1331 }
1332
1333 sub connect_call_do_sql {
1334   my $self = shift;
1335   $self->_do_query(@_);
1336 }
1337
1338 sub disconnect_call_do_sql {
1339   my $self = shift;
1340   $self->_do_query(@_);
1341 }
1342
1343 # override in db-specific backend when necessary
1344 sub connect_call_datetime_setup { 1 }
1345
1346 sub _do_query {
1347   my ($self, $action) = @_;
1348
1349   if (ref $action eq 'CODE') {
1350     $action = $action->($self);
1351     $self->_do_query($_) foreach @$action;
1352   }
1353   else {
1354     # Most debuggers expect ($sql, @bind), so we need to exclude
1355     # the attribute hash which is the second argument to $dbh->do
1356     # furthermore the bind values are usually to be presented
1357     # as named arrayref pairs, so wrap those here too
1358     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
1359     my $sql = shift @do_args;
1360     my $attrs = shift @do_args;
1361     my @bind = map { [ undef, $_ ] } @do_args;
1362
1363     $self->dbh_do(sub {
1364       $_[0]->_query_start($sql, \@bind);
1365       $_[1]->do($sql, $attrs, @do_args);
1366       $_[0]->_query_end($sql, \@bind);
1367     });
1368   }
1369
1370   return $self;
1371 }
1372
1373 sub _connect {
1374   my ($self, @info) = @_;
1375
1376   $self->throw_exception("You did not provide any connection_info")
1377     if ( ! defined $info[0] and ! $ENV{DBI_DSN} and ! $ENV{DBI_DRIVER} );
1378
1379   my ($old_connect_via, $dbh);
1380
1381   local $DBI::connect_via = 'connect' if $INC{'Apache/DBI.pm'} && $ENV{MOD_PERL};
1382
1383   try {
1384     if(ref $info[0] eq 'CODE') {
1385       $dbh = $info[0]->();
1386     }
1387     else {
1388       require DBI;
1389       $dbh = DBI->connect(@info);
1390     }
1391
1392     die $DBI::errstr unless $dbh;
1393
1394     die sprintf ("%s fresh DBI handle with a *false* 'Active' attribute. "
1395       . 'This handle is disconnected as far as DBIC is concerned, and we can '
1396       . 'not continue',
1397       ref $info[0] eq 'CODE'
1398         ? "Connection coderef $info[0] returned a"
1399         : 'DBI->connect($schema->storage->connect_info) resulted in a'
1400     ) unless $dbh->FETCH('Active');
1401
1402     # sanity checks unless asked otherwise
1403     unless ($self->unsafe) {
1404
1405       $self->throw_exception(
1406         'Refusing clobbering of {HandleError} installed on externally supplied '
1407        ."DBI handle $dbh. Either remove the handler or use the 'unsafe' attribute."
1408       ) if $dbh->{HandleError} and ref $dbh->{HandleError} ne '__DBIC__DBH__ERROR__HANDLER__';
1409
1410       # Default via _default_dbi_connect_attributes is 1, hence it was an explicit
1411       # request, or an external handle. Complain and set anyway
1412       unless ($dbh->{RaiseError}) {
1413         carp( ref $info[0] eq 'CODE'
1414
1415           ? "The 'RaiseError' of the externally supplied DBI handle is set to false. "
1416            ."DBIx::Class will toggle it back to true, unless the 'unsafe' connect "
1417            .'attribute has been supplied'
1418
1419           : 'RaiseError => 0 supplied in your connection_info, without an explicit '
1420            .'unsafe => 1. Toggling RaiseError back to true'
1421         );
1422
1423         $dbh->{RaiseError} = 1;
1424       }
1425
1426       # this odd anonymous coderef dereference is in fact really
1427       # necessary to avoid the unwanted effect described in perl5
1428       # RT#75792
1429       sub {
1430         my $weak_self = $_[0];
1431         weaken $weak_self;
1432
1433         # the coderef is blessed so we can distinguish it from externally
1434         # supplied handles (which must be preserved)
1435         $_[1]->{HandleError} = bless sub {
1436           if ($weak_self) {
1437             $weak_self->throw_exception("DBI Exception: $_[0]");
1438           }
1439           else {
1440             # the handler may be invoked by something totally out of
1441             # the scope of DBIC
1442             DBIx::Class::Exception->throw("DBI Exception (unhandled by DBIC, ::Schema GCed): $_[0]");
1443           }
1444         }, '__DBIC__DBH__ERROR__HANDLER__';
1445       }->($self, $dbh);
1446     }
1447   }
1448   catch {
1449     $self->throw_exception("DBI Connection failed: $_")
1450   };
1451
1452   $self->_dbh_autocommit($dbh->{AutoCommit});
1453   $dbh;
1454 }
1455
1456 sub txn_begin {
1457   my $self = shift;
1458
1459   # this means we have not yet connected and do not know the AC status
1460   # (e.g. coderef $dbh), need a full-fledged connection check
1461   if (! defined $self->_dbh_autocommit) {
1462     $self->ensure_connected;
1463   }
1464   # Otherwise simply connect or re-connect on pid changes
1465   else {
1466     $self->_get_dbh;
1467   }
1468
1469   $self->next::method(@_);
1470 }
1471
1472 sub _exec_txn_begin {
1473   my $self = shift;
1474
1475   # if the user is utilizing txn_do - good for him, otherwise we need to
1476   # ensure that the $dbh is healthy on BEGIN.
1477   # We do this via ->dbh_do instead of ->dbh, so that the ->dbh "ping"
1478   # will be replaced by a failure of begin_work itself (which will be
1479   # then retried on reconnect)
1480   if ($self->{_in_do_block}) {
1481     $self->_dbh->begin_work;
1482   } else {
1483     $self->dbh_do(sub { $_[1]->begin_work });
1484   }
1485 }
1486
1487 sub txn_commit {
1488   my $self = shift;
1489
1490   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1491   $self->throw_exception("Unable to txn_commit() on a disconnected storage")
1492     unless $self->_dbh;
1493
1494   # esoteric case for folks using external $dbh handles
1495   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1496     carp "Storage transaction_depth 0 does not match "
1497         ."false AutoCommit of $self->{_dbh}, attempting COMMIT anyway";
1498     $self->transaction_depth(1);
1499   }
1500
1501   $self->next::method(@_);
1502
1503   # if AutoCommit is disabled txn_depth never goes to 0
1504   # as a new txn is started immediately on commit
1505   $self->transaction_depth(1) if (
1506     !$self->transaction_depth
1507       and
1508     defined $self->_dbh_autocommit
1509       and
1510     ! $self->_dbh_autocommit
1511   );
1512 }
1513
1514 sub _exec_txn_commit {
1515   shift->_dbh->commit;
1516 }
1517
1518 sub txn_rollback {
1519   my $self = shift;
1520
1521   $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1522   $self->throw_exception("Unable to txn_rollback() on a disconnected storage")
1523     unless $self->_dbh;
1524
1525   # esoteric case for folks using external $dbh handles
1526   if (! $self->transaction_depth and ! $self->_dbh->FETCH('AutoCommit') ) {
1527     carp "Storage transaction_depth 0 does not match "
1528         ."false AutoCommit of $self->{_dbh}, attempting ROLLBACK anyway";
1529     $self->transaction_depth(1);
1530   }
1531
1532   $self->next::method(@_);
1533
1534   # if AutoCommit is disabled txn_depth never goes to 0
1535   # as a new txn is started immediately on commit
1536   $self->transaction_depth(1) if (
1537     !$self->transaction_depth
1538       and
1539     defined $self->_dbh_autocommit
1540       and
1541     ! $self->_dbh_autocommit
1542   );
1543 }
1544
1545 sub _exec_txn_rollback {
1546   shift->_dbh->rollback;
1547 }
1548
1549 # generate some identical methods
1550 for my $meth (qw/svp_begin svp_release svp_rollback/) {
1551   no strict qw/refs/;
1552   *{__PACKAGE__ ."::$meth"} = subname $meth => sub {
1553     my $self = shift;
1554     $self->_verify_pid unless DBIx::Class::_ENV_::BROKEN_FORK;
1555     $self->throw_exception("Unable to $meth() on a disconnected storage")
1556       unless $self->_dbh;
1557     $self->next::method(@_);
1558   };
1559 }
1560
1561 # This used to be the top-half of _execute.  It was split out to make it
1562 #  easier to override in NoBindVars without duping the rest.  It takes up
1563 #  all of _execute's args, and emits $sql, @bind.
1564 sub _prep_for_execute {
1565   #my ($self, $op, $ident, $args) = @_;
1566   return shift->_gen_sql_bind(@_)
1567 }
1568
1569 sub _gen_sql_bind {
1570   my ($self, $op, $ident, $args) = @_;
1571
1572   my ($colinfos, $from);
1573   if ( blessed($ident) ) {
1574     $from = $ident->from;
1575     $colinfos = $ident->columns_info;
1576   }
1577
1578   my ($sql, $bind);
1579   ($sql, @$bind) = $self->sql_maker->$op( ($from || $ident), @$args );
1580
1581   $bind = $self->_resolve_bindattrs(
1582     $ident, [ @{$args->[2]{bind}||[]}, @$bind ], $colinfos
1583   );
1584
1585   if (
1586     ! $ENV{DBIC_DT_SEARCH_OK}
1587       and
1588     $op eq 'select'
1589       and
1590     first {
1591       length ref $_->[1]
1592         and
1593       blessed($_->[1])
1594         and
1595       $_->[1]->isa('DateTime')
1596     } @$bind
1597   ) {
1598     carp_unique 'DateTime objects passed to search() are not supported '
1599       . 'properly (InflateColumn::DateTime formats and settings are not '
1600       . 'respected.) See "Formatting DateTime objects in queries" in '
1601       . 'DBIx::Class::Manual::Cookbook. To disable this warning for good '
1602       . 'set $ENV{DBIC_DT_SEARCH_OK} to true'
1603   }
1604
1605   return( $sql, $bind );
1606 }
1607
1608 sub _resolve_bindattrs {
1609   my ($self, $ident, $bind, $colinfos) = @_;
1610
1611   $colinfos ||= {};
1612
1613   my $resolve_bindinfo = sub {
1614     #my $infohash = shift;
1615
1616     %$colinfos = %{ $self->_resolve_column_info($ident) }
1617       unless keys %$colinfos;
1618
1619     my $ret;
1620     if (my $col = $_[0]->{dbic_colname}) {
1621       $ret = { %{$_[0]} };
1622
1623       $ret->{sqlt_datatype} ||= $colinfos->{$col}{data_type}
1624         if $colinfos->{$col}{data_type};
1625
1626       $ret->{sqlt_size} ||= $colinfos->{$col}{size}
1627         if $colinfos->{$col}{size};
1628     }
1629
1630     $ret || $_[0];
1631   };
1632
1633   return [ map {
1634     my $resolved =
1635       ( ref $_ ne 'ARRAY' or @$_ != 2 ) ? [ {}, $_ ]
1636     : ( ! defined $_->[0] )             ? [ {}, $_->[1] ]
1637     : (ref $_->[0] eq 'HASH')           ? [ (exists $_->[0]{dbd_attrs} or $_->[0]{sqlt_datatype})
1638                                               ? $_->[0]
1639                                               : $resolve_bindinfo->($_->[0])
1640                                             , $_->[1] ]
1641     : (ref $_->[0] eq 'SCALAR')         ? [ { sqlt_datatype => ${$_->[0]} }, $_->[1] ]
1642     :                                     [ $resolve_bindinfo->(
1643                                               { dbic_colname => $_->[0] }
1644                                             ), $_->[1] ]
1645     ;
1646
1647     if (
1648       ! exists $resolved->[0]{dbd_attrs}
1649         and
1650       ! $resolved->[0]{sqlt_datatype}
1651         and
1652       length ref $resolved->[1]
1653         and
1654       ! overload::Method($resolved->[1], '""')
1655     ) {
1656       require Data::Dumper;
1657       local $Data::Dumper::Maxdepth = 1;
1658       local $Data::Dumper::Terse = 1;
1659       local $Data::Dumper::Useqq = 1;
1660       local $Data::Dumper::Indent = 0;
1661       local $Data::Dumper::Pad = ' ';
1662       $self->throw_exception(
1663         'You must supply a datatype/bindtype (see DBIx::Class::ResultSet/DBIC BIND VALUES) '
1664       . 'for non-scalar value '. Data::Dumper::Dumper ($resolved->[1])
1665       );
1666     }
1667
1668     $resolved;
1669
1670   } @$bind ];
1671 }
1672
1673 sub _format_for_trace {
1674   #my ($self, $bind) = @_;
1675
1676   ### Turn @bind from something like this:
1677   ###   ( [ "artist", 1 ], [ \%attrs, 3 ] )
1678   ### to this:
1679   ###   ( "'1'", "'3'" )
1680
1681   map {
1682     defined( $_ && $_->[1] )
1683       ? qq{'$_->[1]'}
1684       : q{NULL}
1685   } @{$_[1] || []};
1686 }
1687
1688 sub _query_start {
1689   my ( $self, $sql, $bind ) = @_;
1690
1691   $self->debugobj->query_start( $sql, $self->_format_for_trace($bind) )
1692     if $self->debug;
1693 }
1694
1695 sub _query_end {
1696   my ( $self, $sql, $bind ) = @_;
1697
1698   $self->debugobj->query_end( $sql, $self->_format_for_trace($bind) )
1699     if $self->debug;
1700 }
1701
1702 sub _dbi_attrs_for_bind {
1703   my ($self, $ident, $bind) = @_;
1704
1705   my @attrs;
1706
1707   for (map { $_->[0] } @$bind) {
1708     push @attrs, do {
1709       if (exists $_->{dbd_attrs}) {
1710         $_->{dbd_attrs}
1711       }
1712       elsif($_->{sqlt_datatype}) {
1713         # cache the result in the dbh_details hash, as it can not change unless
1714         # we connect to something else
1715         my $cache = $self->_dbh_details->{_datatype_map_cache} ||= {};
1716         if (not exists $cache->{$_->{sqlt_datatype}}) {
1717           $cache->{$_->{sqlt_datatype}} = $self->bind_attribute_by_data_type($_->{sqlt_datatype}) || undef;
1718         }
1719         $cache->{$_->{sqlt_datatype}};
1720       }
1721       else {
1722         undef;  # always push something at this position
1723       }
1724     }
1725   }
1726
1727   return \@attrs;
1728 }
1729
1730 sub _execute {
1731   my ($self, $op, $ident, @args) = @_;
1732
1733   my ($sql, $bind) = $self->_prep_for_execute($op, $ident, \@args);
1734
1735   # not even a PID check - we do not care about the state of the _dbh.
1736   # All we need is to get the appropriate drivers loaded if they aren't
1737   # already so that the assumption in ad7c50fc26e holds
1738   $self->_populate_dbh unless $self->_dbh;
1739
1740   $self->dbh_do( _dbh_execute =>     # retry over disconnects
1741     $sql,
1742     $bind,
1743     $self->_dbi_attrs_for_bind($ident, $bind),
1744   );
1745 }
1746
1747 sub _dbh_execute {
1748   my ($self, $dbh, $sql, $bind, $bind_attrs) = @_;
1749
1750   $self->_query_start( $sql, $bind );
1751
1752   my $sth = $self->_bind_sth_params(
1753     $self->_prepare_sth($dbh, $sql),
1754     $bind,
1755     $bind_attrs,
1756   );
1757
1758   # Can this fail without throwing an exception anyways???
1759   my $rv = $sth->execute();
1760   $self->throw_exception(
1761     $sth->errstr || $sth->err || 'Unknown error: execute() returned false, but error flags were not set...'
1762   ) if !$rv;
1763
1764   $self->_query_end( $sql, $bind );
1765
1766   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1767 }
1768
1769 sub _prepare_sth {
1770   my ($self, $dbh, $sql) = @_;
1771
1772   # 3 is the if_active parameter which avoids active sth re-use
1773   my $sth = $self->disable_sth_caching
1774     ? $dbh->prepare($sql)
1775     : $dbh->prepare_cached($sql, {}, 3);
1776
1777   # XXX You would think RaiseError would make this impossible,
1778   #  but apparently that's not true :(
1779   $self->throw_exception(
1780     $dbh->errstr
1781       ||
1782     sprintf( "\$dbh->prepare() of '%s' through %s failed *silently* without "
1783             .'an exception and/or setting $dbh->errstr',
1784       length ($sql) > 20
1785         ? substr($sql, 0, 20) . '...'
1786         : $sql
1787       ,
1788       'DBD::' . $dbh->{Driver}{Name},
1789     )
1790   ) if !$sth;
1791
1792   $sth;
1793 }
1794
1795 sub _bind_sth_params {
1796   my ($self, $sth, $bind, $bind_attrs) = @_;
1797
1798   for my $i (0 .. $#$bind) {
1799     if (ref $bind->[$i][1] eq 'SCALAR') {  # any scalarrefs are assumed to be bind_inouts
1800       $sth->bind_param_inout(
1801         $i + 1, # bind params counts are 1-based
1802         $bind->[$i][1],
1803         $bind->[$i][0]{dbd_size} || $self->_max_column_bytesize($bind->[$i][0]), # size
1804         $bind_attrs->[$i],
1805       );
1806     }
1807     else {
1808       # FIXME SUBOPTIMAL - most likely this is not necessary at all
1809       # confirm with dbi-dev whether explicit stringification is needed
1810       my $v = ( length ref $bind->[$i][1] and overload::Method($bind->[$i][1], '""') )
1811         ? "$bind->[$i][1]"
1812         : $bind->[$i][1]
1813       ;
1814       $sth->bind_param(
1815         $i + 1,
1816         $v,
1817         $bind_attrs->[$i],
1818       );
1819     }
1820   }
1821
1822   $sth;
1823 }
1824
1825 sub _prefetch_autovalues {
1826   my ($self, $source, $colinfo, $to_insert) = @_;
1827
1828   my %values;
1829   for my $col (keys %$colinfo) {
1830     if (
1831       $colinfo->{$col}{auto_nextval}
1832         and
1833       (
1834         ! exists $to_insert->{$col}
1835           or
1836         ref $to_insert->{$col} eq 'SCALAR'
1837           or
1838         (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1839       )
1840     ) {
1841       $values{$col} = $self->_sequence_fetch(
1842         'NEXTVAL',
1843         ( $colinfo->{$col}{sequence} ||=
1844             $self->_dbh_get_autoinc_seq($self->_get_dbh, $source, $col)
1845         ),
1846       );
1847     }
1848   }
1849
1850   \%values;
1851 }
1852
1853 sub insert {
1854   my ($self, $source, $to_insert) = @_;
1855
1856   my $col_infos = $source->columns_info;
1857
1858   my $prefetched_values = $self->_prefetch_autovalues($source, $col_infos, $to_insert);
1859
1860   # fuse the values, but keep a separate list of prefetched_values so that
1861   # they can be fused once again with the final return
1862   $to_insert = { %$to_insert, %$prefetched_values };
1863
1864   # FIXME - we seem to assume undef values as non-supplied. This is wrong.
1865   # Investigate what does it take to s/defined/exists/
1866   my %pcols = map { $_ => 1 } $source->primary_columns;
1867   my (%retrieve_cols, $autoinc_supplied, $retrieve_autoinc_col);
1868   for my $col ($source->columns) {
1869     if ($col_infos->{$col}{is_auto_increment}) {
1870       $autoinc_supplied ||= 1 if defined $to_insert->{$col};
1871       $retrieve_autoinc_col ||= $col unless $autoinc_supplied;
1872     }
1873
1874     # nothing to retrieve when explicit values are supplied
1875     next if (defined $to_insert->{$col} and ! (
1876       ref $to_insert->{$col} eq 'SCALAR'
1877         or
1878       (ref $to_insert->{$col} eq 'REF' and ref ${$to_insert->{$col}} eq 'ARRAY')
1879     ));
1880
1881     # the 'scalar keys' is a trick to preserve the ->columns declaration order
1882     $retrieve_cols{$col} = scalar keys %retrieve_cols if (
1883       $pcols{$col}
1884         or
1885       $col_infos->{$col}{retrieve_on_insert}
1886     );
1887   };
1888
1889   local $self->{_autoinc_supplied_for_op} = $autoinc_supplied;
1890   local $self->{_perform_autoinc_retrieval} = $retrieve_autoinc_col;
1891
1892   my ($sqla_opts, @ir_container);
1893   if (%retrieve_cols and $self->_use_insert_returning) {
1894     $sqla_opts->{returning_container} = \@ir_container
1895       if $self->_use_insert_returning_bound;
1896
1897     $sqla_opts->{returning} = [
1898       sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols
1899     ];
1900   }
1901
1902   my ($rv, $sth) = $self->_execute('insert', $source, $to_insert, $sqla_opts);
1903
1904   my %returned_cols = %$to_insert;
1905   if (my $retlist = $sqla_opts->{returning}) {  # if IR is supported - we will get everything in one set
1906     @ir_container = try {
1907       local $SIG{__WARN__} = sub {};
1908       my @r = $sth->fetchrow_array;
1909       $sth->finish;
1910       @r;
1911     } unless @ir_container;
1912
1913     @returned_cols{@$retlist} = @ir_container if @ir_container;
1914   }
1915   else {
1916     # pull in PK if needed and then everything else
1917     if (my @missing_pri = grep { $pcols{$_} } keys %retrieve_cols) {
1918
1919       $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
1920         unless $self->can('last_insert_id');
1921
1922       my @pri_values = $self->last_insert_id($source, @missing_pri);
1923
1924       $self->throw_exception( "Can't get last insert id" )
1925         unless (@pri_values == @missing_pri);
1926
1927       @returned_cols{@missing_pri} = @pri_values;
1928       delete @retrieve_cols{@missing_pri};
1929     }
1930
1931     # if there is more left to pull
1932     if (%retrieve_cols) {
1933       $self->throw_exception(
1934         'Unable to retrieve additional columns without a Primary Key on ' . $source->source_name
1935       ) unless %pcols;
1936
1937       my @left_to_fetch = sort { $retrieve_cols{$a} <=> $retrieve_cols{$b} } keys %retrieve_cols;
1938
1939       my $cur = DBIx::Class::ResultSet->new($source, {
1940         where => { map { $_ => $returned_cols{$_} } (keys %pcols) },
1941         select => \@left_to_fetch,
1942       })->cursor;
1943
1944       @returned_cols{@left_to_fetch} = $cur->next;
1945
1946       $self->throw_exception('Duplicate row returned for PK-search after fresh insert')
1947         if scalar $cur->next;
1948     }
1949   }
1950
1951   return { %$prefetched_values, %returned_cols };
1952 }
1953
1954 sub insert_bulk {
1955   my ($self, $source, $cols, $data) = @_;
1956
1957   my @col_range = (0..$#$cols);
1958
1959   # FIXME SUBOPTIMAL - most likely this is not necessary at all
1960   # confirm with dbi-dev whether explicit stringification is needed
1961   #
1962   # forcibly stringify whatever is stringifiable
1963   # ResultSet::populate() hands us a copy - safe to mangle
1964   for my $r (0 .. $#$data) {
1965     for my $c (0 .. $#{$data->[$r]}) {
1966       $data->[$r][$c] = "$data->[$r][$c]"
1967         if ( length ref $data->[$r][$c] and overload::Method($data->[$r][$c], '""') );
1968     }
1969   }
1970
1971   my $colinfos = $source->columns_info($cols);
1972
1973   local $self->{_autoinc_supplied_for_op} =
1974     (first { $_->{is_auto_increment} } values %$colinfos)
1975       ? 1
1976       : 0
1977   ;
1978
1979   # get a slice type index based on first row of data
1980   # a "column" in this context may refer to more than one bind value
1981   # e.g. \[ '?, ?', [...], [...] ]
1982   #
1983   # construct the value type index - a description of values types for every
1984   # per-column slice of $data:
1985   #
1986   # nonexistent - nonbind literal
1987   # 0 - regular value
1988   # [] of bindattrs - resolved attribute(s) of bind(s) passed via literal+bind \[] combo
1989   #
1990   # also construct the column hash to pass to the SQL generator. For plain
1991   # (non literal) values - convert the members of the first row into a
1992   # literal+bind combo, with extra positional info in the bind attr hashref.
1993   # This will allow us to match the order properly, and is so contrived
1994   # because a user-supplied literal/bind (or something else specific to a
1995   # resultsource and/or storage driver) can inject extra binds along the
1996   # way, so one can't rely on "shift positions" ordering at all. Also we
1997   # can't just hand SQLA a set of some known "values" (e.g. hashrefs that
1998   # can be later matched up by address), because we want to supply a real
1999   # value on which perhaps e.g. datatype checks will be performed
2000   my ($proto_data, $value_type_by_col_idx);
2001   for my $i (@col_range) {
2002     my $colname = $cols->[$i];
2003     if (ref $data->[0][$i] eq 'SCALAR') {
2004       # no bind value at all - no type
2005
2006       $proto_data->{$colname} = $data->[0][$i];
2007     }
2008     elsif (ref $data->[0][$i] eq 'REF' and ref ${$data->[0][$i]} eq 'ARRAY' ) {
2009       # repack, so we don't end up mangling the original \[]
2010       my ($sql, @bind) = @${$data->[0][$i]};
2011
2012       # normalization of user supplied stuff
2013       my $resolved_bind = $self->_resolve_bindattrs(
2014         $source, \@bind, $colinfos,
2015       );
2016
2017       # store value-less (attrs only) bind info - we will be comparing all
2018       # supplied binds against this for sanity
2019       $value_type_by_col_idx->{$i} = [ map { $_->[0] } @$resolved_bind ];
2020
2021       $proto_data->{$colname} = \[ $sql, map { [
2022         # inject slice order to use for $proto_bind construction
2023           { %{$resolved_bind->[$_][0]}, _bind_data_slice_idx => $i, _literal_bind_subindex => $_+1 }
2024             =>
2025           $resolved_bind->[$_][1]
2026         ] } (0 .. $#bind)
2027       ];
2028     }
2029     else {
2030       $value_type_by_col_idx->{$i} = undef;
2031
2032       $proto_data->{$colname} = \[ '?', [
2033         { dbic_colname => $colname, _bind_data_slice_idx => $i }
2034           =>
2035         $data->[0][$i]
2036       ] ];
2037     }
2038   }
2039
2040   my ($sql, $proto_bind) = $self->_prep_for_execute (
2041     'insert',
2042     $source,
2043     [ $proto_data ],
2044   );
2045
2046   if (! @$proto_bind and keys %$value_type_by_col_idx) {
2047     # if the bindlist is empty and we had some dynamic binds, this means the
2048     # storage ate them away (e.g. the NoBindVars component) and interpolated
2049     # them directly into the SQL. This obviously can't be good for multi-inserts
2050     $self->throw_exception('Cannot insert_bulk without support for placeholders');
2051   }
2052
2053   # sanity checks
2054   # FIXME - devise a flag "no babysitting" or somesuch to shut this off
2055   #
2056   # use an error reporting closure for convenience (less to pass)
2057   my $bad_slice_report_cref = sub {
2058     my ($msg, $r_idx, $c_idx) = @_;
2059     $self->throw_exception(sprintf "%s for column '%s' in populate slice:\n%s",
2060       $msg,
2061       $cols->[$c_idx],
2062       do {
2063         require Data::Dumper::Concise;
2064         local $Data::Dumper::Maxdepth = 5;
2065         Data::Dumper::Concise::Dumper ({
2066           map { $cols->[$_] =>
2067             $data->[$r_idx][$_]
2068           } @col_range
2069         }),
2070       }
2071     );
2072   };
2073
2074   for my $col_idx (@col_range) {
2075     my $reference_val = $data->[0][$col_idx];
2076
2077     for my $row_idx (1..$#$data) {  # we are comparing against what we got from [0] above, hence start from 1
2078       my $val = $data->[$row_idx][$col_idx];
2079
2080       if (! exists $value_type_by_col_idx->{$col_idx}) { # literal no binds
2081         if (ref $val ne 'SCALAR') {
2082           $bad_slice_report_cref->(
2083             "Incorrect value (expecting SCALAR-ref \\'$$reference_val')",
2084             $row_idx,
2085             $col_idx,
2086           );
2087         }
2088         elsif ($$val ne $$reference_val) {
2089           $bad_slice_report_cref->(
2090             "Inconsistent literal SQL value (expecting \\'$$reference_val')",
2091             $row_idx,
2092             $col_idx,
2093           );
2094         }
2095       }
2096       elsif (! defined $value_type_by_col_idx->{$col_idx} ) {  # regular non-literal value
2097         if (ref $val eq 'SCALAR' or (ref $val eq 'REF' and ref $$val eq 'ARRAY') ) {
2098           $bad_slice_report_cref->("Literal SQL found where a plain bind value is expected", $row_idx, $col_idx);
2099         }
2100       }
2101       else {  # binds from a \[], compare type and attrs
2102         if (ref $val ne 'REF' or ref $$val ne 'ARRAY') {
2103           $bad_slice_report_cref->(
2104             "Incorrect value (expecting ARRAYREF-ref \\['${$reference_val}->[0]', ... ])",
2105             $row_idx,
2106             $col_idx,
2107           );
2108         }
2109         # start drilling down and bail out early on identical refs
2110         elsif (
2111           $reference_val != $val
2112             or
2113           $$reference_val != $$val
2114         ) {
2115           if (${$val}->[0] ne ${$reference_val}->[0]) {
2116             $bad_slice_report_cref->(
2117               "Inconsistent literal/bind SQL (expecting \\['${$reference_val}->[0]', ... ])",
2118               $row_idx,
2119               $col_idx,
2120             );
2121           }
2122           # need to check the bind attrs - a bind will happen only once for
2123           # the entire dataset, so any changes further down will be ignored.
2124           elsif (! Data::Compare::Compare(
2125             $value_type_by_col_idx->{$col_idx},
2126             [
2127               map
2128               { $_->[0] }
2129               @{$self->_resolve_bindattrs(
2130                 $source, [ @{$$val}[1 .. $#$$val] ], $colinfos,
2131               )}
2132             ],
2133           )) {
2134             $bad_slice_report_cref->(
2135               'Differing bind attributes on literal/bind values not supported',
2136               $row_idx,
2137               $col_idx,
2138             );
2139           }
2140         }
2141       }
2142     }
2143   }
2144
2145   # neither _dbh_execute_for_fetch, nor _dbh_execute_inserts_with_no_binds
2146   # are atomic (even if execute_for_fetch is a single call). Thus a safety
2147   # scope guard
2148   my $guard = $self->txn_scope_guard;
2149
2150   $self->_query_start( $sql, @$proto_bind ? [[undef => '__BULK_INSERT__' ]] : () );
2151   my $sth = $self->_prepare_sth($self->_dbh, $sql);
2152   my $rv = do {
2153     if (@$proto_bind) {
2154       # proto bind contains the information on which pieces of $data to pull
2155       # $cols is passed in only for prettier error-reporting
2156       $self->_dbh_execute_for_fetch( $source, $sth, $proto_bind, $cols, $data );
2157     }
2158     else {
2159       # bind_param_array doesn't work if there are no binds
2160       $self->_dbh_execute_inserts_with_no_binds( $sth, scalar @$data );
2161     }
2162   };
2163
2164   $self->_query_end( $sql, @$proto_bind ? [[ undef => '__BULK_INSERT__' ]] : () );
2165
2166   $guard->commit;
2167
2168   return wantarray ? ($rv, $sth, @$proto_bind) : $rv;
2169 }
2170
2171 # execute_for_fetch is capable of returning data just fine (it means it
2172 # can be used for INSERT...RETURNING and UPDATE...RETURNING. Since this
2173 # is the void-populate fast-path we will just ignore this altogether
2174 # for the time being.
2175 sub _dbh_execute_for_fetch {
2176   my ($self, $source, $sth, $proto_bind, $cols, $data) = @_;
2177
2178   my @idx_range = ( 0 .. $#$proto_bind );
2179
2180   # If we have any bind attributes to take care of, we will bind the
2181   # proto-bind data (which will never be used by execute_for_fetch)
2182   # However since column bindtypes are "sticky", this is sufficient
2183   # to get the DBD to apply the bindtype to all values later on
2184
2185   my $bind_attrs = $self->_dbi_attrs_for_bind($source, $proto_bind);
2186
2187   for my $i (@idx_range) {
2188     $sth->bind_param (
2189       $i+1, # DBI bind indexes are 1-based
2190       $proto_bind->[$i][1],
2191       $bind_attrs->[$i],
2192     ) if defined $bind_attrs->[$i];
2193   }
2194
2195   # At this point $data slots named in the _bind_data_slice_idx of
2196   # each piece of $proto_bind are either \[]s or plain values to be
2197   # passed in. Construct the dispensing coderef. *NOTE* the order
2198   # of $data will differ from this of the ?s in the SQL (due to
2199   # alphabetical ordering by colname). We actually do want to
2200   # preserve this behavior so that prepare_cached has a better
2201   # chance of matching on unrelated calls
2202
2203   my $fetch_row_idx = -1; # saner loop this way
2204   my $fetch_tuple = sub {
2205     return undef if ++$fetch_row_idx > $#$data;
2206
2207     return [ map { defined $_->{_literal_bind_subindex}
2208       ? ${ $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]}
2209          ->[ $_->{_literal_bind_subindex} ]
2210           ->[1]
2211       : $data->[ $fetch_row_idx ]->[ $_->{_bind_data_slice_idx} ]
2212     } map { $_->[0] } @$proto_bind];
2213   };
2214
2215   my $tuple_status = [];
2216   my ($rv, $err);
2217   try {
2218     $rv = $sth->execute_for_fetch(
2219       $fetch_tuple,
2220       $tuple_status,
2221     );
2222   }
2223   catch {
2224     $err = shift;
2225   };
2226
2227   # Not all DBDs are create equal. Some throw on error, some return
2228   # an undef $rv, and some set $sth->err - try whatever we can
2229   $err = ($sth->errstr || 'UNKNOWN ERROR ($sth->errstr is unset)') if (
2230     ! defined $err
2231       and
2232     ( !defined $rv or $sth->err )
2233   );
2234
2235   # Statement must finish even if there was an exception.
2236   try {
2237     $sth->finish
2238   }
2239   catch {
2240     $err = shift unless defined $err
2241   };
2242
2243   if (defined $err) {
2244     my $i = 0;
2245     ++$i while $i <= $#$tuple_status && !ref $tuple_status->[$i];
2246
2247     $self->throw_exception("Unexpected populate error: $err")
2248       if ($i > $#$tuple_status);
2249
2250     require Data::Dumper::Concise;
2251     $self->throw_exception(sprintf "execute_for_fetch() aborted with '%s' at populate slice:\n%s",
2252       ($tuple_status->[$i][1] || $err),
2253       Data::Dumper::Concise::Dumper( { map { $cols->[$_] => $data->[$i][$_] } (0 .. $#$cols) } ),
2254     );
2255   }
2256
2257   return $rv;
2258 }
2259
2260 sub _dbh_execute_inserts_with_no_binds {
2261   my ($self, $sth, $count) = @_;
2262
2263   my $err;
2264   try {
2265     my $dbh = $self->_get_dbh;
2266     local $dbh->{RaiseError} = 1;
2267     local $dbh->{PrintError} = 0;
2268
2269     $sth->execute foreach 1..$count;
2270   }
2271   catch {
2272     $err = shift;
2273   };
2274
2275   # Make sure statement is finished even if there was an exception.
2276   try {
2277     $sth->finish
2278   }
2279   catch {
2280     $err = shift unless defined $err;
2281   };
2282
2283   $self->throw_exception($err) if defined $err;
2284
2285   return $count;
2286 }
2287
2288 sub update {
2289   #my ($self, $source, @args) = @_;
2290   shift->_execute('update', @_);
2291 }
2292
2293
2294 sub delete {
2295   #my ($self, $source, @args) = @_;
2296   shift->_execute('delete', @_);
2297 }
2298
2299 sub _select {
2300   my $self = shift;
2301   $self->_execute($self->_select_args(@_));
2302 }
2303
2304 sub _select_args_to_query {
2305   my $self = shift;
2306
2307   $self->throw_exception(
2308     "Unable to generate limited query representation with 'software_limit' enabled"
2309   ) if ($_[3]->{software_limit} and ($_[3]->{offset} or $_[3]->{rows}) );
2310
2311   # my ($op, $ident, $select, $cond, $rs_attrs, $rows, $offset)
2312   #  = $self->_select_args($ident, $select, $cond, $attrs);
2313   my ($op, $ident, @args) =
2314     $self->_select_args(@_);
2315
2316   # my ($sql, $prepared_bind) = $self->_gen_sql_bind($op, $ident, [ $select, $cond, $rs_attrs, $rows, $offset ]);
2317   my ($sql, $bind) = $self->_gen_sql_bind($op, $ident, \@args);
2318
2319   # reuse the bind arrayref
2320   unshift @{$bind}, "($sql)";
2321   \$bind;
2322 }
2323
2324 sub _select_args {
2325   my ($self, $ident, $select, $where, $orig_attrs) = @_;
2326
2327   return (
2328     'select', @{$orig_attrs->{_sqlmaker_select_args}}
2329   ) if $orig_attrs->{_sqlmaker_select_args};
2330
2331   my $sql_maker = $self->sql_maker;
2332   my $alias2source = $self->_resolve_ident_sources ($ident);
2333
2334   my $attrs = {
2335     %$orig_attrs,
2336     select => $select,
2337     from => $ident,
2338     where => $where,
2339
2340     # limit dialects use this stuff
2341     # yes, some CDBICompat crap does not supply an {alias} >.<
2342     ( $orig_attrs->{alias} and $alias2source->{$orig_attrs->{alias}} )
2343       ? ( _rsroot_rsrc => $alias2source->{$orig_attrs->{alias}} )
2344       : ()
2345     ,
2346   };
2347
2348   # Sanity check the attributes (SQLMaker does it too, but
2349   # in case of a software_limit we'll never reach there)
2350   if (defined $attrs->{offset}) {
2351     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
2352       if ( $attrs->{offset} =~ /\D/ or $attrs->{offset} < 0 );
2353   }
2354
2355   if (defined $attrs->{rows}) {
2356     $self->throw_exception("The rows attribute must be a positive integer if present")
2357       if ( $attrs->{rows} =~ /\D/ or $attrs->{rows} <= 0 );
2358   }
2359   elsif ($attrs->{offset}) {
2360     # MySQL actually recommends this approach.  I cringe.
2361     $attrs->{rows} = $sql_maker->__max_int;
2362   }
2363
2364   # see if we will need to tear the prefetch apart to satisfy group_by == select
2365   # this is *extremely tricky* to get right, I am still not sure I did
2366   #
2367   my ($prefetch_needs_subquery, @limit_args);
2368
2369   if ( $attrs->{_grouped_by_distinct} and $attrs->{collapse} ) {
2370     # we already know there is a valid group_by and we know it is intended
2371     # to be based *only* on the main result columns
2372     # short circuit the group_by parsing below
2373     $prefetch_needs_subquery = 1;
2374   }
2375   elsif (
2376     # The rationale is that even if we do *not* have collapse, we still
2377     # need to wrap the core grouped select/group_by in a subquery
2378     # so that databases that care about group_by/select equivalence
2379     # are happy (this includes MySQL in strict_mode)
2380     # If any of the other joined tables are referenced in the group_by
2381     # however - the user is on their own
2382     ( $prefetch_needs_subquery or $attrs->{_related_results_construction} )
2383       and
2384     $attrs->{group_by}
2385       and
2386     @{$attrs->{group_by}}
2387       and
2388     my $grp_aliases = try { # try{} because $attrs->{from} may be unreadable
2389       $self->_resolve_aliastypes_from_select_args( $attrs->{from}, undef, undef, { group_by => $attrs->{group_by} } )
2390     }
2391   ) {
2392     # no aliases other than our own in group_by
2393     # if there are - do not allow subquery even if limit is present
2394     $prefetch_needs_subquery = ! scalar grep { $_ ne $attrs->{alias} } keys %{ $grp_aliases->{grouping} || {} };
2395   }
2396   elsif ( $attrs->{rows} && $attrs->{collapse} ) {
2397     # active collapse with a limit - that one is a no-brainer unless
2398     # overruled by a group_by above
2399     $prefetch_needs_subquery = 1;
2400   }
2401
2402   if ($prefetch_needs_subquery) {
2403     ($ident, $select, $where, $attrs) =
2404       $self->_adjust_select_args_for_complex_prefetch ($ident, $select, $where, $attrs);
2405   }
2406   elsif (! $attrs->{software_limit} ) {
2407     push @limit_args, (
2408       $attrs->{rows} || (),
2409       $attrs->{offset} || (),
2410     );
2411   }
2412
2413   # try to simplify the joinmap further (prune unreferenced type-single joins)
2414   if (
2415     ! $prefetch_needs_subquery  # already pruned
2416       and
2417     ref $ident
2418       and
2419     reftype $ident eq 'ARRAY'
2420       and
2421     @$ident != 1
2422   ) {
2423     ($ident, $attrs->{_aliastypes}) = $self->_prune_unused_joins ($ident, $select, $where, $attrs);
2424   }
2425
2426 ###
2427   # This would be the point to deflate anything found in $where
2428   # (and leave $attrs->{bind} intact). Problem is - inflators historically
2429   # expect a result object. And all we have is a resultsource (it is trivial
2430   # to extract deflator coderefs via $alias2source above).
2431   #
2432   # I don't see a way forward other than changing the way deflators are
2433   # invoked, and that's just bad...
2434 ###
2435
2436   return ( 'select', @{ $orig_attrs->{_sqlmaker_select_args} = [
2437     $ident, $select, $where, $attrs, @limit_args
2438   ]} );
2439 }
2440
2441 # Returns a counting SELECT for a simple count
2442 # query. Abstracted so that a storage could override
2443 # this to { count => 'firstcol' } or whatever makes
2444 # sense as a performance optimization
2445 sub _count_select {
2446   #my ($self, $source, $rs_attrs) = @_;
2447   return { count => '*' };
2448 }
2449
2450 =head2 select
2451
2452 =over 4
2453
2454 =item Arguments: $ident, $select, $condition, $attrs
2455
2456 =back
2457
2458 Handle a SQL select statement.
2459
2460 =cut
2461
2462 sub select {
2463   my $self = shift;
2464   my ($ident, $select, $condition, $attrs) = @_;
2465   return $self->cursor_class->new($self, \@_, $attrs);
2466 }
2467
2468 sub select_single {
2469   my $self = shift;
2470   my ($rv, $sth, @bind) = $self->_select(@_);
2471   my @row = $sth->fetchrow_array;
2472   my @nextrow = $sth->fetchrow_array if @row;
2473   if(@row && @nextrow) {
2474     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
2475   }
2476   # Need to call finish() to work round broken DBDs
2477   $sth->finish();
2478   return @row;
2479 }
2480
2481 =head2 sql_limit_dialect
2482
2483 This is an accessor for the default SQL limit dialect used by a particular
2484 storage driver. Can be overridden by supplying an explicit L</limit_dialect>
2485 to L<DBIx::Class::Schema/connect>. For a list of available limit dialects
2486 see L<DBIx::Class::SQLMaker::LimitDialects>.
2487
2488 =cut
2489
2490 sub _dbh_columns_info_for {
2491   my ($self, $dbh, $table) = @_;
2492
2493   if ($dbh->can('column_info')) {
2494     my %result;
2495     my $caught;
2496     try {
2497       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
2498       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
2499       $sth->execute();
2500       while ( my $info = $sth->fetchrow_hashref() ){
2501         my %column_info;
2502         $column_info{data_type}   = $info->{TYPE_NAME};
2503         $column_info{size}      = $info->{COLUMN_SIZE};
2504         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
2505         $column_info{default_value} = $info->{COLUMN_DEF};
2506         my $col_name = $info->{COLUMN_NAME};
2507         $col_name =~ s/^\"(.*)\"$/$1/;
2508
2509         $result{$col_name} = \%column_info;
2510       }
2511     } catch {
2512       $caught = 1;
2513     };
2514     return \%result if !$caught && scalar keys %result;
2515   }
2516
2517   my %result;
2518   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
2519   $sth->execute;
2520   my @columns = @{$sth->{NAME_lc}};
2521   for my $i ( 0 .. $#columns ){
2522     my %column_info;
2523     $column_info{data_type} = $sth->{TYPE}->[$i];
2524     $column_info{size} = $sth->{PRECISION}->[$i];
2525     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
2526
2527     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
2528       $column_info{data_type} = $1;
2529       $column_info{size}    = $2;
2530     }
2531
2532     $result{$columns[$i]} = \%column_info;
2533   }
2534   $sth->finish;
2535
2536   foreach my $col (keys %result) {
2537     my $colinfo = $result{$col};
2538     my $type_num = $colinfo->{data_type};
2539     my $type_name;
2540     if(defined $type_num && $dbh->can('type_info')) {
2541       my $type_info = $dbh->type_info($type_num);
2542       $type_name = $type_info->{TYPE_NAME} if $type_info;
2543       $colinfo->{data_type} = $type_name if $type_name;
2544     }
2545   }
2546
2547   return \%result;
2548 }
2549
2550 sub columns_info_for {
2551   my ($self, $table) = @_;
2552   $self->_dbh_columns_info_for ($self->_get_dbh, $table);
2553 }
2554
2555 =head2 last_insert_id
2556
2557 Return the row id of the last insert.
2558
2559 =cut
2560
2561 sub _dbh_last_insert_id {
2562     my ($self, $dbh, $source, $col) = @_;
2563
2564     my $id = try { $dbh->last_insert_id (undef, undef, $source->name, $col) };
2565
2566     return $id if defined $id;
2567
2568     my $class = ref $self;
2569     $self->throw_exception ("No storage specific _dbh_last_insert_id() method implemented in $class, and the generic DBI::last_insert_id() failed");
2570 }
2571
2572 sub last_insert_id {
2573   my $self = shift;
2574   $self->_dbh_last_insert_id ($self->_dbh, @_);
2575 }
2576
2577 =head2 _native_data_type
2578
2579 =over 4
2580
2581 =item Arguments: $type_name
2582
2583 =back
2584
2585 This API is B<EXPERIMENTAL>, will almost definitely change in the future, and
2586 currently only used by L<::AutoCast|DBIx::Class::Storage::DBI::AutoCast> and
2587 L<::Sybase::ASE|DBIx::Class::Storage::DBI::Sybase::ASE>.
2588
2589 The default implementation returns C<undef>, implement in your Storage driver if
2590 you need this functionality.
2591
2592 Should map types from other databases to the native RDBMS type, for example
2593 C<VARCHAR2> to C<VARCHAR>.
2594
2595 Types with modifiers should map to the underlying data type. For example,
2596 C<INTEGER AUTO_INCREMENT> should become C<INTEGER>.
2597
2598 Composite types should map to the container type, for example
2599 C<ENUM(foo,bar,baz)> becomes C<ENUM>.
2600
2601 =cut
2602
2603 sub _native_data_type {
2604   #my ($self, $data_type) = @_;
2605   return undef
2606 }
2607
2608 # Check if placeholders are supported at all
2609 sub _determine_supports_placeholders {
2610   my $self = shift;
2611   my $dbh  = $self->_get_dbh;
2612
2613   # some drivers provide a $dbh attribute (e.g. Sybase and $dbh->{syb_dynamic_supported})
2614   # but it is inaccurate more often than not
2615   return try {
2616     local $dbh->{PrintError} = 0;
2617     local $dbh->{RaiseError} = 1;
2618     $dbh->do('select ?', {}, 1);
2619     1;
2620   }
2621   catch {
2622     0;
2623   };
2624 }
2625
2626 # Check if placeholders bound to non-string types throw exceptions
2627 #
2628 sub _determine_supports_typeless_placeholders {
2629   my $self = shift;
2630   my $dbh  = $self->_get_dbh;
2631
2632   return try {
2633     local $dbh->{PrintError} = 0;
2634     local $dbh->{RaiseError} = 1;
2635     # this specifically tests a bind that is NOT a string
2636     $dbh->do('select 1 where 1 = ?', {}, 1);
2637     1;
2638   }
2639   catch {
2640     0;
2641   };
2642 }
2643
2644 =head2 sqlt_type
2645
2646 Returns the database driver name.
2647
2648 =cut
2649
2650 sub sqlt_type {
2651   shift->_get_dbh->{Driver}->{Name};
2652 }
2653
2654 =head2 bind_attribute_by_data_type
2655
2656 Given a datatype from column info, returns a database specific bind
2657 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
2658 let the database planner just handle it.
2659
2660 This method is always called after the driver has been determined and a DBI
2661 connection has been established. Therefore you can refer to C<DBI::$constant>
2662 and/or C<DBD::$driver::$constant> directly, without worrying about loading
2663 the correct modules.
2664
2665 =cut
2666
2667 sub bind_attribute_by_data_type {
2668     return;
2669 }
2670
2671 =head2 is_datatype_numeric
2672
2673 Given a datatype from column_info, returns a boolean value indicating if
2674 the current RDBMS considers it a numeric value. This controls how
2675 L<DBIx::Class::Row/set_column> decides whether to mark the column as
2676 dirty - when the datatype is deemed numeric a C<< != >> comparison will
2677 be performed instead of the usual C<eq>.
2678
2679 =cut
2680
2681 sub is_datatype_numeric {
2682   #my ($self, $dt) = @_;
2683
2684   return 0 unless $_[1];
2685
2686   $_[1] =~ /^ (?:
2687     numeric | int(?:eger)? | (?:tiny|small|medium|big)int | dec(?:imal)? | real | float | double (?: \s+ precision)? | (?:big)?serial
2688   ) $/ix;
2689 }
2690
2691
2692 =head2 create_ddl_dir
2693
2694 =over 4
2695
2696 =item Arguments: $schema, \@databases, $version, $directory, $preversion, \%sqlt_args
2697
2698 =back
2699
2700 Creates a SQL file based on the Schema, for each of the specified
2701 database engines in C<\@databases> in the given directory.
2702 (note: specify L<SQL::Translator> names, not L<DBI> driver names).
2703
2704 Given a previous version number, this will also create a file containing
2705 the ALTER TABLE statements to transform the previous schema into the
2706 current one. Note that these statements may contain C<DROP TABLE> or
2707 C<DROP COLUMN> statements that can potentially destroy data.
2708
2709 The file names are created using the C<ddl_filename> method below, please
2710 override this method in your schema if you would like a different file
2711 name format. For the ALTER file, the same format is used, replacing
2712 $version in the name with "$preversion-$version".
2713
2714 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
2715 The most common value for this would be C<< { add_drop_table => 1 } >>
2716 to have the SQL produced include a C<DROP TABLE> statement for each table
2717 created. For quoting purposes supply C<quote_identifiers>.
2718
2719 If no arguments are passed, then the following default values are assumed:
2720
2721 =over 4
2722
2723 =item databases  - ['MySQL', 'SQLite', 'PostgreSQL']
2724
2725 =item version    - $schema->schema_version
2726
2727 =item directory  - './'
2728
2729 =item preversion - <none>
2730
2731 =back
2732
2733 By default, C<\%sqlt_args> will have
2734
2735  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
2736
2737 merged with the hash passed in. To disable any of those features, pass in a
2738 hashref like the following
2739
2740  { ignore_constraint_names => 0, # ... other options }
2741
2742
2743 WARNING: You are strongly advised to check all SQL files created, before applying
2744 them.
2745
2746 =cut
2747
2748 sub create_ddl_dir {
2749   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
2750
2751   unless ($dir) {
2752     carp "No directory given, using ./\n";
2753     $dir = './';
2754   } else {
2755       -d $dir
2756         or
2757       (require File::Path and File::Path::mkpath (["$dir"]))  # mkpath does not like objects (i.e. Path::Class::Dir)
2758         or
2759       $self->throw_exception(
2760         "Failed to create '$dir': " . ($! || $@ || 'error unknown')
2761       );
2762   }
2763
2764   $self->throw_exception ("Directory '$dir' does not exist\n") unless(-d $dir);
2765
2766   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
2767   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
2768
2769   my $schema_version = $schema->schema_version || '1.x';
2770   $version ||= $schema_version;
2771
2772   $sqltargs = {
2773     add_drop_table => 1,
2774     ignore_constraint_names => 1,
2775     ignore_index_names => 1,
2776     %{$sqltargs || {}}
2777   };
2778
2779   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')) {
2780     $self->throw_exception("Can't create a ddl file without " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2781   }
2782
2783   my $sqlt = SQL::Translator->new( $sqltargs );
2784
2785   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
2786   my $sqlt_schema = $sqlt->translate({ data => $schema })
2787     or $self->throw_exception ($sqlt->error);
2788
2789   foreach my $db (@$databases) {
2790     $sqlt->reset();
2791     $sqlt->{schema} = $sqlt_schema;
2792     $sqlt->producer($db);
2793
2794     my $file;
2795     my $filename = $schema->ddl_filename($db, $version, $dir);
2796     if (-e $filename && ($version eq $schema_version )) {
2797       # if we are dumping the current version, overwrite the DDL
2798       carp "Overwriting existing DDL file - $filename";
2799       unlink($filename);
2800     }
2801
2802     my $output = $sqlt->translate;
2803     if(!$output) {
2804       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
2805       next;
2806     }
2807     if(!open($file, ">$filename")) {
2808       $self->throw_exception("Can't open $filename for writing ($!)");
2809       next;
2810     }
2811     print $file $output;
2812     close($file);
2813
2814     next unless ($preversion);
2815
2816     require SQL::Translator::Diff;
2817
2818     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
2819     if(!-e $prefilename) {
2820       carp("No previous schema file found ($prefilename)");
2821       next;
2822     }
2823
2824     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
2825     if(-e $difffile) {
2826       carp("Overwriting existing diff file - $difffile");
2827       unlink($difffile);
2828     }
2829
2830     my $source_schema;
2831     {
2832       my $t = SQL::Translator->new($sqltargs);
2833       $t->debug( 0 );
2834       $t->trace( 0 );
2835
2836       $t->parser( $db )
2837         or $self->throw_exception ($t->error);
2838
2839       my $out = $t->translate( $prefilename )
2840         or $self->throw_exception ($t->error);
2841
2842       $source_schema = $t->schema;
2843
2844       $source_schema->name( $prefilename )
2845         unless ( $source_schema->name );
2846     }
2847
2848     # The "new" style of producers have sane normalization and can support
2849     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
2850     # And we have to diff parsed SQL against parsed SQL.
2851     my $dest_schema = $sqlt_schema;
2852
2853     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
2854       my $t = SQL::Translator->new($sqltargs);
2855       $t->debug( 0 );
2856       $t->trace( 0 );
2857
2858       $t->parser( $db )
2859         or $self->throw_exception ($t->error);
2860
2861       my $out = $t->translate( $filename )
2862         or $self->throw_exception ($t->error);
2863
2864       $dest_schema = $t->schema;
2865
2866       $dest_schema->name( $filename )
2867         unless $dest_schema->name;
2868     }
2869
2870     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
2871                                                   $dest_schema,   $db,
2872                                                   $sqltargs
2873                                                  );
2874     if(!open $file, ">$difffile") {
2875       $self->throw_exception("Can't write to $difffile ($!)");
2876       next;
2877     }
2878     print $file $diff;
2879     close($file);
2880   }
2881 }
2882
2883 =head2 deployment_statements
2884
2885 =over 4
2886
2887 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
2888
2889 =back
2890
2891 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
2892
2893 The L<SQL::Translator> (not L<DBI>) database driver name can be explicitly
2894 provided in C<$type>, otherwise the result of L</sqlt_type> is used as default.
2895
2896 C<$directory> is used to return statements from files in a previously created
2897 L</create_ddl_dir> directory and is optional. The filenames are constructed
2898 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
2899
2900 If no C<$directory> is specified then the statements are constructed on the
2901 fly using L<SQL::Translator> and C<$version> is ignored.
2902
2903 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
2904
2905 =cut
2906
2907 sub deployment_statements {
2908   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
2909   $type ||= $self->sqlt_type;
2910   $version ||= $schema->schema_version || '1.x';
2911   $dir ||= './';
2912   my $filename = $schema->ddl_filename($type, $version, $dir);
2913   if(-f $filename)
2914   {
2915       # FIXME replace this block when a proper sane sql parser is available
2916       my $file;
2917       open($file, "<$filename")
2918         or $self->throw_exception("Can't open $filename ($!)");
2919       my @rows = <$file>;
2920       close($file);
2921       return join('', @rows);
2922   }
2923
2924   unless (DBIx::Class::Optional::Dependencies->req_ok_for ('deploy') ) {
2925     $self->throw_exception("Can't deploy without a ddl_dir or " . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy') );
2926   }
2927
2928   # sources needs to be a parser arg, but for simplicty allow at top level
2929   # coming in
2930   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
2931       if exists $sqltargs->{sources};
2932
2933   my $tr = SQL::Translator->new(
2934     producer => "SQL::Translator::Producer::${type}",
2935     %$sqltargs,
2936     parser => 'SQL::Translator::Parser::DBIx::Class',
2937     data => $schema,
2938   );
2939
2940   return preserve_context {
2941     $tr->translate
2942   } after => sub {
2943     $self->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
2944       unless defined $_[0];
2945   };
2946 }
2947
2948 # FIXME deploy() currently does not accurately report sql errors
2949 # Will always return true while errors are warned
2950 sub deploy {
2951   my ($self, $schema, $type, $sqltargs, $dir) = @_;
2952   my $deploy = sub {
2953     my $line = shift;
2954     return if(!$line);
2955     return if($line =~ /^--/);
2956     # next if($line =~ /^DROP/m);
2957     return if($line =~ /^BEGIN TRANSACTION/m);
2958     return if($line =~ /^COMMIT/m);
2959     return if $line =~ /^\s+$/; # skip whitespace only
2960     $self->_query_start($line);
2961     try {
2962       # do a dbh_do cycle here, as we need some error checking in
2963       # place (even though we will ignore errors)
2964       $self->dbh_do (sub { $_[1]->do($line) });
2965     } catch {
2966       carp qq{$_ (running "${line}")};
2967     };
2968     $self->_query_end($line);
2969   };
2970   my @statements = $schema->deployment_statements($type, undef, $dir, { %{ $sqltargs || {} }, no_comments => 1 } );
2971   if (@statements > 1) {
2972     foreach my $statement (@statements) {
2973       $deploy->( $statement );
2974     }
2975   }
2976   elsif (@statements == 1) {
2977     # split on single line comments and end of statements
2978     foreach my $line ( split(/\s*--.*\n|;\n/, $statements[0])) {
2979       $deploy->( $line );
2980     }
2981   }
2982 }
2983
2984 =head2 datetime_parser
2985
2986 Returns the datetime parser class
2987
2988 =cut
2989
2990 sub datetime_parser {
2991   my $self = shift;
2992   return $self->{datetime_parser} ||= do {
2993     $self->build_datetime_parser(@_);
2994   };
2995 }
2996
2997 =head2 datetime_parser_type
2998
2999 Defines the datetime parser class - currently defaults to L<DateTime::Format::MySQL>
3000
3001 =head2 build_datetime_parser
3002
3003 See L</datetime_parser>
3004
3005 =cut
3006
3007 sub build_datetime_parser {
3008   my $self = shift;
3009   my $type = $self->datetime_parser_type(@_);
3010   return $type;
3011 }
3012
3013
3014 =head2 is_replicating
3015
3016 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
3017 replicate from a master database.  Default is undef, which is the result
3018 returned by databases that don't support replication.
3019
3020 =cut
3021
3022 sub is_replicating {
3023     return;
3024
3025 }
3026
3027 =head2 lag_behind_master
3028
3029 Returns a number that represents a certain amount of lag behind a master db
3030 when a given storage is replicating.  The number is database dependent, but
3031 starts at zero and increases with the amount of lag. Default in undef
3032
3033 =cut
3034
3035 sub lag_behind_master {
3036     return;
3037 }
3038
3039 =head2 relname_to_table_alias
3040
3041 =over 4
3042
3043 =item Arguments: $relname, $join_count
3044
3045 =item Return Value: $alias
3046
3047 =back
3048
3049 L<DBIx::Class> uses L<DBIx::Class::Relationship> names as table aliases in
3050 queries.
3051
3052 This hook is to allow specific L<DBIx::Class::Storage> drivers to change the
3053 way these aliases are named.
3054
3055 The default behavior is C<< "$relname_$join_count" if $join_count > 1 >>,
3056 otherwise C<"$relname">.
3057
3058 =cut
3059
3060 sub relname_to_table_alias {
3061   my ($self, $relname, $join_count) = @_;
3062
3063   my $alias = ($join_count && $join_count > 1 ?
3064     join('_', $relname, $join_count) : $relname);
3065
3066   return $alias;
3067 }
3068
3069 # The size in bytes to use for DBI's ->bind_param_inout, this is the generic
3070 # version and it may be necessary to amend or override it for a specific storage
3071 # if such binds are necessary.
3072 sub _max_column_bytesize {
3073   my ($self, $attr) = @_;
3074
3075   my $max_size;
3076
3077   if ($attr->{sqlt_datatype}) {
3078     my $data_type = lc($attr->{sqlt_datatype});
3079
3080     if ($attr->{sqlt_size}) {
3081
3082       # String/sized-binary types
3083       if ($data_type =~ /^(?:
3084           l? (?:var)? char(?:acter)? (?:\s*varying)?
3085             |
3086           (?:var)? binary (?:\s*varying)?
3087             |
3088           raw
3089         )\b/x
3090       ) {
3091         $max_size = $attr->{sqlt_size};
3092       }
3093       # Other charset/unicode types, assume scale of 4
3094       elsif ($data_type =~ /^(?:
3095           national \s* character (?:\s*varying)?
3096             |
3097           nchar
3098             |
3099           univarchar
3100             |
3101           nvarchar
3102         )\b/x
3103       ) {
3104         $max_size = $attr->{sqlt_size} * 4;
3105       }
3106     }
3107
3108     if (!$max_size and !$self->_is_lob_type($data_type)) {
3109       $max_size = 100 # for all other (numeric?) datatypes
3110     }
3111   }
3112
3113   $max_size || $self->_dbic_connect_attributes->{LongReadLen} || $self->_get_dbh->{LongReadLen} || 8000;
3114 }
3115
3116 # Determine if a data_type is some type of BLOB
3117 sub _is_lob_type {
3118   my ($self, $data_type) = @_;
3119   $data_type && ($data_type =~ /lob|bfile|text|image|bytea|memo/i
3120     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary
3121                                   |varchar|character\s*varying|nvarchar
3122                                   |national\s*character\s*varying))?\z/xi);
3123 }
3124
3125 sub _is_binary_lob_type {
3126   my ($self, $data_type) = @_;
3127   $data_type && ($data_type =~ /blob|bfile|image|bytea/i
3128     || $data_type =~ /^long(?:\s+(?:raw|bit\s*varying|varbit|binary))?\z/xi);
3129 }
3130
3131 sub _is_text_lob_type {
3132   my ($self, $data_type) = @_;
3133   $data_type && ($data_type =~ /^(?:clob|memo)\z/i
3134     || $data_type =~ /^long(?:\s+(?:varchar|character\s*varying|nvarchar
3135                         |national\s*character\s*varying))\z/xi);
3136 }
3137
3138 # Determine if a data_type is some type of a binary type
3139 sub _is_binary_type {
3140   my ($self, $data_type) = @_;
3141   $data_type && ($self->_is_binary_lob_type($data_type)
3142     || $data_type =~ /(?:var)?(?:binary|bit|graphic)(?:\s*varying)?/i);
3143 }
3144
3145 1;
3146
3147 =head1 USAGE NOTES
3148
3149 =head2 DBIx::Class and AutoCommit
3150
3151 DBIx::Class can do some wonderful magic with handling exceptions,
3152 disconnections, and transactions when you use C<< AutoCommit => 1 >>
3153 (the default) combined with L<txn_do|DBIx::Class::Storage/txn_do> for
3154 transaction support.
3155
3156 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
3157 in an assumed transaction between commits, and you're telling us you'd
3158 like to manage that manually.  A lot of the magic protections offered by
3159 this module will go away.  We can't protect you from exceptions due to database
3160 disconnects because we don't know anything about how to restart your
3161 transactions.  You're on your own for handling all sorts of exceptional
3162 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
3163 be with raw DBI.
3164
3165
3166 =head1 AUTHOR AND CONTRIBUTORS
3167
3168 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
3169
3170 =head1 LICENSE
3171
3172 You may distribute this code under the same terms as Perl itself.
3173
3174 =cut