lib/DBIx/Class/Schema.pm

   1 package DBIx::Class::Schema;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp::Clan qw/^DBIx::Class/;
   7
   8 use base qw/DBIx::Class/;
   9
  10 __PACKAGE__->mk_classdata('class_mappings' => {});
  11 __PACKAGE__->mk_classdata('source_registrations' => {});
  12 __PACKAGE__->mk_classdata('storage_type' => '::DBI');
  13 __PACKAGE__->mk_classdata('storage');
  14
  15 =head1 NAME
  16
  17 DBIx::Class::Schema - composable schemas
  18
  19 =head1 SYNOPSIS
  20
  21   package Library::Schema;
  22   use base qw/DBIx::Class::Schema/;
  23
  24   # load Library::Schema::CD, Library::Schema::Book, Library::Schema::DVD
  25   __PACKAGE__->load_classes(qw/CD Book DVD/);
  26
  27   package Library::Schema::CD;
  28   use base qw/DBIx::Class/;
  29   __PACKAGE__->load_components(qw/PK::Auto Core/); # for example
  30   __PACKAGE__->table('cd');
  31
  32   # Elsewhere in your code:
  33   my $schema1 = Library::Schema->connect(
  34     $dsn,
  35     $user,
  36     $password,
  37     { AutoCommit => 0 },
  38   );
  39
  40   my $schema2 = Library::Schema->connect($coderef_returning_dbh);
  41
  42   # fetch objects using Library::Schema::DVD
  43   my $resultset = $schema1->resultset('DVD')->search( ... );
  44   my @dvd_objects = $schema2->resultset('DVD')->search( ... );
  45
  46 =head1 DESCRIPTION
  47
  48 Creates database classes based on a schema. This is the recommended way to
  49 use L<DBIx::Class> and allows you to use more than one concurrent connection
  50 with your classes.
  51
  52 NB: If you're used to L<Class::DBI> it's worth reading the L</SYNOPSIS>
  53 carefully as DBIx::Class does things a little differently. Note in
  54 particular which module inherits off which.
  55
  56 =head1 METHODS
  57
  58 =head2 register_class
  59
  60 =head3 Arguments: <moniker> <component_class>
  61
  62 Registers a class which isa ResultSourceProxy; equivalent to calling
  63
  64   $schema->register_source($moniker, $component_class->result_source_instance);
  65
  66 =cut
  67
  68 sub register_class {
  69   my ($self, $moniker, $to_register) = @_;
  70   $self->register_source($moniker => $to_register->result_source_instance);
  71 }
  72
  73 =head2 register_source
  74
  75 =head3 Arguments: <moniker> <result source>
  76
  77 Registers the result source in the schema with the given moniker
  78
  79 =cut
  80
  81 sub register_source {
  82   my ($self, $moniker, $source) = @_;
  83   my %reg = %{$self->source_registrations};
  84   $reg{$moniker} = $source;
  85   $self->source_registrations(\%reg);
  86   $source->schema($self);
  87   if ($source->result_class) {
  88     my %map = %{$self->class_mappings};
  89     $map{$source->result_class} = $moniker;
  90     $self->class_mappings(\%map);
  91   }
  92 }
  93
  94 =head2 class
  95
  96   my $class = $schema->class('CD');
  97
  98 Retrieves the result class name for a given result source
  99
 100 =cut
 101
 102 sub class {
 103   my ($self, $moniker) = @_;
 104   return $self->source($moniker)->result_class;
 105 }
 106
 107 =head2 source
 108
 109   my $source = $schema->source('Book');
 110
 111 Returns the result source object for the registered name
 112
 113 =cut
 114
 115 sub source {
 116   my ($self, $moniker) = @_;
 117   my $sreg = $self->source_registrations;
 118   return $sreg->{$moniker} if exists $sreg->{$moniker};
 119
 120   # if we got here, they probably passed a full class name
 121   my $mapped = $self->class_mappings->{$moniker};
 122   $self->throw_exception("Can't find source for ${moniker}")
 123     unless $mapped && exists $sreg->{$mapped};
 124   return $sreg->{$mapped};
 125 }
 126
 127 =head2 sources
 128
 129   my @source_monikers = $schema->sources;
 130
 131 Returns the source monikers of all source registrations on this schema
 132
 133 =cut
 134
 135 sub sources { return keys %{shift->source_registrations}; }
 136
 137 =head2 resultset
 138
 139   my $rs = $schema->resultset('DVD');
 140
 141 Returns the resultset for the registered moniker
 142
 143 =cut
 144
 145 sub resultset {
 146   my ($self, $moniker) = @_;
 147   return $self->source($moniker)->resultset;
 148 }
 149
 150 =head2 load_classes
 151
 152 =head3 Arguments: [<classes>, (<class>, <class>), {<namespace> => [<classes>]}]
 153
 154 Uses L<Module::Find> to find all classes under the database class' namespace,
 155 or uses the classes you select.  Then it loads the component (using L<use>),
 156 and registers them (using B<register_class>);
 157
 158 It is possible to comment out classes with a leading '#', but note that perl
 159 will think it's a mistake (trying to use a comment in a qw list) so you'll
 160 need to add "no warnings 'qw';" before your load_classes call.
 161
 162 =cut
 163
 164 sub load_classes {
 165   my ($class, @params) = @_;
 166
 167   my %comps_for;
 168
 169   if (@params) {
 170     foreach my $param (@params) {
 171       if (ref $param eq 'ARRAY') {
 172         # filter out commented entries
 173         my @modules = grep { $_ !~ /^#/ } @$param;
 174
 175         push (@{$comps_for{$class}}, @modules);
 176       }
 177       elsif (ref $param eq 'HASH') {
 178         # more than one namespace possible
 179         for my $comp ( keys %$param ) {
 180           # filter out commented entries
 181           my @modules = grep { $_ !~ /^#/ } @{$param->{$comp}};
 182
 183           push (@{$comps_for{$comp}}, @modules);
 184         }
 185       }
 186       else {
 187         # filter out commented entries
 188         push (@{$comps_for{$class}}, $param) if $param !~ /^#/;
 189       }
 190     }
 191   } else {
 192     eval "require Module::Find;";
 193     $class->throw_exception("No arguments to load_classes and couldn't load".
 194       " Module::Find ($@)") if $@;
 195     my @comp = map { substr $_, length "${class}::"  } Module::Find::findallmod($class);
 196     $comps_for{$class} = \@comp;
 197   }
 198
 199   my @to_register;
 200   {
 201     no warnings qw/redefine/;
 202     local *Class::C3::reinitialize = sub { };
 203     foreach my $prefix (keys %comps_for) {
 204       foreach my $comp (@{$comps_for{$prefix}||[]}) {
 205         my $comp_class = "${prefix}::${comp}";
 206         eval "use $comp_class"; # If it fails, assume the user fixed it
 207         if ($@) {
 208           $comp_class =~ s/::/\//g;
 209           die $@ unless $@ =~ /Can't locate.+$comp_class\.pm\sin\s\@INC/;
 210           warn $@ if $@;
 211         }
 212         push(@to_register, [ $comp, $comp_class ]);
 213       }
 214     }
 215   }
 216   Class::C3->reinitialize;
 217
 218   foreach my $to (@to_register) {
 219     $class->register_class(@$to);
 220     #  if $class->can('result_source_instance');
 221   }
 222 }
 223
 224 =head2 compose_connection
 225
 226 =head3 Arguments: <target> <@db_info>
 227
 228 This is the most important method in this class. it takes a target namespace,
 229 as well as dbh connection info, and creates a L<DBIx::Class::DB> class as
 230 well as subclasses for each of your database classes in this namespace, using
 231 this connection.
 232
 233 It will also setup a ->class method on the target class, which lets you
 234 resolve database classes based on the schema component name, for example
 235
 236   Library::Model::DB->class('Book') # returns Library::Model::Book,
 237                                     # which ISA Library::Schema::Book
 238
 239 This is the recommended API for accessing Schema generated classes, and
 240 using it might give you instant advantages with future versions of DBIC.
 241
 242 WARNING: Loading components into Schema classes after compose_connection
 243 may not cause them to be seen by the classes in your target namespace due
 244 to the dispatch table approach used by Class::C3. If you do this you may find
 245 you need to call Class::C3->reinitialize() afterwards to get the behaviour
 246 you expect.
 247
 248 =cut
 249
 250 sub compose_connection {
 251   my ($self, $target, @info) = @_;
 252   my $base = 'DBIx::Class::ResultSetProxy';
 253   eval "require ${base};";
 254   $self->throw_exception("No arguments to load_classes and couldn't load".
 255       " ${base} ($@)") if $@;
 256
 257   if ($self eq $target) {
 258     # Pathological case, largely caused by the docs on early C::M::DBIC::Plain
 259     foreach my $moniker ($self->sources) {
 260       my $source = $self->source($moniker);
 261       my $class = $source->result_class;
 262       $self->inject_base($class, $base);
 263       $class->mk_classdata(resultset_instance => $source->resultset);
 264       $class->mk_classdata(class_resolver => $self);
 265     }
 266     $self->connection(@info);
 267     return $self;
 268   }
 269
 270   my $schema = $self->compose_namespace($target, $base);
 271   {
 272     no strict 'refs';
 273     *{"${target}::schema"} = sub { $schema };
 274   }
 275
 276   $schema->connection(@info);
 277   foreach my $moniker ($schema->sources) {
 278     my $source = $schema->source($moniker);
 279     my $class = $source->result_class;
 280     #warn "$moniker $class $source ".$source->storage;
 281     $class->mk_classdata(result_source_instance => $source);
 282     $class->mk_classdata(resultset_instance => $source->resultset);
 283     $class->mk_classdata(class_resolver => $schema);
 284   }
 285   return $schema;
 286 }
 287
 288 sub compose_namespace {
 289   my ($self, $target, $base) = @_;
 290   my %reg = %{ $self->source_registrations };
 291   my %target;
 292   my %map;
 293   my $schema = $self->clone;
 294   {
 295     no warnings qw/redefine/;
 296     local *Class::C3::reinitialize = sub { };
 297     foreach my $moniker ($schema->sources) {
 298       my $source = $schema->source($moniker);
 299       my $target_class = "${target}::${moniker}";
 300       $self->inject_base(
 301         $target_class => $source->result_class, ($base ? $base : ())
 302       );
 303       $source->result_class($target_class);
 304     }
 305   }
 306   Class::C3->reinitialize();
 307   {
 308     no strict 'refs';
 309     foreach my $meth (qw/class source resultset/) {
 310       *{"${target}::${meth}"} =
 311         sub { shift->schema->$meth(@_) };
 312     }
 313   }
 314   return $schema;
 315 }
 316
 317 =head2 setup_connection_class
 318
 319 =head3 Arguments: <$target> <@info>
 320
 321 Sets up a database connection class to inject between the schema
 322 and the subclasses the schema creates.
 323
 324 =cut
 325
 326 sub setup_connection_class {
 327   my ($class, $target, @info) = @_;
 328   $class->inject_base($target => 'DBIx::Class::DB');
 329   #$target->load_components('DB');
 330   $target->connection(@info);
 331 }
 332
 333 =head2 connection
 334
 335 =head3 Arguments: (@args)
 336
 337 Instantiates a new Storage object of type storage_type and passes the
 338 arguments to $storage->connect_info. Sets the connection in-place on
 339 the schema.
 340
 341 =cut
 342
 343 sub connection {
 344   my ($self, @info) = @_;
 345   return $self if !@info && $self->storage;
 346   my $storage_class = $self->storage_type;
 347   $storage_class = 'DBIx::Class::Storage'.$storage_class
 348     if $storage_class =~ m/^::/;
 349   eval "require ${storage_class};";
 350   $self->throw_exception("No arguments to load_classes and couldn't load".
 351       " ${storage_class} ($@)") if $@;
 352   my $storage = $storage_class->new;
 353   $storage->connect_info(\@info);
 354   $self->storage($storage);
 355   return $self;
 356 }
 357
 358 =head2 connect
 359
 360 =head3 Arguments: (@info)
 361
 362 Conveneience method, equivalent to $schema->clone->connection(@info)
 363
 364 =cut
 365
 366 sub connect { shift->clone->connection(@_) }
 367
 368 =head2 txn_begin
 369
 370 Begins a transaction (does nothing if AutoCommit is off).
 371
 372 =cut
 373
 374 sub txn_begin { shift->storage->txn_begin }
 375
 376 =head2 txn_commit
 377
 378 Commits the current transaction.
 379
 380 =cut
 381
 382 sub txn_commit { shift->storage->txn_commit }
 383
 384 =head2 txn_rollback
 385
 386 Rolls back the current transaction.
 387
 388 =cut
 389
 390 sub txn_rollback { shift->storage->txn_rollback }
 391
 392 =head2 txn_do
 393
 394 =head3 Arguments: <$coderef>, [@coderef_args]
 395
 396 Executes C<$coderef> with (optional) arguments C<@coderef_args>
 397 transactionally, returning its result (if any). If an exception is
 398 caught, a rollback is issued and the exception is rethrown. If the
 399 rollback fails, (i.e. throws an exception) an exception is thrown that
 400 includes a "Rollback failed" message.
 401
 402 For example,
 403
 404   my $author_rs = $schema->resultset('Author')->find(1);
 405
 406   my $coderef = sub {
 407     my ($author, @titles) = @_;
 408
 409     # If any one of these fails, the entire transaction fails
 410     $author->create_related('books', {
 411       title => $_
 412     }) foreach (@titles);
 413
 414     return $author->books;
 415   };
 416
 417   my $rs;
 418   eval {
 419     $rs = $schema->txn_do($coderef, $author_rs, qw/Night Day It/);
 420   };
 421
 422   if ($@) {
 423     my $error = $@;
 424     if ($error =~ /Rollback failed/) {
 425       die "something terrible has happened!";
 426     } else {
 427       deal_with_failed_transaction();
 428     }
 429   }
 430
 431 Nested transactions work as expected (i.e. only the outermost
 432 transaction will issue a txn_commit on the Schema's storage), and
 433 txn_do() can be called in void, scalar and list context and it will
 434 behave as expected.
 435
 436 =cut
 437
 438 sub txn_do {
 439   my ($self, $coderef, @args) = @_;
 440
 441   ref $self or $self->throw_exception
 442     ('Cannot execute txn_do as a class method');
 443   ref $coderef eq 'CODE' or $self->throw_exception
 444     ('$coderef must be a CODE reference');
 445
 446   my (@return_values, $return_value);
 447
 448   $self->txn_begin; # If this throws an exception, no rollback is needed
 449
 450   my $wantarray = wantarray; # Need to save this since it's reset in eval{}
 451
 452   eval {
 453     # Need to differentiate between scalar/list context to allow for
 454     # returning a list in scalar context to get the size of the list
 455
 456     if ($wantarray) {
 457       # list context
 458       @return_values = $coderef->(@args);
 459     } elsif (defined $wantarray) {
 460       # scalar context
 461       $return_value = $coderef->(@args);
 462     } else {
 463       # void context
 464       $coderef->(@args);
 465     }
 466     $self->txn_commit;
 467   };
 468
 469   if ($@) {
 470     my $error = $@;
 471
 472     eval {
 473       $self->txn_rollback;
 474     };
 475
 476     if ($@) {
 477       my $rollback_error = $@;
 478       my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 479       $self->throw_exception($error)  # propagate nested rollback
 480         if $rollback_error =~ /$exception_class/;
 481
 482       $self->throw_exception("Transaction aborted: $error. Rollback failed: ".
 483                              $rollback_error);
 484     } else {
 485       $self->throw_exception($error); # txn failed but rollback succeeded
 486     }
 487   }
 488
 489   return $wantarray ? @return_values : $return_value;
 490 }
 491
 492 =head2 clone
 493
 494 Clones the schema and its associated result_source objects and returns the
 495 copy.
 496
 497 =cut
 498
 499 sub clone {
 500   my ($self) = @_;
 501   my $clone = bless({ (ref $self ? %$self : ()) }, ref $self || $self);
 502   foreach my $moniker ($self->sources) {
 503     my $source = $self->source($moniker);
 504     my $new = $source->new($source);
 505     $clone->register_source($moniker => $new);
 506   }
 507   return $clone;
 508 }
 509
 510 =head2 populate
 511
 512 =head3 Arguments: ($moniker, \@data);
 513
 514 Populates the source registered with the given moniker with the supplied data.
 515 @data should be a list of listrefs, the first containing column names, the
 516 second matching values - i.e.
 517
 518   $schema->populate('Artist', [
 519     [ qw/artistid name/ ],
 520     [ 1, 'Popular Band' ],
 521     [ 2, 'Indie Band' ],
 522     ...
 523   ]);
 524
 525 =cut
 526
 527 sub populate {
 528   my ($self, $name, $data) = @_;
 529   my $rs = $self->resultset($name);
 530   my @names = @{shift(@$data)};
 531   my @created;
 532   foreach my $item (@$data) {
 533     my %create;
 534     @create{@names} = @$item;
 535     push(@created, $rs->create(\%create));
 536   }
 537   return @created;
 538 }
 539
 540 =head2 throw_exception
 541
 542 Defaults to using Carp::Clan to report errors from user perspective.
 543
 544 =cut
 545
 546 sub throw_exception {
 547   my ($self) = shift;
 548   croak @_;
 549 }
 550
 551 =head2 deploy (EXPERIMENTAL)
 552
 553 Attempts to deploy the schema to the current storage using SQL::Translator.
 554
 555 Note that this feature is currently EXPERIMENTAL and may not work correctly
 556 across all databases, or fully handle complex relationships.
 557
 558 =cut
 559
 560 sub deploy {
 561   my ($self, $sqltargs) = @_;
 562   $self->throw_exception("Can't deploy without storage") unless $self->storage;
 563   $self->storage->deploy($self, undef, $sqltargs);
 564 }
 565
 566 1;
 567
 568 =head1 AUTHORS
 569
 570 Matt S. Trout <mst@shadowcatsystems.co.uk>
 571
 572 =head1 LICENSE
 573
 574 You may distribute this code under the same terms as Perl itself.
 575
 576 =cut
 577