lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::Storage::DBI/;
   7
   8 use Scope::Guard ();
   9 use Context::Preserve 'preserve_context';
  10 use DBIx::Class::Carp;
  11 use Try::Tiny;
  12 use namespace::clean;
  13
  14 __PACKAGE__->sql_limit_dialect ('LimitOffset');
  15 __PACKAGE__->sql_quote_char ('"');
  16 __PACKAGE__->datetime_parser_type ('DateTime::Format::Pg');
  17 __PACKAGE__->_use_multicolumn_in (1);
  18
  19 sub _determine_supports_insert_returning {
  20   return shift->_server_info->{normalized_dbms_version} >= 8.002
  21     ? 1
  22     : 0
  23   ;
  24 }
  25
  26 sub with_deferred_fk_checks {
  27   my ($self, $sub) = @_;
  28
  29   my $txn_scope_guard = $self->txn_scope_guard;
  30
  31   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  32
  33   return preserve_context {
  34     my $sg = Scope::Guard->new(sub {
  35       $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  36     });
  37     $sub->()
  38   } after => sub { $txn_scope_guard->commit };
  39 }
  40
  41 # only used when INSERT ... RETURNING is disabled
  42 sub last_insert_id {
  43   my ($self,$source,@cols) = @_;
  44
  45   my @values;
  46
  47   my $col_info = $source->columns_info(\@cols);
  48
  49   for my $col (@cols) {
  50     my $seq = ( $col_info->{$col}{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  51       or $self->throw_exception( sprintf(
  52         "Could not determine sequence for column '%s.%s', please consider adding a schema-qualified sequence to its column info",
  53           $source->name,
  54           $col,
  55       ));
  56
  57     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  58   }
  59
  60   return @values;
  61 }
  62
  63 sub _sequence_fetch {
  64   my ($self, $function, $sequence) = @_;
  65
  66   $self->throw_exception('No sequence to fetch') unless $sequence;
  67
  68   my ($val) = $self->_get_dbh->selectrow_array(
  69     sprintf ("select %s('%s')", $function, (ref $sequence eq 'SCALAR') ? $$sequence : $sequence)
  70   );
  71
  72   return $val;
  73 }
  74
  75 sub _dbh_get_autoinc_seq {
  76   my ($self, $dbh, $source, $col) = @_;
  77
  78   my $schema;
  79   my $table = $source->name;
  80
  81   # deref table name if it needs it
  82   $table = $$table
  83       if ref $table eq 'SCALAR';
  84
  85   # parse out schema name if present
  86   if( $table =~ /^(.+)\.(.+)$/ ) {
  87     ( $schema, $table ) = ( $1, $2 );
  88   }
  89
  90   # get the column default using a Postgres-specific pg_catalog query
  91   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  92
  93   # if no default value is set on the column, or if we can't parse the
  94   # default value as a sequence, throw.
  95   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  96     $seq_expr = '' unless defined $seq_expr;
  97     $schema = "$schema." if defined $schema && length $schema;
  98     $self->throw_exception( sprintf (
  99       "No sequence found for '%s%s.%s', check the RDBMS table definition or explicitly set the ".
 100       "'sequence' for this column in %s",
 101         $schema ? "$schema." : '',
 102         $table,
 103         $col,
 104         $source->source_name,
 105     ));
 106   }
 107
 108   return $1;  # exception thrown unless match is made above
 109 }
 110
 111 # custom method for fetching column default, since column_info has a
 112 # bug with older versions of DBD::Pg
 113 sub _dbh_get_column_default {
 114   my ( $self, $dbh, $schema, $table, $col ) = @_;
 115
 116   # Build and execute a query into the pg_catalog to find the Pg
 117   # expression for the default value for this column in this table.
 118   # If the table name is schema-qualified, query using that specific
 119   # schema name.
 120
 121   # Otherwise, find the table in the standard Postgres way, using the
 122   # search path.  This is done with the pg_catalog.pg_table_is_visible
 123   # function, which returns true if a given table is 'visible',
 124   # meaning the first table of that name to be found in the search
 125   # path.
 126
 127   # I *think* we can be assured that this query will always find the
 128   # correct column according to standard Postgres semantics.
 129   #
 130   # -- rbuels
 131
 132   my $sqlmaker = $self->sql_maker;
 133   local $sqlmaker->{bindtype} = 'normal';
 134
 135   my ($where, @bind) = $sqlmaker->where ({
 136     'a.attnum' => {'>', 0},
 137     'c.relname' => $table,
 138     'a.attname' => $col,
 139     -not_bool => 'a.attisdropped',
 140     (defined $schema && length $schema)
 141       ? ( 'n.nspname' => $schema )
 142       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 143   });
 144
 145   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 146
 147 SELECT
 148   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 149    FROM pg_catalog.pg_attrdef d
 150    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 151 FROM pg_catalog.pg_class c
 152      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 153      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 154 $where
 155
 156 EOS
 157
 158   return $seq_expr;
 159 }
 160
 161
 162 sub sqlt_type {
 163   return 'PostgreSQL';
 164 }
 165
 166 sub bind_attribute_by_data_type {
 167   my ($self,$data_type) = @_;
 168
 169   if ($self->_is_binary_lob_type($data_type)) {
 170     # this is a hot-ish codepath, use an escape flag to minimize
 171     # amount of function/method calls
 172     # additionally version.pm is cock, and memleaks on multiple
 173     # ->VERSION calls
 174     # the flag is stored in the DBD namespace, so that Class::Unload
 175     # will work (unlikely, but still)
 176     unless ($DBD::Pg::__DBIC_DBD_VERSION_CHECK_DONE__) {
 177       if ($self->_server_info->{normalized_dbms_version} >= 9.0) {
 178         try { DBD::Pg->VERSION('2.17.2'); 1 } or carp (
 179           __PACKAGE__.': BYTEA columns are known to not work on Pg >= 9.0 with DBD::Pg < 2.17.2'
 180         );
 181       }
 182       elsif (not try { DBD::Pg->VERSION('2.9.2'); 1 } ) { carp (
 183         __PACKAGE__.': DBD::Pg 2.9.2 or greater is strongly recommended for BYTEA column support'
 184       )}
 185
 186       $DBD::Pg::__DBIC_DBD_VERSION_CHECK_DONE__ = 1;
 187     }
 188
 189     return { pg_type => DBD::Pg::PG_BYTEA() };
 190   }
 191   else {
 192     return undef;
 193   }
 194 }
 195
 196 sub _exec_svp_begin {
 197     my ($self, $name) = @_;
 198
 199     $self->_dbh->pg_savepoint($name);
 200 }
 201
 202 sub _exec_svp_release {
 203     my ($self, $name) = @_;
 204
 205     $self->_dbh->pg_release($name);
 206 }
 207
 208 sub _exec_svp_rollback {
 209     my ($self, $name) = @_;
 210
 211     $self->_dbh->pg_rollback_to($name);
 212 }
 213
 214 sub deployment_statements {
 215   my $self = shift;;
 216   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 217
 218   $sqltargs ||= {};
 219
 220   if (
 221     ! exists $sqltargs->{producer_args}{postgres_version}
 222       and
 223     my $dver = $self->_server_info->{normalized_dbms_version}
 224   ) {
 225     $sqltargs->{producer_args}{postgres_version} = $dver;
 226   }
 227
 228   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 229 }
 230
 231 1;
 232
 233 __END__
 234
 235 =head1 NAME
 236
 237 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 238
 239 =head1 SYNOPSIS
 240
 241   # In your result (table) classes
 242   use base 'DBIx::Class::Core';
 243   __PACKAGE__->set_primary_key('id');
 244
 245 =head1 DESCRIPTION
 246
 247 This class implements autoincrements for PostgreSQL.
 248
 249 =head1 POSTGRESQL SCHEMA SUPPORT
 250
 251 This driver supports multiple PostgreSQL schemas, with one caveat: for
 252 performance reasons, data about the search path, sequence names, and
 253 so forth is queried as needed and CACHED for subsequent uses.
 254
 255 For this reason, once your schema is instantiated, you should not
 256 change the PostgreSQL schema search path for that schema's database
 257 connection. If you do, Bad Things may happen.
 258
 259 You should do any necessary manipulation of the search path BEFORE
 260 instantiating your schema object, or as part of the on_connect_do
 261 option to connect(), for example:
 262
 263    my $schema = My::Schema->connect
 264                   ( $dsn,$user,$pass,
 265                     { on_connect_do =>
 266                         [ 'SET search_path TO myschema, foo, public' ],
 267                     },
 268                   );
 269
 270 =head1 FURTHER QUESTIONS?
 271
 272 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 273
 274 =head1 COPYRIGHT AND LICENSE
 275
 276 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 277 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 278 redistribute it and/or modify it under the same terms as the
 279 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.