lib/DBIx/Class/Storage/DBI/Sybase.pm

   1 package DBIx::Class::Storage::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5 use Try::Tiny;
   6 use namespace::clean;
   7
   8 use base qw/DBIx::Class::Storage::DBI/;
   9
  10 =head1 NAME
  11
  12 DBIx::Class::Storage::DBI::Sybase - Base class for drivers using
  13 L<DBD::Sybase>
  14
  15 =head1 DESCRIPTION
  16
  17 This is the base class/dispatcher for Storage's designed to work with
  18 L<DBD::Sybase>
  19
  20 =head1 METHODS
  21
  22 =cut
  23
  24 sub _rebless { shift->_determine_connector_driver('Sybase') }
  25
  26 sub _get_rdbms_name {
  27   my $self = shift;
  28
  29   try {
  30     my $name = $self->_get_dbh->selectrow_arrayref('sp_server_info @attribute_id=1')->[2];
  31
  32     if ($name) {
  33       $name =~ s/\W/_/gi;
  34
  35       # saner class name
  36       $name = 'ASE' if $name eq 'SQL_Server';
  37     }
  38
  39     $name;  # RV
  40   } catch {
  41     $self->throw_exception("Unable to establish connection to determine database type: $_")
  42   };
  43 }
  44
  45 sub _init {
  46   # once the driver is determined see if we need to insert the DBD::Sybase w/ FreeTDS fixups
  47   # this is a dirty version of "instance role application", \o/ DO WANT Moo \o/
  48   my $self = shift;
  49   if (! $self->isa('DBIx::Class::Storage::DBI::Sybase::FreeTDS') and $self->_using_freetds) {
  50     require DBIx::Class::Storage::DBI::Sybase::FreeTDS;
  51
  52     my @isa = @{mro::get_linear_isa(ref $self)};
  53     my $class = shift @isa; # this is our current ref
  54
  55     my $trait_class = $class . '::FreeTDS';
  56     mro::set_mro ($trait_class, 'c3');
  57     no strict 'refs';
  58     @{"${trait_class}::ISA"} = ($class, 'DBIx::Class::Storage::DBI::Sybase::FreeTDS', @isa);
  59
  60     bless ($self, $trait_class);
  61
  62     Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
  63
  64     $self->_init(@_);
  65   }
  66
  67   $self->next::method(@_);
  68 }
  69
  70 sub _ping {
  71   my $self = shift;
  72
  73   my $dbh = $self->_dbh or return 0;
  74
  75   local $dbh->{RaiseError} = 1;
  76   local $dbh->{PrintError} = 0;
  77
  78 # FIXME if the main connection goes stale, does opening another for this statement
  79 # really determine anything?
  80
  81   if ($dbh->{syb_no_child_con}) {
  82     return try {
  83       $self->_connect->do('select 1');
  84       1;
  85     }
  86     catch {
  87       0;
  88     };
  89   }
  90
  91   return try {
  92     $dbh->do('select 1');
  93     1;
  94   }
  95   catch {
  96     0;
  97   };
  98 }
  99
 100 sub _set_max_connect {
 101   my $self = shift;
 102   my $val  = shift || 256;
 103
 104   my $dsn = $self->_dbi_connect_info->[0];
 105
 106   return if ref($dsn) eq 'CODE';
 107
 108   if ($dsn !~ /maxConnect=/) {
 109     $self->_dbi_connect_info->[0] = "$dsn;maxConnect=$val";
 110     my $connected = defined $self->_dbh;
 111     $self->disconnect;
 112     $self->ensure_connected if $connected;
 113   }
 114 }
 115
 116 # Whether or not DBD::Sybase was compiled against FreeTDS. If false, it means
 117 # the Sybase OpenClient libraries were used.
 118 sub _using_freetds {
 119   my $self = shift;
 120   return ($self->_get_dbh->{syb_oc_version}||'') =~ /freetds/i;
 121 }
 122
 123 # Either returns the FreeTDS version against which DBD::Sybase was compiled,
 124 # 0 if can't be determined, or undef otherwise
 125 sub _using_freetds_version {
 126   my $inf = shift->_get_dbh->{syb_oc_version};
 127   return undef unless ($inf||'') =~ /freetds/i;
 128   return $inf =~ /v([0-9\.]+)/ ? $1 : 0;
 129 }
 130
 131 =head1 FURTHER QUESTIONS?
 132
 133 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 134
 135 =head1 COPYRIGHT AND LICENSE
 136
 137 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 138 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 139 redistribute it and/or modify it under the same terms as the
 140 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 141
 142 =cut
 143
 144 1;
 145