lib/DBIx/Class/Storage/DBI/MSSQL.pm

   1 package DBIx::Class::Storage::DBI::MSSQL;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::Storage::DBI::UniqueIdentifier/;
   7 use mro 'c3';
   8
   9 use List::Util();
  10
  11 __PACKAGE__->mk_group_accessors(simple => qw/
  12   _identity _identity_method
  13 /);
  14
  15 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks::MSSQL');
  16
  17 sub _set_identity_insert {
  18   my ($self, $table) = @_;
  19
  20   my $sql = sprintf (
  21     'SET IDENTITY_INSERT %s ON',
  22     $self->sql_maker->_quote ($table),
  23   );
  24
  25   my $dbh = $self->_get_dbh;
  26   eval { $dbh->do ($sql) };
  27   if ($@) {
  28     $self->throw_exception (sprintf "Error executing '%s': %s",
  29       $sql,
  30       $dbh->errstr,
  31     );
  32   }
  33 }
  34
  35 sub _unset_identity_insert {
  36   my ($self, $table) = @_;
  37
  38   my $sql = sprintf (
  39     'SET IDENTITY_INSERT %s OFF',
  40     $self->sql_maker->_quote ($table),
  41   );
  42
  43   my $dbh = $self->_get_dbh;
  44   $dbh->do ($sql);
  45 }
  46
  47 sub insert_bulk {
  48   my $self = shift;
  49   my ($source, $cols, $data) = @_;
  50
  51   my $is_identity_insert = (List::Util::first
  52       { $source->column_info ($_)->{is_auto_increment} }
  53       (@{$cols})
  54   )
  55      ? 1
  56      : 0;
  57
  58   if ($is_identity_insert) {
  59      $self->_set_identity_insert ($source->name);
  60   }
  61
  62   $self->next::method(@_);
  63
  64   if ($is_identity_insert) {
  65      $self->_unset_identity_insert ($source->name);
  66   }
  67 }
  68
  69 sub insert {
  70   my $self = shift;
  71   my ($source, $to_insert) = @_;
  72
  73   my $supplied_col_info = $self->_resolve_column_info($source, [keys %$to_insert] );
  74
  75   my $is_identity_insert = (List::Util::first { $_->{is_auto_increment} } (values %$supplied_col_info) )
  76      ? 1
  77      : 0;
  78
  79   if ($is_identity_insert) {
  80      $self->_set_identity_insert ($source->name);
  81   }
  82
  83   my $updated_cols = $self->next::method(@_);
  84
  85   if ($is_identity_insert) {
  86      $self->_unset_identity_insert ($source->name);
  87   }
  88
  89   return $updated_cols;
  90 }
  91
  92 sub _prep_for_execute {
  93   my $self = shift;
  94   my ($op, $extra_bind, $ident, $args) = @_;
  95
  96 # cast MONEY values properly
  97   if ($op eq 'insert' || $op eq 'update') {
  98     my $fields = $args->[0];
  99
 100     for my $col (keys %$fields) {
 101       # $ident is a result source object with INSERT/UPDATE ops
 102       if ($ident->column_info ($col)->{data_type}
 103          &&
 104          $ident->column_info ($col)->{data_type} =~ /^money\z/i) {
 105         my $val = $fields->{$col};
 106         $fields->{$col} = \['CAST(? AS MONEY)', [ $col => $val ]];
 107       }
 108     }
 109   }
 110
 111   my ($sql, $bind) = $self->next::method (@_);
 112
 113   if ($op eq 'insert') {
 114     $sql .= ';SELECT SCOPE_IDENTITY()';
 115
 116   }
 117
 118   return ($sql, $bind);
 119 }
 120
 121 sub _execute {
 122   my $self = shift;
 123   my ($op) = @_;
 124
 125   my ($rv, $sth, @bind) = $self->dbh_do($self->can('_dbh_execute'), @_);
 126
 127   if ($op eq 'insert') {
 128
 129     # this should bring back the result of SELECT SCOPE_IDENTITY() we tacked
 130     # on in _prep_for_execute above
 131     my ($identity) = eval { $sth->fetchrow_array };
 132
 133     # SCOPE_IDENTITY failed, but we can do something else
 134     if ( (! $identity) && $self->_identity_method) {
 135       ($identity) = $self->_dbh->selectrow_array(
 136         'select ' . $self->_identity_method
 137       );
 138     }
 139
 140     $self->_identity($identity);
 141     $sth->finish;
 142   }
 143
 144   return wantarray ? ($rv, $sth, @bind) : $rv;
 145 }
 146
 147 sub last_insert_id { shift->_identity }
 148
 149 #
 150 # MSSQL is retarded wrt ordered subselects. One needs to add a TOP
 151 # to *all* subqueries, but one also can't use TOP 100 PERCENT
 152 # http://sqladvice.com/forums/permalink/18496/22931/ShowThread.aspx#22931
 153 #
 154 sub _select_args_to_query {
 155   my $self = shift;
 156
 157   my ($sql, $prep_bind, @rest) = $self->next::method (@_);
 158
 159   # see if this is an ordered subquery
 160   my $attrs = $_[3];
 161   if (
 162     $sql !~ /^ \s* SELECT \s+ TOP \s+ \d+ \s+ /xi
 163       &&
 164     scalar $self->_parse_order_by ($attrs->{order_by})
 165   ) {
 166     $self->throw_exception(
 167       'An ordered subselect encountered - this is not safe! Please see "Ordered Subselects" in DBIx::Class::Storage::DBI::MSSQL
 168     ') unless $attrs->{unsafe_subselect_ok};
 169     my $max = 2 ** 32;
 170     $sql =~ s/^ \s* SELECT \s/SELECT TOP $max /xi;
 171   }
 172
 173   return wantarray
 174     ? ($sql, $prep_bind, @rest)
 175     : \[ "($sql)", @$prep_bind ]
 176   ;
 177 }
 178
 179
 180 # savepoint syntax is the same as in Sybase ASE
 181
 182 sub _svp_begin {
 183   my ($self, $name) = @_;
 184
 185   $self->_get_dbh->do("SAVE TRANSACTION $name");
 186 }
 187
 188 # A new SAVE TRANSACTION with the same name releases the previous one.
 189 sub _svp_release { 1 }
 190
 191 sub _svp_rollback {
 192   my ($self, $name) = @_;
 193
 194   $self->_get_dbh->do("ROLLBACK TRANSACTION $name");
 195 }
 196
 197 sub datetime_parser_type {
 198   'DBIx::Class::Storage::DBI::MSSQL::DateTime::Format'
 199 }
 200
 201 sub sqlt_type { 'SQLServer' }
 202
 203 sub sql_maker {
 204   my $self = shift;
 205
 206   unless ($self->_sql_maker) {
 207     unless ($self->{_sql_maker_opts}{limit_dialect}) {
 208
 209       my $version = $self->_server_info->{normalized_dbms_version} || 0;
 210
 211       $self->{_sql_maker_opts} = {
 212         limit_dialect => ($version >= 9 ? 'RowNumberOver' : 'Top'),
 213         %{$self->{_sql_maker_opts}||{}}
 214       };
 215     }
 216
 217     my $maker = $self->next::method (@_);
 218   }
 219
 220   return $self->_sql_maker;
 221 }
 222
 223 sub _ping {
 224   my $self = shift;
 225
 226   my $dbh = $self->_dbh or return 0;
 227
 228   local $dbh->{RaiseError} = 1;
 229   local $dbh->{PrintError} = 0;
 230
 231   eval {
 232     $dbh->do('select 1');
 233   };
 234
 235   return $@ ? 0 : 1;
 236 }
 237
 238 package # hide from PAUSE
 239   DBIx::Class::Storage::DBI::MSSQL::DateTime::Format;
 240
 241 my $datetime_format      = '%Y-%m-%d %H:%M:%S.%3N'; # %F %T
 242 my $smalldatetime_format = '%Y-%m-%d %H:%M:%S';
 243
 244 my ($datetime_parser, $smalldatetime_parser);
 245
 246 sub parse_datetime {
 247   shift;
 248   require DateTime::Format::Strptime;
 249   $datetime_parser ||= DateTime::Format::Strptime->new(
 250     pattern  => $datetime_format,
 251     on_error => 'croak',
 252   );
 253   return $datetime_parser->parse_datetime(shift);
 254 }
 255
 256 sub format_datetime {
 257   shift;
 258   require DateTime::Format::Strptime;
 259   $datetime_parser ||= DateTime::Format::Strptime->new(
 260     pattern  => $datetime_format,
 261     on_error => 'croak',
 262   );
 263   return $datetime_parser->format_datetime(shift);
 264 }
 265
 266 sub parse_smalldatetime {
 267   shift;
 268   require DateTime::Format::Strptime;
 269   $smalldatetime_parser ||= DateTime::Format::Strptime->new(
 270     pattern  => $smalldatetime_format,
 271     on_error => 'croak',
 272   );
 273   return $smalldatetime_parser->parse_datetime(shift);
 274 }
 275
 276 sub format_smalldatetime {
 277   shift;
 278   require DateTime::Format::Strptime;
 279   $smalldatetime_parser ||= DateTime::Format::Strptime->new(
 280     pattern  => $smalldatetime_format,
 281     on_error => 'croak',
 282   );
 283   return $smalldatetime_parser->format_datetime(shift);
 284 }
 285
 286 1;
 287
 288 =head1 NAME
 289
 290 DBIx::Class::Storage::DBI::MSSQL - Base Class for Microsoft SQL Server support
 291 in DBIx::Class
 292
 293 =head1 SYNOPSIS
 294
 295 This is the base class for Microsoft SQL Server support, used by
 296 L<DBIx::Class::Storage::DBI::ODBC::Microsoft_SQL_Server> and
 297 L<DBIx::Class::Storage::DBI::Sybase::Microsoft_SQL_Server>.
 298
 299 =head1 IMPLEMENTATION NOTES
 300
 301 =head2 IDENTITY information
 302
 303 Microsoft SQL Server supports three methods of retrieving the IDENTITY
 304 value for inserted row: IDENT_CURRENT, @@IDENTITY, and SCOPE_IDENTITY().
 305 SCOPE_IDENTITY is used here because it is the safest.  However, it must
 306 be called is the same execute statement, not just the same connection.
 307
 308 So, this implementation appends a SELECT SCOPE_IDENTITY() statement
 309 onto each INSERT to accommodate that requirement.
 310
 311 C<SELECT @@IDENTITY> can also be used by issuing:
 312
 313   $self->_identity_method('@@identity');
 314
 315 it will only be used if SCOPE_IDENTITY() fails.
 316
 317 This is more dangerous, as inserting into a table with an on insert trigger that
 318 inserts into another table with an identity will give erroneous results on
 319 recent versions of SQL Server.
 320
 321 =head2 identity insert
 322
 323 Be aware that we have tried to make things as simple as possible for our users.
 324 For MSSQL that means that when a user tries to create a row, while supplying an
 325 explicit value for an autoincrementing column, we will try to issue the
 326 appropriate database call to make this possible, namely C<SET IDENTITY_INSERT
 327 $table_name ON>. Unfortunately this operation in MSSQL requires the
 328 C<db_ddladmin> privilege, which is normally not included in the standard
 329 write-permissions.
 330
 331 =head2 Ordered Subselects
 332
 333 If you attempted the following query (among many others) in Microsoft SQL
 334 Server
 335
 336  $rs->search ({}, {
 337   prefetch => 'relation',
 338   rows => 2,
 339   offset => 3,
 340  });
 341
 342 You may be surprised to receive an exception. The reason for this is a quirk
 343 in the MSSQL engine itself, and sadly doesn't have a sensible workaround due
 344 to the way DBIC is built. DBIC can do truly wonderful things with the aid of
 345 subselects, and does so automatically when necessary. The list of situations
 346 when a subselect is necessary is long and still changes often, so it can not
 347 be exhaustively enumerated here. The general rule of thumb is a joined
 348 L<has_many|DBIx::Class::Relationship/has_many> relationship with limit/group
 349 applied to the left part of the join.
 350
 351 In its "pursuit of standards" Microsft SQL Server goes to great lengths to
 352 forbid the use of ordered subselects. This breaks a very useful group of
 353 searches like "Give me things number 4 to 6 (ordered by name), and prefetch
 354 all their relations, no matter how many". While there is a hack which fools
 355 the syntax checker, the optimizer may B<still elect to break the subselect>.
 356 Testing has determined that while such breakage does occur (the test suite
 357 contains an explicit test which demonstrates the problem), it is relative
 358 rare. The benefits of ordered subselects are on the other hand too great to be
 359 outright disabled for MSSQL.
 360
 361 Thus compromise between usability and perfection is the MSSQL-specific
 362 L<resultset attribute|DBIx::Class::ResultSet/ATTRIBUTES> C<unsafe_subselect_ok>.
 363 It is deliberately not possible to set this on the Storage level, as the user
 364 should inspect (and preferably regression-test) the return of every such
 365 ResultSet individually. The example above would work if written like:
 366
 367  $rs->search ({}, {
 368   unsafe_subselect_ok => 1,
 369   prefetch => 'relation',
 370   rows => 2,
 371   offset => 3,
 372  });
 373
 374 If it is possible to rewrite the search() in a way that will avoid the need
 375 for this flag - you are urged to do so. If DBIC internals insist that an
 376 ordered subselect is necessary for an operation, and you believe there is a
 377 different/better way to get the same result - please file a bugreport.
 378
 379 =head1 AUTHOR
 380
 381 See L<DBIx::Class/AUTHOR> and L<DBIx::Class/CONTRIBUTORS>.
 382
 383 =head1 LICENSE
 384
 385 You may distribute this code under the same terms as Perl itself.
 386
 387 =cut