lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::Storage::DBI::MultiColumnIn/;
   7 use mro 'c3';
   8
   9 use DBD::Pg qw(:pg_types);
  10
  11 # Ask for a DBD::Pg with array support
  12 warn "DBD::Pg 2.9.2 or greater is strongly recommended\n"
  13   if ($DBD::Pg::VERSION < 2.009002);  # pg uses (used?) version::qv()
  14
  15 sub with_deferred_fk_checks {
  16   my ($self, $sub) = @_;
  17
  18   $self->_get_dbh->do('SET CONSTRAINTS ALL DEFERRED');
  19   $sub->();
  20 }
  21
  22 sub last_insert_id {
  23   my ($self,$source,$col) = @_;
  24   my $seq = ( $source->column_info($col)->{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  25       or $self->throw_exception( "could not determine sequence for "
  26                                  . $source->name
  27                                  . ".$col, please consider adding a "
  28                                  . "schema-qualified sequence to its column info"
  29                                );
  30
  31   $self->_dbh_last_insert_id ($self->_dbh, $seq);
  32 }
  33
  34 # there seems to be absolutely no reason to have this as a separate method,
  35 # but leaving intact in case someone is already overriding it
  36 sub _dbh_last_insert_id {
  37   my ($self, $dbh, $seq) = @_;
  38   $dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  39 }
  40
  41
  42 sub _dbh_get_autoinc_seq {
  43   my ($self, $dbh, $source, $col) = @_;
  44
  45   my $schema;
  46   my $table = $source->name;
  47
  48   # deref table name if it needs it
  49   $table = $$table
  50       if ref $table eq 'SCALAR';
  51
  52   # parse out schema name if present
  53   if( $table =~ /^(.+)\.(.+)$/ ) {
  54     ( $schema, $table ) = ( $1, $2 );
  55   }
  56
  57   # Build and execute a query into the pg_catalog to find the Pg
  58   # expression for the default value for this column in this table.
  59   # If the table name is schema-qualified, query using that specific
  60   # schema name.
  61
  62   # Otherwise, find the table in the standard Postgres way, using the
  63   # search path.  This is done with the pg_catalog.pg_table_is_visible
  64   # function, which returns true if a given table is 'visible',
  65   # meaning the first table of that name to be found in the search
  66   # path.
  67
  68   # I *think* we can be assured that this query will always find the
  69   # correct column according to standard Postgres semantics.
  70   #
  71   # -- rbuels
  72
  73   my $sqlmaker = $self->sql_maker;
  74   local $sqlmaker->{bindtype} = 'normal';
  75
  76   my ($where, @bind) = $sqlmaker->where ({
  77     'a.attnum' => {'>', 0},
  78     'c.relname' => $table,
  79     'a.attname' => $col,
  80     -not_bool => 'a.attisdropped',
  81     (defined $schema && length $schema)
  82       ? ( 'n.nspname' => $schema )
  83       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
  84   });
  85
  86   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
  87
  88 SELECT
  89   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
  90    FROM pg_catalog.pg_attrdef d
  91    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
  92 FROM pg_catalog.pg_class c
  93      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
  94      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
  95 $where
  96
  97 EOS
  98
  99   # if no default value is set on the column, or if we can't parse the
 100   # default value as a sequence, throw.
 101   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ){
 102     $seq_expr = '' unless defined $seq_expr;
 103     $schema = "$schema." if defined $schema && length $schema;
 104     $self->throw_exception( "no sequence found for $schema$table.$col, check table definition, "
 105                             . "or explicitly set the 'sequence' for this column in the "
 106                             . $source->source_name
 107                             . " class"
 108                           );
 109   }
 110
 111   return $1;
 112 }
 113
 114 sub get_autoinc_seq {
 115   my ($self,$source,$col) = @_;
 116
 117 }
 118
 119 sub sqlt_type {
 120   return 'PostgreSQL';
 121 }
 122
 123 sub datetime_parser_type { return "DateTime::Format::Pg"; }
 124
 125 sub bind_attribute_by_data_type {
 126   my ($self,$data_type) = @_;
 127
 128   my $bind_attributes = {
 129     bytea => { pg_type => DBD::Pg::PG_BYTEA },
 130     blob  => { pg_type => DBD::Pg::PG_BYTEA },
 131   };
 132
 133   if( defined $bind_attributes->{$data_type} ) {
 134     return $bind_attributes->{$data_type};
 135   }
 136   else {
 137     return;
 138   }
 139 }
 140
 141 sub _sequence_fetch {
 142   my ( $self, $type, $seq ) = @_;
 143   my ($id) = $self->_get_dbh->selectrow_array("SELECT nextval('${seq}')");
 144   return $id;
 145 }
 146
 147 sub _svp_begin {
 148     my ($self, $name) = @_;
 149
 150     $self->_get_dbh->pg_savepoint($name);
 151 }
 152
 153 sub _svp_release {
 154     my ($self, $name) = @_;
 155
 156     $self->_get_dbh->pg_release($name);
 157 }
 158
 159 sub _svp_rollback {
 160     my ($self, $name) = @_;
 161
 162     $self->_get_dbh->pg_rollback_to($name);
 163 }
 164
 165 1;
 166
 167 __END__
 168
 169 =head1 NAME
 170
 171 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 172
 173 =head1 SYNOPSIS
 174
 175   # In your table classes
 176   __PACKAGE__->load_components(qw/PK::Auto Core/);
 177   __PACKAGE__->set_primary_key('id');
 178   __PACKAGE__->sequence('mysequence');
 179
 180 =head1 DESCRIPTION
 181
 182 This class implements autoincrements for PostgreSQL.
 183
 184 =head1 POSTGRESQL SCHEMA SUPPORT
 185
 186 This driver supports multiple PostgreSQL schemas, with one caveat: for
 187 performance reasons, data about the search path, sequence names, and
 188 so forth is queried as needed and CACHED for subsequent uses.
 189
 190 For this reason, once your schema is instantiated, you should not
 191 change the PostgreSQL schema search path for that schema's database
 192 connection. If you do, Bad Things may happen.
 193
 194 You should do any necessary manipulation of the search path BEFORE
 195 instantiating your schema object, or as part of the on_connect_do
 196 option to connect(), for example:
 197
 198    my $schema = My::Schema->connect
 199                   ( $dsn,$user,$pass,
 200                     { on_connect_do =>
 201                         [ 'SET search_path TO myschema, foo, public' ],
 202                     },
 203                   );
 204
 205 =head1 AUTHORS
 206
 207 See L<DBIx::Class/CONTRIBUTORS>
 208
 209 =head1 LICENSE
 210
 211 You may distribute this code under the same terms as Perl itself.
 212
 213 =cut