lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::Storage::DBI/;
   7
   8 use Scope::Guard ();
   9 use Scalar::Util 'weaken';
  10 use Context::Preserve 'preserve_context';
  11 use DBIx::Class::Carp;
  12 use Try::Tiny;
  13 use namespace::clean;
  14
  15 __PACKAGE__->sql_limit_dialect ('LimitOffset');
  16 __PACKAGE__->sql_quote_char ('"');
  17 __PACKAGE__->datetime_parser_type ('DateTime::Format::Pg');
  18 __PACKAGE__->_use_multicolumn_in (1);
  19
  20 sub _determine_supports_insert_returning {
  21   return shift->_server_info->{normalized_dbms_version} >= 8.002
  22     ? 1
  23     : 0
  24   ;
  25 }
  26
  27 sub with_deferred_fk_checks {
  28   my ($self, $sub) = @_;
  29
  30   my $txn_scope_guard = $self->txn_scope_guard;
  31
  32   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  33
  34   weaken($self);
  35   return preserve_context {
  36     my $sg = Scope::Guard->new(sub {
  37       $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  38     });
  39     $sub->()
  40   } after => sub { $txn_scope_guard->commit };
  41 }
  42
  43 # only used when INSERT ... RETURNING is disabled
  44 sub last_insert_id {
  45   my ($self,$source,@cols) = @_;
  46
  47   my @values;
  48
  49   my $col_info = $source->columns_info(\@cols);
  50
  51   for my $col (@cols) {
  52     my $seq = ( $col_info->{$col}{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  53       or $self->throw_exception( sprintf(
  54         "Could not determine sequence for column '%s.%s', please consider adding a schema-qualified sequence to its column info",
  55           $source->name,
  56           $col,
  57       ));
  58
  59     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  60   }
  61
  62   return @values;
  63 }
  64
  65 sub _sequence_fetch {
  66   my ($self, $function, $sequence) = @_;
  67
  68   $self->throw_exception('No sequence to fetch') unless $sequence;
  69
  70   my ($val) = $self->_get_dbh->selectrow_array(
  71     sprintf ("select %s('%s')", $function, (ref $sequence eq 'SCALAR') ? $$sequence : $sequence)
  72   );
  73
  74   return $val;
  75 }
  76
  77 sub _dbh_get_autoinc_seq {
  78   my ($self, $dbh, $source, $col) = @_;
  79
  80   my $schema;
  81   my $table = $source->name;
  82
  83   # deref table name if it needs it
  84   $table = $$table
  85       if ref $table eq 'SCALAR';
  86
  87   # parse out schema name if present
  88   if( $table =~ /^(.+)\.(.+)$/ ) {
  89     ( $schema, $table ) = ( $1, $2 );
  90   }
  91
  92   # get the column default using a Postgres-specific pg_catalog query
  93   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  94
  95   # if no default value is set on the column, or if we can't parse the
  96   # default value as a sequence, throw.
  97   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  98     $seq_expr = '' unless defined $seq_expr;
  99     $schema = "$schema." if defined $schema && length $schema;
 100     $self->throw_exception( sprintf (
 101       "No sequence found for '%s%s.%s', check the RDBMS table definition or explicitly set the ".
 102       "'sequence' for this column in %s",
 103         $schema ? "$schema." : '',
 104         $table,
 105         $col,
 106         $source->source_name,
 107     ));
 108   }
 109
 110   return $1;  # exception thrown unless match is made above
 111 }
 112
 113 # custom method for fetching column default, since column_info has a
 114 # bug with older versions of DBD::Pg
 115 sub _dbh_get_column_default {
 116   my ( $self, $dbh, $schema, $table, $col ) = @_;
 117
 118   # Build and execute a query into the pg_catalog to find the Pg
 119   # expression for the default value for this column in this table.
 120   # If the table name is schema-qualified, query using that specific
 121   # schema name.
 122
 123   # Otherwise, find the table in the standard Postgres way, using the
 124   # search path.  This is done with the pg_catalog.pg_table_is_visible
 125   # function, which returns true if a given table is 'visible',
 126   # meaning the first table of that name to be found in the search
 127   # path.
 128
 129   # I *think* we can be assured that this query will always find the
 130   # correct column according to standard Postgres semantics.
 131   #
 132   # -- rbuels
 133
 134   my $sqlmaker = $self->sql_maker;
 135   local $sqlmaker->{bindtype} = 'normal';
 136
 137   my ($where, @bind) = $sqlmaker->where ({
 138     'a.attnum' => {'>', 0},
 139     'c.relname' => $table,
 140     'a.attname' => $col,
 141     -not_bool => 'a.attisdropped',
 142     (defined $schema && length $schema)
 143       ? ( 'n.nspname' => $schema )
 144       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 145   });
 146
 147   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 148
 149 SELECT
 150   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 151    FROM pg_catalog.pg_attrdef d
 152    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 153 FROM pg_catalog.pg_class c
 154      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 155      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 156 $where
 157
 158 EOS
 159
 160   return $seq_expr;
 161 }
 162
 163
 164 sub sqlt_type {
 165   return 'PostgreSQL';
 166 }
 167
 168 sub bind_attribute_by_data_type {
 169   my ($self,$data_type) = @_;
 170
 171   if ($self->_is_binary_lob_type($data_type)) {
 172     # this is a hot-ish codepath, use an escape flag to minimize
 173     # amount of function/method calls
 174     # additionally version.pm is cock, and memleaks on multiple
 175     # ->VERSION calls
 176     # the flag is stored in the DBD namespace, so that Class::Unload
 177     # will work (unlikely, but still)
 178     unless ($DBD::Pg::__DBIC_DBD_VERSION_CHECK_DONE__) {
 179       if ($self->_server_info->{normalized_dbms_version} >= 9.0) {
 180         try { DBD::Pg->VERSION('2.17.2'); 1 } or carp (
 181           __PACKAGE__.': BYTEA columns are known to not work on Pg >= 9.0 with DBD::Pg < 2.17.2'
 182         );
 183       }
 184       elsif (not try { DBD::Pg->VERSION('2.9.2'); 1 } ) { carp (
 185         __PACKAGE__.': DBD::Pg 2.9.2 or greater is strongly recommended for BYTEA column support'
 186       )}
 187
 188       $DBD::Pg::__DBIC_DBD_VERSION_CHECK_DONE__ = 1;
 189     }
 190
 191     return { pg_type => DBD::Pg::PG_BYTEA() };
 192   }
 193   else {
 194     return undef;
 195   }
 196 }
 197
 198 sub _exec_svp_begin {
 199     my ($self, $name) = @_;
 200
 201     $self->_dbh->pg_savepoint($name);
 202 }
 203
 204 sub _exec_svp_release {
 205     my ($self, $name) = @_;
 206
 207     $self->_dbh->pg_release($name);
 208 }
 209
 210 sub _exec_svp_rollback {
 211     my ($self, $name) = @_;
 212
 213     $self->_dbh->pg_rollback_to($name);
 214 }
 215
 216 sub deployment_statements {
 217   my $self = shift;;
 218   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 219
 220   $sqltargs ||= {};
 221
 222   if (
 223     ! exists $sqltargs->{producer_args}{postgres_version}
 224       and
 225     my $dver = $self->_server_info->{normalized_dbms_version}
 226   ) {
 227     $sqltargs->{producer_args}{postgres_version} = $dver;
 228   }
 229
 230   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 231 }
 232
 233 1;
 234
 235 __END__
 236
 237 =head1 NAME
 238
 239 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 240
 241 =head1 SYNOPSIS
 242
 243   # In your result (table) classes
 244   use base 'DBIx::Class::Core';
 245   __PACKAGE__->set_primary_key('id');
 246
 247 =head1 DESCRIPTION
 248
 249 This class implements autoincrements for PostgreSQL.
 250
 251 =head1 POSTGRESQL SCHEMA SUPPORT
 252
 253 This driver supports multiple PostgreSQL schemas, with one caveat: for
 254 performance reasons, data about the search path, sequence names, and
 255 so forth is queried as needed and CACHED for subsequent uses.
 256
 257 For this reason, once your schema is instantiated, you should not
 258 change the PostgreSQL schema search path for that schema's database
 259 connection. If you do, Bad Things may happen.
 260
 261 You should do any necessary manipulation of the search path BEFORE
 262 instantiating your schema object, or as part of the on_connect_do
 263 option to connect(), for example:
 264
 265    my $schema = My::Schema->connect
 266                   ( $dsn,$user,$pass,
 267                     { on_connect_do =>
 268                         [ 'SET search_path TO myschema, foo, public' ],
 269                     },
 270                   );
 271
 272 =head1 FURTHER QUESTIONS?
 273
 274 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 275
 276 =head1 COPYRIGHT AND LICENSE
 277
 278 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 279 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 280 redistribute it and/or modify it under the same terms as the
 281 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.