lib/DBIx/Class/Storage/DBI/Oracle/Generic.pm

   1 package DBIx::Class::Storage::DBI::Oracle::Generic;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use strict;
   5 use warnings;
   6
   7 =head1 NAME
   8
   9 DBIx::Class::Storage::DBI::Oracle::Generic - Automatic primary key class for Oracle
  10
  11 =head1 SYNOPSIS
  12
  13   # In your table classes
  14   __PACKAGE__->load_components(qw/PK::Auto Core/);
  15   __PACKAGE__->add_columns({ id => { sequence => 'mysequence', auto_nextval => 1 } });
  16   __PACKAGE__->set_primary_key('id');
  17   __PACKAGE__->sequence('mysequence');
  18
  19 =head1 DESCRIPTION
  20
  21 This class implements autoincrements for Oracle.
  22
  23 =head1 METHODS
  24
  25 =cut
  26
  27 use Carp::Clan qw/^DBIx::Class/;
  28
  29 use base qw/DBIx::Class::Storage::DBI::MultiDistinctEmulation/;
  30
  31 # __PACKAGE__->load_components(qw/PK::Auto/);
  32
  33 sub _dbh_last_insert_id {
  34   my ($self, $dbh, $source, @columns) = @_;
  35   my @ids = ();
  36   foreach my $col (@columns) {
  37     my $seq = ($source->column_info($col)->{sequence} ||= $self->get_autoinc_seq($source,$col));
  38     my $id = $self->_sequence_fetch( 'currval', $seq );
  39     push @ids, $id;
  40   }
  41   return @ids;
  42 }
  43
  44 sub _dbh_get_autoinc_seq {
  45   my ($self, $dbh, $source, $col) = @_;
  46
  47   # look up the correct sequence automatically
  48   my $sql = q{
  49     SELECT trigger_body FROM ALL_TRIGGERS t
  50     WHERE t.table_name = ?
  51     AND t.triggering_event = 'INSERT'
  52     AND t.status = 'ENABLED'
  53   };
  54
  55   # trigger_body is a LONG
  56   $dbh->{LongReadLen} = 64 * 1024 if ($dbh->{LongReadLen} < 64 * 1024);
  57
  58   my $sth = $dbh->prepare($sql);
  59   $sth->execute( uc($source->name) );
  60   while (my ($insert_trigger) = $sth->fetchrow_array) {
  61     return uc($1) if $insert_trigger =~ m!(\w+)\.nextval!i; # col name goes here???
  62   }
  63   $self->throw_exception("Unable to find a sequence INSERT trigger on table '" . $source->name . "'.");
  64 }
  65
  66 sub _sequence_fetch {
  67   my ( $self, $type, $seq ) = @_;
  68   my ($id) = $self->dbh->selectrow_array("SELECT ${seq}.${type} FROM DUAL");
  69   return $id;
  70 }
  71
  72 sub _dbh_execute {
  73   my $self = shift;
  74   my ($dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
  75
  76   my $wantarray = wantarray;
  77   my @res;
  78   my $exception;
  79
  80   my $try = 2;
  81
  82   while ($try--) {
  83     eval {
  84       if ($wantarray) {
  85         @res    = $self->SUPER::_dbh_execute(@_);
  86       } else {
  87         $res[0] = $self->SUPER::_dbh_execute(@_);
  88       }
  89     };
  90     $exception = $@;
  91     if ($exception =~ /ORA-(?:00028|01012)/) {
  92 # ORA-00028: your session has been killed
  93 # ORA-01012: not logged on
  94       $self->disconnect;
  95
  96       $self->throw_exception($exception) if $self->{_in_dbh_do};
  97
  98       $self->ensure_connected;
  99     } elsif ($exception =~ /ORA-01003/) { # invalid cursor
 100 # ORA-01003: no statement parsed (someone renamed a column or something,
 101 # invalidating your cursor.)
 102       my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 103       delete $dbh->{CachedKids}{$sql};
 104     } else {
 105       last;
 106     }
 107   }
 108
 109   $self->throw_exception($exception) if $exception;
 110
 111   wantarray ? @res : $res[0]
 112 }
 113
 114 =head2 get_autoinc_seq
 115
 116 Returns the sequence name for an autoincrement column
 117
 118 =cut
 119
 120 sub get_autoinc_seq {
 121   my ($self, $source, $col) = @_;
 122
 123   $self->dbh_do('_dbh_get_autoinc_seq', $source, $col);
 124 }
 125
 126 =head2 columns_info_for
 127
 128 This wraps the superclass version of this method to force table
 129 names to uppercase
 130
 131 =cut
 132
 133 sub columns_info_for {
 134   my ($self, $table) = @_;
 135
 136   $self->next::method(uc($table));
 137 }
 138
 139 =head2 datetime_parser_type
 140
 141 This sets the proper DateTime::Format module for use with
 142 L<DBIx::Class::InflateColumn::DateTime>.
 143
 144 =cut
 145
 146 sub datetime_parser_type { return "DateTime::Format::Oracle"; }
 147
 148 sub _svp_begin {
 149     my ($self, $name) = @_;
 150
 151     $self->dbh->do("SAVEPOINT $name");
 152 }
 153
 154 # Oracle automatically releases a savepoint when you start another one with the
 155 # same name.
 156 sub _svp_release { 1 }
 157
 158 sub _svp_rollback {
 159     my ($self, $name) = @_;
 160
 161     $self->dbh->do("ROLLBACK TO SAVEPOINT $name")
 162 }
 163
 164 =head1 AUTHORS
 165
 166 Andy Grundman <andy@hybridized.org>
 167
 168 Scott Connelly <scottsweep@yahoo.com>
 169
 170 =head1 LICENSE
 171
 172 You may distribute this code under the same terms as Perl itself.
 173
 174 =cut
 175
 176 1;