lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5 use mro 'c3';
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase::Base
   8     DBIx::Class::Storage::DBI
   9 /;
  10 use Carp::Clan qw/^DBIx::Class/;
  11
  12 =head1 NAME
  13
  14 DBIx::Class::Storage::DBI::Sybase - Storage::DBI subclass for Sybase
  15
  16 =head1 SYNOPSIS
  17
  18 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
  19 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
  20 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
  21
  22 =head1 DESCRIPTION
  23
  24 If your version of Sybase does not support placeholders, then your storage
  25 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
  26 also enable that driver explicitly, see the documentation for more details.
  27
  28 With this driver there is unfortunately no way to get the C<last_insert_id>
  29 without doing a C<select max(col)>.
  30
  31 But your queries will be cached.
  32
  33 A recommended L<DBIx::Class::Storage::DBI/connect_info> settings:
  34
  35   on_connect_call => [['datetime_setup'], [blob_setup => log_on_update => 0]]
  36
  37 =head1 METHODS
  38
  39 =cut
  40
  41 __PACKAGE__->mk_group_accessors('simple' =>
  42     qw/_blob_log_on_update/
  43 );
  44
  45 sub _rebless {
  46   my $self = shift;
  47
  48   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  49     my $dbtype = eval {
  50       @{$self->dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  51     } || '';
  52
  53     my $exception = $@;
  54     $dbtype =~ s/\W/_/gi;
  55     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  56
  57     if (!$exception && $dbtype && $self->load_optional_class($subclass)) {
  58       bless $self, $subclass;
  59       $self->_rebless;
  60     } else {
  61       # real Sybase
  62       if (not $self->dbh->{syb_dynamic_supported}) {
  63         $self->ensure_class_loaded('DBIx::Class::Storage::DBI::Sybase::NoBindVars');
  64         bless $self, 'DBIx::Class::Storage::DBI::Sybase::NoBindVars';
  65         $self->_rebless;
  66       }
  67     }
  68   }
  69 }
  70
  71 =head2 connect_call_blob_setup
  72
  73 Used as:
  74
  75   on_connect_call => [ [ blob_setup => log_on_update => 0 ] ]
  76
  77 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
  78 instead of as a hex string.
  79
  80 Recommended.
  81
  82 Also sets the C<log_on_update> value for blob write operations. The default is
  83 C<1>, but C<0> is better if your database is configured for it.
  84
  85 See
  86 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
  87
  88 =cut
  89
  90 sub connect_call_blob_setup {
  91   my $self = shift;
  92   my %args = @_;
  93   my $dbh = $self->_dbh;
  94   $dbh->{syb_binary_images} = 1;
  95
  96   $self->_blob_log_on_update($args{log_on_update})
  97     if exists $args{log_on_update};
  98 }
  99
 100 sub _is_lob_type {
 101   my $self = shift;
 102   shift =~ /(?:text|image|lob|bytea|binary)/i;
 103 }
 104
 105 sub insert {
 106   my ($self, $source, $to_insert) = splice @_, 0, 3;
 107
 108   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 109
 110   my $updated_cols = $self->next::method($source, $to_insert, @_);
 111
 112   $self->_update_blobs($source, $blob_cols, $to_insert) if %$blob_cols;
 113
 114   return $updated_cols;
 115 }
 116
 117 #sub update {
 118 #  my ($self, $source) = splice @_, 0, 2;
 119 #  my ($fields)        = @_;
 120 #
 121 #  my $blob_cols = $self->_remove_blob_cols($source, $fields);
 122 #
 123 #  my @res = 1;
 124 #
 125 #  if (%$fields) {
 126 #    if (wantarray) {
 127 #      @res    = $self->next::method($source, @_);
 128 #    } else {
 129 #      $res[0] = $self->next::method($source, @_);
 130 #    }
 131 #  }
 132 #
 133 #  $self->_update_blobs($source, $blob_cols, $fields) if %$blob_cols;
 134 #
 135 #  return wantarray ? @res : $res[0];
 136 #}
 137
 138 sub _remove_blob_cols {
 139   my ($self, $source, $fields) = @_;
 140
 141   my %blob_cols;
 142
 143   for my $col (keys %$fields) {
 144     $blob_cols{$col} = delete $fields->{$col}
 145       if $self->_is_lob_type($source->column_info($col)->{data_type});
 146   }
 147
 148   return \%blob_cols;
 149 }
 150
 151 sub _update_blobs {
 152   my ($self, $source, $blob_cols, $inserted) = @_;
 153   my $dbh = $self->dbh;
 154
 155   my $table = $source->from;
 156
 157   my (@primary_cols) = $source->primary_columns;
 158
 159   croak "Cannot update TEXT/IMAGE without a primary key!"
 160     unless @primary_cols;
 161
 162   my $search_cond = join ',' => map "$_ = ?", @primary_cols;
 163
 164   for my $col (keys %$blob_cols) {
 165     my $blob = $blob_cols->{$col};
 166
 167 # First update to empty string in case it's NULL, can't update a NULL blob using
 168 # the API.
 169     my $sth = $dbh->prepare_cached(
 170       qq{update $table set $col = '' where $search_cond}
 171     );
 172     $sth->execute(map $inserted->{$_}, @primary_cols) or die $sth->errstr;
 173     $sth->finish;
 174
 175     $sth = $dbh->prepare_cached(
 176       "select $col from $table where $search_cond"
 177     );
 178     $sth->execute(map $inserted->{$_}, @primary_cols);
 179
 180     eval {
 181       while ($sth->fetch) {
 182         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 183       }
 184       $sth->func('ct_prepare_send') or die $sth->errstr;
 185
 186       my $log_on_update = $self->_blob_log_on_update;
 187       $log_on_update    = 1 if not defined $log_on_update;
 188
 189       $sth->func('CS_SET', 1, {
 190         total_txtlen => length($blob),
 191         log_on_update => $log_on_update
 192       }, 'ct_data_info') or die $sth->errstr;
 193
 194       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 195
 196       $sth->func('ct_finish_send') or die $sth->errstr;
 197     };
 198     my $exception = $@;
 199     $sth->finish;
 200     croak $exception if $exception;
 201   }
 202 }
 203
 204 =head2 connect_call_datetime_setup
 205
 206 Used as:
 207
 208   on_connect_call => 'datetime_setup'
 209
 210 In L<DBIx::Class::Storage::DBI/connect_info> to set:
 211
 212   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 213   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 214
 215 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 216 L<DateTime::Format::Sybase>, which you will need to install.
 217
 218 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 219 C<SMALLDATETIME> columns only have minute precision.
 220
 221 =cut
 222
 223 {
 224   my $old_dbd_warned = 0;
 225
 226   sub connect_call_datetime_setup {
 227     my $self = shift;
 228     my $dbh = $self->_dbh;
 229
 230     if ($dbh->can('syb_date_fmt')) {
 231       $dbh->syb_date_fmt('ISO_strict');
 232     } elsif (not $old_dbd_warned) {
 233       carp "Your DBD::Sybase is too old to support ".
 234       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 235       $old_dbd_warned = 1;
 236     }
 237
 238     $dbh->do('set dateformat mdy');
 239
 240     1;
 241   }
 242 }
 243
 244 sub datetime_parser_type { "DateTime::Format::Sybase" }
 245
 246 sub _dbh_last_insert_id {
 247   my ($self, $dbh, $source, $col) = @_;
 248
 249   # sorry, there's no other way!
 250   my $sth = $dbh->prepare_cached("select max($col) from ".$source->from);
 251   return ($dbh->selectrow_array($sth))[0];
 252 }
 253
 254 1;
 255
 256 =head1 DATES
 257
 258 See L</connect_call_datetime_setup> to setup date formats
 259 for L<DBIx::Class::InflateColumn::DateTime>.
 260
 261 =head1 IMAGE AND TEXT COLUMNS
 262
 263 See L</connect_call_blob_setup> for a L<DBIx::Class::Storage::DBI/connect_info>
 264 setting you need to work with C<IMAGE> columns.
 265
 266 Due to limitations in L<DBD::Sybase> and this driver, it is only possible to
 267 select one C<TEXT> or C<IMAGE> column at a time.
 268
 269 =head1 AUTHORS
 270
 271 See L<DBIx::Class/CONTRIBUTORS>.
 272
 273 =head1 LICENSE
 274
 275 You may distribute this code under the same terms as Perl itself.
 276
 277 =cut
 278 # vim:sts=2 sw=2: