lib/DBIx/Class/Schema.pm

   1 package DBIx::Class::Schema;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Carp::Clan qw/^DBIx::Class/;
   7
   8 use base qw/DBIx::Class/;
   9
  10 __PACKAGE__->mk_classdata('class_mappings' => {});
  11 __PACKAGE__->mk_classdata('source_registrations' => {});
  12 __PACKAGE__->mk_classdata('storage_type' => '::DBI');
  13 __PACKAGE__->mk_classdata('storage');
  14
  15 =head1 NAME
  16
  17 DBIx::Class::Schema - composable schemas
  18
  19 =head1 SYNOPSIS
  20
  21   package Library::Schema;
  22   use base qw/DBIx::Class::Schema/;
  23
  24   # load Library::Schema::CD, Library::Schema::Book, Library::Schema::DVD
  25   __PACKAGE__->load_classes(qw/CD Book DVD/);
  26
  27   package Library::Schema::CD;
  28   use base qw/DBIx::Class/;
  29   __PACKAGE__->load_components(qw/PK::Auto Core/); # for example
  30   __PACKAGE__->table('cd');
  31
  32   # Elsewhere in your code:
  33   my $schema1 = Library::Schema->connect(
  34     $dsn,
  35     $user,
  36     $password,
  37     { AutoCommit => 0 },
  38   );
  39
  40   my $schema2 = Library::Schema->connect($coderef_returning_dbh);
  41
  42   # fetch objects using Library::Schema::DVD
  43   my $resultset = $schema1->resultset('DVD')->search( ... );
  44   my @dvd_objects = $schema2->resultset('DVD')->search( ... );
  45
  46 =head1 DESCRIPTION
  47
  48 Creates database classes based on a schema. This is the recommended way to
  49 use L<DBIx::Class> and allows you to use more than one concurrent connection
  50 with your classes.
  51
  52 NB: If you're used to L<Class::DBI> it's worth reading the L</SYNOPSIS>
  53 carefully as DBIx::Class does things a little differently. Note in
  54 particular which module inherits off which.
  55
  56 =head1 METHODS
  57
  58 =head2 register_class
  59
  60 =head3 Arguments: <moniker> <component_class>
  61
  62 Registers a class which isa ResultSourceProxy; equivalent to calling
  63
  64   $schema->register_source($moniker, $component_class->result_source_instance);
  65
  66 =cut
  67
  68 sub register_class {
  69   my ($self, $moniker, $to_register) = @_;
  70   $self->register_source($moniker => $to_register->result_source_instance);
  71 }
  72
  73 =head2 register_source
  74
  75 =head3 Arguments: <moniker> <result source>
  76
  77 Registers the result source in the schema with the given moniker
  78
  79 =cut
  80
  81 sub register_source {
  82   my ($self, $moniker, $source) = @_;
  83   my %reg = %{$self->source_registrations};
  84   $reg{$moniker} = $source;
  85   $self->source_registrations(\%reg);
  86   $source->schema($self);
  87   if ($source->result_class) {
  88     my %map = %{$self->class_mappings};
  89     $map{$source->result_class} = $moniker;
  90     $self->class_mappings(\%map);
  91   }
  92 }
  93
  94 =head2 class
  95
  96   my $class = $schema->class('CD');
  97
  98 Retrieves the result class name for a given result source
  99
 100 =cut
 101
 102 sub class {
 103   my ($self, $moniker) = @_;
 104   return $self->source($moniker)->result_class;
 105 }
 106
 107 =head2 source
 108
 109   my $source = $schema->source('Book');
 110
 111 Returns the result source object for the registered name
 112
 113 =cut
 114
 115 sub source {
 116   my ($self, $moniker) = @_;
 117   my $sreg = $self->source_registrations;
 118   return $sreg->{$moniker} if exists $sreg->{$moniker};
 119
 120   # if we got here, they probably passed a full class name
 121   my $mapped = $self->class_mappings->{$moniker};
 122   $self->throw_exception("Can't find source for ${moniker}")
 123     unless $mapped && exists $sreg->{$mapped};
 124   return $sreg->{$mapped};
 125 }
 126
 127 =head2 sources
 128
 129   my @source_monikers = $schema->sources;
 130
 131 Returns the source monikers of all source registrations on this schema
 132
 133 =cut
 134
 135 sub sources { return keys %{shift->source_registrations}; }
 136
 137 =head2 resultset
 138
 139   my $rs = $schema->resultset('DVD');
 140
 141 Returns the resultset for the registered moniker
 142
 143 =cut
 144
 145 sub resultset {
 146   my ($self, $moniker) = @_;
 147   return $self->source($moniker)->resultset;
 148 }
 149
 150 =head2 load_classes
 151
 152 =head3 Arguments: [<classes>, (<class>, <class>), {<namespace> => [<classes>]}]
 153
 154 Uses L<Module::Find> to find all classes under the database class' namespace,
 155 or uses the classes you select.  Then it loads the component (using L<use>),
 156 and registers them (using B<register_class>);
 157
 158 It is possible to comment out classes with a leading '#', but note that perl
 159 will think it's a mistake (trying to use a comment in a qw list) so you'll
 160 need to add "no warnings 'qw';" before your load_classes call.
 161
 162 =cut
 163
 164 sub load_classes {
 165   my ($class, @params) = @_;
 166
 167   my %comps_for;
 168
 169   if (@params) {
 170     foreach my $param (@params) {
 171       if (ref $param eq 'ARRAY') {
 172         # filter out commented entries
 173         my @modules = grep { $_ !~ /^#/ } @$param;
 174
 175         push (@{$comps_for{$class}}, @modules);
 176       }
 177       elsif (ref $param eq 'HASH') {
 178         # more than one namespace possible
 179         for my $comp ( keys %$param ) {
 180           # filter out commented entries
 181           my @modules = grep { $_ !~ /^#/ } @{$param->{$comp}};
 182
 183           push (@{$comps_for{$comp}}, @modules);
 184         }
 185       }
 186       else {
 187         # filter out commented entries
 188         push (@{$comps_for{$class}}, $param) if $param !~ /^#/;
 189       }
 190     }
 191   } else {
 192     eval "require Module::Find;";
 193     $class->throw_exception("No arguments to load_classes and couldn't load".
 194       " Module::Find ($@)") if $@;
 195     my @comp = map { substr $_, length "${class}::"  } Module::Find::findallmod($class);
 196     $comps_for{$class} = \@comp;
 197   }
 198
 199   my @to_register;
 200   {
 201     no warnings qw/redefine/;
 202     local *Class::C3::reinitialize = sub { };
 203     foreach my $prefix (keys %comps_for) {
 204       foreach my $comp (@{$comps_for{$prefix}||[]}) {
 205         my $comp_class = "${prefix}::${comp}";
 206         eval "use $comp_class"; # If it fails, assume the user fixed it
 207         if ($@) {
 208           $comp_class =~ s/::/\//g;
 209           die $@ unless $@ =~ /Can't locate.+$comp_class\.pm\sin\s\@INC/;
 210           warn $@ if $@;
 211         }
 212         push(@to_register, [ $comp, $comp_class ]);
 213       }
 214     }
 215   }
 216   Class::C3->reinitialize;
 217
 218   foreach my $to (@to_register) {
 219     $class->register_class(@$to);
 220     #  if $class->can('result_source_instance');
 221   }
 222 }
 223
 224 =head2 compose_connection
 225
 226 =head3 Arguments: $target_ns, @db_info
 227
 228 =head3 Return value: $new_schema
 229
 230 Calls compose_namespace to the $target_ns, calls ->connection(@db_info) on
 231 the new schema, then injects the ResultSetProxy component and a
 232 resultset_instance classdata entry on all the new classes in order to support
 233 $target_ns::Class->search(...) method calls. Primarily useful when you have
 234 a specific need for classmethod access to a connection - in normal usage
 235 ->connect is preferred.
 236
 237 =cut
 238
 239 sub compose_connection {
 240   my ($self, $target, @info) = @_;
 241   my $base = 'DBIx::Class::ResultSetProxy';
 242   eval "require ${base};";
 243   $self->throw_exception("No arguments to load_classes and couldn't load".
 244       " ${base} ($@)") if $@;
 245
 246   if ($self eq $target) {
 247     # Pathological case, largely caused by the docs on early C::M::DBIC::Plain
 248     foreach my $moniker ($self->sources) {
 249       my $source = $self->source($moniker);
 250       my $class = $source->result_class;
 251       $self->inject_base($class, $base);
 252       $class->mk_classdata(resultset_instance => $source->resultset);
 253       $class->mk_classdata(class_resolver => $self);
 254     }
 255     $self->connection(@info);
 256     return $self;
 257   }
 258
 259   my $schema = $self->compose_namespace($target, $base);
 260   {
 261     no strict 'refs';
 262     *{"${target}::schema"} = sub { $schema };
 263   }
 264
 265   $schema->connection(@info);
 266   foreach my $moniker ($schema->sources) {
 267     my $source = $schema->source($moniker);
 268     my $class = $source->result_class;
 269     #warn "$moniker $class $source ".$source->storage;
 270     $class->mk_classdata(result_source_instance => $source);
 271     $class->mk_classdata(resultset_instance => $source->resultset);
 272     $class->mk_classdata(class_resolver => $schema);
 273   }
 274   return $schema;
 275 }
 276
 277 =head2 compose_namespace
 278
 279 =head3 Arguments: $target_ns, $additional_base_class?
 280
 281 =head3 Return value: $new_schema
 282
 283 For each result source in the schema, creates a class in the target
 284 namespace (e.g. $target_ns::CD, $target_ns::Artist) inheriting from the
 285 corresponding classes attached to the current schema and a result source
 286 to match attached to the new $schema object. If an additional base class is
 287 given, injects this immediately behind the corresponding classes from the
 288 current schema in the created classes' @ISA.
 289
 290 =cut
 291
 292 sub compose_namespace {
 293   my ($self, $target, $base) = @_;
 294   my %reg = %{ $self->source_registrations };
 295   my %target;
 296   my %map;
 297   my $schema = $self->clone;
 298   {
 299     no warnings qw/redefine/;
 300     local *Class::C3::reinitialize = sub { };
 301     foreach my $moniker ($schema->sources) {
 302       my $source = $schema->source($moniker);
 303       my $target_class = "${target}::${moniker}";
 304       $self->inject_base(
 305         $target_class => $source->result_class, ($base ? $base : ())
 306       );
 307       $source->result_class($target_class);
 308     }
 309   }
 310   Class::C3->reinitialize();
 311   {
 312     no strict 'refs';
 313     foreach my $meth (qw/class source resultset/) {
 314       *{"${target}::${meth}"} =
 315         sub { shift->schema->$meth(@_) };
 316     }
 317   }
 318   return $schema;
 319 }
 320
 321 =head2 setup_connection_class
 322
 323 =head3 Arguments: <$target> <@info>
 324
 325 Sets up a database connection class to inject between the schema
 326 and the subclasses the schema creates.
 327
 328 =cut
 329
 330 sub setup_connection_class {
 331   my ($class, $target, @info) = @_;
 332   $class->inject_base($target => 'DBIx::Class::DB');
 333   #$target->load_components('DB');
 334   $target->connection(@info);
 335 }
 336
 337 =head2 connection
 338
 339 =head3 Arguments: (@args)
 340
 341 Instantiates a new Storage object of type storage_type and passes the
 342 arguments to $storage->connect_info. Sets the connection in-place on
 343 the schema.
 344
 345 =cut
 346
 347 sub connection {
 348   my ($self, @info) = @_;
 349   return $self if !@info && $self->storage;
 350   my $storage_class = $self->storage_type;
 351   $storage_class = 'DBIx::Class::Storage'.$storage_class
 352     if $storage_class =~ m/^::/;
 353   eval "require ${storage_class};";
 354   $self->throw_exception("No arguments to load_classes and couldn't load".
 355       " ${storage_class} ($@)") if $@;
 356   my $storage = $storage_class->new;
 357   $storage->connect_info(\@info);
 358   $self->storage($storage);
 359   return $self;
 360 }
 361
 362 =head2 connect
 363
 364 =head3 Arguments: (@info)
 365
 366 Conveneience method, equivalent to $schema->clone->connection(@info)
 367
 368 =cut
 369
 370 sub connect { shift->clone->connection(@_) }
 371
 372 =head2 txn_begin
 373
 374 Begins a transaction (does nothing if AutoCommit is off).
 375
 376 =cut
 377
 378 sub txn_begin { shift->storage->txn_begin }
 379
 380 =head2 txn_commit
 381
 382 Commits the current transaction.
 383
 384 =cut
 385
 386 sub txn_commit { shift->storage->txn_commit }
 387
 388 =head2 txn_rollback
 389
 390 Rolls back the current transaction.
 391
 392 =cut
 393
 394 sub txn_rollback { shift->storage->txn_rollback }
 395
 396 =head2 txn_do
 397
 398 =head3 Arguments: <$coderef>, [@coderef_args]
 399
 400 Executes C<$coderef> with (optional) arguments C<@coderef_args>
 401 transactionally, returning its result (if any). If an exception is
 402 caught, a rollback is issued and the exception is rethrown. If the
 403 rollback fails, (i.e. throws an exception) an exception is thrown that
 404 includes a "Rollback failed" message.
 405
 406 For example,
 407
 408   my $author_rs = $schema->resultset('Author')->find(1);
 409
 410   my $coderef = sub {
 411     my ($author, @titles) = @_;
 412
 413     # If any one of these fails, the entire transaction fails
 414     $author->create_related('books', {
 415       title => $_
 416     }) foreach (@titles);
 417
 418     return $author->books;
 419   };
 420
 421   my $rs;
 422   eval {
 423     $rs = $schema->txn_do($coderef, $author_rs, qw/Night Day It/);
 424   };
 425
 426   if ($@) {
 427     my $error = $@;
 428     if ($error =~ /Rollback failed/) {
 429       die "something terrible has happened!";
 430     } else {
 431       deal_with_failed_transaction();
 432     }
 433   }
 434
 435 Nested transactions work as expected (i.e. only the outermost
 436 transaction will issue a txn_commit on the Schema's storage), and
 437 txn_do() can be called in void, scalar and list context and it will
 438 behave as expected.
 439
 440 =cut
 441
 442 sub txn_do {
 443   my ($self, $coderef, @args) = @_;
 444
 445   ref $self or $self->throw_exception
 446     ('Cannot execute txn_do as a class method');
 447   ref $coderef eq 'CODE' or $self->throw_exception
 448     ('$coderef must be a CODE reference');
 449
 450   my (@return_values, $return_value);
 451
 452   $self->txn_begin; # If this throws an exception, no rollback is needed
 453
 454   my $wantarray = wantarray; # Need to save this since it's reset in eval{}
 455
 456   eval {
 457     # Need to differentiate between scalar/list context to allow for
 458     # returning a list in scalar context to get the size of the list
 459
 460     if ($wantarray) {
 461       # list context
 462       @return_values = $coderef->(@args);
 463     } elsif (defined $wantarray) {
 464       # scalar context
 465       $return_value = $coderef->(@args);
 466     } else {
 467       # void context
 468       $coderef->(@args);
 469     }
 470     $self->txn_commit;
 471   };
 472
 473   if ($@) {
 474     my $error = $@;
 475
 476     eval {
 477       $self->txn_rollback;
 478     };
 479
 480     if ($@) {
 481       my $rollback_error = $@;
 482       my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 483       $self->throw_exception($error)  # propagate nested rollback
 484         if $rollback_error =~ /$exception_class/;
 485
 486       $self->throw_exception("Transaction aborted: $error. Rollback failed: ".
 487                              $rollback_error);
 488     } else {
 489       $self->throw_exception($error); # txn failed but rollback succeeded
 490     }
 491   }
 492
 493   return $wantarray ? @return_values : $return_value;
 494 }
 495
 496 =head2 clone
 497
 498 Clones the schema and its associated result_source objects and returns the
 499 copy.
 500
 501 =cut
 502
 503 sub clone {
 504   my ($self) = @_;
 505   my $clone = bless({ (ref $self ? %$self : ()) }, ref $self || $self);
 506   foreach my $moniker ($self->sources) {
 507     my $source = $self->source($moniker);
 508     my $new = $source->new($source);
 509     $clone->register_source($moniker => $new);
 510   }
 511   return $clone;
 512 }
 513
 514 =head2 populate
 515
 516 =head3 Arguments: ($moniker, \@data);
 517
 518 Populates the source registered with the given moniker with the supplied data.
 519 @data should be a list of listrefs, the first containing column names, the
 520 second matching values - i.e.
 521
 522   $schema->populate('Artist', [
 523     [ qw/artistid name/ ],
 524     [ 1, 'Popular Band' ],
 525     [ 2, 'Indie Band' ],
 526     ...
 527   ]);
 528
 529 =cut
 530
 531 sub populate {
 532   my ($self, $name, $data) = @_;
 533   my $rs = $self->resultset($name);
 534   my @names = @{shift(@$data)};
 535   my @created;
 536   foreach my $item (@$data) {
 537     my %create;
 538     @create{@names} = @$item;
 539     push(@created, $rs->create(\%create));
 540   }
 541   return @created;
 542 }
 543
 544 =head2 throw_exception
 545
 546 Defaults to using Carp::Clan to report errors from user perspective.
 547
 548 =cut
 549
 550 sub throw_exception {
 551   my ($self) = shift;
 552   croak @_;
 553 }
 554
 555 =head2 deploy (EXPERIMENTAL)
 556
 557 Attempts to deploy the schema to the current storage using SQL::Translator.
 558
 559 Note that this feature is currently EXPERIMENTAL and may not work correctly
 560 across all databases, or fully handle complex relationships.
 561
 562 =cut
 563
 564 sub deploy {
 565   my ($self, $sqltargs) = @_;
 566   $self->throw_exception("Can't deploy without storage") unless $self->storage;
 567   $self->storage->deploy($self, undef, $sqltargs);
 568 }
 569
 570 1;
 571
 572 =head1 AUTHORS
 573
 574 Matt S. Trout <mst@shadowcatsystems.co.uk>
 575
 576 =head1 LICENSE
 577
 578 You may distribute this code under the same terms as Perl itself.
 579
 580 =cut
 581