lib/DBIx/Class/SQLMaker/OracleJoins.pm

   1 package DBIx::Class::SQLMaker::OracleJoins;
   2
   3 use warnings;
   4 use strict;
   5
   6 use base qw( DBIx::Class::SQLMaker::Oracle );
   7
   8 sub select {
   9   my ($self, $table, $fields, $where, $rs_attrs, @rest) = @_;
  10
  11   # pull out all join conds as regular WHEREs from all extra tables
  12   if (ref($table) eq 'ARRAY') {
  13     $where = $self->_oracle_joins($where, @{ $table }[ 1 .. $#$table ]);
  14   }
  15
  16   return $self->next::method($table, $fields, $where, $rs_attrs, @rest);
  17 }
  18
  19 sub _recurse_from {
  20   my ($self, $from, @join) = @_;
  21
  22   my @sqlf = $self->_from_chunk_to_sql($from);
  23
  24   for (@join) {
  25     my ($to, $on) = @$_;
  26
  27     if (ref $to eq 'ARRAY') {
  28       push (@sqlf, $self->_recurse_from(@{ $to }));
  29     }
  30     else {
  31       push (@sqlf, $self->_from_chunk_to_sql($to));
  32     }
  33   }
  34
  35   return join q{, }, @sqlf;
  36 }
  37
  38 sub _oracle_joins {
  39   my ($self, $where, @join) = @_;
  40   my $join_where = $self->_recurse_oracle_joins(@join);
  41
  42   if (keys %$join_where) {
  43     if (!defined($where)) {
  44       $where = $join_where;
  45     } else {
  46       if (ref($where) eq 'ARRAY') {
  47         $where = { -or => $where };
  48       }
  49       $where = { -and => [ $join_where, $where ] };
  50     }
  51   }
  52   return $where;
  53 }
  54
  55 sub _recurse_oracle_joins {
  56   my $self = shift;
  57
  58   my @where;
  59   for my $j (@_) {
  60     my ($to, $on) = @{ $j };
  61
  62     push @where, $self->_recurse_oracle_joins(@{ $to })
  63       if (ref $to eq 'ARRAY');
  64
  65     my $join_opts  = ref $to eq 'ARRAY' ? $to->[0] : $to;
  66     my $left_join  = q{};
  67     my $right_join = q{};
  68
  69     if (ref $join_opts eq 'HASH' and my $jt = $join_opts->{-join_type}) {
  70       #TODO: Support full outer joins -- this would happen much earlier in
  71       #the sequence since oracle 8's full outer join syntax is best
  72       #described as INSANE.
  73       $self->throw_exception("Can't handle full outer joins in Oracle 8 yet!\n")
  74         if $jt =~ /full/i;
  75
  76       $left_join  = q{(+)} if $jt =~ /left/i
  77         && $jt !~ /inner/i;
  78
  79       $right_join = q{(+)} if $jt =~ /right/i
  80         && $jt !~ /inner/i;
  81     }
  82
  83     # sadly SQLA treats where($scalar) as literal, so we need to jump some hoops
  84     push @where, map { \sprintf ('%s%s = %s%s',
  85       ref $_ ? $self->_recurse_where($_) : $self->_quote($_),
  86       $left_join,
  87       ref $on->{$_} ? $self->_recurse_where($on->{$_}) : $self->_quote($on->{$_}),
  88       $right_join,
  89     )} keys %$on;
  90   }
  91
  92   return { -and => \@where };
  93 }
  94
  95 1;
  96
  97 =pod
  98
  99 =head1 NAME
 100
 101 DBIx::Class::SQLMaker::OracleJoins - Pre-ANSI Joins-via-Where-Clause Syntax
 102
 103 =head1 PURPOSE
 104
 105 This module is used with Oracle < 9.0 due to lack of support for standard
 106 ANSI join syntax.
 107
 108 =head1 SYNOPSIS
 109
 110 Not intended for use directly; used as the sql_maker_class for schemas and components.
 111
 112 =head1 DESCRIPTION
 113
 114 Implements pre-ANSI joins specified in the where clause.  Instead of:
 115
 116     SELECT x FROM y JOIN z ON y.id = z.id
 117
 118 It will write:
 119
 120     SELECT x FROM y, z WHERE y.id = z.id
 121
 122 It should properly support left joins, and right joins.  Full outer joins are
 123 not possible due to the fact that Oracle requires the entire query be written
 124 to union the results of a left and right join, and by the time this module is
 125 called to create the where query and table definition part of the sql query,
 126 it's already too late.
 127
 128 =head1 METHODS
 129
 130 =over
 131
 132 =item select
 133
 134 Overrides DBIx::Class::SQLMaker's select() method, which calls _oracle_joins()
 135 to modify the column and table list before calling next::method().
 136
 137 =back
 138
 139 =head1 BUGS
 140
 141 Does not support full outer joins (however neither really does DBIC itself)
 142
 143 =head1 SEE ALSO
 144
 145 =over
 146
 147 =item L<DBIx::Class::Storage::DBI::Oracle::WhereJoins> - Storage class using this
 148
 149 =item L<DBIx::Class::SQLMaker> - Parent module
 150
 151 =item L<DBIx::Class> - Duh
 152
 153 =back
 154
 155 =head1 AUTHOR
 156
 157 Justin Wheeler C<< <jwheeler@datademons.com> >>
 158
 159 =head1 CONTRIBUTORS
 160
 161 David Jack Olrik C<< <djo@cpan.org> >>
 162
 163 =head1 LICENSE
 164
 165 This module is licensed under the same terms as Perl itself.
 166
 167 =cut
 168