lib/DBIx/Class/SQLMaker.pm

   1 package DBIx::Class::SQLMaker;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 DBIx::Class::SQLMaker - An SQL::Abstract-based SQL maker class
   9
  10 =head1 DESCRIPTION
  11
  12 This module is a subclass of L<SQL::Abstract> and includes a number of
  13 DBIC-specific workarounds, not yet suitable for inclusion into the
  14 L<SQL::Abstract> core. It also provides all (and more than) the functionality
  15 of L<SQL::Abstract::Limit>, see L<DBIx::Class::SQLMaker::LimitDialects> for
  16 more info.
  17
  18 Currently the enhancements to L<SQL::Abstract> are:
  19
  20 =over
  21
  22 =item * Support for C<JOIN> statements (via extended C<table/from> support)
  23
  24 =item * Support of functions in C<SELECT> lists
  25
  26 =item * C<GROUP BY>/C<HAVING> support (via extensions to the order_by parameter)
  27
  28 =item * Support of C<...FOR UPDATE> type of select statement modifiers
  29
  30 =back
  31
  32 =cut
  33
  34 use base qw/
  35   DBIx::Class::SQLMaker::LimitDialects
  36   SQL::Abstract
  37   DBIx::Class
  38 /;
  39 use mro 'c3';
  40
  41 use Sub::Name 'subname';
  42 use DBIx::Class::Carp;
  43 use namespace::clean;
  44
  45 __PACKAGE__->mk_group_accessors (simple => qw/quote_char name_sep limit_dialect/);
  46
  47 # for when I need a normalized l/r pair
  48 sub _quote_chars {
  49   map
  50     { defined $_ ? $_ : '' }
  51     ( ref $_[0]->{quote_char} ? (@{$_[0]->{quote_char}}) : ( ($_[0]->{quote_char}) x 2 ) )
  52   ;
  53 }
  54
  55 # FIXME when we bring in the storage weaklink, check its schema
  56 # weaklink and channel through $schema->throw_exception
  57 sub throw_exception { DBIx::Class::Exception->throw($_[1]) }
  58
  59 BEGIN {
  60   # reinstall the belch()/puke() functions of SQL::Abstract with custom versions
  61   # that use DBIx::Class::Carp/DBIx::Class::Exception instead of plain Carp
  62   no warnings qw/redefine/;
  63
  64   *SQL::Abstract::belch = subname 'SQL::Abstract::belch' => sub (@) {
  65     my($func) = (caller(1))[3];
  66     carp "[$func] Warning: ", @_;
  67   };
  68
  69   *SQL::Abstract::puke = subname 'SQL::Abstract::puke' => sub (@) {
  70     my($func) = (caller(1))[3];
  71     __PACKAGE__->throw_exception("[$func] Fatal: " . join ('',  @_));
  72   };
  73 }
  74
  75 # the "oh noes offset/top without limit" constant
  76 # limited to 31 bits for sanity (and consistency,
  77 # since it may be handed to the like of sprintf %u)
  78 #
  79 # Also *some* builds of SQLite fail the test
  80 #   some_column BETWEEN ? AND ?: 1, 4294967295
  81 # with the proper integer bind attrs
  82 #
  83 # Implemented as a method, since ::Storage::DBI also
  84 # refers to it (i.e. for the case of software_limit or
  85 # as the value to abuse with MSSQL ordered subqueries)
  86 sub __max_int () { 0x7FFFFFFF };
  87
  88 # we ne longer need to check this - DBIC has ways of dealing with it
  89 # specifically ::Storage::DBI::_resolve_bindattrs()
  90 sub _assert_bindval_matches_bindtype () { 1 };
  91
  92 # poor man's de-qualifier
  93 sub _quote {
  94   $_[0]->next::method( ( $_[0]{_dequalify_idents} and ! ref $_[1] )
  95     ? $_[1] =~ / ([^\.]+) $ /x
  96     : $_[1]
  97   );
  98 }
  99
 100 sub _where_op_NEST {
 101   carp_unique ("-nest in search conditions is deprecated, you most probably wanted:\n"
 102       .q|{..., -and => [ \%cond0, \@cond1, \'cond2', \[ 'cond3', [ col => bind ] ], etc. ], ... }|
 103   );
 104
 105   shift->next::method(@_);
 106 }
 107
 108 # Handle limit-dialect selection
 109 sub select {
 110   my ($self, $table, $fields, $where, $rs_attrs, $limit, $offset) = @_;
 111
 112
 113   $fields = $self->_recurse_fields($fields);
 114
 115   if (defined $offset) {
 116     $self->throw_exception('A supplied offset must be a non-negative integer')
 117       if ( $offset =~ /\D/ or $offset < 0 );
 118   }
 119   $offset ||= 0;
 120
 121   if (defined $limit) {
 122     $self->throw_exception('A supplied limit must be a positive integer')
 123       if ( $limit =~ /\D/ or $limit <= 0 );
 124   }
 125   elsif ($offset) {
 126     $limit = $self->__max_int;
 127   }
 128
 129
 130   my ($sql, @bind);
 131   if ($limit) {
 132     # this is legacy code-flow from SQLA::Limit, it is not set in stone
 133
 134     ($sql, @bind) = $self->next::method ($table, $fields, $where);
 135
 136     my $limiter;
 137
 138     if( $limiter = $self->can ('emulate_limit') ) {
 139       carp_unique(
 140         'Support for the legacy emulate_limit() mechanism inherited from '
 141       . 'SQL::Abstract::Limit has been deprecated, and will be removed when '
 142       . 'DBIC transitions to Data::Query. If your code uses this type of '
 143       . 'limit specification please file an RT and provide the source of '
 144       . 'your emulate_limit() implementation, so an acceptable upgrade-path '
 145       . 'can be devised'
 146       );
 147     }
 148     else {
 149       my $dialect = $self->limit_dialect
 150         or $self->throw_exception( "Unable to generate SQL-limit - no limit dialect specified on $self" );
 151
 152       $limiter = $self->can ("_$dialect")
 153         or $self->throw_exception(__PACKAGE__ . " does not implement the requested dialect '$dialect'");
 154     }
 155
 156     $sql = $self->$limiter (
 157       $sql,
 158       { %{$rs_attrs||{}}, _selector_sql => $fields },
 159       $limit,
 160       $offset
 161     );
 162   }
 163   else {
 164     ($sql, @bind) = $self->next::method ($table, $fields, $where, $rs_attrs);
 165   }
 166
 167   push @{$self->{where_bind}}, @bind;
 168
 169 # this *must* be called, otherwise extra binds will remain in the sql-maker
 170   my @all_bind = $self->_assemble_binds;
 171
 172   $sql .= $self->_lock_select ($rs_attrs->{for})
 173     if $rs_attrs->{for};
 174
 175   return wantarray ? ($sql, @all_bind) : $sql;
 176 }
 177
 178 sub _assemble_binds {
 179   my $self = shift;
 180   return map { @{ (delete $self->{"${_}_bind"}) || [] } } (qw/pre_select select from where group having order limit/);
 181 }
 182
 183 my $for_syntax = {
 184   update => 'FOR UPDATE',
 185   shared => 'FOR SHARE',
 186 };
 187 sub _lock_select {
 188   my ($self, $type) = @_;
 189
 190   my $sql;
 191   if (ref($type) eq 'SCALAR') {
 192     $sql = "FOR $$type";
 193   }
 194   else {
 195     $sql = $for_syntax->{$type} || $self->throw_exception( "Unknown SELECT .. FOR type '$type' requested" );
 196   }
 197
 198   return " $sql";
 199 }
 200
 201 # Handle default inserts
 202 sub insert {
 203 # optimized due to hotttnesss
 204 #  my ($self, $table, $data, $options) = @_;
 205
 206   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 207   # which is sadly understood only by MySQL. Change default behavior here,
 208   # until SQLA2 comes with proper dialect support
 209   if (! $_[2] or (ref $_[2] eq 'HASH' and !keys %{$_[2]} ) ) {
 210     my @bind;
 211     my $sql = sprintf(
 212       'INSERT INTO %s DEFAULT VALUES', $_[0]->_quote($_[1])
 213     );
 214
 215     if ( ($_[3]||{})->{returning} ) {
 216       my $s;
 217       ($s, @bind) = $_[0]->_insert_returning ($_[3]);
 218       $sql .= $s;
 219     }
 220
 221     return ($sql, @bind);
 222   }
 223
 224   next::method(@_);
 225 }
 226
 227 sub _insert_ARRAYREFREF {
 228   my ($self, $data) = @_;
 229
 230   my ($cols, $subquery) = @$data;
 231   if (not $subuery) {
 232     # if somehow someone is calling this with the original SQLA api,
 233     # pass it along
 234     return next::method($self, $cols);
 235   }
 236
 237   my $subsql, @subbind = @$subquery;
 238
 239   my @fields = sort @$cols;
 240
 241   my ($sql, @bind) = $self->_insert_values($data);
 242
 243   $_ = $self->_quote($_) foreach @$fields;
 244   $sql = "( ".join(", ", sort @$fields).") ".$sql;
 245
 246   return ($sql, @bind);
 247
 248   # when passing ARRAYREFREF with [cols], SQLA drops INTO $table (cols)
 249   # we inject the returned sql here
 250   #$_ = $self->_quote($_) foreach @fields;
 251   #  $sql = "( ".join(", ", @fields).") ".$sql;
 252     my $sql = sprintf(
 253       'INSERT INTO %s( %s ) VALUES', $_[0]->_quote($_[1])
 254     );
 255 }
 256
 257 sub _recurse_fields {
 258   my ($self, $fields) = @_;
 259   my $ref = ref $fields;
 260   return $self->_quote($fields) unless $ref;
 261   return $$fields if $ref eq 'SCALAR';
 262
 263   if ($ref eq 'ARRAY') {
 264     return join(', ', map { $self->_recurse_fields($_) } @$fields);
 265   }
 266   elsif ($ref eq 'HASH') {
 267     my %hash = %$fields;  # shallow copy
 268
 269     my $as = delete $hash{-as};   # if supplied
 270
 271     my ($func, $args, @toomany) = %hash;
 272
 273     # there should be only one pair
 274     if (@toomany) {
 275       $self->throw_exception( "Malformed select argument - too many keys in hash: " . join (',', keys %$fields ) );
 276     }
 277
 278     if (lc ($func) eq 'distinct' && ref $args eq 'ARRAY' && @$args > 1) {
 279       $self->throw_exception (
 280         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 281        .' Instead please use { group_by => [ qw/' . (join ' ', @$args) . '/ ] }'
 282        .' or { select => [ qw/' . (join ' ', @$args) . '/ ], distinct => 1 }'
 283       );
 284     }
 285
 286     my $select = sprintf ('%s( %s )%s',
 287       $self->_sqlcase($func),
 288       $self->_recurse_fields($args),
 289       $as
 290         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
 291         : ''
 292     );
 293
 294     return $select;
 295   }
 296   # Is the second check absolutely necessary?
 297   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 298     push @{$self->{select_bind}}, @{$$fields}[1..$#$$fields];
 299     return $$fields->[0];
 300   }
 301   else {
 302     $self->throw_exception( $ref . qq{ unexpected in _recurse_fields()} );
 303   }
 304 }
 305
 306
 307 # this used to be a part of _order_by but is broken out for clarity.
 308 # What we have been doing forever is hijacking the $order arg of
 309 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
 310 # then pretty much the entire resultset attr-hash, as more and more
 311 # things in the SQLA space need to have more info about the $rs they
 312 # create SQL for. The alternative would be to keep expanding the
 313 # signature of _select with more and more positional parameters, which
 314 # is just gross. All hail SQLA2!
 315 sub _parse_rs_attrs {
 316   my ($self, $arg) = @_;
 317
 318   my $sql = '';
 319
 320   if ($arg->{group_by}) {
 321     # horrible horrible, waiting for refactor
 322     local $self->{select_bind};
 323     if (my $g = $self->_recurse_fields($arg->{group_by}) ) {
 324       $sql .= $self->_sqlcase(' group by ') . $g;
 325       push @{$self->{group_bind} ||= []}, @{$self->{select_bind}||[]};
 326     }
 327   }
 328
 329   if (defined $arg->{having}) {
 330     my ($frag, @bind) = $self->_recurse_where($arg->{having});
 331     push(@{$self->{having_bind}}, @bind);
 332     $sql .= $self->_sqlcase(' having ') . $frag;
 333   }
 334
 335   if (defined $arg->{order_by}) {
 336     $sql .= $self->_order_by ($arg->{order_by});
 337   }
 338
 339   return $sql;
 340 }
 341
 342 sub _order_by {
 343   my ($self, $arg) = @_;
 344
 345   # check that we are not called in legacy mode (order_by as 4th argument)
 346   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 347     return $self->_parse_rs_attrs ($arg);
 348   }
 349   else {
 350     my ($sql, @bind) = $self->next::method($arg);
 351     push @{$self->{order_bind}}, @bind;
 352     return $sql;
 353   }
 354 }
 355
 356 sub _split_order_chunk {
 357   my ($self, $chunk) = @_;
 358
 359   # strip off sort modifiers, but always succeed, so $1 gets reset
 360   $chunk =~ s/ (?: \s+ (ASC|DESC) )? \s* $//ix;
 361
 362   return (
 363     $chunk,
 364     ( $1 and uc($1) eq 'DESC' ) ? 1 : 0,
 365   );
 366 }
 367
 368 sub _table {
 369 # optimized due to hotttnesss
 370 #  my ($self, $from) = @_;
 371   if (my $ref = ref $_[1] ) {
 372     if ($ref eq 'ARRAY') {
 373       return $_[0]->_recurse_from(@{$_[1]});
 374     }
 375     elsif ($ref eq 'HASH') {
 376       return $_[0]->_recurse_from($_[1]);
 377     }
 378     elsif ($ref eq 'REF' && ref ${$_[1]} eq 'ARRAY') {
 379       my ($sql, @bind) = @{ ${$_[1]} };
 380       push @{$_[0]->{from_bind}}, @bind;
 381       return $sql
 382     }
 383   }
 384   return $_[0]->next::method ($_[1]);
 385 }
 386
 387 sub _generate_join_clause {
 388     my ($self, $join_type) = @_;
 389
 390     $join_type = $self->{_default_jointype}
 391       if ! defined $join_type;
 392
 393     return sprintf ('%s JOIN ',
 394       $join_type ?  $self->_sqlcase($join_type) : ''
 395     );
 396 }
 397
 398 sub _recurse_from {
 399   my $self = shift;
 400   return join (' ', $self->_gen_from_blocks(@_) );
 401 }
 402
 403 sub _gen_from_blocks {
 404   my ($self, $from, @joins) = @_;
 405
 406   my @fchunks = $self->_from_chunk_to_sql($from);
 407
 408   for (@joins) {
 409     my ($to, $on) = @$_;
 410
 411     # check whether a join type exists
 412     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 413     my $join_type;
 414     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 415       $join_type = $to_jt->{-join_type};
 416       $join_type =~ s/^\s+ | \s+$//xg;
 417     }
 418
 419     my @j = $self->_generate_join_clause( $join_type );
 420
 421     if (ref $to eq 'ARRAY') {
 422       push(@j, '(', $self->_recurse_from(@$to), ')');
 423     }
 424     else {
 425       push(@j, $self->_from_chunk_to_sql($to));
 426     }
 427
 428     my ($sql, @bind) = $self->_join_condition($on);
 429     push(@j, ' ON ', $sql);
 430     push @{$self->{from_bind}}, @bind;
 431
 432     push @fchunks, join '', @j;
 433   }
 434
 435   return @fchunks;
 436 }
 437
 438 sub _from_chunk_to_sql {
 439   my ($self, $fromspec) = @_;
 440
 441   return join (' ', do {
 442     if (! ref $fromspec) {
 443       $self->_quote($fromspec);
 444     }
 445     elsif (ref $fromspec eq 'SCALAR') {
 446       $$fromspec;
 447     }
 448     elsif (ref $fromspec eq 'REF' and ref $$fromspec eq 'ARRAY') {
 449       push @{$self->{from_bind}}, @{$$fromspec}[1..$#$$fromspec];
 450       $$fromspec->[0];
 451     }
 452     elsif (ref $fromspec eq 'HASH') {
 453       my ($as, $table, $toomuch) = ( map
 454         { $_ => $fromspec->{$_} }
 455         ( grep { $_ !~ /^\-/ } keys %$fromspec )
 456       );
 457
 458       $self->throw_exception( "Only one table/as pair expected in from-spec but an exra '$toomuch' key present" )
 459         if defined $toomuch;
 460
 461       ($self->_from_chunk_to_sql($table), $self->_quote($as) );
 462     }
 463     else {
 464       $self->throw_exception('Unsupported from refkind: ' . ref $fromspec );
 465     }
 466   });
 467 }
 468
 469 sub _join_condition {
 470   my ($self, $cond) = @_;
 471
 472   # Backcompat for the old days when a plain hashref
 473   # { 't1.col1' => 't2.col2' } meant ON t1.col1 = t2.col2
 474   # Once things settle we should start warning here so that
 475   # folks unroll their hacks
 476   if (
 477     ref $cond eq 'HASH'
 478       and
 479     keys %$cond == 1
 480       and
 481     (keys %$cond)[0] =~ /\./
 482       and
 483     ! ref ( (values %$cond)[0] )
 484   ) {
 485     $cond = { keys %$cond => { -ident => values %$cond } }
 486   }
 487   elsif ( ref $cond eq 'ARRAY' ) {
 488     # do our own ORing so that the hashref-shim above is invoked
 489     my @parts;
 490     my @binds;
 491     foreach my $c (@$cond) {
 492       my ($sql, @bind) = $self->_join_condition($c);
 493       push @binds, @bind;
 494       push @parts, $sql;
 495     }
 496     return join(' OR ', @parts), @binds;
 497   }
 498
 499   return $self->_recurse_where($cond);
 500 }
 501
 502 # This is hideously ugly, but SQLA does not understand multicol IN expressions
 503 # FIXME TEMPORARY - DQ should have native syntax for this
 504 # moved here to raise API questions
 505 #
 506 # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
 507 sub _where_op_multicolumn_in {
 508   my ($self, $lhs, $rhs) = @_;
 509
 510   if (! ref $lhs or ref $lhs eq 'ARRAY') {
 511     my (@sql, @bind);
 512     for (ref $lhs ? @$lhs : $lhs) {
 513       if (! ref $_) {
 514         push @sql, $self->_quote($_);
 515       }
 516       elsif (ref $_ eq 'SCALAR') {
 517         push @sql, $$_;
 518       }
 519       elsif (ref $_ eq 'REF' and ref $$_ eq 'ARRAY') {
 520         my ($s, @b) = @$$_;
 521         push @sql, $s;
 522         push @bind, @b;
 523       }
 524       else {
 525         $self->throw_exception("ARRAY of @{[ ref $_ ]}es unsupported for multicolumn IN lhs...");
 526       }
 527     }
 528     $lhs = \[ join(', ', @sql), @bind];
 529   }
 530   elsif (ref $lhs eq 'SCALAR') {
 531     $lhs = \[ $$lhs ];
 532   }
 533   elsif (ref $lhs eq 'REF' and ref $$lhs eq 'ARRAY' ) {
 534     # noop
 535   }
 536   else {
 537     $self->throw_exception( ref($lhs) . "es unsupported for multicolumn IN lhs...");
 538   }
 539
 540   # is this proper...?
 541   $rhs = \[ $self->_recurse_where($rhs) ];
 542
 543   for ($lhs, $rhs) {
 544     $$_->[0] = "( $$_->[0] )"
 545       unless $$_->[0] =~ /^ \s* \( .* \) \s* ^/xs;
 546   }
 547
 548   \[ join( ' IN ', shift @$$lhs, shift @$$rhs ), @$$lhs, @$$rhs ];
 549 }
 550
 551 1;
 552
 553 =head1 AUTHORS
 554
 555 See L<DBIx::Class/CONTRIBUTORS>.
 556
 557 =head1 LICENSE
 558
 559 You may distribute this code under the same terms as Perl itself.
 560
 561 =cut