lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase::Base
   8     DBIx::Class::Storage::DBI
   9 /;
  10 use mro 'c3';
  11 use Carp::Clan qw/^DBIx::Class/;
  12
  13 =head1 NAME
  14
  15 DBIx::Class::Storage::DBI::Sybase - Storage::DBI subclass for Sybase
  16
  17 =head1 SYNOPSIS
  18
  19 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
  20 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
  21 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
  22
  23 =head1 DESCRIPTION
  24
  25 If your version of Sybase does not support placeholders, then your storage
  26 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
  27 also enable that driver explicitly, see the documentation for more details.
  28
  29 With this driver there is unfortunately no way to get the C<last_insert_id>
  30 without doing a C<select max(col)>.
  31
  32 But your queries will be cached.
  33
  34 A recommended L<DBIx::Class::Storage::DBI/connect_info> settings:
  35
  36   on_connect_call => [['datetime_setup'], [blob_setup => log_on_update => 0]]
  37
  38 =head1 METHODS
  39
  40 =cut
  41
  42 __PACKAGE__->mk_group_accessors('simple' =>
  43     qw/_blob_log_on_update/
  44 );
  45
  46 sub _rebless {
  47   my $self = shift;
  48
  49   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  50     my $dbtype = eval {
  51       @{$self->dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  52     } || '';
  53
  54     my $exception = $@;
  55     $dbtype =~ s/\W/_/gi;
  56     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  57
  58     if (!$exception && $dbtype && $self->load_optional_class($subclass)) {
  59       bless $self, $subclass;
  60       $self->_rebless;
  61     } else {
  62       # real Sybase
  63       if (not $self->dbh->{syb_dynamic_supported}) {
  64         $self->ensure_class_loaded('DBIx::Class::Storage::DBI::Sybase::NoBindVars');
  65         bless $self, 'DBIx::Class::Storage::DBI::Sybase::NoBindVars';
  66         $self->_rebless;
  67       }
  68     }
  69   }
  70 }
  71
  72 =head2 connect_call_blob_setup
  73
  74 Used as:
  75
  76   on_connect_call => [ [ blob_setup => log_on_update => 0 ] ]
  77
  78 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
  79 instead of as a hex string.
  80
  81 Recommended.
  82
  83 Also sets the C<log_on_update> value for blob write operations. The default is
  84 C<1>, but C<0> is better if your database is configured for it.
  85
  86 See
  87 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
  88
  89 =cut
  90
  91 sub connect_call_blob_setup {
  92   my $self = shift;
  93   my %args = @_;
  94   my $dbh = $self->_dbh;
  95   $dbh->{syb_binary_images} = 1;
  96
  97   $self->_blob_log_on_update($args{log_on_update})
  98     if exists $args{log_on_update};
  99 }
 100
 101 sub _is_lob_type {
 102   my $self = shift;
 103   shift =~ /(?:text|image|lob|bytea|binary)/i;
 104 }
 105
 106 sub insert {
 107   my ($self, $source, $to_insert) = splice @_, 0, 3;
 108
 109   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 110
 111   my $updated_cols = $self->next::method($source, $to_insert, @_);
 112
 113   $self->_update_blobs($source, $blob_cols, $to_insert) if %$blob_cols;
 114
 115   return $updated_cols;
 116 }
 117
 118 #sub update {
 119 #  my ($self, $source) = splice @_, 0, 2;
 120 #  my ($fields)        = @_;
 121 #
 122 #  my $blob_cols = $self->_remove_blob_cols($source, $fields);
 123 #
 124 #  my @res = 1;
 125 #
 126 #  if (%$fields) {
 127 #    if (wantarray) {
 128 #      @res    = $self->next::method($source, @_);
 129 #    } else {
 130 #      $res[0] = $self->next::method($source, @_);
 131 #    }
 132 #  }
 133 #
 134 #  $self->_update_blobs($source, $blob_cols, $fields) if %$blob_cols;
 135 #
 136 #  return wantarray ? @res : $res[0];
 137 #}
 138
 139 sub _remove_blob_cols {
 140   my ($self, $source, $fields) = @_;
 141
 142   my %blob_cols;
 143
 144   for my $col (keys %$fields) {
 145     $blob_cols{$col} = delete $fields->{$col}
 146       if $self->_is_lob_type($source->column_info($col)->{data_type});
 147   }
 148
 149   return \%blob_cols;
 150 }
 151
 152 sub _update_blobs {
 153   my ($self, $source, $blob_cols, $inserted) = @_;
 154   my $dbh = $self->dbh;
 155
 156   my $table = $source->from;
 157
 158   my (@primary_cols) = $source->primary_columns;
 159
 160   croak "Cannot update TEXT/IMAGE without a primary key!"
 161     unless @primary_cols;
 162
 163   my $search_cond = join ',' => map "$_ = ?", @primary_cols;
 164
 165   for my $col (keys %$blob_cols) {
 166     my $blob = $blob_cols->{$col};
 167
 168 # First update to empty string in case it's NULL, can't update a NULL blob using
 169 # the API.
 170     my $sth = $dbh->prepare_cached(
 171       qq{update $table set $col = '' where $search_cond}
 172     );
 173     $sth->execute(map $inserted->{$_}, @primary_cols) or die $sth->errstr;
 174     $sth->finish;
 175
 176     $sth = $dbh->prepare_cached(
 177       "select $col from $table where $search_cond"
 178     );
 179     $sth->execute(map $inserted->{$_}, @primary_cols);
 180
 181     eval {
 182       while ($sth->fetch) {
 183         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 184       }
 185       $sth->func('ct_prepare_send') or die $sth->errstr;
 186
 187       my $log_on_update = $self->_blob_log_on_update;
 188       $log_on_update    = 1 if not defined $log_on_update;
 189
 190       $sth->func('CS_SET', 1, {
 191         total_txtlen => length($blob),
 192         log_on_update => $log_on_update
 193       }, 'ct_data_info') or die $sth->errstr;
 194
 195       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 196
 197       $sth->func('ct_finish_send') or die $sth->errstr;
 198     };
 199     my $exception = $@;
 200     $sth->finish;
 201     croak $exception if $exception;
 202   }
 203 }
 204
 205 =head2 connect_call_datetime_setup
 206
 207 Used as:
 208
 209   on_connect_call => 'datetime_setup'
 210
 211 In L<DBIx::Class::Storage::DBI/connect_info> to set:
 212
 213   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 214   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 215
 216 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 217 L<DateTime::Format::Sybase>, which you will need to install.
 218
 219 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 220 C<SMALLDATETIME> columns only have minute precision.
 221
 222 =cut
 223
 224 {
 225   my $old_dbd_warned = 0;
 226
 227   sub connect_call_datetime_setup {
 228     my $self = shift;
 229     my $dbh = $self->_dbh;
 230
 231     if ($dbh->can('syb_date_fmt')) {
 232       $dbh->syb_date_fmt('ISO_strict');
 233     } elsif (not $old_dbd_warned) {
 234       carp "Your DBD::Sybase is too old to support ".
 235       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 236       $old_dbd_warned = 1;
 237     }
 238
 239     $dbh->do('set dateformat mdy');
 240
 241     1;
 242   }
 243 }
 244
 245 sub datetime_parser_type { "DateTime::Format::Sybase" }
 246
 247 sub _dbh_last_insert_id {
 248   my ($self, $dbh, $source, $col) = @_;
 249
 250   # sorry, there's no other way!
 251   my $sth = $dbh->prepare_cached("select max($col) from ".$source->from);
 252   return ($dbh->selectrow_array($sth))[0];
 253 }
 254
 255 1;
 256
 257 =head1 DATES
 258
 259 See L</connect_call_datetime_setup> to setup date formats
 260 for L<DBIx::Class::InflateColumn::DateTime>.
 261
 262 =head1 IMAGE AND TEXT COLUMNS
 263
 264 See L</connect_call_blob_setup> for a L<DBIx::Class::Storage::DBI/connect_info>
 265 setting you need to work with C<IMAGE> columns.
 266
 267 Due to limitations in L<DBD::Sybase> and this driver, it is only possible to
 268 select one C<TEXT> or C<IMAGE> column at a time.
 269
 270 =head1 AUTHORS
 271
 272 See L<DBIx::Class/CONTRIBUTORS>.
 273
 274 =head1 LICENSE
 275
 276 You may distribute this code under the same terms as Perl itself.
 277
 278 =cut
 279 # vim:sts=2 sw=2: