lib/DBIx/Class/Storage/DBI/mysql.pm

   1 package DBIx::Class::Storage::DBI::mysql;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7   DBIx::Class::Storage::DBI::MultiColumnIn
   8   DBIx::Class::Storage::DBI
   9 /;
  10 use mro 'c3';
  11
  12 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker::MySQL');
  13 __PACKAGE__->sql_limit_dialect ('LimitXY');
  14
  15 sub with_deferred_fk_checks {
  16   my ($self, $sub) = @_;
  17
  18   $self->_do_query('SET FOREIGN_KEY_CHECKS = 0');
  19   $sub->();
  20   $self->_do_query('SET FOREIGN_KEY_CHECKS = 1');
  21 }
  22
  23 sub connect_call_set_strict_mode {
  24   my $self = shift;
  25
  26   # the @@sql_mode puts back what was previously set on the session handle
  27   $self->_do_query(q|SET SQL_MODE = CONCAT('ANSI,TRADITIONAL,ONLY_FULL_GROUP_BY,', @@sql_mode)|);
  28   $self->_do_query(q|SET SQL_AUTO_IS_NULL = 0|);
  29 }
  30
  31 sub _dbh_last_insert_id {
  32   my ($self, $dbh, $source, $col) = @_;
  33   $dbh->{mysql_insertid};
  34 }
  35
  36 # here may seem like an odd place to override, but this is the first
  37 # method called after we are connected *and* the driver is determined
  38 # ($self is reblessed). See code flow in ::Storage::DBI::_populate_dbh
  39 sub _run_connection_actions {
  40   my $self = shift;
  41
  42   # default mysql_auto_reconnect to off unless explicitly set
  43   if (
  44     $self->_dbh->{mysql_auto_reconnect}
  45       and
  46     ! exists $self->_dbic_connect_attributes->{mysql_auto_reconnect}
  47   ) {
  48     $self->_dbh->{mysql_auto_reconnect} = 0;
  49   }
  50
  51   $self->next::method(@_);
  52 }
  53
  54 # we need to figure out what mysql version we're running
  55 sub sql_maker {
  56   my $self = shift;
  57
  58   unless ($self->_sql_maker) {
  59     my $maker = $self->next::method (@_);
  60
  61     # mysql 3 does not understand a bare JOIN
  62     my $mysql_ver = $self->_get_dbh->get_info(18);
  63     $maker->{_default_jointype} = 'INNER' if $mysql_ver =~ /^3/;
  64   }
  65
  66   return $self->_sql_maker;
  67 }
  68
  69 sub sqlt_type {
  70   return 'MySQL';
  71 }
  72
  73 sub deployment_statements {
  74   my $self = shift;
  75   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
  76
  77   $sqltargs ||= {};
  78
  79   if (
  80     ! exists $sqltargs->{producer_args}{mysql_version}
  81       and
  82     my $dver = $self->_server_info->{normalized_dbms_version}
  83   ) {
  84     $sqltargs->{producer_args}{mysql_version} = $dver;
  85   }
  86
  87   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
  88 }
  89
  90 sub _svp_begin {
  91     my ($self, $name) = @_;
  92
  93     $self->_get_dbh->do("SAVEPOINT $name");
  94 }
  95
  96 sub _svp_release {
  97     my ($self, $name) = @_;
  98
  99     $self->_get_dbh->do("RELEASE SAVEPOINT $name");
 100 }
 101
 102 sub _svp_rollback {
 103     my ($self, $name) = @_;
 104
 105     $self->_get_dbh->do("ROLLBACK TO SAVEPOINT $name")
 106 }
 107
 108 sub is_replicating {
 109     my $status = shift->_get_dbh->selectrow_hashref('show slave status');
 110     return ($status->{Slave_IO_Running} eq 'Yes') && ($status->{Slave_SQL_Running} eq 'Yes');
 111 }
 112
 113 sub lag_behind_master {
 114     return shift->_get_dbh->selectrow_hashref('show slave status')->{Seconds_Behind_Master};
 115 }
 116
 117 # MySql can not do subquery update/deletes, only way is slow per-row operations.
 118 # This assumes you have set proper transaction isolation and use innodb.
 119 sub _subq_update_delete {
 120   return shift->_per_row_update_delete (@_);
 121 }
 122
 123 1;
 124
 125 =head1 NAME
 126
 127 DBIx::Class::Storage::DBI::mysql - Storage::DBI class implementing MySQL specifics
 128
 129 =head1 SYNOPSIS
 130
 131 Storage::DBI autodetects the underlying MySQL database, and re-blesses the
 132 C<$storage> object into this class.
 133
 134   my $schema = MyDb::Schema->connect( $dsn, $user, $pass, { on_connect_call => 'set_strict_mode' } );
 135
 136 =head1 DESCRIPTION
 137
 138 This class implements MySQL specific bits of L<DBIx::Class::Storage::DBI>,
 139 like AutoIncrement column support and savepoints. Also it augments the
 140 SQL maker to support the MySQL-specific C<STRAIGHT_JOIN> join type, which
 141 you can use by specifying C<< join_type => 'straight' >> in the
 142 L<relationship attributes|DBIx::Class::Relationship::Base/join_type>
 143
 144
 145 It also provides a one-stop on-connect macro C<set_strict_mode> which sets
 146 session variables such that MySQL behaves more predictably as far as the
 147 SQL standard is concerned.
 148
 149 =head1 STORAGE OPTIONS
 150
 151 =head2 set_strict_mode
 152
 153 Enables session-wide strict options upon connecting. Equivalent to:
 154
 155   ->connect ( ... , {
 156     on_connect_do => [
 157       q|SET SQL_MODE = CONCAT('ANSI,TRADITIONAL,ONLY_FULL_GROUP_BY,', @@sql_mode)|,
 158       q|SET SQL_AUTO_IS_NULL = 0|,
 159     ]
 160   });
 161
 162 =head1 AUTHORS
 163
 164 See L<DBIx::Class/CONTRIBUTORS>
 165
 166 =head1 LICENSE
 167
 168 You may distribute this code under the same terms as Perl itself.
 169
 170 =cut