lib/DBIx/Class/ResultSetManager.pm

   1 package DBIx::Class::ResultSetManager;
   2 use strict;
   3 use base 'DBIx::Class';
   4 use Class::Inspector;
   5
   6 __PACKAGE__->mk_classdata($_) for qw/ base_resultset_class table_resultset_class_suffix /;
   7 __PACKAGE__->base_resultset_class('DBIx::Class::ResultSet');
   8 __PACKAGE__->table_resultset_class_suffix('::_resultset');
   9
  10 sub table {
  11     my ($self,@rest) = @_;
  12     $self->next::method(@rest);
  13     $self->_register_attributes;
  14     $self->_register_resultset_class;
  15 }
  16
  17 sub load_resultset_components {
  18     my ($self,@comp) = @_;
  19     my $resultset_class = $self->_setup_resultset_class;
  20     $resultset_class->load_components(@comp);
  21 }
  22
  23 sub _register_attributes {
  24     my $self = shift;
  25     my $cache = $self->_attr_cache;
  26     foreach my $meth (@{Class::Inspector->methods($self) || []}) {
  27         my $attrs = $cache->{$self->can($meth)};
  28         next unless $attrs;
  29         if ($attrs->[0] eq 'resultset') {
  30             no strict 'refs';
  31             my $resultset_class = $self->_setup_resultset_class;
  32             *{"$resultset_class\::$meth"} = *{"$self\::$meth"};
  33             undef *{"$self\::$meth"};
  34         }
  35     }
  36 }
  37
  38 sub _setup_resultset_class {
  39     my $self = shift;
  40     my $resultset_class = $self . $self->table_resultset_class_suffix;
  41     no strict 'refs';
  42     unless (@{"$resultset_class\::ISA"}) {
  43         @{"$resultset_class\::ISA"} = ($self->base_resultset_class);
  44     }
  45     return $resultset_class;
  46 }
  47
  48 sub _register_resultset_class {
  49     my $self = shift;
  50     my $resultset_class = $self . $self->table_resultset_class_suffix;
  51     no strict 'refs';
  52     if (@{"$resultset_class\::ISA"}) {
  53         $self->result_source_instance->resultset_class($resultset_class);
  54     } else {
  55         $self->result_source_instance->resultset_class($self->base_resultset_class);
  56     }
  57 }
  58
  59 1;