1 package DBIx::Class::Schema;
6 use base 'DBIx::Class';
10 use Scalar::Util qw/weaken blessed/;
11 use Sub::Name 'subname';
12 use B 'svref_2object';
13 use Devel::GlobalDestruction;
16 __PACKAGE__->mk_classdata('class_mappings' => {});
17 __PACKAGE__->mk_classdata('source_registrations' => {});
18 __PACKAGE__->mk_classdata('storage_type' => '::DBI');
19 __PACKAGE__->mk_classdata('storage');
20 __PACKAGE__->mk_classdata('exception_action');
21 __PACKAGE__->mk_classdata('stacktrace' => $ENV{DBIC_TRACE} || 0);
22 __PACKAGE__->mk_classdata('default_resultset_attributes' => {});
26 DBIx::Class::Schema - composable schemas
30 package Library::Schema;
31 use base qw/DBIx::Class::Schema/;
33 # load all Result classes in Library/Schema/Result/
34 __PACKAGE__->load_namespaces();
36 package Library::Schema::Result::CD;
37 use base qw/DBIx::Class::Core/;
39 __PACKAGE__->load_components(qw/InflateColumn::DateTime/); # for example
40 __PACKAGE__->table('cd');
42 # Elsewhere in your code:
43 my $schema1 = Library::Schema->connect(
50 my $schema2 = Library::Schema->connect($coderef_returning_dbh);
52 # fetch objects using Library::Schema::Result::DVD
53 my $resultset = $schema1->resultset('DVD')->search( ... );
54 my @dvd_objects = $schema2->resultset('DVD')->search( ... );
58 Creates database classes based on a schema. This is the recommended way to
59 use L<DBIx::Class> and allows you to use more than one concurrent connection
62 NB: If you're used to L<Class::DBI> it's worth reading the L</SYNOPSIS>
63 carefully, as DBIx::Class does things a little differently. Note in
64 particular which module inherits off which.
68 =head2 load_namespaces
72 =item Arguments: %options?
76 package MyApp::Schema;
77 __PACKAGE__->load_namespaces();
79 __PACKAGE__->load_namespaces(
80 result_namespace => 'Res',
81 resultset_namespace => 'RSet',
82 default_resultset_class => '+MyApp::Othernamespace::RSet',
85 With no arguments, this method uses L<Module::Find> to load all of the
86 Result and ResultSet classes under the namespace of the schema from
87 which it is called. For example, C<My::Schema> will by default find
88 and load Result classes named C<My::Schema::Result::*> and ResultSet
89 classes named C<My::Schema::ResultSet::*>.
91 ResultSet classes are associated with Result class of the same name.
92 For example, C<My::Schema::Result::CD> will get the ResultSet class
93 C<My::Schema::ResultSet::CD> if it is present.
95 Both Result and ResultSet namespaces are configurable via the
96 C<result_namespace> and C<resultset_namespace> options.
98 Another option, C<default_resultset_class> specifies a custom default
99 ResultSet class for Result classes with no corresponding ResultSet.
101 All of the namespace and classname options are by default relative to
102 the schema classname. To specify a fully-qualified name, prefix it
103 with a literal C<+>. For example, C<+Other::NameSpace::Result>.
107 You will be warned if ResultSet classes are discovered for which there
108 are no matching Result classes like this:
110 load_namespaces found ResultSet class $classname with no corresponding Result class
112 If a Result class is found to already have a ResultSet class set using
113 L</resultset_class> to some other class, you will be warned like this:
115 We found ResultSet class '$rs_class' for '$result', but it seems
116 that you had already set '$result' to use '$rs_set' instead
120 # load My::Schema::Result::CD, My::Schema::Result::Artist,
121 # My::Schema::ResultSet::CD, etc...
122 My::Schema->load_namespaces;
124 # Override everything to use ugly names.
125 # In this example, if there is a My::Schema::Res::Foo, but no matching
126 # My::Schema::RSets::Foo, then Foo will have its
127 # resultset_class set to My::Schema::RSetBase
128 My::Schema->load_namespaces(
129 result_namespace => 'Res',
130 resultset_namespace => 'RSets',
131 default_resultset_class => 'RSetBase',
134 # Put things in other namespaces
135 My::Schema->load_namespaces(
136 result_namespace => '+Some::Place::Results',
137 resultset_namespace => '+Another::Place::RSets',
140 To search multiple namespaces for either Result or ResultSet classes,
141 use an arrayref of namespaces for that option. In the case that the
142 same result (or resultset) class exists in multiple namespaces, later
143 entries in the list of namespaces will override earlier ones.
145 My::Schema->load_namespaces(
146 # My::Schema::Results_C::Foo takes precedence over My::Schema::Results_B::Foo :
147 result_namespace => [ 'Results_A', 'Results_B', 'Results_C' ],
148 resultset_namespace => [ '+Some::Place::RSets', 'RSets' ],
153 # Pre-pends our classname to the given relative classname or
154 # class namespace, unless there is a '+' prefix, which will
156 sub _expand_relative_name {
157 my ($class, $name) = @_;
158 $name =~ s/^\+// or $name = "${class}::${name}";
162 # Finds all modules in the supplied namespace, or if omitted in the
163 # namespace of $class. Untaints all findings as they can be assumed
166 require Module::Find;
168 { $_ =~ /(.+)/ } # untaint result
169 Module::Find::findallmod( $_[1] || ref $_[0] || $_[0] )
173 # returns a hash of $shortname => $fullname for every package
174 # found in the given namespaces ($shortname is with the $fullname's
175 # namespace stripped off)
176 sub _map_namespaces {
177 my ($me, $namespaces) = @_;
180 for my $ns (@$namespaces) {
181 $res{ substr($_, length "${ns}::") } = $_
182 for $me->_findallmod($ns);
188 # returns the result_source_instance for the passed class/object,
189 # or dies with an informative message (used by load_namespaces)
190 sub _ns_get_rsrc_instance {
192 my $rs_class = ref ($_[0]) || $_[0];
195 $rs_class->result_source_instance
197 $me->throw_exception (
198 "Attempt to load_namespaces() class $rs_class failed - are you sure this is a real Result Class?: $_"
203 sub load_namespaces {
204 my ($class, %args) = @_;
206 my $result_namespace = delete $args{result_namespace} || 'Result';
207 my $resultset_namespace = delete $args{resultset_namespace} || 'ResultSet';
209 my $default_resultset_class = delete $args{default_resultset_class};
211 $default_resultset_class = $class->_expand_relative_name($default_resultset_class)
212 if $default_resultset_class;
214 $class->throw_exception('load_namespaces: unknown option(s): '
215 . join(q{,}, map { qq{'$_'} } keys %args))
216 if scalar keys %args;
218 for my $arg ($result_namespace, $resultset_namespace) {
219 $arg = [ $arg ] if ( $arg and ! ref $arg );
221 $class->throw_exception('load_namespaces: namespace arguments must be '
222 . 'a simple string or an arrayref')
223 if ref($arg) ne 'ARRAY';
225 $_ = $class->_expand_relative_name($_) for (@$arg);
228 my $results_by_source_name = $class->_map_namespaces($result_namespace);
229 my $resultsets_by_source_name = $class->_map_namespaces($resultset_namespace);
233 no warnings qw/redefine/;
234 local *Class::C3::reinitialize = sub { } if DBIx::Class::_ENV_::OLD_MRO;
235 use warnings qw/redefine/;
237 # ensure classes are loaded and attached in inheritance order
238 for my $result_class (values %$results_by_source_name) {
239 $class->ensure_class_loaded($result_class);
242 my @source_names_by_subclass_last = sort {
245 scalar @{mro::get_linear_isa( $results_by_source_name->{$a} )}
251 scalar @{mro::get_linear_isa( $results_by_source_name->{$b} )}
254 } keys(%$results_by_source_name);
256 foreach my $source_name (@source_names_by_subclass_last) {
257 my $result_class = $results_by_source_name->{$source_name};
259 my $preset_resultset_class = $class->_ns_get_rsrc_instance ($result_class)->resultset_class;
260 my $found_resultset_class = delete $resultsets_by_source_name->{$source_name};
262 if($preset_resultset_class && $preset_resultset_class ne 'DBIx::Class::ResultSet') {
263 if($found_resultset_class && $found_resultset_class ne $preset_resultset_class) {
264 carp "We found ResultSet class '$found_resultset_class' matching '$results_by_source_name->{$source_name}', but it seems "
265 . "that you had already set the '$results_by_source_name->{$source_name}' resultet to '$preset_resultset_class' instead";
268 # elsif - there may be *no* default_resultset_class, in which case we fallback to
269 # DBIx::Class::Resultset and there is nothing to check
270 elsif($found_resultset_class ||= $default_resultset_class) {
271 $class->ensure_class_loaded($found_resultset_class);
272 if(!$found_resultset_class->isa("DBIx::Class::ResultSet")) {
273 carp "load_namespaces found ResultSet class '$found_resultset_class' that does not subclass DBIx::Class::ResultSet";
276 $class->_ns_get_rsrc_instance ($result_class)->resultset_class($found_resultset_class);
279 my $source_name = $class->_ns_get_rsrc_instance ($result_class)->source_name || $source_name;
281 push(@to_register, [ $source_name, $result_class ]);
285 foreach (sort keys %$resultsets_by_source_name) {
286 carp "load_namespaces found ResultSet class '$resultsets_by_source_name->{$_}' "
287 .'with no corresponding Result class';
290 Class::C3->reinitialize if DBIx::Class::_ENV_::OLD_MRO;
292 $class->register_class(@$_) for (@to_register);
301 =item Arguments: @classes?, { $namespace => [ @classes ] }+
305 L</load_classes> is an alternative method to L</load_namespaces>, both of
306 which serve similar purposes, each with different advantages and disadvantages.
307 In the general case you should use L</load_namespaces>, unless you need to
308 be able to specify that only specific classes are loaded at runtime.
310 With no arguments, this method uses L<Module::Find> to find all classes under
311 the schema's namespace. Otherwise, this method loads the classes you specify
312 (using L<use>), and registers them (using L</"register_class">).
314 It is possible to comment out classes with a leading C<#>, but note that perl
315 will think it's a mistake (trying to use a comment in a qw list), so you'll
316 need to add C<no warnings 'qw';> before your load_classes call.
318 If any classes found do not appear to be Result class files, you will
319 get the following warning:
321 Failed to load $comp_class. Can't find source_name method. Is
322 $comp_class really a full DBIC result class? Fix it, move it elsewhere,
323 or make your load_classes call more specific.
327 My::Schema->load_classes(); # loads My::Schema::CD, My::Schema::Artist,
328 # etc. (anything under the My::Schema namespace)
330 # loads My::Schema::CD, My::Schema::Artist, Other::Namespace::Producer but
331 # not Other::Namespace::LinerNotes nor My::Schema::Track
332 My::Schema->load_classes(qw/ CD Artist #Track /, {
333 Other::Namespace => [qw/ Producer #LinerNotes /],
339 my ($class, @params) = @_;
344 foreach my $param (@params) {
345 if (ref $param eq 'ARRAY') {
346 # filter out commented entries
347 my @modules = grep { $_ !~ /^#/ } @$param;
349 push (@{$comps_for{$class}}, @modules);
351 elsif (ref $param eq 'HASH') {
352 # more than one namespace possible
353 for my $comp ( keys %$param ) {
354 # filter out commented entries
355 my @modules = grep { $_ !~ /^#/ } @{$param->{$comp}};
357 push (@{$comps_for{$comp}}, @modules);
361 # filter out commented entries
362 push (@{$comps_for{$class}}, $param) if $param !~ /^#/;
366 my @comp = map { substr $_, length "${class}::" }
367 $class->_findallmod($class);
368 $comps_for{$class} = \@comp;
373 no warnings qw/redefine/;
374 local *Class::C3::reinitialize = sub { } if DBIx::Class::_ENV_::OLD_MRO;
375 use warnings qw/redefine/;
377 foreach my $prefix (keys %comps_for) {
378 foreach my $comp (@{$comps_for{$prefix}||[]}) {
379 my $comp_class = "${prefix}::${comp}";
380 $class->ensure_class_loaded($comp_class);
382 my $snsub = $comp_class->can('source_name');
384 carp "Failed to load $comp_class. Can't find source_name method. Is $comp_class really a full DBIC result class? Fix it, move it elsewhere, or make your load_classes call more specific.";
387 $comp = $snsub->($comp_class) || $comp;
389 push(@to_register, [ $comp, $comp_class ]);
393 Class::C3->reinitialize if DBIx::Class::_ENV_::OLD_MRO;
395 foreach my $to (@to_register) {
396 $class->register_class(@$to);
404 =item Arguments: $storage_type|{$storage_type, \%args}
406 =item Return Value: $storage_type|{$storage_type, \%args}
408 =item Default value: DBIx::Class::Storage::DBI
412 Set the storage class that will be instantiated when L</connect> is called.
413 If the classname starts with C<::>, the prefix C<DBIx::Class::Storage> is
414 assumed by L</connect>.
416 You want to use this to set subclasses of L<DBIx::Class::Storage::DBI>
417 in cases where the appropriate subclass is not autodetected.
419 If your storage type requires instantiation arguments, those are
420 defined as a second argument in the form of a hashref and the entire
421 value needs to be wrapped into an arrayref or a hashref. We support
422 both types of refs here in order to play nice with your
423 Config::[class] or your choice. See
424 L<DBIx::Class::Storage::DBI::Replicated> for an example of this.
426 =head2 exception_action
430 =item Arguments: $code_reference
432 =item Return Value: $code_reference
434 =item Default value: None
438 When L</throw_exception> is invoked and L</exception_action> is set to a code
439 reference, this reference will be called instead of
440 L<DBIx::Class::Exception/throw>, with the exception message passed as the only
443 Your custom throw code B<must> rethrow the exception, as L</throw_exception> is
444 an integral part of DBIC's internal execution control flow.
449 use base qw/DBIx::Class::Schema/;
450 use My::ExceptionClass;
451 __PACKAGE__->exception_action(sub { My::ExceptionClass->throw(@_) });
452 __PACKAGE__->load_classes;
455 my $schema_obj = My::Schema->connect( .... );
456 $schema_obj->exception_action(sub { My::ExceptionClass->throw(@_) });
462 =item Arguments: boolean
466 Whether L</throw_exception> should include stack trace information.
467 Defaults to false normally, but defaults to true if C<$ENV{DBIC_TRACE}>
470 =head2 sqlt_deploy_hook
474 =item Arguments: $sqlt_schema
478 An optional sub which you can declare in your own Schema class that will get
479 passed the L<SQL::Translator::Schema> object when you deploy the schema via
480 L</create_ddl_dir> or L</deploy>.
482 For an example of what you can do with this, see
483 L<DBIx::Class::Manual::Cookbook/Adding Indexes And Functions To Your SQL>.
485 Note that sqlt_deploy_hook is called by L</deployment_statements>, which in turn
486 is called before L</deploy>. Therefore the hook can be used only to manipulate
487 the L<SQL::Translator::Schema> object before it is turned into SQL fed to the
488 database. If you want to execute post-deploy statements which can not be generated
489 by L<SQL::Translator>, the currently suggested method is to overload L</deploy>
490 and use L<dbh_do|DBIx::Class::Storage::DBI/dbh_do>.
498 =item Arguments: @connectinfo
500 =item Return Value: $new_schema
504 Creates and returns a new Schema object. The connection info set on it
505 is used to create a new instance of the storage backend and set it on
508 See L<DBIx::Class::Storage::DBI/"connect_info"> for DBI-specific
509 syntax on the C<@connectinfo> argument, or L<DBIx::Class::Storage> in
512 Note that C<connect_info> expects an arrayref of arguments, but
513 C<connect> does not. C<connect> wraps its arguments in an arrayref
514 before passing them to C<connect_info>.
518 C<connect> is a convenience method. It is equivalent to calling
519 $schema->clone->connection(@connectinfo). To write your own overloaded
520 version, overload L</connection> instead.
524 sub connect { shift->clone->connection(@_) }
530 =item Arguments: L<$source_name|DBIx::Class::ResultSource/source_name>
532 =item Return Value: L<$resultset|DBIx::Class::ResultSet>
536 my $rs = $schema->resultset('DVD');
538 Returns the L<DBIx::Class::ResultSet> object for the registered source
544 my ($self, $source_name) = @_;
545 $self->throw_exception('resultset() expects a source name')
546 unless defined $source_name;
547 return $self->source($source_name)->resultset;
554 =item Return Value: L<@source_names|DBIx::Class::ResultSource/source_name>
558 my @source_names = $schema->sources;
560 Lists names of all the sources registered on this Schema object.
564 sub sources { keys %{shift->source_registrations} }
570 =item Arguments: L<$source_name|DBIx::Class::ResultSource/source_name>
572 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
576 my $source = $schema->source('Book');
578 Returns the L<DBIx::Class::ResultSource> object for the registered
586 $self->throw_exception("source() expects a source name")
589 my $source_name = shift;
591 my $sreg = $self->source_registrations;
592 return $sreg->{$source_name} if exists $sreg->{$source_name};
594 # if we got here, they probably passed a full class name
595 my $mapped = $self->class_mappings->{$source_name};
596 $self->throw_exception("Can't find source for ${source_name}")
597 unless $mapped && exists $sreg->{$mapped};
598 return $sreg->{$mapped};
605 =item Arguments: L<$source_name|DBIx::Class::ResultSource/source_name>
607 =item Return Value: $classname
611 my $class = $schema->class('CD');
613 Retrieves the Result class name for the given source name.
618 return shift->source(shift)->result_class;
625 =item Arguments: C<$coderef>, @coderef_args?
627 =item Return Value: The return value of $coderef
631 Executes C<$coderef> with (optional) arguments C<@coderef_args> atomically,
632 returning its result (if any). Equivalent to calling $schema->storage->txn_do.
633 See L<DBIx::Class::Storage/"txn_do"> for more information.
635 This interface is preferred over using the individual methods L</txn_begin>,
636 L</txn_commit>, and L</txn_rollback> below.
638 WARNING: If you are connected with C<< AutoCommit => 0 >> the transaction is
639 considered nested, and you will still need to call L</txn_commit> to write your
640 changes when appropriate. You will also want to connect with C<< auto_savepoint =>
641 1 >> to get partial rollback to work, if the storage driver for your database
644 Connecting with C<< AutoCommit => 1 >> is recommended.
651 $self->storage or $self->throw_exception
652 ('txn_do called on $schema without storage');
654 $self->storage->txn_do(@_);
657 =head2 txn_scope_guard
659 Runs C<txn_scope_guard> on the schema's storage. See
660 L<DBIx::Class::Storage/txn_scope_guard>.
664 sub txn_scope_guard {
667 $self->storage or $self->throw_exception
668 ('txn_scope_guard called on $schema without storage');
670 $self->storage->txn_scope_guard(@_);
675 Begins a transaction (does nothing if AutoCommit is off). Equivalent to
676 calling $schema->storage->txn_begin. See
677 L<DBIx::Class::Storage/"txn_begin"> for more information.
684 $self->storage or $self->throw_exception
685 ('txn_begin called on $schema without storage');
687 $self->storage->txn_begin;
692 Commits the current transaction. Equivalent to calling
693 $schema->storage->txn_commit. See L<DBIx::Class::Storage/"txn_commit">
694 for more information.
701 $self->storage or $self->throw_exception
702 ('txn_commit called on $schema without storage');
704 $self->storage->txn_commit;
709 Rolls back the current transaction. Equivalent to calling
710 $schema->storage->txn_rollback. See
711 L<DBIx::Class::Storage/"txn_rollback"> for more information.
718 $self->storage or $self->throw_exception
719 ('txn_rollback called on $schema without storage');
721 $self->storage->txn_rollback;
726 my $storage = $schema->storage;
728 Returns the L<DBIx::Class::Storage> object for this Schema. Grab this
729 if you want to turn on SQL statement debugging at runtime, or set the
730 quote character. For the default storage, the documentation can be
731 found in L<DBIx::Class::Storage::DBI>.
737 =item Arguments: L<$source_name|DBIx::Class::ResultSource/source_name>, [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
739 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
743 A convenience shortcut to L<DBIx::Class::ResultSet/populate>. Equivalent to:
745 $schema->resultset($source_name)->populate([...]);
751 The context of this method call has an important effect on what is
752 submitted to storage. In void context data is fed directly to fastpath
753 insertion routines provided by the underlying storage (most often
754 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
755 L<insert|DBIx::Class::Row/insert> calls on the
756 L<Result|DBIx::Class::Manual::ResultClass> class, including any
757 augmentation of these methods provided by components. For example if you
758 are using something like L<DBIx::Class::UUIDColumns> to create primary
759 keys for you, you will find that your PKs are empty. In this case you
760 will have to explicitly force scalar or list context in order to create
768 my ($self, $name, $data) = @_;
769 my $rs = $self->resultset($name)
770 or $self->throw_exception("'$name' is not a resultset");
772 return $rs->populate($data);
779 =item Arguments: @args
781 =item Return Value: $new_schema
785 Similar to L</connect> except sets the storage object and connection
786 data in-place on the Schema class. You should probably be calling
787 L</connect> to get a proper Schema object instead.
791 Overload C<connection> to change the behaviour of C<connect>.
796 my ($self, @info) = @_;
797 return $self if !@info && $self->storage;
799 my ($storage_class, $args) = ref $self->storage_type
800 ? $self->_normalize_storage_type($self->storage_type)
801 : $self->storage_type
804 $storage_class =~ s/^::/DBIx::Class::Storage::/;
807 $self->ensure_class_loaded ($storage_class);
810 $self->throw_exception(
811 "Unable to load storage class ${storage_class}: $_"
815 my $storage = $storage_class->new( $self => $args||{} );
816 $storage->connect_info(\@info);
817 $self->storage($storage);
821 sub _normalize_storage_type {
822 my ($self, $storage_type) = @_;
823 if(ref $storage_type eq 'ARRAY') {
824 return @$storage_type;
825 } elsif(ref $storage_type eq 'HASH') {
826 return %$storage_type;
828 $self->throw_exception('Unsupported REFTYPE given: '. ref $storage_type);
832 =head2 compose_namespace
836 =item Arguments: $target_namespace, $additional_base_class?
838 =item Return Value: $new_schema
842 For each L<DBIx::Class::ResultSource> in the schema, this method creates a
843 class in the target namespace (e.g. $target_namespace::CD,
844 $target_namespace::Artist) that inherits from the corresponding classes
845 attached to the current schema.
847 It also attaches a corresponding L<DBIx::Class::ResultSource> object to the
848 new $schema object. If C<$additional_base_class> is given, the new composed
849 classes will inherit from first the corresponding class from the current
850 schema then the base class.
852 For example, for a schema with My::Schema::CD and My::Schema::Artist classes,
854 $schema->compose_namespace('My::DB', 'Base::Class');
855 print join (', ', @My::DB::CD::ISA) . "\n";
856 print join (', ', @My::DB::Artist::ISA) ."\n";
858 will produce the output
860 My::Schema::CD, Base::Class
861 My::Schema::Artist, Base::Class
865 # this might be oversimplified
866 # sub compose_namespace {
867 # my ($self, $target, $base) = @_;
869 # my $schema = $self->clone;
870 # foreach my $source_name ($schema->sources) {
871 # my $source = $schema->source($source_name);
872 # my $target_class = "${target}::${source_name}";
873 # $self->inject_base(
874 # $target_class => $source->result_class, ($base ? $base : ())
876 # $source->result_class($target_class);
877 # $target_class->result_source_instance($source)
878 # if $target_class->can('result_source_instance');
879 # $schema->register_source($source_name, $source);
884 sub compose_namespace {
885 my ($self, $target, $base) = @_;
887 my $schema = $self->clone;
889 $schema->source_registrations({});
891 # the original class-mappings must remain - otherwise
892 # reverse_relationship_info will not work
893 #$schema->class_mappings({});
896 no warnings qw/redefine/;
897 local *Class::C3::reinitialize = sub { } if DBIx::Class::_ENV_::OLD_MRO;
898 use warnings qw/redefine/;
901 foreach my $source_name ($self->sources) {
902 my $orig_source = $self->source($source_name);
904 my $target_class = "${target}::${source_name}";
905 $self->inject_base($target_class, $orig_source->result_class, ($base || ()) );
907 # register_source examines result_class, and then returns us a clone
908 my $new_source = $schema->register_source($source_name, bless
909 { %$orig_source, result_class => $target_class },
913 if ($target_class->can('result_source_instance')) {
914 # give the class a schema-less source copy
915 $target_class->result_source_instance( bless
916 { %$new_source, schema => ref $new_source->{schema} || $new_source->{schema} },
922 foreach my $meth (qw/class source resultset/) {
923 no warnings 'redefine';
924 *{"${target}::${meth}"} = subname "${target}::${meth}" =>
925 sub { shift->schema->$meth(@_) };
929 Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
934 sub setup_connection_class {
935 my ($class, $target, @info) = @_;
936 $class->inject_base($target => 'DBIx::Class::DB');
937 #$target->load_components('DB');
938 $target->connection(@info);
943 Creates a new savepoint (does nothing outside a transaction).
944 Equivalent to calling $schema->storage->svp_begin. See
945 L<DBIx::Class::Storage/"svp_begin"> for more information.
950 my ($self, $name) = @_;
952 $self->storage or $self->throw_exception
953 ('svp_begin called on $schema without storage');
955 $self->storage->svp_begin($name);
960 Releases a savepoint (does nothing outside a transaction).
961 Equivalent to calling $schema->storage->svp_release. See
962 L<DBIx::Class::Storage/"svp_release"> for more information.
967 my ($self, $name) = @_;
969 $self->storage or $self->throw_exception
970 ('svp_release called on $schema without storage');
972 $self->storage->svp_release($name);
977 Rollback to a savepoint (does nothing outside a transaction).
978 Equivalent to calling $schema->storage->svp_rollback. See
979 L<DBIx::Class::Storage/"svp_rollback"> for more information.
984 my ($self, $name) = @_;
986 $self->storage or $self->throw_exception
987 ('svp_rollback called on $schema without storage');
989 $self->storage->svp_rollback($name);
996 =item Arguments: %attrs?
998 =item Return Value: $new_schema
1002 Clones the schema and its associated result_source objects and returns the
1003 copy. The resulting copy will have the same attributes as the source schema,
1004 except for those attributes explicitly overridden by the provided C<%attrs>.
1012 (ref $self ? %$self : ()),
1013 (@_ == 1 && ref $_[0] eq 'HASH' ? %{ $_[0] } : @_),
1015 bless $clone, (ref $self || $self);
1017 $clone->$_(undef) for qw/class_mappings source_registrations storage/;
1019 $clone->_copy_state_from($self);
1024 # Needed in Schema::Loader - if you refactor, please make a compatibility shim
1026 sub _copy_state_from {
1027 my ($self, $from) = @_;
1029 $self->class_mappings({ %{$from->class_mappings} });
1030 $self->source_registrations({ %{$from->source_registrations} });
1032 foreach my $source_name ($from->sources) {
1033 my $source = $from->source($source_name);
1034 my $new = $source->new($source);
1035 # we use extra here as we want to leave the class_mappings as they are
1036 # but overwrite the source_registrations entry with the new source
1037 $self->register_extra_source($source_name => $new);
1040 if ($from->storage) {
1041 $self->storage($from->storage);
1042 $self->storage->set_schema($self);
1046 =head2 throw_exception
1050 =item Arguments: $message
1054 Throws an exception. Obeys the exemption rules of L<DBIx::Class::Carp> to report
1055 errors from outer-user's perspective. See L</exception_action> for details on overriding
1056 this method's behavior. If L</stacktrace> is turned on, C<throw_exception>'s
1057 default behavior will provide a detailed stack trace.
1061 sub throw_exception {
1064 if (my $act = $self->exception_action) {
1066 DBIx::Class::Exception->throw(
1067 "Invocation of the exception_action handler installed on $self did *not*"
1068 .' result in an exception. DBIx::Class is unable to function without a reliable'
1069 .' exception mechanism, ensure that exception_action does not hide exceptions'
1070 ." (original error: $_[0])"
1075 "The exception_action handler installed on $self returned false instead"
1076 .' of throwing an exception. This behavior has been deprecated, adjust your'
1077 .' handler to always rethrow the supplied error.'
1081 DBIx::Class::Exception->throw($_[0], $self->stacktrace);
1088 =item Arguments: \%sqlt_args, $dir
1092 Attempts to deploy the schema to the current storage using L<SQL::Translator>.
1094 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
1095 The most common value for this would be C<< { add_drop_table => 1 } >>
1096 to have the SQL produced include a C<DROP TABLE> statement for each table
1097 created. For quoting purposes supply C<quote_identifiers>.
1099 Additionally, the DBIx::Class parser accepts a C<sources> parameter as a hash
1100 ref or an array ref, containing a list of source to deploy. If present, then
1101 only the sources listed will get deployed. Furthermore, you can use the
1102 C<add_fk_index> parser parameter to prevent the parser from creating an index for each
1108 my ($self, $sqltargs, $dir) = @_;
1109 $self->throw_exception("Can't deploy without storage") unless $self->storage;
1110 $self->storage->deploy($self, undef, $sqltargs, $dir);
1113 =head2 deployment_statements
1117 =item Arguments: See L<DBIx::Class::Storage::DBI/deployment_statements>
1119 =item Return Value: $listofstatements
1123 A convenient shortcut to
1124 C<< $self->storage->deployment_statements($self, @args) >>.
1125 Returns the SQL statements used by L</deploy> and
1126 L<DBIx::Class::Schema::Storage/deploy>.
1130 sub deployment_statements {
1133 $self->throw_exception("Can't generate deployment statements without a storage")
1134 if not $self->storage;
1136 $self->storage->deployment_statements($self, @_);
1139 =head2 create_ddl_dir
1143 =item Arguments: See L<DBIx::Class::Storage::DBI/create_ddl_dir>
1147 A convenient shortcut to
1148 C<< $self->storage->create_ddl_dir($self, @args) >>.
1150 Creates an SQL file based on the Schema, for each of the specified
1151 database types, in the given directory.
1155 sub create_ddl_dir {
1158 $self->throw_exception("Can't create_ddl_dir without storage") unless $self->storage;
1159 $self->storage->create_ddl_dir($self, @_);
1166 =item Arguments: $database-type, $version, $directory, $preversion
1168 =item Return Value: $normalised_filename
1172 my $filename = $table->ddl_filename($type, $version, $dir, $preversion)
1174 This method is called by C<create_ddl_dir> to compose a file name out of
1175 the supplied directory, database type and version number. The default file
1176 name format is: C<$dir$schema-$version-$type.sql>.
1178 You may override this method in your schema if you wish to use a different
1183 Prior to DBIx::Class version 0.08100 this method had a different signature:
1185 my $filename = $table->ddl_filename($type, $dir, $version, $preversion)
1187 In recent versions variables $dir and $version were reversed in order to
1188 bring the signature in line with other Schema/Storage methods. If you
1189 really need to maintain backward compatibility, you can do the following
1190 in any overriding methods:
1192 ($dir, $version) = ($version, $dir) if ($DBIx::Class::VERSION < 0.08100);
1197 my ($self, $type, $version, $dir, $preversion) = @_;
1201 $version = "$preversion-$version" if $preversion;
1203 my $class = blessed($self) || $self;
1206 return File::Spec->catfile($dir, "$class-$version-$type.sql");
1211 Provided as the recommended way of thawing schema objects. You can call
1212 C<Storable::thaw> directly if you wish, but the thawed objects will not have a
1213 reference to any schema, so are rather useless.
1218 my ($self, $obj) = @_;
1219 local $DBIx::Class::ResultSourceHandle::thaw_schema = $self;
1221 return Storable::thaw($obj);
1226 This doesn't actually do anything more than call L<Storable/nfreeze>, it is just
1227 provided here for symmetry.
1233 return Storable::nfreeze($_[1]);
1240 =item Arguments: $object
1242 =item Return Value: dcloned $object
1246 Recommended way of dcloning L<DBIx::Class::Row> and L<DBIx::Class::ResultSet>
1247 objects so their references to the schema object
1248 (which itself is B<not> cloned) are properly maintained.
1253 my ($self, $obj) = @_;
1254 local $DBIx::Class::ResultSourceHandle::thaw_schema = $self;
1256 return Storable::dclone($obj);
1259 =head2 schema_version
1261 Returns the current schema class' $VERSION in a normalised way.
1265 sub schema_version {
1267 my $class = ref($self)||$self;
1269 # does -not- use $schema->VERSION
1270 # since that varies in results depending on if version.pm is installed, and if
1271 # so the perl or XS versions. If you want this to change, bug the version.pm
1272 # author to make vpp and vxs behave the same.
1277 $version = ${"${class}::VERSION"};
1283 =head2 register_class
1287 =item Arguments: $source_name, $component_class
1291 This method is called by L</load_namespaces> and L</load_classes> to install the found classes into your Schema. You should be using those instead of this one.
1293 You will only need this method if you have your Result classes in
1294 files which are not named after the packages (or all in the same
1295 file). You may also need it to register classes at runtime.
1297 Registers a class which isa DBIx::Class::ResultSourceProxy. Equivalent to
1300 $schema->register_source($source_name, $component_class->result_source_instance);
1304 sub register_class {
1305 my ($self, $source_name, $to_register) = @_;
1306 $self->register_source($source_name => $to_register->result_source_instance);
1309 =head2 register_source
1313 =item Arguments: $source_name, L<$result_source|DBIx::Class::ResultSource>
1317 This method is called by L</register_class>.
1319 Registers the L<DBIx::Class::ResultSource> in the schema with the given
1324 sub register_source { shift->_register_source(@_) }
1326 =head2 unregister_source
1330 =item Arguments: $source_name
1334 Removes the L<DBIx::Class::ResultSource> from the schema for the given source name.
1338 sub unregister_source { shift->_unregister_source(@_) }
1340 =head2 register_extra_source
1344 =item Arguments: $source_name, L<$result_source|DBIx::Class::ResultSource>
1348 As L</register_source> but should be used if the result class already
1349 has a source and you want to register an extra one.
1353 sub register_extra_source { shift->_register_source(@_, { extra => 1 }) }
1355 sub _register_source {
1356 my ($self, $source_name, $source, $params) = @_;
1358 $source = $source->new({ %$source, source_name => $source_name });
1360 $source->schema($self);
1361 weaken $source->{schema} if ref($self);
1363 my %reg = %{$self->source_registrations};
1364 $reg{$source_name} = $source;
1365 $self->source_registrations(\%reg);
1367 return $source if $params->{extra};
1369 my $rs_class = $source->result_class;
1370 if ($rs_class and my $rsrc = try { $rs_class->result_source_instance } ) {
1371 my %map = %{$self->class_mappings};
1373 exists $map{$rs_class}
1375 $map{$rs_class} ne $source_name
1377 $rsrc ne $_[2] # orig_source
1380 "$rs_class already had a registered source which was replaced by this call. "
1381 . 'Perhaps you wanted register_extra_source(), though it is more likely you did '
1382 . 'something wrong.'
1386 $map{$rs_class} = $source_name;
1387 $self->class_mappings(\%map);
1393 my $global_phase_destroy;
1395 return if $global_phase_destroy ||= in_global_destruction;
1398 my $srcs = $self->source_registrations;
1400 for my $source_name (keys %$srcs) {
1401 # find first source that is not about to be GCed (someone other than $self
1402 # holds a reference to it) and reattach to it, weakening our own link
1404 # during global destruction (if we have not yet bailed out) this should throw
1405 # which will serve as a signal to not try doing anything else
1406 # however beware - on older perls the exception seems randomly untrappable
1407 # due to some weird race condition during thread joining :(((
1408 if (ref $srcs->{$source_name} and svref_2object($srcs->{$source_name})->REFCNT > 1) {
1411 $srcs->{$source_name}->schema($self);
1412 weaken $srcs->{$source_name};
1415 $global_phase_destroy = 1;
1423 sub _unregister_source {
1424 my ($self, $source_name) = @_;
1425 my %reg = %{$self->source_registrations};
1427 my $source = delete $reg{$source_name};
1428 $self->source_registrations(\%reg);
1429 if ($source->result_class) {
1430 my %map = %{$self->class_mappings};
1431 delete $map{$source->result_class};
1432 $self->class_mappings(\%map);
1437 =head2 compose_connection (DEPRECATED)
1441 =item Arguments: $target_namespace, @db_info
1443 =item Return Value: $new_schema
1447 DEPRECATED. You probably wanted compose_namespace.
1449 Actually, you probably just wanted to call connect.
1453 (hidden due to deprecation)
1455 Calls L<DBIx::Class::Schema/"compose_namespace"> to the target namespace,
1456 calls L<DBIx::Class::Schema/connection> with @db_info on the new schema,
1457 then injects the L<DBix::Class::ResultSetProxy> component and a
1458 resultset_instance classdata entry on all the new classes, in order to support
1459 $target_namespaces::$class->search(...) method calls.
1461 This is primarily useful when you have a specific need for class method access
1462 to a connection. In normal usage it is preferred to call
1463 L<DBIx::Class::Schema/connect> and use the resulting schema object to operate
1464 on L<DBIx::Class::ResultSet> objects with L<DBIx::Class::Schema/resultset> for
1471 sub compose_connection {
1472 my ($self, $target, @info) = @_;
1474 carp_once "compose_connection deprecated as of 0.08000"
1475 unless $INC{"DBIx/Class/CDBICompat.pm"};
1477 my $base = 'DBIx::Class::ResultSetProxy';
1479 eval "require ${base};"
1482 $self->throw_exception
1483 ("No arguments to load_classes and couldn't load ${base} ($_)")
1486 if ($self eq $target) {
1487 # Pathological case, largely caused by the docs on early C::M::DBIC::Plain
1488 foreach my $source_name ($self->sources) {
1489 my $source = $self->source($source_name);
1490 my $class = $source->result_class;
1491 $self->inject_base($class, $base);
1492 $class->mk_classdata(resultset_instance => $source->resultset);
1493 $class->mk_classdata(class_resolver => $self);
1495 $self->connection(@info);
1499 my $schema = $self->compose_namespace($target, $base);
1502 my $name = join '::', $target, 'schema';
1503 *$name = subname $name, sub { $schema };
1506 $schema->connection(@info);
1507 foreach my $source_name ($schema->sources) {
1508 my $source = $schema->source($source_name);
1509 my $class = $source->result_class;
1510 #warn "$source_name $class $source ".$source->storage;
1511 $class->mk_classdata(result_source_instance => $source);
1512 $class->mk_classdata(resultset_instance => $source->resultset);
1513 $class->mk_classdata(class_resolver => $schema);
1520 =head1 AUTHOR AND CONTRIBUTORS
1522 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
1526 You may distribute this code under the same terms as Perl itself.