1 package DBIx::Class::Row;
6 use base qw/DBIx::Class/;
8 use Scalar::Util 'blessed';
9 use List::Util 'first';
11 use DBIx::Class::Carp;
19 $ENV{DBIC_MULTICREATE_DEBUG}
26 __PACKAGE__->mk_group_accessors ( simple => [ in_storage => '_in_storage' ] );
30 DBIx::Class::Row - Basic row methods
36 This class is responsible for defining and doing basic operations on rows
37 derived from L<DBIx::Class::ResultSource> objects.
39 Result objects are returned from L<DBIx::Class::ResultSet>s using the
40 L<create|DBIx::Class::ResultSet/create>, L<find|DBIx::Class::ResultSet/find>,
41 L<next|DBIx::Class::ResultSet/next> and L<all|DBIx::Class::ResultSet/all> methods,
42 as well as invocations of 'single' (
43 L<belongs_to|DBIx::Class::Relationship/belongs_to>,
44 L<has_one|DBIx::Class::Relationship/has_one> or
45 L<might_have|DBIx::Class::Relationship/might_have>)
46 relationship accessors of L<Result|DBIx::Class::Manual::ResultClass> objects.
50 All "Row objects" derived from a Schema-attached L<DBIx::Class::ResultSet>
51 object (such as a typical C<< L<search|DBIx::Class::ResultSet/search>->
52 L<next|DBIx::Class::ResultSet/next> >> call) are actually Result
53 instances, based on your application's
54 L<Result class|DBIx::Class::Manual::Glossary/Result_class>.
56 L<DBIx::Class::Row> implements most of the row-based communication with the
57 underlying storage, but a Result class B<should not inherit from it directly>.
58 Usually, Result classes inherit from L<DBIx::Class::Core>, which in turn
59 combines the methods from several classes, one of them being
60 L<DBIx::Class::Row>. Therefore, while many of the methods available to a
61 L<DBIx::Class::Core>-derived Result class are described in the following
62 documentation, it does not detail all of the methods available to Result
63 objects. Refer to L<DBIx::Class::Manual::ResultClass> for more info.
69 my $result = My::Class->new(\%attrs);
71 my $result = $schema->resultset('MySource')->new(\%colsandvalues);
75 =item Arguments: \%attrs or \%colsandvalues
77 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
81 While you can create a new result object by calling C<new> directly on
82 this class, you are better off calling it on a
83 L<DBIx::Class::ResultSet> object.
85 When calling it directly, you will not get a complete, usable row
86 object until you pass or set the C<result_source> attribute, to a
87 L<DBIx::Class::ResultSource> instance that is attached to a
88 L<DBIx::Class::Schema> with a valid connection.
90 C<$attrs> is a hashref of column name, value data. It can also contain
91 some other attributes such as the C<result_source>.
93 Passing an object, or an arrayref of objects as a value will call
94 L<DBIx::Class::Relationship::Base/set_from_related> for you. When
95 passed a hashref or an arrayref of hashrefs as the value, these will
96 be turned into objects via new_related, and treated as if you had
99 For a more involved explanation, see L<DBIx::Class::ResultSet/create>.
101 Please note that if a value is not passed to new, no value will be sent
102 in the SQL INSERT call, and the column will therefore assume whatever
103 default value was specified in your database. While DBIC will retrieve the
104 value of autoincrement columns, it will never make an explicit database
105 trip to retrieve default values assigned by the RDBMS. You can explicitly
106 request that all values be fetched back from the database by calling
107 L</discard_changes>, or you can supply an explicit C<undef> to columns
108 with NULL as the default, and save yourself a SELECT.
112 The behavior described above will backfire if you use a foreign key column
113 with a database-defined default. If you call the relationship accessor on
114 an object that doesn't have a set value for the FK column, DBIC will throw
115 an exception, as it has no way of knowing the PK of the related object (if
120 ## It needs to store the new objects somewhere, and call insert on that list later when insert is called on this object. We may need an accessor for these so the user can retrieve them, if just doing ->new().
121 ## This only works because DBIC doesn't yet care to check whether the new_related objects have been passed all their mandatory columns
122 ## When doing the later insert, we need to make sure the PKs are set.
123 ## using _relationship_data in new and funky ways..
124 ## check Relationship::CascadeActions and Relationship::Accessor for compat
127 sub __new_related_find_or_new_helper {
128 my ($self, $relname, $values) = @_;
130 my $rsrc = $self->result_source;
132 # create a mock-object so all new/set_column component overrides will run:
133 my $rel_rs = $rsrc->related_source($relname)->resultset;
134 my $new_rel_obj = $rel_rs->new_result($values);
135 my $proc_data = { $new_rel_obj->get_columns };
137 if ($self->__their_pk_needs_us($relname)) {
138 MULTICREATE_DEBUG and print STDERR "MC $self constructing $relname via new_result\n";
141 elsif ($rsrc->_pk_depends_on($relname, $proc_data )) {
142 if (! keys %$proc_data) {
143 # there is nothing to search for - blind create
144 MULTICREATE_DEBUG and print STDERR "MC $self constructing default-insert $relname\n";
147 MULTICREATE_DEBUG and print STDERR "MC $self constructing $relname via find_or_new\n";
148 # this is not *really* find or new, as we don't want to double-new the
149 # data (thus potentially double encoding or whatever)
150 my $exists = $rel_rs->find ($proc_data);
151 return $exists if $exists;
156 my $us = $rsrc->source_name;
157 $self->throw_exception (
158 "Unable to determine relationship '$relname' direction from '$us', "
159 . "possibly due to a missing reverse-relationship on '$relname' to '$us'."
164 sub __their_pk_needs_us { # this should maybe be in resultsource.
165 my ($self, $relname) = @_;
166 my $rsrc = $self->result_source;
167 my $reverse = $rsrc->reverse_relationship_info($relname);
168 my $rel_source = $rsrc->related_source($relname);
169 my $us = { $self->get_columns };
170 foreach my $key (keys %$reverse) {
171 # if their primary key depends on us, then we have to
172 # just create a result and we'll fill it out afterwards
173 return 1 if $rel_source->_pk_depends_on($key, $us);
179 my ($class, $attrs) = @_;
180 $class = ref $class if ref $class;
182 my $new = bless { _column_data => {}, _in_storage => 0 }, $class;
185 $new->throw_exception("attrs must be a hashref")
186 unless ref($attrs) eq 'HASH';
188 my $rsrc = delete $attrs->{-result_source};
189 if ( my $h = delete $attrs->{-source_handle} ) {
190 $rsrc ||= $h->resolve;
193 $new->result_source($rsrc) if $rsrc;
195 if (my $col_from_rel = delete $attrs->{-cols_from_relations}) {
196 @{$new->{_ignore_at_insert}={}}{@$col_from_rel} = ();
199 my ($related,$inflated);
201 foreach my $key (keys %$attrs) {
202 if (ref $attrs->{$key}) {
203 ## Can we extract this lot to use with update(_or .. ) ?
204 $new->throw_exception("Can't do multi-create without result source")
206 my $info = $rsrc->relationship_info($key);
207 my $acc_type = $info->{attrs}{accessor} || '';
208 if ($acc_type eq 'single') {
209 my $rel_obj = delete $attrs->{$key};
210 if(!blessed $rel_obj) {
211 $rel_obj = $new->__new_related_find_or_new_helper($key, $rel_obj);
214 if ($rel_obj->in_storage) {
215 $new->{_rel_in_storage}{$key} = 1;
216 $new->set_from_related($key, $rel_obj);
218 MULTICREATE_DEBUG and print STDERR "MC $new uninserted $key $rel_obj\n";
221 $related->{$key} = $rel_obj;
224 elsif ($acc_type eq 'multi' && ref $attrs->{$key} eq 'ARRAY' ) {
225 my $others = delete $attrs->{$key};
226 my $total = @$others;
228 foreach my $idx (0 .. $#$others) {
229 my $rel_obj = $others->[$idx];
230 if(!blessed $rel_obj) {
231 $rel_obj = $new->__new_related_find_or_new_helper($key, $rel_obj);
234 if ($rel_obj->in_storage) {
235 $rel_obj->throw_exception ('A multi relationship can not be pre-existing when doing multicreate. Something went wrong');
237 MULTICREATE_DEBUG and
238 print STDERR "MC $new uninserted $key $rel_obj (${\($idx+1)} of $total)\n";
240 push(@objects, $rel_obj);
242 $related->{$key} = \@objects;
245 elsif ($acc_type eq 'filter') {
246 ## 'filter' should disappear and get merged in with 'single' above!
247 my $rel_obj = delete $attrs->{$key};
248 if(!blessed $rel_obj) {
249 $rel_obj = $new->__new_related_find_or_new_helper($key, $rel_obj);
251 if ($rel_obj->in_storage) {
252 $new->{_rel_in_storage}{$key} = 1;
255 MULTICREATE_DEBUG and print STDERR "MC $new uninserted $key $rel_obj\n";
257 $inflated->{$key} = $rel_obj;
259 } elsif ($class->has_column($key)
260 && $class->column_info($key)->{_inflate_info}) {
261 $inflated->{$key} = $attrs->{$key};
265 $new->throw_exception("No such column '$key' on $class")
266 unless $class->has_column($key);
267 $new->store_column($key => $attrs->{$key});
270 $new->{_relationship_data} = $related if $related;
271 $new->{_inflated_column} = $inflated if $inflated;
277 =head2 $column_accessor
279 # Each pair does the same thing
281 # (un-inflated, regular column)
282 my $val = $result->get_column('first_name');
283 my $val = $result->first_name;
285 $result->set_column('first_name' => $val);
286 $result->first_name($val);
288 # (inflated column via DBIx::Class::InflateColumn::DateTime)
289 my $val = $result->get_inflated_column('last_modified');
290 my $val = $result->last_modified;
292 $result->set_inflated_column('last_modified' => $val);
293 $result->last_modified($val);
297 =item Arguments: $value?
299 =item Return Value: $value
303 A column accessor method is created for each column, which is used for
304 getting/setting the value for that column.
306 The actual method name is based on the
307 L<accessor|DBIx::Class::ResultSource/accessor> name given during the
308 L<Result Class|DBIx::Class::Manual::ResultClass> L<column definition
309 |DBIx::Class::ResultSource/add_columns>. Like L</set_column>, this
310 will not store the data in the database until L</insert> or L</update>
311 is called on the row.
319 =item Arguments: none
321 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
325 Inserts an object previously created by L</new> into the database if
326 it isn't already in there. Returns the object itself. To insert an
327 entirely new row into the database, use L<DBIx::Class::ResultSet/create>.
329 To fetch an uninserted result object, call
330 L<new_result|DBIx::Class::ResultSet/new_result> on a resultset.
332 This will also insert any uninserted, related objects held inside this
333 one, see L<DBIx::Class::ResultSet/create> for more details.
339 return $self if $self->in_storage;
340 my $rsrc = $self->result_source;
341 $self->throw_exception("No result_source set on this object; can't insert")
344 my $storage = $rsrc->storage;
348 # Check if we stored uninserted relobjs here in new()
349 my %related_stuff = (%{$self->{_relationship_data} || {}},
350 %{$self->{_inflated_column} || {}});
352 # insert what needs to be inserted before us
354 for my $relname (keys %related_stuff) {
355 my $rel_obj = $related_stuff{$relname};
357 if (! $self->{_rel_in_storage}{$relname}) {
358 next unless (blessed $rel_obj && $rel_obj->isa('DBIx::Class::Row'));
360 next unless $rsrc->_pk_depends_on(
361 $relname, { $rel_obj->get_columns }
364 # The guard will save us if we blow out of this scope via die
365 $rollback_guard ||= $storage->txn_scope_guard;
367 MULTICREATE_DEBUG and print STDERR "MC $self pre-reconstructing $relname $rel_obj\n";
369 my $them = { %{$rel_obj->{_relationship_data} || {} }, $rel_obj->get_columns };
372 # if there are no keys - nothing to search for
373 if (keys %$them and $existing = $self->result_source
374 ->related_source($relname)
378 %{$rel_obj} = %{$existing};
384 $self->{_rel_in_storage}{$relname} = 1;
387 $self->set_from_related($relname, $rel_obj);
388 delete $related_stuff{$relname};
391 # start a transaction here if not started yet and there is more stuff
393 if (keys %related_stuff) {
394 $rollback_guard ||= $storage->txn_scope_guard
397 MULTICREATE_DEBUG and do {
398 no warnings 'uninitialized';
399 print STDERR "MC $self inserting (".join(', ', $self->get_columns).")\n";
402 # perform the insert - the storage will return everything it is asked to
403 # (autoinc primary columns and any retrieve_on_insert columns)
404 my %current_rowdata = $self->get_columns;
405 my $returned_cols = $storage->insert(
407 { %current_rowdata }, # what to insert, copy because the storage *will* change it
410 for (keys %$returned_cols) {
411 $self->store_column($_, $returned_cols->{$_})
412 # this ensures we fire store_column only once
413 # (some asshats like overriding it)
415 (!exists $current_rowdata{$_})
417 (defined $current_rowdata{$_} xor defined $returned_cols->{$_})
419 (defined $current_rowdata{$_} and $current_rowdata{$_} ne $returned_cols->{$_})
423 delete $self->{_column_data_in_storage};
424 $self->in_storage(1);
426 $self->{_dirty_columns} = {};
427 $self->{related_resultsets} = {};
429 foreach my $relname (keys %related_stuff) {
430 next unless $rsrc->has_relationship ($relname);
432 my @cands = ref $related_stuff{$relname} eq 'ARRAY'
433 ? @{$related_stuff{$relname}}
434 : $related_stuff{$relname}
437 if (@cands && blessed $cands[0] && $cands[0]->isa('DBIx::Class::Row')
439 my $reverse = $rsrc->reverse_relationship_info($relname);
440 foreach my $obj (@cands) {
441 $obj->set_from_related($_, $self) for keys %$reverse;
442 if ($self->__their_pk_needs_us($relname)) {
443 if (exists $self->{_ignore_at_insert}{$relname}) {
444 MULTICREATE_DEBUG and print STDERR "MC $self skipping post-insert on $relname\n";
447 MULTICREATE_DEBUG and print STDERR "MC $self inserting $relname $obj\n";
451 MULTICREATE_DEBUG and print STDERR "MC $self post-inserting $obj\n";
458 delete $self->{_ignore_at_insert};
460 $rollback_guard->commit if $rollback_guard;
467 $result->in_storage; # Get value
468 $result->in_storage(1); # Set value
472 =item Arguments: none or 1|0
474 =item Return Value: 1|0
478 Indicates whether the object exists as a row in the database or
479 not. This is set to true when L<DBIx::Class::ResultSet/find>,
480 L<DBIx::Class::ResultSet/create> or L<DBIx::Class::ResultSet/insert>
483 Creating a result object using L<DBIx::Class::ResultSet/new_result>, or
484 calling L</delete> on one, sets it to false.
489 $result->update(\%columns?)
493 =item Arguments: none or a hashref
495 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
499 Throws an exception if the result object is not yet in the database,
500 according to L</in_storage>. Returns the object itself.
502 This method issues an SQL UPDATE query to commit any changes to the
503 object to the database if required (see L</get_dirty_columns>).
504 It throws an exception if a proper WHERE clause uniquely identifying
505 the database row can not be constructed (see
506 L<significance of primary keys|DBIx::Class::Manual::Intro/The Significance and Importance of Primary Keys>
509 Also takes an optional hashref of C<< column_name => value >> pairs
510 to update on the object first. Be aware that the hashref will be
511 passed to C<set_inflated_columns>, which might edit it in place, so
512 don't rely on it being the same after a call to C<update>. If you
513 need to preserve the hashref, it is sufficient to pass a shallow copy
514 to C<update>, e.g. ( { %{ $href } } )
516 If the values passed or any of the column values set on the object
517 contain scalar references, e.g.:
519 $result->last_modified(\'NOW()')->update();
521 $result->update({ last_modified => \'NOW()' });
523 The update will pass the values verbatim into SQL. (See
524 L<SQL::Abstract> docs). The values in your Result object will NOT change
525 as a result of the update call, if you want the object to be updated
526 with the actual values from the database, call L</discard_changes>
529 $result->update()->discard_changes();
531 To determine before calling this method, which column values have
532 changed and will be updated, call L</get_dirty_columns>.
534 To check if any columns will be updated, call L</is_changed>.
536 To force a column to be updated, call L</make_column_dirty> before
542 my ($self, $upd) = @_;
544 $self->set_inflated_columns($upd) if $upd;
546 my %to_update = $self->get_dirty_columns
549 $self->throw_exception( "Not in database" ) unless $self->in_storage;
551 my $rows = $self->result_source->storage->update(
552 $self->result_source, \%to_update, $self->_storage_ident_condition
555 $self->throw_exception( "Can't update ${self}: row not found" );
556 } elsif ($rows > 1) {
557 $self->throw_exception("Can't update ${self}: updated more than one row");
559 $self->{_dirty_columns} = {};
560 $self->{related_resultsets} = {};
561 delete $self->{_column_data_in_storage};
571 =item Arguments: none
573 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
577 Throws an exception if the object is not in the database according to
578 L</in_storage>. Also throws an exception if a proper WHERE clause
579 uniquely identifying the database row can not be constructed (see
580 L<significance of primary keys|DBIx::Class::Manual::Intro/The Significance and Importance of Primary Keys>
583 The object is still perfectly usable, but L</in_storage> will
584 now return 0 and the object must be reinserted using L</insert>
585 before it can be used to L</update> the row again.
587 If you delete an object in a class with a C<has_many> relationship, an
588 attempt is made to delete all the related objects as well. To turn
589 this behaviour off, pass C<< cascade_delete => 0 >> in the C<$attr>
590 hashref of the relationship, see L<DBIx::Class::Relationship>. Any
591 database-level cascade or restrict will take precedence over a
592 DBIx-Class-based cascading delete, since DBIx-Class B<deletes the
593 main row first> and only then attempts to delete any remaining related
596 If you delete an object within a txn_do() (see L<DBIx::Class::Storage/txn_do>)
597 and the transaction subsequently fails, the result object will remain marked as
598 not being in storage. If you know for a fact that the object is still in
599 storage (i.e. by inspecting the cause of the transaction's failure), you can
600 use C<< $obj->in_storage(1) >> to restore consistency between the object and
601 the database. This would allow a subsequent C<< $obj->delete >> to work
604 See also L<DBIx::Class::ResultSet/delete>.
611 $self->throw_exception( "Not in database" ) unless $self->in_storage;
613 $self->result_source->storage->delete(
614 $self->result_source, $self->_storage_ident_condition
617 delete $self->{_column_data_in_storage};
618 $self->in_storage(0);
621 my $rsrc = try { $self->result_source_instance }
622 or $self->throw_exception("Can't do class delete without a ResultSource instance");
624 my $attrs = @_ > 1 && ref $_[$#_] eq 'HASH' ? { %{pop(@_)} } : {};
625 my $query = ref $_[0] eq 'HASH' ? $_[0] : {@_};
626 $rsrc->resultset->search(@_)->delete;
633 my $val = $result->get_column($col);
637 =item Arguments: $columnname
639 =item Return Value: The value of the column
643 Throws an exception if the column name given doesn't exist according
644 to L<has_column|DBIx::Class::ResultSource/has_column>.
646 Returns a raw column value from the result object, if it has already
647 been fetched from the database or set by an accessor.
649 If an L<inflated value|DBIx::Class::InflateColumn> has been set, it
650 will be deflated and returned.
652 Note that if you used the C<columns> or the C<select/as>
653 L<search attributes|DBIx::Class::ResultSet/ATTRIBUTES> on the resultset from
654 which C<$result> was derived, and B<did not include> C<$columnname> in the list,
655 this method will return C<undef> even if the database contains some value.
657 To retrieve all loaded column values as a hash, use L</get_columns>.
662 my ($self, $column) = @_;
663 $self->throw_exception( "Can't fetch data as class method" ) unless ref $self;
664 return $self->{_column_data}{$column} if exists $self->{_column_data}{$column};
665 if (exists $self->{_inflated_column}{$column}) {
666 return $self->store_column($column,
667 $self->_deflated_column($column, $self->{_inflated_column}{$column}));
669 $self->throw_exception( "No such column '${column}'" ) unless $self->has_column($column);
673 =head2 has_column_loaded
675 if ( $result->has_column_loaded($col) ) {
676 print "$col has been loaded from db";
681 =item Arguments: $columnname
683 =item Return Value: 0|1
687 Returns a true value if the column value has been loaded from the
688 database (or set locally).
692 sub has_column_loaded {
693 my ($self, $column) = @_;
694 $self->throw_exception( "Can't call has_column data as class method" ) unless ref $self;
695 return 1 if exists $self->{_inflated_column}{$column};
696 return exists $self->{_column_data}{$column};
701 my %data = $result->get_columns;
705 =item Arguments: none
707 =item Return Value: A hash of columnname, value pairs.
711 Returns all loaded column data as a hash, containing raw values. To
712 get just one value for a particular column, use L</get_column>.
714 See L</get_inflated_columns> to get the inflated values.
720 if (exists $self->{_inflated_column}) {
721 foreach my $col (keys %{$self->{_inflated_column}}) {
722 unless (exists $self->{_column_data}{$col}) {
724 # if cached related_resultset is present assume this was a prefetch
726 "Returning primary keys of prefetched 'filter' rels as part of get_columns() is deprecated and will "
727 . 'eventually be removed entirely (set DBIC_COLUMNS_INCLUDE_FILTER_RELS to disable this warning)'
729 ! $ENV{DBIC_COLUMNS_INCLUDE_FILTER_RELS}
731 defined $self->{related_resultsets}{$col}
733 defined $self->{related_resultsets}{$col}->get_cache
736 $self->store_column($col, $self->_deflated_column($col, $self->{_inflated_column}{$col}));
740 return %{$self->{_column_data}};
743 =head2 get_dirty_columns
745 my %data = $result->get_dirty_columns;
749 =item Arguments: none
751 =item Return Value: A hash of column, value pairs
755 Only returns the column, value pairs for those columns that have been
756 changed on this object since the last L</update> or L</insert> call.
758 See L</get_columns> to fetch all column/value pairs.
762 sub get_dirty_columns {
764 return map { $_ => $self->{_column_data}{$_} }
765 keys %{$self->{_dirty_columns}};
768 =head2 make_column_dirty
770 $result->make_column_dirty($col)
774 =item Arguments: $columnname
776 =item Return Value: not defined
780 Throws an exception if the column does not exist.
782 Marks a column as having been changed regardless of whether it has
787 sub make_column_dirty {
788 my ($self, $column) = @_;
790 $self->throw_exception( "No such column '${column}'" )
791 unless exists $self->{_column_data}{$column} || $self->has_column($column);
793 # the entire clean/dirty code relies on exists, not on true/false
794 return 1 if exists $self->{_dirty_columns}{$column};
796 $self->{_dirty_columns}{$column} = 1;
798 # if we are just now making the column dirty, and if there is an inflated
799 # value, force it over the deflated one
800 if (exists $self->{_inflated_column}{$column}) {
801 $self->store_column($column,
802 $self->_deflated_column(
803 $column, $self->{_inflated_column}{$column}
809 =head2 get_inflated_columns
811 my %inflated_data = $obj->get_inflated_columns;
815 =item Arguments: none
817 =item Return Value: A hash of column, object|value pairs
821 Returns a hash of all column keys and associated values. Values for any
822 columns set to use inflation will be inflated and returns as objects.
824 See L</get_columns> to get the uninflated values.
826 See L<DBIx::Class::InflateColumn> for how to setup inflation.
830 sub get_inflated_columns {
833 my $loaded_colinfo = $self->columns_info ([
834 grep { $self->has_column_loaded($_) } $self->columns
837 my %cols_to_return = ( %{$self->{_column_data}}, %$loaded_colinfo );
839 unless ($ENV{DBIC_COLUMNS_INCLUDE_FILTER_RELS}) {
840 for (keys %$loaded_colinfo) {
841 # if cached related_resultset is present assume this was a prefetch
843 $loaded_colinfo->{$_}{_inflate_info}
845 defined $self->{related_resultsets}{$_}
847 defined $self->{related_resultsets}{$_}->get_cache
850 "Returning prefetched 'filter' rels as part of get_inflated_columns() is deprecated and will "
851 . 'eventually be removed entirely (set DBIC_COLUMNS_INCLUDE_FILTER_RELS to disable this warning)'
860 ! exists $loaded_colinfo->{$_}
863 exists $loaded_colinfo->{$_}{accessor}
865 ! defined $loaded_colinfo->{$_}{accessor}
867 ) ? $self->get_column($_)
869 defined $loaded_colinfo->{$_}{accessor}
870 ? $loaded_colinfo->{$_}{accessor}
873 )} keys %cols_to_return;
876 sub _is_column_numeric {
877 my ($self, $column) = @_;
878 my $colinfo = $self->column_info ($column);
880 # cache for speed (the object may *not* have a resultsource instance)
882 ! defined $colinfo->{is_numeric}
884 my $storage = try { $self->result_source->schema->storage }
886 $colinfo->{is_numeric} =
887 $storage->is_datatype_numeric ($colinfo->{data_type})
893 return $colinfo->{is_numeric};
898 $result->set_column($col => $val);
902 =item Arguments: $columnname, $value
904 =item Return Value: $value
908 Sets a raw column value. If the new value is different from the old one,
909 the column is marked as dirty for when you next call L</update>.
911 If passed an object or reference as a value, this method will happily
912 attempt to store it, and a later L</insert> or L</update> will try and
913 stringify/numify as appropriate. To set an object to be deflated
914 instead, see L</set_inflated_columns>, or better yet, use L</$column_accessor>.
919 my ($self, $column, $new_value) = @_;
921 my $had_value = $self->has_column_loaded($column);
922 my ($old_value, $in_storage) = ($self->get_column($column), $self->in_storage)
925 $new_value = $self->store_column($column, $new_value);
928 $self->{_dirty_columns}{$column}
930 $in_storage # no point tracking dirtyness on uninserted data
931 ? ! $self->_eq_column_values ($column, $old_value, $new_value)
936 # FIXME sadly the update code just checks for keys, not for their value
937 $self->{_dirty_columns}{$column} = 1;
939 # Clear out the relation/inflation cache related to this column
941 # FIXME - this is a quick *largely incorrect* hack, pending a more
942 # serious rework during the merge of single and filter rels
943 my $relnames = $self->result_source->{_relationships};
944 for my $relname (keys %$relnames) {
946 my $acc = $relnames->{$relname}{attrs}{accessor} || '';
948 if ( $acc eq 'single' and $relnames->{$relname}{attrs}{fk_columns}{$column} ) {
949 delete $self->{related_resultsets}{$relname};
950 delete $self->{_relationship_data}{$relname};
951 #delete $self->{_inflated_column}{$relname};
953 elsif ( $acc eq 'filter' and $relname eq $column) {
954 delete $self->{related_resultsets}{$relname};
955 #delete $self->{_relationship_data}{$relname};
956 delete $self->{_inflated_column}{$relname};
961 # value change from something (even if NULL)
964 # no storage - no storage-value
967 # no value already stored (multiple changes before commit to storage)
968 ! exists $self->{_column_data_in_storage}{$column}
970 $self->_track_storage_value($column)
972 $self->{_column_data_in_storage}{$column} = $old_value;
979 sub _eq_column_values {
980 my ($self, $col, $old, $new) = @_;
982 if (defined $old xor defined $new) {
985 elsif (not defined $old) { # both undef
988 elsif ($old eq $new) {
991 elsif ($self->_is_column_numeric($col)) { # do a numeric comparison if datatype allows it
999 # returns a boolean indicating if the passed column should have its original
1000 # value tracked between column changes and commitment to storage
1001 sub _track_storage_value {
1002 my ($self, $col) = @_;
1003 return defined first { $col eq $_ } ($self->primary_columns);
1008 $result->set_columns({ $col => $val, ... });
1012 =item Arguments: \%columndata
1014 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
1018 Sets multiple column, raw value pairs at once.
1020 Works as L</set_column>.
1025 my ($self, $values) = @_;
1026 $self->set_column( $_, $values->{$_} ) for keys %$values;
1030 =head2 set_inflated_columns
1032 $result->set_inflated_columns({ $col => $val, $relname => $obj, ... });
1036 =item Arguments: \%columndata
1038 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
1042 Sets more than one column value at once. Any inflated values are
1043 deflated and the raw values stored.
1045 Any related values passed as Result objects, using the relation name as a
1046 key, are reduced to the appropriate foreign key values and stored. If
1047 instead of related result objects, a hashref of column, value data is
1048 passed, will create the related object first then store.
1050 Will even accept arrayrefs of data as a value to a
1051 L<DBIx::Class::Relationship/has_many> key, and create the related
1052 objects if necessary.
1054 Be aware that the input hashref might be edited in place, so don't rely
1055 on it being the same after a call to C<set_inflated_columns>. If you
1056 need to preserve the hashref, it is sufficient to pass a shallow copy
1057 to C<set_inflated_columns>, e.g. ( { %{ $href } } )
1059 See also L<DBIx::Class::Relationship::Base/set_from_related>.
1063 sub set_inflated_columns {
1064 my ( $self, $upd ) = @_;
1065 foreach my $key (keys %$upd) {
1066 if (ref $upd->{$key}) {
1067 my $info = $self->relationship_info($key);
1068 my $acc_type = $info->{attrs}{accessor} || '';
1069 if ($acc_type eq 'single') {
1070 my $rel_obj = delete $upd->{$key};
1071 $self->set_from_related($key => $rel_obj);
1072 $self->{_relationship_data}{$key} = $rel_obj;
1074 elsif ($acc_type eq 'multi') {
1075 $self->throw_exception(
1076 "Recursive update is not supported over relationships of type '$acc_type' ($key)"
1079 elsif ($self->has_column($key) && exists $self->column_info($key)->{_inflate_info}) {
1080 $self->set_inflated_column($key, delete $upd->{$key});
1084 $self->set_columns($upd);
1089 my $copy = $orig->copy({ change => $to, ... });
1093 =item Arguments: \%replacementdata
1095 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> copy
1099 Inserts a new row into the database, as a copy of the original
1100 object. If a hashref of replacement data is supplied, these will take
1101 precedence over data in the original. Also any columns which have
1102 the L<column info attribute|DBIx::Class::ResultSource/add_columns>
1103 C<< is_auto_increment => 1 >> are explicitly removed before the copy,
1104 so that the database can insert its own autoincremented values into
1107 Relationships will be followed by the copy procedure B<only> if the
1108 relationship specifies a true value for its
1109 L<cascade_copy|DBIx::Class::Relationship::Base> attribute. C<cascade_copy>
1110 is set by default on C<has_many> relationships and unset on all others.
1115 my ($self, $changes) = @_;
1117 my $col_data = { %{$self->{_column_data}} };
1119 my $colinfo = $self->columns_info([ keys %$col_data ]);
1120 foreach my $col (keys %$col_data) {
1121 delete $col_data->{$col}
1122 if $colinfo->{$col}{is_auto_increment};
1125 my $new = { _column_data => $col_data };
1126 bless $new, ref $self;
1128 $new->result_source(my $source = $self->result_source);
1129 $new->set_inflated_columns($changes);
1132 # Its possible we'll have 2 relations to the same Source. We need to make
1133 # sure we don't try to insert the same row twice else we'll violate unique
1135 my $relnames_copied = {};
1137 foreach my $relname ($source->relationships) {
1138 my $rel_info = $source->relationship_info($relname);
1140 next unless $rel_info->{attrs}{cascade_copy};
1142 my $resolved = $source->_resolve_condition(
1143 $rel_info->{cond}, $relname, $new, $relname
1146 if (ref($resolved) eq 'REF') {
1147 $resolved = $source->_extract_fixed_values_for($$resolved, 'me');
1150 my $copied = $relnames_copied->{ $rel_info->{source} } ||= {};
1151 foreach my $related ($self->search_related($relname)->all) {
1152 my $id_str = join("\0", $related->id);
1153 next if $copied->{$id_str};
1154 $copied->{$id_str} = 1;
1155 my $rel_copy = $related->copy($resolved);
1164 $result->store_column($col => $val);
1168 =item Arguments: $columnname, $value
1170 =item Return Value: The value sent to storage
1174 Set a raw value for a column without marking it as changed. This
1175 method is used internally by L</set_column> which you should probably
1178 This is the lowest level at which data is set on a result object,
1179 extend this method to catch all data setting methods.
1184 my ($self, $column, $value) = @_;
1185 $self->throw_exception( "No such column '${column}'" )
1186 unless exists $self->{_column_data}{$column} || $self->has_column($column);
1187 $self->throw_exception( "set_column called for ${column} without value" )
1189 return $self->{_column_data}{$column} = $value;
1192 =head2 inflate_result
1194 Class->inflate_result($result_source, \%me, \%prefetch?)
1198 =item Arguments: L<$result_source|DBIx::Class::ResultSource>, \%columndata, \%prefetcheddata
1200 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
1204 All L<DBIx::Class::ResultSet> methods that retrieve data from the
1205 database and turn it into result objects call this method.
1207 Extend this method in your Result classes to hook into this process,
1208 for example to rebless the result into a different class.
1210 Reblessing can also be done more easily by setting C<result_class> in
1211 your Result class. See L<DBIx::Class::ResultSource/result_class>.
1213 Different types of results can also be created from a particular
1214 L<DBIx::Class::ResultSet>, see L<DBIx::Class::ResultSet/result_class>.
1218 sub inflate_result {
1219 my ($class, $rsrc, $me, $prefetch) = @_;
1222 { _column_data => $me, _result_source => $rsrc },
1223 ref $class || $class
1227 for my $relname ( keys %$prefetch ) {
1229 my $relinfo = $rsrc->relationship_info($relname) or do {
1231 "Inflation into non-existent relationship '%s' of '%s' requested",
1235 if (my ($colname) = sort { length($a) <=> length ($b) } keys %{$prefetch->{$relname}[0] || {}} ) {
1236 $err .= sprintf ", check the inflation specification (columns/as) ending in '...%s.%s'",
1241 $rsrc->throw_exception($err);
1244 $class->throw_exception("No accessor type declared for prefetched relationship '$relname'")
1245 unless $relinfo->{attrs}{accessor};
1249 $prefetch->{$relname}
1251 @{$prefetch->{$relname}}
1253 ref($prefetch->{$relname}) ne $DBIx::Class::ResultSource::RowParser::Util::null_branch_class
1256 my $rel_rs = $new->related_resultset($relname);
1258 if (ref $prefetch->{$relname}[0] eq 'ARRAY') {
1259 my $rel_rsrc = $rel_rs->result_source;
1260 my $rel_class = $rel_rs->result_class;
1261 my $rel_inflator = $rel_class->can('inflate_result');
1263 { $rel_class->$rel_inflator ( $rel_rsrc, @$_ ) }
1264 @{$prefetch->{$relname}}
1268 @rel_objects = $rel_rs->result_class->inflate_result(
1269 $rel_rs->result_source, @{$prefetch->{$relname}}
1274 if ($relinfo->{attrs}{accessor} eq 'single') {
1275 $new->{_relationship_data}{$relname} = $rel_objects[0];
1277 elsif ($relinfo->{attrs}{accessor} eq 'filter') {
1278 $new->{_inflated_column}{$relname} = $rel_objects[0];
1281 $new->related_resultset($relname)->set_cache(\@rel_objects);
1285 $new->in_storage (1);
1289 =head2 update_or_insert
1291 $result->update_or_insert
1295 =item Arguments: none
1297 =item Return Value: Result of update or insert operation
1301 L</Update>s the object if it's already in the database, according to
1302 L</in_storage>, else L</insert>s it.
1304 =head2 insert_or_update
1306 $obj->insert_or_update
1308 Alias for L</update_or_insert>
1312 sub insert_or_update { shift->update_or_insert(@_) }
1314 sub update_or_insert {
1316 return ($self->in_storage ? $self->update : $self->insert);
1321 my @changed_col_names = $result->is_changed();
1322 if ($result->is_changed()) { ... }
1326 =item Arguments: none
1328 =item Return Value: 0|1 or @columnnames
1332 In list context returns a list of columns with uncommited changes, or
1333 in scalar context returns a true value if there are uncommitted
1339 return keys %{shift->{_dirty_columns} || {}};
1342 =head2 is_column_changed
1344 if ($result->is_column_changed('col')) { ... }
1348 =item Arguments: $columname
1350 =item Return Value: 0|1
1354 Returns a true value if the column has uncommitted changes.
1358 sub is_column_changed {
1359 my( $self, $col ) = @_;
1360 return exists $self->{_dirty_columns}->{$col};
1363 =head2 result_source
1365 my $resultsource = $result->result_source;
1369 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1371 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1375 Accessor to the L<DBIx::Class::ResultSource> this object was created from.
1380 $_[0]->throw_exception( 'result_source can be called on instances only' )
1384 ? $_[0]->{_result_source} = $_[1]
1386 # note this is a || not a ||=, the difference is important
1387 : $_[0]->{_result_source} || do {
1388 my $class = ref $_[0];
1389 $_[0]->can('result_source_instance')
1390 ? $_[0]->result_source_instance
1391 : $_[0]->throw_exception(
1392 "No result source instance registered for $class, did you forget to call $class->table(...) ?"
1398 =head2 register_column
1400 $column_info = { .... };
1401 $class->register_column($column_name, $column_info);
1405 =item Arguments: $columnname, \%columninfo
1407 =item Return Value: not defined
1411 Registers a column on the class. If the column_info has an 'accessor'
1412 key, creates an accessor named after the value if defined; if there is
1413 no such key, creates an accessor with the same name as the column
1415 The column_info attributes are described in
1416 L<DBIx::Class::ResultSource/add_columns>
1420 sub register_column {
1421 my ($class, $col, $info) = @_;
1423 if (exists $info->{accessor}) {
1424 return unless defined $info->{accessor};
1425 $acc = [ $info->{accessor}, $col ];
1427 $class->mk_group_accessors('column' => $acc);
1430 =head2 get_from_storage
1432 my $copy = $result->get_from_storage($attrs)
1436 =item Arguments: \%attrs
1438 =item Return Value: A Result object
1442 Fetches a fresh copy of the Result object from the database and returns it.
1443 Throws an exception if a proper WHERE clause identifying the database row
1444 can not be constructed (i.e. if the original object does not contain its
1446 L<primary key|DBIx::Class::Manual::Intro/The Significance and Importance of Primary Keys>
1447 ). If passed the \%attrs argument, will first apply these attributes to
1448 the resultset used to find the row.
1450 This copy can then be used to compare to an existing result object, to
1451 determine if any changes have been made in the database since it was
1454 To just update your Result object with any latest changes from the
1455 database, use L</discard_changes> instead.
1457 The \%attrs argument should be compatible with
1458 L<DBIx::Class::ResultSet/ATTRIBUTES>.
1462 sub get_from_storage {
1463 my $self = shift @_;
1464 my $attrs = shift @_;
1465 my $resultset = $self->result_source->resultset;
1467 if(defined $attrs) {
1468 $resultset = $resultset->search(undef, $attrs);
1471 return $resultset->find($self->_storage_ident_condition);
1474 =head2 discard_changes
1476 $result->discard_changes
1480 =item Arguments: none or $attrs
1482 =item Return Value: self (updates object in-place)
1486 Re-selects the row from the database, losing any changes that had
1487 been made. Throws an exception if a proper C<WHERE> clause identifying
1488 the database row can not be constructed (i.e. if the original object
1489 does not contain its entire
1490 L<primary key|DBIx::Class::Manual::Intro/The Significance and Importance of Primary Keys>).
1492 This method can also be used to refresh from storage, retrieving any
1493 changes made since the row was last read from storage.
1495 $attrs, if supplied, is expected to be a hashref of attributes suitable for passing as the
1496 second argument to C<< $resultset->search($cond, $attrs) >>;
1498 Note: If you are using L<DBIx::Class::Storage::DBI::Replicated> as your
1499 storage, please kept in mind that if you L</discard_changes> on a row that you
1500 just updated or created, you should wrap the entire bit inside a transaction.
1501 Otherwise you run the risk that you insert or update to the master database
1502 but read from a replicant database that has not yet been updated from the
1503 master. This will result in unexpected results.
1507 sub discard_changes {
1508 my ($self, $attrs) = @_;
1509 return unless $self->in_storage; # Don't reload if we aren't real!
1511 # add a replication default to read from the master only
1512 $attrs = { force_pool => 'master', %{$attrs||{}} };
1514 if( my $current_storage = $self->get_from_storage($attrs)) {
1516 # Set $self to the current.
1517 %$self = %$current_storage;
1519 # Avoid a possible infinite loop with
1520 # sub DESTROY { $_[0]->discard_changes }
1521 bless $current_storage, 'Do::Not::Exist';
1526 $self->in_storage(0);
1531 =head2 throw_exception
1533 See L<DBIx::Class::Schema/throw_exception>.
1537 sub throw_exception {
1540 if (ref $self && ref $self->result_source ) {
1541 $self->result_source->throw_exception(@_)
1544 DBIx::Class::Exception->throw(@_);
1550 my @pk = $result->id;
1554 =item Arguments: none
1556 =item Returns: A list of primary key values
1560 Returns the primary key(s) for a row. Can't be called as a class method.
1561 Actually implemented in L<DBIx::Class::PK>
1563 =head1 AUTHOR AND CONTRIBUTORS
1565 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
1569 You may distribute this code under the same terms as Perl itself.