lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Class::C3;
   7 use base qw/DBIx::Class::Storage::DBI/;
   8
   9 use Carp::Clan qw/^DBIx::Class/;
  10
  11 =head1 NAME
  12
  13 DBIx::Class::Storage::DBI::Sybase - Storage::DBI subclass for Sybase
  14
  15 =head1 SYNOPSIS
  16
  17 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
  18 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
  19 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
  20
  21 =head1 DESCRIPTION
  22
  23 If your version of Sybase does not support placeholders, then your storage
  24 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
  25 also enable that driver explicitly, see the documentation for more details.
  26
  27 With this driver there is unfortunately no way to get the C<last_insert_id>
  28 without doing a C<select max(col)>.
  29
  30 But your queries will be cached.
  31
  32 A recommended L<DBIx::Class::Storage::DBI/connect_info> settings:
  33
  34   on_connect_call => [['datetime_setup'], [blob_setup => log_on_update => 0]]
  35
  36 =head1 METHODS
  37
  38 =cut
  39
  40 __PACKAGE__->mk_group_accessors('simple' =>
  41     qw/_blob_log_on_update/
  42 );
  43
  44 sub _rebless {
  45   my $self = shift;
  46
  47   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  48     my $dbtype = eval {
  49       @{$self->dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  50     } || '';
  51
  52     my $exception = $@;
  53     $dbtype =~ s/\W/_/gi;
  54     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  55
  56     if (!$exception && $dbtype && $self->load_optional_class($subclass)) {
  57       bless $self, $subclass;
  58       $self->_rebless;
  59     } else {
  60       # real Sybase
  61       if (not $self->dbh->{syb_dynamic_supported}) {
  62         bless $self, 'DBIx::Class::Storage:DBI::Sybase::NoBindVars';
  63         $self->_rebless;
  64       }
  65     }
  66   }
  67 }
  68
  69 =head2 connect_call_blob_setup
  70
  71 Used as:
  72
  73   on_connect_call => [ [ blob_setup => log_on_update => 0 ] ]
  74
  75 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
  76 instead of as a hex string.
  77
  78 Recommended.
  79
  80 Also sets the C<log_on_update> value for blob write operations. The default is
  81 C<1>, but C<0> is better if your database is configured for it.
  82
  83 See
  84 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
  85
  86 =cut
  87
  88 sub connect_call_blob_setup {
  89   my $self = shift;
  90   my %args = @_;
  91   my $dbh = $self->_dbh;
  92   $dbh->{syb_binary_images} = 1;
  93
  94   $self->_blob_log_on_update($args{log_on_update})
  95     if exists $args{log_on_update};
  96 }
  97
  98 sub _is_lob_type {
  99   my $self = shift;
 100   shift =~ /(?:text|image|lob|bytea|binary)/i;
 101 }
 102
 103 sub insert {
 104   my ($self, $source, $to_insert) = splice @_, 0, 3;
 105
 106   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 107
 108   my $updated_cols = $self->next::method($source, $to_insert, @_);
 109
 110   $self->_update_blobs($source, $blob_cols, $to_insert) if %$blob_cols;
 111
 112   return $updated_cols;
 113 }
 114
 115 #sub update {
 116 #  my ($self, $source) = splice @_, 0, 2;
 117 #  my ($fields)        = @_;
 118 #
 119 #  my $blob_cols = $self->_remove_blob_cols($source, $fields);
 120 #
 121 #  my @res = 1;
 122 #
 123 #  if (%$fields) {
 124 #    if (wantarray) {
 125 #      @res    = $self->next::method($source, @_);
 126 #    } else {
 127 #      $res[0] = $self->next::method($source, @_);
 128 #    }
 129 #  }
 130 #
 131 #  $self->_update_blobs($source, $blob_cols, $fields) if %$blob_cols;
 132 #
 133 #  return wantarray ? @res : $res[0];
 134 #}
 135
 136 sub _remove_blob_cols {
 137   my ($self, $source, $fields) = @_;
 138
 139   my %blob_cols;
 140
 141   for my $col (keys %$fields) {
 142     $blob_cols{$col} = delete $fields->{$col}
 143       if $self->_is_lob_type($source->column_info($col)->{data_type});
 144   }
 145
 146   return \%blob_cols;
 147 }
 148
 149 sub _update_blobs {
 150   my ($self, $source, $blob_cols, $inserted) = @_;
 151   my $dbh = $self->dbh;
 152
 153   my $table = $source->from;
 154
 155   my (@primary_cols) = $source->primary_columns;
 156
 157   croak "Cannot update TEXT/IMAGE without a primary key!"
 158     unless @primary_cols;
 159
 160   my $search_cond = join ',' => map "$_ = ?", @primary_cols;
 161
 162   for my $col (keys %$blob_cols) {
 163     my $blob = $blob_cols->{$col};
 164
 165 # First update to empty string in case it's NULL, can't update a NULL blob using
 166 # the API.
 167     my $sth = $dbh->prepare_cached(
 168       qq{update $table set $col = '' where $search_cond}
 169     );
 170     $sth->execute(map $inserted->{$_}, @primary_cols) or die $sth->errstr;
 171     $sth->finish;
 172
 173     $sth = $dbh->prepare_cached(
 174       "select $col from $table where $search_cond"
 175     );
 176     $sth->execute(map $inserted->{$_}, @primary_cols);
 177
 178     eval {
 179       while ($sth->fetch) {
 180         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 181       }
 182       $sth->func('ct_prepare_send') or die $sth->errstr;
 183
 184       my $log_on_update = $self->_blob_log_on_update;
 185       $log_on_update    = 1 if not defined $log_on_update;
 186
 187       $sth->func('CS_SET', 1, {
 188         total_txtlen => length($blob),
 189         log_on_update => $log_on_update
 190       }, 'ct_data_info') or die $sth->errstr;
 191
 192       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 193
 194       $sth->func('ct_finish_send') or die $sth->errstr;
 195     };
 196     my $exception = $@;
 197     $sth->finish;
 198     croak $exception if $exception;
 199   }
 200 }
 201
 202 =head2 connect_call_datetime_setup
 203
 204 Used as:
 205
 206   on_connect_call => 'datetime_setup'
 207
 208 In L<DBIx::Class::Storage::DBI/connect_info> to set:
 209
 210   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 211   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 212
 213 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 214 L<DateTime::Format::Sybase>, which you will need to install.
 215
 216 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 217 C<SMALLDATETIME> columns only have minute precision.
 218
 219 =cut
 220
 221 {
 222   my $old_dbd_warned = 0;
 223
 224   sub connect_call_datetime_setup {
 225     my $self = shift;
 226     my $dbh = $self->_dbh;
 227
 228     if ($dbh->can('syb_date_fmt')) {
 229       $dbh->syb_date_fmt('ISO_strict');
 230     } elsif (not $old_dbd_warned) {
 231       carp "Your DBD::Sybase is too old to support ".
 232       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 233       $old_dbd_warned = 1;
 234     }
 235
 236     $dbh->do('set dateformat mdy');
 237
 238     1;
 239   }
 240 }
 241
 242 sub datetime_parser_type { "DateTime::Format::Sybase" }
 243
 244 sub _dbh_last_insert_id {
 245   my ($self, $dbh, $source, $col) = @_;
 246
 247   # sorry, there's no other way!
 248   my $sth = $dbh->prepare_cached("select max($col) from ".$source->from);
 249   return ($dbh->selectrow_array($sth))[0];
 250 }
 251
 252 # previous implementation of limited count for Sybase, does not include
 253 # count_grouped.
 254
 255 #sub _copy_attributes_for_count {
 256 #  my ($self, $source, $attrs) = @_;
 257 #  my %attrs = %$attrs;
 258 #
 259 #  # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
 260 #  delete @attrs{qw/select as rows offset page order_by record_filter/};
 261 #
 262 #  return \%attrs;
 263 #}
 264 #
 265 #=head2 count
 266 #
 267 #Counts for limited queries are emulated by executing select queries and
 268 #returning the number of successful executions minus the offset.
 269 #
 270 #This is necessary due to the limitations of Sybase.
 271 #
 272 #=cut
 273 #
 274 #sub count {
 275 #  my $self = shift;
 276 #  my ($source, $attrs) = @_;
 277 #
 278 #  my $new_attrs = $self->_copy_attributes_for_count($source, $attrs);
 279 #
 280 #  if (exists $attrs->{rows}) {
 281 #    my $offset = $attrs->{offset} || 0;
 282 #    my $total  = $attrs->{rows} + $offset;
 283 #
 284 #    my $first_pk = ($source->primary_columns)[0];
 285 #
 286 #    $new_attrs->{select} = $first_pk ? "me.$first_pk" : 1;
 287 #
 288 #    my $tmp_rs = $source->resultset_class->new($source, $new_attrs);
 289 #
 290 #    $self->dbh->{syb_rowcount} = $total;
 291 #
 292 #    my $count = 0;
 293 #    $count++ while $tmp_rs->cursor->next;
 294 #
 295 #    $self->dbh->{syb_rowcount} = 0;
 296 #
 297 #    return $count - $offset;
 298 #  } else {
 299 #    # overwrite the selector
 300 #    $new_attrs->{select} = { count => '*' };
 301 #
 302 #    my $tmp_rs = $source->resultset_class->new($source, $new_attrs);
 303 #    my ($count) = $tmp_rs->cursor->next;
 304 #
 305 #    # if the offset/rows attributes are still present, we did not use
 306 #    # a subquery, so we need to make the calculations in software
 307 #    $count -= $attrs->{offset} if $attrs->{offset};
 308 #    $count = $attrs->{rows} if $attrs->{rows} and $attrs->{rows} < $count;
 309 #    $count = 0 if ($count < 0);
 310 #
 311 #    return $count;
 312 #  }
 313 #}
 314
 315 1;
 316
 317 =head1 DATES
 318
 319 See L</connect_call_datetime_setup> to setup date formats
 320 for L<DBIx::Class::InflateColumn::DateTime>.
 321
 322 =head1 IMAGE AND TEXT COLUMNS
 323
 324 See L</connect_call_blob_setup> for a L<DBIx::Class::Storage::DBI/connect_info>
 325 setting you need to work with C<IMAGE> columns.
 326
 327 Due to limitations in L<DBD::Sybase> and this driver, it is only possible to
 328 select one C<TEXT> or C<IMAGE> column at a time.
 329
 330 =head1 AUTHORS
 331
 332 See L<DBIx::Class/CONTRIBUTORS>.
 333
 334 =head1 LICENSE
 335
 336 You may distribute this code under the same terms as Perl itself.
 337
 338 =cut
 339 # vim:sts=2 sw=2: