lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::Sybase::Common
   8     DBIx::Class::Storage::DBI::AutoCast
   9 /;
  10 use mro 'c3';
  11 use Carp::Clan qw/^DBIx::Class/;
  12 use List::Util ();
  13 use Sub::Name ();
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_identity _blob_log_on_update _writer_storage _is_extra_storage
  17        _bulk_storage _is_bulk_storage _began_bulk_work
  18        _bulk_disabled_due_to_coderef_connect_info_warned
  19        _identity_method/
  20 );
  21
  22 my @also_proxy_to_extra_storages = qw/
  23   connect_call_set_auto_cast auto_cast connect_call_blob_setup
  24   connect_call_datetime_setup
  25
  26   disconnect _connect_info _sql_maker _sql_maker_opts disable_sth_caching
  27   auto_savepoint unsafe cursor_class debug debugobj schema
  28 /;
  29
  30 =head1 NAME
  31
  32 DBIx::Class::Storage::DBI::Sybase - Sybase support for DBIx::Class
  33
  34 =head1 SYNOPSIS
  35
  36 This subclass supports L<DBD::Sybase> for real Sybase databases.  If you are
  37 using an MSSQL database via L<DBD::Sybase>, your storage will be reblessed to
  38 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
  39
  40 =head1 DESCRIPTION
  41
  42 If your version of Sybase does not support placeholders, then your storage
  43 will be reblessed to L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>. You can
  44 also enable that driver explicitly, see the documentation for more details.
  45
  46 With this driver there is unfortunately no way to get the C<last_insert_id>
  47 without doing a C<SELECT MAX(col)>. This is done safely in a transaction
  48 (locking the table.) See L</INSERTS WITH PLACEHOLDERS>.
  49
  50 A recommended L<DBIx::Class::Storage::DBI/connect_info> setting:
  51
  52   on_connect_call => [['datetime_setup'], ['blob_setup', log_on_update => 0]]
  53
  54 =head1 METHODS
  55
  56 =cut
  57
  58 sub _rebless {
  59   my $self = shift;
  60
  61   if (ref($self) eq 'DBIx::Class::Storage::DBI::Sybase') {
  62     my $dbtype = eval {
  63       @{$self->_get_dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2]
  64     } || '';
  65
  66     my $exception = $@;
  67     $dbtype =~ s/\W/_/gi;
  68     my $subclass = "DBIx::Class::Storage::DBI::Sybase::${dbtype}";
  69
  70     if (!$exception && $dbtype && $self->load_optional_class($subclass)) {
  71       bless $self, $subclass;
  72       $self->_rebless;
  73     } else { # real Sybase
  74       my $no_bind_vars = 'DBIx::Class::Storage::DBI::Sybase::NoBindVars';
  75
  76       if ($self->using_freetds) {
  77         carp <<'EOF' unless $ENV{DBIC_SYBASE_FREETDS_NOWARN};
  78
  79 You are using FreeTDS with Sybase.
  80
  81 We will do our best to support this configuration, but please consider this
  82 support experimental.
  83
  84 TEXT/IMAGE columns will definitely not work.
  85
  86 You are encouraged to recompile DBD::Sybase with the Sybase Open Client libraries
  87 instead.
  88
  89 See perldoc DBIx::Class::Storage::DBI::Sybase for more details.
  90
  91 To turn off this warning set the DBIC_SYBASE_FREETDS_NOWARN environment
  92 variable.
  93 EOF
  94         if (not $self->_typeless_placeholders_supported) {
  95           if ($self->_placeholders_supported) {
  96             $self->auto_cast(1);
  97           } else {
  98             $self->ensure_class_loaded($no_bind_vars);
  99             bless $self, $no_bind_vars;
 100             $self->_rebless;
 101           }
 102         }
 103       }
 104       elsif (not $self->_get_dbh->{syb_dynamic_supported}) {
 105         # not necessarily FreeTDS, but no placeholders nevertheless
 106         $self->ensure_class_loaded($no_bind_vars);
 107         bless $self, $no_bind_vars;
 108         $self->_rebless;
 109       } elsif (not $self->_typeless_placeholders_supported) {
 110         # this is highly unlikely, but we check just in case
 111         $self->auto_cast(1);
 112       }
 113     }
 114   }
 115 }
 116
 117 sub _init {
 118   my $self = shift;
 119   $self->_set_max_connect(256);
 120
 121   # based on LongReadLen in connect_info
 122   $self->set_textsize if $self->using_freetds;
 123
 124 # create storage for insert/(update blob) transactions,
 125 # unless this is that storage
 126   return if $self->_is_extra_storage;
 127
 128   my $writer_storage = (ref $self)->new;
 129
 130   $writer_storage->_is_extra_storage(1);
 131   $writer_storage->connect_info($self->connect_info);
 132   $writer_storage->auto_cast($self->auto_cast);
 133
 134   $self->_writer_storage($writer_storage);
 135
 136 # create a bulk storage unless connect_info is a coderef
 137   return
 138     if (Scalar::Util::reftype($self->_dbi_connect_info->[0])||'') eq 'CODE';
 139
 140   my $bulk_storage = (ref $self)->new;
 141
 142   $bulk_storage->_is_extra_storage(1);
 143   $bulk_storage->_is_bulk_storage(1); # for special ->disconnect acrobatics
 144   $bulk_storage->connect_info($self->connect_info);
 145
 146 # this is why
 147   $bulk_storage->_dbi_connect_info->[0] .= ';bulkLogin=1';
 148
 149   $self->_bulk_storage($bulk_storage);
 150 }
 151
 152 for my $method (@also_proxy_to_extra_storages) {
 153   no strict 'refs';
 154   no warnings 'redefine';
 155
 156   my $replaced = __PACKAGE__->can($method);
 157
 158   *{$method} = Sub::Name::subname $method => sub {
 159     my $self = shift;
 160     $self->_writer_storage->$replaced(@_) if $self->_writer_storage;
 161     $self->_bulk_storage->$replaced(@_)   if $self->_bulk_storage;
 162     return $self->$replaced(@_);
 163   };
 164 }
 165
 166 sub disconnect {
 167   my $self = shift;
 168
 169 # Even though we call $sth->finish for uses off the bulk API, there's still an
 170 # "active statement" warning on disconnect, which we throw away here.
 171 # This is due to the bug described in insert_bulk.
 172 # Currently a noop because 'prepare' is used instead of 'prepare_cached'.
 173   local $SIG{__WARN__} = sub {
 174     warn $_[0] unless $_[0] =~ /active statement/i;
 175   } if $self->_is_bulk_storage;
 176
 177 # so that next transaction gets a dbh
 178   $self->_began_bulk_work(0) if $self->_is_bulk_storage;
 179
 180   $self->next::method;
 181 }
 182
 183 # Make sure we have CHAINED mode turned on if AutoCommit is off in non-FreeTDS
 184 # DBD::Sybase (since we don't know how DBD::Sybase was compiled.) If however
 185 # we're using FreeTDS, CHAINED mode turns on an implicit transaction which we
 186 # only want when AutoCommit is off.
 187 sub _populate_dbh {
 188   my $self = shift;
 189
 190   $self->next::method(@_);
 191
 192   if ($self->_is_bulk_storage) {
 193 # this should be cleared on every reconnect
 194     $self->_began_bulk_work(0);
 195     return;
 196   }
 197
 198   if (not $self->using_freetds) {
 199     $self->_dbh->{syb_chained_txn} = 1;
 200   } else {
 201     if ($self->_dbh_autocommit) {
 202       $self->_dbh->do('SET CHAINED OFF');
 203     } else {
 204       $self->_dbh->do('SET CHAINED ON');
 205     }
 206   }
 207 }
 208
 209 =head2 connect_call_blob_setup
 210
 211 Used as:
 212
 213   on_connect_call => [ [ 'blob_setup', log_on_update => 0 ] ]
 214
 215 Does C<< $dbh->{syb_binary_images} = 1; >> to return C<IMAGE> data as raw binary
 216 instead of as a hex string.
 217
 218 Recommended.
 219
 220 Also sets the C<log_on_update> value for blob write operations. The default is
 221 C<1>, but C<0> is better if your database is configured for it.
 222
 223 See
 224 L<DBD::Sybase/Handling_IMAGE/TEXT_data_with_syb_ct_get_data()/syb_ct_send_data()>.
 225
 226 =cut
 227
 228 sub connect_call_blob_setup {
 229   my $self = shift;
 230   my %args = @_;
 231   my $dbh = $self->_dbh;
 232   $dbh->{syb_binary_images} = 1;
 233
 234   $self->_blob_log_on_update($args{log_on_update})
 235     if exists $args{log_on_update};
 236 }
 237
 238 sub _is_lob_type {
 239   my $self = shift;
 240   my $type = shift;
 241   $type && $type =~ /(?:text|image|lob|bytea|binary|memo)/i;
 242 }
 243
 244 sub _is_lob_column {
 245   my ($self, $source, $column) = @_;
 246
 247   return $self->_is_lob_type($source->column_info($column)->{data_type});
 248 }
 249
 250 sub _prep_for_execute {
 251   my $self = shift;
 252   my ($op, $extra_bind, $ident, $args) = @_;
 253
 254   my ($sql, $bind) = $self->next::method (@_);
 255
 256   my $table = Scalar::Util::blessed($ident) ? $ident->from : $ident;
 257
 258   my $bind_info = $self->_resolve_column_info(
 259     $ident, [map $_->[0], @{$bind}]
 260   );
 261   my $bound_identity_col = List::Util::first
 262     { $bind_info->{$_}{is_auto_increment} }
 263     (keys %$bind_info)
 264   ;
 265   my $identity_col = Scalar::Util::blessed($ident) &&
 266     List::Util::first
 267     { $ident->column_info($_)->{is_auto_increment} }
 268     $ident->columns
 269   ;
 270
 271   if (($op eq 'insert' && $bound_identity_col) ||
 272       ($op eq 'update' && exists $args->[0]{$identity_col})) {
 273     $sql = join ("\n",
 274       $self->_set_table_identity_sql($op => $table, 'on'),
 275       $sql,
 276       $self->_set_table_identity_sql($op => $table, 'off'),
 277     );
 278   }
 279
 280   if ($op eq 'insert' && (not $bound_identity_col) && $identity_col &&
 281       (not $self->{insert_bulk})) {
 282     $sql =
 283       "$sql\n" .
 284       $self->_fetch_identity_sql($ident, $identity_col);
 285   }
 286
 287   return ($sql, $bind);
 288 }
 289
 290 sub _set_table_identity_sql {
 291   my ($self, $op, $table, $on_off) = @_;
 292
 293   return sprintf 'SET IDENTITY_%s %s %s',
 294     uc($op), $self->sql_maker->_quote($table), uc($on_off);
 295 }
 296
 297 # Stolen from SQLT, with some modifications. This is a makeshift
 298 # solution before a sane type-mapping library is available, thus
 299 # the 'our' for easy overrides.
 300 our %TYPE_MAPPING  = (
 301     number    => 'numeric',
 302     money     => 'money',
 303     varchar   => 'varchar',
 304     varchar2  => 'varchar',
 305     timestamp => 'datetime',
 306     text      => 'varchar',
 307     real      => 'double precision',
 308     comment   => 'text',
 309     bit       => 'bit',
 310     tinyint   => 'smallint',
 311     float     => 'double precision',
 312     serial    => 'numeric',
 313     bigserial => 'numeric',
 314     boolean   => 'varchar',
 315     long      => 'varchar',
 316 );
 317
 318 sub _native_data_type {
 319   my ($self, $type) = @_;
 320
 321   $type = lc $type;
 322   $type =~ s/\s* identity//x;
 323
 324   return uc($TYPE_MAPPING{$type} || $type);
 325 }
 326
 327 sub _fetch_identity_sql {
 328   my ($self, $source, $col) = @_;
 329
 330   return sprintf ("SELECT MAX(%s) FROM %s",
 331     map { $self->sql_maker->_quote ($_) } ($col, $source->from)
 332   );
 333 }
 334
 335 sub _execute {
 336   my $self = shift;
 337   my ($op) = @_;
 338
 339   my ($rv, $sth, @bind) = $self->dbh_do($self->can('_dbh_execute'), @_);
 340
 341   if ($op eq 'insert') {
 342     $self->_identity($sth->fetchrow_array);
 343     $sth->finish;
 344   }
 345
 346   return wantarray ? ($rv, $sth, @bind) : $rv;
 347 }
 348
 349 sub last_insert_id { shift->_identity }
 350
 351 # handles TEXT/IMAGE and transaction for last_insert_id
 352 sub insert {
 353   my $self = shift;
 354   my ($source, $to_insert) = @_;
 355
 356   my $identity_col = (List::Util::first
 357     { $source->column_info($_)->{is_auto_increment} }
 358     $source->columns) || '';
 359
 360   # check for empty insert
 361   # INSERT INTO foo DEFAULT VALUES -- does not work with Sybase
 362   # try to insert explicit 'DEFAULT's instead (except for identity)
 363   if (not %$to_insert) {
 364     for my $col ($source->columns) {
 365       next if $col eq $identity_col;
 366       $to_insert->{$col} = \'DEFAULT';
 367     }
 368   }
 369
 370   my $blob_cols = $self->_remove_blob_cols($source, $to_insert);
 371
 372   # do we need the horrific SELECT MAX(COL) hack?
 373   my $dumb_last_insert_id =
 374        $identity_col
 375     && (not exists $to_insert->{$identity_col})
 376     && ($self->_identity_method||'') ne '@@IDENTITY';
 377
 378   my $next = $self->next::can;
 379
 380   # we are already in a transaction, or there are no blobs
 381   # and we don't need the PK - just (try to) do it
 382   if ($self->{transaction_depth}
 383         || (!$blob_cols && !$dumb_last_insert_id)
 384   ) {
 385     return $self->_insert (
 386       $next, $source, $to_insert, $blob_cols, $identity_col
 387     );
 388   }
 389
 390   # otherwise use the _writer_storage to do the insert+transaction on another
 391   # connection
 392   my $guard = $self->_writer_storage->txn_scope_guard;
 393
 394   my $updated_cols = $self->_writer_storage->_insert (
 395     $next, $source, $to_insert, $blob_cols, $identity_col
 396   );
 397
 398   $self->_identity($self->_writer_storage->_identity);
 399
 400   $guard->commit;
 401
 402   return $updated_cols;
 403 }
 404
 405 sub _insert {
 406   my ($self, $next, $source, $to_insert, $blob_cols, $identity_col) = @_;
 407
 408   my $updated_cols = $self->$next ($source, $to_insert);
 409
 410   my $final_row = {
 411     ($identity_col ?
 412       ($identity_col => $self->last_insert_id($source, $identity_col)) : ()),
 413     %$to_insert,
 414     %$updated_cols,
 415   };
 416
 417   $self->_insert_blobs ($source, $blob_cols, $final_row) if $blob_cols;
 418
 419   return $updated_cols;
 420 }
 421
 422 sub update {
 423   my $self = shift;
 424   my ($source, $fields, $where, @rest) = @_;
 425
 426   my $wantarray = wantarray;
 427
 428   my $blob_cols = $self->_remove_blob_cols($source, $fields);
 429
 430   my $table = $source->name;
 431
 432   my $identity_col = List::Util::first
 433     { $source->column_info($_)->{is_auto_increment} }
 434     $source->columns;
 435
 436   my $is_identity_update = $identity_col && defined $fields->{$identity_col};
 437
 438   return $self->next::method(@_) unless $blob_cols;
 439
 440 # If there are any blobs in $where, Sybase will return a descriptive error
 441 # message.
 442 # XXX blobs can still be used with a LIKE query, and this should be handled.
 443
 444 # update+blob update(s) done atomically on separate connection
 445   $self = $self->_writer_storage;
 446
 447   my $guard = $self->txn_scope_guard;
 448
 449 # First update the blob columns to be updated to '' (taken from $fields, where
 450 # it is originally put by _remove_blob_cols .)
 451   my %blobs_to_empty = map { ($_ => delete $fields->{$_}) } keys %$blob_cols;
 452
 453 # We can't only update NULL blobs, because blobs cannot be in the WHERE clause.
 454
 455   $self->next::method($source, \%blobs_to_empty, $where, @rest);
 456
 457 # Now update the blobs before the other columns in case the update of other
 458 # columns makes the search condition invalid.
 459   $self->_update_blobs($source, $blob_cols, $where);
 460
 461   my @res;
 462   if (%$fields) {
 463     if ($wantarray) {
 464       @res    = $self->next::method(@_);
 465     }
 466     elsif (defined $wantarray) {
 467       $res[0] = $self->next::method(@_);
 468     }
 469     else {
 470       $self->next::method(@_);
 471     }
 472   }
 473
 474   $guard->commit;
 475
 476   return $wantarray ? @res : $res[0];
 477 }
 478
 479 sub insert_bulk {
 480   my $self = shift;
 481   my ($source, $cols, $data) = @_;
 482
 483   my $identity_col = List::Util::first
 484     { $source->column_info($_)->{is_auto_increment} }
 485     $source->columns;
 486
 487   my $is_identity_insert = (List::Util::first
 488     { $_ eq $identity_col }
 489     @{$cols}
 490   ) ? 1 : 0;
 491
 492   my @source_columns = $source->columns;
 493
 494   my $use_bulk_api =
 495     $self->_bulk_storage &&
 496     $self->_get_dbh->{syb_has_blk};
 497
 498   if ((not $use_bulk_api) &&
 499       (Scalar::Util::reftype($self->_dbi_connect_info->[0])||'') eq 'CODE' &&
 500       (not $self->_bulk_disabled_due_to_coderef_connect_info_warned)) {
 501     carp <<'EOF';
 502 Bulk API support disabled due to use of a CODEREF connect_info. Reverting to
 503 regular array inserts.
 504 EOF
 505     $self->_bulk_disabled_due_to_coderef_connect_info_warned(1);
 506   }
 507
 508   if (not $use_bulk_api) {
 509     my $blob_cols = $self->_remove_blob_cols_array($source, $cols, $data);
 510
 511     my $dumb_last_insert_id =
 512          $identity_col
 513       && (not $is_identity_insert)
 514       && ($self->_identity_method||'') ne '@@IDENTITY';
 515
 516     ($self, my $guard) = $self->{transaction_depth} == 0 ?
 517       ($self->_writer_storage, $self->_writer_storage->txn_scope_guard)
 518       :
 519       ($self, undef);
 520
 521     local $self->{insert_bulk} = 1;
 522
 523     $self->next::method(@_);
 524
 525     if ($blob_cols) {
 526       if ($is_identity_insert) {
 527         $self->_insert_blobs_array ($source, $blob_cols, $cols, $data);
 528       }
 529       else {
 530         my @cols_with_identities = (@$cols, $identity_col);
 531
 532         ## calculate identities
 533         # XXX This assumes identities always increase by 1, which may or may not
 534         # be true.
 535         my ($last_identity) =
 536           $self->_dbh->selectrow_array (
 537             $self->_fetch_identity_sql($source, $identity_col)
 538           );
 539         my @identities = (($last_identity - @$data + 1) .. $last_identity);
 540
 541         my @data_with_identities = map [@$_, shift @identities], @$data;
 542
 543         $self->_insert_blobs_array (
 544           $source, $blob_cols, \@cols_with_identities, \@data_with_identities
 545         );
 546       }
 547     }
 548
 549     $guard->commit if $guard;
 550
 551     return;
 552   }
 553
 554 # otherwise, use the bulk API
 555
 556 # rearrange @$data so that columns are in database order
 557   my %orig_idx;
 558   @orig_idx{@$cols} = 0..$#$cols;
 559
 560   my %new_idx;
 561   @new_idx{@source_columns} = 0..$#source_columns;
 562
 563   my @new_data;
 564   for my $datum (@$data) {
 565     my $new_datum = [];
 566     for my $col (@source_columns) {
 567 # identity data will be 'undef' if not $is_identity_insert
 568 # columns with defaults will also be 'undef'
 569       $new_datum->[ $new_idx{$col} ] =
 570         exists $orig_idx{$col} ? $datum->[ $orig_idx{$col} ] : undef;
 571     }
 572     push @new_data, $new_datum;
 573   }
 574
 575 # bcp identity index is 1-based
 576   my $identity_idx = exists $new_idx{$identity_col} ?
 577     $new_idx{$identity_col} + 1 : 0;
 578
 579 ## Set a client-side conversion error handler, straight from DBD::Sybase docs.
 580 # This ignores any data conversion errors detected by the client side libs, as
 581 # they are usually harmless.
 582   my $orig_cslib_cb = DBD::Sybase::set_cslib_cb(
 583     Sub::Name::subname insert_bulk => sub {
 584       my ($layer, $origin, $severity, $errno, $errmsg, $osmsg, $blkmsg) = @_;
 585
 586       return 1 if $errno == 36;
 587
 588       carp
 589         "Layer: $layer, Origin: $origin, Severity: $severity, Error: $errno" .
 590         ($errmsg ? "\n$errmsg" : '') .
 591         ($osmsg  ? "\n$osmsg"  : '')  .
 592         ($blkmsg ? "\n$blkmsg" : '');
 593
 594       return 0;
 595   });
 596
 597   eval {
 598     my $bulk = $self->_bulk_storage;
 599
 600     my $guard = $bulk->txn_scope_guard;
 601
 602 ## XXX get this to work instead of our own $sth
 603 ## will require SQLA or *Hacks changes for ordered columns
 604 #    $bulk->next::method($source, \@source_columns, \@new_data, {
 605 #      syb_bcp_attribs => {
 606 #        identity_flag   => $is_identity_insert,
 607 #        identity_column => $identity_idx,
 608 #      }
 609 #    });
 610     my $sql = 'INSERT INTO ' .
 611       $bulk->sql_maker->_quote($source->name) . ' (' .
 612 # colname list is ignored for BCP, but does no harm
 613       (join ', ', map $bulk->sql_maker->_quote($_), @source_columns) . ') '.
 614       ' VALUES ('.  (join ', ', ('?') x @source_columns) . ')';
 615
 616 ## XXX there's a bug in the DBD::Sybase bulk support that makes $sth->finish for
 617 ## a prepare_cached statement ineffective. Replace with ->sth when fixed, or
 618 ## better yet the version above. Should be fixed in DBD::Sybase .
 619     my $sth = $bulk->_get_dbh->prepare($sql,
 620 #      'insert', # op
 621       {
 622         syb_bcp_attribs => {
 623           identity_flag   => $is_identity_insert,
 624           identity_column => $identity_idx,
 625         }
 626       }
 627     );
 628
 629     my @bind = do {
 630       my $idx = 0;
 631       map [ $_, $idx++ ], @source_columns;
 632     };
 633
 634     $self->_execute_array(
 635       $source, $sth, \@bind, \@source_columns, \@new_data, sub {
 636         $guard->commit
 637       }
 638     );
 639
 640     $bulk->_query_end($sql);
 641   };
 642
 643   my $exception = $@;
 644   DBD::Sybase::set_cslib_cb($orig_cslib_cb);
 645
 646   if ($exception =~ /-Y option/) {
 647     carp <<"EOF";
 648
 649 Sybase bulk API operation failed due to character set incompatibility, reverting
 650 to regular array inserts:
 651
 652 *** Try unsetting the LANG environment variable.
 653
 654 $exception
 655 EOF
 656     $self->_bulk_storage(undef);
 657     unshift @_, $self;
 658     goto \&insert_bulk;
 659   }
 660   elsif ($exception) {
 661 # rollback makes the bulkLogin connection unusable
 662     $self->_bulk_storage->disconnect;
 663     $self->throw_exception($exception);
 664   }
 665 }
 666
 667 sub _dbh_execute_array {
 668   my ($self, $sth, $tuple_status, $cb) = @_;
 669
 670   my $rv = $self->next::method($sth, $tuple_status);
 671   $cb->() if $cb;
 672
 673   return $rv;
 674 }
 675
 676 # Make sure blobs are not bound as placeholders, and return any non-empty ones
 677 # as a hash.
 678 sub _remove_blob_cols {
 679   my ($self, $source, $fields) = @_;
 680
 681   my %blob_cols;
 682
 683   for my $col (keys %$fields) {
 684     if ($self->_is_lob_column($source, $col)) {
 685       my $blob_val = delete $fields->{$col};
 686       if (not defined $blob_val) {
 687         $fields->{$col} = \'NULL';
 688       }
 689       else {
 690         $fields->{$col} = \"''";
 691         $blob_cols{$col} = $blob_val unless $blob_val eq '';
 692       }
 693     }
 694   }
 695
 696   return %blob_cols ? \%blob_cols : undef;
 697 }
 698
 699 # same for insert_bulk
 700 sub _remove_blob_cols_array {
 701   my ($self, $source, $cols, $data) = @_;
 702
 703   my @blob_cols;
 704
 705   for my $i (0..$#$cols) {
 706     my $col = $cols->[$i];
 707
 708     if ($self->_is_lob_column($source, $col)) {
 709       for my $j (0..$#$data) {
 710         my $blob_val = delete $data->[$j][$i];
 711         if (not defined $blob_val) {
 712           $data->[$j][$i] = \'NULL';
 713         }
 714         else {
 715           $data->[$j][$i] = \"''";
 716           $blob_cols[$j][$i] = $blob_val
 717             unless $blob_val eq '';
 718         }
 719       }
 720     }
 721   }
 722
 723   return @blob_cols ? \@blob_cols : undef;
 724 }
 725
 726 sub _update_blobs {
 727   my ($self, $source, $blob_cols, $where) = @_;
 728
 729   my (@primary_cols) = $source->primary_columns;
 730
 731   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without a primary key')
 732     unless @primary_cols;
 733
 734 # check if we're updating a single row by PK
 735   my $pk_cols_in_where = 0;
 736   for my $col (@primary_cols) {
 737     $pk_cols_in_where++ if defined $where->{$col};
 738   }
 739   my @rows;
 740
 741   if ($pk_cols_in_where == @primary_cols) {
 742     my %row_to_update;
 743     @row_to_update{@primary_cols} = @{$where}{@primary_cols};
 744     @rows = \%row_to_update;
 745   } else {
 746     my $cursor = $self->select ($source, \@primary_cols, $where, {});
 747     @rows = map {
 748       my %row; @row{@primary_cols} = @$_; \%row
 749     } $cursor->all;
 750   }
 751
 752   for my $row (@rows) {
 753     $self->_insert_blobs($source, $blob_cols, $row);
 754   }
 755 }
 756
 757 sub _insert_blobs {
 758   my ($self, $source, $blob_cols, $row) = @_;
 759   my $dbh = $self->_get_dbh;
 760
 761   my $table = $source->name;
 762
 763   my %row = %$row;
 764   my (@primary_cols) = $source->primary_columns;
 765
 766   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without a primary key')
 767     unless @primary_cols;
 768
 769   $self->throw_exception('Cannot update TEXT/IMAGE column(s) without primary key values')
 770     if ((grep { defined $row{$_} } @primary_cols) != @primary_cols);
 771
 772   for my $col (keys %$blob_cols) {
 773     my $blob = $blob_cols->{$col};
 774
 775     my %where = map { ($_, $row{$_}) } @primary_cols;
 776
 777     my $cursor = $self->select ($source, [$col], \%where, {});
 778     $cursor->next;
 779     my $sth = $cursor->sth;
 780
 781     if (not $sth) {
 782
 783       $self->throw_exception(
 784           "Could not find row in table '$table' for blob update:\n"
 785         . $self->_pretty_print (\%where)
 786       );
 787     }
 788
 789     eval {
 790       do {
 791         $sth->func('CS_GET', 1, 'ct_data_info') or die $sth->errstr;
 792       } while $sth->fetch;
 793
 794       $sth->func('ct_prepare_send') or die $sth->errstr;
 795
 796       my $log_on_update = $self->_blob_log_on_update;
 797       $log_on_update    = 1 if not defined $log_on_update;
 798
 799       $sth->func('CS_SET', 1, {
 800         total_txtlen => length($blob),
 801         log_on_update => $log_on_update
 802       }, 'ct_data_info') or die $sth->errstr;
 803
 804       $sth->func($blob, length($blob), 'ct_send_data') or die $sth->errstr;
 805
 806       $sth->func('ct_finish_send') or die $sth->errstr;
 807     };
 808     my $exception = $@;
 809     $sth->finish if $sth;
 810     if ($exception) {
 811       if ($self->using_freetds) {
 812         $self->throw_exception (
 813           'TEXT/IMAGE operation failed, probably because you are using FreeTDS: '
 814           . $exception
 815         );
 816       } else {
 817         $self->throw_exception($exception);
 818       }
 819     }
 820   }
 821 }
 822
 823 sub _insert_blobs_array {
 824   my ($self, $source, $blob_cols, $cols, $data) = @_;
 825
 826   for my $i (0..$#$data) {
 827     my $datum = $data->[$i];
 828
 829     my %row;
 830     @row{ @$cols } = @$datum;
 831
 832     my %blob_vals;
 833     for my $j (0..$#$cols) {
 834       if (exists $blob_cols->[$i][$j]) {
 835         $blob_vals{ $cols->[$j] } = $blob_cols->[$i][$j];
 836       }
 837     }
 838
 839     $self->_insert_blobs ($source, \%blob_vals, \%row);
 840   }
 841 }
 842
 843 =head2 connect_call_datetime_setup
 844
 845 Used as:
 846
 847   on_connect_call => 'datetime_setup'
 848
 849 In L<DBIx::Class::Storage::DBI/connect_info> to set:
 850
 851   $dbh->syb_date_fmt('ISO_strict'); # output fmt: 2004-08-21T14:36:48.080Z
 852   $dbh->do('set dateformat mdy');   # input fmt:  08/13/1979 18:08:55.080
 853
 854 On connection for use with L<DBIx::Class::InflateColumn::DateTime>, using
 855 L<DateTime::Format::Sybase>, which you will need to install.
 856
 857 This works for both C<DATETIME> and C<SMALLDATETIME> columns, although
 858 C<SMALLDATETIME> columns only have minute precision.
 859
 860 =cut
 861
 862 {
 863   my $old_dbd_warned = 0;
 864
 865   sub connect_call_datetime_setup {
 866     my $self = shift;
 867     my $dbh = $self->_get_dbh;
 868
 869     if ($dbh->can('syb_date_fmt')) {
 870       # amazingly, this works with FreeTDS
 871       $dbh->syb_date_fmt('ISO_strict');
 872     } elsif (not $old_dbd_warned) {
 873       carp "Your DBD::Sybase is too old to support ".
 874       "DBIx::Class::InflateColumn::DateTime, please upgrade!";
 875       $old_dbd_warned = 1;
 876     }
 877
 878     $dbh->do('SET DATEFORMAT mdy');
 879
 880     1;
 881   }
 882 }
 883
 884 sub datetime_parser_type { "DateTime::Format::Sybase" }
 885
 886 # ->begin_work and such have no effect with FreeTDS but we run them anyway to
 887 # let the DBD keep any state it needs to.
 888 #
 889 # If they ever do start working, the extra statements will do no harm (because
 890 # Sybase supports nested transactions.)
 891
 892 sub _dbh_begin_work {
 893   my $self = shift;
 894
 895 # bulkLogin=1 connections are always in a transaction, and can only call BEGIN
 896 # TRAN once. However, we need to make sure there's a $dbh.
 897   return if $self->_is_bulk_storage && $self->_dbh && $self->_began_bulk_work;
 898
 899   $self->next::method(@_);
 900
 901   if ($self->using_freetds) {
 902     $self->_get_dbh->do('BEGIN TRAN');
 903   }
 904
 905   $self->_began_bulk_work(1) if $self->_is_bulk_storage;
 906 }
 907
 908 sub _dbh_commit {
 909   my $self = shift;
 910   if ($self->using_freetds) {
 911     $self->_dbh->do('COMMIT');
 912   }
 913   return $self->next::method(@_);
 914 }
 915
 916 sub _dbh_rollback {
 917   my $self = shift;
 918   if ($self->using_freetds) {
 919     $self->_dbh->do('ROLLBACK');
 920   }
 921   return $self->next::method(@_);
 922 }
 923
 924 # savepoint support using ASE syntax
 925
 926 sub _svp_begin {
 927   my ($self, $name) = @_;
 928
 929   $self->_get_dbh->do("SAVE TRANSACTION $name");
 930 }
 931
 932 # A new SAVE TRANSACTION with the same name releases the previous one.
 933 sub _svp_release { 1 }
 934
 935 sub _svp_rollback {
 936   my ($self, $name) = @_;
 937
 938   $self->_get_dbh->do("ROLLBACK TRANSACTION $name");
 939 }
 940
 941 1;
 942
 943 =head1 Schema::Loader Support
 944
 945 There is an experimental branch of L<DBIx::Class::Schema::Loader> that will
 946 allow you to dump a schema from most (if not all) versions of Sybase.
 947
 948 It is available via subversion from:
 949
 950   http://dev.catalyst.perl.org/repos/bast/branches/DBIx-Class-Schema-Loader/current/
 951
 952 =head1 FreeTDS
 953
 954 This driver supports L<DBD::Sybase> compiled against FreeTDS
 955 (L<http://www.freetds.org/>) to the best of our ability, however it is
 956 recommended that you recompile L<DBD::Sybase> against the Sybase Open Client
 957 libraries. They are a part of the Sybase ASE distribution:
 958
 959 The Open Client FAQ is here:
 960 L<http://www.isug.com/Sybase_FAQ/ASE/section7.html>.
 961
 962 Sybase ASE for Linux (which comes with the Open Client libraries) may be
 963 downloaded here: L<http://response.sybase.com/forms/ASE_Linux_Download>.
 964
 965 To see if you're using FreeTDS check C<< $schema->storage->using_freetds >>, or run:
 966
 967   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
 968
 969 Some versions of the libraries involved will not support placeholders, in which
 970 case the storage will be reblessed to
 971 L<DBIx::Class::Storage::DBI::Sybase::NoBindVars>.
 972
 973 In some configurations, placeholders will work but will throw implicit type
 974 conversion errors for anything that's not expecting a string. In such a case,
 975 the C<auto_cast> option from L<DBIx::Class::Storage::DBI::AutoCast> is
 976 automatically set, which you may enable on connection with
 977 L<DBIx::Class::Storage::DBI::AutoCast/connect_call_set_auto_cast>. The type info
 978 for the C<CAST>s is taken from the L<DBIx::Class::ResultSource/data_type>
 979 definitions in your Result classes, and are mapped to a Sybase type (if it isn't
 980 already) using a mapping based on L<SQL::Translator>.
 981
 982 In other configurations, placeholers will work just as they do with the Sybase
 983 Open Client libraries.
 984
 985 Inserts or updates of TEXT/IMAGE columns will B<NOT> work with FreeTDS.
 986
 987 =head1 INSERTS WITH PLACEHOLDERS
 988
 989 With placeholders enabled, inserts are done in a transaction so that there are
 990 no concurrency issues with getting the inserted identity value using
 991 C<SELECT MAX(col)>, which is the only way to get the C<IDENTITY> value in this
 992 mode.
 993
 994 In addition, they are done on a separate connection so that it's possible to
 995 have active cursors when doing an insert.
 996
 997 When using C<DBIx::Class::Storage::DBI::Sybase::NoBindVars> transactions are
 998 disabled, as there are no concurrency issues with C<SELECT @@IDENTITY> as it's a
 999 session variable.
1000
1001 =head1 TRANSACTIONS
1002
1003 Due to limitations of the TDS protocol, L<DBD::Sybase>, or both; you cannot
1004 begin a transaction while there are active cursors; nor can you use multiple
1005 active cursors within a transaction. An active cursor is, for example, a
1006 L<ResultSet|DBIx::Class::ResultSet> that has been executed using C<next> or
1007 C<first> but has not been exhausted or L<reset|DBIx::Class::ResultSet/reset>.
1008
1009 For example, this will not work:
1010
1011   $schema->txn_do(sub {
1012     my $rs = $schema->resultset('Book');
1013     while (my $row = $rs->next) {
1014       $schema->resultset('MetaData')->create({
1015         book_id => $row->id,
1016         ...
1017       });
1018     }
1019   });
1020
1021 This won't either:
1022
1023   my $first_row = $large_rs->first;
1024   $schema->txn_do(sub { ... });
1025
1026 Transactions done for inserts in C<AutoCommit> mode when placeholders are in use
1027 are not affected, as they are done on an extra database handle.
1028
1029 Some workarounds:
1030
1031 =over 4
1032
1033 =item * use L<DBIx::Class::Storage::DBI::Replicated>
1034
1035 =item * L<connect|DBIx::Class::Schema/connect> another L<Schema|DBIx::Class::Schema>
1036
1037 =item * load the data from your cursor with L<DBIx::Class::ResultSet/all>
1038
1039 =back
1040
1041 =head1 MAXIMUM CONNECTIONS
1042
1043 The TDS protocol makes separate connections to the server for active statements
1044 in the background. By default the number of such connections is limited to 25,
1045 on both the client side and the server side.
1046
1047 This is a bit too low for a complex L<DBIx::Class> application, so on connection
1048 the client side setting is set to C<256> (see L<DBD::Sybase/maxConnect>.) You
1049 can override it to whatever setting you like in the DSN.
1050
1051 See
1052 L<http://infocenter.sybase.com/help/index.jsp?topic=/com.sybase.help.ase_15.0.sag1/html/sag1/sag1272.htm>
1053 for information on changing the setting on the server side.
1054
1055 =head1 DATES
1056
1057 See L</connect_call_datetime_setup> to setup date formats
1058 for L<DBIx::Class::InflateColumn::DateTime>.
1059
1060 =head1 TEXT/IMAGE COLUMNS
1061
1062 L<DBD::Sybase> compiled with FreeTDS will B<NOT> allow you to insert or update
1063 C<TEXT/IMAGE> columns.
1064
1065 Setting C<< $dbh->{LongReadLen} >> will also not work with FreeTDS use either:
1066
1067   $schema->storage->dbh->do("SET TEXTSIZE $bytes");
1068
1069 or
1070
1071   $schema->storage->set_textsize($bytes);
1072
1073 instead.
1074
1075 However, the C<LongReadLen> you pass in
1076 L<DBIx::Class::Storage::DBI/connect_info> is used to execute the equivalent
1077 C<SET TEXTSIZE> command on connection.
1078
1079 See L</connect_call_blob_setup> for a L<DBIx::Class::Storage::DBI/connect_info>
1080 setting you need to work with C<IMAGE> columns.
1081
1082 =head1 BULK API
1083
1084 The experimental L<DBD::Sybase> Bulk API support is used for
1085 L<populate|DBIx::Class::ResultSet/populate> in B<void> context, in a transaction
1086 on a separate connection.
1087
1088 To use this feature effectively, use a large number of rows for each
1089 L<populate|DBIx::Class::ResultSet/populate> call, eg.:
1090
1091   while (my $rows = $data_source->get_100_rows()) {
1092     $rs->populate($rows);
1093   }
1094
1095 B<NOTE:> the L<add_columns|DBIx::Class::ResultSource/add_columns>
1096 calls in your C<Result> classes B<must> list columns in database order for this
1097 to work. Also, you may have to unset the C<LANG> environment variable before
1098 loading your app, if it doesn't match the character set of your database.
1099
1100 When inserting IMAGE columns using this method, you'll need to use
1101 L</connect_call_blob_setup> as well.
1102
1103 =head1 TODO
1104
1105 =over
1106
1107 =item *
1108
1109 Transitions to AutoCommit=0 (starting a transaction) mode by exhausting
1110 any active cursors, using eager cursors.
1111
1112 =item *
1113
1114 Real limits and limited counts using stored procedures deployed on startup.
1115
1116 =item *
1117
1118 Adaptive Server Anywhere (ASA) support, with possible SQLA::Limit support.
1119
1120 =item *
1121
1122 Blob update with a LIKE query on a blob, without invalidating the WHERE condition.
1123
1124 =item *
1125
1126 bulk_insert using prepare_cached (see comments.)
1127
1128 =back
1129
1130 =head1 AUTHOR
1131
1132 See L<DBIx::Class/CONTRIBUTORS>.
1133
1134 =head1 LICENSE
1135
1136 You may distribute this code under the same terms as Perl itself.
1137
1138 =cut
1139 # vim:sts=2 sw=2: