lib/DBIx/Class/ResultSourceProxy/Table.pm

   1 package DBIx::Class::ResultSourceProxy::Table;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::ResultSourceProxy/;
   7
   8 use DBIx::Class::ResultSource::Table;
   9 use Scalar::Util 'blessed';
  10 use namespace::clean;
  11
  12 __PACKAGE__->mk_classdata(table_class => 'DBIx::Class::ResultSource::Table');
  13
  14 __PACKAGE__->mk_classdata('table_alias'); # FIXME: Doesn't actually do
  15                                           # anything yet!
  16
  17 sub _init_result_source_instance {
  18     my $class = shift;
  19
  20     $class->mk_classdata('result_source_instance')
  21         unless $class->can('result_source_instance');
  22
  23     my $table = $class->result_source_instance;
  24     my $class_has_table_instance = ($table and $table->result_class eq $class);
  25     return $table if $class_has_table_instance;
  26
  27     my $table_class = $class->table_class;
  28     $class->ensure_class_loaded($table_class);
  29
  30     if( $table ) {
  31         $table = $table_class->new({
  32             %$table,
  33             result_class => $class,
  34             source_name => undef,
  35             schema => undef
  36         });
  37     }
  38     else {
  39         $table = $table_class->new({
  40             name            => undef,
  41             result_class    => $class,
  42             source_name     => undef,
  43         });
  44     }
  45
  46     $class->result_source_instance($table);
  47
  48     return $table;
  49 }
  50
  51 =head1 NAME
  52
  53 DBIx::Class::ResultSourceProxy::Table - provides a classdata table
  54 object and method proxies
  55
  56 =head1 SYNOPSIS
  57
  58   __PACKAGE__->table('cd');
  59   __PACKAGE__->add_columns(qw/cdid artist title year/);
  60   __PACKAGE__->set_primary_key('cdid');
  61
  62 =head1 METHODS
  63
  64 =head2 add_columns
  65
  66   __PACKAGE__->add_columns(qw/cdid artist title year/);
  67
  68 Adds columns to the current class and creates accessors for them.
  69
  70 =cut
  71
  72 =head2 table
  73
  74   __PACKAGE__->table('tbl_name');
  75
  76 Gets or sets the table name.
  77
  78 =cut
  79
  80 sub table {
  81   my ($class, $table) = @_;
  82   return $class->result_source_instance->name unless $table;
  83
  84   unless (blessed $table && $table->isa($class->table_class)) {
  85
  86     my $table_class = $class->table_class;
  87     $class->ensure_class_loaded($table_class);
  88
  89     $table = $table_class->new({
  90         $class->can('result_source_instance') ?
  91           %{$class->result_source_instance||{}} : (),
  92         name => $table,
  93         result_class => $class,
  94         source_name => undef,
  95     });
  96   }
  97
  98   $class->mk_classdata('result_source_instance')
  99     unless $class->can('result_source_instance');
 100
 101   $class->result_source_instance($table);
 102
 103   return $class->result_source_instance->name;
 104 }
 105
 106 =head2 has_column
 107
 108   if ($obj->has_column($col)) { ... }
 109
 110 Returns 1 if the class has a column of this name, 0 otherwise.
 111
 112 =cut
 113
 114 =head2 column_info
 115
 116   my $info = $obj->column_info($col);
 117
 118 Returns the column metadata hashref for a column. For a description of
 119 the various types of column data in this hashref, see
 120 L<DBIx::Class::ResultSource/add_column>
 121
 122 =cut
 123
 124 =head2 columns
 125
 126   my @column_names = $obj->columns;
 127
 128 =cut
 129
 130 1;
 131
 132 =head1 AUTHORS
 133
 134 Matt S. Trout <mst@shadowcatsystems.co.uk>
 135
 136 =head1 LICENSE
 137
 138 You may distribute this code under the same terms as Perl itself.
 139
 140 =cut
 141