lib/DBIx/Class/Row.pm

   1 package DBIx::Class::Row;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class/;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::Row - Basic row methods
  11
  12 =head1 SYNOPSIS
  13
  14 =head1 DESCRIPTION
  15
  16 This class is responsible for defining and doing basic operations on rows
  17 derived from L<DBIx::Class::Table> objects.
  18
  19 =head1 METHODS
  20
  21 =head2 new
  22
  23   my $obj = My::Class->new($attrs);
  24
  25 Creates a new row object from column => value mappings passed as a hash ref
  26
  27 =cut
  28
  29 sub new {
  30   my ($class, $attrs) = @_;
  31   $class = ref $class if ref $class;
  32   my $new = bless({ _column_data => { } }, $class);
  33   if ($attrs) {
  34     $new->throw("attrs must be a hashref" ) unless ref($attrs) eq 'HASH';
  35     while (my ($k, $v) = each %{$attrs}) {
  36       die "No such column $k on $class" unless $class->has_column($k);
  37       $new->store_column($k => $v);
  38     }
  39   }
  40   return $new;
  41 }
  42
  43 =head2 insert
  44
  45   $obj->insert;
  46
  47 Inserts an object into the database if it isn't already in there. Returns
  48 the object itself.
  49
  50 =cut
  51
  52 sub insert {
  53   my ($self) = @_;
  54   return $self if $self->in_storage;
  55   #use Data::Dumper; warn Dumper($self);
  56   $self->result_source->storage->insert(
  57     $self->_table_name, { $self->get_columns });
  58   $self->in_storage(1);
  59   $self->{_dirty_columns} = {};
  60   return $self;
  61 }
  62
  63 =head2 in_storage
  64
  65   $obj->in_storage; # Get value
  66   $obj->in_storage(1); # Set value
  67
  68 Indicated whether the object exists as a row in the database or not
  69
  70 =cut
  71
  72 sub in_storage {
  73   my ($self, $val) = @_;
  74   $self->{_in_storage} = $val if @_ > 1;
  75   return $self->{_in_storage};
  76 }
  77
  78 =head2 update
  79
  80   $obj->update;
  81
  82 Must be run on an object that is already in the database; issues an SQL
  83 UPDATE query to commit any changes to the object to the db if required.
  84
  85 =cut
  86
  87 sub update {
  88   my ($self, $upd) = @_;
  89   $self->throw( "Not in database" ) unless $self->in_storage;
  90   my %to_update = $self->get_dirty_columns;
  91   return -1 unless keys %to_update;
  92   my $rows = $self->result_source->storage->update(
  93                $self->result_source->from, \%to_update, $self->ident_condition);
  94   if ($rows == 0) {
  95     $self->throw( "Can't update ${self}: row not found" );
  96   } elsif ($rows > 1) {
  97     $self->throw("Can't update ${self}: updated more than one row");
  98   }
  99   $self->{_dirty_columns} = {};
 100   return $self;
 101 }
 102
 103 =head2 delete
 104
 105   $obj->delete
 106
 107 Deletes the object from the database. The object is still perfectly usable
 108 accessor-wise etc. but ->in_storage will now return 0 and the object must
 109 be re ->insert'ed before it can be ->update'ed
 110
 111 =cut
 112
 113 sub delete {
 114   my $self = shift;
 115   if (ref $self) {
 116     $self->throw( "Not in database" ) unless $self->in_storage;
 117     #warn $self->_ident_cond.' '.join(', ', $self->_ident_values);
 118     $self->result_source->storage->delete(
 119       $self->result_source->from, $self->ident_condition);
 120     $self->in_storage(undef);
 121     #$self->store_column($_ => undef) for $self->primary_columns;
 122       # Should probably also arrange to trash PK if auto
 123       # but if we do, post-delete cascade triggers fail :/
 124   } else {
 125     my $attrs = { };
 126     if (@_ > 1 && ref $_[$#_] eq 'HASH') {
 127       $attrs = { %{ pop(@_) } };
 128     }
 129     my $query = (ref $_[0] eq 'HASH' ? $_[0] : {@_});
 130     $self->storage->delete($self->_table_name, $query);
 131   }
 132   return $self;
 133 }
 134
 135 =head2 get_column
 136
 137   my $val = $obj->get_column($col);
 138
 139 Gets a column value from a row object. Currently, does not do
 140 any queries; the column must have already been fetched from
 141 the database and stored in the object.
 142
 143 =cut
 144
 145 sub get_column {
 146   my ($self, $column) = @_;
 147   $self->throw( "Can't fetch data as class method" ) unless ref $self;
 148   return $self->{_column_data}{$column}
 149     if exists $self->{_column_data}{$column};
 150   $self->throw( "No such column '${column}'" ) unless $self->has_column($column);
 151   return undef;
 152 }
 153
 154 =head2 get_columns
 155
 156   my %data = $obj->get_columns;
 157
 158 Does C<get_column>, for all column values at once.
 159
 160 =cut
 161
 162 sub get_columns {
 163   my $self = shift;
 164   return return %{$self->{_column_data}};
 165 }
 166
 167 =head2 get_dirty_columns
 168
 169   my %data = $obj->get_dirty_columns;
 170
 171 Identical to get_columns but only returns those that have been changed.
 172
 173 =cut
 174
 175 sub get_dirty_columns {
 176   my $self = shift;
 177   return map { $_ => $self->{_column_data}{$_} }
 178            keys %{$self->{_dirty_columns}};
 179 }
 180
 181 =head2 set_column
 182
 183   $obj->set_column($col => $val);
 184
 185 Sets a column value. If the new value is different from the old one,
 186 the column is marked as dirty for when you next call $obj->update.
 187
 188 =cut
 189
 190 sub set_column {
 191   my $self = shift;
 192   my ($column) = @_;
 193   my $old = $self->get_column($column);
 194   my $ret = $self->store_column(@_);
 195   $self->{_dirty_columns}{$column} = 1 unless defined $old && $old eq $ret;
 196   return $ret;
 197 }
 198
 199 =head2 set_columns
 200
 201   my $copy = $orig->set_columns({ $col => $val, ... });
 202
 203 Sets more than one column value at once.
 204
 205 =cut
 206
 207 sub set_columns {
 208   my ($self,$data) = @_;
 209   while (my ($col,$val) = each %$data) {
 210     $self->set_column($col,$val);
 211   }
 212 }
 213
 214 =head2 copy
 215
 216   my $copy = $orig->copy({ change => $to, ... });
 217
 218 Inserts a new row with the specified changes.
 219
 220 =cut
 221
 222 =head2 store_column
 223
 224   $obj->store_column($col => $val);
 225
 226 Sets a column value without marking it as dirty.
 227
 228 =cut
 229
 230 sub store_column {
 231   my ($self, $column, $value) = @_;
 232   $self->throw( "No such column '${column}'" )
 233     unless exists $self->{_column_data}{$column} || $self->has_column($column);
 234   $self->throw( "set_column called for ${column} without value" )
 235     if @_ < 3;
 236   return $self->{_column_data}{$column} = $value;
 237 }
 238
 239 =head2 inflate_result
 240
 241   Class->inflate_result(\%me, \%prefetch?)
 242
 243 Called by ResultSet to inflate a result from storage
 244
 245 =cut
 246
 247 sub inflate_result {
 248   my ($class, $me, $prefetch) = @_;
 249   #use Data::Dumper; print Dumper(@_);
 250   my $new = bless({ _column_data => $me, _in_storage => 1 },
 251                     ref $class || $class);
 252   my $schema;
 253   PRE: foreach my $pre (keys %{$prefetch||{}}) {
 254     my $rel_obj = $class->relationship_info($pre);
 255     die "Can't prefetch non-eistant relationship ${pre}" unless $rel_obj;
 256     $schema ||= $new->result_source->schema;
 257     my $pre_class = $schema->class($rel_obj->{class});
 258     my $fetched = $pre_class->inflate_result(@{$prefetch->{$pre}});
 259     $class->throw("No accessor for prefetched $pre")
 260       unless defined $rel_obj->{attrs}{accessor};
 261     PRIMARY: foreach my $pri ($rel_obj->{class}->primary_columns) {
 262       unless (defined $fetched->get_column($pri)) {
 263         undef $fetched;
 264         last PRIMARY;
 265       }
 266     }
 267     if ($rel_obj->{attrs}{accessor} eq 'single') {
 268       $new->{_relationship_data}{$pre} = $fetched;
 269     } elsif ($rel_obj->{attrs}{accessor} eq 'filter') {
 270       $new->{_inflated_column}{$pre} = $fetched;
 271     } else {
 272       $class->throw("Don't know how to store prefetched $pre");
 273     }
 274   }
 275   return $new;
 276 }
 277
 278 sub copy {
 279   my ($self, $changes) = @_;
 280   my $new = bless({ _column_data => { %{$self->{_column_data}}} }, ref $self);
 281   $new->set_column($_ => $changes->{$_}) for keys %$changes;
 282   return $new->insert;
 283 }
 284
 285 =head2 insert_or_update
 286
 287   $obj->insert_or_update
 288
 289 Updates the object if it's already in the db, else inserts it.
 290
 291 =cut
 292
 293 sub insert_or_update {
 294   my $self = shift;
 295   return ($self->in_storage ? $self->update : $self->insert);
 296 }
 297
 298 =head2 is_changed
 299
 300   my @changed_col_names = $obj->is_changed
 301
 302 =cut
 303
 304 sub is_changed {
 305   return keys %{shift->{_dirty_columns} || {}};
 306 }
 307
 308 1;
 309
 310 =head1 AUTHORS
 311
 312 Matt S. Trout <mst@shadowcatsystems.co.uk>
 313
 314 =head1 LICENSE
 315
 316 You may distribute this code under the same terms as Perl itself.
 317
 318 =cut
 319