lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Class::C3;
   7 use base qw/DBIx::Class::Storage::DBI/;
   8
   9 use Carp::Clan qw/^DBIx::Class/;
  10
  11 sub _rebless {
  12   my $self = shift;
  13
  14   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  15     my $dbtype = eval {
  16       @{$self->dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  17     } || '';
  18
  19     my $exception = $@;
  20     $dbtype =~ s/\W/_/gi;
  21     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  22
  23     if (!$exception && $dbtype && $self->load_optional_class($subclass)) {
  24       bless $self, $subclass;
  25       $self->_rebless;
  26     } else {
  27       # real Sybase
  28       if (not $self->dbh->{syb_dynamic_supported}) {
  29         bless $self, 'DBIx::Class::Storage:DBI::Sybase::NoBindVars';
  30         $self->_rebless;
  31       }
  32       $self->connect_call_datetime_setup;
  33     }
  34   }
  35 }
  36
  37 sub _populate_dbh {
  38   my $self = shift;
  39   $self->next::method(@_);
  40   $self->connect_call_datetime_setup;
  41   1;
  42 }
  43
  44 {
  45   my $old_dbd_warned = 0;
  46
  47 =head2 connect_call_datetime_setup
  48
  49 Used as:
  50
  51   on_connect_call => 'datetime_setup'
  52
  53 In L<DBIx::Class::Storage::DBI/connect_info> to set:
  54
  55   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
  56   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
  57
  58 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
  59 L<DateTime::Format::Sybase>, which you will need to install.
  60
  61 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
  62 C<SMALLDATETIME> columns only have minute precision.
  63
  64 =cut
  65
  66   sub connect_call_datetime_setup {
  67     my $self = shift;
  68     my $dbh = $self->_dbh;
  69
  70     if ($dbh->can('syb_date_fmt')) {
  71       $dbh->syb_date_fmt('ISO_strict');
  72     } elsif (not $old_dbd_warned) {
  73       carp "Your DBD::Sybase is too old to support ".
  74       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
  75       $old_dbd_warned = 1;
  76     }
  77
  78     $dbh->do('set dateformat mdy');
  79
  80     1;
  81   }
  82 }
  83
  84 sub _dbh_last_insert_id {
  85   my ($self, $dbh, $source, $col) = @_;
  86
  87   # sorry, there's no other way!
  88   my $sth = $dbh->prepare_cached("select max($col) from ".$source->from);
  89   return ($dbh->selectrow_array($sth))[0];
  90 }
  91
  92 sub count {
  93   my $self = shift;
  94   my ($source, $attrs) = @_;
  95
  96   if (not exists $attrs->{rows}) {
  97     return $self->next::method(@_);
  98   }
  99
 100   my $offset = $attrs->{offset} || 0;
 101   my $total  = $attrs->{rows} + $offset;
 102
 103   my $new_attrs = $self->_copy_attributes_for_count($source, $attrs);
 104
 105   my $first_pk = ($source->primary_columns)[0];
 106
 107   $new_attrs->{select} = $first_pk ? "me.$first_pk" : 1;
 108
 109   my $tmp_rs = $source->resultset_class->new($source, $new_attrs);
 110
 111   $self->dbh->{syb_rowcount} = $total;
 112
 113   my $count = 0;
 114   $count++ while $tmp_rs->cursor->next;
 115
 116   $self->dbh->{syb_rowcount} = 0;
 117
 118   return $count - $offset;
 119 }
 120
 121 sub datetime_parser_type { "DateTime::Format::Sybase" }
 122
 123 1;
 124
 125 =head1 NAME
 126
 127 DBIx::Class::Storage::DBI::Sybase - Storage::DBI subclass for Sybase
 128
 129 =head1 SYNOPSIS
 130
 131 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
 132 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
 133 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
 134
 135 =head1 DESCRIPTION
 136
 137 If your version of Sybase does not support placeholders, then your storage
 138 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
 139 also enable that driver explicitly, see the documentation for more details.
 140
 141 With this driver there is unfortunately no way to get the C<last_insert_id>
 142 without doing a C<select max(col)>.
 143
 144 But your queries will be cached.
 145
 146 =head1 DATES
 147
 148 See L</connect_call_datetime_setup> to setup date formats
 149 for L<DBIx::Class::InflateColumn::DateTime>.
 150
 151 =head1 AUTHORS
 152
 153 See L<DBIx::Class/CONTRIBUTORS>.
 154
 155 =head1 LICENSE
 156
 157 You may distribute this code under the same terms as Perl itself.
 158
 159 =cut
 160 # vim:sts=2 sw=2: