lib/DBIx/Class/Storage/DBI/Pg.pm

   1 package DBIx::Class::Storage::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/
   7     DBIx::Class::Storage::DBI::MultiColumnIn
   8 /;
   9 use mro 'c3';
  10
  11 use Scope::Guard ();
  12 use Context::Preserve 'preserve_context';
  13 use DBIx::Class::Carp;
  14 use Try::Tiny;
  15 use namespace::clean;
  16
  17 __PACKAGE__->sql_maker_class('DBIx::Class::SQLMaker::Pg');
  18 __PACKAGE__->sql_limit_dialect ('LimitOffset');
  19 __PACKAGE__->sql_quote_char ('"');
  20 __PACKAGE__->datetime_parser_type ('DateTime::Format::Pg');
  21
  22 sub _determine_supports_insert_returning {
  23   return shift->_server_info->{normalized_dbms_version} >= 8.002
  24     ? 1
  25     : 0
  26   ;
  27 }
  28
  29 sub with_deferred_fk_checks {
  30   my ($self, $sub) = @_;
  31
  32   my $txn_scope_guard = $self->txn_scope_guard;
  33
  34   $self->_do_query('SET CONSTRAINTS ALL DEFERRED');
  35
  36   my $sg = Scope::Guard->new(sub {
  37     $self->_do_query('SET CONSTRAINTS ALL IMMEDIATE');
  38   });
  39
  40   return preserve_context { $sub->() } after => sub { $txn_scope_guard->commit };
  41 }
  42
  43 # only used when INSERT ... RETURNING is disabled
  44 sub last_insert_id {
  45   my ($self,$source,@cols) = @_;
  46
  47   my @values;
  48
  49   my $col_info = $source->columns_info(\@cols);
  50
  51   for my $col (@cols) {
  52     my $seq = ( $col_info->{$col}{sequence} ||= $self->dbh_do('_dbh_get_autoinc_seq', $source, $col) )
  53       or $self->throw_exception( sprintf(
  54         'could not determine sequence for column %s.%s, please consider adding a schema-qualified sequence to its column info',
  55           $source->name,
  56           $col,
  57       ));
  58
  59     push @values, $self->_dbh->last_insert_id(undef, undef, undef, undef, {sequence => $seq});
  60   }
  61
  62   return @values;
  63 }
  64
  65 sub _sequence_fetch {
  66   my ($self, $function, $sequence) = @_;
  67
  68   $self->throw_exception('No sequence to fetch') unless $sequence;
  69
  70   my ($val) = $self->_get_dbh->selectrow_array(
  71     sprintf ("select %s('%s')", $function, (ref $sequence eq 'SCALAR') ? $$sequence : $sequence)
  72   );
  73
  74   return $val;
  75 }
  76
  77 sub _dbh_get_autoinc_seq {
  78   my ($self, $dbh, $source, $col) = @_;
  79
  80   my $schema;
  81   my $table = $source->name;
  82
  83   # deref table name if it needs it
  84   $table = $$table
  85       if ref $table eq 'SCALAR';
  86
  87   # parse out schema name if present
  88   if( $table =~ /^(.+)\.(.+)$/ ) {
  89     ( $schema, $table ) = ( $1, $2 );
  90   }
  91
  92   # get the column default using a Postgres-specific pg_catalog query
  93   my $seq_expr = $self->_dbh_get_column_default( $dbh, $schema, $table, $col );
  94
  95   # if no default value is set on the column, or if we can't parse the
  96   # default value as a sequence, throw.
  97   unless ( defined $seq_expr and $seq_expr =~ /^nextval\(+'([^']+)'::(?:text|regclass)\)/i ) {
  98     $seq_expr = '' unless defined $seq_expr;
  99     $schema = "$schema." if defined $schema && length $schema;
 100     $self->throw_exception( sprintf (
 101       'no sequence found for %s%s.%s, check the RDBMS table definition or explicitly set the '.
 102       "'sequence' for this column in %s",
 103         $schema ? "$schema." : '',
 104         $table,
 105         $col,
 106         $source->source_name,
 107     ));
 108   }
 109
 110   return $1;
 111 }
 112
 113 # custom method for fetching column default, since column_info has a
 114 # bug with older versions of DBD::Pg
 115 sub _dbh_get_column_default {
 116   my ( $self, $dbh, $schema, $table, $col ) = @_;
 117
 118   # Build and execute a query into the pg_catalog to find the Pg
 119   # expression for the default value for this column in this table.
 120   # If the table name is schema-qualified, query using that specific
 121   # schema name.
 122
 123   # Otherwise, find the table in the standard Postgres way, using the
 124   # search path.  This is done with the pg_catalog.pg_table_is_visible
 125   # function, which returns true if a given table is 'visible',
 126   # meaning the first table of that name to be found in the search
 127   # path.
 128
 129   # I *think* we can be assured that this query will always find the
 130   # correct column according to standard Postgres semantics.
 131   #
 132   # -- rbuels
 133
 134   my $sqlmaker = $self->sql_maker;
 135   local $sqlmaker->{bindtype} = 'normal';
 136
 137   my ($where, @bind) = $sqlmaker->where ({
 138     'a.attnum' => {'>', 0},
 139     'c.relname' => $table,
 140     'a.attname' => $col,
 141     -not_bool => 'a.attisdropped',
 142     (defined $schema && length $schema)
 143       ? ( 'n.nspname' => $schema )
 144       : ( -bool => \'pg_catalog.pg_table_is_visible(c.oid)' )
 145   });
 146
 147   my ($seq_expr) = $dbh->selectrow_array(<<EOS,undef,@bind);
 148
 149 SELECT
 150   (SELECT pg_catalog.pg_get_expr(d.adbin, d.adrelid)
 151    FROM pg_catalog.pg_attrdef d
 152    WHERE d.adrelid = a.attrelid AND d.adnum = a.attnum AND a.atthasdef)
 153 FROM pg_catalog.pg_class c
 154      LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 155      JOIN pg_catalog.pg_attribute a ON a.attrelid = c.oid
 156 $where
 157
 158 EOS
 159
 160   return $seq_expr;
 161 }
 162
 163
 164 sub sqlt_type {
 165   return 'PostgreSQL';
 166 }
 167
 168 my $type_cache;
 169 sub bind_attribute_by_data_type {
 170   my ($self,$data_type) = @_;
 171
 172   # Ask for a DBD::Pg with array support
 173   # pg uses (used?) version::qv()
 174   require DBD::Pg;
 175
 176   if ($self->_server_info->{normalized_dbms_version} >= 9.0) {
 177     if (not try { DBD::Pg->VERSION('2.17.2') }) {
 178       carp_once( __PACKAGE__.': BYTEA columns are known to not work on Pg >='
 179         . " 9.0 with DBD::Pg < 2.17.2\n" );
 180     }
 181   }
 182   elsif (not try { DBD::Pg->VERSION('2.9.2') }) {
 183     carp_once( __PACKAGE__.': DBD::Pg 2.9.2 or greater is strongly recommended'
 184       . "for BYTEA column support.\n" );
 185   }
 186   my $bind_attributes = {
 187     bytea => { pg_type => DBD::Pg::PG_BYTEA() },
 188     blob  => { pg_type => DBD::Pg::PG_BYTEA() },
 189     timestamp  => { pg_type => DBD::Pg::PG_TIMESTAMP() },
 190   };
 191
 192   if( defined $bind_attributes->{$data_type} ) {
 193     return $bind_attributes->{$data_type};
 194   }
 195
 196   # cache the result of _is_binary_lob_type
 197   if (!exists $type_cache->{$data_type}) {
 198     $type_cache->{$data_type} = $self->_is_binary_lob_type($data_type)
 199       ? +{ pg_type => DBD::Pg::PG_BYTEA() }
 200       : undef
 201   }
 202
 203   $type_cache->{$data_type};
 204 }
 205
 206 sub _exec_svp_begin {
 207     my ($self, $name) = @_;
 208
 209     $self->_dbh->pg_savepoint($name);
 210 }
 211
 212 sub _exec_svp_release {
 213     my ($self, $name) = @_;
 214
 215     $self->_dbh->pg_release($name);
 216 }
 217
 218 sub _exec_svp_rollback {
 219     my ($self, $name) = @_;
 220
 221     $self->_dbh->pg_rollback_to($name);
 222 }
 223
 224 sub deployment_statements {
 225   my $self = shift;;
 226   my ($schema, $type, $version, $dir, $sqltargs, @rest) = @_;
 227
 228   $sqltargs ||= {};
 229
 230   if (
 231     ! exists $sqltargs->{producer_args}{postgres_version}
 232       and
 233     my $dver = $self->_server_info->{normalized_dbms_version}
 234   ) {
 235     $sqltargs->{producer_args}{postgres_version} = $dver;
 236   }
 237
 238   $self->next::method($schema, $type, $version, $dir, $sqltargs, @rest);
 239 }
 240
 241 1;
 242
 243 __END__
 244
 245 =head1 NAME
 246
 247 DBIx::Class::Storage::DBI::Pg - Automatic primary key class for PostgreSQL
 248
 249 =head1 SYNOPSIS
 250
 251   # In your result (table) classes
 252   use base 'DBIx::Class::Core';
 253   __PACKAGE__->set_primary_key('id');
 254
 255 =head1 DESCRIPTION
 256
 257 This class implements autoincrements for PostgreSQL.
 258
 259 =head1 POSTGRESQL SCHEMA SUPPORT
 260
 261 This driver supports multiple PostgreSQL schemas, with one caveat: for
 262 performance reasons, data about the search path, sequence names, and
 263 so forth is queried as needed and CACHED for subsequent uses.
 264
 265 For this reason, once your schema is instantiated, you should not
 266 change the PostgreSQL schema search path for that schema's database
 267 connection. If you do, Bad Things may happen.
 268
 269 You should do any necessary manipulation of the search path BEFORE
 270 instantiating your schema object, or as part of the on_connect_do
 271 option to connect(), for example:
 272
 273    my $schema = My::Schema->connect
 274                   ( $dsn,$user,$pass,
 275                     { on_connect_do =>
 276                         [ 'SET search_path TO myschema, foo, public' ],
 277                     },
 278                   );
 279
 280 =head1 AUTHORS
 281
 282 See L<DBIx::Class/CONTRIBUTORS>
 283
 284 =head1 LICENSE
 285
 286 You may distribute this code under the same terms as Perl itself.
 287
 288 =cut