lib/DBIx/Class/ResultSource/View.pm

   1 package DBIx::Class::ResultSource::View;
   2
   3 use strict;
   4 use warnings;
   5
   6 use DBIx::Class::ResultSet;
   7
   8 use base qw/DBIx::Class/;
   9 __PACKAGE__->load_components(qw/ResultSource/);
  10 __PACKAGE__->mk_group_accessors(
  11   'simple' => qw(is_virtual view_definition)
  12 );
  13
  14 =head1 NAME
  15
  16 DBIx::Class::ResultSource::View - ResultSource object representing a view
  17
  18 =head1 SYNOPSIS
  19
  20   package MyDB::Schema::Result::Year2000CDs;
  21
  22   use base qw/DBIx::Class::Core/;
  23
  24   __PACKAGE__->table_class('DBIx::Class::ResultSource::View');
  25
  26   __PACKAGE__->table('year2000cds');
  27   __PACKAGE__->result_source_instance->is_virtual(1);
  28   __PACKAGE__->result_source_instance->view_definition(
  29       "SELECT cdid, artist, title FROM cd WHERE year ='2000'"
  30   );
  31   __PACKAGE__->add_columns(
  32     'cdid' => {
  33       data_type => 'integer',
  34       is_auto_increment => 1,
  35     },
  36     'artist' => {
  37       data_type => 'integer',
  38     },
  39     'title' => {
  40       data_type => 'varchar',
  41       size      => 100,
  42     },
  43   );
  44
  45 =head1 DESCRIPTION
  46
  47 View object that inherits from L<DBIx::Class::ResultSource>
  48
  49 This class extends ResultSource to add basic view support.
  50
  51 A view has a L</view_definition>, which contains a SQL query. The query can
  52 only have parameters if L</is_virtual> is set to true. It may contain JOINs,
  53 sub selects and any other SQL your database supports.
  54
  55 View definition SQL is deployed to your database on
  56 L<DBIx::Class::Schema/deploy> unless you set L</is_virtual> to true.
  57
  58 Deploying the view does B<not> translate it between different database
  59 syntaxes, so be careful what you write in your view SQL.
  60
  61 Virtual views (L</is_virtual> true), are assumed to not
  62 exist in your database as a real view. The L</view_definition> in this
  63 case replaces the view name in a FROM clause in a subselect.
  64
  65 =head1 EXAMPLES
  66
  67 Having created the MyDB::Schema::Year2000CDs schema as shown in the SYNOPSIS
  68 above, you can then:
  69
  70   $2000_cds = $schema->resultset('Year2000CDs')
  71                      ->search()
  72                      ->all();
  73   $count    = $schema->resultset('Year2000CDs')
  74                      ->search()
  75                      ->count();
  76
  77 If you modified the schema to include a placeholder
  78
  79   __PACKAGE__->result_source_instance->view_definition(
  80       "SELECT cdid, artist, title FROM cd WHERE year ='?'"
  81   );
  82
  83 and ensuring you have is_virtual set to true:
  84
  85   __PACKAGE__->result_source_instance->is_virtual(1);
  86
  87 You could now say:
  88
  89   $2001_cds = $schema->resultset('Year2000CDs')
  90                      ->search({}, { bind => [2001] })
  91                      ->all();
  92   $count    = $schema->resultset('Year2000CDs')
  93                      ->search({}, { bind => [2001] })
  94                      ->count();
  95
  96 =head1 SQL EXAMPLES
  97
  98 =over
  99
 100 =item is_virtual set to false
 101
 102   $schema->resultset('Year2000CDs')->all();
 103
 104   SELECT cdid, artist, title FROM year2000cds me
 105
 106 =item is_virtual set to true
 107
 108   $schema->resultset('Year2000CDs')->all();
 109
 110   SELECT cdid, artist, title FROM
 111     (SELECT cdid, artist, title FROM cd WHERE year ='2000') me
 112
 113 =back
 114
 115 =head1 METHODS
 116
 117 =head2 is_virtual
 118
 119   __PACKAGE__->result_source_instance->is_virtual(1);
 120
 121 Set to true for a virtual view, false or unset for a real
 122 database-based view.
 123
 124 =head2 view_definition
 125
 126   __PACKAGE__->result_source_instance->view_definition(
 127       "SELECT cdid, artist, title FROM cd WHERE year ='2000'"
 128       );
 129
 130 An SQL query for your view. Will not be translated across database
 131 syntaxes.
 132
 133
 134 =head1 OVERRIDDEN METHODS
 135
 136 =head2 from
 137
 138 Returns the FROM entry for the table (i.e. the view name)
 139 or the SQL as a subselect if this is a virtual view.
 140
 141 =cut
 142
 143 sub from {
 144   my $self = shift;
 145   return \"(${\$self->view_definition})" if $self->is_virtual;
 146   return $self->name;
 147 }
 148
 149 1;
 150
 151 =head1 AUTHORS
 152
 153 Matt S. Trout <mst@shadowcatsystems.co.uk>
 154
 155 With Contributions from:
 156
 157 Guillermo Roditi E<lt>groditi@cpan.orgE<gt>
 158
 159 Jess Robinson <castaway@desert-island.me.uk>
 160
 161 Wallace Reis <wreis@cpan.org>
 162
 163 =head1 LICENSE
 164
 165 You may distribute this code under the same terms as Perl itself.
 166
 167 =cut
 168