lib/DBIx/Class/SQLMaker.pm

   1 package DBIx::Class::SQLMaker;
   2
   3 =head1 NAME
   4
   5 DBIx::Class::SQLMaker - An SQL::Abstract-based SQL maker class
   6
   7 =head1 DESCRIPTION
   8
   9 This module is a subclass of L<SQL::Abstract> and includes a number of
  10 DBIC-specific workarounds, not yet suitable for inclusion into the
  11 L<SQL::Abstract> core. It also provides all (and more than) the functionality
  12 of L<SQL::Abstract::Limit>, see L<DBIx::Class::SQLMaker::LimitDialects> for
  13 more info.
  14
  15 Currently the enhancements to L<SQL::Abstract> are:
  16
  17 =over
  18
  19 =item * Support for C<JOIN> statements (via extended C<table/from> support)
  20
  21 =item * Support of functions in C<SELECT> lists
  22
  23 =item * C<GROUP BY>/C<HAVING> support (via extensions to the order_by parameter)
  24
  25 =item * Support of C<...FOR UPDATE> type of select statement modifiers
  26
  27 =item * The -ident operator
  28
  29 =item * The -value operator
  30
  31 =back
  32
  33 =cut
  34
  35 use base qw/
  36   DBIx::Class::SQLMaker::LimitDialects
  37   SQL::Abstract
  38   Class::Accessor::Grouped
  39 /;
  40 use mro 'c3';
  41 use strict;
  42 use warnings;
  43 use Sub::Name 'subname';
  44 use Carp::Clan qw/^DBIx::Class|^SQL::Abstract|^Try::Tiny/;
  45 use namespace::clean;
  46
  47 __PACKAGE__->mk_group_accessors (simple => qw/quote_char name_sep limit_dialect/);
  48
  49 # for when I need a normalized l/r pair
  50 sub _quote_chars {
  51   map
  52     { defined $_ ? $_ : '' }
  53     ( ref $_[0]->{quote_char} ? (@{$_[0]->{quote_char}}) : ( ($_[0]->{quote_char}) x 2 ) )
  54   ;
  55 }
  56
  57 BEGIN {
  58   # reinstall the carp()/croak() functions imported into SQL::Abstract
  59   # as Carp and Carp::Clan do not like each other much
  60   no warnings qw/redefine/;
  61   no strict qw/refs/;
  62   for my $f (qw/carp croak/) {
  63
  64     my $orig = \&{"SQL::Abstract::$f"};
  65     my $clan_import = \&{$f};
  66     *{"SQL::Abstract::$f"} = subname "SQL::Abstract::$f" =>
  67       sub {
  68         if (Carp::longmess() =~ /DBIx::Class::SQLMaker::[\w]+ .+? called \s at/x) {
  69           goto $clan_import;
  70         }
  71         else {
  72           goto $orig;
  73         }
  74       };
  75   }
  76 }
  77
  78 # the "oh noes offset/top without limit" constant
  79 # limited to 32 bits for sanity (and consistency,
  80 # since it is ultimately handed to sprintf %u)
  81 # Implemented as a method, since ::Storage::DBI also
  82 # refers to it (i.e. for the case of software_limit or
  83 # as the value to abuse with MSSQL ordered subqueries)
  84 sub __max_int { 0xFFFFFFFF };
  85
  86 sub new {
  87   my $self = shift->next::method(@_);
  88
  89   # use the same coderefs, they are prepared to handle both cases
  90   my @extra_dbic_syntax = (
  91     { regex => qr/^ ident $/xi, handler => '_where_op_IDENT' },
  92     { regex => qr/^ value $/xi, handler => '_where_op_VALUE' },
  93   );
  94
  95   push @{$self->{special_ops}}, @extra_dbic_syntax;
  96   push @{$self->{unary_ops}}, @extra_dbic_syntax;
  97
  98   $self;
  99 }
 100
 101 sub _where_op_IDENT {
 102   my $self = shift;
 103   my ($op, $rhs) = splice @_, -2;
 104   if (ref $rhs) {
 105     croak "-$op takes a single scalar argument (a quotable identifier)";
 106   }
 107
 108   # in case we are called as a top level special op (no '=')
 109   my $lhs = shift;
 110
 111   $_ = $self->_convert($self->_quote($_)) for ($lhs, $rhs);
 112
 113   return $lhs
 114     ? "$lhs = $rhs"
 115     : $rhs
 116   ;
 117 }
 118
 119 sub _where_op_VALUE {
 120   my $self = shift;
 121   my ($op, $rhs) = splice @_, -2;
 122
 123   # in case we are called as a top level special op (no '=')
 124   my $lhs = shift;
 125
 126   my @bind = [
 127     ($lhs || $self->{_nested_func_lhs} || croak "Unable to find bindtype for -value $rhs"),
 128     $rhs
 129   ];
 130
 131   return $lhs
 132     ? (
 133       $self->_convert($self->_quote($lhs)) . ' = ' . $self->_convert('?'),
 134       @bind
 135     )
 136     : (
 137       $self->_convert('?'),
 138       @bind,
 139     )
 140   ;
 141 }
 142
 143 my $callsites_warned;
 144 sub _where_op_NEST {
 145   # determine callsite obeying Carp::Clan rules (fucking ugly but don't have better ideas)
 146   my $callsite = do {
 147     my $w;
 148     local $SIG{__WARN__} = sub { $w = shift };
 149     carp;
 150     $w
 151   };
 152
 153   carp ("-nest in search conditions is deprecated, you most probably wanted:\n"
 154       .q|{..., -and => [ \%cond0, \@cond1, \'cond2', \[ 'cond3', [ col => bind ] ], etc. ], ... }|
 155   ) unless $callsites_warned->{$callsite}++;
 156
 157   shift->next::method(@_);
 158 }
 159
 160 # Handle limit-dialect selection
 161 sub select {
 162   my ($self, $table, $fields, $where, $rs_attrs, $limit, $offset) = @_;
 163
 164
 165   $fields = $self->_recurse_fields($fields);
 166
 167   if (defined $offset) {
 168     croak ('A supplied offset must be a non-negative integer')
 169       if ( $offset =~ /\D/ or $offset < 0 );
 170   }
 171   $offset ||= 0;
 172
 173   if (defined $limit) {
 174     croak ('A supplied limit must be a positive integer')
 175       if ( $limit =~ /\D/ or $limit <= 0 );
 176   }
 177   elsif ($offset) {
 178     $limit = $self->__max_int;
 179   }
 180
 181
 182   my ($sql, @bind);
 183   if ($limit) {
 184     # this is legacy code-flow from SQLA::Limit, it is not set in stone
 185
 186     ($sql, @bind) = $self->next::method ($table, $fields, $where);
 187
 188     my $limiter =
 189       $self->can ('emulate_limit')  # also backcompat hook from SQLA::Limit
 190         ||
 191       do {
 192         my $dialect = $self->limit_dialect
 193           or croak "Unable to generate SQL-limit - no limit dialect specified on $self, and no emulate_limit method found";
 194         $self->can ("_$dialect")
 195           or croak (__PACKAGE__ . " does not implement the requested dialect '$dialect'");
 196       }
 197     ;
 198
 199     $sql = $self->$limiter ($sql, $rs_attrs, $limit, $offset);
 200   }
 201   else {
 202     ($sql, @bind) = $self->next::method ($table, $fields, $where, $rs_attrs);
 203   }
 204
 205   push @{$self->{where_bind}}, @bind;
 206
 207 # this *must* be called, otherwise extra binds will remain in the sql-maker
 208   my @all_bind = $self->_assemble_binds;
 209
 210   $sql .= $self->_lock_select ($rs_attrs->{for})
 211     if $rs_attrs->{for};
 212
 213   return wantarray ? ($sql, @all_bind) : $sql;
 214 }
 215
 216 sub _assemble_binds {
 217   my $self = shift;
 218   return map { @{ (delete $self->{"${_}_bind"}) || [] } } (qw/select from where group having order/);
 219 }
 220
 221 my $for_syntax = {
 222   update => 'FOR UPDATE',
 223   shared => 'FOR SHARE',
 224 };
 225 sub _lock_select {
 226   my ($self, $type) = @_;
 227   my $sql = $for_syntax->{$type} || croak "Unknown SELECT .. FOR type '$type' requested";
 228   return " $sql";
 229 }
 230
 231 # Handle default inserts
 232 sub insert {
 233 # optimized due to hotttnesss
 234 #  my ($self, $table, $data, $options) = @_;
 235
 236   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 237   # which is sadly understood only by MySQL. Change default behavior here,
 238   # until SQLA2 comes with proper dialect support
 239   if (! $_[2] or (ref $_[2] eq 'HASH' and !keys %{$_[2]} ) ) {
 240     my @bind;
 241     my $sql = sprintf(
 242       'INSERT INTO %s DEFAULT VALUES', $_[0]->_quote($_[1])
 243     );
 244
 245     if ( ($_[3]||{})->{returning} ) {
 246       my $s;
 247       ($s, @bind) = $_[0]->_insert_returning ($_[3]);
 248       $sql .= $s;
 249     }
 250
 251     return ($sql, @bind);
 252   }
 253
 254   next::method(@_);
 255 }
 256
 257 sub _recurse_fields {
 258   my ($self, $fields) = @_;
 259   my $ref = ref $fields;
 260   return $self->_quote($fields) unless $ref;
 261   return $$fields if $ref eq 'SCALAR';
 262
 263   if ($ref eq 'ARRAY') {
 264     return join(', ', map { $self->_recurse_fields($_) } @$fields);
 265   }
 266   elsif ($ref eq 'HASH') {
 267     my %hash = %$fields;  # shallow copy
 268
 269     my $as = delete $hash{-as};   # if supplied
 270
 271     my ($func, $args, @toomany) = %hash;
 272
 273     # there should be only one pair
 274     if (@toomany) {
 275       croak "Malformed select argument - too many keys in hash: " . join (',', keys %$fields );
 276     }
 277
 278     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
 279       croak (
 280         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 281        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
 282        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
 283       );
 284     }
 285
 286     my $select = sprintf ('%s( %s )%s',
 287       $self->_sqlcase($func),
 288       $self->_recurse_fields($args),
 289       $as
 290         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
 291         : ''
 292     );
 293
 294     return $select;
 295   }
 296   # Is the second check absolutely necessary?
 297   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 298     push @{$self->{select_bind}}, @{$$fields}[1..$#$$fields];
 299     return $$fields->[0];
 300   }
 301   else {
 302     croak($ref . qq{ unexpected in _recurse_fields()})
 303   }
 304 }
 305
 306
 307 # this used to be a part of _order_by but is broken out for clarity.
 308 # What we have been doing forever is hijacking the $order arg of
 309 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
 310 # then pretty much the entire resultset attr-hash, as more and more
 311 # things in the SQLA space need to have mopre info about the $rs they
 312 # create SQL for. The alternative would be to keep expanding the
 313 # signature of _select with more and more positional parameters, which
 314 # is just gross. All hail SQLA2!
 315 sub _parse_rs_attrs {
 316   my ($self, $arg) = @_;
 317
 318   my $sql = '';
 319
 320   if ($arg->{group_by}) {
 321     # horible horrible, waiting for refactor
 322     local $self->{select_bind};
 323     if (my $g = $self->_recurse_fields($arg->{group_by}) ) {
 324       $sql .= $self->_sqlcase(' group by ') . $g;
 325       push @{$self->{group_bind} ||= []}, @{$self->{select_bind}||[]};
 326     }
 327   }
 328
 329   if (defined $arg->{having}) {
 330     my ($frag, @bind) = $self->_recurse_where($arg->{having});
 331     push(@{$self->{having_bind}}, @bind);
 332     $sql .= $self->_sqlcase(' having ') . $frag;
 333   }
 334
 335   if (defined $arg->{order_by}) {
 336     $sql .= $self->_order_by ($arg->{order_by});
 337   }
 338
 339   return $sql;
 340 }
 341
 342 sub _order_by {
 343   my ($self, $arg) = @_;
 344
 345   # check that we are not called in legacy mode (order_by as 4th argument)
 346   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 347     return $self->_parse_rs_attrs ($arg);
 348   }
 349   else {
 350     my ($sql, @bind) = $self->next::method($arg);
 351     push @{$self->{order_bind}}, @bind;
 352     return $sql;
 353   }
 354 }
 355
 356 sub _table {
 357 # optimized due to hotttnesss
 358 #  my ($self, $from) = @_;
 359   if (my $ref = ref $_[1] ) {
 360     if ($ref eq 'ARRAY') {
 361       return $_[0]->_recurse_from(@{$_[1]});
 362     }
 363     elsif ($ref eq 'HASH') {
 364       return $_[0]->_recurse_from($_[1]);
 365     }
 366   }
 367
 368   return $_[0]->next::method ($_[1]);
 369 }
 370
 371 sub _generate_join_clause {
 372     my ($self, $join_type) = @_;
 373
 374     return sprintf ('%s JOIN ',
 375       $join_type ?  ' ' . $self->_sqlcase($join_type) : ''
 376     );
 377 }
 378
 379 sub _recurse_from {
 380   my ($self, $from, @join) = @_;
 381   my @sqlf;
 382   push @sqlf, $self->_from_chunk_to_sql($from);
 383
 384   for (@join) {
 385     my ($to, $on) = @$_;
 386
 387     # check whether a join type exists
 388     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 389     my $join_type;
 390     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 391       $join_type = $to_jt->{-join_type};
 392       $join_type =~ s/^\s+ | \s+$//xg;
 393     }
 394
 395     $join_type = $self->{_default_jointype} if not defined $join_type;
 396
 397     push @sqlf, $self->_generate_join_clause( $join_type );
 398
 399     if (ref $to eq 'ARRAY') {
 400       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 401     } else {
 402       push(@sqlf, $self->_from_chunk_to_sql($to));
 403     }
 404     push(@sqlf, ' ON ', $self->_join_condition($on));
 405   }
 406   return join('', @sqlf);
 407 }
 408
 409 sub _from_chunk_to_sql {
 410   my ($self, $fromspec) = @_;
 411
 412   return join (' ', $self->_SWITCH_refkind($fromspec, {
 413     SCALARREF => sub {
 414       $$fromspec;
 415     },
 416     ARRAYREFREF => sub {
 417       push @{$self->{from_bind}}, @{$$fromspec}[1..$#$$fromspec];
 418       $$fromspec->[0];
 419     },
 420     HASHREF => sub {
 421       my ($as, $table, $toomuch) = ( map
 422         { $_ => $fromspec->{$_} }
 423         ( grep { $_ !~ /^\-/ } keys %$fromspec )
 424       );
 425
 426       croak "Only one table/as pair expected in from-spec but an exra '$toomuch' key present"
 427         if defined $toomuch;
 428
 429       ($self->_from_chunk_to_sql($table), $self->_quote($as) );
 430     },
 431     SCALAR => sub {
 432       $self->_quote($fromspec);
 433     },
 434   }));
 435 }
 436
 437 sub _join_condition {
 438   my ($self, $cond) = @_;
 439
 440   if (ref $cond eq 'HASH') {
 441     my %j;
 442     for (keys %$cond) {
 443       my $v = $cond->{$_};
 444       if (ref $v) {
 445         croak (ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 446             if ref($v) ne 'SCALAR';
 447         $j{$_} = $v;
 448       }
 449       else {
 450         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 451       }
 452     };
 453     return scalar($self->_recurse_where(\%j));
 454   } elsif (ref $cond eq 'ARRAY') {
 455     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 456   } else {
 457     croak "Can't handle this yet!";
 458   }
 459 }
 460
 461 1;
 462
 463 =head1 AUTHORS
 464
 465 See L<DBIx::Class/CONTRIBUTORS>.
 466
 467 =head1 LICENSE
 468
 469 You may distribute this code under the same terms as Perl itself.
 470
 471 =cut