lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::MultiColumnIn
   8 /;
   9 use mro 'c3';
  10
  11 use DBD::Pg qw(:pg_types);
  12 use Scope::Guard ();
  13 use Context::Preserve 'preserve_context';
  14 use namespace::clean;
  15
  16 __PACKAGE__->sql_limit_dialect ('LimitOffset');
  17 __PACKAGE__->sql_quote_char ('"');
  18
  19 # Ask for a DBD::Pg with array support
  20 warn __PACKAGE__.": DBD::Pg 2.9.2 or greater is strongly recommended\n"
  21   if ($DBD::Pg::VERSION < 2.009002);  # pg uses (used?) version::qv()
  22
  23 sub _determine_supports_insert_returning {
  24   return shift->_server_info->{normalized_dbms_version} >= 8.002
  25     ? 1
  26     : 0
  27   ;
  28 }
  29
  30 sub with_deferred_fk_checks {
  31   my ($self, $sub) = @_;
  32
  33   my $txn_scope_guard = $self->txn_scope_guard;
  34
  35   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  36
  37   my $sg = Scope::Guard->new(sub {
  38     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  39   });
  40
  41   return preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
  42 }
  43
  44 # only used when INSERT ... RETURNING is disabled
  45 sub last_insert_id {
  46   my ($self,$source,@cols) = @_;
  47
  48   my @values;
  49
  50   my $col_info = $source->columns_info(\@cols);
  51
  52   for my $col (@cols) {
  53     my $seq = ( $col_info->{$col}{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  54       or $self->throw_exception( sprintf(
  55         'could not determine sequence for column %s.%s, please consider adding a schema-qualified sequence to its column info',
  56           $source->name,
  57           $col,
  58       ));
  59
  60     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  61   }
  62
  63   return @values;
  64 }
  65
  66 sub _sequence_fetch {
  67   my ($self, $function, $sequence) = @_;
  68
  69   $self->throw_exception('No sequence to fetch') unless $sequence;
  70
  71   my ($val) = $self->_get_dbh->selectrow_array(
  72     sprintf ("select %s('%s')", $function, (ref $sequence eq 'SCALAR') ? $$sequence : $sequence)
  73   );
  74
  75   return $val;
  76 }
  77
  78 sub _dbh_get_autoinc_seq {
  79   my ($self, $dbh, $source, $col) = @_;
  80
  81   my $schema;
  82   my $table = $source->name;
  83
  84   # deref table name if it needs it
  85   $table = $$table
  86       if ref $table eq 'SCALAR';
  87
  88   # parse out schema name if present
  89   if( $table =~ /^(.+)\.(.+)$/ ) {
  90     ( $schema, $table ) = ( $1, $2 );
  91   }
  92
  93   # get the column default using a Postgres-specific pg_catalog query
  94   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  95
  96   # if no default value is set on the column, or if we can't parse the
  97   # default value as a sequence, throw.
  98   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  99     $seq_expr = '' unless defined $seq_expr;
 100     $schema = "$schema." if defined $schema && length $schema;
 101     $self->throw_exception( sprintf (
 102       'no sequence found for %s%s.%s, check the RDBMS table definition or explicitly set the '.
 103       "'sequence' for this column in %s",
 104         $schema ? "$schema." : '',
 105         $table,
 106         $col,
 107         $source->source_name,
 108     ));
 109   }
 110
 111   return $1;
 112 }
 113
 114 # custom method for fetching column default, since column_info has a
 115 # bug with older versions of DBD::Pg
 116 sub _dbh_get_column_default {
 117   my ( $self, $dbh, $schema, $table, $col ) = @_;
 118
 119   # Build and execute a query into the pg_catalog to find the Pg
 120   # expression for the default value for this column in this table.
 121   # If the table name is schema-qualified, query using that specific
 122   # schema name.
 123
 124   # Otherwise, find the table in the standard Postgres way, using the
 125   # search path.  This is done with the pg_catalog.pg_table_is_visible
 126   # function, which returns true if a given table is 'visible',
 127   # meaning the first table of that name to be found in the search
 128   # path.
 129
 130   # I *think* we can be assured that this query will always find the
 131   # correct column according to standard Postgres semantics.
 132   #
 133   # -- rbuels
 134
 135   my $sqlmaker = $self->sql_maker;
 136   local $sqlmaker->{bindtype} = 'normal';
 137
 138   my ($where, @bind) = $sqlmaker->where ({
 139     'a.attnum' => {'>', 0},
 140     'c.relname' => $table,
 141     'a.attname' => $col,
 142     -not_bool => 'a.attisdropped',
 143     (defined $schema && length $schema)
 144       ? ( 'n.nspname' => $schema )
 145       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 146   });
 147
 148   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 149
 150 SELECT
 151   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 152    FROM pg_catalog.pg_attrdef d
 153    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 154 FROM pg_catalog.pg_class c
 155      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 156      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 157 $where
 158
 159 EOS
 160
 161   return $seq_expr;
 162 }
 163
 164
 165 sub sqlt_type {
 166   return 'PostgreSQL';
 167 }
 168
 169 sub datetime_parser_type { return "DateTime::Format::Pg"; }
 170
 171 sub bind_attribute_by_data_type {
 172   my ($self,$data_type) = @_;
 173
 174   my $bind_attributes = {
 175     bytea => { pg_type => DBD::Pg::PG_BYTEA },
 176     blob  => { pg_type => DBD::Pg::PG_BYTEA },
 177   };
 178
 179   if( defined $bind_attributes->{$data_type} ) {
 180     return $bind_attributes->{$data_type};
 181   }
 182   else {
 183     return;
 184   }
 185 }
 186
 187 sub _svp_begin {
 188     my ($self, $name) = @_;
 189
 190     $self->_get_dbh->pg_savepoint($name);
 191 }
 192
 193 sub _svp_release {
 194     my ($self, $name) = @_;
 195
 196     $self->_get_dbh->pg_release($name);
 197 }
 198
 199 sub _svp_rollback {
 200     my ($self, $name) = @_;
 201
 202     $self->_get_dbh->pg_rollback_to($name);
 203 }
 204
 205 sub deployment_statements {
 206   my $self = shift;;
 207   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 208
 209   $sqltargs ||= {};
 210
 211   if (
 212     ! exists $sqltargs->{producer_args}{postgres_version}
 213       and
 214     my $dver = $self->_server_info->{normalized_dbms_version}
 215   ) {
 216     $sqltargs->{producer_args}{postgres_version} = $dver;
 217   }
 218
 219   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 220 }
 221
 222 1;
 223
 224 __END__
 225
 226 =head1 NAME
 227
 228 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 229
 230 =head1 SYNOPSIS
 231
 232   # In your result (table) classes
 233   use base 'DBIx::Class::Core';
 234   __PACKAGE__->set_primary_key('id');
 235
 236 =head1 DESCRIPTION
 237
 238 This class implements autoincrements for PostgreSQL.
 239
 240 =head1 POSTGRESQL SCHEMA SUPPORT
 241
 242 This driver supports multiple PostgreSQL schemas, with one caveat: for
 243 performance reasons, data about the search path, sequence names, and
 244 so forth is queried as needed and CACHED for subsequent uses.
 245
 246 For this reason, once your schema is instantiated, you should not
 247 change the PostgreSQL schema search path for that schema's database
 248 connection. If you do, Bad Things may happen.
 249
 250 You should do any necessary manipulation of the search path BEFORE
 251 instantiating your schema object, or as part of the on_connect_do
 252 option to connect(), for example:
 253
 254    my $schema = My::Schema->connect
 255                   ( $dsn,$user,$pass,
 256                     { on_connect_do =>
 257                         [ 'SET search_path TO myschema, foo, public' ],
 258                     },
 259                   );
 260
 261 =head1 AUTHORS
 262
 263 See L<DBIx::Class/CONTRIBUTORS>
 264
 265 =head1 LICENSE
 266
 267 You may distribute this code under the same terms as Perl itself.
 268
 269 =cut